gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Aux;  use Sem_Aux;
  42 with Sem_Case; use Sem_Case;
  43 with Sem_Ch3;  use Sem_Ch3;
  44 with Sem_Ch8;  use Sem_Ch8;
  45 with Sem_Disp; use Sem_Disp;
  46 with Sem_Elab; use Sem_Elab;
  47 with Sem_Eval; use Sem_Eval;
  48 with Sem_Res;  use Sem_Res;
  49 with Sem_Type; use Sem_Type;
  50 with Sem_Util; use Sem_Util;
  51 with Sem_Warn; use Sem_Warn;
  52 with Snames;   use Snames;
  53 with Stand;    use Stand;
  54 with Sinfo;    use Sinfo;
  55 with Targparm; use Targparm;
  56 with Tbuild;   use Tbuild;
  57 with Uintp;    use Uintp;
  58
  59 package body Sem_Ch5 is
  60
  61    Unblocked_Exit_Count : Nat := 0;
  62    --  This variable is used when processing if statements, case statements,
  63    --  and block statements. It counts the number of exit points that are not
  64    --  blocked by unconditional transfer instructions: for IF and CASE, these
  65    --  are the branches of the conditional; for a block, they are the statement
  66    --  sequence of the block, and the statement sequences of any exception
  67    --  handlers that are part of the block. When processing is complete, if
  68    --  this count is zero, it means that control cannot fall through the IF,
  69    --  CASE or block statement. This is used for the generation of warning
  70    --  messages. This variable is recursively saved on entry to processing the
  71    --  construct, and restored on exit.
  72
  73    -----------------------
  74    -- Local Subprograms --
  75    -----------------------
  76
  77    procedure Analyze_Iteration_Scheme (N : Node_Id);
  78
  79    ------------------------
  80    -- Analyze_Assignment --
  81    ------------------------
  82
  83    procedure Analyze_Assignment (N : Node_Id) is
  84       Lhs  : constant Node_Id := Name (N);
  85       Rhs  : constant Node_Id := Expression (N);
  86       T1   : Entity_Id;
  87       T2   : Entity_Id;
  88       Decl : Node_Id;
  89
  90       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  91       --  N is the node for the left hand side of an assignment, and it is not
  92       --  a variable. This routine issues an appropriate diagnostic.
  93
  94       procedure Kill_Lhs;
  95       --  This is called to kill current value settings of a simple variable
  96       --  on the left hand side. We call it if we find any error in analyzing
  97       --  the assignment, and at the end of processing before setting any new
  98       --  current values in place.
  99
 100       procedure Set_Assignment_Type
 101         (Opnd      : Node_Id;
 102          Opnd_Type : in out Entity_Id);
 103       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 104       --  is the nominal subtype. This procedure is used to deal with cases
 105       --  where the nominal subtype must be replaced by the actual subtype.
 106
 107       -------------------------------
 108       -- Diagnose_Non_Variable_Lhs --
 109       -------------------------------
 110
 111       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 112       begin
 113          --  Not worth posting another error if left hand side already
 114          --  flagged as being illegal in some respect.
 115
 116          if Error_Posted (N) then
 117             return;
 118
 119          --  Some special bad cases of entity names
 120
 121          elsif Is_Entity_Name (N) then
 122             declare
 123                Ent : constant Entity_Id := Entity (N);
 124
 125             begin
 126                if Ekind (Ent) = E_In_Parameter then
 127                   Error_Msg_N
 128                     ("assignment to IN mode parameter not allowed", N);
 129
 130                --  Renamings of protected private components are turned into
 131                --  constants when compiling a protected function. In the case
 132                --  of single protected types, the private component appears
 133                --  directly.
 134
 135                elsif (Is_Prival (Ent)
 136                         and then
 137                           (Ekind (Current_Scope) = E_Function
 138                              or else Ekind (Enclosing_Dynamic_Scope (
 139                                        Current_Scope)) = E_Function))
 140                    or else
 141                      (Ekind (Ent) = E_Component
 142                         and then Is_Protected_Type (Scope (Ent)))
 143                then
 144                   Error_Msg_N
 145                     ("protected function cannot modify protected object", N);
 146
 147                elsif Ekind (Ent) = E_Loop_Parameter then
 148                   Error_Msg_N
 149                     ("assignment to loop parameter not allowed", N);
 150
 151                else
 152                   Error_Msg_N
 153                     ("left hand side of assignment must be a variable", N);
 154                end if;
 155             end;
 156
 157          --  For indexed components or selected components, test prefix
 158
 159          elsif Nkind (N) = N_Indexed_Component then
 160             Diagnose_Non_Variable_Lhs (Prefix (N));
 161
 162          --  Another special case for assignment to discriminant
 163
 164          elsif Nkind (N) = N_Selected_Component then
 165             if Present (Entity (Selector_Name (N)))
 166               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 167             then
 168                Error_Msg_N
 169                  ("assignment to discriminant not allowed", N);
 170             else
 171                Diagnose_Non_Variable_Lhs (Prefix (N));
 172             end if;
 173
 174          else
 175             --  If we fall through, we have no special message to issue!
 176
 177             Error_Msg_N ("left hand side of assignment must be a variable", N);
 178          end if;
 179       end Diagnose_Non_Variable_Lhs;
 180
 181       --------------
 182       -- Kill_LHS --
 183       --------------
 184
 185       procedure Kill_Lhs is
 186       begin
 187          if Is_Entity_Name (Lhs) then
 188             declare
 189                Ent : constant Entity_Id := Entity (Lhs);
 190             begin
 191                if Present (Ent) then
 192                   Kill_Current_Values (Ent);
 193                end if;
 194             end;
 195          end if;
 196       end Kill_Lhs;
 197
 198       -------------------------
 199       -- Set_Assignment_Type --
 200       -------------------------
 201
 202       procedure Set_Assignment_Type
 203         (Opnd      : Node_Id;
 204          Opnd_Type : in out Entity_Id)
 205       is
 206       begin
 207          Require_Entity (Opnd);
 208
 209          --  If the assignment operand is an in-out or out parameter, then we
 210          --  get the actual subtype (needed for the unconstrained case).
 211          --  If the operand is the actual in an entry declaration, then within
 212          --  the accept statement it is replaced with a local renaming, which
 213          --  may also have an actual subtype.
 214
 215          if Is_Entity_Name (Opnd)
 216            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 217                       or else Ekind (Entity (Opnd)) =
 218                            E_In_Out_Parameter
 219                       or else Ekind (Entity (Opnd)) =
 220                            E_Generic_In_Out_Parameter
 221                       or else
 222                         (Ekind (Entity (Opnd)) = E_Variable
 223                           and then Nkind (Parent (Entity (Opnd))) =
 224                              N_Object_Renaming_Declaration
 225                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 226                              N_Accept_Statement))
 227          then
 228             Opnd_Type := Get_Actual_Subtype (Opnd);
 229
 230          --  If assignment operand is a component reference, then we get the
 231          --  actual subtype of the component for the unconstrained case.
 232
 233          elsif Nkind_In (Opnd, N_Selected_Component, N_Explicit_Dereference)
 234            and then not Is_Unchecked_Union (Opnd_Type)
 235          then
 236             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 237
 238             if Present (Decl) then
 239                Insert_Action (N, Decl);
 240                Mark_Rewrite_Insertion (Decl);
 241                Analyze (Decl);
 242                Opnd_Type := Defining_Identifier (Decl);
 243                Set_Etype (Opnd, Opnd_Type);
 244                Freeze_Itype (Opnd_Type, N);
 245
 246             elsif Is_Constrained (Etype (Opnd)) then
 247                Opnd_Type := Etype (Opnd);
 248             end if;
 249
 250          --  For slice, use the constrained subtype created for the slice
 251
 252          elsif Nkind (Opnd) = N_Slice then
 253             Opnd_Type := Etype (Opnd);
 254          end if;
 255       end Set_Assignment_Type;
 256
 257    --  Start of processing for Analyze_Assignment
 258
 259    begin
 260       Mark_Coextensions (N, Rhs);
 261
 262       Analyze (Rhs);
 263       Analyze (Lhs);
 264
 265       --  Start type analysis for assignment
 266
 267       T1 := Etype (Lhs);
 268
 269       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 270       --  must compute the intersection of the possible types on each side.
 271
 272       if Is_Overloaded (Lhs) then
 273          declare
 274             I  : Interp_Index;
 275             It : Interp;
 276
 277          begin
 278             T1 := Any_Type;
 279             Get_First_Interp (Lhs, I, It);
 280
 281             while Present (It.Typ) loop
 282                if Has_Compatible_Type (Rhs, It.Typ) then
 283                   if T1 /= Any_Type then
 284
 285                      --  An explicit dereference is overloaded if the prefix
 286                      --  is. Try to remove the ambiguity on the prefix, the
 287                      --  error will be posted there if the ambiguity is real.
 288
 289                      if Nkind (Lhs) = N_Explicit_Dereference then
 290                         declare
 291                            PI    : Interp_Index;
 292                            PI1   : Interp_Index := 0;
 293                            PIt   : Interp;
 294                            Found : Boolean;
 295
 296                         begin
 297                            Found := False;
 298                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 299
 300                            while Present (PIt.Typ) loop
 301                               if Is_Access_Type (PIt.Typ)
 302                                 and then Has_Compatible_Type
 303                                            (Rhs, Designated_Type (PIt.Typ))
 304                               then
 305                                  if Found then
 306                                     PIt :=
 307                                       Disambiguate (Prefix (Lhs),
 308                                         PI1, PI, Any_Type);
 309
 310                                     if PIt = No_Interp then
 311                                        Error_Msg_N
 312                                          ("ambiguous left-hand side"
 313                                             & " in assignment", Lhs);
 314                                        exit;
 315                                     else
 316                                        Resolve (Prefix (Lhs), PIt.Typ);
 317                                     end if;
 318
 319                                     exit;
 320                                  else
 321                                     Found := True;
 322                                     PI1 := PI;
 323                                  end if;
 324                               end if;
 325
 326                               Get_Next_Interp (PI, PIt);
 327                            end loop;
 328                         end;
 329
 330                      else
 331                         Error_Msg_N
 332                           ("ambiguous left-hand side in assignment", Lhs);
 333                         exit;
 334                      end if;
 335                   else
 336                      T1 := It.Typ;
 337                   end if;
 338                end if;
 339
 340                Get_Next_Interp (I, It);
 341             end loop;
 342          end;
 343
 344          if T1 = Any_Type then
 345             Error_Msg_N
 346               ("no valid types for left-hand side for assignment", Lhs);
 347             Kill_Lhs;
 348             return;
 349          end if;
 350       end if;
 351
 352       --  The resulting assignment type is T1, so now we will resolve the
 353       --  left hand side of the assignment using this determined type.
 354
 355       Resolve (Lhs, T1);
 356
 357       --  Cases where Lhs is not a variable
 358
 359       if not Is_Variable (Lhs) then
 360
 361          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 362          --  a protected object.
 363
 364          declare
 365             Ent : Entity_Id;
 366             S   : Entity_Id;
 367
 368          begin
 369             if Ada_Version >= Ada_05 then
 370
 371                --  Handle chains of renamings
 372
 373                Ent := Lhs;
 374                while Nkind (Ent) in N_Has_Entity
 375                  and then Present (Entity (Ent))
 376                  and then Present (Renamed_Object (Entity (Ent)))
 377                loop
 378                   Ent := Renamed_Object (Entity (Ent));
 379                end loop;
 380
 381                if (Nkind (Ent) = N_Attribute_Reference
 382                      and then Attribute_Name (Ent) = Name_Priority)
 383
 384                   --  Renamings of the attribute Priority applied to protected
 385                   --  objects have been previously expanded into calls to the
 386                   --  Get_Ceiling run-time subprogram.
 387
 388                  or else
 389                   (Nkind (Ent) = N_Function_Call
 390                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 391                                 or else
 392                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 393                then
 394                   --  The enclosing subprogram cannot be a protected function
 395
 396                   S := Current_Scope;
 397                   while not (Is_Subprogram (S)
 398                                and then Convention (S) = Convention_Protected)
 399                      and then S /= Standard_Standard
 400                   loop
 401                      S := Scope (S);
 402                   end loop;
 403
 404                   if Ekind (S) = E_Function
 405                     and then Convention (S) = Convention_Protected
 406                   then
 407                      Error_Msg_N
 408                        ("protected function cannot modify protected object",
 409                         Lhs);
 410                   end if;
 411
 412                   --  Changes of the ceiling priority of the protected object
 413                   --  are only effective if the Ceiling_Locking policy is in
 414                   --  effect (AARM D.5.2 (5/2)).
 415
 416                   if Locking_Policy /= 'C' then
 417                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 418                                   "no effect?", Lhs);
 419                      Error_Msg_N ("\since no Locking_Policy has been " &
 420                                   "specified", Lhs);
 421                   end if;
 422
 423                   return;
 424                end if;
 425             end if;
 426          end;
 427
 428          Diagnose_Non_Variable_Lhs (Lhs);
 429          return;
 430
 431       --  Error of assigning to limited type. We do however allow this in
 432       --  certain cases where the front end generates the assignments.
 433
 434       elsif Is_Limited_Type (T1)
 435         and then not Assignment_OK (Lhs)
 436         and then not Assignment_OK (Original_Node (Lhs))
 437         and then not Is_Value_Type (T1)
 438       then
 439          --  CPP constructors can only be called in declarations
 440
 441          if Is_CPP_Constructor_Call (Rhs) then
 442             Error_Msg_N ("invalid use of 'C'P'P constructor", Rhs);
 443          else
 444             Error_Msg_N
 445               ("left hand of assignment must not be limited type", Lhs);
 446             Explain_Limited_Type (T1, Lhs);
 447          end if;
 448          return;
 449
 450       --  Enforce RM 3.9.3 (8): the target of an assignment operation cannot be
 451       --  abstract. This is only checked when the assignment Comes_From_Source,
 452       --  because in some cases the expander generates such assignments (such
 453       --  in the _assign operation for an abstract type).
 454
 455       elsif Is_Abstract_Type (T1) and then Comes_From_Source (N) then
 456          Error_Msg_N
 457            ("target of assignment operation must not be abstract", Lhs);
 458       end if;
 459
 460       --  Resolution may have updated the subtype, in case the left-hand
 461       --  side is a private protected component. Use the correct subtype
 462       --  to avoid scoping issues in the back-end.
 463
 464       T1 := Etype (Lhs);
 465
 466       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 467       --  type. For example:
 468
 469       --    limited with P;
 470       --    package Pkg is
 471       --      type Acc is access P.T;
 472       --    end Pkg;
 473
 474       --    with Pkg; use Acc;
 475       --    procedure Example is
 476       --       A, B : Acc;
 477       --    begin
 478       --       A.all := B.all;  -- ERROR
 479       --    end Example;
 480
 481       if Nkind (Lhs) = N_Explicit_Dereference
 482         and then Ekind (T1) = E_Incomplete_Type
 483       then
 484          Error_Msg_N ("invalid use of incomplete type", Lhs);
 485          Kill_Lhs;
 486          return;
 487       end if;
 488
 489       --  Now we can complete the resolution of the right hand side
 490
 491       Set_Assignment_Type (Lhs, T1);
 492       Resolve (Rhs, T1);
 493
 494       --  This is the point at which we check for an unset reference
 495
 496       Check_Unset_Reference (Rhs);
 497       Check_Unprotected_Access (Lhs, Rhs);
 498
 499       --  Remaining steps are skipped if Rhs was syntactically in error
 500
 501       if Rhs = Error then
 502          Kill_Lhs;
 503          return;
 504       end if;
 505
 506       T2 := Etype (Rhs);
 507
 508       if not Covers (T1, T2) then
 509          Wrong_Type (Rhs, Etype (Lhs));
 510          Kill_Lhs;
 511          return;
 512       end if;
 513
 514       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 515       --  types, use the non-limited view if available
 516
 517       if Nkind (Rhs) = N_Explicit_Dereference
 518         and then Ekind (T2) = E_Incomplete_Type
 519         and then Is_Tagged_Type (T2)
 520         and then Present (Non_Limited_View (T2))
 521       then
 522          T2 := Non_Limited_View (T2);
 523       end if;
 524
 525       Set_Assignment_Type (Rhs, T2);
 526
 527       if Total_Errors_Detected /= 0 then
 528          if No (T1) then
 529             T1 := Any_Type;
 530          end if;
 531
 532          if No (T2) then
 533             T2 := Any_Type;
 534          end if;
 535       end if;
 536
 537       if T1 = Any_Type or else T2 = Any_Type then
 538          Kill_Lhs;
 539          return;
 540       end if;
 541
 542       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 543       --  to be class-wide. The case where the rhs is a dynamically tagged call
 544       --  to a dispatching operation with a controlling access result is
 545       --  excluded from this check, since the target has an access type (and
 546       --  no tag propagation occurs in that case).
 547
 548       if (Is_Class_Wide_Type (T2)
 549            or else (Is_Dynamically_Tagged (Rhs)
 550                      and then not Is_Access_Type (T1)))
 551         and then not Is_Class_Wide_Type (T1)
 552       then
 553          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 554
 555       elsif Is_Class_Wide_Type (T1)
 556         and then not Is_Class_Wide_Type (T2)
 557         and then not Is_Tag_Indeterminate (Rhs)
 558         and then not Is_Dynamically_Tagged (Rhs)
 559       then
 560          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 561       end if;
 562
 563       --  Propagate the tag from a class-wide target to the rhs when the rhs
 564       --  is a tag-indeterminate call.
 565
 566       if Is_Tag_Indeterminate (Rhs) then
 567          if Is_Class_Wide_Type (T1) then
 568             Propagate_Tag (Lhs, Rhs);
 569
 570          elsif Nkind (Rhs) = N_Function_Call
 571               and then Is_Entity_Name (Name (Rhs))
 572               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 573          then
 574             Error_Msg_N
 575               ("call to abstract function must be dispatching", Name (Rhs));
 576
 577          elsif Nkind (Rhs) = N_Qualified_Expression
 578            and then Nkind (Expression (Rhs)) = N_Function_Call
 579               and then Is_Entity_Name (Name (Expression (Rhs)))
 580               and then
 581                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 582          then
 583             Error_Msg_N
 584               ("call to abstract function must be dispatching",
 585                 Name (Expression (Rhs)));
 586          end if;
 587       end if;
 588
 589       --  Ada 2005 (AI-385): When the lhs type is an anonymous access type,
 590       --  apply an implicit conversion of the rhs to that type to force
 591       --  appropriate static and run-time accessibility checks. This applies
 592       --  as well to anonymous access-to-subprogram types that are component
 593       --  subtypes or formal parameters.
 594
 595       if Ada_Version >= Ada_05
 596         and then Is_Access_Type (T1)
 597       then
 598          if Is_Local_Anonymous_Access (T1)
 599            or else Ekind (T2) = E_Anonymous_Access_Subprogram_Type
 600          then
 601             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 602             Analyze_And_Resolve (Rhs, T1);
 603          end if;
 604       end if;
 605
 606       --  Ada 2005 (AI-231): Assignment to not null variable
 607
 608       if Ada_Version >= Ada_05
 609         and then Can_Never_Be_Null (T1)
 610         and then not Assignment_OK (Lhs)
 611       then
 612          --  Case where we know the right hand side is null
 613
 614          if Known_Null (Rhs) then
 615             Apply_Compile_Time_Constraint_Error
 616               (N   => Rhs,
 617                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 618                Reason => CE_Null_Not_Allowed);
 619
 620             --  We still mark this as a possible modification, that's necessary
 621             --  to reset Is_True_Constant, and desirable for xref purposes.
 622
 623             Note_Possible_Modification (Lhs, Sure => True);
 624             return;
 625
 626          --  If we know the right hand side is non-null, then we convert to the
 627          --  target type, since we don't need a run time check in that case.
 628
 629          elsif not Can_Never_Be_Null (T2) then
 630             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 631             Analyze_And_Resolve (Rhs, T1);
 632          end if;
 633       end if;
 634
 635       if Is_Scalar_Type (T1) then
 636          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 637
 638       --  For array types, verify that lengths match. If the right hand side
 639       --  if a function call that has been inlined, the assignment has been
 640       --  rewritten as a block, and the constraint check will be applied to the
 641       --  assignment within the block.
 642
 643       elsif Is_Array_Type (T1)
 644         and then
 645           (Nkind (Rhs) /= N_Type_Conversion
 646             or else Is_Constrained (Etype (Rhs)))
 647         and then
 648           (Nkind (Rhs) /= N_Function_Call
 649             or else Nkind (N) /= N_Block_Statement)
 650       then
 651          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 652          --  but of course the indices do not have to match. If the right-hand
 653          --  side is a type conversion to an unconstrained type, a length check
 654          --  is performed on the expression itself during expansion. In rare
 655          --  cases, the redundant length check is computed on an index type
 656          --  with a different representation, triggering incorrect code in
 657          --  the back end.
 658
 659          Apply_Length_Check (Rhs, Etype (Lhs));
 660
 661       else
 662          --  Discriminant checks are applied in the course of expansion
 663
 664          null;
 665       end if;
 666
 667       --  Note: modifications of the Lhs may only be recorded after
 668       --  checks have been applied.
 669
 670       Note_Possible_Modification (Lhs, Sure => True);
 671
 672       --  ??? a real accessibility check is needed when ???
 673
 674       --  Post warning for redundant assignment or variable to itself
 675
 676       if Warn_On_Redundant_Constructs
 677
 678          --  We only warn for source constructs
 679
 680          and then Comes_From_Source (N)
 681
 682          --  Where the object is the same on both sides
 683
 684          and then Same_Object (Lhs, Original_Node (Rhs))
 685
 686          --  But exclude the case where the right side was an operation
 687          --  that got rewritten (e.g. JUNK + K, where K was known to be
 688          --  zero). We don't want to warn in such a case, since it is
 689          --  reasonable to write such expressions especially when K is
 690          --  defined symbolically in some other package.
 691
 692         and then Nkind (Original_Node (Rhs)) not in N_Op
 693       then
 694          if Nkind (Lhs) in N_Has_Entity then
 695             Error_Msg_NE -- CODEFIX
 696               ("?useless assignment of & to itself!", N, Entity (Lhs));
 697          else
 698             Error_Msg_N -- CODEFIX
 699               ("?useless assignment of object to itself!", N);
 700          end if;
 701       end if;
 702
 703       --  Check for non-allowed composite assignment
 704
 705       if not Support_Composite_Assign_On_Target
 706         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 707         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 708       then
 709          Error_Msg_CRT ("composite assignment", N);
 710       end if;
 711
 712       --  Check elaboration warning for left side if not in elab code
 713
 714       if not In_Subprogram_Or_Concurrent_Unit then
 715          Check_Elab_Assign (Lhs);
 716       end if;
 717
 718       --  Set Referenced_As_LHS if appropriate. We only set this flag if the
 719       --  assignment is a source assignment in the extended main source unit.
 720       --  We are not interested in any reference information outside this
 721       --  context, or in compiler generated assignment statements.
 722
 723       if Comes_From_Source (N)
 724         and then In_Extended_Main_Source_Unit (Lhs)
 725       then
 726          Set_Referenced_Modified (Lhs, Out_Param => False);
 727       end if;
 728
 729       --  Final step. If left side is an entity, then we may be able to
 730       --  reset the current tracked values to new safe values. We only have
 731       --  something to do if the left side is an entity name, and expansion
 732       --  has not modified the node into something other than an assignment,
 733       --  and of course we only capture values if it is safe to do so.
 734
 735       if Is_Entity_Name (Lhs)
 736         and then Nkind (N) = N_Assignment_Statement
 737       then
 738          declare
 739             Ent : constant Entity_Id := Entity (Lhs);
 740
 741          begin
 742             if Safe_To_Capture_Value (N, Ent) then
 743
 744                --  If simple variable on left side, warn if this assignment
 745                --  blots out another one (rendering it useless) and note
 746                --  location of assignment in case no one references value.
 747                --  We only do this for source assignments, otherwise we can
 748                --  generate bogus warnings when an assignment is rewritten as
 749                --  another assignment, and gets tied up with itself.
 750
 751                --  Note: we don't use Record_Last_Assignment here, because we
 752                --  have lots of other stuff to do under control of this test.
 753
 754                if Warn_On_Modified_Unread
 755                  and then Is_Assignable (Ent)
 756                  and then Comes_From_Source (N)
 757                  and then In_Extended_Main_Source_Unit (Ent)
 758                then
 759                   Warn_On_Useless_Assignment (Ent, N);
 760                   Set_Last_Assignment (Ent, Lhs);
 761                end if;
 762
 763                --  If we are assigning an access type and the left side is an
 764                --  entity, then make sure that the Is_Known_[Non_]Null flags
 765                --  properly reflect the state of the entity after assignment.
 766
 767                if Is_Access_Type (T1) then
 768                   if Known_Non_Null (Rhs) then
 769                      Set_Is_Known_Non_Null (Ent, True);
 770
 771                   elsif Known_Null (Rhs)
 772                     and then not Can_Never_Be_Null (Ent)
 773                   then
 774                      Set_Is_Known_Null (Ent, True);
 775
 776                   else
 777                      Set_Is_Known_Null (Ent, False);
 778
 779                      if not Can_Never_Be_Null (Ent) then
 780                         Set_Is_Known_Non_Null (Ent, False);
 781                      end if;
 782                   end if;
 783
 784                --  For discrete types, we may be able to set the current value
 785                --  if the value is known at compile time.
 786
 787                elsif Is_Discrete_Type (T1)
 788                  and then Compile_Time_Known_Value (Rhs)
 789                then
 790                   Set_Current_Value (Ent, Rhs);
 791                else
 792                   Set_Current_Value (Ent, Empty);
 793                end if;
 794
 795             --  If not safe to capture values, kill them
 796
 797             else
 798                Kill_Lhs;
 799             end if;
 800          end;
 801       end if;
 802    end Analyze_Assignment;
 803
 804    -----------------------------
 805    -- Analyze_Block_Statement --
 806    -----------------------------
 807
 808    procedure Analyze_Block_Statement (N : Node_Id) is
 809       Decls : constant List_Id := Declarations (N);
 810       Id    : constant Node_Id := Identifier (N);
 811       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 812
 813    begin
 814       --  If no handled statement sequence is present, things are really
 815       --  messed up, and we just return immediately (this is a defence
 816       --  against previous errors).
 817
 818       if No (HSS) then
 819          return;
 820       end if;
 821
 822       --  Normal processing with HSS present
 823
 824       declare
 825          EH  : constant List_Id := Exception_Handlers (HSS);
 826          Ent : Entity_Id        := Empty;
 827          S   : Entity_Id;
 828
 829          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 830          --  Recursively save value of this global, will be restored on exit
 831
 832       begin
 833          --  Initialize unblocked exit count for statements of begin block
 834          --  plus one for each exception handler that is present.
 835
 836          Unblocked_Exit_Count := 1;
 837
 838          if Present (EH) then
 839             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 840          end if;
 841
 842          --  If a label is present analyze it and mark it as referenced
 843
 844          if Present (Id) then
 845             Analyze (Id);
 846             Ent := Entity (Id);
 847
 848             --  An error defense. If we have an identifier, but no entity,
 849             --  then something is wrong. If we have previous errors, then
 850             --  just remove the identifier and continue, otherwise raise
 851             --  an exception.
 852
 853             if No (Ent) then
 854                if Total_Errors_Detected /= 0 then
 855                   Set_Identifier (N, Empty);
 856                else
 857                   raise Program_Error;
 858                end if;
 859
 860             else
 861                Set_Ekind (Ent, E_Block);
 862                Generate_Reference (Ent, N, ' ');
 863                Generate_Definition (Ent);
 864
 865                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 866                   Set_Label_Construct (Parent (Ent), N);
 867                end if;
 868             end if;
 869          end if;
 870
 871          --  If no entity set, create a label entity
 872
 873          if No (Ent) then
 874             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 875             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 876             Set_Parent (Ent, N);
 877          end if;
 878
 879          Set_Etype (Ent, Standard_Void_Type);
 880          Set_Block_Node (Ent, Identifier (N));
 881          Push_Scope (Ent);
 882
 883          if Present (Decls) then
 884             Analyze_Declarations (Decls);
 885             Check_Completion;
 886             Inspect_Deferred_Constant_Completion (Decls);
 887          end if;
 888
 889          Analyze (HSS);
 890          Process_End_Label (HSS, 'e', Ent);
 891
 892          --  If exception handlers are present, then we indicate that
 893          --  enclosing scopes contain a block with handlers. We only
 894          --  need to mark non-generic scopes.
 895
 896          if Present (EH) then
 897             S := Scope (Ent);
 898             loop
 899                Set_Has_Nested_Block_With_Handler (S);
 900                exit when Is_Overloadable (S)
 901                  or else Ekind (S) = E_Package
 902                  or else Is_Generic_Unit (S);
 903                S := Scope (S);
 904             end loop;
 905          end if;
 906
 907          Check_References (Ent);
 908          Warn_On_Useless_Assignments (Ent);
 909          End_Scope;
 910
 911          if Unblocked_Exit_Count = 0 then
 912             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 913             Check_Unreachable_Code (N);
 914          else
 915             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 916          end if;
 917       end;
 918    end Analyze_Block_Statement;
 919
 920    ----------------------------
 921    -- Analyze_Case_Statement --
 922    ----------------------------
 923
 924    procedure Analyze_Case_Statement (N : Node_Id) is
 925       Exp            : Node_Id;
 926       Exp_Type       : Entity_Id;
 927       Exp_Btype      : Entity_Id;
 928       Last_Choice    : Nat;
 929       Dont_Care      : Boolean;
 930       Others_Present : Boolean;
 931
 932       pragma Warnings (Off, Last_Choice);
 933       pragma Warnings (Off, Dont_Care);
 934       --  Don't care about assigned values
 935
 936       Statements_Analyzed : Boolean := False;
 937       --  Set True if at least some statement sequences get analyzed.
 938       --  If False on exit, means we had a serious error that prevented
 939       --  full analysis of the case statement, and as a result it is not
 940       --  a good idea to output warning messages about unreachable code.
 941
 942       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 943       --  Recursively save value of this global, will be restored on exit
 944
 945       procedure Non_Static_Choice_Error (Choice : Node_Id);
 946       --  Error routine invoked by the generic instantiation below when
 947       --  the case statement has a non static choice.
 948
 949       procedure Process_Statements (Alternative : Node_Id);
 950       --  Analyzes all the statements associated with a case alternative.
 951       --  Needed by the generic instantiation below.
 952
 953       package Case_Choices_Processing is new
 954         Generic_Choices_Processing
 955           (Get_Alternatives          => Alternatives,
 956            Get_Choices               => Discrete_Choices,
 957            Process_Empty_Choice      => No_OP,
 958            Process_Non_Static_Choice => Non_Static_Choice_Error,
 959            Process_Associated_Node   => Process_Statements);
 960       use Case_Choices_Processing;
 961       --  Instantiation of the generic choice processing package
 962
 963       -----------------------------
 964       -- Non_Static_Choice_Error --
 965       -----------------------------
 966
 967       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 968       begin
 969          Flag_Non_Static_Expr
 970            ("choice given in case statement is not static!", Choice);
 971       end Non_Static_Choice_Error;
 972
 973       ------------------------
 974       -- Process_Statements --
 975       ------------------------
 976
 977       procedure Process_Statements (Alternative : Node_Id) is
 978          Choices : constant List_Id := Discrete_Choices (Alternative);
 979          Ent     : Entity_Id;
 980
 981       begin
 982          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 983          Statements_Analyzed := True;
 984
 985          --  An interesting optimization. If the case statement expression
 986          --  is a simple entity, then we can set the current value within
 987          --  an alternative if the alternative has one possible value.
 988
 989          --    case N is
 990          --      when 1      => alpha
 991          --      when 2 | 3  => beta
 992          --      when others => gamma
 993
 994          --  Here we know that N is initially 1 within alpha, but for beta
 995          --  and gamma, we do not know anything more about the initial value.
 996
 997          if Is_Entity_Name (Exp) then
 998             Ent := Entity (Exp);
 999
