gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Case; use Sem_Case;
  42 with Sem_Ch3;  use Sem_Ch3;
  43 with Sem_Ch8;  use Sem_Ch8;
  44 with Sem_Disp; use Sem_Disp;
  45 with Sem_Elab; use Sem_Elab;
  46 with Sem_Eval; use Sem_Eval;
  47 with Sem_Res;  use Sem_Res;
  48 with Sem_Type; use Sem_Type;
  49 with Sem_Util; use Sem_Util;
  50 with Sem_Warn; use Sem_Warn;
  51 with Snames;   use Snames;
  52 with Stand;    use Stand;
  53 with Sinfo;    use Sinfo;
  54 with Targparm; use Targparm;
  55 with Tbuild;   use Tbuild;
  56 with Uintp;    use Uintp;
  57
  58 package body Sem_Ch5 is
  59
  60    Unblocked_Exit_Count : Nat := 0;
  61    --  This variable is used when processing if statements, case statements,
  62    --  and block statements. It counts the number of exit points that are not
  63    --  blocked by unconditional transfer instructions: for IF and CASE, these
  64    --  are the branches of the conditional; for a block, they are the statement
  65    --  sequence of the block, and the statement sequences of any exception
  66    --  handlers that are part of the block. When processing is complete, if
  67    --  this count is zero, it means that control cannot fall through the IF,
  68    --  CASE or block statement. This is used for the generation of warning
  69    --  messages. This variable is recursively saved on entry to processing the
  70    --  construct, and restored on exit.
  71
  72    -----------------------
  73    -- Local Subprograms --
  74    -----------------------
  75
  76    procedure Analyze_Iteration_Scheme (N : Node_Id);
  77
  78    ------------------------
  79    -- Analyze_Assignment --
  80    ------------------------
  81
  82    procedure Analyze_Assignment (N : Node_Id) is
  83       Lhs  : constant Node_Id := Name (N);
  84       Rhs  : constant Node_Id := Expression (N);
  85       T1   : Entity_Id;
  86       T2   : Entity_Id;
  87       Decl : Node_Id;
  88
  89       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  90       --  N is the node for the left hand side of an assignment, and it
  91       --  is not a variable. This routine issues an appropriate diagnostic.
  92
  93       procedure Kill_Lhs;
  94       --  This is called to kill current value settings of a simple variable
  95       --  on the left hand side. We call it if we find any error in analyzing
  96       --  the assignment, and at the end of processing before setting any new
  97       --  current values in place.
  98
  99       procedure Set_Assignment_Type
 100         (Opnd      : Node_Id;
 101          Opnd_Type : in out Entity_Id);
 102       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 103       --  is the nominal subtype. This procedure is used to deal with cases
 104       --  where the nominal subtype must be replaced by the actual subtype.
 105
 106       -------------------------------
 107       -- Diagnose_Non_Variable_Lhs --
 108       -------------------------------
 109
 110       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 111       begin
 112          --  Not worth posting another error if left hand side already
 113          --  flagged as being illegal in some respect.
 114
 115          if Error_Posted (N) then
 116             return;
 117
 118          --  Some special bad cases of entity names
 119
 120          elsif Is_Entity_Name (N) then
 121             declare
 122                Ent : constant Entity_Id := Entity (N);
 123
 124             begin
 125                if Ekind (Ent) = E_In_Parameter then
 126                   Error_Msg_N
 127                     ("assignment to IN mode parameter not allowed", N);
 128
 129                --  Renamings of protected private components are turned into
 130                --  constants when compiling a protected function. In the case
 131                --  of single protected types, the private component appears
 132                --  directly.
 133
 134                elsif (Is_Prival (Ent)
 135                         and then
 136                           (Ekind (Current_Scope) = E_Function
 137                              or else Ekind (Enclosing_Dynamic_Scope (
 138                                        Current_Scope)) = E_Function))
 139                    or else
 140                      (Ekind (Ent) = E_Component
 141                         and then Is_Protected_Type (Scope (Ent)))
 142                then
 143                   Error_Msg_N
 144                     ("protected function cannot modify protected object", N);
 145
 146                elsif Ekind (Ent) = E_Loop_Parameter then
 147                   Error_Msg_N
 148                     ("assignment to loop parameter not allowed", N);
 149
 150                else
 151                   Error_Msg_N
 152                     ("left hand side of assignment must be a variable", N);
 153                end if;
 154             end;
 155
 156          --  For indexed components or selected components, test prefix
 157
 158          elsif Nkind (N) = N_Indexed_Component then
 159             Diagnose_Non_Variable_Lhs (Prefix (N));
 160
 161          --  Another special case for assignment to discriminant
 162
 163          elsif Nkind (N) = N_Selected_Component then
 164             if Present (Entity (Selector_Name (N)))
 165               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 166             then
 167                Error_Msg_N
 168                  ("assignment to discriminant not allowed", N);
 169             else
 170                Diagnose_Non_Variable_Lhs (Prefix (N));
 171             end if;
 172
 173          else
 174             --  If we fall through, we have no special message to issue!
 175
 176             Error_Msg_N ("left hand side of assignment must be a variable", N);
 177          end if;
 178       end Diagnose_Non_Variable_Lhs;
 179
 180       --------------
 181       -- Kill_LHS --
 182       --------------
 183
 184       procedure Kill_Lhs is
 185       begin
 186          if Is_Entity_Name (Lhs) then
 187             declare
 188                Ent : constant Entity_Id := Entity (Lhs);
 189             begin
 190                if Present (Ent) then
 191                   Kill_Current_Values (Ent);
 192                end if;
 193             end;
 194          end if;
 195       end Kill_Lhs;
 196
 197       -------------------------
 198       -- Set_Assignment_Type --
 199       -------------------------
 200
 201       procedure Set_Assignment_Type
 202         (Opnd      : Node_Id;
 203          Opnd_Type : in out Entity_Id)
 204       is
 205       begin
 206          Require_Entity (Opnd);
 207
 208          --  If the assignment operand is an in-out or out parameter, then we
 209          --  get the actual subtype (needed for the unconstrained case).
 210          --  If the operand is the actual in an entry declaration, then within
 211          --  the accept statement it is replaced with a local renaming, which
 212          --  may also have an actual subtype.
 213
 214          if Is_Entity_Name (Opnd)
 215            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 216                       or else Ekind (Entity (Opnd)) =
 217                            E_In_Out_Parameter
 218                       or else Ekind (Entity (Opnd)) =
 219                            E_Generic_In_Out_Parameter
 220                       or else
 221                         (Ekind (Entity (Opnd)) = E_Variable
 222                           and then Nkind (Parent (Entity (Opnd))) =
 223                              N_Object_Renaming_Declaration
 224                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 225                              N_Accept_Statement))
 226          then
 227             Opnd_Type := Get_Actual_Subtype (Opnd);
 228
 229          --  If assignment operand is a component reference, then we get the
 230          --  actual subtype of the component for the unconstrained case.
 231
 232          elsif Nkind_In (Opnd, N_Selected_Component, N_Explicit_Dereference)
 233            and then not Is_Unchecked_Union (Opnd_Type)
 234          then
 235             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 236
 237             if Present (Decl) then
 238                Insert_Action (N, Decl);
 239                Mark_Rewrite_Insertion (Decl);
 240                Analyze (Decl);
 241                Opnd_Type := Defining_Identifier (Decl);
 242                Set_Etype (Opnd, Opnd_Type);
 243                Freeze_Itype (Opnd_Type, N);
 244
 245             elsif Is_Constrained (Etype (Opnd)) then
 246                Opnd_Type := Etype (Opnd);
 247             end if;
 248
 249          --  For slice, use the constrained subtype created for the slice
 250
 251          elsif Nkind (Opnd) = N_Slice then
 252             Opnd_Type := Etype (Opnd);
 253          end if;
 254       end Set_Assignment_Type;
 255
 256    --  Start of processing for Analyze_Assignment
 257
 258    begin
 259       Mark_Coextensions (N, Rhs);
 260
 261       Analyze (Rhs);
 262       Analyze (Lhs);
 263
 264       --  Start type analysis for assignment
 265
 266       T1 := Etype (Lhs);
 267
 268       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 269       --  must compute the intersection of the possible types on each side.
 270
 271       if Is_Overloaded (Lhs) then
 272          declare
 273             I  : Interp_Index;
 274             It : Interp;
 275
 276          begin
 277             T1 := Any_Type;
 278             Get_First_Interp (Lhs, I, It);
 279
 280             while Present (It.Typ) loop
 281                if Has_Compatible_Type (Rhs, It.Typ) then
 282                   if T1 /= Any_Type then
 283
 284                      --  An explicit dereference is overloaded if the prefix
 285                      --  is. Try to remove the ambiguity on the prefix, the
 286                      --  error will be posted there if the ambiguity is real.
 287
 288                      if Nkind (Lhs) = N_Explicit_Dereference then
 289                         declare
 290                            PI    : Interp_Index;
 291                            PI1   : Interp_Index := 0;
 292                            PIt   : Interp;
 293                            Found : Boolean;
 294
 295                         begin
 296                            Found := False;
 297                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 298
 299                            while Present (PIt.Typ) loop
 300                               if Is_Access_Type (PIt.Typ)
 301                                 and then Has_Compatible_Type
 302                                            (Rhs, Designated_Type (PIt.Typ))
 303                               then
 304                                  if Found then
 305                                     PIt :=
 306                                       Disambiguate (Prefix (Lhs),
 307                                         PI1, PI, Any_Type);
 308
 309                                     if PIt = No_Interp then
 310                                        Error_Msg_N
 311                                          ("ambiguous left-hand side"
 312                                             & " in assignment", Lhs);
 313                                        exit;
 314                                     else
 315                                        Resolve (Prefix (Lhs), PIt.Typ);
 316                                     end if;
 317
 318                                     exit;
 319                                  else
 320                                     Found := True;
 321                                     PI1 := PI;
 322                                  end if;
 323                               end if;
 324
 325                               Get_Next_Interp (PI, PIt);
 326                            end loop;
 327                         end;
 328
 329                      else
 330                         Error_Msg_N
 331                           ("ambiguous left-hand side in assignment", Lhs);
 332                         exit;
 333                      end if;
 334                   else
 335                      T1 := It.Typ;
 336                   end if;
 337                end if;
 338
 339                Get_Next_Interp (I, It);
 340             end loop;
 341          end;
 342
 343          if T1 = Any_Type then
 344             Error_Msg_N
 345               ("no valid types for left-hand side for assignment", Lhs);
 346             Kill_Lhs;
 347             return;
 348          end if;
 349       end if;
 350
 351       --  The resulting assignment type is T1, so now we will resolve the
 352       --  left hand side of the assignment using this determined type.
 353
 354       Resolve (Lhs, T1);
 355
 356       --  Cases where Lhs is not a variable
 357
 358       if not Is_Variable (Lhs) then
 359
 360          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 361          --  a protected object.
 362
 363          declare
 364             Ent : Entity_Id;
 365             S   : Entity_Id;
 366
 367          begin
 368             if Ada_Version >= Ada_05 then
 369
 370                --  Handle chains of renamings
 371
 372                Ent := Lhs;
 373                while Nkind (Ent) in N_Has_Entity
 374                  and then Present (Entity (Ent))
 375                  and then Present (Renamed_Object (Entity (Ent)))
 376                loop
 377                   Ent := Renamed_Object (Entity (Ent));
 378                end loop;
 379
 380                if (Nkind (Ent) = N_Attribute_Reference
 381                      and then Attribute_Name (Ent) = Name_Priority)
 382
 383                   --  Renamings of the attribute Priority applied to protected
 384                   --  objects have been previously expanded into calls to the
 385                   --  Get_Ceiling run-time subprogram.
 386
 387                  or else
 388                   (Nkind (Ent) = N_Function_Call
 389                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 390                                 or else
 391                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 392                then
 393                   --  The enclosing subprogram cannot be a protected function
 394
 395                   S := Current_Scope;
 396                   while not (Is_Subprogram (S)
 397                                and then Convention (S) = Convention_Protected)
 398                      and then S /= Standard_Standard
 399                   loop
 400                      S := Scope (S);
 401                   end loop;
 402
 403                   if Ekind (S) = E_Function
 404                     and then Convention (S) = Convention_Protected
 405                   then
 406                      Error_Msg_N
 407                        ("protected function cannot modify protected object",
 408                         Lhs);
 409                   end if;
 410
 411                   --  Changes of the ceiling priority of the protected object
 412                   --  are only effective if the Ceiling_Locking policy is in
 413                   --  effect (AARM D.5.2 (5/2)).
 414
 415                   if Locking_Policy /= 'C' then
 416                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 417                                   "no effect?", Lhs);
 418                      Error_Msg_N ("\since no Locking_Policy has been " &
 419                                   "specified", Lhs);
 420                   end if;
 421
 422                   return;
 423                end if;
 424             end if;
 425          end;
 426
 427          Diagnose_Non_Variable_Lhs (Lhs);
 428          return;
 429
 430       --  Error of assigning to limited type. We do however allow this in
 431       --  certain cases where the front end generates the assignments.
 432
 433       elsif Is_Limited_Type (T1)
 434         and then not Assignment_OK (Lhs)
 435         and then not Assignment_OK (Original_Node (Lhs))
 436         and then not Is_Value_Type (T1)
 437       then
 438          Error_Msg_N
 439            ("left hand of assignment must not be limited type", Lhs);
 440          Explain_Limited_Type (T1, Lhs);
 441          return;
 442
 443       --  Enforce RM 3.9.3 (8): left-hand side cannot be abstract
 444
 445       elsif Is_Interface (T1)
 446         and then not Is_Class_Wide_Type (T1)
 447       then
 448          Error_Msg_N
 449            ("target of assignment operation may not be abstract", Lhs);
 450          return;
 451       end if;
 452
 453       --  Resolution may have updated the subtype, in case the left-hand
 454       --  side is a private protected component. Use the correct subtype
 455       --  to avoid scoping issues in the back-end.
 456
 457       T1 := Etype (Lhs);
 458
 459       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 460       --  type. For example:
 461
 462       --    limited with P;
 463       --    package Pkg is
 464       --      type Acc is access P.T;
 465       --    end Pkg;
 466
 467       --    with Pkg; use Acc;
 468       --    procedure Example is
 469       --       A, B : Acc;
 470       --    begin
 471       --       A.all := B.all;  -- ERROR
 472       --    end Example;
 473
 474       if Nkind (Lhs) = N_Explicit_Dereference
 475         and then Ekind (T1) = E_Incomplete_Type
 476       then
 477          Error_Msg_N ("invalid use of incomplete type", Lhs);
 478          Kill_Lhs;
 479          return;
 480       end if;
 481
 482       --  Now we can complete the resolution of the right hand side
 483
 484       Set_Assignment_Type (Lhs, T1);
 485       Resolve (Rhs, T1);
 486
 487       --  This is the point at which we check for an unset reference
 488
 489       Check_Unset_Reference (Rhs);
 490       Check_Unprotected_Access (Lhs, Rhs);
 491
 492       --  Remaining steps are skipped if Rhs was syntactically in error
 493
 494       if Rhs = Error then
 495          Kill_Lhs;
 496          return;
 497       end if;
 498
 499       T2 := Etype (Rhs);
 500
 501       if not Covers (T1, T2) then
 502          Wrong_Type (Rhs, Etype (Lhs));
 503          Kill_Lhs;
 504          return;
 505       end if;
 506
 507       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 508       --  types, use the non-limited view if available
 509
 510       if Nkind (Rhs) = N_Explicit_Dereference
 511         and then Ekind (T2) = E_Incomplete_Type
 512         and then Is_Tagged_Type (T2)
 513         and then Present (Non_Limited_View (T2))
 514       then
 515          T2 := Non_Limited_View (T2);
 516       end if;
 517
 518       Set_Assignment_Type (Rhs, T2);
 519
 520       if Total_Errors_Detected /= 0 then
 521          if No (T1) then
 522             T1 := Any_Type;
 523          end if;
 524
 525          if No (T2) then
 526             T2 := Any_Type;
 527          end if;
 528       end if;
 529
 530       if T1 = Any_Type or else T2 = Any_Type then
 531          Kill_Lhs;
 532          return;
 533       end if;
 534
 535       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 536       --  to be class-wide. The case where the rhs is a dynamically tagged call
 537       --  to a dispatching operation with a controlling access result is
 538       --  excluded from this check, since the target has an access type (and
 539       --  no tag propagation occurs in that case).
 540
 541       if (Is_Class_Wide_Type (T2)
 542            or else (Is_Dynamically_Tagged (Rhs)
 543                      and then not Is_Access_Type (T1)))
 544         and then not Is_Class_Wide_Type (T1)
 545       then
 546          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 547
 548       elsif Is_Class_Wide_Type (T1)
 549         and then not Is_Class_Wide_Type (T2)
 550         and then not Is_Tag_Indeterminate (Rhs)
 551         and then not Is_Dynamically_Tagged (Rhs)
 552       then
 553          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 554       end if;
 555
 556       --  Propagate the tag from a class-wide target to the rhs when the rhs
 557       --  is a tag-indeterminate call.
 558
 559       if Is_Tag_Indeterminate (Rhs) then
 560          if Is_Class_Wide_Type (T1) then
 561             Propagate_Tag (Lhs, Rhs);
 562
 563          elsif Nkind (Rhs) = N_Function_Call
 564               and then Is_Entity_Name (Name (Rhs))
 565               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 566          then
 567             Error_Msg_N
 568               ("call to abstract function must be dispatching", Name (Rhs));
 569
 570          elsif Nkind (Rhs) = N_Qualified_Expression
 571            and then Nkind (Expression (Rhs)) = N_Function_Call
 572               and then Is_Entity_Name (Name (Expression (Rhs)))
 573               and then
 574                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 575          then
 576             Error_Msg_N
 577               ("call to abstract function must be dispatching",
 578                 Name (Expression (Rhs)));
 579          end if;
 580       end if;
 581
 582       --  Ada 2005 (AI-385): When the lhs type is an anonymous access type,
 583       --  apply an implicit conversion of the rhs to that type to force
 584       --  appropriate static and run-time accessibility checks. This applies
 585       --  as well to anonymous access-to-subprogram types that are component
 586       --  subtypes or formal parameters.
 587
 588       if Ada_Version >= Ada_05
 589         and then Is_Access_Type (T1)
 590       then
 591          if Is_Local_Anonymous_Access (T1)
 592            or else Ekind (T2) = E_Anonymous_Access_Subprogram_Type
 593          then
 594             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 595             Analyze_And_Resolve (Rhs, T1);
 596          end if;
 597       end if;
 598
 599       --  Ada 2005 (AI-231): Assignment to not null variable
 600
 601       if Ada_Version >= Ada_05
 602         and then Can_Never_Be_Null (T1)
 603         and then not Assignment_OK (Lhs)
 604       then
 605          --  Case where we know the right hand side is null
 606
 607          if Known_Null (Rhs) then
 608             Apply_Compile_Time_Constraint_Error
 609               (N   => Rhs,
 610                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 611                Reason => CE_Null_Not_Allowed);
 612
 613             --  We still mark this as a possible modification, that's necessary
 614             --  to reset Is_True_Constant, and desirable for xref purposes.
 615
 616             Note_Possible_Modification (Lhs, Sure => True);
 617             return;
 618
 619          --  If we know the right hand side is non-null, then we convert to the
 620          --  target type, since we don't need a run time check in that case.
 621
 622          elsif not Can_Never_Be_Null (T2) then
 623             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 624             Analyze_And_Resolve (Rhs, T1);
 625          end if;
 626       end if;
 627
 628       if Is_Scalar_Type (T1) then
 629          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 630
 631       --  For array types, verify that lengths match. If the right hand side
 632       --  if a function call that has been inlined, the assignment has been
 633       --  rewritten as a block, and the constraint check will be applied to the
 634       --  assignment within the block.
 635
 636       elsif Is_Array_Type (T1)
 637         and then
 638           (Nkind (Rhs) /= N_Type_Conversion
 639             or else Is_Constrained (Etype (Rhs)))
 640         and then
 641           (Nkind (Rhs) /= N_Function_Call
 642             or else Nkind (N) /= N_Block_Statement)
 643       then
 644          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 645          --  but of course the indices do not have to match. If the right-hand
 646          --  side is a type conversion to an unconstrained type, a length check
 647          --  is performed on the expression itself during expansion. In rare
 648          --  cases, the redundant length check is computed on an index type
 649          --  with a different representation, triggering incorrect code in
 650          --  the back end.
 651
 652          Apply_Length_Check (Rhs, Etype (Lhs));
 653
 654       else
 655          --  Discriminant checks are applied in the course of expansion
 656
 657          null;
 658       end if;
 659
 660       --  Note: modifications of the Lhs may only be recorded after
 661       --  checks have been applied.
 662
 663       Note_Possible_Modification (Lhs, Sure => True);
 664
 665       --  ??? a real accessibility check is needed when ???
 666
 667       --  Post warning for redundant assignment or variable to itself
 668
 669       if Warn_On_Redundant_Constructs
 670
 671          --  We only warn for source constructs
 672
 673          and then Comes_From_Source (N)
 674
 675          --  Where the object is the same on both sides
 676
 677          and then Same_Object (Lhs, Original_Node (Rhs))
 678
 679          --  But exclude the case where the right side was an operation
 680          --  that got rewritten (e.g. JUNK + K, where K was known to be
 681          --  zero). We don't want to warn in such a case, since it is
 682          --  reasonable to write such expressions especially when K is
 683          --  defined symbolically in some other package.
 684
 685         and then Nkind (Original_Node (Rhs)) not in N_Op
 686       then
 687          if Nkind (Lhs) in N_Has_Entity then
 688             Error_Msg_NE
 689               ("?useless assignment of & to itself!", N, Entity (Lhs));
 690          else
 691             Error_Msg_N
 692               ("?useless assignment of object to itself!", N);
 693          end if;
 694       end if;
 695
 696       --  Check for non-allowed composite assignment
 697
 698       if not Support_Composite_Assign_On_Target
 699         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 700         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 701       then
 702          Error_Msg_CRT ("composite assignment", N);
 703       end if;
 704
 705       --  Check elaboration warning for left side if not in elab code
 706
 707       if not In_Subprogram_Or_Concurrent_Unit then
 708          Check_Elab_Assign (Lhs);
 709       end if;
 710
 711       --  Set Referenced_As_LHS if appropriate. We only set this flag if the
 712       --  assignment is a source assignment in the extended main source unit.
 713       --  We are not interested in any reference information outside this
 714       --  context, or in compiler generated assignment statements.
 715
 716       if Comes_From_Source (N)
 717         and then In_Extended_Main_Source_Unit (Lhs)
 718       then
 719          Set_Referenced_Modified (Lhs, Out_Param => False);
 720       end if;
 721
 722       --  Final step. If left side is an entity, then we may be able to
 723       --  reset the current tracked values to new safe values. We only have
 724       --  something to do if the left side is an entity name, and expansion
 725       --  has not modified the node into something other than an assignment,
 726       --  and of course we only capture values if it is safe to do so.
 727
 728       if Is_Entity_Name (Lhs)
 729         and then Nkind (N) = N_Assignment_Statement
 730       then
 731          declare
 732             Ent : constant Entity_Id := Entity (Lhs);
 733
 734          begin
 735             if Safe_To_Capture_Value (N, Ent) then
 736
 737                --  If simple variable on left side, warn if this assignment
 738                --  blots out another one (rendering it useless) and note
 739                --  location of assignment in case no one references value.
 740                --  We only do this for source assignments, otherwise we can
 741                --  generate bogus warnings when an assignment is rewritten as
 742                --  another assignment, and gets tied up with itself.
 743
 744                --  Note: we don't use Record_Last_Assignment here, because we
 745                --  have lots of other stuff to do under control of this test.
 746
 747                if Warn_On_Modified_Unread
 748                  and then Is_Assignable (Ent)
 749                  and then Comes_From_Source (N)
 750                  and then In_Extended_Main_Source_Unit (Ent)
 751                then
 752                   Warn_On_Useless_Assignment (Ent, N);
 753                   Set_Last_Assignment (Ent, Lhs);
 754                end if;
 755
 756                --  If we are assigning an access type and the left side is an
 757                --  entity, then make sure that the Is_Known_[Non_]Null flags
 758                --  properly reflect the state of the entity after assignment.
 759
 760                if Is_Access_Type (T1) then
 761                   if Known_Non_Null (Rhs) then
 762                      Set_Is_Known_Non_Null (Ent, True);
 763
 764                   elsif Known_Null (Rhs)
 765                     and then not Can_Never_Be_Null (Ent)
 766                   then
 767                      Set_Is_Known_Null (Ent, True);
 768
 769                   else
 770                      Set_Is_Known_Null (Ent, False);
 771
 772                      if not Can_Never_Be_Null (Ent) then
 773                         Set_Is_Known_Non_Null (Ent, False);
 774                      end if;
 775                   end if;
 776
 777                --  For discrete types, we may be able to set the current value
 778                --  if the value is known at compile time.
 779
 780                elsif Is_Discrete_Type (T1)
 781                  and then Compile_Time_Known_Value (Rhs)
 782                then
 783                   Set_Current_Value (Ent, Rhs);
 784                else
 785                   Set_Current_Value (Ent, Empty);
 786                end if;
 787
 788             --  If not safe to capture values, kill them
 789
 790             else
 791                Kill_Lhs;
 792             end if;
 793          end;
 794       end if;
 795    end Analyze_Assignment;
 796
 797    -----------------------------
 798    -- Analyze_Block_Statement --
 799    -----------------------------
 800
 801    procedure Analyze_Block_Statement (N : Node_Id) is
 802       Decls : constant List_Id := Declarations (N);
 803       Id    : constant Node_Id := Identifier (N);
 804       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 805
 806    begin
 807       --  If no handled statement sequence is present, things are really
 808       --  messed up, and we just return immediately (this is a defence
 809       --  against previous errors).
 810
 811       if No (HSS) then
 812          return;
 813       end if;
 814
 815       --  Normal processing with HSS present
 816
 817       declare
 818          EH  : constant List_Id := Exception_Handlers (HSS);
 819          Ent : Entity_Id        := Empty;
 820          S   : Entity_Id;
 821
 822          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 823          --  Recursively save value of this global, will be restored on exit
 824
 825       begin
 826          --  Initialize unblocked exit count for statements of begin block
 827          --  plus one for each exception handler that is present.
 828
 829          Unblocked_Exit_Count := 1;
 830
 831          if Present (EH) then
 832             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 833          end if;
 834
 835          --  If a label is present analyze it and mark it as referenced
 836
 837          if Present (Id) then
 838             Analyze (Id);
 839             Ent := Entity (Id);
 840
 841             --  An error defense. If we have an identifier, but no entity,
 842             --  then something is wrong. If we have previous errors, then
 843             --  just remove the identifier and continue, otherwise raise
 844             --  an exception.
 845
 846             if No (Ent) then
 847                if Total_Errors_Detected /= 0 then
 848                   Set_Identifier (N, Empty);
 849                else
 850                   raise Program_Error;
 851                end if;
 852
 853             else
 854                Set_Ekind (Ent, E_Block);
 855                Generate_Reference (Ent, N, ' ');
 856                Generate_Definition (Ent);
 857
 858                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 859                   Set_Label_Construct (Parent (Ent), N);
 860                end if;
 861             end if;
 862          end if;
 863
 864          --  If no entity set, create a label entity
 865
 866          if No (Ent) then
 867             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 868             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 869             Set_Parent (Ent, N);
 870          end if;
 871
 872          Set_Etype (Ent, Standard_Void_Type);
 873          Set_Block_Node (Ent, Identifier (N));
 874          Push_Scope (Ent);
 875
 876          if Present (Decls) then
 877             Analyze_Declarations (Decls);
 878             Check_Completion;
 879             Inspect_Deferred_Constant_Completion (Decls);
 880          end if;
 881
 882          Analyze (HSS);
 883          Process_End_Label (HSS, 'e', Ent);
 884
 885          --  If exception handlers are present, then we indicate that
 886          --  enclosing scopes contain a block with handlers. We only
 887          --  need to mark non-generic scopes.
 888
 889          if Present (EH) then
 890             S := Scope (Ent);
 891             loop
 892                Set_Has_Nested_Block_With_Handler (S);
 893                exit when Is_Overloadable (S)
 894                  or else Ekind (S) = E_Package
 895                  or else Is_Generic_Unit (S);
 896                S := Scope (S);
 897             end loop;
 898          end if;
 899
 900          Check_References (Ent);
 901          Warn_On_Useless_Assignments (Ent);
 902          End_Scope;
 903
 904          if Unblocked_Exit_Count = 0 then
 905             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 906             Check_Unreachable_Code (N);
 907          else
 908             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 909          end if;
 910       end;
 911    end Analyze_Block_Statement;
 912
 913    ----------------------------
 914    -- Analyze_Case_Statement --
 915    ----------------------------
 916
 917    procedure Analyze_Case_Statement (N : Node_Id) is
 918       Exp            : Node_Id;
 919       Exp_Type       : Entity_Id;
 920       Exp_Btype      : Entity_Id;
 921       Last_Choice    : Nat;
 922       Dont_Care      : Boolean;
 923       Others_Present : Boolean;
 924
 925       pragma Warnings (Off, Last_Choice);
 926       pragma Warnings (Off, Dont_Care);
 927       --  Don't care about assigned values
 928
 929       Statements_Analyzed : Boolean := False;
 930       --  Set True if at least some statement sequences get analyzed.
 931       --  If False on exit, means we had a serious error that prevented
 932       --  full analysis of the case statement, and as a result it is not
 933       --  a good idea to output warning messages about unreachable code.
 934
 935       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 936       --  Recursively save value of this global, will be restored on exit
 937
 938       procedure Non_Static_Choice_Error (Choice : Node_Id);
 939       --  Error routine invoked by the generic instantiation below when
 940       --  the case statement has a non static choice.
 941
 942       procedure Process_Statements (Alternative : Node_Id);
 943       --  Analyzes all the statements associated to a case alternative.
 944       --  Needed by the generic instantiation below.
 945
 946       package Case_Choices_Processing is new
 947         Generic_Choices_Processing
 948           (Get_Alternatives          => Alternatives,
 949            Get_Choices               => Discrete_Choices,
 950            Process_Empty_Choice      => No_OP,
 951            Process_Non_Static_Choice => Non_Static_Choice_Error,
 952            Process_Associated_Node   => Process_Statements);
 953       use Case_Choices_Processing;
 954       --  Instantiation of the generic choice processing package
 955
 956       -----------------------------
 957       -- Non_Static_Choice_Error --
 958       -----------------------------
 959
 960       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 961       begin
 962          Flag_Non_Static_Expr
 963            ("choice given in case statement is not static!", Choice);
 964       end Non_Static_Choice_Error;
 965
 966       ------------------------
 967       -- Process_Statements --
 968       ------------------------
 969
 970       procedure Process_Statements (Alternative : Node_Id) is
 971          Choices : constant List_Id := Discrete_Choices (Alternative);
 972          Ent     : Entity_Id;
 973
 974       begin
 975          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 976          Statements_Analyzed := True;
 977
 978          --  An interesting optimization. If the case statement expression
 979          --  is a simple entity, then we can set the current value within
 980          --  an alternative if the alternative has one possible value.
 981
 982          --    case N is
 983          --      when 1      => alpha
 984          --      when 2 | 3  => beta
 985          --      when others => gamma
 986
 987          --  Here we know that N is initially 1 within alpha, but for beta
 988          --  and gamma, we do not know anything more about the initial value.
 989
 990          if Is_Entity_Name (Exp) then
 991             Ent := Entity (Exp);
 992
 993             if Ekind (Ent) = E_Variable
 994                  or else
 995                Ekind (Ent) = E_In_Out_Parameter
 996                  or else
 997                Ekind (Ent) = E_Out_Parameter
 998             then
 999                if List_Length (Choices) = 1
