gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Checks;   use Checks;
  29 with Einfo;    use Einfo;
  30 with Errout;   use Errout;
  31 with Expander; use Expander;
  32 with Exp_Util; use Exp_Util;
  33 with Freeze;   use Freeze;
  34 with Lib.Xref; use Lib.Xref;
  35 with Nlists;   use Nlists;
  36 with Nmake;    use Nmake;
  37 with Opt;      use Opt;
  38 with Sem;      use Sem;
  39 with Sem_Case; use Sem_Case;
  40 with Sem_Ch3;  use Sem_Ch3;
  41 with Sem_Ch8;  use Sem_Ch8;
  42 with Sem_Disp; use Sem_Disp;
  43 with Sem_Eval; use Sem_Eval;
  44 with Sem_Res;  use Sem_Res;
  45 with Sem_Type; use Sem_Type;
  46 with Sem_Util; use Sem_Util;
  47 with Sem_Warn; use Sem_Warn;
  48 with Stand;    use Stand;
  49 with Sinfo;    use Sinfo;
  50 with Targparm; use Targparm;
  51 with Tbuild;   use Tbuild;
  52 with Uintp;    use Uintp;
  53
  54 package body Sem_Ch5 is
  55
  56    Unblocked_Exit_Count : Nat := 0;
  57    --  This variable is used when processing if statements, case statements,
  58    --  and block statements. It counts the number of exit points that are
  59    --  not blocked by unconditional transfer instructions (for IF and CASE,
  60    --  these are the branches of the conditional, for a block, they are the
  61    --  statement sequence of the block, and the statement sequences of any
  62    --  exception handlers that are part of the block. When processing is
  63    --  complete, if this count is zero, it means that control cannot fall
  64    --  through the IF, CASE or block statement. This is used for the
  65    --  generation of warning messages. This variable is recursively saved
  66    --  on entry to processing the construct, and restored on exit.
  67
  68    -----------------------
  69    -- Local Subprograms --
  70    -----------------------
  71
  72    procedure Analyze_Iteration_Scheme (N : Node_Id);
  73
  74    procedure Check_Possible_Current_Value_Condition (Cnode : Node_Id);
  75    --  Cnode is N_If_Statement, N_Elsif_Part, or N_Iteration_Scheme
  76    --  (the latter when a WHILE condition is present). This call checks
  77    --  if Condition (Cnode) is of the form ([NOT] var op val), where var
  78    --  is a simple object, val is known at compile time, and op is one
  79    --  of the six relational operators. If this is the case, and the
  80    --  Current_Value field of "var" is not set, then it is set to Cnode.
  81    --  See Exp_Util.Set_Current_Value_Condition for further details.
  82
  83    ------------------------
  84    -- Analyze_Assignment --
  85    ------------------------
  86
  87    procedure Analyze_Assignment (N : Node_Id) is
  88       Lhs  : constant Node_Id := Name (N);
  89       Rhs  : constant Node_Id := Expression (N);
  90       T1   : Entity_Id;
  91       T2   : Entity_Id;
  92       Decl : Node_Id;
  93       Ent  : Entity_Id;
  94
  95       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  96       --  N is the node for the left hand side of an assignment, and it
  97       --  is not a variable. This routine issues an appropriate diagnostic.
  98
  99       procedure Set_Assignment_Type
 100         (Opnd      : Node_Id;
 101          Opnd_Type : in out Entity_Id);
 102       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 103       --  is the nominal subtype. This procedure is used to deal with cases
 104       --  where the nominal subtype must be replaced by the actual subtype.
 105
 106       -------------------------------
 107       -- Diagnose_Non_Variable_Lhs --
 108       -------------------------------
 109
 110       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 111       begin
 112          --  Not worth posting another error if left hand side already
 113          --  flagged as being illegal in some respect
 114
 115          if Error_Posted (N) then
 116             return;
 117
 118          --  Some special bad cases of entity names
 119
 120          elsif Is_Entity_Name (N) then
 121             if Ekind (Entity (N)) = E_In_Parameter then
 122                Error_Msg_N
 123                  ("assignment to IN mode parameter not allowed", N);
 124
 125             --  Private declarations in a protected object are turned into
 126             --  constants when compiling a protected function.
 127
 128             elsif Present (Scope (Entity (N)))
 129               and then Is_Protected_Type (Scope (Entity (N)))
 130               and then
 131                 (Ekind (Current_Scope) = E_Function
 132                   or else
 133                  Ekind (Enclosing_Dynamic_Scope (Current_Scope)) = E_Function)
 134             then
 135                Error_Msg_N
 136                  ("protected function cannot modify protected object", N);
 137
 138             elsif Ekind (Entity (N)) = E_Loop_Parameter then
 139                Error_Msg_N
 140                  ("assignment to loop parameter not allowed", N);
 141
 142             else
 143                Error_Msg_N
 144                  ("left hand side of assignment must be a variable", N);
 145             end if;
 146
 147          --  For indexed components or selected components, test prefix
 148
 149          elsif Nkind (N) = N_Indexed_Component then
 150             Diagnose_Non_Variable_Lhs (Prefix (N));
 151
 152          --  Another special case for assignment to discriminant
 153
 154          elsif Nkind (N) = N_Selected_Component then
 155             if Present (Entity (Selector_Name (N)))
 156               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 157             then
 158                Error_Msg_N
 159                  ("assignment to discriminant not allowed", N);
 160             else
 161                Diagnose_Non_Variable_Lhs (Prefix (N));
 162             end if;
 163
 164          else
 165             --  If we fall through, we have no special message to issue!
 166
 167             Error_Msg_N ("left hand side of assignment must be a variable", N);
 168          end if;
 169       end Diagnose_Non_Variable_Lhs;
 170
 171       -------------------------
 172       -- Set_Assignment_Type --
 173       -------------------------
 174
 175       procedure Set_Assignment_Type
 176         (Opnd      : Node_Id;
 177          Opnd_Type : in out Entity_Id)
 178       is
 179       begin
 180          Require_Entity (Opnd);
 181
 182          --  If the assignment operand is an in-out or out parameter, then we
 183          --  get the actual subtype (needed for the unconstrained case).
 184          --  If the operand is the actual in an entry declaration, then within
 185          --  the accept statement it is replaced with a local renaming, which
 186          --  may also have an actual subtype.
 187
 188          if Is_Entity_Name (Opnd)
 189            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 190                       or else Ekind (Entity (Opnd)) =
 191                            E_In_Out_Parameter
 192                       or else Ekind (Entity (Opnd)) =
 193                            E_Generic_In_Out_Parameter
 194                       or else
 195                         (Ekind (Entity (Opnd)) = E_Variable
 196                           and then Nkind (Parent (Entity (Opnd))) =
 197                              N_Object_Renaming_Declaration
 198                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 199                              N_Accept_Statement))
 200          then
 201             Opnd_Type := Get_Actual_Subtype (Opnd);
 202
 203          --  If assignment operand is a component reference, then we get the
 204          --  actual subtype of the component for the unconstrained case.
 205
 206          elsif
 207            (Nkind (Opnd) = N_Selected_Component
 208              or else Nkind (Opnd) = N_Explicit_Dereference)
 209            and then not Is_Unchecked_Union (Opnd_Type)
 210          then
 211             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 212
 213             if Present (Decl) then
 214                Insert_Action (N, Decl);
 215                Mark_Rewrite_Insertion (Decl);
 216                Analyze (Decl);
 217                Opnd_Type := Defining_Identifier (Decl);
 218                Set_Etype (Opnd, Opnd_Type);
 219                Freeze_Itype (Opnd_Type, N);
 220
 221             elsif Is_Constrained (Etype (Opnd)) then
 222                Opnd_Type := Etype (Opnd);
 223             end if;
 224
 225          --  For slice, use the constrained subtype created for the slice
 226
 227          elsif Nkind (Opnd) = N_Slice then
 228             Opnd_Type := Etype (Opnd);
 229          end if;
 230       end Set_Assignment_Type;
 231
 232    --  Start of processing for Analyze_Assignment
 233
 234    begin
 235       Analyze (Rhs);
 236       Analyze (Lhs);
 237       T1 := Etype (Lhs);
 238
 239       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 240       --  must compute the intersection of the possible types on each side.
 241
 242       if Is_Overloaded (Lhs) then
 243          declare
 244             I  : Interp_Index;
 245             It : Interp;
 246
 247          begin
 248             T1 := Any_Type;
 249             Get_First_Interp (Lhs, I, It);
 250
 251             while Present (It.Typ) loop
 252                if Has_Compatible_Type (Rhs, It.Typ) then
 253                   if T1 /= Any_Type then
 254
 255                      --  An explicit dereference is overloaded if the prefix
 256                      --  is. Try to remove the ambiguity on the prefix, the
 257                      --  error will be posted there if the ambiguity is real.
 258
 259                      if Nkind (Lhs) = N_Explicit_Dereference then
 260                         declare
 261                            PI    : Interp_Index;
 262                            PI1   : Interp_Index := 0;
 263                            PIt   : Interp;
 264                            Found : Boolean;
 265
 266                         begin
 267                            Found := False;
 268                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 269
 270                            while Present (PIt.Typ) loop
 271                               if Is_Access_Type (PIt.Typ)
 272                                 and then Has_Compatible_Type
 273                                            (Rhs, Designated_Type (PIt.Typ))
 274                               then
 275                                  if Found then
 276                                     PIt :=
 277                                       Disambiguate (Prefix (Lhs),
 278                                         PI1, PI, Any_Type);
 279
 280                                     if PIt = No_Interp then
 281                                        Error_Msg_N
 282                                          ("ambiguous left-hand side"
 283                                             & " in assignment", Lhs);
 284                                        exit;
 285                                     else
 286                                        Resolve (Prefix (Lhs), PIt.Typ);
 287                                     end if;
 288
 289                                     exit;
 290                                  else
 291                                     Found := True;
 292                                     PI1 := PI;
 293                                  end if;
 294                               end if;
 295
 296                               Get_Next_Interp (PI, PIt);
 297                            end loop;
 298                         end;
 299
 300                      else
 301                         Error_Msg_N
 302                           ("ambiguous left-hand side in assignment", Lhs);
 303                         exit;
 304                      end if;
 305                   else
 306                      T1 := It.Typ;
 307                   end if;
 308                end if;
 309
 310                Get_Next_Interp (I, It);
 311             end loop;
 312          end;
 313
 314          if T1 = Any_Type then
 315             Error_Msg_N
 316               ("no valid types for left-hand side for assignment", Lhs);
 317             return;
 318          end if;
 319       end if;
 320
 321       Resolve (Lhs, T1);
 322
 323       if not Is_Variable (Lhs) then
 324          Diagnose_Non_Variable_Lhs (Lhs);
 325          return;
 326
 327       elsif Is_Limited_Type (T1)
 328         and then not Assignment_OK (Lhs)
 329         and then not Assignment_OK (Original_Node (Lhs))
 330       then
 331          Error_Msg_N
 332            ("left hand of assignment must not be limited type", Lhs);
 333          Explain_Limited_Type (T1, Lhs);
 334          return;
 335       end if;
 336
 337       --  Resolution may have updated the subtype, in case the left-hand
 338       --  side is a private protected component. Use the correct subtype
 339       --  to avoid scoping issues in the back-end.
 340
 341       T1 := Etype (Lhs);
 342
 343       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 344       --  type. For example:
 345
 346       --    limited with P;
 347       --    package Pkg is
 348       --      type Acc is access P.T;
 349       --    end Pkg;
 350
 351       --    with Pkg; use Acc;
 352       --    procedure Example is
 353       --       A, B : Acc;
 354       --    begin
 355       --       A.all := B.all;  -- ERROR
 356       --    end Example;
 357
 358       if Nkind (Lhs) = N_Explicit_Dereference
 359         and then Ekind (T1) = E_Incomplete_Type
 360       then
 361          Error_Msg_N ("invalid use of incomplete type", Lhs);
 362          return;
 363       end if;
 364
 365       Set_Assignment_Type (Lhs, T1);
 366
 367       Resolve (Rhs, T1);
 368       Check_Unset_Reference (Rhs);
 369
 370       --  Remaining steps are skipped if Rhs was syntactically in error
 371
 372       if Rhs = Error then
 373          return;
 374       end if;
 375
 376       T2 := Etype (Rhs);
 377
 378       if Covers (T1, T2) then
 379          null;
 380       else
 381          Wrong_Type (Rhs, Etype (Lhs));
 382          return;
 383       end if;
 384
 385       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 386       --  types, use the non-limited view if available
 387
 388       if Nkind (Rhs) = N_Explicit_Dereference
 389         and then Ekind (T2) = E_Incomplete_Type
 390         and then Is_Tagged_Type (T2)
 391         and then Present (Non_Limited_View (T2))
 392       then
 393          T2 := Non_Limited_View (T2);
 394       end if;
 395
 396       Set_Assignment_Type (Rhs, T2);
 397
 398       if Total_Errors_Detected /= 0 then
 399          if No (T1) then
 400             T1 := Any_Type;
 401          end if;
 402
 403          if No (T2) then
 404             T2 := Any_Type;
 405          end if;
 406       end if;
 407
 408       if T1 = Any_Type or else T2 = Any_Type then
 409          return;
 410       end if;
 411
 412       if (Is_Class_Wide_Type (T2) or else Is_Dynamically_Tagged (Rhs))
 413         and then not Is_Class_Wide_Type (T1)
 414       then
 415          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 416
 417       elsif Is_Class_Wide_Type (T1)
 418         and then not Is_Class_Wide_Type (T2)
 419         and then not Is_Tag_Indeterminate (Rhs)
 420         and then not Is_Dynamically_Tagged (Rhs)
 421       then
 422          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 423       end if;
 424
 425       --  Tag propagation is done only in semantics mode only. If expansion
 426       --  is on, the rhs tag indeterminate function call has been expanded
 427       --  and tag propagation would have happened too late, so the
 428       --  propagation take place in expand_call instead.
 429
 430       if not Expander_Active
 431         and then Is_Class_Wide_Type (T1)
 432         and then Is_Tag_Indeterminate (Rhs)
 433       then
 434          Propagate_Tag (Lhs, Rhs);
 435       end if;
 436
 437       --  Ada 2005 (AI-230 and AI-385): When the lhs type is an anonymous
 438       --  access type, apply an implicit conversion of the rhs to that type
 439       --  to force appropriate static and run-time accessibility checks.
 440
 441       if Ada_Version >= Ada_05
 442         and then Ekind (T1) = E_Anonymous_Access_Type
 443       then
 444          Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 445          Analyze_And_Resolve (Rhs, T1);
 446       end if;
 447
 448       --  Ada 2005 (AI-231)
 449
 450       if Ada_Version >= Ada_05
 451         and then Nkind (Rhs) = N_Null
 452         and then Is_Access_Type (T1)
 453         and then not Assignment_OK (Lhs)
 454         and then ((Is_Entity_Name (Lhs)
 455                      and then Can_Never_Be_Null (Entity (Lhs)))
 456                    or else Can_Never_Be_Null (Etype (Lhs)))
 457       then
 458          Apply_Compile_Time_Constraint_Error
 459            (N      => Lhs,
 460             Msg    => "(Ada 2005) NULL not allowed in null-excluding objects?",
 461             Reason => CE_Null_Not_Allowed);
 462       end if;
 463
 464       if Is_Scalar_Type (T1) then
 465          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 466
 467       elsif Is_Array_Type (T1)
 468         and then
 469           (Nkind (Rhs) /= N_Type_Conversion
 470              or else Is_Constrained (Etype (Rhs)))
 471       then
 472          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 473          --  but of course the indices do not have to match. If the right-hand
 474          --  side is a type conversion to an unconstrained type, a length check
 475          --  is performed on the expression itself during expansion. In rare
 476          --  cases, the redundant length check is computed on an index type
 477          --  with a different representation, triggering incorrect code in
 478          --  the back end.
 479
 480          Apply_Length_Check (Rhs, Etype (Lhs));
 481
 482       else
 483          --  Discriminant checks are applied in the course of expansion
 484
 485          null;
 486       end if;
 487
 488       --  Note: modifications of the Lhs may only be recorded after
 489       --  checks have been applied.
 490
 491       Note_Possible_Modification (Lhs);
 492
 493       --  ??? a real accessibility check is needed when ???
 494
 495       --  Post warning for useless assignment
 496
 497       if Warn_On_Redundant_Constructs
 498
 499          --  We only warn for source constructs
 500
 501          and then Comes_From_Source (N)
 502
 503          --  Where the entity is the same on both sides
 504
 505          and then Is_Entity_Name (Lhs)
 506          and then Is_Entity_Name (Original_Node (Rhs))
 507          and then Entity (Lhs) = Entity (Original_Node (Rhs))
 508
 509          --  But exclude the case where the right side was an operation
 510          --  that got rewritten (e.g. JUNK + K, where K was known to be
 511          --  zero). We don't want to warn in such a case, since it is
 512          --  reasonable to write such expressions especially when K is
 513          --  defined symbolically in some other package.
 514
 515         and then Nkind (Original_Node (Rhs)) not in N_Op
 516       then
 517          Error_Msg_NE
 518            ("?useless assignment of & to itself", N, Entity (Lhs));
 519       end if;
 520
 521       --  Check for non-allowed composite assignment
 522
 523       if not Support_Composite_Assign_On_Target
 524         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 525         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 526       then
 527          Error_Msg_CRT ("composite assignment", N);
 528       end if;
 529
 530       --  One more step. Let's see if we have a simple assignment of a
 531       --  known at compile time value to a simple variable. If so, we
 532       --  can record the value as the current value providing that:
 533
 534       --    We still have a simple assignment statement (no expansion
 535       --    activity has modified it in some peculiar manner)
 536
 537       --    The type is a discrete type
 538
 539       --    The assignment is to a named entity
 540
 541       --    The value is known at compile time
 542
 543       if Nkind (N) /= N_Assignment_Statement
 544         or else not Is_Discrete_Type (T1)
 545         or else not Is_Entity_Name (Lhs)
 546         or else not Compile_Time_Known_Value (Rhs)
 547       then
 548          return;
 549       end if;
 550
 551       Ent := Entity (Lhs);
 552
 553       --  Capture value if save to do so
 554
 555       if Safe_To_Capture_Value (N, Ent) then
 556          Set_Current_Value (Ent, Rhs);
 557       end if;
 558    end Analyze_Assignment;
 559
 560    -----------------------------
 561    -- Analyze_Block_Statement --
 562    -----------------------------
 563
 564    procedure Analyze_Block_Statement (N : Node_Id) is
 565       Decls : constant List_Id := Declarations (N);
 566       Id    : constant Node_Id := Identifier (N);
 567       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 568
 569    begin
 570       --  If no handled statement sequence is present, things are really
 571       --  messed up, and we just return immediately (this is a defence
 572       --  against previous errors).
 573
 574       if No (HSS) then
 575          return;
 576       end if;
 577
 578       --  Normal processing with HSS present
 579
 580       declare
 581          EH  : constant List_Id := Exception_Handlers (HSS);
 582          Ent : Entity_Id        := Empty;
 583          S   : Entity_Id;
 584
 585          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 586          --  Recursively save value of this global, will be restored on exit
 587
 588       begin
 589          --  Initialize unblocked exit count for statements of begin block
 590          --  plus one for each excption handler that is present.
 591
 592          Unblocked_Exit_Count := 1;
 593
 594          if Present (EH) then
 595             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 596          end if;
 597
 598          --  If a label is present analyze it and mark it as referenced
 599
 600          if Present (Id) then
 601             Analyze (Id);
 602             Ent := Entity (Id);
 603
 604             --  An error defense. If we have an identifier, but no entity,
 605             --  then something is wrong. If we have previous errors, then
 606             --  just remove the identifier and continue, otherwise raise
 607             --  an exception.
 608
 609             if No (Ent) then
 610                if Total_Errors_Detected /= 0 then
 611                   Set_Identifier (N, Empty);
 612                else
 613                   raise Program_Error;
 614                end if;
 615
 616             else
 617                Set_Ekind (Ent, E_Block);
 618                Generate_Reference (Ent, N, ' ');
 619                Generate_Definition (Ent);
 620
 621                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 622                   Set_Label_Construct (Parent (Ent), N);
 623                end if;
 624             end if;
 625          end if;
 626
 627          --  If no entity set, create a label entity
 628
 629          if No (Ent) then
 630             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 631             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 632             Set_Parent (Ent, N);
 633          end if;
 634
 635          Set_Etype (Ent, Standard_Void_Type);
 636          Set_Block_Node (Ent, Identifier (N));
 637          New_Scope (Ent);
 638
 639          if Present (Decls) then
 640             Analyze_Declarations (Decls);
 641             Check_Completion;
 642          end if;
 643
 644          Analyze (HSS);
 645          Process_End_Label (HSS, 'e', Ent);
 646
 647          --  If exception handlers are present, then we indicate that
 648          --  enclosing scopes contain a block with handlers. We only
 649          --  need to mark non-generic scopes.
 650
 651          if Present (EH) then
 652             S := Scope (Ent);
 653             loop
 654                Set_Has_Nested_Block_With_Handler (S);
 655                exit when Is_Overloadable (S)
 656                  or else Ekind (S) = E_Package
 657                  or else Is_Generic_Unit (S);
 658                S := Scope (S);
 659             end loop;
 660          end if;
 661
 662          Check_References (Ent);
 663          End_Scope;
 664
 665          if Unblocked_Exit_Count = 0 then
 666             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 667             Check_Unreachable_Code (N);
 668          else
 669             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 670          end if;
 671       end;
 672    end Analyze_Block_Statement;
 673
 674    ----------------------------
 675    -- Analyze_Case_Statement --
 676    ----------------------------
 677
 678    procedure Analyze_Case_Statement (N : Node_Id) is
 679       Exp            : Node_Id;
 680       Exp_Type       : Entity_Id;
 681       Exp_Btype      : Entity_Id;
 682       Last_Choice    : Nat;
 683       Dont_Care      : Boolean;
 684       Others_Present : Boolean;
 685
 686       Statements_Analyzed : Boolean := False;
 687       --  Set True if at least some statement sequences get analyzed.
 688       --  If False on exit, means we had a serious error that prevented
 689       --  full analysis of the case statement, and as a result it is not
 690       --  a good idea to output warning messages about unreachable code.
 691
 692       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 693       --  Recursively save value of this global, will be restored on exit
 694
 695       procedure Non_Static_Choice_Error (Choice : Node_Id);
 696       --  Error routine invoked by the generic instantiation below when
 697       --  the case statment has a non static choice.
 698
 699       procedure Process_Statements (Alternative : Node_Id);
 700       --  Analyzes all the statements associated to a case alternative.
 701       --  Needed by the generic instantiation below.
 702
 703       package Case_Choices_Processing is new
 704         Generic_Choices_Processing
 705           (Get_Alternatives          => Alternatives,
 706            Get_Choices               => Discrete_Choices,
 707            Process_Empty_Choice      => No_OP,
 708            Process_Non_Static_Choice => Non_Static_Choice_Error,
 709            Process_Associated_Node   => Process_Statements);
 710       use Case_Choices_Processing;
 711       --  Instantiation of the generic choice processing package
 712
 713       -----------------------------
 714       -- Non_Static_Choice_Error --
 715       -----------------------------
 716
 717       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 718       begin
 719          Flag_Non_Static_Expr
 720            ("choice given in case statement is not static!", Choice);
 721       end Non_Static_Choice_Error;
 722
 723       ------------------------
 724       -- Process_Statements --
 725       ------------------------
 726
 727       procedure Process_Statements (Alternative : Node_Id) is
 728          Choices : constant List_Id := Discrete_Choices (Alternative);
 729          Ent     : Entity_Id;
 730
 731       begin
 732          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 733          Statements_Analyzed := True;
 734
 735          --  An interesting optimization. If the case statement expression
 736          --  is a simple entity, then we can set the current value within
 737          --  an alternative if the alternative has one possible value.
 738
 739          --    case N is
 740          --      when 1      => alpha
 741          --      when 2 | 3  => beta
 742          --      when others => gamma
 743
 744          --  Here we know that N is initially 1 within alpha, but for beta
 745          --  and gamma, we do not know anything more about the initial value.
 746
 747          if Is_Entity_Name (Exp) then
 748             Ent := Entity (Exp);
 749
 750             if Ekind (Ent) = E_Variable
 751                  or else
 752                Ekind (Ent) = E_In_Out_Parameter
 753                  or else
 754                Ekind (Ent) = E_Out_Parameter
 755             then
 756                if List_Length (Choices) = 1
 757                  and then Nkind (First (Choices)) in N_Subexpr
 758                  and then Compile_Time_Known_Value (First (Choices))
 759                then
 760                   Set_Current_Value (Entity (Exp), First (Choices));
 761                end if;
 762
 763                Analyze_Statements (Statements (Alternative));
 764
 765                --  After analyzing the case, set the current value to empty
 766                --  since we won't know what it is for the next alternative
 767                --  (unless reset by this same circuit), or after the case.
 768
 769                Set_Current_Value (Entity (Exp), Empty);
 770                return;
 771             end if;
 772          end if;
 773
 774          --  Case where expression is not an entity name of a variable
 775
 776          Analyze_Statements (Statements (Alternative));
 777       end Process_Statements;
 778
 779       --  Table to record choices. Put after subprograms since we make
 780       --  a call to Number_Of_Choices to get the right number of entries.
 781
 782       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
 783
 784    --  Start of processing for Analyze_Case_Statement
 785
 786    begin
 787       Unblocked_Exit_Count := 0;
 788       Exp := Expression (N);
 789       Analyze (Exp);
 790
 791       --  The expression must be of any discrete type. In rare cases, the
 792       --  expander constructs a case statement whose expression has a private
 793       --  type whose full view is discrete. This can happen when generating
 794       --  a stream operation for a variant type after the type is frozen,
 795       --  when the partial of view of the type of the discriminant is private.
 796       --  In that case, use the full view to analyze case alternatives.
 797
 798       if not Is_Overloaded (Exp)
 799         and then not Comes_From_Source (N)
 800         and then Is_Private_Type (Etype (Exp))
 801         and then Present (Full_View (Etype (Exp)))
 802         and then Is_Discrete_Type (Full_View (Etype (Exp)))
 803       then
 804          Resolve (Exp, Etype (Exp));
 805          Exp_Type := Full_View (Etype (Exp));
 806
 807       else
 808          Analyze_And_Resolve (Exp, Any_Discrete);
 809          Exp_Type := Etype (Exp);
 810       end if;
 811
 812       Check_Unset_Reference (Exp);
 813       Exp_Btype := Base_Type (Exp_Type);
 814
 815       --  The expression must be of a discrete type which must be determinable
 816       --  independently of the context in which the expression occurs, but
 817       --  using the fact that the expression must be of a discrete type.
 818       --  Moreover, the type this expression must not be a character literal
 819       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
 820
 821       --  If error already reported by Resolve, nothing more to do
 822
 823       if Exp_Btype = Any_Discrete
 824         or else Exp_Btype = Any_Type
 825       then
 826          return;
 827
 828       elsif Exp_Btype = Any_Character then
 829          Error_Msg_N
 830            ("character literal as case expression is ambiguous", Exp);
 831          return;
 832
 833       elsif Ada_Version = Ada_83
 834         and then (Is_Generic_Type (Exp_Btype)
 835                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
 836       then
 837          Error_Msg_N
 838            ("(Ada 83) case expression cannot be of a generic type", Exp);
 839          return;
 840       end if;
 841
 842       --  If the case expression is a formal object of mode in out, then
 843       --  treat it as having a nonstatic subtype by forcing use of the base
 844       --  type (which has to get passed to Check_Case_Choices below).  Also
 845       --  use base type when the case expression is parenthesized.
 846
 847       if Paren_Count (Exp) > 0
 848         or else (Is_Entity_Name (Exp)
 849                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
 850       then
 851          Exp_Type := Exp_Btype;
 852       end if;
 853
 854       --  Call instantiated Analyze_Choices which does the rest of the work
 855
 856       Analyze_Choices
 857         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
 858
 859       if Exp_Type = Universal_Integer and then not Others_Present then
 860          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
 861       end if;
 862
 863       --  If all our exits were blocked by unconditional transfers of control,
 864       --  then the entire CASE statement acts as an unconditional transfer of
 865       --  control, so treat it like one, and check unreachable code. Skip this
 866       --  test if we had serious errors preventing any statement analysis.
 867
 868       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
 869          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 870          Check_Unreachable_Code (N);
 871       else
 872          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 873       end if;
 874
 875       if not Expander_Active
 876         and then Compile_Time_Known_Value (Expression (N))
 877         and then Serious_Errors_Detected = 0
 878       then
 879          declare
 880             Chosen : constant Node_Id := Find_Static_Alternative (N);
 881             Alt    : Node_Id;
 882
 883          begin
 884             Alt := First (Alternatives (N));
 885
 886             while Present (Alt) loop
 887                if Alt /= Chosen then
 888                   Remove_Warning_Messages (Statements (Alt));
 889                end if;
 890
 891                Next (Alt);
 892             end loop;
 893          end;
 894       end if;
 895    end Analyze_Case_Statement;
 896
 897    ----------------------------
 898    -- Analyze_Exit_Statement --
 899    ----------------------------
 900
 901    --  If the exit includes a name, it must be the name of a currently open
 902    --  loop. Otherwise there must be an innermost open loop on the stack,
 903    --  to which the statement implicitly refers.
 904
 905    procedure Analyze_Exit_Statement (N : Node_Id) is
 906       Target   : constant Node_Id := Name (N);
 907       Cond     : constant Node_Id := Condition (N);
 908       Scope_Id : Entity_Id;
 909       U_Name   : Entity_Id;
 910       Kind     : Entity_Kind;
 911
 912    begin
 913       if No (Cond) then
 914          Check_Unreachable_Code (N);
 915       end if;
 916
 917       if Present (Target) then
 918          Analyze (Target);
 919          U_Name := Entity (Target);
 920
 921          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
 922             Error_Msg_N ("invalid loop name in exit statement", N);
 923             return;
 924          else
 925             Set_Has_Exit (U_Name);
 926          end if;
 927
 928       else
 929          U_Name := Empty;
 930       end if;
 931
 932       for J in reverse 0 .. Scope_Stack.Last loop
 933          Scope_Id := Scope_Stack.Table (J).Entity;
 934          Kind := Ekind (Scope_Id);
 935
 936          if Kind = E_Loop
 937            and then (No (Target) or else Scope_Id = U_Name) then
 938             Set_Has_Exit (Scope_Id);
 939             exit;
 940
 941          elsif Kind = E_Block or else Kind = E_Loop then
 942             null;
 943
 944          else
 945             Error_Msg_N
 946               ("cannot exit from program unit or accept statement", N);
 947             exit;
 948          end if;
 949       end loop;
 950
 951       --  Verify that if present the condition is a Boolean expression
 952
 953       if Present (Cond) then
 954          Analyze_And_Resolve (Cond, Any_Boolean);
 955          Check_Unset_Reference (Cond);
 956       end if;
 957    end Analyze_Exit_Statement;
 958
 959    ----------------------------
 960    -- Analyze_Goto_Statement --
 961    ----------------------------
 962
 963    procedure Analyze_Goto_Statement (N : Node_Id) is
 964       Label       : constant Node_Id := Name (N);
 965       Scope_Id    : Entity_Id;
 966       Label_Scope : Entity_Id;
 967
 968    begin
 969       Check_Unreachable_Code (N);
 970
 971       Analyze (Label);
 972
 973       if Entity (Label) = Any_Id then
 974          return;
 975
 976       elsif Ekind (Entity (Label)) /= E_Label then
 977          Error_Msg_N ("target of goto statement must be a label", Label);
 978          return;
 979
 980       elsif not Reachable (Entity (Label)) then
 981          Error_Msg_N ("target of goto statement is not reachable", Label);
 982          return;
 983       end if;
 984
 985       Label_Scope := Enclosing_Scope (Entity (Label));
 986
 987       for J in reverse 0 .. Scope_Stack.Last loop
 988          Scope_Id := Scope_Stack.Table (J).Entity;
 989
 990          if Label_Scope = Scope_Id
 991            or else (Ekind (Scope_Id) /= E_Block
 992                      and then Ekind (Scope_Id) /= E_Loop)
 993          then
 994             if Scope_Id /= Label_Scope then
 995                Error_Msg_N
 996                  ("cannot exit from program unit or accept statement", N);
 997             end if;
 998
 999             return;
1000          end if;
1001       end loop;
1002
1003       raise Program_Error;
1004    end Analyze_Goto_Statement;
1005
1006    --------------------------
1007    -- Analyze_If_Statement --
1008    --------------------------
1009
1010    --  A special complication arises in the analysis of if statements
1011
1012    --  The expander has circuitry to completely delete code that it
1013    --  can tell will not be executed (as a result of compile time known
1014    --  conditions). In the analyzer, we ensure that code that will be
1015    --  deleted in this manner is analyzed but not expanded. This is
1016    --  obviously more efficient, but more significantly, difficulties
1017    --  arise if code is expanded and then eliminated (e.g. exception
1018    --  table entries disappear). Similarly, itypes generated in deleted
1019    --  code must be frozen from start, because the nodes on which they
1020    --  depend will not be available at the freeze point.
1021
1022    procedure Analyze_If_Statement (N : Node_Id) is
1023       E : Node_Id;
1024
1025       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1026       --  Recursively save value of this global, will be restored on exit
1027
1028       Save_In_Deleted_Code : Boolean;
1029
1030       Del : Boolean := False;
1031       --  This flag gets set True if a True condition has been found,
1032       --  which means that remaining ELSE/ELSIF parts are deleted.
1033
1034       procedure Analyze_Cond_Then (Cnode : Node_Id);
1035       --  This is applied to either the N_If_Statement node itself or
1036       --  to an N_Elsif_Part node. It deals with analyzing the condition
1037       --  and the THEN statements associated with it.
1038
1039       -----------------------
1040       -- Analyze_Cond_Then --
1041       -----------------------
1042
1043       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1044          Cond : constant Node_Id := Condition (Cnode);
1045          Tstm : constant List_Id := Then_Statements (Cnode);
1046
1047       begin
1048          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1049          Analyze_And_Resolve (Cond, Any_Boolean);
1050          Check_Unset_Reference (Cond);
1051          Check_Possible_Current_Value_Condition (Cnode);
1052
1053          --  If already deleting, then just analyze then statements
1054
1055          if Del then
1056             Analyze_Statements (Tstm);
1057
1058          --  Compile time known value, not deleting yet
1059
1060          elsif Compile_Time_Known_Value (Cond) then
1061             Save_In_Deleted_Code := In_Deleted_Code;
1062
1063             --  If condition is True, then analyze the THEN statements
1064             --  and set no expansion for ELSE and ELSIF parts.
1065
1066             if Is_True (Expr_Value (Cond)) then
1067                Analyze_Statements (Tstm);
1068                Del := True;
1069                Expander_Mode_Save_And_Set (False);
1070                In_Deleted_Code := True;
1071
1072             --  If condition is False, analyze THEN with expansion off
1073
1074             else -- Is_False (Expr_Value (Cond))
1075                Expander_Mode_Save_And_Set (False);
1076                In_Deleted_Code := True;
1077                Analyze_Statements (Tstm);
1078                Expander_Mode_Restore;
1079                In_Deleted_Code := Save_In_Deleted_Code;
1080             end if;
1081
1082          --  Not known at compile time, not deleting, normal analysis
1083
1084          else
1085             Analyze_Statements (Tstm);
1086          end if;
1087       end Analyze_Cond_Then;
1088
1089    --  Start of Analyze_If_Statement
1090
1091    begin
1092       --  Initialize exit count for else statements. If there is no else
1093       --  part, this count will stay non-zero reflecting the fact that the
1094       --  uncovered else case is an unblocked exit.
1095
1096       Unblocked_Exit_Count := 1;
1097       Analyze_Cond_Then (N);
1098
1099       --  Now to analyze the elsif parts if any are present
1100
1101       if Present (Elsif_Parts (N)) then
1102          E := First (Elsif_Parts (N));
1103          while Present (E) loop
1104             Analyze_Cond_Then (E);
1105             Next (E);
1106          end loop;
1107       end if;
1108
1109       if Present (Else_Statements (N)) then
1110          Analyze_Statements (Else_Statements (N));
1111       end if;
1112
1113       --  If all our exits were blocked by unconditional transfers of control,
1114       --  then the entire IF statement acts as an unconditional transfer of
1115       --  control, so treat it like one, and check unreachable code.
1116
1117       if Unblocked_Exit_Count = 0 then
1118          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1119          Check_Unreachable_Code (N);
1120       else
1121          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1122       end if;
1123
1124       if Del then
1125          Expander_Mode_Restore;
1126          In_Deleted_Code := Save_In_Deleted_Code;
1127       end if;
1128
1129       if not Expander_Active
1130         and then Compile_Time_Known_Value (Condition (N))
1131         and then Serious_Errors_Detected = 0
1132       then
1133          if Is_True (Expr_Value (Condition (N))) then
1134             Remove_Warning_Messages (Else_Statements (N));
1135
1136             if Present (Elsif_Parts (N)) then
1137                E := First (Elsif_Parts (N));
1138
1139                while Present (E) loop
1140                   Remove_Warning_Messages (Then_Statements (E));
1141                   Next (E);
1142                end loop;
1143             end if;
1144
1145          else
1146             Remove_Warning_Messages (Then_Statements (N));
1147          end if;
1148       end if;
1149    end Analyze_If_Statement;
1150
1151    ----------------------------------------
1152    -- Analyze_Implicit_Label_Declaration --
1153    ----------------------------------------
1154
1155    --  An implicit label declaration is generated in the innermost
1156    --  enclosing declarative part. This is done for labels as well as
1157    --  block and loop names.
1158
1159    --  Note: any changes in this routine may need to be reflected in
1160    --  Analyze_Label_Entity.
1161
1162    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1163       Id : constant Node_Id := Defining_Identifier (N);
1164    begin
1165       Enter_Name          (Id);
1166       Set_Ekind           (Id, E_Label);
1167       Set_Etype           (Id, Standard_Void_Type);
1168       Set_Enclosing_Scope (Id, Current_Scope);
1169    end Analyze_Implicit_Label_Declaration;
1170
1171    ------------------------------
1172    -- Analyze_Iteration_Scheme --
1173    ------------------------------
1174
1175    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1176
1177       procedure Process_Bounds (R : Node_Id);
1178       --  If the iteration is given by a range, create temporaries and
1179       --  assignment statements block to capture the bounds and perform
1180       --  required finalization actions in case a bound includes a function
1181       --  call that uses the temporary stack. We first pre-analyze a copy of
1182       --  the range in order to determine the expected type, and analyze and
1183       --  resolve the original bounds.
1184
1185       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1186       --  If the bounds are given by a 'Range reference on a function call
1187       --  that returns a controlled array, introduce an explicit declaration
1188       --  to capture the bounds, so that the function result can be finalized
1189       --  in timely fashion.
1190
1191       --------------------
1192       -- Process_Bounds --
1193       --------------------
1194
1195       procedure Process_Bounds (R : Node_Id) is
1196          Loc          : constant Source_Ptr := Sloc (N);
1197          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1198          Lo           : constant Node_Id := Low_Bound  (R);
1199          Hi           : constant Node_Id := High_Bound (R);
1200          New_Lo_Bound : Node_Id := Empty;
1201          New_Hi_Bound : Node_Id := Empty;
1202          Typ          : Entity_Id;
1203
1204          function One_Bound
1205            (Original_Bound : Node_Id;
1206             Analyzed_Bound : Node_Id) return Node_Id;
1207          --  Create one declaration followed by one assignment statement
1208          --  to capture the value of bound. We create a separate assignment
1209          --  in order to force the creation of a block in case the bound
1210          --  contains a call that uses the secondary stack.
1211
1212          ---------------
1213          -- One_Bound --
1214          ---------------
1215
1216          function One_Bound
1217            (Original_Bound : Node_Id;
1218             Analyzed_Bound : Node_Id) return Node_Id
1219          is
1220             Assign : Node_Id;
1221             Id     : Entity_Id;
1222             Decl   : Node_Id;
1223
1224          begin
1225             --  If the bound is a constant or an object, no need for a separate
1226             --  declaration. If the bound is the result of previous expansion
1227             --  it is already analyzed and should not be modified. Note that
1228             --  the Bound will be resolved later, if needed, as part of the
1229             --  call to Make_Index (literal bounds may need to be resolved to
1230             --  type Integer).
1231
1232             if Analyzed (Original_Bound) then
1233                return Original_Bound;
1234
1235             elsif Nkind (Analyzed_Bound) = N_Integer_Literal
1236               or else Is_Entity_Name (Analyzed_Bound)
1237             then
1238                Analyze_And_Resolve (Original_Bound, Typ);
1239                return Original_Bound;
1240
1241             else
1242                Analyze_And_Resolve (Original_Bound, Typ);
1243             end if;
1244
1245             Id :=
1246               Make_Defining_Identifier (Loc,
1247                 Chars => New_Internal_Name ('S'));
1248
1249             Decl :=
1250               Make_Object_Declaration (Loc,
1251                 Defining_Identifier => Id,
1252                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1253
1254             Insert_Before (Parent (N), Decl);
1255             Analyze (Decl);
1256
1257             Assign :=
1258               Make_Assignment_Statement (Loc,
1259                 Name        => New_Occurrence_Of (Id, Loc),
1260                 Expression  => Relocate_Node (Original_Bound));
1261
1262             Insert_Before (Parent (N), Assign);
1263             Analyze (Assign);
1264
1265             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1266
1267             if Nkind (Assign) = N_Assignment_Statement then
1268                return Expression (Assign);
1269             else
1270                return Original_Bound;
1271             end if;
1272          end One_Bound;
1273
1274       --  Start of processing for Process_Bounds
1275
1276       begin
1277          --  Determine expected type of range by analyzing separate copy.
1278
1279          Set_Parent (R_Copy, Parent (R));
1280          Pre_Analyze_And_Resolve (R_Copy);
1281          Typ := Etype (R_Copy);
1282
1283          --  If the type of the discrete range is Universal_Integer, then
1284          --  the bound's type must be resolved to Integer, and any object
1285          --  used to hold the bound must also have type Integer.
1286
1287          if Typ = Universal_Integer then
1288             Typ := Standard_Integer;
1289          end if;
1290
1291          Set_Etype (R, Typ);
1292
1293          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1294          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1295
1296          --  Propagate staticness to loop range itself, in case the
1297          --  corresponding subtype is static.
1298
1299          if New_Lo_Bound /= Lo
1300            and then Is_Static_Expression (New_Lo_Bound)
1301          then
1302             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1303          end if;
1304
1305          if New_Hi_Bound /= Hi
1306            and then Is_Static_Expression (New_Hi_Bound)
1307          then
1308             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1309          end if;
1310       end Process_Bounds;
1311
1312       --------------------------------------
1313       -- Check_Controlled_Array_Attribute --
1314       --------------------------------------
1315
1316       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1317       begin
1318          if Nkind (DS) = N_Attribute_Reference
1319             and then Is_Entity_Name (Prefix (DS))
1320             and then Ekind (Entity (Prefix (DS))) = E_Function
1321             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1322             and then
1323               Is_Controlled (
1324                 Component_Type (Etype (Entity (Prefix (DS)))))
1325             and then Expander_Active
1326          then
1327             declare
1328                Loc  : constant Source_Ptr := Sloc (N);
1329                Arr  : constant Entity_Id :=
1330                         Etype (Entity (Prefix (DS)));
1331                Indx : constant Entity_Id :=
1332                         Base_Type (Etype (First_Index (Arr)));
1333                Subt : constant Entity_Id :=
1334                         Make_Defining_Identifier
1335                           (Loc, New_Internal_Name ('S'));
1336                Decl : Node_Id;
1337
1338             begin
1339                Decl :=
1340                  Make_Subtype_Declaration (Loc,
1341                    Defining_Identifier => Subt,
1342                    Subtype_Indication  =>
1343                       Make_Subtype_Indication (Loc,
1344                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1345                         Constraint =>
1346                           Make_Range_Constraint (Loc,
1347                             Relocate_Node (DS))));
1348                Insert_Before (Parent (N), Decl);
1349                Analyze (Decl);
1350
1351                Rewrite (DS,
1352                   Make_Attribute_Reference (Loc,
1353                     Prefix => New_Reference_To (Subt, Loc),
1354                     Attribute_Name => Attribute_Name (DS)));
1355                Analyze (DS);
1356             end;
1357          end if;
1358       end Check_Controlled_Array_Attribute;
1359
1360    --  Start of processing for Analyze_Iteration_Scheme
1361
1362    begin
1363       --  For an infinite loop, there is no iteration scheme
1364
1365       if No (N) then
1366          return;
1367
1368       else
1369          declare
1370             Cond : constant Node_Id := Condition (N);
1371
1372          begin
1373             --  For WHILE loop, verify that the condition is a Boolean
1374             --  expression and resolve and check it.
1375
1376             if Present (Cond) then
1377                Analyze_And_Resolve (Cond, Any_Boolean);
1378                Check_Unset_Reference (Cond);
1379
1380             --  Else we have a FOR loop
1381
1382             else
1383                declare
1384                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1385                   Id : constant Entity_Id := Defining_Identifier (LP);
1386                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1387
1388                begin
1389                   Enter_Name (Id);
1390
1391                   --  We always consider the loop variable to be referenced,
1392                   --  since the loop may be used just for counting purposes.
1393
1394                   Generate_Reference (Id, N, ' ');
1395
1396                   --  Check for case of loop variable hiding a local
1397                   --  variable (used later on to give a nice warning
1398                   --  if the hidden variable is never assigned).
1399
1400                   declare
1401                      H : constant Entity_Id := Homonym (Id);
1402                   begin
1403                      if Present (H)
1404                        and then Enclosing_Dynamic_Scope (H) =
1405                                 Enclosing_Dynamic_Scope (Id)
1406                        and then Ekind (H) = E_Variable
1407                        and then Is_Discrete_Type (Etype (H))
1408                      then
1409                         Set_Hiding_Loop_Variable (H, Id);
1410                      end if;
1411                   end;
1412
1413                   --  Now analyze the subtype definition. If it is
1414                   --  a range, create temporaries for bounds.
1415
1416                   if Nkind (DS) = N_Range
1417                     and then Expander_Active
1418                   then
1419                      Process_Bounds (DS);
1420                   else
1421                      Analyze (DS);
1422                   end if;
1423
1424                   if DS = Error then
1425                      return;
1426                   end if;
1427
1428                   --  The subtype indication may denote the completion
1429                   --  of an incomplete type declaration.
1430
1431                   if Is_Entity_Name (DS)
1432                     and then Present (Entity (DS))
1433                     and then Is_Type (Entity (DS))
1434                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1435                   then
1436                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1437                      Set_Etype  (DS, Entity (DS));
1438                   end if;
1439
1440                   if not Is_Discrete_Type (Etype (DS)) then
1441                      Wrong_Type (DS, Any_Discrete);
1442                      Set_Etype (DS, Any_Type);
1443                   end if;
1444
1445                   Check_Controlled_Array_Attribute (DS);
1446
1447                   Make_Index (DS, LP);
1448
1449                   Set_Ekind          (Id, E_Loop_Parameter);
1450                   Set_Etype          (Id, Etype (DS));
1451                   Set_Is_Known_Valid (Id, True);
1452
1453                   --  The loop is not a declarative part, so the only entity
1454                   --  declared "within" must be frozen explicitly.
1455
1456                   declare
1457                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1458                   begin
1459                      if Is_Non_Empty_List (Flist) then
1460                         Insert_Actions (N, Flist);
1461                      end if;
1462                   end;
1463
1464                   --  Check for null or possibly null range and issue warning.
1465                   --  We suppress such messages in generic templates and
1466                   --  instances, because in practice they tend to be dubious
1467                   --  in these cases.
1468
1469                   if Nkind (DS) = N_Range
1470                     and then Comes_From_Source (N)
1471                   then
1472                      declare
1473                         L : constant Node_Id := Low_Bound  (DS);
1474                         H : constant Node_Id := High_Bound (DS);
1475
1476                         Llo : Uint;
1477                         Lhi : Uint;
1478                         LOK : Boolean;
1479                         Hlo : Uint;
1480                         Hhi : Uint;
1481                         HOK : Boolean;
1482
1483                      begin
1484                         Determine_Range (L, LOK, Llo, Lhi);
1485                         Determine_Range (H, HOK, Hlo, Hhi);
1486
1487                         --  If range of loop is null, issue warning
1488
1489                         if (LOK and HOK) and then Llo > Hhi then
1490
1491                            --  Suppress the warning if inside a generic
1492                            --  template or instance, since in practice
1493                            --  they tend to be dubious in these cases since
1494                            --  they can result from intended parametrization.
1495
1496                            if not Inside_A_Generic
1497                               and then not In_Instance
1498                            then
1499                               Error_Msg_N
1500                                 ("?loop range is null, loop will not execute",
1501                                  DS);
1502                            end if;
1503
1504                            --  Since we know the range of the loop is null,
1505                            --  set the appropriate flag to suppress any
1506                            --  warnings that would otherwise be issued in
1507                            --  the body of the loop that will not execute.
1508                            --  We do this even in the generic case, since
1509                            --  if it is dubious to warn on the null loop
1510                            --  itself, it is certainly dubious to warn for
1511                            --  conditions that occur inside it!
1512
1513                            Set_Is_Null_Loop (Parent (N));
1514
1515                         --  The other case for a warning is a reverse loop
1516                         --  where the upper bound is the integer literal
1517                         --  zero or one, and the lower bound can be positive.
1518
1519                         --  For example, we have
1520
1521                         --     for J in reverse N .. 1 loop
1522
1523                         --  In practice, this is very likely to be a case
1524                         --  of reversing the bounds incorrectly in the range.
1525
1526                         elsif Reverse_Present (LP)
1527                           and then Nkind (H) = N_Integer_Literal
1528                           and then (Intval (H) = Uint_0
1529                                       or else
1530                                     Intval (H) = Uint_1)
1531                           and then Lhi > Hhi
1532                         then
1533                            Error_Msg_N ("?loop range may be null", DS);
1534                         end if;
1535                      end;
1536                   end if;
1537                end;
1538             end if;
1539          end;
1540       end if;
1541    end Analyze_Iteration_Scheme;
1542
1543    -------------------
1544    -- Analyze_Label --
1545    -------------------
1546
1547    --  Note: the semantic work required for analyzing labels (setting them as
1548    --  reachable) was done in a prepass through the statements in the block,
1549    --  so that forward gotos would be properly handled. See Analyze_Statements
1550    --  for further details. The only processing required here is to deal with
1551    --  optimizations that depend on an assumption of sequential control flow,
1552    --  since of course the occurrence of a label breaks this assumption.
1553
1554    procedure Analyze_Label (N : Node_Id) is
1555       pragma Warnings (Off, N);
1556    begin
1557       Kill_Current_Values;
1558    end Analyze_Label;
1559
1560    --------------------------
1561    -- Analyze_Label_Entity --
1562    --------------------------
1563
1564    procedure Analyze_Label_Entity (E : Entity_Id) is
1565    begin
1566       Set_Ekind           (E, E_Label);
1567       Set_Etype           (E, Standard_Void_Type);
1568       Set_Enclosing_Scope (E, Current_Scope);
1569       Set_Reachable       (E, True);
1570    end Analyze_Label_Entity;
1571
1572    ----------------------------
1573    -- Analyze_Loop_Statement --
1574    ----------------------------
1575
1576    procedure Analyze_Loop_Statement (N : Node_Id) is
1577       Id  : constant Node_Id := Identifier (N);
1578       Ent : Entity_Id;
1579
1580    begin
1581       if Present (Id) then
1582
1583          --  Make name visible, e.g. for use in exit statements. Loop
1584          --  labels are always considered to be referenced.
1585
1586          Analyze (Id);
1587          Ent := Entity (Id);
1588          Generate_Reference  (Ent, N, ' ');
1589          Generate_Definition (Ent);
1590
1591          --  If we found a label, mark its type. If not, ignore it, since it
1592          --  means we have a conflicting declaration, which would already have
1593          --  been diagnosed at declaration time. Set Label_Construct of the
1594          --  implicit label declaration, which is not created by the parser
1595          --  for generic units.
1596
1597          if Ekind (Ent) = E_Label then
1598             Set_Ekind (Ent, E_Loop);
1599
1600             if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
1601                Set_Label_Construct (Parent (Ent), N);
1602             end if;
1603          end if;
1604
1605       --  Case of no identifier present
1606
1607       else
1608          Ent := New_Internal_Entity (E_Loop, Current_Scope, Sloc (N), 'L');
1609          Set_Etype (Ent,  Standard_Void_Type);
1610          Set_Parent (Ent, N);
1611       end if;
1612
1613       --  Kill current values on entry to loop, since statements in body
1614       --  of loop may have been executed before the loop is entered.
1615       --  Similarly we kill values after the loop, since we do not know
1616       --  that the body of the loop was executed.
1617
1618       Kill_Current_Values;
1619       New_Scope (Ent);
1620       Analyze_Iteration_Scheme (Iteration_Scheme (N));
1621       Analyze_Statements (Statements (N));
1622       Process_End_Label (N, 'e', Ent);
1623       End_Scope;
1624       Kill_Current_Values;
1625    end Analyze_Loop_Statement;
1626
1627    ----------------------------
1628    -- Analyze_Null_Statement --
1629    ----------------------------
1630
1631    --  Note: the semantics of the null statement is implemented by a single
1632    --  null statement, too bad everything isn't as simple as this!
1633
1634    procedure Analyze_Null_Statement (N : Node_Id) is
1635       pragma Warnings (Off, N);
1636    begin
1637       null;
1638    end Analyze_Null_Statement;
1639
1640    ------------------------
1641    -- Analyze_Statements --
1642    ------------------------
1643
1644    procedure Analyze_Statements (L : List_Id) is
1645       S   : Node_Id;
1646       Lab : Entity_Id;
1647
1648    begin
1649       --  The labels declared in the statement list are reachable from
1650       --  statements in the list. We do this as a prepass so that any
1651       --  goto statement will be properly flagged if its target is not
1652       --  reachable. This is not required, but is nice behavior!
1653
1654       S := First (L);
1655       while Present (S) loop
1656          if Nkind (S) = N_Label then
1657             Analyze (Identifier (S));
1658             Lab := Entity (Identifier (S));
1659
1660             --  If we found a label mark it as reachable
1661
1662             if Ekind (Lab) = E_Label then
1663                Generate_Definition (Lab);
1664                Set_Reachable (Lab);
1665
1666                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
1667                   Set_Label_Construct (Parent (Lab), S);
1668                end if;
1669
1670             --  If we failed to find a label, it means the implicit declaration
1671             --  of the label was hidden.  A for-loop parameter can do this to
1672             --  a label with the same name inside the loop, since the implicit
1673             --  label declaration is in the innermost enclosing body or block
1674             --  statement.
1675
1676             else
1677                Error_Msg_Sloc := Sloc (Lab);
1678                Error_Msg_N
1679                  ("implicit label declaration for & is hidden#",
1680                   Identifier (S));
1681             end if;
1682          end if;
1683
1684          Next (S);
1685       end loop;
1686
1687       --  Perform semantic analysis on all statements
1688
1689       Conditional_Statements_Begin;
1690
1691       S := First (L);
1692       while Present (S) loop
1693          Analyze (S);
1694          Next (S);
1695       end loop;
1696
1697       Conditional_Statements_End;
1698
1699       --  Make labels unreachable. Visibility is not sufficient, because
1700       --  labels in one if-branch for example are not reachable from the
1701       --  other branch, even though their declarations are in the enclosing
1702       --  declarative part.
1703
1704       S := First (L);
1705       while Present (S) loop
1706          if Nkind (S) = N_Label then
1707             Set_Reachable (Entity (Identifier (S)), False);
1708          end if;
1709
1710          Next (S);
1711       end loop;
1712    end Analyze_Statements;
1713
1714    --------------------------------------------
1715    -- Check_Possible_Current_Value_Condition --
1716    --------------------------------------------
1717
1718    procedure Check_Possible_Current_Value_Condition (Cnode : Node_Id) is
1719       Cond : Node_Id;
1720
1721    begin
1722       --  Loop to deal with (ignore for now) any NOT operators present
1723
1724       Cond := Condition (Cnode);
1725       while Nkind (Cond) = N_Op_Not loop
1726          Cond := Right_Opnd (Cond);
1727       end loop;
1728
1729       --  Check possible relational operator
1730
1731       if Nkind (Cond) = N_Op_Eq
1732            or else
1733          Nkind (Cond) = N_Op_Ne
1734            or else
1735          Nkind (Cond) = N_Op_Ge
1736            or else
1737          Nkind (Cond) = N_Op_Le
1738            or else
1739          Nkind (Cond) = N_Op_Gt
1740            or else
1741          Nkind (Cond) = N_Op_Lt
1742       then
1743          if Compile_Time_Known_Value (Right_Opnd (Cond))
1744            and then Nkind (Left_Opnd (Cond)) = N_Identifier
1745          then
1746             declare
1747                Ent : constant Entity_Id := Entity (Left_Opnd (Cond));
1748
1749             begin
1750                if Ekind (Ent) = E_Variable
1751                     or else
1752                   Ekind (Ent) = E_Constant
1753                     or else
1754                   Is_Formal (Ent)
1755                     or else
1756                   Ekind (Ent) = E_Loop_Parameter
1757                then
1758                   --  Here we have a case where the Current_Value field
1759                   --  may need to be set. We set it if it is not already
1760                   --  set to a compile time expression value.
1761
1762                   --  Note that this represents a decision that one
1763                   --  condition blots out another previous one. That's
1764                   --  certainly right if they occur at the same level.
1765                   --  If the second one is nested, then the decision is
1766                   --  neither right nor wrong (it would be equally OK
1767                   --  to leave the outer one in place, or take the new
1768                   --  inner one. Really we should record both, but our
1769                   --  data structures are not that elaborate.
1770
1771                   if Nkind (Current_Value (Ent)) not in N_Subexpr then
1772                      Set_Current_Value (Ent, Cnode);
1773                   end if;
1774                end if;
1775             end;
1776          end if;
1777       end if;
1778    end Check_Possible_Current_Value_Condition;
1779
1780    ----------------------------
1781    -- Check_Unreachable_Code --
1782    ----------------------------
1783
1784    procedure Check_Unreachable_Code (N : Node_Id) is
1785       Error_Loc : Source_Ptr;
1786       P         : Node_Id;
1787
1788    begin
1789       if Is_List_Member (N)
1790         and then Comes_From_Source (N)
1791       then
1792          declare
1793             Nxt : Node_Id;
1794
1795          begin
1796             Nxt := Original_Node (Next (N));
1797
1798             --  If a label follows us, then we never have dead code, since
1799             --  someone could branch to the label, so we just ignore it.
1800
1801             if Nkind (Nxt) = N_Label then
1802                return;
1803
1804             --  Otherwise see if we have a real statement following us
1805
1806             elsif Present (Nxt)
1807               and then Comes_From_Source (Nxt)
1808               and then Is_Statement (Nxt)
1809             then
1810                --  Special very annoying exception. If we have a return that
1811                --  follows a raise, then we allow it without a warning, since
1812                --  the Ada RM annoyingly requires a useless return here!
1813
1814                if Nkind (Original_Node (N)) /= N_Raise_Statement
1815                  or else Nkind (Nxt) /= N_Return_Statement
1816                then
1817                   --  The rather strange shenanigans with the warning message
1818                   --  here reflects the fact that Kill_Dead_Code is very good
1819                   --  at removing warnings in deleted code, and this is one
1820                   --  warning we would prefer NOT to have removed :-)
1821
1822                   Error_Loc := Sloc (Nxt);
1823
1824                   --  If we have unreachable code, analyze and remove the
1825                   --  unreachable code, since it is useless and we don't
1826                   --  want to generate junk warnings.
1827
1828                   --  We skip this step if we are not in code generation mode.
1829                   --  This is the one case where we remove dead code in the
1830                   --  semantics as opposed to the expander, and we do not want
1831                   --  to remove code if we are not in code generation mode,
1832                   --  since this messes up the ASIS trees.
1833
1834                   --  Note that one might react by moving the whole circuit to
1835                   --  exp_ch5, but then we lose the warning in -gnatc mode.
1836
1837                   if Operating_Mode = Generate_Code then
1838                      loop
1839                         Nxt := Next (N);
1840
1841                         --  Quit deleting when we have nothing more to delete
1842                         --  or if we hit a label (since someone could transfer
1843                         --  control to a label, so we should not delete it).
1844
1845                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
1846
1847                         --  Statement/declaration is to be deleted
1848
1849                         Analyze (Nxt);
1850                         Remove (Nxt);
1851                         Kill_Dead_Code (Nxt);
1852                      end loop;
1853                   end if;
1854
1855                   --  Now issue the warning
1856
1857                   Error_Msg ("?unreachable code", Error_Loc);
1858                end if;
1859
1860             --  If the unconditional transfer of control instruction is
1861             --  the last statement of a sequence, then see if our parent
1862             --  is one of the constructs for which we count unblocked exits,
1863             --  and if so, adjust the count.
1864
1865             else
1866                P := Parent (N);
1867
1868                --  Statements in THEN part or ELSE part of IF statement
1869
1870                if Nkind (P) = N_If_Statement then
1871                   null;
1872
1873                --  Statements in ELSIF part of an IF statement
1874
1875                elsif Nkind (P) = N_Elsif_Part then
1876                   P := Parent (P);
1877                   pragma Assert (Nkind (P) = N_If_Statement);
1878
1879                --  Statements in CASE statement alternative
1880
1881                elsif Nkind (P) = N_Case_Statement_Alternative then
1882                   P := Parent (P);
1883                   pragma Assert (Nkind (P) = N_Case_Statement);
1884
1885                --  Statements in body of block
1886
1887                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
1888                  and then Nkind (Parent (P)) = N_Block_Statement
1889                then
1890                   null;
1891
1892                --  Statements in exception handler in a block
1893
1894                elsif Nkind (P) = N_Exception_Handler
1895                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
1896                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
1897                then
1898                   null;
1899
1900                --  None of these cases, so return
1901
1902                else
1903                   return;
1904                end if;
1905
1906                --  This was one of the cases we are looking for (i.e. the
1907                --  parent construct was IF, CASE or block) so decrement count.
1908
1909                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
1910             end if;
1911          end;
1912       end if;
1913    end Check_Unreachable_Code;
1914
1915 end Sem_Ch5;