gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Aux;  use Sem_Aux;
  42 with Sem_Case; use Sem_Case;
  43 with Sem_Ch3;  use Sem_Ch3;
  44 with Sem_Ch8;  use Sem_Ch8;
  45 with Sem_Disp; use Sem_Disp;
  46 with Sem_Elab; use Sem_Elab;
  47 with Sem_Eval; use Sem_Eval;
  48 with Sem_Res;  use Sem_Res;
  49 with Sem_Type; use Sem_Type;
  50 with Sem_Util; use Sem_Util;
  51 with Sem_Warn; use Sem_Warn;
  52 with Snames;   use Snames;
  53 with Stand;    use Stand;
  54 with Sinfo;    use Sinfo;
  55 with Targparm; use Targparm;
  56 with Tbuild;   use Tbuild;
  57 with Uintp;    use Uintp;
  58
  59 package body Sem_Ch5 is
  60
  61    Unblocked_Exit_Count : Nat := 0;
  62    --  This variable is used when processing if statements, case statements,
  63    --  and block statements. It counts the number of exit points that are not
  64    --  blocked by unconditional transfer instructions: for IF and CASE, these
  65    --  are the branches of the conditional; for a block, they are the statement
  66    --  sequence of the block, and the statement sequences of any exception
  67    --  handlers that are part of the block. When processing is complete, if
  68    --  this count is zero, it means that control cannot fall through the IF,
  69    --  CASE or block statement. This is used for the generation of warning
  70    --  messages. This variable is recursively saved on entry to processing the
  71    --  construct, and restored on exit.
  72
  73    ------------------------
  74    -- Analyze_Assignment --
  75    ------------------------
  76
  77    procedure Analyze_Assignment (N : Node_Id) is
  78       Lhs  : constant Node_Id := Name (N);
  79       Rhs  : constant Node_Id := Expression (N);
  80       T1   : Entity_Id;
  81       T2   : Entity_Id;
  82       Decl : Node_Id;
  83
  84       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  85       --  N is the node for the left hand side of an assignment, and it is not
  86       --  a variable. This routine issues an appropriate diagnostic.
  87
  88       procedure Kill_Lhs;
  89       --  This is called to kill current value settings of a simple variable
  90       --  on the left hand side. We call it if we find any error in analyzing
  91       --  the assignment, and at the end of processing before setting any new
  92       --  current values in place.
  93
  94       procedure Set_Assignment_Type
  95         (Opnd      : Node_Id;
  96          Opnd_Type : in out Entity_Id);
  97       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
  98       --  is the nominal subtype. This procedure is used to deal with cases
  99       --  where the nominal subtype must be replaced by the actual subtype.
 100
 101       -------------------------------
 102       -- Diagnose_Non_Variable_Lhs --
 103       -------------------------------
 104
 105       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 106       begin
 107          --  Not worth posting another error if left hand side already
 108          --  flagged as being illegal in some respect.
 109
 110          if Error_Posted (N) then
 111             return;
 112
 113          --  Some special bad cases of entity names
 114
 115          elsif Is_Entity_Name (N) then
 116             declare
 117                Ent : constant Entity_Id := Entity (N);
 118
 119             begin
 120                if Ekind (Ent) = E_In_Parameter then
 121                   Error_Msg_N
 122                     ("assignment to IN mode parameter not allowed", N);
 123
 124                --  Renamings of protected private components are turned into
 125                --  constants when compiling a protected function. In the case
 126                --  of single protected types, the private component appears
 127                --  directly.
 128
 129                elsif (Is_Prival (Ent)
 130                         and then
 131                           (Ekind (Current_Scope) = E_Function
 132                              or else Ekind (Enclosing_Dynamic_Scope (
 133                                        Current_Scope)) = E_Function))
 134                    or else
 135                      (Ekind (Ent) = E_Component
 136                         and then Is_Protected_Type (Scope (Ent)))
 137                then
 138                   Error_Msg_N
 139                     ("protected function cannot modify protected object", N);
 140
 141                elsif Ekind (Ent) = E_Loop_Parameter then
 142                   Error_Msg_N
 143                     ("assignment to loop parameter not allowed", N);
 144
 145                else
 146                   Error_Msg_N
 147                     ("left hand side of assignment must be a variable", N);
 148                end if;
 149             end;
 150
 151          --  For indexed components or selected components, test prefix
 152
 153          elsif Nkind (N) = N_Indexed_Component then
 154             Diagnose_Non_Variable_Lhs (Prefix (N));
 155
 156          --  Another special case for assignment to discriminant
 157
 158          elsif Nkind (N) = N_Selected_Component then
 159             if Present (Entity (Selector_Name (N)))
 160               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 161             then
 162                Error_Msg_N
 163                  ("assignment to discriminant not allowed", N);
 164             else
 165                Diagnose_Non_Variable_Lhs (Prefix (N));
 166             end if;
 167
 168          else
 169             --  If we fall through, we have no special message to issue!
 170
 171             Error_Msg_N ("left hand side of assignment must be a variable", N);
 172          end if;
 173       end Diagnose_Non_Variable_Lhs;
 174
 175       --------------
 176       -- Kill_LHS --
 177       --------------
 178
 179       procedure Kill_Lhs is
 180       begin
 181          if Is_Entity_Name (Lhs) then
 182             declare
 183                Ent : constant Entity_Id := Entity (Lhs);
 184             begin
 185                if Present (Ent) then
 186                   Kill_Current_Values (Ent);
 187                end if;
 188             end;
 189          end if;
 190       end Kill_Lhs;
 191
 192       -------------------------
 193       -- Set_Assignment_Type --
 194       -------------------------
 195
 196       procedure Set_Assignment_Type
 197         (Opnd      : Node_Id;
 198          Opnd_Type : in out Entity_Id)
 199       is
 200       begin
 201          Require_Entity (Opnd);
 202
 203          --  If the assignment operand is an in-out or out parameter, then we
 204          --  get the actual subtype (needed for the unconstrained case).
 205          --  If the operand is the actual in an entry declaration, then within
 206          --  the accept statement it is replaced with a local renaming, which
 207          --  may also have an actual subtype.
 208
 209          if Is_Entity_Name (Opnd)
 210            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 211                       or else Ekind (Entity (Opnd)) =
 212                            E_In_Out_Parameter
 213                       or else Ekind (Entity (Opnd)) =
 214                            E_Generic_In_Out_Parameter
 215                       or else
 216                         (Ekind (Entity (Opnd)) = E_Variable
 217                           and then Nkind (Parent (Entity (Opnd))) =
 218                              N_Object_Renaming_Declaration
 219                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 220                              N_Accept_Statement))
 221          then
 222             Opnd_Type := Get_Actual_Subtype (Opnd);
 223
 224          --  If assignment operand is a component reference, then we get the
 225          --  actual subtype of the component for the unconstrained case.
 226
 227          elsif Nkind_In (Opnd, N_Selected_Component, N_Explicit_Dereference)
 228            and then not Is_Unchecked_Union (Opnd_Type)
 229          then
 230             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 231
 232             if Present (Decl) then
 233                Insert_Action (N, Decl);
 234                Mark_Rewrite_Insertion (Decl);
 235                Analyze (Decl);
 236                Opnd_Type := Defining_Identifier (Decl);
 237                Set_Etype (Opnd, Opnd_Type);
 238                Freeze_Itype (Opnd_Type, N);
 239
 240             elsif Is_Constrained (Etype (Opnd)) then
 241                Opnd_Type := Etype (Opnd);
 242             end if;
 243
 244          --  For slice, use the constrained subtype created for the slice
 245
 246          elsif Nkind (Opnd) = N_Slice then
 247             Opnd_Type := Etype (Opnd);
 248          end if;
 249       end Set_Assignment_Type;
 250
 251    --  Start of processing for Analyze_Assignment
 252
 253    begin
 254       Mark_Coextensions (N, Rhs);
 255
 256       Analyze (Rhs);
 257       Analyze (Lhs);
 258
 259       --  Start type analysis for assignment
 260
 261       T1 := Etype (Lhs);
 262
 263       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 264       --  must compute the intersection of the possible types on each side.
 265
 266       if Is_Overloaded (Lhs) then
 267          declare
 268             I  : Interp_Index;
 269             It : Interp;
 270
 271          begin
 272             T1 := Any_Type;
 273             Get_First_Interp (Lhs, I, It);
 274
 275             while Present (It.Typ) loop
 276                if Has_Compatible_Type (Rhs, It.Typ) then
 277                   if T1 /= Any_Type then
 278
 279                      --  An explicit dereference is overloaded if the prefix
 280                      --  is. Try to remove the ambiguity on the prefix, the
 281                      --  error will be posted there if the ambiguity is real.
 282
 283                      if Nkind (Lhs) = N_Explicit_Dereference then
 284                         declare
 285                            PI    : Interp_Index;
 286                            PI1   : Interp_Index := 0;
 287                            PIt   : Interp;
 288                            Found : Boolean;
 289
 290                         begin
 291                            Found := False;
 292                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 293
 294                            while Present (PIt.Typ) loop
 295                               if Is_Access_Type (PIt.Typ)
 296                                 and then Has_Compatible_Type
 297                                            (Rhs, Designated_Type (PIt.Typ))
 298                               then
 299                                  if Found then
 300                                     PIt :=
 301                                       Disambiguate (Prefix (Lhs),
 302                                         PI1, PI, Any_Type);
 303
 304                                     if PIt = No_Interp then
 305                                        Error_Msg_N
 306                                          ("ambiguous left-hand side"
 307                                             & " in assignment", Lhs);
 308                                        exit;
 309                                     else
 310                                        Resolve (Prefix (Lhs), PIt.Typ);
 311                                     end if;
 312
 313                                     exit;
 314                                  else
 315                                     Found := True;
 316                                     PI1 := PI;
 317                                  end if;
 318                               end if;
 319
 320                               Get_Next_Interp (PI, PIt);
 321                            end loop;
 322                         end;
 323
 324                      else
 325                         Error_Msg_N
 326                           ("ambiguous left-hand side in assignment", Lhs);
 327                         exit;
 328                      end if;
 329                   else
 330                      T1 := It.Typ;
 331                   end if;
 332                end if;
 333
 334                Get_Next_Interp (I, It);
 335             end loop;
 336          end;
 337
 338          if T1 = Any_Type then
 339             Error_Msg_N
 340               ("no valid types for left-hand side for assignment", Lhs);
 341             Kill_Lhs;
 342             return;
 343          end if;
 344       end if;
 345
 346       --  The resulting assignment type is T1, so now we will resolve the
 347       --  left hand side of the assignment using this determined type.
 348
 349       Resolve (Lhs, T1);
 350
 351       --  Cases where Lhs is not a variable
 352
 353       if not Is_Variable (Lhs) then
 354
 355          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 356          --  a protected object.
 357
 358          declare
 359             Ent : Entity_Id;
 360             S   : Entity_Id;
 361
 362          begin
 363             if Ada_Version >= Ada_2005 then
 364
 365                --  Handle chains of renamings
 366
 367                Ent := Lhs;
 368                while Nkind (Ent) in N_Has_Entity
 369                  and then Present (Entity (Ent))
 370                  and then Present (Renamed_Object (Entity (Ent)))
 371                loop
 372                   Ent := Renamed_Object (Entity (Ent));
 373                end loop;
 374
 375                if (Nkind (Ent) = N_Attribute_Reference
 376                      and then Attribute_Name (Ent) = Name_Priority)
 377
 378                   --  Renamings of the attribute Priority applied to protected
 379                   --  objects have been previously expanded into calls to the
 380                   --  Get_Ceiling run-time subprogram.
 381
 382                  or else
 383                   (Nkind (Ent) = N_Function_Call
 384                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 385                                 or else
 386                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 387                then
 388                   --  The enclosing subprogram cannot be a protected function
 389
 390                   S := Current_Scope;
 391                   while not (Is_Subprogram (S)
 392                                and then Convention (S) = Convention_Protected)
 393                      and then S /= Standard_Standard
 394                   loop
 395                      S := Scope (S);
 396                   end loop;
 397
 398                   if Ekind (S) = E_Function
 399                     and then Convention (S) = Convention_Protected
 400                   then
 401                      Error_Msg_N
 402                        ("protected function cannot modify protected object",
 403                         Lhs);
 404                   end if;
 405
 406                   --  Changes of the ceiling priority of the protected object
 407                   --  are only effective if the Ceiling_Locking policy is in
 408                   --  effect (AARM D.5.2 (5/2)).
 409
 410                   if Locking_Policy /= 'C' then
 411                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 412                                   "no effect?", Lhs);
 413                      Error_Msg_N ("\since no Locking_Policy has been " &
 414                                   "specified", Lhs);
 415                   end if;
 416
 417                   return;
 418                end if;
 419             end if;
 420          end;
 421
 422          Diagnose_Non_Variable_Lhs (Lhs);
 423          return;
 424
 425       --  Error of assigning to limited type. We do however allow this in
 426       --  certain cases where the front end generates the assignments.
 427
 428       elsif Is_Limited_Type (T1)
 429         and then not Assignment_OK (Lhs)
 430         and then not Assignment_OK (Original_Node (Lhs))
 431         and then not Is_Value_Type (T1)
 432       then
 433          --  CPP constructors can only be called in declarations
 434
 435          if Is_CPP_Constructor_Call (Rhs) then
 436             Error_Msg_N ("invalid use of 'C'P'P constructor", Rhs);
 437          else
 438             Error_Msg_N
 439               ("left hand of assignment must not be limited type", Lhs);
 440             Explain_Limited_Type (T1, Lhs);
 441          end if;
 442          return;
 443
 444       --  Enforce RM 3.9.3 (8): the target of an assignment operation cannot be
 445       --  abstract. This is only checked when the assignment Comes_From_Source,
 446       --  because in some cases the expander generates such assignments (such
 447       --  in the _assign operation for an abstract type).
 448
 449       elsif Is_Abstract_Type (T1) and then Comes_From_Source (N) then
 450          Error_Msg_N
 451            ("target of assignment operation must not be abstract", Lhs);
 452       end if;
 453
 454       --  Resolution may have updated the subtype, in case the left-hand
 455       --  side is a private protected component. Use the correct subtype
 456       --  to avoid scoping issues in the back-end.
 457
 458       T1 := Etype (Lhs);
 459
 460       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 461       --  type. For example:
 462
 463       --    limited with P;
 464       --    package Pkg is
 465       --      type Acc is access P.T;
 466       --    end Pkg;
 467
 468       --    with Pkg; use Acc;
 469       --    procedure Example is
 470       --       A, B : Acc;
 471       --    begin
 472       --       A.all := B.all;  -- ERROR
 473       --    end Example;
 474
 475       if Nkind (Lhs) = N_Explicit_Dereference
 476         and then Ekind (T1) = E_Incomplete_Type
 477       then
 478          Error_Msg_N ("invalid use of incomplete type", Lhs);
 479          Kill_Lhs;
 480          return;
 481       end if;
 482
 483       --  Now we can complete the resolution of the right hand side
 484
 485       Set_Assignment_Type (Lhs, T1);
 486       Resolve (Rhs, T1);
 487
 488       --  This is the point at which we check for an unset reference
 489
 490       Check_Unset_Reference (Rhs);
 491       Check_Unprotected_Access (Lhs, Rhs);
 492
 493       --  Remaining steps are skipped if Rhs was syntactically in error
 494
 495       if Rhs = Error then
 496          Kill_Lhs;
 497          return;
 498       end if;
 499
 500       T2 := Etype (Rhs);
 501
 502       if not Covers (T1, T2) then
 503          Wrong_Type (Rhs, Etype (Lhs));
 504          Kill_Lhs;
 505          return;
 506       end if;
 507
 508       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 509       --  types, use the non-limited view if available
 510
 511       if Nkind (Rhs) = N_Explicit_Dereference
 512         and then Ekind (T2) = E_Incomplete_Type
 513         and then Is_Tagged_Type (T2)
 514         and then Present (Non_Limited_View (T2))
 515       then
 516          T2 := Non_Limited_View (T2);
 517       end if;
 518
 519       Set_Assignment_Type (Rhs, T2);
 520
 521       if Total_Errors_Detected /= 0 then
 522          if No (T1) then
 523             T1 := Any_Type;
 524          end if;
 525
 526          if No (T2) then
 527             T2 := Any_Type;
 528          end if;
 529       end if;
 530
 531       if T1 = Any_Type or else T2 = Any_Type then
 532          Kill_Lhs;
 533          return;
 534       end if;
 535
 536       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 537       --  to be class-wide. The case where the rhs is a dynamically tagged call
 538       --  to a dispatching operation with a controlling access result is
 539       --  excluded from this check, since the target has an access type (and
 540       --  no tag propagation occurs in that case).
 541
 542       if (Is_Class_Wide_Type (T2)
 543            or else (Is_Dynamically_Tagged (Rhs)
 544                      and then not Is_Access_Type (T1)))
 545         and then not Is_Class_Wide_Type (T1)
 546       then
 547          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 548
 549       elsif Is_Class_Wide_Type (T1)
 550         and then not Is_Class_Wide_Type (T2)
 551         and then not Is_Tag_Indeterminate (Rhs)
 552         and then not Is_Dynamically_Tagged (Rhs)
 553       then
 554          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 555       end if;
 556
 557       --  Propagate the tag from a class-wide target to the rhs when the rhs
 558       --  is a tag-indeterminate call.
 559
 560       if Is_Tag_Indeterminate (Rhs) then
 561          if Is_Class_Wide_Type (T1) then
 562             Propagate_Tag (Lhs, Rhs);
 563
 564          elsif Nkind (Rhs) = N_Function_Call
 565               and then Is_Entity_Name (Name (Rhs))
 566               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 567          then
 568             Error_Msg_N
 569               ("call to abstract function must be dispatching", Name (Rhs));
 570
 571          elsif Nkind (Rhs) = N_Qualified_Expression
 572            and then Nkind (Expression (Rhs)) = N_Function_Call
 573               and then Is_Entity_Name (Name (Expression (Rhs)))
 574               and then
 575                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 576          then
 577             Error_Msg_N
 578               ("call to abstract function must be dispatching",
 579                 Name (Expression (Rhs)));
 580          end if;
 581       end if;
 582
 583       --  Ada 2005 (AI-385): When the lhs type is an anonymous access type,
 584       --  apply an implicit conversion of the rhs to that type to force
 585       --  appropriate static and run-time accessibility checks. This applies
 586       --  as well to anonymous access-to-subprogram types that are component
 587       --  subtypes or formal parameters.
 588
 589       if Ada_Version >= Ada_2005
 590         and then Is_Access_Type (T1)
 591       then
 592          if Is_Local_Anonymous_Access (T1)
 593            or else Ekind (T2) = E_Anonymous_Access_Subprogram_Type
 594          then
 595             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 596             Analyze_And_Resolve (Rhs, T1);
 597          end if;
 598       end if;
 599
 600       --  Ada 2005 (AI-231): Assignment to not null variable
 601
 602       if Ada_Version >= Ada_2005
 603         and then Can_Never_Be_Null (T1)
 604         and then not Assignment_OK (Lhs)
 605       then
 606          --  Case where we know the right hand side is null
 607
 608          if Known_Null (Rhs) then
 609             Apply_Compile_Time_Constraint_Error
 610               (N   => Rhs,
 611                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 612                Reason => CE_Null_Not_Allowed);
 613
 614             --  We still mark this as a possible modification, that's necessary
 615             --  to reset Is_True_Constant, and desirable for xref purposes.
 616
 617             Note_Possible_Modification (Lhs, Sure => True);
 618             return;
 619
 620          --  If we know the right hand side is non-null, then we convert to the
 621          --  target type, since we don't need a run time check in that case.
 622
 623          elsif not Can_Never_Be_Null (T2) then
 624             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 625             Analyze_And_Resolve (Rhs, T1);
 626          end if;
 627       end if;
 628
 629       if Is_Scalar_Type (T1) then
 630          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 631
 632       --  For array types, verify that lengths match. If the right hand side
 633       --  if a function call that has been inlined, the assignment has been
 634       --  rewritten as a block, and the constraint check will be applied to the
 635       --  assignment within the block.
 636
 637       elsif Is_Array_Type (T1)
 638         and then
 639           (Nkind (Rhs) /= N_Type_Conversion
 640             or else Is_Constrained (Etype (Rhs)))
 641         and then
 642           (Nkind (Rhs) /= N_Function_Call
 643             or else Nkind (N) /= N_Block_Statement)
 644       then
 645          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 646          --  but of course the indexes do not have to match. If the right-hand
 647          --  side is a type conversion to an unconstrained type, a length check
 648          --  is performed on the expression itself during expansion. In rare
 649          --  cases, the redundant length check is computed on an index type
 650          --  with a different representation, triggering incorrect code in
 651          --  the back end.
 652
 653          Apply_Length_Check (Rhs, Etype (Lhs));
 654
 655       else
 656          --  Discriminant checks are applied in the course of expansion
 657
 658          null;
 659       end if;
 660
 661       --  Note: modifications of the Lhs may only be recorded after
 662       --  checks have been applied.
 663
 664       Note_Possible_Modification (Lhs, Sure => True);
 665       Check_Order_Dependence;
 666
 667       --  ??? a real accessibility check is needed when ???
 668
 669       --  Post warning for redundant assignment or variable to itself
 670
 671       if Warn_On_Redundant_Constructs
 672
 673          --  We only warn for source constructs
 674
 675          and then Comes_From_Source (N)
 676
 677          --  Where the object is the same on both sides
 678
 679          and then Same_Object (Lhs, Original_Node (Rhs))
 680
 681          --  But exclude the case where the right side was an operation
 682          --  that got rewritten (e.g. JUNK + K, where K was known to be
 683          --  zero). We don't want to warn in such a case, since it is
 684          --  reasonable to write such expressions especially when K is
 685          --  defined symbolically in some other package.
 686
 687         and then Nkind (Original_Node (Rhs)) not in N_Op
 688       then
 689          if Nkind (Lhs) in N_Has_Entity then
 690             Error_Msg_NE -- CODEFIX
 691               ("?useless assignment of & to itself!", N, Entity (Lhs));
 692          else
 693             Error_Msg_N -- CODEFIX
 694               ("?useless assignment of object to itself!", N);
 695          end if;
 696       end if;
 697
 698       --  Check for non-allowed composite assignment
 699
 700       if not Support_Composite_Assign_On_Target
 701         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 702         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 703       then
 704          Error_Msg_CRT ("composite assignment", N);
 705       end if;
 706
 707       --  Check elaboration warning for left side if not in elab code
 708
 709       if not In_Subprogram_Or_Concurrent_Unit then
 710          Check_Elab_Assign (Lhs);
 711       end if;
 712
 713       --  Set Referenced_As_LHS if appropriate. We only set this flag if the
 714       --  assignment is a source assignment in the extended main source unit.
 715       --  We are not interested in any reference information outside this
 716       --  context, or in compiler generated assignment statements.
 717
 718       if Comes_From_Source (N)
 719         and then In_Extended_Main_Source_Unit (Lhs)
 720       then
 721          Set_Referenced_Modified (Lhs, Out_Param => False);
 722       end if;
 723
 724       --  Final step. If left side is an entity, then we may be able to
 725       --  reset the current tracked values to new safe values. We only have
 726       --  something to do if the left side is an entity name, and expansion
 727       --  has not modified the node into something other than an assignment,
 728       --  and of course we only capture values if it is safe to do so.
 729
 730       if Is_Entity_Name (Lhs)
 731         and then Nkind (N) = N_Assignment_Statement
 732       then
 733          declare
 734             Ent : constant Entity_Id := Entity (Lhs);
 735
 736          begin
 737             if Safe_To_Capture_Value (N, Ent) then
 738
 739                --  If simple variable on left side, warn if this assignment
 740                --  blots out another one (rendering it useless) and note
 741                --  location of assignment in case no one references value.
 742                --  We only do this for source assignments, otherwise we can
 743                --  generate bogus warnings when an assignment is rewritten as
 744                --  another assignment, and gets tied up with itself.
 745
 746                --  Note: we don't use Record_Last_Assignment here, because we
 747                --  have lots of other stuff to do under control of this test.
 748
 749                if Warn_On_Modified_Unread
 750                  and then Is_Assignable (Ent)
 751                  and then Comes_From_Source (N)
 752                  and then In_Extended_Main_Source_Unit (Ent)
 753                then
 754                   Warn_On_Useless_Assignment (Ent, N);
 755                   Set_Last_Assignment (Ent, Lhs);
 756                end if;
 757
 758                --  If we are assigning an access type and the left side is an
 759                --  entity, then make sure that the Is_Known_[Non_]Null flags
 760                --  properly reflect the state of the entity after assignment.
 761
 762                if Is_Access_Type (T1) then
 763                   if Known_Non_Null (Rhs) then
 764                      Set_Is_Known_Non_Null (Ent, True);
 765
 766                   elsif Known_Null (Rhs)
 767                     and then not Can_Never_Be_Null (Ent)
 768                   then
 769                      Set_Is_Known_Null (Ent, True);
 770
 771                   else
 772                      Set_Is_Known_Null (Ent, False);
 773
 774                      if not Can_Never_Be_Null (Ent) then
 775                         Set_Is_Known_Non_Null (Ent, False);
 776                      end if;
 777                   end if;
 778
 779                --  For discrete types, we may be able to set the current value
 780                --  if the value is known at compile time.
 781
 782                elsif Is_Discrete_Type (T1)
 783                  and then Compile_Time_Known_Value (Rhs)
 784                then
 785                   Set_Current_Value (Ent, Rhs);
 786                else
 787                   Set_Current_Value (Ent, Empty);
 788                end if;
 789
 790             --  If not safe to capture values, kill them
 791
 792             else
 793                Kill_Lhs;
 794             end if;
 795          end;
 796       end if;
 797    end Analyze_Assignment;
 798
 799    -----------------------------
 800    -- Analyze_Block_Statement --
 801    -----------------------------
 802
 803    procedure Analyze_Block_Statement (N : Node_Id) is
 804       Decls : constant List_Id := Declarations (N);
 805       Id    : constant Node_Id := Identifier (N);
 806       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 807
 808    begin
 809       --  Block statement is not allowed in SPARK or ALFA
 810
 811       if Formal_Verification_Mode then
 812          Error_Msg_F ("|~~block statement is not allowed", N);
 813       end if;
 814
 815       --  If no handled statement sequence is present, things are really
 816       --  messed up, and we just return immediately (this is a defence
 817       --  against previous errors).
 818
 819       if No (HSS) then
 820          return;
 821       end if;
 822
 823       --  Normal processing with HSS present
 824
 825       declare
 826          EH  : constant List_Id := Exception_Handlers (HSS);
 827          Ent : Entity_Id        := Empty;
 828          S   : Entity_Id;
 829
 830          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 831          --  Recursively save value of this global, will be restored on exit
 832
 833       begin
 834          --  Initialize unblocked exit count for statements of begin block
 835          --  plus one for each exception handler that is present.
 836
 837          Unblocked_Exit_Count := 1;
 838
 839          if Present (EH) then
 840             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 841          end if;
 842
 843          --  If a label is present analyze it and mark it as referenced
 844
 845          if Present (Id) then
 846             Analyze (Id);
 847             Ent := Entity (Id);
 848
 849             --  An error defense. If we have an identifier, but no entity,
 850             --  then something is wrong. If we have previous errors, then
 851             --  just remove the identifier and continue, otherwise raise
 852             --  an exception.
 853
 854             if No (Ent) then
 855                if Total_Errors_Detected /= 0 then
 856                   Set_Identifier (N, Empty);
 857                else
 858                   raise Program_Error;
 859                end if;
 860
 861             else
 862                Set_Ekind (Ent, E_Block);
 863                Generate_Reference (Ent, N, ' ');
 864                Generate_Definition (Ent);
 865
 866                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 867                   Set_Label_Construct (Parent (Ent), N);
 868                end if;
 869             end if;
 870          end if;
 871
 872          --  If no entity set, create a label entity
 873
 874          if No (Ent) then
 875             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 876             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 877             Set_Parent (Ent, N);
 878          end if;
 879
 880          Set_Etype (Ent, Standard_Void_Type);
 881          Set_Block_Node (Ent, Identifier (N));
 882          Push_Scope (Ent);
 883
 884          if Present (Decls) then
 885             Analyze_Declarations (Decls);
 886             Check_Completion;
 887             Inspect_Deferred_Constant_Completion (Decls);
 888          end if;
 889
 890          Analyze (HSS);
 891          Process_End_Label (HSS, 'e', Ent);
 892
 893          --  If exception handlers are present, then we indicate that
 894          --  enclosing scopes contain a block with handlers. We only
 895          --  need to mark non-generic scopes.
 896
 897          if Present (EH) then
 898             S := Scope (Ent);
 899             loop
 900                Set_Has_Nested_Block_With_Handler (S);
 901                exit when Is_Overloadable (S)
 902                  or else Ekind (S) = E_Package
 903                  or else Is_Generic_Unit (S);
 904                S := Scope (S);
 905             end loop;
 906          end if;
 907
 908          Check_References (Ent);
 909          Warn_On_Useless_Assignments (Ent);
 910          End_Scope;
 911
 912          if Unblocked_Exit_Count = 0 then
 913             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 914             Check_Unreachable_Code (N);
 915          else
 916             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 917          end if;
 918       end;
 919    end Analyze_Block_Statement;
 920
 921    ----------------------------
 922    -- Analyze_Case_Statement --
 923    ----------------------------
 924
 925    procedure Analyze_Case_Statement (N : Node_Id) is
 926       Exp            : Node_Id;
 927       Exp_Type       : Entity_Id;
 928       Exp_Btype      : Entity_Id;
 929       Last_Choice    : Nat;
 930       Dont_Care      : Boolean;
 931       Others_Present : Boolean;
 932
 933       pragma Warnings (Off, Last_Choice);
 934       pragma Warnings (Off, Dont_Care);
 935       --  Don't care about assigned values
 936
 937       Statements_Analyzed : Boolean := False;
 938       --  Set True if at least some statement sequences get analyzed.
 939       --  If False on exit, means we had a serious error that prevented
 940       --  full analysis of the case statement, and as a result it is not
 941       --  a good idea to output warning messages about unreachable code.
 942
 943       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 944       --  Recursively save value of this global, will be restored on exit
 945
 946       procedure Non_Static_Choice_Error (Choice : Node_Id);
 947       --  Error routine invoked by the generic instantiation below when
 948       --  the case statement has a non static choice.
 949
 950       procedure Process_Statements (Alternative : Node_Id);
 951       --  Analyzes all the statements associated with a case alternative.
 952       --  Needed by the generic instantiation below.
 953
 954       package Case_Choices_Processing is new
 955         Generic_Choices_Processing
 956           (Get_Alternatives          => Alternatives,
 957            Get_Choices               => Discrete_Choices,
 958            Process_Empty_Choice      => No_OP,
 959            Process_Non_Static_Choice => Non_Static_Choice_Error,
 960            Process_Associated_Node   => Process_Statements);
 961       use Case_Choices_Processing;
 962       --  Instantiation of the generic choice processing package
 963
 964       -----------------------------
 965       -- Non_Static_Choice_Error --
 966       -----------------------------
 967
 968       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 969       begin
 970          Flag_Non_Static_Expr
 971            ("choice given in case statement is not static!", Choice);
 972       end Non_Static_Choice_Error;
 973
 974       ------------------------
 975       -- Process_Statements --
 976       ------------------------
 977
 978       procedure Process_Statements (Alternative : Node_Id) is
 979          Choices : constant List_Id := Discrete_Choices (Alternative);
 980          Ent     : Entity_Id;
 981
 982       begin
 983          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 984          Statements_Analyzed := True;
 985
 986          --  An interesting optimization. If the case statement expression
 987          --  is a simple entity, then we can set the current value within
 988          --  an alternative if the alternative has one possible value.
 989
 990          --    case N is
 991          --      when 1      => alpha
 992          --      when 2 | 3  => beta
 993          --      when others => gamma
 994
 995          --  Here we know that N is initially 1 within alpha, but for beta
 996          --  and gamma, we do not know anything more about the initial value.
 997
 998          if Is_Entity_Name (Exp) then
 999             Ent := Entity (Exp);