1000                  and then Nkind (First (Choices)) in N_Subexpr
1001                  and then Compile_Time_Known_Value (First (Choices))
1002                then
1003                   Set_Current_Value (Entity (Exp), First (Choices));
1004                end if;
1005
1006                Analyze_Statements (Statements (Alternative));
1007
1008                --  After analyzing the case, set the current value to empty
1009                --  since we won't know what it is for the next alternative
1010                --  (unless reset by this same circuit), or after the case.
1011
1012                Set_Current_Value (Entity (Exp), Empty);
1013                return;
1014             end if;
1015          end if;
1016
1017          --  Case where expression is not an entity name of a variable
1018
1019          Analyze_Statements (Statements (Alternative));
1020       end Process_Statements;
1021
1022       --  Table to record choices. Put after subprograms since we make
1023       --  a call to Number_Of_Choices to get the right number of entries.
1024
1025       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
1026       pragma Warnings (Off, Case_Table);
1027
1028    --  Start of processing for Analyze_Case_Statement
1029
1030    begin
1031       Unblocked_Exit_Count := 0;
1032       Exp := Expression (N);
1033       Analyze (Exp);
1034
1035       --  The expression must be of any discrete type. In rare cases, the
1036       --  expander constructs a case statement whose expression has a private
1037       --  type whose full view is discrete. This can happen when generating
1038       --  a stream operation for a variant type after the type is frozen,
1039       --  when the partial of view of the type of the discriminant is private.
1040       --  In that case, use the full view to analyze case alternatives.
1041
1042       if not Is_Overloaded (Exp)
1043         and then not Comes_From_Source (N)
1044         and then Is_Private_Type (Etype (Exp))
1045         and then Present (Full_View (Etype (Exp)))
1046         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1047       then
1048          Resolve (Exp, Etype (Exp));
1049          Exp_Type := Full_View (Etype (Exp));
1050
1051       else
1052          Analyze_And_Resolve (Exp, Any_Discrete);
1053          Exp_Type := Etype (Exp);
1054       end if;
1055
1056       Check_Unset_Reference (Exp);
1057       Exp_Btype := Base_Type (Exp_Type);
1058
1059       --  The expression must be of a discrete type which must be determinable
1060       --  independently of the context in which the expression occurs, but
1061       --  using the fact that the expression must be of a discrete type.
1062       --  Moreover, the type this expression must not be a character literal
1063       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1064
1065       --  If error already reported by Resolve, nothing more to do
1066
1067       if Exp_Btype = Any_Discrete
1068         or else Exp_Btype = Any_Type
1069       then
1070          return;
1071
1072       elsif Exp_Btype = Any_Character then
1073          Error_Msg_N
1074            ("character literal as case expression is ambiguous", Exp);
1075          return;
1076
1077       elsif Ada_Version = Ada_83
1078         and then (Is_Generic_Type (Exp_Btype)
1079                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1080       then
1081          Error_Msg_N
1082            ("(Ada 83) case expression cannot be of a generic type", Exp);
1083          return;
1084       end if;
1085
1086       --  If the case expression is a formal object of mode in out, then
1087       --  treat it as having a nonstatic subtype by forcing use of the base
1088       --  type (which has to get passed to Check_Case_Choices below).  Also
1089       --  use base type when the case expression is parenthesized.
1090
1091       if Paren_Count (Exp) > 0
1092         or else (Is_Entity_Name (Exp)
1093                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1094       then
1095          Exp_Type := Exp_Btype;
1096       end if;
1097
1098       --  Call instantiated Analyze_Choices which does the rest of the work
1099
1100       Analyze_Choices
1101         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
1102
1103       if Exp_Type = Universal_Integer and then not Others_Present then
1104          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1105       end if;
1106
1107       --  If all our exits were blocked by unconditional transfers of control,
1108       --  then the entire CASE statement acts as an unconditional transfer of
1109       --  control, so treat it like one, and check unreachable code. Skip this
1110       --  test if we had serious errors preventing any statement analysis.
1111
1112       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1113          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1114          Check_Unreachable_Code (N);
1115       else
1116          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1117       end if;
1118
1119       if not Expander_Active
1120         and then Compile_Time_Known_Value (Expression (N))
1121         and then Serious_Errors_Detected = 0
1122       then
1123          declare
1124             Chosen : constant Node_Id := Find_Static_Alternative (N);
1125             Alt    : Node_Id;
1126
1127          begin
1128             Alt := First (Alternatives (N));
1129             while Present (Alt) loop
1130                if Alt /= Chosen then
1131                   Remove_Warning_Messages (Statements (Alt));
1132                end if;
1133
1134                Next (Alt);
1135             end loop;
1136          end;
1137       end if;
1138    end Analyze_Case_Statement;
1139
1140    ----------------------------
1141    -- Analyze_Exit_Statement --
1142    ----------------------------
1143
1144    --  If the exit includes a name, it must be the name of a currently open
1145    --  loop. Otherwise there must be an innermost open loop on the stack,
1146    --  to which the statement implicitly refers.
1147
1148    procedure Analyze_Exit_Statement (N : Node_Id) is
1149       Target   : constant Node_Id := Name (N);
1150       Cond     : constant Node_Id := Condition (N);
1151       Scope_Id : Entity_Id;
1152       U_Name   : Entity_Id;
1153       Kind     : Entity_Kind;
1154
1155    begin
1156       if No (Cond) then
1157          Check_Unreachable_Code (N);
1158       end if;
1159
1160       if Present (Target) then
1161          Analyze (Target);
1162          U_Name := Entity (Target);
1163
1164          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1165             Error_Msg_N ("invalid loop name in exit statement", N);
1166             return;
1167          else
1168             Set_Has_Exit (U_Name);
1169          end if;
1170
1171       else
1172          U_Name := Empty;
1173       end if;
1174
1175       for J in reverse 0 .. Scope_Stack.Last loop
1176          Scope_Id := Scope_Stack.Table (J).Entity;
1177          Kind := Ekind (Scope_Id);
1178
1179          if Kind = E_Loop
1180            and then (No (Target) or else Scope_Id = U_Name) then
1181             Set_Has_Exit (Scope_Id);
1182             exit;
1183
1184          elsif Kind = E_Block
1185            or else Kind = E_Loop
1186            or else Kind = E_Return_Statement
1187          then
1188             null;
1189
1190          else
1191             Error_Msg_N
1192               ("cannot exit from program unit or accept statement", N);
1193             exit;
1194          end if;
1195       end loop;
1196
1197       --  Verify that if present the condition is a Boolean expression
1198
1199       if Present (Cond) then
1200          Analyze_And_Resolve (Cond, Any_Boolean);
1201          Check_Unset_Reference (Cond);
1202       end if;
1203    end Analyze_Exit_Statement;
1204
1205    ----------------------------
1206    -- Analyze_Goto_Statement --
1207    ----------------------------
1208
1209    procedure Analyze_Goto_Statement (N : Node_Id) is
1210       Label       : constant Node_Id := Name (N);
1211       Scope_Id    : Entity_Id;
1212       Label_Scope : Entity_Id;
1213       Label_Ent   : Entity_Id;
1214
1215    begin
1216       Check_Unreachable_Code (N);
1217       Kill_Current_Values (Last_Assignment_Only => True);
1218
1219       Analyze (Label);
1220       Label_Ent := Entity (Label);
1221
1222       --  Ignore previous error
1223
1224       if Label_Ent = Any_Id then
1225          return;
1226
1227       --  We just have a label as the target of a goto
1228
1229       elsif Ekind (Label_Ent) /= E_Label then
1230          Error_Msg_N ("target of goto statement must be a label", Label);
1231          return;
1232
1233       --  Check that the target of the goto is reachable according to Ada
1234       --  scoping rules. Note: the special gotos we generate for optimizing
1235       --  local handling of exceptions would violate these rules, but we mark
1236       --  such gotos as analyzed when built, so this code is never entered.
1237
1238       elsif not Reachable (Label_Ent) then
1239          Error_Msg_N ("target of goto statement is not reachable", Label);
1240          return;
1241       end if;
1242
1243       --  Here if goto passes initial validity checks
1244
1245       Label_Scope := Enclosing_Scope (Label_Ent);
1246
1247       for J in reverse 0 .. Scope_Stack.Last loop
1248          Scope_Id := Scope_Stack.Table (J).Entity;
1249
1250          if Label_Scope = Scope_Id
1251            or else (Ekind (Scope_Id) /= E_Block
1252                      and then Ekind (Scope_Id) /= E_Loop
1253                      and then Ekind (Scope_Id) /= E_Return_Statement)
1254          then
1255             if Scope_Id /= Label_Scope then
1256                Error_Msg_N
1257                  ("cannot exit from program unit or accept statement", N);
1258             end if;
1259
1260             return;
1261          end if;
1262       end loop;
1263
1264       raise Program_Error;
1265    end Analyze_Goto_Statement;
1266
1267    --------------------------
1268    -- Analyze_If_Statement --
1269    --------------------------
1270
1271    --  A special complication arises in the analysis of if statements
1272
1273    --  The expander has circuitry to completely delete code that it
1274    --  can tell will not be executed (as a result of compile time known
1275    --  conditions). In the analyzer, we ensure that code that will be
1276    --  deleted in this manner is analyzed but not expanded. This is
1277    --  obviously more efficient, but more significantly, difficulties
1278    --  arise if code is expanded and then eliminated (e.g. exception
1279    --  table entries disappear). Similarly, itypes generated in deleted
1280    --  code must be frozen from start, because the nodes on which they
1281    --  depend will not be available at the freeze point.
1282
1283    procedure Analyze_If_Statement (N : Node_Id) is
1284       E : Node_Id;
1285
1286       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1287       --  Recursively save value of this global, will be restored on exit
1288
1289       Save_In_Deleted_Code : Boolean;
1290
1291       Del : Boolean := False;
1292       --  This flag gets set True if a True condition has been found,
1293       --  which means that remaining ELSE/ELSIF parts are deleted.
1294
1295       procedure Analyze_Cond_Then (Cnode : Node_Id);
1296       --  This is applied to either the N_If_Statement node itself or
1297       --  to an N_Elsif_Part node. It deals with analyzing the condition
1298       --  and the THEN statements associated with it.
1299
1300       -----------------------
1301       -- Analyze_Cond_Then --
1302       -----------------------
1303
1304       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1305          Cond : constant Node_Id := Condition (Cnode);
1306          Tstm : constant List_Id := Then_Statements (Cnode);
1307
1308       begin
1309          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1310          Analyze_And_Resolve (Cond, Any_Boolean);
1311          Check_Unset_Reference (Cond);
1312          Set_Current_Value_Condition (Cnode);
1313
1314          --  If already deleting, then just analyze then statements
1315
1316          if Del then
1317             Analyze_Statements (Tstm);
1318
1319          --  Compile time known value, not deleting yet
1320
1321          elsif Compile_Time_Known_Value (Cond) then
1322             Save_In_Deleted_Code := In_Deleted_Code;
1323
1324             --  If condition is True, then analyze the THEN statements
1325             --  and set no expansion for ELSE and ELSIF parts.
1326
1327             if Is_True (Expr_Value (Cond)) then
1328                Analyze_Statements (Tstm);
1329                Del := True;
1330                Expander_Mode_Save_And_Set (False);
1331                In_Deleted_Code := True;
1332
1333             --  If condition is False, analyze THEN with expansion off
1334
1335             else -- Is_False (Expr_Value (Cond))
1336                Expander_Mode_Save_And_Set (False);
1337                In_Deleted_Code := True;
1338                Analyze_Statements (Tstm);
1339                Expander_Mode_Restore;
1340                In_Deleted_Code := Save_In_Deleted_Code;
1341             end if;
1342
1343          --  Not known at compile time, not deleting, normal analysis
1344
1345          else
1346             Analyze_Statements (Tstm);
1347          end if;
1348       end Analyze_Cond_Then;
1349
1350    --  Start of Analyze_If_Statement
1351
1352    begin
1353       --  Initialize exit count for else statements. If there is no else
1354       --  part, this count will stay non-zero reflecting the fact that the
1355       --  uncovered else case is an unblocked exit.
1356
1357       Unblocked_Exit_Count := 1;
1358       Analyze_Cond_Then (N);
1359
1360       --  Now to analyze the elsif parts if any are present
1361
1362       if Present (Elsif_Parts (N)) then
1363          E := First (Elsif_Parts (N));
1364          while Present (E) loop
1365             Analyze_Cond_Then (E);
1366             Next (E);
1367          end loop;
1368       end if;
1369
1370       if Present (Else_Statements (N)) then
1371          Analyze_Statements (Else_Statements (N));
1372       end if;
1373
1374       --  If all our exits were blocked by unconditional transfers of control,
1375       --  then the entire IF statement acts as an unconditional transfer of
1376       --  control, so treat it like one, and check unreachable code.
1377
1378       if Unblocked_Exit_Count = 0 then
1379          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1380          Check_Unreachable_Code (N);
1381       else
1382          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1383       end if;
1384
1385       if Del then
1386          Expander_Mode_Restore;
1387          In_Deleted_Code := Save_In_Deleted_Code;
1388       end if;
1389
1390       if not Expander_Active
1391         and then Compile_Time_Known_Value (Condition (N))
1392         and then Serious_Errors_Detected = 0
1393       then
1394          if Is_True (Expr_Value (Condition (N))) then
1395             Remove_Warning_Messages (Else_Statements (N));
1396
1397             if Present (Elsif_Parts (N)) then
1398                E := First (Elsif_Parts (N));
1399                while Present (E) loop
1400                   Remove_Warning_Messages (Then_Statements (E));
1401                   Next (E);
1402                end loop;
1403             end if;
1404
1405          else
1406             Remove_Warning_Messages (Then_Statements (N));
1407          end if;
1408       end if;
1409    end Analyze_If_Statement;
1410
1411    ----------------------------------------
1412    -- Analyze_Implicit_Label_Declaration --
1413    ----------------------------------------
1414
1415    --  An implicit label declaration is generated in the innermost
1416    --  enclosing declarative part. This is done for labels as well as
1417    --  block and loop names.
1418
1419    --  Note: any changes in this routine may need to be reflected in
1420    --  Analyze_Label_Entity.
1421
1422    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1423       Id : constant Node_Id := Defining_Identifier (N);
1424    begin
1425       Enter_Name          (Id);
1426       Set_Ekind           (Id, E_Label);
1427       Set_Etype           (Id, Standard_Void_Type);
1428       Set_Enclosing_Scope (Id, Current_Scope);
1429    end Analyze_Implicit_Label_Declaration;
1430
1431    ------------------------------
1432    -- Analyze_Iteration_Scheme --
1433    ------------------------------
1434
1435    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1436
1437       procedure Process_Bounds (R : Node_Id);
1438       --  If the iteration is given by a range, create temporaries and
1439       --  assignment statements block to capture the bounds and perform
1440       --  required finalization actions in case a bound includes a function
1441       --  call that uses the temporary stack. We first pre-analyze a copy of
1442       --  the range in order to determine the expected type, and analyze and
1443       --  resolve the original bounds.
1444
1445       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1446       --  If the bounds are given by a 'Range reference on a function call
1447       --  that returns a controlled array, introduce an explicit declaration
1448       --  to capture the bounds, so that the function result can be finalized
1449       --  in timely fashion.
1450
1451       --------------------
1452       -- Process_Bounds --
1453       --------------------
1454
1455       procedure Process_Bounds (R : Node_Id) is
1456          Loc          : constant Source_Ptr := Sloc (N);
1457          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1458          Lo           : constant Node_Id := Low_Bound  (R);
1459          Hi           : constant Node_Id := High_Bound (R);
1460          New_Lo_Bound : Node_Id := Empty;
1461          New_Hi_Bound : Node_Id := Empty;
1462          Typ          : Entity_Id;
1463          Save_Analysis : Boolean;
1464
1465          function One_Bound
1466            (Original_Bound : Node_Id;
1467             Analyzed_Bound : Node_Id) return Node_Id;
1468          --  Create one declaration followed by one assignment statement
1469          --  to capture the value of bound. We create a separate assignment
1470          --  in order to force the creation of a block in case the bound
1471          --  contains a call that uses the secondary stack.
1472
1473          ---------------
1474          -- One_Bound --
1475          ---------------
1476
1477          function One_Bound
1478            (Original_Bound : Node_Id;
1479             Analyzed_Bound : Node_Id) return Node_Id
1480          is
1481             Assign : Node_Id;
1482             Id     : Entity_Id;
1483             Decl   : Node_Id;
1484
1485          begin
1486             --  If the bound is a constant or an object, no need for a separate
1487             --  declaration. If the bound is the result of previous expansion
1488             --  it is already analyzed and should not be modified. Note that
1489             --  the Bound will be resolved later, if needed, as part of the
1490             --  call to Make_Index (literal bounds may need to be resolved to
1491             --  type Integer).
1492
1493             if Analyzed (Original_Bound) then
1494                return Original_Bound;
1495
1496             elsif Nkind_In (Analyzed_Bound, N_Integer_Literal,
1497                                             N_Character_Literal)
1498               or else Is_Entity_Name (Analyzed_Bound)
1499             then
1500                Analyze_And_Resolve (Original_Bound, Typ);
1501                return Original_Bound;
1502
1503             else
1504                Analyze_And_Resolve (Original_Bound, Typ);
1505             end if;
1506
1507             Id :=
1508               Make_Defining_Identifier (Loc,
1509                 Chars => New_Internal_Name ('S'));
1510
1511             Decl :=
1512               Make_Object_Declaration (Loc,
1513                 Defining_Identifier => Id,
1514                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1515
1516             Insert_Before (Parent (N), Decl);
1517             Analyze (Decl);
1518
1519             Assign :=
1520               Make_Assignment_Statement (Loc,
1521                 Name        => New_Occurrence_Of (Id, Loc),
1522                 Expression  => Relocate_Node (Original_Bound));
1523
1524             Insert_Before (Parent (N), Assign);
1525             Analyze (Assign);
1526
1527             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1528
1529             if Nkind (Assign) = N_Assignment_Statement then
1530                return Expression (Assign);
1531             else
1532                return Original_Bound;
1533             end if;
1534          end One_Bound;
1535
1536       --  Start of processing for Process_Bounds
1537
1538       begin
1539          --  Determine expected type of range by analyzing separate copy
1540          --  Do the analysis and resolution of the copy of the bounds with
1541          --  expansion disabled, to prevent the generation of finalization
1542          --  actions on each bound. This prevents memory leaks when the
1543          --  bounds contain calls to functions returning controlled arrays.
1544
1545          Set_Parent (R_Copy, Parent (R));
1546          Save_Analysis := Full_Analysis;
1547          Full_Analysis := False;
1548          Expander_Mode_Save_And_Set (False);
1549
1550          Analyze (R_Copy);
1551
1552          if Is_Overloaded (R_Copy) then
1553
1554             --  Apply preference rules for range of predefined integer types,
1555             --  or diagnose true ambiguity.
1556
1557             declare
1558                I     : Interp_Index;
1559                It    : Interp;
1560                Found : Entity_Id := Empty;
1561
1562             begin
1563                Get_First_Interp (R_Copy, I, It);
1564                while Present (It.Typ) loop
1565                   if Is_Discrete_Type (It.Typ) then
1566                      if No (Found) then
1567                         Found := It.Typ;
1568                      else
1569                         if Scope (Found) = Standard_Standard then
1570                            null;
1571
1572                         elsif Scope (It.Typ) = Standard_Standard then
1573                            Found := It.Typ;
1574
1575                         else
1576                            --  Both of them are user-defined
1577
1578                            Error_Msg_N
1579                              ("ambiguous bounds in range of iteration",
1580                                R_Copy);
1581                            Error_Msg_N ("\possible interpretations:", R_Copy);
1582                            Error_Msg_NE ("\\} ", R_Copy, Found);
1583                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1584                            exit;
1585                         end if;
1586                      end if;
1587                   end if;
1588
1589                   Get_Next_Interp (I, It);
1590                end loop;
1591             end;
1592          end if;
1593
1594          Resolve (R_Copy);
1595          Expander_Mode_Restore;
1596          Full_Analysis := Save_Analysis;
1597
1598          Typ := Etype (R_Copy);
1599
1600          --  If the type of the discrete range is Universal_Integer, then
1601          --  the bound's type must be resolved to Integer, and any object
1602          --  used to hold the bound must also have type Integer, unless the
1603          --  literal bounds are constant-folded expressions that carry a user-
1604          --  defined type.
1605
1606          if Typ = Universal_Integer then
1607             if Nkind (Lo) = N_Integer_Literal
1608               and then Present (Etype (Lo))
1609               and then Scope (Etype (Lo)) /= Standard_Standard
1610             then
1611                Typ := Etype (Lo);
1612
1613             elsif Nkind (Hi) = N_Integer_Literal
1614               and then Present (Etype (Hi))
1615               and then Scope (Etype (Hi)) /= Standard_Standard
1616             then
1617                Typ := Etype (Hi);
1618
1619             else
1620                Typ := Standard_Integer;
1621             end if;
1622          end if;
1623
1624          Set_Etype (R, Typ);
1625
1626          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1627          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1628
1629          --  Propagate staticness to loop range itself, in case the
1630          --  corresponding subtype is static.
1631
1632          if New_Lo_Bound /= Lo
1633            and then Is_Static_Expression (New_Lo_Bound)
1634          then
1635             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1636          end if;
1637
1638          if New_Hi_Bound /= Hi
1639            and then Is_Static_Expression (New_Hi_Bound)
1640          then
1641             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1642          end if;
1643       end Process_Bounds;
1644
1645       --------------------------------------
1646       -- Check_Controlled_Array_Attribute --
1647       --------------------------------------
1648
1649       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1650       begin
1651          if Nkind (DS) = N_Attribute_Reference
1652             and then Is_Entity_Name (Prefix (DS))
1653             and then Ekind (Entity (Prefix (DS))) = E_Function
1654             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1655             and then
1656               Is_Controlled (
1657                 Component_Type (Etype (Entity (Prefix (DS)))))
1658             and then Expander_Active
1659          then
1660             declare
1661                Loc  : constant Source_Ptr := Sloc (N);
1662                Arr  : constant Entity_Id :=
1663                         Etype (Entity (Prefix (DS)));
1664                Indx : constant Entity_Id :=
1665                         Base_Type (Etype (First_Index (Arr)));
1666                Subt : constant Entity_Id :=
1667                         Make_Defining_Identifier
1668                           (Loc, New_Internal_Name ('S'));
1669                Decl : Node_Id;
1670
1671             begin
1672                Decl :=
1673                  Make_Subtype_Declaration (Loc,
1674                    Defining_Identifier => Subt,
1675                    Subtype_Indication  =>
1676                       Make_Subtype_Indication (Loc,
1677                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1678                         Constraint =>
1679                           Make_Range_Constraint (Loc,
1680                             Relocate_Node (DS))));
1681                Insert_Before (Parent (N), Decl);
1682                Analyze (Decl);
1683
1684                Rewrite (DS,
1685                   Make_Attribute_Reference (Loc,
1686                     Prefix => New_Reference_To (Subt, Loc),
1687                     Attribute_Name => Attribute_Name (DS)));
1688                Analyze (DS);
1689             end;
1690          end if;
1691       end Check_Controlled_Array_Attribute;
1692
1693    --  Start of processing for Analyze_Iteration_Scheme
1694
1695    begin
1696       --  For an infinite loop, there is no iteration scheme
1697
1698       if No (N) then
1699          return;
1700
1701       else
1702          declare
1703             Cond : constant Node_Id := Condition (N);
1704
1705          begin
1706             --  For WHILE loop, verify that the condition is a Boolean
1707             --  expression and resolve and check it.
1708
1709             if Present (Cond) then
1710                Analyze_And_Resolve (Cond, Any_Boolean);
1711                Check_Unset_Reference (Cond);
1712                Set_Current_Value_Condition (N);
1713                return;
1714
1715             --  Else we have a FOR loop
1716
1717             else
1718                declare
1719                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1720                   Id : constant Entity_Id := Defining_Identifier (LP);
1721                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1722
1723                begin
1724                   Enter_Name (Id);
1725
1726                   --  We always consider the loop variable to be referenced,
1727                   --  since the loop may be used just for counting purposes.
1728
1729                   Generate_Reference (Id, N, ' ');
1730
1731                   --  Check for case of loop variable hiding a local
1732                   --  variable (used later on to give a nice warning
1733                   --  if the hidden variable is never assigned).
1734
1735                   declare
1736                      H : constant Entity_Id := Homonym (Id);
1737                   begin
1738                      if Present (H)
1739                        and then Enclosing_Dynamic_Scope (H) =
1740                                 Enclosing_Dynamic_Scope (Id)
1741                        and then Ekind (H) = E_Variable
1742                        and then Is_Discrete_Type (Etype (H))
1743                      then
1744                         Set_Hiding_Loop_Variable (H, Id);
1745                      end if;
1746                   end;
1747
1748                   --  Now analyze the subtype definition. If it is
1749                   --  a range, create temporaries for bounds.
1750
1751                   if Nkind (DS) = N_Range
1752                     and then Expander_Active
1753                   then
1754                      Process_Bounds (DS);
1755                   else
1756                      Analyze (DS);
1757                   end if;
1758
1759                   if DS = Error then
1760                      return;
1761                   end if;
1762
1763                   --  The subtype indication may denote the completion
1764                   --  of an incomplete type declaration.
1765
1766                   if Is_Entity_Name (DS)
1767                     and then Present (Entity (DS))
1768                     and then Is_Type (Entity (DS))
1769                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1770                   then
1771                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1772                      Set_Etype  (DS, Entity (DS));
1773                   end if;
1774
1775                   if not Is_Discrete_Type (Etype (DS)) then
1776                      Wrong_Type (DS, Any_Discrete);
1777                      Set_Etype (DS, Any_Type);
1778                   end if;
1779
1780                   Check_Controlled_Array_Attribute (DS);
1781
1782                   Make_Index (DS, LP);
1783
1784                   Set_Ekind          (Id, E_Loop_Parameter);
1785                   Set_Etype          (Id, Etype (DS));
1786                   Set_Is_Known_Valid (Id, True);
1787
1788                   --  The loop is not a declarative part, so the only entity
1789                   --  declared "within" must be frozen explicitly.
1790
1791                   declare
1792                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1793                   begin
1794                      if Is_Non_Empty_List (Flist) then
1795                         Insert_Actions (N, Flist);
1796                      end if;
1797                   end;
1798
1799                   --  Check for null or possibly null range and issue warning.
1800                   --  We suppress such messages in generic templates and
1801                   --  instances, because in practice they tend to be dubious
1802                   --  in these cases.
1803
1804                   if Nkind (DS) = N_Range
1805                     and then Comes_From_Source (N)
1806                   then
1807                      declare
1808                         L : constant Node_Id := Low_Bound  (DS);
1809                         H : constant Node_Id := High_Bound (DS);
1810
1811                         Llo : Uint;
1812                         Lhi : Uint;
1813                         LOK : Boolean;
1814                         Hlo : Uint;
1815                         Hhi : Uint;
1816                         HOK : Boolean;
1817
1818                         pragma Warnings (Off, Hlo);
1819
1820                      begin
1821                         Determine_Range (L, LOK, Llo, Lhi);
1822                         Determine_Range (H, HOK, Hlo, Hhi);
1823
1824                         --  If range of loop is null, issue warning
1825
1826                         if (LOK and HOK) and then Llo > Hhi then
1827
1828                            --  Suppress the warning if inside a generic
1829                            --  template or instance, since in practice
1830                            --  they tend to be dubious in these cases since
1831                            --  they can result from intended parametrization.
1832
1833                            if not Inside_A_Generic
1834                               and then not In_Instance
1835                            then
1836                               Error_Msg_N
1837                                 ("?loop range is null, loop will not execute",
1838                                  DS);
1839                            end if;
1840
1841                            --  Since we know the range of the loop is null,
1842                            --  set the appropriate flag to suppress any
1843                            --  warnings that would otherwise be issued in
1844                            --  the body of the loop that will not execute.
1845                            --  We do this even in the generic case, since
1846                            --  if it is dubious to warn on the null loop
1847                            --  itself, it is certainly dubious to warn for
1848                            --  conditions that occur inside it!
1849
1850                            Set_Is_Null_Loop (Parent (N));
1851
1852                         --  The other case for a warning is a reverse loop
1853                         --  where the upper bound is the integer literal
1854                         --  zero or one, and the lower bound can be positive.
1855
1856                         --  For example, we have
1857
1858                         --     for J in reverse N .. 1 loop
1859
1860                         --  In practice, this is very likely to be a case
1861                         --  of reversing the bounds incorrectly in the range.
1862
1863                         elsif Reverse_Present (LP)
1864                           and then Nkind (Original_Node (H)) =
1865                                                           N_Integer_Literal
1866                           and then (Intval (H) = Uint_0
1867                                       or else
1868                                     Intval (H) = Uint_1)
1869                           and then Lhi > Hhi
1870                         then
1871                            Error_Msg_N ("?loop range may be null", DS);
1872                            Error_Msg_N ("\?bounds may be wrong way round", DS);
1873                         end if;
1874                      end;
1875                   end if;
1876                end;
1877             end if;
1878          end;
1879       end if;
1880    end Analyze_Iteration_Scheme;
1881
1882    -------------------
1883    -- Analyze_Label --
1884    -------------------
1885
1886    --  Note: the semantic work required for analyzing labels (setting them as
1887    --  reachable) was done in a prepass through the statements in the block,
1888    --  so that forward gotos would be properly handled. See Analyze_Statements
1889    --  for further details. The only processing required here is to deal with
1890    --  optimizations that depend on an assumption of sequential control flow,
1891    --  since of course the occurrence of a label breaks this assumption.
1892
1893    procedure Analyze_Label (N : Node_Id) is
1894       pragma Warnings (Off, N);
1895    begin
1896       Kill_Current_Values;
1897    end Analyze_Label;
1898
1899    --------------------------
1900    -- Analyze_Label_Entity --
1901    --------------------------
1902
1903    procedure Analyze_Label_Entity (E : Entity_Id) is
1904    begin
1905       Set_Ekind           (E, E_Label);
1906       Set_Etype           (E, Standard_Void_Type);
1907       Set_Enclosing_Scope (E, Current_Scope);
1908       Set_Reachable       (E, True);
1909    end Analyze_Label_Entity;
1910
1911    ----------------------------
1912    -- Analyze_Loop_Statement --
1913    ----------------------------
1914
1915    procedure Analyze_Loop_Statement (N : Node_Id) is
1916       Loop_Statement : constant Node_Id := N;
1917
1918       Id   : constant Node_Id := Identifier (Loop_Statement);
1919       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
1920       Ent  : Entity_Id;
1921
1922    begin
1923       if Present (Id) then
1924
1925          --  Make name visible, e.g. for use in exit statements. Loop
1926          --  labels are always considered to be referenced.
1927
1928          Analyze (Id);
1929          Ent := Entity (Id);
1930
1931          --  Guard against serious error (typically, a scope mismatch when
1932          --  semantic analysis is requested) by creating loop entity to
1933          --  continue analysis.
1934
1935          if No (Ent) then
1936             if Total_Errors_Detected /= 0 then
1937                Ent :=
1938                  New_Internal_Entity
1939                    (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
1940             else
1941                raise Program_Error;
1942             end if;
1943
1944          else
1945             Generate_Reference  (Ent, Loop_Statement, ' ');
1946             Generate_Definition (Ent);
1947
1948             --  If we found a label, mark its type. If not, ignore it, since it
1949             --  means we have a conflicting declaration, which would already
1950             --  have been diagnosed at declaration time. Set Label_Construct
1951             --  of the implicit label declaration, which is not created by the
1952             --  parser for generic units.
1953
1954             if Ekind (Ent) = E_Label then
1955                Set_Ekind (Ent, E_Loop);
1956
1957                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
1958                   Set_Label_Construct (Parent (Ent), Loop_Statement);
1959                end if;
1960             end if;
1961          end if;
1962
1963       --  Case of no identifier present
1964
1965       else
1966          Ent :=
1967            New_Internal_Entity
1968              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
1969          Set_Etype (Ent,  Standard_Void_Type);
1970          Set_Parent (Ent, Loop_Statement);
1971       end if;
1972
1973       --  Kill current values on entry to loop, since statements in body of
1974       --  loop may have been executed before the loop is entered. Similarly we
1975       --  kill values after the loop, since we do not know that the body of the
1976       --  loop was executed.
1977
1978       Kill_Current_Values;
1979       Push_Scope (Ent);
1980       Analyze_Iteration_Scheme (Iter);
1981       Analyze_Statements (Statements (Loop_Statement));
1982       Process_End_Label (Loop_Statement, 'e', Ent);
1983       End_Scope;
1984       Kill_Current_Values;
1985       Check_Infinite_Loop_Warning (N);
1986
1987       --  Code after loop is unreachable if the loop has no WHILE or FOR
1988       --  and contains no EXIT statements within the body of the loop.
1989
1990       if No (Iter) and then not Has_Exit (Ent) then
1991          Check_Unreachable_Code (N);
1992       end if;
1993    end Analyze_Loop_Statement;
1994
1995    ----------------------------
1996    -- Analyze_Null_Statement --
1997    ----------------------------
1998
1999    --  Note: the semantics of the null statement is implemented by a single
2000    --  null statement, too bad everything isn't as simple as this!
2001
2002    procedure Analyze_Null_Statement (N : Node_Id) is
2003       pragma Warnings (Off, N);
2004    begin
2005       null;
2006    end Analyze_Null_Statement;
2007
2008    ------------------------
2009    -- Analyze_Statements --
2010    ------------------------
2011
2012    procedure Analyze_Statements (L : List_Id) is
2013       S   : Node_Id;
2014       Lab : Entity_Id;
2015
2016    begin
2017       --  The labels declared in the statement list are reachable from
2018       --  statements in the list. We do this as a prepass so that any
2019       --  goto statement will be properly flagged if its target is not
2020       --  reachable. This is not required, but is nice behavior!
2021
2022       S := First (L);
2023       while Present (S) loop
2024          if Nkind (S) = N_Label then
2025             Analyze (Identifier (S));
2026             Lab := Entity (Identifier (S));
2027
2028             --  If we found a label mark it as reachable
2029
2030             if Ekind (Lab) = E_Label then
2031                Generate_Definition (Lab);
2032                Set_Reachable (Lab);
2033
2034                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
2035                   Set_Label_Construct (Parent (Lab), S);
2036                end if;
2037
2038             --  If we failed to find a label, it means the implicit declaration
2039             --  of the label was hidden.  A for-loop parameter can do this to
2040             --  a label with the same name inside the loop, since the implicit
2041             --  label declaration is in the innermost enclosing body or block
2042             --  statement.
2043
2044             else
2045                Error_Msg_Sloc := Sloc (Lab);
2046                Error_Msg_N
2047                  ("implicit label declaration for & is hidden#",
2048                   Identifier (S));
2049             end if;
2050          end if;
2051
2052          Next (S);
2053       end loop;
2054
2055       --  Perform semantic analysis on all statements
2056
2057       Conditional_Statements_Begin;
2058
2059       S := First (L);
2060       while Present (S) loop
2061          Analyze (S);
2062          Next (S);
2063       end loop;
2064
2065       Conditional_Statements_End;
2066
2067       --  Make labels unreachable. Visibility is not sufficient, because
2068       --  labels in one if-branch for example are not reachable from the
2069       --  other branch, even though their declarations are in the enclosing
2070       --  declarative part.
2071
2072       S := First (L);
2073       while Present (S) loop
2074          if Nkind (S) = N_Label then
2075             Set_Reachable (Entity (Identifier (S)), False);
2076          end if;
2077
2078          Next (S);
2079       end loop;
2080    end Analyze_Statements;
2081
2082    ----------------------------
2083    -- Check_Unreachable_Code --
2084    ----------------------------
2085
2086    procedure Check_Unreachable_Code (N : Node_Id) is
2087       Error_Loc : Source_Ptr;
2088       P         : Node_Id;
2089
2090    begin
2091       if Is_List_Member (N)
2092         and then Comes_From_Source (N)
2093       then
2094          declare
2095             Nxt : Node_Id;
2096
2097          begin
2098             Nxt := Original_Node (Next (N));
2099
2100             --  If a label follows us, then we never have dead code, since
2101             --  someone could branch to the label, so we just ignore it.
2102
2103             if Nkind (Nxt) = N_Label then
2104                return;
2105
2106             --  Otherwise see if we have a real statement following us
2107
2108             elsif Present (Nxt)
2109               and then Comes_From_Source (Nxt)
2110               and then Is_Statement (Nxt)
2111             then
2112                --  Special very annoying exception. If we have a return that
2113                --  follows a raise, then we allow it without a warning, since
2114                --  the Ada RM annoyingly requires a useless return here!
2115
2116                if Nkind (Original_Node (N)) /= N_Raise_Statement
2117                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2118                then
2119                   --  The rather strange shenanigans with the warning message
2120                   --  here reflects the fact that Kill_Dead_Code is very good
2121                   --  at removing warnings in deleted code, and this is one
2122                   --  warning we would prefer NOT to have removed.
2123
2124                   Error_Loc := Sloc (Nxt);
2125
2126                   --  If we have unreachable code, analyze and remove the
2127                   --  unreachable code, since it is useless and we don't
2128                   --  want to generate junk warnings.
2129
2130                   --  We skip this step if we are not in code generation mode.
2131                   --  This is the one case where we remove dead code in the
2132                   --  semantics as opposed to the expander, and we do not want
2133                   --  to remove code if we are not in code generation mode,
2134                   --  since this messes up the ASIS trees.
2135
2136                   --  Note that one might react by moving the whole circuit to
2137                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2138
2139                   if Operating_Mode = Generate_Code then
2140                      loop
2141                         Nxt := Next (N);
2142
2143                         --  Quit deleting when we have nothing more to delete
2144                         --  or if we hit a label (since someone could transfer
2145                         --  control to a label, so we should not delete it).
2146
2147                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2148
2149                         --  Statement/declaration is to be deleted
2150
2151                         Analyze (Nxt);
2152                         Remove (Nxt);
2153                         Kill_Dead_Code (Nxt);
2154                      end loop;
2155                   end if;
2156
2157                   --  Now issue the warning
2158
2159                   Error_Msg ("?unreachable code!", Error_Loc);
2160                end if;
2161
2162             --  If the unconditional transfer of control instruction is
2163             --  the last statement of a sequence, then see if our parent
2164             --  is one of the constructs for which we count unblocked exits,
2165             --  and if so, adjust the count.
2166
2167             else
2168                P := Parent (N);
2169
2170                --  Statements in THEN part or ELSE part of IF statement
2171
2172                if Nkind (P) = N_If_Statement then
2173                   null;
2174
2175                --  Statements in ELSIF part of an IF statement
2176
2177                elsif Nkind (P) = N_Elsif_Part then
2178                   P := Parent (P);
2179                   pragma Assert (Nkind (P) = N_If_Statement);
2180
2181                --  Statements in CASE statement alternative
2182
2183                elsif Nkind (P) = N_Case_Statement_Alternative then
2184                   P := Parent (P);
2185                   pragma Assert (Nkind (P) = N_Case_Statement);
2186
2187                --  Statements in body of block
2188
2189                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2190                  and then Nkind (Parent (P)) = N_Block_Statement
2191                then
2192                   null;
2193
2194                --  Statements in exception handler in a block
2195
2196                elsif Nkind (P) = N_Exception_Handler
2197                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2198                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2199                then
2200                   null;
2201
2202                --  None of these cases, so return
2203
2204                else
2205                   return;
2206                end if;
2207
2208                --  This was one of the cases we are looking for (i.e. the
2209                --  parent construct was IF, CASE or block) so decrement count.
2210
2211                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2212             end if;
2213          end;
2214       end if;
2215    end Check_Unreachable_Code;
2216
2217 end Sem_Ch5;