1000             if Ekind_In (Ent, E_Variable,
1001                               E_In_Out_Parameter,
1002                               E_Out_Parameter)
1003             then
1004                if List_Length (Choices) = 1
1005                  and then Nkind (First (Choices)) in N_Subexpr
1006                  and then Compile_Time_Known_Value (First (Choices))
1007                then
1008                   Set_Current_Value (Entity (Exp), First (Choices));
1009                end if;
1010
1011                Analyze_Statements (Statements (Alternative));
1012
1013                --  After analyzing the case, set the current value to empty
1014                --  since we won't know what it is for the next alternative
1015                --  (unless reset by this same circuit), or after the case.
1016
1017                Set_Current_Value (Entity (Exp), Empty);
1018                return;
1019             end if;
1020          end if;
1021
1022          --  Case where expression is not an entity name of a variable
1023
1024          Analyze_Statements (Statements (Alternative));
1025       end Process_Statements;
1026
1027       --  Table to record choices. Put after subprograms since we make
1028       --  a call to Number_Of_Choices to get the right number of entries.
1029
1030       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
1031       pragma Warnings (Off, Case_Table);
1032
1033    --  Start of processing for Analyze_Case_Statement
1034
1035    begin
1036       Unblocked_Exit_Count := 0;
1037       Exp := Expression (N);
1038       Analyze (Exp);
1039
1040       --  The expression must be of any discrete type. In rare cases, the
1041       --  expander constructs a case statement whose expression has a private
1042       --  type whose full view is discrete. This can happen when generating
1043       --  a stream operation for a variant type after the type is frozen,
1044       --  when the partial of view of the type of the discriminant is private.
1045       --  In that case, use the full view to analyze case alternatives.
1046
1047       if not Is_Overloaded (Exp)
1048         and then not Comes_From_Source (N)
1049         and then Is_Private_Type (Etype (Exp))
1050         and then Present (Full_View (Etype (Exp)))
1051         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1052       then
1053          Resolve (Exp, Etype (Exp));
1054          Exp_Type := Full_View (Etype (Exp));
1055
1056       else
1057          Analyze_And_Resolve (Exp, Any_Discrete);
1058          Exp_Type := Etype (Exp);
1059       end if;
1060
1061       Check_Unset_Reference (Exp);
1062       Exp_Btype := Base_Type (Exp_Type);
1063
1064       --  The expression must be of a discrete type which must be determinable
1065       --  independently of the context in which the expression occurs, but
1066       --  using the fact that the expression must be of a discrete type.
1067       --  Moreover, the type this expression must not be a character literal
1068       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1069
1070       --  If error already reported by Resolve, nothing more to do
1071
1072       if Exp_Btype = Any_Discrete
1073         or else Exp_Btype = Any_Type
1074       then
1075          return;
1076
1077       elsif Exp_Btype = Any_Character then
1078          Error_Msg_N
1079            ("character literal as case expression is ambiguous", Exp);
1080          return;
1081
1082       elsif Ada_Version = Ada_83
1083         and then (Is_Generic_Type (Exp_Btype)
1084                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1085       then
1086          Error_Msg_N
1087            ("(Ada 83) case expression cannot be of a generic type", Exp);
1088          return;
1089       end if;
1090
1091       --  If the case expression is a formal object of mode in out, then
1092       --  treat it as having a nonstatic subtype by forcing use of the base
1093       --  type (which has to get passed to Check_Case_Choices below).  Also
1094       --  use base type when the case expression is parenthesized.
1095
1096       if Paren_Count (Exp) > 0
1097         or else (Is_Entity_Name (Exp)
1098                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1099       then
1100          Exp_Type := Exp_Btype;
1101       end if;
1102
1103       --  Call instantiated Analyze_Choices which does the rest of the work
1104
1105       Analyze_Choices
1106         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
1107
1108       if Exp_Type = Universal_Integer and then not Others_Present then
1109          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1110       end if;
1111
1112       --  If all our exits were blocked by unconditional transfers of control,
1113       --  then the entire CASE statement acts as an unconditional transfer of
1114       --  control, so treat it like one, and check unreachable code. Skip this
1115       --  test if we had serious errors preventing any statement analysis.
1116
1117       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1118          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1119          Check_Unreachable_Code (N);
1120       else
1121          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1122       end if;
1123
1124       if not Expander_Active
1125         and then Compile_Time_Known_Value (Expression (N))
1126         and then Serious_Errors_Detected = 0
1127       then
1128          declare
1129             Chosen : constant Node_Id := Find_Static_Alternative (N);
1130             Alt    : Node_Id;
1131
1132          begin
1133             Alt := First (Alternatives (N));
1134             while Present (Alt) loop
1135                if Alt /= Chosen then
1136                   Remove_Warning_Messages (Statements (Alt));
1137                end if;
1138
1139                Next (Alt);
1140             end loop;
1141          end;
1142       end if;
1143    end Analyze_Case_Statement;
1144
1145    ----------------------------
1146    -- Analyze_Exit_Statement --
1147    ----------------------------
1148
1149    --  If the exit includes a name, it must be the name of a currently open
1150    --  loop. Otherwise there must be an innermost open loop on the stack,
1151    --  to which the statement implicitly refers.
1152
1153    procedure Analyze_Exit_Statement (N : Node_Id) is
1154       Target   : constant Node_Id := Name (N);
1155       Cond     : constant Node_Id := Condition (N);
1156       Scope_Id : Entity_Id;
1157       U_Name   : Entity_Id;
1158       Kind     : Entity_Kind;
1159
1160    begin
1161       if No (Cond) then
1162          Check_Unreachable_Code (N);
1163       end if;
1164
1165       if Present (Target) then
1166          Analyze (Target);
1167          U_Name := Entity (Target);
1168
1169          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1170             Error_Msg_N ("invalid loop name in exit statement", N);
1171             return;
1172          else
1173             Set_Has_Exit (U_Name);
1174          end if;
1175
1176       else
1177          U_Name := Empty;
1178       end if;
1179
1180       for J in reverse 0 .. Scope_Stack.Last loop
1181          Scope_Id := Scope_Stack.Table (J).Entity;
1182          Kind := Ekind (Scope_Id);
1183
1184          if Kind = E_Loop
1185            and then (No (Target) or else Scope_Id = U_Name) then
1186             Set_Has_Exit (Scope_Id);
1187             exit;
1188
1189          elsif Kind = E_Block
1190            or else Kind = E_Loop
1191            or else Kind = E_Return_Statement
1192          then
1193             null;
1194
1195          else
1196             Error_Msg_N
1197               ("cannot exit from program unit or accept statement", N);
1198             return;
1199          end if;
1200       end loop;
1201
1202       --  Verify that if present the condition is a Boolean expression
1203
1204       if Present (Cond) then
1205          Analyze_And_Resolve (Cond, Any_Boolean);
1206          Check_Unset_Reference (Cond);
1207       end if;
1208
1209       --  Chain exit statement to associated loop entity
1210
1211       Set_Next_Exit_Statement  (N, First_Exit_Statement (Scope_Id));
1212       Set_First_Exit_Statement (Scope_Id, N);
1213
1214       --  Since the exit may take us out of a loop, any previous assignment
1215       --  statement is not useless, so clear last assignment indications. It
1216       --  is OK to keep other current values, since if the exit statement
1217       --  does not exit, then the current values are still valid.
1218
1219       Kill_Current_Values (Last_Assignment_Only => True);
1220    end Analyze_Exit_Statement;
1221
1222    ----------------------------
1223    -- Analyze_Goto_Statement --
1224    ----------------------------
1225
1226    procedure Analyze_Goto_Statement (N : Node_Id) is
1227       Label       : constant Node_Id := Name (N);
1228       Scope_Id    : Entity_Id;
1229       Label_Scope : Entity_Id;
1230       Label_Ent   : Entity_Id;
1231
1232    begin
1233       Check_Unreachable_Code (N);
1234       Kill_Current_Values (Last_Assignment_Only => True);
1235
1236       Analyze (Label);
1237       Label_Ent := Entity (Label);
1238
1239       --  Ignore previous error
1240
1241       if Label_Ent = Any_Id then
1242          return;
1243
1244       --  We just have a label as the target of a goto
1245
1246       elsif Ekind (Label_Ent) /= E_Label then
1247          Error_Msg_N ("target of goto statement must be a label", Label);
1248          return;
1249
1250       --  Check that the target of the goto is reachable according to Ada
1251       --  scoping rules. Note: the special gotos we generate for optimizing
1252       --  local handling of exceptions would violate these rules, but we mark
1253       --  such gotos as analyzed when built, so this code is never entered.
1254
1255       elsif not Reachable (Label_Ent) then
1256          Error_Msg_N ("target of goto statement is not reachable", Label);
1257          return;
1258       end if;
1259
1260       --  Here if goto passes initial validity checks
1261
1262       Label_Scope := Enclosing_Scope (Label_Ent);
1263
1264       for J in reverse 0 .. Scope_Stack.Last loop
1265          Scope_Id := Scope_Stack.Table (J).Entity;
1266
1267          if Label_Scope = Scope_Id
1268            or else (Ekind (Scope_Id) /= E_Block
1269                      and then Ekind (Scope_Id) /= E_Loop
1270                      and then Ekind (Scope_Id) /= E_Return_Statement)
1271          then
1272             if Scope_Id /= Label_Scope then
1273                Error_Msg_N
1274                  ("cannot exit from program unit or accept statement", N);
1275             end if;
1276
1277             return;
1278          end if;
1279       end loop;
1280
1281       raise Program_Error;
1282    end Analyze_Goto_Statement;
1283
1284    --------------------------
1285    -- Analyze_If_Statement --
1286    --------------------------
1287
1288    --  A special complication arises in the analysis of if statements
1289
1290    --  The expander has circuitry to completely delete code that it
1291    --  can tell will not be executed (as a result of compile time known
1292    --  conditions). In the analyzer, we ensure that code that will be
1293    --  deleted in this manner is analyzed but not expanded. This is
1294    --  obviously more efficient, but more significantly, difficulties
1295    --  arise if code is expanded and then eliminated (e.g. exception
1296    --  table entries disappear). Similarly, itypes generated in deleted
1297    --  code must be frozen from start, because the nodes on which they
1298    --  depend will not be available at the freeze point.
1299
1300    procedure Analyze_If_Statement (N : Node_Id) is
1301       E : Node_Id;
1302
1303       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1304       --  Recursively save value of this global, will be restored on exit
1305
1306       Save_In_Deleted_Code : Boolean;
1307
1308       Del : Boolean := False;
1309       --  This flag gets set True if a True condition has been found,
1310       --  which means that remaining ELSE/ELSIF parts are deleted.
1311
1312       procedure Analyze_Cond_Then (Cnode : Node_Id);
1313       --  This is applied to either the N_If_Statement node itself or
1314       --  to an N_Elsif_Part node. It deals with analyzing the condition
1315       --  and the THEN statements associated with it.
1316
1317       -----------------------
1318       -- Analyze_Cond_Then --
1319       -----------------------
1320
1321       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1322          Cond : constant Node_Id := Condition (Cnode);
1323          Tstm : constant List_Id := Then_Statements (Cnode);
1324
1325       begin
1326          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1327          Analyze_And_Resolve (Cond, Any_Boolean);
1328          Check_Unset_Reference (Cond);
1329          Set_Current_Value_Condition (Cnode);
1330
1331          --  If already deleting, then just analyze then statements
1332
1333          if Del then
1334             Analyze_Statements (Tstm);
1335
1336          --  Compile time known value, not deleting yet
1337
1338          elsif Compile_Time_Known_Value (Cond) then
1339             Save_In_Deleted_Code := In_Deleted_Code;
1340
1341             --  If condition is True, then analyze the THEN statements
1342             --  and set no expansion for ELSE and ELSIF parts.
1343
1344             if Is_True (Expr_Value (Cond)) then
1345                Analyze_Statements (Tstm);
1346                Del := True;
1347                Expander_Mode_Save_And_Set (False);
1348                In_Deleted_Code := True;
1349
1350             --  If condition is False, analyze THEN with expansion off
1351
1352             else -- Is_False (Expr_Value (Cond))
1353                Expander_Mode_Save_And_Set (False);
1354                In_Deleted_Code := True;
1355                Analyze_Statements (Tstm);
1356                Expander_Mode_Restore;
1357                In_Deleted_Code := Save_In_Deleted_Code;
1358             end if;
1359
1360          --  Not known at compile time, not deleting, normal analysis
1361
1362          else
1363             Analyze_Statements (Tstm);
1364          end if;
1365       end Analyze_Cond_Then;
1366
1367    --  Start of Analyze_If_Statement
1368
1369    begin
1370       --  Initialize exit count for else statements. If there is no else
1371       --  part, this count will stay non-zero reflecting the fact that the
1372       --  uncovered else case is an unblocked exit.
1373
1374       Unblocked_Exit_Count := 1;
1375       Analyze_Cond_Then (N);
1376
1377       --  Now to analyze the elsif parts if any are present
1378
1379       if Present (Elsif_Parts (N)) then
1380          E := First (Elsif_Parts (N));
1381          while Present (E) loop
1382             Analyze_Cond_Then (E);
1383             Next (E);
1384          end loop;
1385       end if;
1386
1387       if Present (Else_Statements (N)) then
1388          Analyze_Statements (Else_Statements (N));
1389       end if;
1390
1391       --  If all our exits were blocked by unconditional transfers of control,
1392       --  then the entire IF statement acts as an unconditional transfer of
1393       --  control, so treat it like one, and check unreachable code.
1394
1395       if Unblocked_Exit_Count = 0 then
1396          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1397          Check_Unreachable_Code (N);
1398       else
1399          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1400       end if;
1401
1402       if Del then
1403          Expander_Mode_Restore;
1404          In_Deleted_Code := Save_In_Deleted_Code;
1405       end if;
1406
1407       if not Expander_Active
1408         and then Compile_Time_Known_Value (Condition (N))
1409         and then Serious_Errors_Detected = 0
1410       then
1411          if Is_True (Expr_Value (Condition (N))) then
1412             Remove_Warning_Messages (Else_Statements (N));
1413
1414             if Present (Elsif_Parts (N)) then
1415                E := First (Elsif_Parts (N));
1416                while Present (E) loop
1417                   Remove_Warning_Messages (Then_Statements (E));
1418                   Next (E);
1419                end loop;
1420             end if;
1421
1422          else
1423             Remove_Warning_Messages (Then_Statements (N));
1424          end if;
1425       end if;
1426    end Analyze_If_Statement;
1427
1428    ----------------------------------------
1429    -- Analyze_Implicit_Label_Declaration --
1430    ----------------------------------------
1431
1432    --  An implicit label declaration is generated in the innermost
1433    --  enclosing declarative part. This is done for labels as well as
1434    --  block and loop names.
1435
1436    --  Note: any changes in this routine may need to be reflected in
1437    --  Analyze_Label_Entity.
1438
1439    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1440       Id : constant Node_Id := Defining_Identifier (N);
1441    begin
1442       Enter_Name          (Id);
1443       Set_Ekind           (Id, E_Label);
1444       Set_Etype           (Id, Standard_Void_Type);
1445       Set_Enclosing_Scope (Id, Current_Scope);
1446    end Analyze_Implicit_Label_Declaration;
1447
1448    ------------------------------
1449    -- Analyze_Iteration_Scheme --
1450    ------------------------------
1451
1452    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1453
1454       procedure Process_Bounds (R : Node_Id);
1455       --  If the iteration is given by a range, create temporaries and
1456       --  assignment statements block to capture the bounds and perform
1457       --  required finalization actions in case a bound includes a function
1458       --  call that uses the temporary stack. We first pre-analyze a copy of
1459       --  the range in order to determine the expected type, and analyze and
1460       --  resolve the original bounds.
1461
1462       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1463       --  If the bounds are given by a 'Range reference on a function call
1464       --  that returns a controlled array, introduce an explicit declaration
1465       --  to capture the bounds, so that the function result can be finalized
1466       --  in timely fashion.
1467
1468       --------------------
1469       -- Process_Bounds --
1470       --------------------
1471
1472       procedure Process_Bounds (R : Node_Id) is
1473          Loc          : constant Source_Ptr := Sloc (N);
1474          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1475          Lo           : constant Node_Id := Low_Bound  (R);
1476          Hi           : constant Node_Id := High_Bound (R);
1477          New_Lo_Bound : Node_Id := Empty;
1478          New_Hi_Bound : Node_Id := Empty;
1479          Typ          : Entity_Id;
1480          Save_Analysis : Boolean;
1481
1482          function One_Bound
1483            (Original_Bound : Node_Id;
1484             Analyzed_Bound : Node_Id) return Node_Id;
1485          --  Capture value of bound and return captured value
1486
1487          ---------------
1488          -- One_Bound --
1489          ---------------
1490
1491          function One_Bound
1492            (Original_Bound : Node_Id;
1493             Analyzed_Bound : Node_Id) return Node_Id
1494          is
1495             Assign : Node_Id;
1496             Id     : Entity_Id;
1497             Decl   : Node_Id;
1498
1499          begin
1500             --  If the bound is a constant or an object, no need for a separate
1501             --  declaration. If the bound is the result of previous expansion
1502             --  it is already analyzed and should not be modified. Note that
1503             --  the Bound will be resolved later, if needed, as part of the
1504             --  call to Make_Index (literal bounds may need to be resolved to
1505             --  type Integer).
1506
1507             if Analyzed (Original_Bound) then
1508                return Original_Bound;
1509
1510             elsif Nkind_In (Analyzed_Bound, N_Integer_Literal,
1511                                             N_Character_Literal)
1512               or else Is_Entity_Name (Analyzed_Bound)
1513             then
1514                Analyze_And_Resolve (Original_Bound, Typ);
1515                return Original_Bound;
1516             end if;
1517
1518             --  Here we need to capture the value
1519
1520             Analyze_And_Resolve (Original_Bound, Typ);
1521
1522             Id := Make_Temporary (Loc, 'S', Original_Bound);
1523
1524             --  Normally, the best approach is simply to generate a constant
1525             --  declaration that captures the bound. However, there is a nasty
1526             --  case where this is wrong. If the bound is complex, and has a
1527             --  possible use of the secondary stack, we need to generate a
1528             --  separate assignment statement to ensure the creation of a block
1529             --  which will release the secondary stack.
1530
1531             --  We prefer the constant declaration, since it leaves us with a
1532             --  proper trace of the value, useful in optimizations that get rid
1533             --  of junk range checks.
1534
1535             --  Probably we want something like the Side_Effect_Free routine
1536             --  in Exp_Util, but for now, we just optimize the cases of 'Last
1537             --  and 'First applied to an entity, since these are the important
1538             --  cases for range check optimizations.
1539
1540             if Nkind (Original_Bound) = N_Attribute_Reference
1541               and then (Attribute_Name (Original_Bound) = Name_First
1542                           or else
1543                         Attribute_Name (Original_Bound) = Name_Last)
1544               and then Is_Entity_Name (Prefix (Original_Bound))
1545             then
1546                Decl :=
1547                  Make_Object_Declaration (Loc,
1548                    Defining_Identifier => Id,
1549                    Constant_Present    => True,
1550                    Object_Definition   => New_Occurrence_Of (Typ, Loc),
1551                    Expression          => Relocate_Node (Original_Bound));
1552
1553                Insert_Before (Parent (N), Decl);
1554                Analyze (Decl);
1555                Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1556                return Expression (Decl);
1557             end if;
1558
1559             --  Here we make a declaration with a separate assignment statement
1560
1561             Decl :=
1562               Make_Object_Declaration (Loc,
1563                 Defining_Identifier => Id,
1564                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1565
1566             Insert_Before (Parent (N), Decl);
1567             Analyze (Decl);
1568
1569             Assign :=
1570               Make_Assignment_Statement (Loc,
1571                 Name        => New_Occurrence_Of (Id, Loc),
1572                 Expression  => Relocate_Node (Original_Bound));
1573
1574             Insert_Before (Parent (N), Assign);
1575             Analyze (Assign);
1576
1577             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1578
1579             if Nkind (Assign) = N_Assignment_Statement then
1580                return Expression (Assign);
1581             else
1582                return Original_Bound;
1583             end if;
1584          end One_Bound;
1585
1586       --  Start of processing for Process_Bounds
1587
1588       begin
1589          --  Determine expected type of range by analyzing separate copy
1590          --  Do the analysis and resolution of the copy of the bounds with
1591          --  expansion disabled, to prevent the generation of finalization
1592          --  actions on each bound. This prevents memory leaks when the
1593          --  bounds contain calls to functions returning controlled arrays.
1594
1595          Set_Parent (R_Copy, Parent (R));
1596          Save_Analysis := Full_Analysis;
1597          Full_Analysis := False;
1598          Expander_Mode_Save_And_Set (False);
1599
1600          Analyze (R_Copy);
1601
1602          if Is_Overloaded (R_Copy) then
1603
1604             --  Apply preference rules for range of predefined integer types,
1605             --  or diagnose true ambiguity.
1606
1607             declare
1608                I     : Interp_Index;
1609                It    : Interp;
1610                Found : Entity_Id := Empty;
1611
1612             begin
1613                Get_First_Interp (R_Copy, I, It);
1614                while Present (It.Typ) loop
1615                   if Is_Discrete_Type (It.Typ) then
1616                      if No (Found) then
1617                         Found := It.Typ;
1618                      else
1619                         if Scope (Found) = Standard_Standard then
1620                            null;
1621
1622                         elsif Scope (It.Typ) = Standard_Standard then
1623                            Found := It.Typ;
1624
1625                         else
1626                            --  Both of them are user-defined
1627
1628                            Error_Msg_N
1629                              ("ambiguous bounds in range of iteration",
1630                                R_Copy);
1631                            Error_Msg_N ("\possible interpretations:", R_Copy);
1632                            Error_Msg_NE ("\\} ", R_Copy, Found);
1633                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1634                            exit;
1635                         end if;
1636                      end if;
1637                   end if;
1638
1639                   Get_Next_Interp (I, It);
1640                end loop;
1641             end;
1642          end if;
1643
1644          Resolve (R_Copy);
1645          Expander_Mode_Restore;
1646          Full_Analysis := Save_Analysis;
1647
1648          Typ := Etype (R_Copy);
1649
1650          --  If the type of the discrete range is Universal_Integer, then
1651          --  the bound's type must be resolved to Integer, and any object
1652          --  used to hold the bound must also have type Integer, unless the
1653          --  literal bounds are constant-folded expressions that carry a user-
1654          --  defined type.
1655
1656          if Typ = Universal_Integer then
1657             if Nkind (Lo) = N_Integer_Literal
1658               and then Present (Etype (Lo))
1659               and then Scope (Etype (Lo)) /= Standard_Standard
1660             then
1661                Typ := Etype (Lo);
1662
1663             elsif Nkind (Hi) = N_Integer_Literal
1664               and then Present (Etype (Hi))
1665               and then Scope (Etype (Hi)) /= Standard_Standard
1666             then
1667                Typ := Etype (Hi);
1668
1669             else
1670                Typ := Standard_Integer;
1671             end if;
1672          end if;
1673
1674          Set_Etype (R, Typ);
1675
1676          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1677          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1678
1679          --  Propagate staticness to loop range itself, in case the
1680          --  corresponding subtype is static.
1681
1682          if New_Lo_Bound /= Lo
1683            and then Is_Static_Expression (New_Lo_Bound)
1684          then
1685             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1686          end if;
1687
1688          if New_Hi_Bound /= Hi
1689            and then Is_Static_Expression (New_Hi_Bound)
1690          then
1691             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1692          end if;
1693       end Process_Bounds;
1694
1695       --------------------------------------
1696       -- Check_Controlled_Array_Attribute --
1697       --------------------------------------
1698
1699       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1700       begin
1701          if Nkind (DS) = N_Attribute_Reference
1702             and then Is_Entity_Name (Prefix (DS))
1703             and then Ekind (Entity (Prefix (DS))) = E_Function
1704             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1705             and then
1706               Is_Controlled (
1707                 Component_Type (Etype (Entity (Prefix (DS)))))
1708             and then Expander_Active
1709          then
1710             declare
1711                Loc  : constant Source_Ptr := Sloc (N);
1712                Arr  : constant Entity_Id := Etype (Entity (Prefix (DS)));
1713                Indx : constant Entity_Id :=
1714                         Base_Type (Etype (First_Index (Arr)));
1715                Subt : constant Entity_Id := Make_Temporary (Loc, 'S');
1716                Decl : Node_Id;
1717
1718             begin
1719                Decl :=
1720                  Make_Subtype_Declaration (Loc,
1721                    Defining_Identifier => Subt,
1722                    Subtype_Indication  =>
1723                       Make_Subtype_Indication (Loc,
1724                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1725                         Constraint =>
1726                           Make_Range_Constraint (Loc,
1727                             Relocate_Node (DS))));
1728                Insert_Before (Parent (N), Decl);
1729                Analyze (Decl);
1730
1731                Rewrite (DS,
1732                   Make_Attribute_Reference (Loc,
1733                     Prefix => New_Reference_To (Subt, Loc),
1734                     Attribute_Name => Attribute_Name (DS)));
1735                Analyze (DS);
1736             end;
1737          end if;
1738       end Check_Controlled_Array_Attribute;
1739
1740    --  Start of processing for Analyze_Iteration_Scheme
1741
1742    begin
1743       --  For an infinite loop, there is no iteration scheme
1744
1745       if No (N) then
1746          return;
1747
1748       else
1749          declare
1750             Cond : constant Node_Id := Condition (N);
1751
1752          begin
1753             --  For WHILE loop, verify that the condition is a Boolean
1754             --  expression and resolve and check it.
1755
1756             if Present (Cond) then
1757                Analyze_And_Resolve (Cond, Any_Boolean);
1758                Check_Unset_Reference (Cond);
1759                Set_Current_Value_Condition (N);
1760                return;
1761
1762             --  Else we have a FOR loop
1763
1764             else
1765                declare
1766                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1767                   Id : constant Entity_Id := Defining_Identifier (LP);
1768                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1769
1770                begin
1771                   Enter_Name (Id);
1772
1773                   --  We always consider the loop variable to be referenced,
1774                   --  since the loop may be used just for counting purposes.
1775
1776                   Generate_Reference (Id, N, ' ');
1777
1778                   --  Check for case of loop variable hiding a local
1779                   --  variable (used later on to give a nice warning
1780                   --  if the hidden variable is never assigned).
1781
1782                   declare
1783                      H : constant Entity_Id := Homonym (Id);
1784                   begin
1785                      if Present (H)
1786                        and then Enclosing_Dynamic_Scope (H) =
1787                                 Enclosing_Dynamic_Scope (Id)
1788                        and then Ekind (H) = E_Variable
1789                        and then Is_Discrete_Type (Etype (H))
1790                      then
1791                         Set_Hiding_Loop_Variable (H, Id);
1792                      end if;
1793                   end;
1794
1795                   --  Now analyze the subtype definition. If it is
1796                   --  a range, create temporaries for bounds.
1797
1798                   if Nkind (DS) = N_Range
1799                     and then Expander_Active
1800                   then
1801                      Process_Bounds (DS);
1802                   else
1803                      Analyze (DS);
1804                   end if;
1805
1806                   if DS = Error then
1807                      return;
1808                   end if;
1809
1810                   --  The subtype indication may denote the completion
1811                   --  of an incomplete type declaration.
1812
1813                   if Is_Entity_Name (DS)
1814                     and then Present (Entity (DS))
1815                     and then Is_Type (Entity (DS))
1816                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1817                   then
1818                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1819                      Set_Etype  (DS, Entity (DS));
1820                   end if;
1821
1822                   if not Is_Discrete_Type (Etype (DS)) then
1823                      Wrong_Type (DS, Any_Discrete);
1824                      Set_Etype (DS, Any_Type);
1825                   end if;
1826
1827                   Check_Controlled_Array_Attribute (DS);
1828
1829                   Make_Index (DS, LP);
1830
1831                   Set_Ekind          (Id, E_Loop_Parameter);
1832                   Set_Etype          (Id, Etype (DS));
1833
1834                   --  Treat a range as an implicit reference to the type, to
1835                   --  inhibit spurious warnings.
1836
1837                   Generate_Reference (Base_Type (Etype (DS)), N, ' ');
1838                   Set_Is_Known_Valid (Id, True);
1839
1840                   --  The loop is not a declarative part, so the only entity
1841                   --  declared "within" must be frozen explicitly.
1842
1843                   declare
1844                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1845                   begin
1846                      if Is_Non_Empty_List (Flist) then
1847                         Insert_Actions (N, Flist);
1848                      end if;
1849                   end;
1850
1851                   --  Check for null or possibly null range and issue warning.
1852                   --  We suppress such messages in generic templates and
1853                   --  instances, because in practice they tend to be dubious
1854                   --  in these cases.
1855
1856                   if Nkind (DS) = N_Range
1857                     and then Comes_From_Source (N)
1858                   then
1859                      declare
1860                         L : constant Node_Id := Low_Bound  (DS);
1861                         H : constant Node_Id := High_Bound (DS);
1862
1863                      begin
1864                         --  If range of loop is null, issue warning
1865
1866                         if Compile_Time_Compare
1867                             (L, H, Assume_Valid => True) = GT
1868                         then
1869                            --  Suppress the warning if inside a generic
1870                            --  template or instance, since in practice
1871                            --  they tend to be dubious in these cases since
1872                            --  they can result from intended parametrization.
1873
1874                            if not Inside_A_Generic
1875                               and then not In_Instance
1876                            then
1877                               --  Specialize msg if invalid values could make
1878                               --  the loop non-null after all.
1879
1880                               if Compile_Time_Compare
1881                                    (L, H, Assume_Valid => False) = GT
1882                               then
1883                                  Error_Msg_N
1884                                    ("?loop range is null, "
1885                                     & "loop will not execute",
1886                                     DS);
1887
1888                                  --  Since we know the range of the loop is
1889                                  --  null, set the appropriate flag to remove
1890                                  --  the loop entirely during expansion.
1891
1892                                  Set_Is_Null_Loop (Parent (N));
1893
1894                               --  Here is where the loop could execute because
1895                               --  of invalid values, so issue appropriate
1896                               --  message and in this case we do not set the
1897                               --  Is_Null_Loop flag since the loop may execute.
1898
1899                               else
1900                                  Error_Msg_N
1901                                    ("?loop range may be null, "
1902                                     & "loop may not execute",
1903                                     DS);
1904                                  Error_Msg_N
1905                                    ("?can only execute if invalid values "
1906                                     & "are present",
1907                                     DS);
1908                               end if;
1909                            end if;
1910
1911                            --  In either case, suppress warnings in the body of
1912                            --  the loop, since it is likely that these warnings
1913                            --  will be inappropriate if the loop never actually
1914                            --  executes, which is unlikely.
1915
1916                            Set_Suppress_Loop_Warnings (Parent (N));
1917
1918                         --  The other case for a warning is a reverse loop
1919                         --  where the upper bound is the integer literal
1920                         --  zero or one, and the lower bound can be positive.
1921
1922                         --  For example, we have
1923
1924                         --     for J in reverse N .. 1 loop
1925
1926                         --  In practice, this is very likely to be a case
1927                         --  of reversing the bounds incorrectly in the range.
1928
1929                         elsif Reverse_Present (LP)
1930                           and then Nkind (Original_Node (H)) =
1931                                                           N_Integer_Literal
1932                           and then (Intval (Original_Node (H)) = Uint_0
1933                                       or else
1934                                     Intval (Original_Node (H)) = Uint_1)
1935                         then
1936                            Error_Msg_N ("?loop range may be null", DS);
1937                            Error_Msg_N ("\?bounds may be wrong way round", DS);
1938                         end if;
1939                      end;
1940                   end if;
1941                end;
1942             end if;
1943          end;
1944       end if;
1945    end Analyze_Iteration_Scheme;
1946
1947    -------------------
1948    -- Analyze_Label --
1949    -------------------
1950
1951    --  Note: the semantic work required for analyzing labels (setting them as
1952    --  reachable) was done in a prepass through the statements in the block,
1953    --  so that forward gotos would be properly handled. See Analyze_Statements
1954    --  for further details. The only processing required here is to deal with
1955    --  optimizations that depend on an assumption of sequential control flow,
1956    --  since of course the occurrence of a label breaks this assumption.
1957
1958    procedure Analyze_Label (N : Node_Id) is
1959       pragma Warnings (Off, N);
1960    begin
1961       Kill_Current_Values;
1962    end Analyze_Label;
1963
1964    --------------------------
1965    -- Analyze_Label_Entity --
1966    --------------------------
1967
1968    procedure Analyze_Label_Entity (E : Entity_Id) is
1969    begin
1970       Set_Ekind           (E, E_Label);
1971       Set_Etype           (E, Standard_Void_Type);
1972       Set_Enclosing_Scope (E, Current_Scope);
1973       Set_Reachable       (E, True);
1974    end Analyze_Label_Entity;
1975
1976    ----------------------------
1977    -- Analyze_Loop_Statement --
1978    ----------------------------
1979
1980    procedure Analyze_Loop_Statement (N : Node_Id) is
1981       Loop_Statement : constant Node_Id := N;
1982
1983       Id   : constant Node_Id := Identifier (Loop_Statement);
1984       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
1985       Ent  : Entity_Id;
1986
1987    begin
1988       if Present (Id) then
1989
1990          --  Make name visible, e.g. for use in exit statements. Loop
1991          --  labels are always considered to be referenced.
1992
1993          Analyze (Id);
1994          Ent := Entity (Id);
1995
1996          --  Guard against serious error (typically, a scope mismatch when
1997          --  semantic analysis is requested) by creating loop entity to
1998          --  continue analysis.
1999
2000          if No (Ent) then
2001             if Total_Errors_Detected /= 0 then
2002                Ent :=
2003                  New_Internal_Entity
2004                    (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2005             else
2006                raise Program_Error;
2007             end if;
2008
2009          else
2010             Generate_Reference  (Ent, Loop_Statement, ' ');
2011             Generate_Definition (Ent);
2012
2013             --  If we found a label, mark its type. If not, ignore it, since it
2014             --  means we have a conflicting declaration, which would already
2015             --  have been diagnosed at declaration time. Set Label_Construct
2016             --  of the implicit label declaration, which is not created by the
2017             --  parser for generic units.
2018
2019             if Ekind (Ent) = E_Label then
2020                Set_Ekind (Ent, E_Loop);
2021
2022                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
2023                   Set_Label_Construct (Parent (Ent), Loop_Statement);
2024                end if;
2025             end if;
2026          end if;
2027
2028       --  Case of no identifier present
2029
2030       else
2031          Ent :=
2032            New_Internal_Entity
2033              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2034          Set_Etype (Ent,  Standard_Void_Type);
2035          Set_Parent (Ent, Loop_Statement);
2036       end if;
2037
2038       --  Kill current values on entry to loop, since statements in body of
2039       --  loop may have been executed before the loop is entered. Similarly we
2040       --  kill values after the loop, since we do not know that the body of the
2041       --  loop was executed.
2042
2043       Kill_Current_Values;
2044       Push_Scope (Ent);
2045       Analyze_Iteration_Scheme (Iter);
2046       Analyze_Statements (Statements (Loop_Statement));
2047       Process_End_Label (Loop_Statement, 'e', Ent);
2048       End_Scope;
2049       Kill_Current_Values;
2050
2051       --  Check for infinite loop. Skip check for generated code, since it
2052       --  justs waste time and makes debugging the routine called harder.
2053
2054       --  Note that we have to wait till the body of the loop is fully analyzed
2055       --  before making this call, since Check_Infinite_Loop_Warning relies on
2056       --  being able to use semantic visibility information to find references.
2057
2058       if Comes_From_Source (N) then
2059          Check_Infinite_Loop_Warning (N);
2060       end if;
2061
2062       --  Code after loop is unreachable if the loop has no WHILE or FOR
2063       --  and contains no EXIT statements within the body of the loop.
2064
2065       if No (Iter) and then not Has_Exit (Ent) then
2066          Check_Unreachable_Code (N);
2067       end if;
2068    end Analyze_Loop_Statement;
2069
2070    ----------------------------
2071    -- Analyze_Null_Statement --
2072    ----------------------------
2073
2074    --  Note: the semantics of the null statement is implemented by a single
2075    --  null statement, too bad everything isn't as simple as this!
2076
2077    procedure Analyze_Null_Statement (N : Node_Id) is
2078       pragma Warnings (Off, N);
2079    begin
2080       null;
2081    end Analyze_Null_Statement;
2082
2083    ------------------------
2084    -- Analyze_Statements --
2085    ------------------------
2086
2087    procedure Analyze_Statements (L : List_Id) is
2088       S   : Node_Id;
2089       Lab : Entity_Id;
2090
2091    begin
2092       --  The labels declared in the statement list are reachable from
2093       --  statements in the list. We do this as a prepass so that any
2094       --  goto statement will be properly flagged if its target is not
2095       --  reachable. This is not required, but is nice behavior!
2096
2097       S := First (L);
2098       while Present (S) loop
2099          if Nkind (S) = N_Label then
2100             Analyze (Identifier (S));
2101             Lab := Entity (Identifier (S));
2102
2103             --  If we found a label mark it as reachable
2104
2105             if Ekind (Lab) = E_Label then
2106                Generate_Definition (Lab);
2107                Set_Reachable (Lab);
2108
2109                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
2110                   Set_Label_Construct (Parent (Lab), S);
2111                end if;
2112
2113             --  If we failed to find a label, it means the implicit declaration
2114             --  of the label was hidden.  A for-loop parameter can do this to
2115             --  a label with the same name inside the loop, since the implicit
2116             --  label declaration is in the innermost enclosing body or block
2117             --  statement.
2118
2119             else
2120                Error_Msg_Sloc := Sloc (Lab);
2121                Error_Msg_N
2122                  ("implicit label declaration for & is hidden#",
2123                   Identifier (S));
2124             end if;
2125          end if;
2126
2127          Next (S);
2128       end loop;
2129
2130       --  Perform semantic analysis on all statements
2131
2132       Conditional_Statements_Begin;
2133
2134       S := First (L);
2135       while Present (S) loop
2136          Analyze (S);
2137          Next (S);
2138       end loop;
2139
2140       Conditional_Statements_End;
2141
2142       --  Make labels unreachable. Visibility is not sufficient, because
2143       --  labels in one if-branch for example are not reachable from the
2144       --  other branch, even though their declarations are in the enclosing
2145       --  declarative part.
2146
2147       S := First (L);
2148       while Present (S) loop
2149          if Nkind (S) = N_Label then
2150             Set_Reachable (Entity (Identifier (S)), False);
2151          end if;
2152
2153          Next (S);
2154       end loop;
2155    end Analyze_Statements;
2156
2157    ----------------------------
2158    -- Check_Unreachable_Code --
2159    ----------------------------
2160
2161    procedure Check_Unreachable_Code (N : Node_Id) is
2162       Error_Loc : Source_Ptr;
2163       P         : Node_Id;
2164
2165    begin
2166       if Is_List_Member (N)
2167         and then Comes_From_Source (N)
2168       then
2169          declare
2170             Nxt : Node_Id;
2171
2172          begin
2173             Nxt := Original_Node (Next (N));
2174
2175             --  If a label follows us, then we never have dead code, since
2176             --  someone could branch to the label, so we just ignore it.
2177
2178             if Nkind (Nxt) = N_Label then
2179                return;
2180
2181             --  Otherwise see if we have a real statement following us
2182
2183             elsif Present (Nxt)
2184               and then Comes_From_Source (Nxt)
2185               and then Is_Statement (Nxt)
2186             then
2187                --  Special very annoying exception. If we have a return that
2188                --  follows a raise, then we allow it without a warning, since
2189                --  the Ada RM annoyingly requires a useless return here!
2190
2191                if Nkind (Original_Node (N)) /= N_Raise_Statement
2192                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2193                then
2194                   --  The rather strange shenanigans with the warning message
2195                   --  here reflects the fact that Kill_Dead_Code is very good
2196                   --  at removing warnings in deleted code, and this is one
2197                   --  warning we would prefer NOT to have removed.
2198
2199                   Error_Loc := Sloc (Nxt);
2200
2201                   --  If we have unreachable code, analyze and remove the
2202                   --  unreachable code, since it is useless and we don't
2203                   --  want to generate junk warnings.
2204
2205                   --  We skip this step if we are not in code generation mode.
2206                   --  This is the one case where we remove dead code in the
2207                   --  semantics as opposed to the expander, and we do not want
2208                   --  to remove code if we are not in code generation mode,
2209                   --  since this messes up the ASIS trees.
2210
2211                   --  Note that one might react by moving the whole circuit to
2212                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2213
2214                   if Operating_Mode = Generate_Code then
2215                      loop
2216                         Nxt := Next (N);
2217
2218                         --  Quit deleting when we have nothing more to delete
2219                         --  or if we hit a label (since someone could transfer
2220                         --  control to a label, so we should not delete it).
2221
2222                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2223
2224                         --  Statement/declaration is to be deleted
2225
2226                         Analyze (Nxt);
2227                         Remove (Nxt);
2228                         Kill_Dead_Code (Nxt);
2229                      end loop;
2230                   end if;
2231
2232                   --  Now issue the warning
2233
2234                   Error_Msg ("?unreachable code!", Error_Loc);
2235                end if;
2236
2237             --  If the unconditional transfer of control instruction is
2238             --  the last statement of a sequence, then see if our parent
2239             --  is one of the constructs for which we count unblocked exits,
2240             --  and if so, adjust the count.
2241
2242             else
2243                P := Parent (N);
2244
2245                --  Statements in THEN part or ELSE part of IF statement
2246
2247                if Nkind (P) = N_If_Statement then
2248                   null;
2249
2250                --  Statements in ELSIF part of an IF statement
2251
2252                elsif Nkind (P) = N_Elsif_Part then
2253                   P := Parent (P);
2254                   pragma Assert (Nkind (P) = N_If_Statement);
2255
2256                --  Statements in CASE statement alternative
2257
2258                elsif Nkind (P) = N_Case_Statement_Alternative then
2259                   P := Parent (P);
2260                   pragma Assert (Nkind (P) = N_Case_Statement);
2261
2262                --  Statements in body of block
2263
2264                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2265                  and then Nkind (Parent (P)) = N_Block_Statement
2266                then
2267                   null;
2268
2269                --  Statements in exception handler in a block
2270
2271                elsif Nkind (P) = N_Exception_Handler
2272                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2273                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2274                then
2275                   null;
2276
2277                --  None of these cases, so return
2278
2279                else
2280                   return;
2281                end if;
2282
2283                --  This was one of the cases we are looking for (i.e. the
2284                --  parent construct was IF, CASE or block) so decrement count.
2285
2286                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2287             end if;
2288          end;
2289       end if;
2290    end Check_Unreachable_Code;
2291
2292 end Sem_Ch5;