1000
1001             if Ekind_In (Ent, E_Variable,
1002                               E_In_Out_Parameter,
1003                               E_Out_Parameter)
1004             then
1005                if List_Length (Choices) = 1
1006                  and then Nkind (First (Choices)) in N_Subexpr
1007                  and then Compile_Time_Known_Value (First (Choices))
1008                then
1009                   Set_Current_Value (Entity (Exp), First (Choices));
1010                end if;
1011
1012                Analyze_Statements (Statements (Alternative));
1013
1014                --  After analyzing the case, set the current value to empty
1015                --  since we won't know what it is for the next alternative
1016                --  (unless reset by this same circuit), or after the case.
1017
1018                Set_Current_Value (Entity (Exp), Empty);
1019                return;
1020             end if;
1021          end if;
1022
1023          --  Case where expression is not an entity name of a variable
1024
1025          Analyze_Statements (Statements (Alternative));
1026       end Process_Statements;
1027
1028    --  Start of processing for Analyze_Case_Statement
1029
1030    begin
1031       Unblocked_Exit_Count := 0;
1032       Exp := Expression (N);
1033       Analyze (Exp);
1034
1035       --  The expression must be of any discrete type. In rare cases, the
1036       --  expander constructs a case statement whose expression has a private
1037       --  type whose full view is discrete. This can happen when generating
1038       --  a stream operation for a variant type after the type is frozen,
1039       --  when the partial of view of the type of the discriminant is private.
1040       --  In that case, use the full view to analyze case alternatives.
1041
1042       if not Is_Overloaded (Exp)
1043         and then not Comes_From_Source (N)
1044         and then Is_Private_Type (Etype (Exp))
1045         and then Present (Full_View (Etype (Exp)))
1046         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1047       then
1048          Resolve (Exp, Etype (Exp));
1049          Exp_Type := Full_View (Etype (Exp));
1050
1051       else
1052          Analyze_And_Resolve (Exp, Any_Discrete);
1053          Exp_Type := Etype (Exp);
1054       end if;
1055
1056       Check_Unset_Reference (Exp);
1057       Exp_Btype := Base_Type (Exp_Type);
1058
1059       --  The expression must be of a discrete type which must be determinable
1060       --  independently of the context in which the expression occurs, but
1061       --  using the fact that the expression must be of a discrete type.
1062       --  Moreover, the type this expression must not be a character literal
1063       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1064
1065       --  If error already reported by Resolve, nothing more to do
1066
1067       if Exp_Btype = Any_Discrete
1068         or else Exp_Btype = Any_Type
1069       then
1070          return;
1071
1072       elsif Exp_Btype = Any_Character then
1073          Error_Msg_N
1074            ("character literal as case expression is ambiguous", Exp);
1075          return;
1076
1077       elsif Ada_Version = Ada_83
1078         and then (Is_Generic_Type (Exp_Btype)
1079                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1080       then
1081          Error_Msg_N
1082            ("(Ada 83) case expression cannot be of a generic type", Exp);
1083          return;
1084       end if;
1085
1086       --  If the case expression is a formal object of mode in out, then
1087       --  treat it as having a nonstatic subtype by forcing use of the base
1088       --  type (which has to get passed to Check_Case_Choices below).  Also
1089       --  use base type when the case expression is parenthesized.
1090
1091       if Paren_Count (Exp) > 0
1092         or else (Is_Entity_Name (Exp)
1093                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1094       then
1095          Exp_Type := Exp_Btype;
1096       end if;
1097
1098       --  Call instantiated Analyze_Choices which does the rest of the work
1099
1100       Analyze_Choices (N, Exp_Type, Dont_Care, Others_Present);
1101
1102       --  A case statement with a single "others" alternative is not allowed
1103       --  in SPARK or ALFA.
1104
1105       if Formal_Verification_Mode
1106         and then Others_Present
1107         and then List_Length (Alternatives (N)) = 1
1108       then
1109          Error_Msg_F
1110            ("|~~OTHERS as unique case alternative is not allowed", N);
1111       end if;
1112
1113       if Exp_Type = Universal_Integer and then not Others_Present then
1114          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1115       end if;
1116
1117       --  If all our exits were blocked by unconditional transfers of control,
1118       --  then the entire CASE statement acts as an unconditional transfer of
1119       --  control, so treat it like one, and check unreachable code. Skip this
1120       --  test if we had serious errors preventing any statement analysis.
1121
1122       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1123          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1124          Check_Unreachable_Code (N);
1125       else
1126          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1127       end if;
1128
1129       if not Expander_Active
1130         and then Compile_Time_Known_Value (Expression (N))
1131         and then Serious_Errors_Detected = 0
1132       then
1133          declare
1134             Chosen : constant Node_Id := Find_Static_Alternative (N);
1135             Alt    : Node_Id;
1136
1137          begin
1138             Alt := First (Alternatives (N));
1139             while Present (Alt) loop
1140                if Alt /= Chosen then
1141                   Remove_Warning_Messages (Statements (Alt));
1142                end if;
1143
1144                Next (Alt);
1145             end loop;
1146          end;
1147       end if;
1148    end Analyze_Case_Statement;
1149
1150    ----------------------------
1151    -- Analyze_Exit_Statement --
1152    ----------------------------
1153
1154    --  If the exit includes a name, it must be the name of a currently open
1155    --  loop. Otherwise there must be an innermost open loop on the stack,
1156    --  to which the statement implicitly refers.
1157
1158    --  Additionally, in formal mode:
1159    --  * the exit can only name the closest enclosing loop;
1160    --  * an exit with a when clause must be directly contained in a loop;
1161    --  * an exit without a when clause must be directly contained in an
1162    --    if-statement with no elsif or else, which is itself directly contained
1163    --    in a loop. The exit must be the last statement in the if-statement.
1164
1165    procedure Analyze_Exit_Statement (N : Node_Id) is
1166       Target   : constant Node_Id := Name (N);
1167       Cond     : constant Node_Id := Condition (N);
1168       Scope_Id : Entity_Id;
1169       U_Name   : Entity_Id;
1170       Kind     : Entity_Kind;
1171
1172    begin
1173       if No (Cond) then
1174          Check_Unreachable_Code (N);
1175       end if;
1176
1177       if Present (Target) then
1178          Analyze (Target);
1179          U_Name := Entity (Target);
1180
1181          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1182             Error_Msg_N ("invalid loop name in exit statement", N);
1183             return;
1184          elsif Formal_Verification_Mode
1185            and then Has_Loop_In_Inner_Open_Scopes (U_Name)
1186          then
1187             Error_Msg_F
1188               ("|~~exit label must name the closest enclosing loop", N);
1189             return;
1190          else
1191             Set_Has_Exit (U_Name);
1192          end if;
1193
1194       else
1195          U_Name := Empty;
1196       end if;
1197
1198       for J in reverse 0 .. Scope_Stack.Last loop
1199          Scope_Id := Scope_Stack.Table (J).Entity;
1200          Kind := Ekind (Scope_Id);
1201
1202          if Kind = E_Loop
1203            and then (No (Target) or else Scope_Id = U_Name) then
1204             Set_Has_Exit (Scope_Id);
1205             exit;
1206
1207          elsif Kind = E_Block
1208            or else Kind = E_Loop
1209            or else Kind = E_Return_Statement
1210          then
1211             null;
1212
1213          else
1214             Error_Msg_N
1215               ("cannot exit from program unit or accept statement", N);
1216             return;
1217          end if;
1218       end loop;
1219
1220       --  Verify that if present the condition is a Boolean expression
1221
1222       if Present (Cond) then
1223          Analyze_And_Resolve (Cond, Any_Boolean);
1224          Check_Unset_Reference (Cond);
1225       end if;
1226
1227       --  In formal mode, verify that the exit statement respects the SPARK
1228       --  restrictions.
1229
1230       if Formal_Verification_Mode then
1231          if Present (Cond) then
1232             if Nkind (Parent (N)) /= N_Loop_Statement then
1233                Error_Msg_F
1234                  ("|~~exit with when clause must be directly in loop", N);
1235             end if;
1236
1237          else
1238             if Nkind (Parent (N)) /= N_If_Statement then
1239                if Nkind (Parent (N)) = N_Elsif_Part then
1240                   Error_Msg_F ("|~~exit must be in IF without ELSIF", N);
1241                else
1242                   Error_Msg_F ("|~~exit must be directly in IF", N);
1243                end if;
1244
1245             elsif Nkind (Parent (Parent (N))) /= N_Loop_Statement then
1246                Error_Msg_F ("|~~exit must be in IF directly in loop", N);
1247
1248             --  First test the presence of ELSE, so that an exit in an ELSE
1249             --  leads to an error mentioning the ELSE.
1250
1251             elsif Present (Else_Statements (Parent (N))) then
1252                Error_Msg_F ("|~~exit must be in IF without ELSE", N);
1253
1254             --  An exit in an ELSIF does not reach here, as it would have been
1255             --  detected in the case (Nkind (Parent (N)) /= N_If_Statement).
1256
1257             elsif Present (Elsif_Parts (Parent (N))) then
1258                Error_Msg_F ("|~~exit must be in IF without ELSIF", N);
1259             end if;
1260          end if;
1261       end if;
1262
1263       --  Chain exit statement to associated loop entity
1264
1265       Set_Next_Exit_Statement  (N, First_Exit_Statement (Scope_Id));
1266       Set_First_Exit_Statement (Scope_Id, N);
1267
1268       --  Since the exit may take us out of a loop, any previous assignment
1269       --  statement is not useless, so clear last assignment indications. It
1270       --  is OK to keep other current values, since if the exit statement
1271       --  does not exit, then the current values are still valid.
1272
1273       Kill_Current_Values (Last_Assignment_Only => True);
1274    end Analyze_Exit_Statement;
1275
1276    ----------------------------
1277    -- Analyze_Goto_Statement --
1278    ----------------------------
1279
1280    procedure Analyze_Goto_Statement (N : Node_Id) is
1281       Label       : constant Node_Id := Name (N);
1282       Scope_Id    : Entity_Id;
1283       Label_Scope : Entity_Id;
1284       Label_Ent   : Entity_Id;
1285
1286    begin
1287       --  Goto statement is not allowed in SPARK or ALFA
1288
1289       if Formal_Verification_Mode then
1290          Error_Msg_F ("|~~goto statement is not allowed", N);
1291       end if;
1292
1293       --  Actual semantic checks
1294
1295       Check_Unreachable_Code (N);
1296       Kill_Current_Values (Last_Assignment_Only => True);
1297
1298       Analyze (Label);
1299       Label_Ent := Entity (Label);
1300
1301       --  Ignore previous error
1302
1303       if Label_Ent = Any_Id then
1304          return;
1305
1306       --  We just have a label as the target of a goto
1307
1308       elsif Ekind (Label_Ent) /= E_Label then
1309          Error_Msg_N ("target of goto statement must be a label", Label);
1310          return;
1311
1312       --  Check that the target of the goto is reachable according to Ada
1313       --  scoping rules. Note: the special gotos we generate for optimizing
1314       --  local handling of exceptions would violate these rules, but we mark
1315       --  such gotos as analyzed when built, so this code is never entered.
1316
1317       elsif not Reachable (Label_Ent) then
1318          Error_Msg_N ("target of goto statement is not reachable", Label);
1319          return;
1320       end if;
1321
1322       --  Here if goto passes initial validity checks
1323
1324       Label_Scope := Enclosing_Scope (Label_Ent);
1325
1326       for J in reverse 0 .. Scope_Stack.Last loop
1327          Scope_Id := Scope_Stack.Table (J).Entity;
1328
1329          if Label_Scope = Scope_Id
1330            or else (Ekind (Scope_Id) /= E_Block
1331                      and then Ekind (Scope_Id) /= E_Loop
1332                      and then Ekind (Scope_Id) /= E_Return_Statement)
1333          then
1334             if Scope_Id /= Label_Scope then
1335                Error_Msg_N
1336                  ("cannot exit from program unit or accept statement", N);
1337             end if;
1338
1339             return;
1340          end if;
1341       end loop;
1342
1343       raise Program_Error;
1344    end Analyze_Goto_Statement;
1345
1346    --------------------------
1347    -- Analyze_If_Statement --
1348    --------------------------
1349
1350    --  A special complication arises in the analysis of if statements
1351
1352    --  The expander has circuitry to completely delete code that it
1353    --  can tell will not be executed (as a result of compile time known
1354    --  conditions). In the analyzer, we ensure that code that will be
1355    --  deleted in this manner is analyzed but not expanded. This is
1356    --  obviously more efficient, but more significantly, difficulties
1357    --  arise if code is expanded and then eliminated (e.g. exception
1358    --  table entries disappear). Similarly, itypes generated in deleted
1359    --  code must be frozen from start, because the nodes on which they
1360    --  depend will not be available at the freeze point.
1361
1362    procedure Analyze_If_Statement (N : Node_Id) is
1363       E : Node_Id;
1364
1365       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1366       --  Recursively save value of this global, will be restored on exit
1367
1368       Save_In_Deleted_Code : Boolean;
1369
1370       Del : Boolean := False;
1371       --  This flag gets set True if a True condition has been found,
1372       --  which means that remaining ELSE/ELSIF parts are deleted.
1373
1374       procedure Analyze_Cond_Then (Cnode : Node_Id);
1375       --  This is applied to either the N_If_Statement node itself or
1376       --  to an N_Elsif_Part node. It deals with analyzing the condition
1377       --  and the THEN statements associated with it.
1378
1379       -----------------------
1380       -- Analyze_Cond_Then --
1381       -----------------------
1382
1383       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1384          Cond : constant Node_Id := Condition (Cnode);
1385          Tstm : constant List_Id := Then_Statements (Cnode);
1386
1387       begin
1388          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1389          Analyze_And_Resolve (Cond, Any_Boolean);
1390          Check_Unset_Reference (Cond);
1391          Set_Current_Value_Condition (Cnode);
1392
1393          --  If already deleting, then just analyze then statements
1394
1395          if Del then
1396             Analyze_Statements (Tstm);
1397
1398          --  Compile time known value, not deleting yet
1399
1400          elsif Compile_Time_Known_Value (Cond) then
1401             Save_In_Deleted_Code := In_Deleted_Code;
1402
1403             --  If condition is True, then analyze the THEN statements
1404             --  and set no expansion for ELSE and ELSIF parts.
1405
1406             if Is_True (Expr_Value (Cond)) then
1407                Analyze_Statements (Tstm);
1408                Del := True;
1409                Expander_Mode_Save_And_Set (False);
1410                In_Deleted_Code := True;
1411
1412             --  If condition is False, analyze THEN with expansion off
1413
1414             else -- Is_False (Expr_Value (Cond))
1415                Expander_Mode_Save_And_Set (False);
1416                In_Deleted_Code := True;
1417                Analyze_Statements (Tstm);
1418                Expander_Mode_Restore;
1419                In_Deleted_Code := Save_In_Deleted_Code;
1420             end if;
1421
1422          --  Not known at compile time, not deleting, normal analysis
1423
1424          else
1425             Analyze_Statements (Tstm);
1426          end if;
1427       end Analyze_Cond_Then;
1428
1429    --  Start of Analyze_If_Statement
1430
1431    begin
1432       --  Initialize exit count for else statements. If there is no else
1433       --  part, this count will stay non-zero reflecting the fact that the
1434       --  uncovered else case is an unblocked exit.
1435
1436       Unblocked_Exit_Count := 1;
1437       Analyze_Cond_Then (N);
1438
1439       --  Now to analyze the elsif parts if any are present
1440
1441       if Present (Elsif_Parts (N)) then
1442          E := First (Elsif_Parts (N));
1443          while Present (E) loop
1444             Analyze_Cond_Then (E);
1445             Next (E);
1446          end loop;
1447       end if;
1448
1449       if Present (Else_Statements (N)) then
1450          Analyze_Statements (Else_Statements (N));
1451       end if;
1452
1453       --  If all our exits were blocked by unconditional transfers of control,
1454       --  then the entire IF statement acts as an unconditional transfer of
1455       --  control, so treat it like one, and check unreachable code.
1456
1457       if Unblocked_Exit_Count = 0 then
1458          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1459          Check_Unreachable_Code (N);
1460       else
1461          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1462       end if;
1463
1464       if Del then
1465          Expander_Mode_Restore;
1466          In_Deleted_Code := Save_In_Deleted_Code;
1467       end if;
1468
1469       if not Expander_Active
1470         and then Compile_Time_Known_Value (Condition (N))
1471         and then Serious_Errors_Detected = 0
1472       then
1473          if Is_True (Expr_Value (Condition (N))) then
1474             Remove_Warning_Messages (Else_Statements (N));
1475
1476             if Present (Elsif_Parts (N)) then
1477                E := First (Elsif_Parts (N));
1478                while Present (E) loop
1479                   Remove_Warning_Messages (Then_Statements (E));
1480                   Next (E);
1481                end loop;
1482             end if;
1483
1484          else
1485             Remove_Warning_Messages (Then_Statements (N));
1486          end if;
1487       end if;
1488    end Analyze_If_Statement;
1489
1490    ----------------------------------------
1491    -- Analyze_Implicit_Label_Declaration --
1492    ----------------------------------------
1493
1494    --  An implicit label declaration is generated in the innermost
1495    --  enclosing declarative part. This is done for labels as well as
1496    --  block and loop names.
1497
1498    --  Note: any changes in this routine may need to be reflected in
1499    --  Analyze_Label_Entity.
1500
1501    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1502       Id : constant Node_Id := Defining_Identifier (N);
1503    begin
1504       Enter_Name          (Id);
1505       Set_Ekind           (Id, E_Label);
1506       Set_Etype           (Id, Standard_Void_Type);
1507       Set_Enclosing_Scope (Id, Current_Scope);
1508    end Analyze_Implicit_Label_Declaration;
1509
1510    ------------------------------
1511    -- Analyze_Iteration_Scheme --
1512    ------------------------------
1513
1514    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1515
1516       procedure Process_Bounds (R : Node_Id);
1517       --  If the iteration is given by a range, create temporaries and
1518       --  assignment statements block to capture the bounds and perform
1519       --  required finalization actions in case a bound includes a function
1520       --  call that uses the temporary stack. We first pre-analyze a copy of
1521       --  the range in order to determine the expected type, and analyze and
1522       --  resolve the original bounds.
1523
1524       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1525       --  If the bounds are given by a 'Range reference on a function call
1526       --  that returns a controlled array, introduce an explicit declaration
1527       --  to capture the bounds, so that the function result can be finalized
1528       --  in timely fashion.
1529
1530       --------------------
1531       -- Process_Bounds --
1532       --------------------
1533
1534       procedure Process_Bounds (R : Node_Id) is
1535          Loc          : constant Source_Ptr := Sloc (N);
1536          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1537          Lo           : constant Node_Id := Low_Bound  (R);
1538          Hi           : constant Node_Id := High_Bound (R);
1539          New_Lo_Bound : Node_Id;
1540          New_Hi_Bound : Node_Id;
1541          Typ          : Entity_Id;
1542          Save_Analysis : Boolean;
1543
1544          function One_Bound
1545            (Original_Bound : Node_Id;
1546             Analyzed_Bound : Node_Id) return Node_Id;
1547          --  Capture value of bound and return captured value
1548
1549          ---------------
1550          -- One_Bound --
1551          ---------------
1552
1553          function One_Bound
1554            (Original_Bound : Node_Id;
1555             Analyzed_Bound : Node_Id) return Node_Id
1556          is
1557             Assign : Node_Id;
1558             Id     : Entity_Id;
1559             Decl   : Node_Id;
1560
1561          begin
1562             --  If the bound is a constant or an object, no need for a separate
1563             --  declaration. If the bound is the result of previous expansion
1564             --  it is already analyzed and should not be modified. Note that
1565             --  the Bound will be resolved later, if needed, as part of the
1566             --  call to Make_Index (literal bounds may need to be resolved to
1567             --  type Integer).
1568
1569             if Analyzed (Original_Bound) then
1570                return Original_Bound;
1571
1572             elsif Nkind_In (Analyzed_Bound, N_Integer_Literal,
1573                                             N_Character_Literal)
1574               or else Is_Entity_Name (Analyzed_Bound)
1575             then
1576                Analyze_And_Resolve (Original_Bound, Typ);
1577                return Original_Bound;
1578             end if;
1579
1580             --  Here we need to capture the value
1581
1582             Analyze_And_Resolve (Original_Bound, Typ);
1583
1584             Id := Make_Temporary (Loc, 'S', Original_Bound);
1585
1586             --  Normally, the best approach is simply to generate a constant
1587             --  declaration that captures the bound. However, there is a nasty
1588             --  case where this is wrong. If the bound is complex, and has a
1589             --  possible use of the secondary stack, we need to generate a
1590             --  separate assignment statement to ensure the creation of a block
1591             --  which will release the secondary stack.
1592
1593             --  We prefer the constant declaration, since it leaves us with a
1594             --  proper trace of the value, useful in optimizations that get rid
1595             --  of junk range checks.
1596
1597             --  Probably we want something like the Side_Effect_Free routine
1598             --  in Exp_Util, but for now, we just optimize the cases of 'Last
1599             --  and 'First applied to an entity, since these are the important
1600             --  cases for range check optimizations.
1601
1602             if Nkind (Original_Bound) = N_Attribute_Reference
1603               and then (Attribute_Name (Original_Bound) = Name_First
1604                           or else
1605                         Attribute_Name (Original_Bound) = Name_Last)
1606               and then Is_Entity_Name (Prefix (Original_Bound))
1607             then
1608                Decl :=
1609                  Make_Object_Declaration (Loc,
1610                    Defining_Identifier => Id,
1611                    Constant_Present    => True,
1612                    Object_Definition   => New_Occurrence_Of (Typ, Loc),
1613                    Expression          => Relocate_Node (Original_Bound));
1614
1615                --  Insert declaration at proper place. If loop comes from an
1616                --  enclosing quantified expression, the insertion point is
1617                --  arbitrarily far up in the tree.
1618
1619                Insert_Action (Parent (N), Decl);
1620                Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1621                return Expression (Decl);
1622             end if;
1623
1624             --  Here we make a declaration with a separate assignment
1625             --   statement, and insert before loop header.
1626
1627             Decl :=
1628               Make_Object_Declaration (Loc,
1629                 Defining_Identifier => Id,
1630                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1631
1632             Assign :=
1633               Make_Assignment_Statement (Loc,
1634                 Name        => New_Occurrence_Of (Id, Loc),
1635                 Expression  => Relocate_Node (Original_Bound));
1636
1637             Insert_Actions (Parent (N), New_List (Decl, Assign));
1638
1639             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1640
1641             if Nkind (Assign) = N_Assignment_Statement then
1642                return Expression (Assign);
1643             else
1644                return Original_Bound;
1645             end if;
1646          end One_Bound;
1647
1648       --  Start of processing for Process_Bounds
1649
1650       begin
1651          --  Determine expected type of range by analyzing separate copy
1652          --  Do the analysis and resolution of the copy of the bounds with
1653          --  expansion disabled, to prevent the generation of finalization
1654          --  actions on each bound. This prevents memory leaks when the
1655          --  bounds contain calls to functions returning controlled arrays.
1656
1657          Set_Parent (R_Copy, Parent (R));
1658          Save_Analysis := Full_Analysis;
1659          Full_Analysis := False;
1660          Expander_Mode_Save_And_Set (False);
1661
1662          Analyze (R_Copy);
1663
1664          if Is_Overloaded (R_Copy) then
1665
1666             --  Apply preference rules for range of predefined integer types,
1667             --  or diagnose true ambiguity.
1668
1669             declare
1670                I     : Interp_Index;
1671                It    : Interp;
1672                Found : Entity_Id := Empty;
1673
1674             begin
1675                Get_First_Interp (R_Copy, I, It);
1676                while Present (It.Typ) loop
1677                   if Is_Discrete_Type (It.Typ) then
1678                      if No (Found) then
1679                         Found := It.Typ;
1680                      else
1681                         if Scope (Found) = Standard_Standard then
1682                            null;
1683
1684                         elsif Scope (It.Typ) = Standard_Standard then
1685                            Found := It.Typ;
1686
1687                         else
1688                            --  Both of them are user-defined
1689
1690                            Error_Msg_N
1691                              ("ambiguous bounds in range of iteration",
1692                                R_Copy);
1693                            Error_Msg_N ("\possible interpretations:", R_Copy);
1694                            Error_Msg_NE ("\\} ", R_Copy, Found);
1695                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1696                            exit;
1697                         end if;
1698                      end if;
1699                   end if;
1700
1701                   Get_Next_Interp (I, It);
1702                end loop;
1703             end;
1704          end if;
1705
1706          Resolve (R_Copy);
1707          Expander_Mode_Restore;
1708          Full_Analysis := Save_Analysis;
1709
1710          Typ := Etype (R_Copy);
1711
1712          --  If the type of the discrete range is Universal_Integer, then
1713          --  the bound's type must be resolved to Integer, and any object
1714          --  used to hold the bound must also have type Integer, unless the
1715          --  literal bounds are constant-folded expressions that carry a user-
1716          --  defined type.
1717
1718          if Typ = Universal_Integer then
1719             if Nkind (Lo) = N_Integer_Literal
1720               and then Present (Etype (Lo))
1721               and then Scope (Etype (Lo)) /= Standard_Standard
1722             then
1723                Typ := Etype (Lo);
1724
1725             elsif Nkind (Hi) = N_Integer_Literal
1726               and then Present (Etype (Hi))
1727               and then Scope (Etype (Hi)) /= Standard_Standard
1728             then
1729                Typ := Etype (Hi);
1730
1731             else
1732                Typ := Standard_Integer;
1733             end if;
1734          end if;
1735
1736          Set_Etype (R, Typ);
1737
1738          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1739          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1740
1741          --  Propagate staticness to loop range itself, in case the
1742          --  corresponding subtype is static.
1743
1744          if New_Lo_Bound /= Lo
1745            and then Is_Static_Expression (New_Lo_Bound)
1746          then
1747             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1748          end if;
1749
1750          if New_Hi_Bound /= Hi
1751            and then Is_Static_Expression (New_Hi_Bound)
1752          then
1753             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1754          end if;
1755       end Process_Bounds;
1756
1757       --------------------------------------
1758       -- Check_Controlled_Array_Attribute --
1759       --------------------------------------
1760
1761       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1762       begin
1763          if Nkind (DS) = N_Attribute_Reference
1764             and then Is_Entity_Name (Prefix (DS))
1765             and then Ekind (Entity (Prefix (DS))) = E_Function
1766             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1767             and then
1768               Is_Controlled (
1769                 Component_Type (Etype (Entity (Prefix (DS)))))
1770             and then Expander_Active
1771          then
1772             declare
1773                Loc  : constant Source_Ptr := Sloc (N);
1774                Arr  : constant Entity_Id := Etype (Entity (Prefix (DS)));
1775                Indx : constant Entity_Id :=
1776                         Base_Type (Etype (First_Index (Arr)));
1777                Subt : constant Entity_Id := Make_Temporary (Loc, 'S');
1778                Decl : Node_Id;
1779
1780             begin
1781                Decl :=
1782                  Make_Subtype_Declaration (Loc,
1783                    Defining_Identifier => Subt,
1784                    Subtype_Indication  =>
1785                       Make_Subtype_Indication (Loc,
1786                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1787                         Constraint =>
1788                           Make_Range_Constraint (Loc,
1789                             Relocate_Node (DS))));
1790                Insert_Before (Parent (N), Decl);
1791                Analyze (Decl);
1792
1793                Rewrite (DS,
1794                   Make_Attribute_Reference (Loc,
1795                     Prefix => New_Reference_To (Subt, Loc),
1796                     Attribute_Name => Attribute_Name (DS)));
1797                Analyze (DS);
1798             end;
1799          end if;
1800       end Check_Controlled_Array_Attribute;
1801
1802    --  Start of processing for Analyze_Iteration_Scheme
1803
1804    begin
1805       --  If this is a rewritten quantified expression, the iteration
1806       --  scheme has been analyzed already. Do no repeat analysis because
1807       --  the loop variable is already declared.
1808
1809       if Analyzed (N) then
1810          return;
1811       end if;
1812
1813       --  For an infinite loop, there is no iteration scheme
1814
1815       if No (N) then
1816          return;
1817       end if;
1818
1819       --  Iteration scheme is present
1820
1821       declare
1822          Cond : constant Node_Id := Condition (N);
1823
1824       begin
1825          --  For WHILE loop, verify that the condition is a Boolean
1826          --  expression and resolve and check it.
1827
1828          if Present (Cond) then
1829             Analyze_And_Resolve (Cond, Any_Boolean);
1830             Check_Unset_Reference (Cond);
1831             Set_Current_Value_Condition (N);
1832             return;
1833
1834          elsif Present (Iterator_Specification (N)) then
1835             Analyze_Iterator_Specification (Iterator_Specification (N));
1836
1837          --  Else we have a FOR loop
1838
1839          else
1840             declare
1841                LP : constant Node_Id   := Loop_Parameter_Specification (N);
1842                Id : constant Entity_Id := Defining_Identifier (LP);
1843                DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1844
1845             begin
1846                Enter_Name (Id);
1847
1848                --  We always consider the loop variable to be referenced,
1849                --  since the loop may be used just for counting purposes.
1850
1851                Generate_Reference (Id, N, ' ');
1852
1853                --  Check for the case of loop variable hiding a local variable
1854                --  (used later on to give a nice warning if the hidden variable
1855                --  is never assigned).
1856
1857                declare
1858                   H : constant Entity_Id := Homonym (Id);
1859                begin
1860                   if Present (H)
1861                     and then Enclosing_Dynamic_Scope (H) =
1862                     Enclosing_Dynamic_Scope (Id)
1863                     and then Ekind (H) = E_Variable
1864                     and then Is_Discrete_Type (Etype (H))
1865                   then
1866                      Set_Hiding_Loop_Variable (H, Id);
1867                   end if;
1868                end;
1869
1870                --  Loop parameter specification must include subtype mark in
1871                --  SPARK or ALFA.
1872
1873                if Formal_Verification_Mode
1874                  and then Nkind (DS) = N_Range
1875                then
1876                   Error_Msg_F ("|~~loop parameter specification must "
1877                                & "include subtype mark", N);
1878                end if;
1879
1880                --  Now analyze the subtype definition. If it is a range, create
1881                --  temporaries for bounds.
1882
1883                if Nkind (DS) = N_Range
1884                  and then Expander_Active
1885                then
1886                   Process_Bounds (DS);
1887
1888                --  Not a range or expander not active (is that right???)
1889
1890                else
1891                   Analyze (DS);
1892
1893                   if Nkind (DS) = N_Function_Call
1894                     or else
1895                       (Is_Entity_Name (DS)
1896                         and then not Is_Type (Entity (DS)))
1897                   then
1898                      --  This is an iterator specification. Rewrite as such
1899                      --  and analyze.
1900
1901                      declare
1902                         I_Spec : constant Node_Id :=
1903                                    Make_Iterator_Specification (Sloc (LP),
1904                                      Defining_Identifier =>
1905                                        Relocate_Node (Id),
1906                                      Name                =>
1907                                        Relocate_Node (DS),
1908                                      Subtype_Indication  =>
1909                                        Empty,
1910                                      Reverse_Present     =>
1911                                        Reverse_Present (LP));
1912                      begin
1913                         Set_Iterator_Specification (N, I_Spec);
1914                         Set_Loop_Parameter_Specification (N, Empty);
1915                         Analyze_Iterator_Specification (I_Spec);
1916                         return;
1917                      end;
1918                   end if;
1919                end if;
1920
1921                if DS = Error then
1922                   return;
1923                end if;
1924
1925                --  Some additional checks if we are iterating through a type
1926
1927                if Is_Entity_Name (DS)
1928                  and then Present (Entity (DS))
1929                  and then Is_Type (Entity (DS))
1930                then
1931                   --  The subtype indication may denote the completion of an
1932                   --  incomplete type declaration.
1933
1934                   if Ekind (Entity (DS)) = E_Incomplete_Type then
1935                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1936                      Set_Etype  (DS, Entity (DS));
1937                   end if;
1938
1939                   --  Attempt to iterate through non-static predicate
1940
1941                   if Is_Discrete_Type (Entity (DS))
1942                     and then Present (Predicate_Function (Entity (DS)))
1943                     and then No (Static_Predicate (Entity (DS)))
1944                   then
1945                      Bad_Predicated_Subtype_Use
1946                        ("cannot use subtype& with non-static "
1947                         & "predicate for loop iteration", DS, Entity (DS));
1948                   end if;
1949                end if;
1950
1951                --  Error if not discrete type
1952
1953                if not Is_Discrete_Type (Etype (DS)) then
1954                   Wrong_Type (DS, Any_Discrete);
1955                   Set_Etype (DS, Any_Type);
1956                end if;
1957
1958                Check_Controlled_Array_Attribute (DS);
1959
1960                Make_Index (DS, LP);
1961
1962                Set_Ekind (Id, E_Loop_Parameter);
1963
1964                --  If the loop is part of a predicate or precondition, it may
1965                --  be analyzed twice, once in the source and once on the copy
1966                --  used to check conformance. Preserve the original itype
1967                --  because the second one may be created in a different scope,
1968                --  e.g. a precondition procedure, leading to a crash in GIGI.
1969
1970                if No (Etype (Id)) or else Etype (Id) = Any_Type then
1971                   Set_Etype (Id, Etype (DS));
1972                end if;
1973
1974                --  Treat a range as an implicit reference to the type, to
1975                --  inhibit spurious warnings.
1976
1977                Generate_Reference (Base_Type (Etype (DS)), N, ' ');
1978                Set_Is_Known_Valid (Id, True);
1979
1980                --  The loop is not a declarative part, so the only entity
1981                --  declared "within" must be frozen explicitly.
1982
1983                declare
1984                   Flist : constant List_Id := Freeze_Entity (Id, N);
1985                begin
1986                   if Is_Non_Empty_List (Flist) then
1987                      Insert_Actions (N, Flist);
1988                   end if;
1989                end;
1990
1991                --  Check for null or possibly null range and issue warning. We
1992                --  suppress such messages in generic templates and instances,
1993                --  because in practice they tend to be dubious in these cases.
1994
1995                if Nkind (DS) = N_Range and then Comes_From_Source (N) then
1996                   declare
1997                      L : constant Node_Id := Low_Bound  (DS);
1998                      H : constant Node_Id := High_Bound (DS);
1999
2000                   begin
2001                      --  If range of loop is null, issue warning
2002
2003                      if Compile_Time_Compare
2004                           (L, H, Assume_Valid => True) = GT
2005                      then
2006                         --  Suppress the warning if inside a generic template
2007                         --  or instance, since in practice they tend to be
2008                         --  dubious in these cases since they can result from
2009                         --  intended parametrization.
2010
2011                         if not Inside_A_Generic
2012                           and then not In_Instance
2013                         then
2014                            --  Specialize msg if invalid values could make
2015                            --  the loop non-null after all.
2016
2017                            if Compile_Time_Compare
2018                                 (L, H, Assume_Valid => False) = GT
2019                            then
2020                               Error_Msg_N
2021                                 ("?loop range is null, loop will not execute",
2022                                  DS);
2023
2024                               --  Since we know the range of the loop is
2025                               --  null, set the appropriate flag to remove
2026                               --  the loop entirely during expansion.
2027
2028                               Set_Is_Null_Loop (Parent (N));
2029
2030                               --  Here is where the loop could execute because
2031                               --  of invalid values, so issue appropriate
2032                               --  message and in this case we do not set the
2033                               --  Is_Null_Loop flag since the loop may execute.
2034
2035                            else
2036                               Error_Msg_N
2037                                 ("?loop range may be null, "
2038                                  & "loop may not execute",
2039                                  DS);
2040                               Error_Msg_N
2041                                 ("?can only execute if invalid values "
2042                                  & "are present",
2043                                  DS);
2044                            end if;
2045                         end if;
2046
2047                         --  In either case, suppress warnings in the body of
2048                         --  the loop, since it is likely that these warnings
2049                         --  will be inappropriate if the loop never actually
2050                         --  executes, which is likely.
2051
2052                         Set_Suppress_Loop_Warnings (Parent (N));
2053
2054                         --  The other case for a warning is a reverse loop
2055                         --  where the upper bound is the integer literal zero
2056                         --  or one, and the lower bound can be positive.
2057
2058                         --  For example, we have
2059
2060                         --     for J in reverse N .. 1 loop
2061
2062                         --  In practice, this is very likely to be a case of
2063                         --  reversing the bounds incorrectly in the range.
2064
2065                      elsif Reverse_Present (LP)
2066                        and then Nkind (Original_Node (H)) =
2067                                                       N_Integer_Literal
2068                        and then (Intval (Original_Node (H)) = Uint_0
2069                                   or else
2070                                     Intval (Original_Node (H)) = Uint_1)
2071                      then
2072                         Error_Msg_N ("?loop range may be null", DS);
2073                         Error_Msg_N ("\?bounds may be wrong way round", DS);
2074                      end if;
2075                   end;
2076                end if;
2077             end;
2078          end if;
2079       end;
2080    end Analyze_Iteration_Scheme;
2081
2082    -------------------------------------
2083    --  Analyze_Iterator_Specification --
2084    -------------------------------------
2085
2086    procedure Analyze_Iterator_Specification (N : Node_Id) is
2087       Def_Id    : constant Node_Id := Defining_Identifier (N);
2088       Subt      : constant Node_Id := Subtype_Indication (N);
2089       Container : constant Node_Id := Name (N);
2090
2091       Ent : Entity_Id;
2092       Typ : Entity_Id;
2093
2094    begin
2095       Enter_Name (Def_Id);
2096       Set_Ekind (Def_Id, E_Variable);
2097
2098       if Present (Subt) then
2099          Analyze (Subt);
2100       end if;
2101
2102       Analyze_And_Resolve (Container);
2103       Typ := Etype (Container);
2104
2105       if Is_Array_Type (Typ) then
2106          if Of_Present (N) then
2107             Set_Etype (Def_Id, Component_Type (Typ));
2108          else
2109             Error_Msg_N
2110               ("to iterate over the elements of an array, use OF", N);
2111             Set_Etype (Def_Id, Etype (First_Index (Typ)));
2112          end if;
2113
2114       --  Iteration over a container
2115
2116       else
2117          Set_Ekind (Def_Id, E_Loop_Parameter);
2118
2119          if Of_Present (N) then
2120
2121             --  Find the Element_Type in the package instance that defines the
2122             --  container type.
2123
2124             Ent := First_Entity (Scope (Typ));
2125             while Present (Ent) loop
2126                if Chars (Ent) = Name_Element_Type then
2127                   Set_Etype (Def_Id, Ent);
2128                   exit;
2129                end if;
2130
2131                Next_Entity (Ent);
2132             end loop;
2133
2134          else
2135             --  Find the Cursor type in similar fashion
2136
2137             Ent := First_Entity (Scope (Typ));
2138             while Present (Ent) loop
2139                if Chars (Ent) = Name_Cursor then
2140                   Set_Etype (Def_Id, Ent);
2141                   exit;
2142                end if;
2143
2144                Next_Entity (Ent);
2145             end loop;
2146          end if;
2147       end if;
2148    end Analyze_Iterator_Specification;
2149
2150    -------------------
2151    -- Analyze_Label --
2152    -------------------
2153
2154    --  Note: the semantic work required for analyzing labels (setting them as
2155    --  reachable) was done in a prepass through the statements in the block,
2156    --  so that forward gotos would be properly handled. See Analyze_Statements
2157    --  for further details. The only processing required here is to deal with
2158    --  optimizations that depend on an assumption of sequential control flow,
2159    --  since of course the occurrence of a label breaks this assumption.
2160
2161    procedure Analyze_Label (N : Node_Id) is
2162       pragma Warnings (Off, N);
2163    begin
2164       Kill_Current_Values;
2165    end Analyze_Label;
2166
2167    --------------------------
2168    -- Analyze_Label_Entity --
2169    --------------------------
2170
2171    procedure Analyze_Label_Entity (E : Entity_Id) is
2172    begin
2173       Set_Ekind           (E, E_Label);
2174       Set_Etype           (E, Standard_Void_Type);
2175       Set_Enclosing_Scope (E, Current_Scope);
2176       Set_Reachable       (E, True);
2177    end Analyze_Label_Entity;
2178
2179    ----------------------------
2180    -- Analyze_Loop_Statement --
2181    ----------------------------
2182
2183    procedure Analyze_Loop_Statement (N : Node_Id) is
2184       Loop_Statement : constant Node_Id := N;
2185
2186       Id   : constant Node_Id := Identifier (Loop_Statement);
2187       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
2188       Ent  : Entity_Id;
2189
2190    begin
2191       if Present (Id) then
2192
2193          --  Make name visible, e.g. for use in exit statements. Loop
2194          --  labels are always considered to be referenced.
2195
2196          Analyze (Id);
2197          Ent := Entity (Id);
2198
2199          --  Guard against serious error (typically, a scope mismatch when
2200          --  semantic analysis is requested) by creating loop entity to
2201          --  continue analysis.
2202
2203          if No (Ent) then
2204             if Total_Errors_Detected /= 0 then
2205                Ent :=
2206                  New_Internal_Entity
2207                    (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2208             else
2209                raise Program_Error;
2210             end if;
2211
2212          else
2213             Generate_Reference  (Ent, Loop_Statement, ' ');
2214             Generate_Definition (Ent);
2215
2216             --  If we found a label, mark its type. If not, ignore it, since it
2217             --  means we have a conflicting declaration, which would already
2218             --  have been diagnosed at declaration time. Set Label_Construct
2219             --  of the implicit label declaration, which is not created by the
2220             --  parser for generic units.
2221
2222             if Ekind (Ent) = E_Label then
2223                Set_Ekind (Ent, E_Loop);
2224
2225                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
2226                   Set_Label_Construct (Parent (Ent), Loop_Statement);
2227                end if;
2228             end if;
2229          end if;
2230
2231       --  Case of no identifier present
2232
2233       else
2234          Ent :=
2235            New_Internal_Entity
2236              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2237          Set_Etype (Ent,  Standard_Void_Type);
2238          Set_Parent (Ent, Loop_Statement);
2239       end if;
2240
2241       --  Kill current values on entry to loop, since statements in body of
2242       --  loop may have been executed before the loop is entered. Similarly we
2243       --  kill values after the loop, since we do not know that the body of the
2244       --  loop was executed.
2245
2246       Kill_Current_Values;
2247       Push_Scope (Ent);
2248       Analyze_Iteration_Scheme (Iter);
2249       Analyze_Statements (Statements (Loop_Statement));
2250       Process_End_Label (Loop_Statement, 'e', Ent);
2251       End_Scope;
2252       Kill_Current_Values;
2253
2254       --  Check for infinite loop. Skip check for generated code, since it
2255       --  justs waste time and makes debugging the routine called harder.
2256
2257       --  Note that we have to wait till the body of the loop is fully analyzed
2258       --  before making this call, since Check_Infinite_Loop_Warning relies on
2259       --  being able to use semantic visibility information to find references.
2260
2261       if Comes_From_Source (N) then
2262          Check_Infinite_Loop_Warning (N);
2263       end if;
2264
2265       --  Code after loop is unreachable if the loop has no WHILE or FOR
2266       --  and contains no EXIT statements within the body of the loop.
2267
2268       if No (Iter) and then not Has_Exit (Ent) then
2269          Check_Unreachable_Code (N);
2270       end if;
2271    end Analyze_Loop_Statement;
2272
2273    ----------------------------
2274    -- Analyze_Null_Statement --
2275    ----------------------------
2276
2277    --  Note: the semantics of the null statement is implemented by a single
2278    --  null statement, too bad everything isn't as simple as this!
2279
2280    procedure Analyze_Null_Statement (N : Node_Id) is
2281       pragma Warnings (Off, N);
2282    begin
2283       null;
2284    end Analyze_Null_Statement;
2285
2286    ------------------------
2287    -- Analyze_Statements --
2288    ------------------------
2289
2290    procedure Analyze_Statements (L : List_Id) is
2291       S   : Node_Id;
2292       Lab : Entity_Id;
2293
2294    begin
2295       --  The labels declared in the statement list are reachable from
2296       --  statements in the list. We do this as a prepass so that any
2297       --  goto statement will be properly flagged if its target is not
2298       --  reachable. This is not required, but is nice behavior!
2299
2300       S := First (L);
2301       while Present (S) loop
2302          if Nkind (S) = N_Label then
2303             Analyze (Identifier (S));
2304             Lab := Entity (Identifier (S));
2305
2306             --  If we found a label mark it as reachable
2307
2308             if Ekind (Lab) = E_Label then
2309                Generate_Definition (Lab);
2310                Set_Reachable (Lab);
2311
2312                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
2313                   Set_Label_Construct (Parent (Lab), S);
2314                end if;
2315
2316             --  If we failed to find a label, it means the implicit declaration
2317             --  of the label was hidden.  A for-loop parameter can do this to
2318             --  a label with the same name inside the loop, since the implicit
2319             --  label declaration is in the innermost enclosing body or block
2320             --  statement.
2321
2322             else
2323                Error_Msg_Sloc := Sloc (Lab);
2324                Error_Msg_N
2325                  ("implicit label declaration for & is hidden#",
2326                   Identifier (S));
2327             end if;
2328          end if;
2329
2330          Next (S);
2331       end loop;
2332
2333       --  Perform semantic analysis on all statements
2334
2335       Conditional_Statements_Begin;
2336
2337       S := First (L);
2338       while Present (S) loop
2339          Analyze (S);
2340          Next (S);
2341       end loop;
2342
2343       Conditional_Statements_End;
2344
2345       --  Make labels unreachable. Visibility is not sufficient, because
2346       --  labels in one if-branch for example are not reachable from the
2347       --  other branch, even though their declarations are in the enclosing
2348       --  declarative part.
2349
2350       S := First (L);
2351       while Present (S) loop
2352          if Nkind (S) = N_Label then
2353             Set_Reachable (Entity (Identifier (S)), False);
2354          end if;
2355
2356          Next (S);
2357       end loop;
2358    end Analyze_Statements;
2359
2360    ----------------------------
2361    -- Check_Unreachable_Code --
2362    ----------------------------
2363
2364    procedure Check_Unreachable_Code (N : Node_Id) is
2365       Error_Loc : Source_Ptr;
2366       P         : Node_Id;
2367
2368    begin
2369       if Is_List_Member (N)
2370         and then Comes_From_Source (N)
2371       then
2372          declare
2373             Nxt : Node_Id;
2374
2375          begin
2376             Nxt := Original_Node (Next (N));
2377
2378             --  If a label follows us, then we never have dead code, since
2379             --  someone could branch to the label, so we just ignore it,
2380             --  unless we are in formal mode where goto statements are not
2381             --  allowed.
2382
2383             if Nkind (Nxt) = N_Label and then not Formal_Verification_Mode then
2384                return;
2385
2386             --  Otherwise see if we have a real statement following us
2387
2388             elsif Present (Nxt)
2389               and then Comes_From_Source (Nxt)
2390               and then Is_Statement (Nxt)
2391             then
2392                --  Special very annoying exception. If we have a return that
2393                --  follows a raise, then we allow it without a warning, since
2394                --  the Ada RM annoyingly requires a useless return here!
2395
2396                if Nkind (Original_Node (N)) /= N_Raise_Statement
2397                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2398                then
2399                   --  The rather strange shenanigans with the warning message
2400                   --  here reflects the fact that Kill_Dead_Code is very good
2401                   --  at removing warnings in deleted code, and this is one
2402                   --  warning we would prefer NOT to have removed.
2403
2404                   Error_Loc := Sloc (Nxt);
2405
2406                   --  If we have unreachable code, analyze and remove the
2407                   --  unreachable code, since it is useless and we don't
2408                   --  want to generate junk warnings.
2409
2410                   --  We skip this step if we are not in code generation mode.
2411                   --  This is the one case where we remove dead code in the
2412                   --  semantics as opposed to the expander, and we do not want
2413                   --  to remove code if we are not in code generation mode,
2414                   --  since this messes up the ASIS trees.
2415
2416                   --  Note that one might react by moving the whole circuit to
2417                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2418
2419                   if Operating_Mode = Generate_Code then
2420                      loop
2421                         Nxt := Next (N);
2422
2423                         --  Quit deleting when we have nothing more to delete
2424                         --  or if we hit a label (since someone could transfer
2425                         --  control to a label, so we should not delete it).
2426
2427                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2428
2429                         --  Statement/declaration is to be deleted
2430
2431                         Analyze (Nxt);
2432                         Remove (Nxt);
2433                         Kill_Dead_Code (Nxt);
2434                      end loop;
2435                   end if;
2436
2437                   --  Now issue the warning (or error in formal mode)
2438
2439                   if Formal_Verification_Mode then
2440                      Error_Msg
2441                        ("|~~unreachable code is not allowed", Error_Loc);
2442                   else
2443                      Error_Msg ("?unreachable code!", Error_Loc);
2444                   end if;
2445                end if;
2446
2447             --  If the unconditional transfer of control instruction is
2448             --  the last statement of a sequence, then see if our parent
2449             --  is one of the constructs for which we count unblocked exits,
2450             --  and if so, adjust the count.
2451
2452             else
2453                P := Parent (N);
2454
2455                --  Statements in THEN part or ELSE part of IF statement
2456
2457                if Nkind (P) = N_If_Statement then
2458                   null;
2459
2460                --  Statements in ELSIF part of an IF statement
2461
2462                elsif Nkind (P) = N_Elsif_Part then
2463                   P := Parent (P);
2464                   pragma Assert (Nkind (P) = N_If_Statement);
2465
2466                --  Statements in CASE statement alternative
2467
2468                elsif Nkind (P) = N_Case_Statement_Alternative then
2469                   P := Parent (P);
2470                   pragma Assert (Nkind (P) = N_Case_Statement);
2471
2472                --  Statements in body of block
2473
2474                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2475                  and then Nkind (Parent (P)) = N_Block_Statement
2476                then
2477                   null;
2478
2479                --  Statements in exception handler in a block
2480
2481                elsif Nkind (P) = N_Exception_Handler
2482                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2483                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2484                then
2485                   null;
2486
2487                --  None of these cases, so return
2488
2489                else
2490                   return;
2491                end if;
2492
2493                --  This was one of the cases we are looking for (i.e. the
2494                --  parent construct was IF, CASE or block) so decrement count.
2495
2496                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2497             end if;
2498          end;
2499       end if;
2500    end Check_Unreachable_Code;
2501
2502 end Sem_Ch5;