gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Aux;  use Sem_Aux;
  42 with Sem_Case; use Sem_Case;
  43 with Sem_Ch3;  use Sem_Ch3;
  44 with Sem_Ch8;  use Sem_Ch8;
  45 with Sem_Disp; use Sem_Disp;
  46 with Sem_Elab; use Sem_Elab;
  47 with Sem_Eval; use Sem_Eval;
  48 with Sem_Res;  use Sem_Res;
  49 with Sem_Type; use Sem_Type;
  50 with Sem_Util; use Sem_Util;
  51 with Sem_Warn; use Sem_Warn;
  52 with Snames;   use Snames;
  53 with Stand;    use Stand;
  54 with Sinfo;    use Sinfo;
  55 with Targparm; use Targparm;
  56 with Tbuild;   use Tbuild;
  57 with Uintp;    use Uintp;
  58
  59 package body Sem_Ch5 is
  60
  61    Unblocked_Exit_Count : Nat := 0;
  62    --  This variable is used when processing if statements, case statements,
  63    --  and block statements. It counts the number of exit points that are not
  64    --  blocked by unconditional transfer instructions: for IF and CASE, these
  65    --  are the branches of the conditional; for a block, they are the statement
  66    --  sequence of the block, and the statement sequences of any exception
  67    --  handlers that are part of the block. When processing is complete, if
  68    --  this count is zero, it means that control cannot fall through the IF,
  69    --  CASE or block statement. This is used for the generation of warning
  70    --  messages. This variable is recursively saved on entry to processing the
  71    --  construct, and restored on exit.
  72
  73    ------------------------
  74    -- Analyze_Assignment --
  75    ------------------------
  76
  77    procedure Analyze_Assignment (N : Node_Id) is
  78       Lhs  : constant Node_Id := Name (N);
  79       Rhs  : constant Node_Id := Expression (N);
  80       T1   : Entity_Id;
  81       T2   : Entity_Id;
  82       Decl : Node_Id;
  83
  84       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  85       --  N is the node for the left hand side of an assignment, and it is not
  86       --  a variable. This routine issues an appropriate diagnostic.
  87
  88       procedure Kill_Lhs;
  89       --  This is called to kill current value settings of a simple variable
  90       --  on the left hand side. We call it if we find any error in analyzing
  91       --  the assignment, and at the end of processing before setting any new
  92       --  current values in place.
  93
  94       procedure Set_Assignment_Type
  95         (Opnd      : Node_Id;
  96          Opnd_Type : in out Entity_Id);
  97       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
  98       --  is the nominal subtype. This procedure is used to deal with cases
  99       --  where the nominal subtype must be replaced by the actual subtype.
 100
 101       -------------------------------
 102       -- Diagnose_Non_Variable_Lhs --
 103       -------------------------------
 104
 105       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 106       begin
 107          --  Not worth posting another error if left hand side already
 108          --  flagged as being illegal in some respect.
 109
 110          if Error_Posted (N) then
 111             return;
 112
 113          --  Some special bad cases of entity names
 114
 115          elsif Is_Entity_Name (N) then
 116             declare
 117                Ent : constant Entity_Id := Entity (N);
 118
 119             begin
 120                if Ekind (Ent) = E_In_Parameter then
 121                   Error_Msg_N
 122                     ("assignment to IN mode parameter not allowed", N);
 123
 124                --  Renamings of protected private components are turned into
 125                --  constants when compiling a protected function. In the case
 126                --  of single protected types, the private component appears
 127                --  directly.
 128
 129                elsif (Is_Prival (Ent)
 130                         and then
 131                           (Ekind (Current_Scope) = E_Function
 132                              or else Ekind (Enclosing_Dynamic_Scope (
 133                                        Current_Scope)) = E_Function))
 134                    or else
 135                      (Ekind (Ent) = E_Component
 136                         and then Is_Protected_Type (Scope (Ent)))
 137                then
 138                   Error_Msg_N
 139                     ("protected function cannot modify protected object", N);
 140
 141                elsif Ekind (Ent) = E_Loop_Parameter then
 142                   Error_Msg_N
 143                     ("assignment to loop parameter not allowed", N);
 144
 145                else
 146                   Error_Msg_N
 147                     ("left hand side of assignment must be a variable", N);
 148                end if;
 149             end;
 150
 151          --  For indexed components or selected components, test prefix
 152
 153          elsif Nkind (N) = N_Indexed_Component then
 154             Diagnose_Non_Variable_Lhs (Prefix (N));
 155
 156          --  Another special case for assignment to discriminant
 157
 158          elsif Nkind (N) = N_Selected_Component then
 159             if Present (Entity (Selector_Name (N)))
 160               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 161             then
 162                Error_Msg_N
 163                  ("assignment to discriminant not allowed", N);
 164             else
 165                Diagnose_Non_Variable_Lhs (Prefix (N));
 166             end if;
 167
 168          else
 169             --  If we fall through, we have no special message to issue!
 170
 171             Error_Msg_N ("left hand side of assignment must be a variable", N);
 172          end if;
 173       end Diagnose_Non_Variable_Lhs;
 174
 175       --------------
 176       -- Kill_LHS --
 177       --------------
 178
 179       procedure Kill_Lhs is
 180       begin
 181          if Is_Entity_Name (Lhs) then
 182             declare
 183                Ent : constant Entity_Id := Entity (Lhs);
 184             begin
 185                if Present (Ent) then
 186                   Kill_Current_Values (Ent);
 187                end if;
 188             end;
 189          end if;
 190       end Kill_Lhs;
 191
 192       -------------------------
 193       -- Set_Assignment_Type --
 194       -------------------------
 195
 196       procedure Set_Assignment_Type
 197         (Opnd      : Node_Id;
 198          Opnd_Type : in out Entity_Id)
 199       is
 200       begin
 201          Require_Entity (Opnd);
 202
 203          --  If the assignment operand is an in-out or out parameter, then we
 204          --  get the actual subtype (needed for the unconstrained case).
 205          --  If the operand is the actual in an entry declaration, then within
 206          --  the accept statement it is replaced with a local renaming, which
 207          --  may also have an actual subtype.
 208
 209          if Is_Entity_Name (Opnd)
 210            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 211                       or else Ekind (Entity (Opnd)) =
 212                            E_In_Out_Parameter
 213                       or else Ekind (Entity (Opnd)) =
 214                            E_Generic_In_Out_Parameter
 215                       or else
 216                         (Ekind (Entity (Opnd)) = E_Variable
 217                           and then Nkind (Parent (Entity (Opnd))) =
 218                              N_Object_Renaming_Declaration
 219                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 220                              N_Accept_Statement))
 221          then
 222             Opnd_Type := Get_Actual_Subtype (Opnd);
 223
 224          --  If assignment operand is a component reference, then we get the
 225          --  actual subtype of the component for the unconstrained case.
 226
 227          elsif Nkind_In (Opnd, N_Selected_Component, N_Explicit_Dereference)
 228            and then not Is_Unchecked_Union (Opnd_Type)
 229          then
 230             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 231
 232             if Present (Decl) then
 233                Insert_Action (N, Decl);
 234                Mark_Rewrite_Insertion (Decl);
 235                Analyze (Decl);
 236                Opnd_Type := Defining_Identifier (Decl);
 237                Set_Etype (Opnd, Opnd_Type);
 238                Freeze_Itype (Opnd_Type, N);
 239
 240             elsif Is_Constrained (Etype (Opnd)) then
 241                Opnd_Type := Etype (Opnd);
 242             end if;
 243
 244          --  For slice, use the constrained subtype created for the slice
 245
 246          elsif Nkind (Opnd) = N_Slice then
 247             Opnd_Type := Etype (Opnd);
 248          end if;
 249       end Set_Assignment_Type;
 250
 251    --  Start of processing for Analyze_Assignment
 252
 253    begin
 254       Mark_Coextensions (N, Rhs);
 255
 256       Analyze (Rhs);
 257       Analyze (Lhs);
 258
 259       --  Start type analysis for assignment
 260
 261       T1 := Etype (Lhs);
 262
 263       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 264       --  must compute the intersection of the possible types on each side.
 265
 266       if Is_Overloaded (Lhs) then
 267          declare
 268             I  : Interp_Index;
 269             It : Interp;
 270
 271          begin
 272             T1 := Any_Type;
 273             Get_First_Interp (Lhs, I, It);
 274
 275             while Present (It.Typ) loop
 276                if Has_Compatible_Type (Rhs, It.Typ) then
 277                   if T1 /= Any_Type then
 278
 279                      --  An explicit dereference is overloaded if the prefix
 280                      --  is. Try to remove the ambiguity on the prefix, the
 281                      --  error will be posted there if the ambiguity is real.
 282
 283                      if Nkind (Lhs) = N_Explicit_Dereference then
 284                         declare
 285                            PI    : Interp_Index;
 286                            PI1   : Interp_Index := 0;
 287                            PIt   : Interp;
 288                            Found : Boolean;
 289
 290                         begin
 291                            Found := False;
 292                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 293
 294                            while Present (PIt.Typ) loop
 295                               if Is_Access_Type (PIt.Typ)
 296                                 and then Has_Compatible_Type
 297                                            (Rhs, Designated_Type (PIt.Typ))
 298                               then
 299                                  if Found then
 300                                     PIt :=
 301                                       Disambiguate (Prefix (Lhs),
 302                                         PI1, PI, Any_Type);
 303
 304                                     if PIt = No_Interp then
 305                                        Error_Msg_N
 306                                          ("ambiguous left-hand side"
 307                                             & " in assignment", Lhs);
 308                                        exit;
 309                                     else
 310                                        Resolve (Prefix (Lhs), PIt.Typ);
 311                                     end if;
 312
 313                                     exit;
 314                                  else
 315                                     Found := True;
 316                                     PI1 := PI;
 317                                  end if;
 318                               end if;
 319
 320                               Get_Next_Interp (PI, PIt);
 321                            end loop;
 322                         end;
 323
 324                      else
 325                         Error_Msg_N
 326                           ("ambiguous left-hand side in assignment", Lhs);
 327                         exit;
 328                      end if;
 329                   else
 330                      T1 := It.Typ;
 331                   end if;
 332                end if;
 333
 334                Get_Next_Interp (I, It);
 335             end loop;
 336          end;
 337
 338          if T1 = Any_Type then
 339             Error_Msg_N
 340               ("no valid types for left-hand side for assignment", Lhs);
 341             Kill_Lhs;
 342             return;
 343          end if;
 344       end if;
 345
 346       --  The resulting assignment type is T1, so now we will resolve the
 347       --  left hand side of the assignment using this determined type.
 348
 349       Resolve (Lhs, T1);
 350
 351       --  Cases where Lhs is not a variable
 352
 353       if not Is_Variable (Lhs) then
 354
 355          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 356          --  a protected object.
 357
 358          declare
 359             Ent : Entity_Id;
 360             S   : Entity_Id;
 361
 362          begin
 363             if Ada_Version >= Ada_2005 then
 364
 365                --  Handle chains of renamings
 366
 367                Ent := Lhs;
 368                while Nkind (Ent) in N_Has_Entity
 369                  and then Present (Entity (Ent))
 370                  and then Present (Renamed_Object (Entity (Ent)))
 371                loop
 372                   Ent := Renamed_Object (Entity (Ent));
 373                end loop;
 374
 375                if (Nkind (Ent) = N_Attribute_Reference
 376                      and then Attribute_Name (Ent) = Name_Priority)
 377
 378                   --  Renamings of the attribute Priority applied to protected
 379                   --  objects have been previously expanded into calls to the
 380                   --  Get_Ceiling run-time subprogram.
 381
 382                  or else
 383                   (Nkind (Ent) = N_Function_Call
 384                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 385                                 or else
 386                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 387                then
 388                   --  The enclosing subprogram cannot be a protected function
 389
 390                   S := Current_Scope;
 391                   while not (Is_Subprogram (S)
 392                                and then Convention (S) = Convention_Protected)
 393                      and then S /= Standard_Standard
 394                   loop
 395                      S := Scope (S);
 396                   end loop;
 397
 398                   if Ekind (S) = E_Function
 399                     and then Convention (S) = Convention_Protected
 400                   then
 401                      Error_Msg_N
 402                        ("protected function cannot modify protected object",
 403                         Lhs);
 404                   end if;
 405
 406                   --  Changes of the ceiling priority of the protected object
 407                   --  are only effective if the Ceiling_Locking policy is in
 408                   --  effect (AARM D.5.2 (5/2)).
 409
 410                   if Locking_Policy /= 'C' then
 411                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 412                                   "no effect?", Lhs);
 413                      Error_Msg_N ("\since no Locking_Policy has been " &
 414                                   "specified", Lhs);
 415                   end if;
 416
 417                   return;
 418                end if;
 419             end if;
 420          end;
 421
 422          Diagnose_Non_Variable_Lhs (Lhs);
 423          return;
 424
 425       --  Error of assigning to limited type. We do however allow this in
 426       --  certain cases where the front end generates the assignments.
 427
 428       elsif Is_Limited_Type (T1)
 429         and then not Assignment_OK (Lhs)
 430         and then not Assignment_OK (Original_Node (Lhs))
 431         and then not Is_Value_Type (T1)
 432       then
 433          --  CPP constructors can only be called in declarations
 434
 435          if Is_CPP_Constructor_Call (Rhs) then
 436             Error_Msg_N ("invalid use of 'C'P'P constructor", Rhs);
 437          else
 438             Error_Msg_N
 439               ("left hand of assignment must not be limited type", Lhs);
 440             Explain_Limited_Type (T1, Lhs);
 441          end if;
 442          return;
 443
 444       --  Enforce RM 3.9.3 (8): the target of an assignment operation cannot be
 445       --  abstract. This is only checked when the assignment Comes_From_Source,
 446       --  because in some cases the expander generates such assignments (such
 447       --  in the _assign operation for an abstract type).
 448
 449       elsif Is_Abstract_Type (T1) and then Comes_From_Source (N) then
 450          Error_Msg_N
 451            ("target of assignment operation must not be abstract", Lhs);
 452       end if;
 453
 454       --  Resolution may have updated the subtype, in case the left-hand
 455       --  side is a private protected component. Use the correct subtype
 456       --  to avoid scoping issues in the back-end.
 457
 458       T1 := Etype (Lhs);
 459
 460       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 461       --  type. For example:
 462
 463       --    limited with P;
 464       --    package Pkg is
 465       --      type Acc is access P.T;
 466       --    end Pkg;
 467
 468       --    with Pkg; use Acc;
 469       --    procedure Example is
 470       --       A, B : Acc;
 471       --    begin
 472       --       A.all := B.all;  -- ERROR
 473       --    end Example;
 474
 475       if Nkind (Lhs) = N_Explicit_Dereference
 476         and then Ekind (T1) = E_Incomplete_Type
 477       then
 478          Error_Msg_N ("invalid use of incomplete type", Lhs);
 479          Kill_Lhs;
 480          return;
 481       end if;
 482
 483       --  Now we can complete the resolution of the right hand side
 484
 485       Set_Assignment_Type (Lhs, T1);
 486       Resolve (Rhs, T1);
 487
 488       --  This is the point at which we check for an unset reference
 489
 490       Check_Unset_Reference (Rhs);
 491       Check_Unprotected_Access (Lhs, Rhs);
 492
 493       --  Remaining steps are skipped if Rhs was syntactically in error
 494
 495       if Rhs = Error then
 496          Kill_Lhs;
 497          return;
 498       end if;
 499
 500       T2 := Etype (Rhs);
 501
 502       if not Covers (T1, T2) then
 503          Wrong_Type (Rhs, Etype (Lhs));
 504          Kill_Lhs;
 505          return;
 506       end if;
 507
 508       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 509       --  types, use the non-limited view if available
 510
 511       if Nkind (Rhs) = N_Explicit_Dereference
 512         and then Ekind (T2) = E_Incomplete_Type
 513         and then Is_Tagged_Type (T2)
 514         and then Present (Non_Limited_View (T2))
 515       then
 516          T2 := Non_Limited_View (T2);
 517       end if;
 518
 519       Set_Assignment_Type (Rhs, T2);
 520
 521       if Total_Errors_Detected /= 0 then
 522          if No (T1) then
 523             T1 := Any_Type;
 524          end if;
 525
 526          if No (T2) then
 527             T2 := Any_Type;
 528          end if;
 529       end if;
 530
 531       if T1 = Any_Type or else T2 = Any_Type then
 532          Kill_Lhs;
 533          return;
 534       end if;
 535
 536       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 537       --  to be class-wide. The case where the rhs is a dynamically tagged call
 538       --  to a dispatching operation with a controlling access result is
 539       --  excluded from this check, since the target has an access type (and
 540       --  no tag propagation occurs in that case).
 541
 542       if (Is_Class_Wide_Type (T2)
 543            or else (Is_Dynamically_Tagged (Rhs)
 544                      and then not Is_Access_Type (T1)))
 545         and then not Is_Class_Wide_Type (T1)
 546       then
 547          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 548
 549       elsif Is_Class_Wide_Type (T1)
 550         and then not Is_Class_Wide_Type (T2)
 551         and then not Is_Tag_Indeterminate (Rhs)
 552         and then not Is_Dynamically_Tagged (Rhs)
 553       then
 554          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 555       end if;
 556
 557       --  Propagate the tag from a class-wide target to the rhs when the rhs
 558       --  is a tag-indeterminate call.
 559
 560       if Is_Tag_Indeterminate (Rhs) then
 561          if Is_Class_Wide_Type (T1) then
 562             Propagate_Tag (Lhs, Rhs);
 563
 564          elsif Nkind (Rhs) = N_Function_Call
 565               and then Is_Entity_Name (Name (Rhs))
 566               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 567          then
 568             Error_Msg_N
 569               ("call to abstract function must be dispatching", Name (Rhs));
 570
 571          elsif Nkind (Rhs) = N_Qualified_Expression
 572            and then Nkind (Expression (Rhs)) = N_Function_Call
 573               and then Is_Entity_Name (Name (Expression (Rhs)))
 574               and then
 575                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 576          then
 577             Error_Msg_N
 578               ("call to abstract function must be dispatching",
 579                 Name (Expression (Rhs)));
 580          end if;
 581       end if;
 582
 583       --  Ada 2005 (AI-385): When the lhs type is an anonymous access type,
 584       --  apply an implicit conversion of the rhs to that type to force
 585       --  appropriate static and run-time accessibility checks. This applies
 586       --  as well to anonymous access-to-subprogram types that are component
 587       --  subtypes or formal parameters.
 588
 589       if Ada_Version >= Ada_2005
 590         and then Is_Access_Type (T1)
 591       then
 592          if Is_Local_Anonymous_Access (T1)
 593            or else Ekind (T2) = E_Anonymous_Access_Subprogram_Type
 594          then
 595             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 596             Analyze_And_Resolve (Rhs, T1);
 597          end if;
 598       end if;
 599
 600       --  Ada 2005 (AI-231): Assignment to not null variable
 601
 602       if Ada_Version >= Ada_2005
 603         and then Can_Never_Be_Null (T1)
 604         and then not Assignment_OK (Lhs)
 605       then
 606          --  Case where we know the right hand side is null
 607
 608          if Known_Null (Rhs) then
 609             Apply_Compile_Time_Constraint_Error
 610               (N   => Rhs,
 611                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 612                Reason => CE_Null_Not_Allowed);
 613
 614             --  We still mark this as a possible modification, that's necessary
 615             --  to reset Is_True_Constant, and desirable for xref purposes.
 616
 617             Note_Possible_Modification (Lhs, Sure => True);
 618             return;
 619
 620          --  If we know the right hand side is non-null, then we convert to the
 621          --  target type, since we don't need a run time check in that case.
 622
 623          elsif not Can_Never_Be_Null (T2) then
 624             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 625             Analyze_And_Resolve (Rhs, T1);
 626          end if;
 627       end if;
 628
 629       if Is_Scalar_Type (T1) then
 630          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 631
 632       --  For array types, verify that lengths match. If the right hand side
 633       --  if a function call that has been inlined, the assignment has been
 634       --  rewritten as a block, and the constraint check will be applied to the
 635       --  assignment within the block.
 636
 637       elsif Is_Array_Type (T1)
 638         and then
 639           (Nkind (Rhs) /= N_Type_Conversion
 640             or else Is_Constrained (Etype (Rhs)))
 641         and then
 642           (Nkind (Rhs) /= N_Function_Call
 643             or else Nkind (N) /= N_Block_Statement)
 644       then
 645          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 646          --  but of course the indexes do not have to match. If the right-hand
 647          --  side is a type conversion to an unconstrained type, a length check
 648          --  is performed on the expression itself during expansion. In rare
 649          --  cases, the redundant length check is computed on an index type
 650          --  with a different representation, triggering incorrect code in
 651          --  the back end.
 652
 653          Apply_Length_Check (Rhs, Etype (Lhs));
 654
 655       else
 656          --  Discriminant checks are applied in the course of expansion
 657
 658          null;
 659       end if;
 660
 661       --  Note: modifications of the Lhs may only be recorded after
 662       --  checks have been applied.
 663
 664       Note_Possible_Modification (Lhs, Sure => True);
 665       Check_Order_Dependence;
 666
 667       --  ??? a real accessibility check is needed when ???
 668
 669       --  Post warning for redundant assignment or variable to itself
 670
 671       if Warn_On_Redundant_Constructs
 672
 673          --  We only warn for source constructs
 674
 675          and then Comes_From_Source (N)
 676
 677          --  Where the object is the same on both sides
 678
 679          and then Same_Object (Lhs, Original_Node (Rhs))
 680
 681          --  But exclude the case where the right side was an operation
 682          --  that got rewritten (e.g. JUNK + K, where K was known to be
 683          --  zero). We don't want to warn in such a case, since it is
 684          --  reasonable to write such expressions especially when K is
 685          --  defined symbolically in some other package.
 686
 687         and then Nkind (Original_Node (Rhs)) not in N_Op
 688       then
 689          if Nkind (Lhs) in N_Has_Entity then
 690             Error_Msg_NE -- CODEFIX
 691               ("?useless assignment of & to itself!", N, Entity (Lhs));
 692          else
 693             Error_Msg_N -- CODEFIX
 694               ("?useless assignment of object to itself!", N);
 695          end if;
 696       end if;
 697
 698       --  Check for non-allowed composite assignment
 699
 700       if not Support_Composite_Assign_On_Target
 701         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 702         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 703       then
 704          Error_Msg_CRT ("composite assignment", N);
 705       end if;
 706
 707       --  Check elaboration warning for left side if not in elab code
 708
 709       if not In_Subprogram_Or_Concurrent_Unit then
 710          Check_Elab_Assign (Lhs);
 711       end if;
 712
 713       --  Set Referenced_As_LHS if appropriate. We only set this flag if the
 714       --  assignment is a source assignment in the extended main source unit.
 715       --  We are not interested in any reference information outside this
 716       --  context, or in compiler generated assignment statements.
 717
 718       if Comes_From_Source (N)
 719         and then In_Extended_Main_Source_Unit (Lhs)
 720       then
 721          Set_Referenced_Modified (Lhs, Out_Param => False);
 722       end if;
 723
 724       --  Final step. If left side is an entity, then we may be able to
 725       --  reset the current tracked values to new safe values. We only have
 726       --  something to do if the left side is an entity name, and expansion
 727       --  has not modified the node into something other than an assignment,
 728       --  and of course we only capture values if it is safe to do so.
 729
 730       if Is_Entity_Name (Lhs)
 731         and then Nkind (N) = N_Assignment_Statement
 732       then
 733          declare
 734             Ent : constant Entity_Id := Entity (Lhs);
 735
 736          begin
 737             if Safe_To_Capture_Value (N, Ent) then
 738
 739                --  If simple variable on left side, warn if this assignment
 740                --  blots out another one (rendering it useless) and note
 741                --  location of assignment in case no one references value.
 742                --  We only do this for source assignments, otherwise we can
 743                --  generate bogus warnings when an assignment is rewritten as
 744                --  another assignment, and gets tied up with itself.
 745
 746                --  Note: we don't use Record_Last_Assignment here, because we
 747                --  have lots of other stuff to do under control of this test.
 748
 749                if Warn_On_Modified_Unread
 750                  and then Is_Assignable (Ent)
 751                  and then Comes_From_Source (N)
 752                  and then In_Extended_Main_Source_Unit (Ent)
 753                then
 754                   Warn_On_Useless_Assignment (Ent, N);
 755                   Set_Last_Assignment (Ent, Lhs);
 756                end if;
 757
 758                --  If we are assigning an access type and the left side is an
 759                --  entity, then make sure that the Is_Known_[Non_]Null flags
 760                --  properly reflect the state of the entity after assignment.
 761
 762                if Is_Access_Type (T1) then
 763                   if Known_Non_Null (Rhs) then
 764                      Set_Is_Known_Non_Null (Ent, True);
 765
 766                   elsif Known_Null (Rhs)
 767                     and then not Can_Never_Be_Null (Ent)
 768                   then
 769                      Set_Is_Known_Null (Ent, True);
 770
 771                   else
 772                      Set_Is_Known_Null (Ent, False);
 773
 774                      if not Can_Never_Be_Null (Ent) then
 775                         Set_Is_Known_Non_Null (Ent, False);
 776                      end if;
 777                   end if;
 778
 779                --  For discrete types, we may be able to set the current value
 780                --  if the value is known at compile time.
 781
 782                elsif Is_Discrete_Type (T1)
 783                  and then Compile_Time_Known_Value (Rhs)
 784                then
 785                   Set_Current_Value (Ent, Rhs);
 786                else
 787                   Set_Current_Value (Ent, Empty);
 788                end if;
 789
 790             --  If not safe to capture values, kill them
 791
 792             else
 793                Kill_Lhs;
 794             end if;
 795          end;
 796       end if;
 797    end Analyze_Assignment;
 798
 799    -----------------------------
 800    -- Analyze_Block_Statement --
 801    -----------------------------
 802
 803    procedure Analyze_Block_Statement (N : Node_Id) is
 804       Decls : constant List_Id := Declarations (N);
 805       Id    : constant Node_Id := Identifier (N);
 806       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 807
 808    begin
 809       Check_Formal_Restriction ("block statement is not allowed", N);
 810
 811       --  If no handled statement sequence is present, things are really
 812       --  messed up, and we just return immediately (this is a defence
 813       --  against previous errors).
 814
 815       if No (HSS) then
 816          return;
 817       end if;
 818
 819       --  Normal processing with HSS present
 820
 821       declare
 822          EH  : constant List_Id := Exception_Handlers (HSS);
 823          Ent : Entity_Id        := Empty;
 824          S   : Entity_Id;
 825
 826          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 827          --  Recursively save value of this global, will be restored on exit
 828
 829       begin
 830          --  Initialize unblocked exit count for statements of begin block
 831          --  plus one for each exception handler that is present.
 832
 833          Unblocked_Exit_Count := 1;
 834
 835          if Present (EH) then
 836             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 837          end if;
 838
 839          --  If a label is present analyze it and mark it as referenced
 840
 841          if Present (Id) then
 842             Analyze (Id);
 843             Ent := Entity (Id);
 844
 845             --  An error defense. If we have an identifier, but no entity,
 846             --  then something is wrong. If we have previous errors, then
 847             --  just remove the identifier and continue, otherwise raise
 848             --  an exception.
 849
 850             if No (Ent) then
 851                if Total_Errors_Detected /= 0 then
 852                   Set_Identifier (N, Empty);
 853                else
 854                   raise Program_Error;
 855                end if;
 856
 857             else
 858                Set_Ekind (Ent, E_Block);
 859                Generate_Reference (Ent, N, ' ');
 860                Generate_Definition (Ent);
 861
 862                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 863                   Set_Label_Construct (Parent (Ent), N);
 864                end if;
 865             end if;
 866          end if;
 867
 868          --  If no entity set, create a label entity
 869
 870          if No (Ent) then
 871             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 872             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 873             Set_Parent (Ent, N);
 874          end if;
 875
 876          Set_Etype (Ent, Standard_Void_Type);
 877          Set_Block_Node (Ent, Identifier (N));
 878          Push_Scope (Ent);
 879
 880          if Present (Decls) then
 881             Analyze_Declarations (Decls);
 882             Check_Completion;
 883             Inspect_Deferred_Constant_Completion (Decls);
 884          end if;
 885
 886          Analyze (HSS);
 887          Process_End_Label (HSS, 'e', Ent);
 888
 889          --  If exception handlers are present, then we indicate that
 890          --  enclosing scopes contain a block with handlers. We only
 891          --  need to mark non-generic scopes.
 892
 893          if Present (EH) then
 894             S := Scope (Ent);
 895             loop
 896                Set_Has_Nested_Block_With_Handler (S);
 897                exit when Is_Overloadable (S)
 898                  or else Ekind (S) = E_Package
 899                  or else Is_Generic_Unit (S);
 900                S := Scope (S);
 901             end loop;
 902          end if;
 903
 904          Check_References (Ent);
 905          Warn_On_Useless_Assignments (Ent);
 906          End_Scope;
 907
 908          if Unblocked_Exit_Count = 0 then
 909             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 910             Check_Unreachable_Code (N);
 911          else
 912             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 913          end if;
 914       end;
 915    end Analyze_Block_Statement;
 916
 917    ----------------------------
 918    -- Analyze_Case_Statement --
 919    ----------------------------
 920
 921    procedure Analyze_Case_Statement (N : Node_Id) is
 922       Exp            : Node_Id;
 923       Exp_Type       : Entity_Id;
 924       Exp_Btype      : Entity_Id;
 925       Last_Choice    : Nat;
 926       Dont_Care      : Boolean;
 927       Others_Present : Boolean;
 928
 929       pragma Warnings (Off, Last_Choice);
 930       pragma Warnings (Off, Dont_Care);
 931       --  Don't care about assigned values
 932
 933       Statements_Analyzed : Boolean := False;
 934       --  Set True if at least some statement sequences get analyzed.
 935       --  If False on exit, means we had a serious error that prevented
 936       --  full analysis of the case statement, and as a result it is not
 937       --  a good idea to output warning messages about unreachable code.
 938
 939       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 940       --  Recursively save value of this global, will be restored on exit
 941
 942       procedure Non_Static_Choice_Error (Choice : Node_Id);
 943       --  Error routine invoked by the generic instantiation below when
 944       --  the case statement has a non static choice.
 945
 946       procedure Process_Statements (Alternative : Node_Id);
 947       --  Analyzes all the statements associated with a case alternative.
 948       --  Needed by the generic instantiation below.
 949
 950       package Case_Choices_Processing is new
 951         Generic_Choices_Processing
 952           (Get_Alternatives          => Alternatives,
 953            Get_Choices               => Discrete_Choices,
 954            Process_Empty_Choice      => No_OP,
 955            Process_Non_Static_Choice => Non_Static_Choice_Error,
 956            Process_Associated_Node   => Process_Statements);
 957       use Case_Choices_Processing;
 958       --  Instantiation of the generic choice processing package
 959
 960       -----------------------------
 961       -- Non_Static_Choice_Error --
 962       -----------------------------
 963
 964       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 965       begin
 966          Flag_Non_Static_Expr
 967            ("choice given in case statement is not static!", Choice);
 968       end Non_Static_Choice_Error;
 969
 970       ------------------------
 971       -- Process_Statements --
 972       ------------------------
 973
 974       procedure Process_Statements (Alternative : Node_Id) is
 975          Choices : constant List_Id := Discrete_Choices (Alternative);
 976          Ent     : Entity_Id;
 977
 978       begin
 979          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 980          Statements_Analyzed := True;
 981
 982          --  An interesting optimization. If the case statement expression
 983          --  is a simple entity, then we can set the current value within
 984          --  an alternative if the alternative has one possible value.
 985
 986          --    case N is
 987          --      when 1      => alpha
 988          --      when 2 | 3  => beta
 989          --      when others => gamma
 990
 991          --  Here we know that N is initially 1 within alpha, but for beta
 992          --  and gamma, we do not know anything more about the initial value.
 993
 994          if Is_Entity_Name (Exp) then
 995             Ent := Entity (Exp);
 996
 997             if Ekind_In (Ent, E_Variable,
 998                               E_In_Out_Parameter,
 999                               E_Out_Parameter)
1000             then
1001                if List_Length (Choices) = 1
1002                  and then Nkind (First (Choices)) in N_Subexpr
1003                  and then Compile_Time_Known_Value (First (Choices))
1004                then
1005                   Set_Current_Value (Entity (Exp), First (Choices));
1006                end if;
1007
1008                Analyze_Statements (Statements (Alternative));
1009
1010                --  After analyzing the case, set the current value to empty
1011                --  since we won't know what it is for the next alternative
1012                --  (unless reset by this same circuit), or after the case.
1013
1014                Set_Current_Value (Entity (Exp), Empty);
1015                return;
1016             end if;
1017          end if;
1018
1019          --  Case where expression is not an entity name of a variable
1020
1021          Analyze_Statements (Statements (Alternative));
1022       end Process_Statements;
1023
1024    --  Start of processing for Analyze_Case_Statement
1025
1026    begin
1027       Unblocked_Exit_Count := 0;
1028       Exp := Expression (N);
1029       Analyze (Exp);
1030
1031       --  The expression must be of any discrete type. In rare cases, the
1032       --  expander constructs a case statement whose expression has a private
1033       --  type whose full view is discrete. This can happen when generating
1034       --  a stream operation for a variant type after the type is frozen,
1035       --  when the partial of view of the type of the discriminant is private.
1036       --  In that case, use the full view to analyze case alternatives.
1037
1038       if not Is_Overloaded (Exp)
1039         and then not Comes_From_Source (N)
1040         and then Is_Private_Type (Etype (Exp))
1041         and then Present (Full_View (Etype (Exp)))
1042         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1043       then
1044          Resolve (Exp, Etype (Exp));
1045          Exp_Type := Full_View (Etype (Exp));
1046
1047       else
1048          Analyze_And_Resolve (Exp, Any_Discrete);
1049          Exp_Type := Etype (Exp);
1050       end if;
1051
1052       Check_Unset_Reference (Exp);
1053       Exp_Btype := Base_Type (Exp_Type);
1054
1055       --  The expression must be of a discrete type which must be determinable
1056       --  independently of the context in which the expression occurs, but
1057       --  using the fact that the expression must be of a discrete type.
1058       --  Moreover, the type this expression must not be a character literal
1059       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1060
1061       --  If error already reported by Resolve, nothing more to do
1062
1063       if Exp_Btype = Any_Discrete
1064         or else Exp_Btype = Any_Type
1065       then
1066          return;
1067
1068       elsif Exp_Btype = Any_Character then
1069          Error_Msg_N
1070            ("character literal as case expression is ambiguous", Exp);
1071          return;
1072
1073       elsif Ada_Version = Ada_83
1074         and then (Is_Generic_Type (Exp_Btype)
1075                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1076       then
1077          Error_Msg_N
1078            ("(Ada 83) case expression cannot be of a generic type", Exp);
1079          return;
1080       end if;
1081
1082       --  If the case expression is a formal object of mode in out, then
1083       --  treat it as having a nonstatic subtype by forcing use of the base
1084       --  type (which has to get passed to Check_Case_Choices below).  Also
1085       --  use base type when the case expression is parenthesized.
1086
1087       if Paren_Count (Exp) > 0
1088         or else (Is_Entity_Name (Exp)
1089                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1090       then
1091          Exp_Type := Exp_Btype;
1092       end if;
1093
1094       --  Call instantiated Analyze_Choices which does the rest of the work
1095
1096       Analyze_Choices (N, Exp_Type, Dont_Care, Others_Present);
1097
1098       --  A case statement with a single OTHERS alternative is not allowed
1099       --  in SPARK or ALFA.
1100
1101       if Others_Present
1102         and then List_Length (Alternatives (N)) = 1
1103       then
1104          Check_Formal_Restriction
1105            ("OTHERS as unique case alternative is not allowed", N);
1106       end if;
1107
1108       if Exp_Type = Universal_Integer and then not Others_Present then
1109          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1110       end if;
1111
1112       --  If all our exits were blocked by unconditional transfers of control,
1113       --  then the entire CASE statement acts as an unconditional transfer of
1114       --  control, so treat it like one, and check unreachable code. Skip this
1115       --  test if we had serious errors preventing any statement analysis.
1116
1117       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1118          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1119          Check_Unreachable_Code (N);
1120       else
1121          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1122       end if;
1123
1124       if not Expander_Active
1125         and then Compile_Time_Known_Value (Expression (N))
1126         and then Serious_Errors_Detected = 0
1127       then
1128          declare
1129             Chosen : constant Node_Id := Find_Static_Alternative (N);
1130             Alt    : Node_Id;
1131
1132          begin
1133             Alt := First (Alternatives (N));
1134             while Present (Alt) loop
1135                if Alt /= Chosen then
1136                   Remove_Warning_Messages (Statements (Alt));
1137                end if;
1138
1139                Next (Alt);
1140             end loop;
1141          end;
1142       end if;
1143    end Analyze_Case_Statement;
1144
1145    ----------------------------
1146    -- Analyze_Exit_Statement --
1147    ----------------------------
1148
1149    --  If the exit includes a name, it must be the name of a currently open
1150    --  loop. Otherwise there must be an innermost open loop on the stack,
1151    --  to which the statement implicitly refers.
1152
1153    --  Additionally, in formal mode:
1154    --  * the exit can only name the closest enclosing loop;
1155    --  * an exit with a when clause must be directly contained in a loop;
1156    --  * an exit without a when clause must be directly contained in an
1157    --    if-statement with no elsif or else, which is itself directly contained
1158    --    in a loop. The exit must be the last statement in the if-statement.
1159
1160    procedure Analyze_Exit_Statement (N : Node_Id) is
1161       Target   : constant Node_Id := Name (N);
1162       Cond     : constant Node_Id := Condition (N);
1163       Scope_Id : Entity_Id;
1164       U_Name   : Entity_Id;
1165       Kind     : Entity_Kind;
1166
1167    begin
1168       if No (Cond) then
1169          Check_Unreachable_Code (N);
1170       end if;
1171
1172       if Present (Target) then
1173          Analyze (Target);
1174          U_Name := Entity (Target);
1175
1176          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1177             Error_Msg_N ("invalid loop name in exit statement", N);
1178             return;
1179          else
1180             if Has_Loop_In_Inner_Open_Scopes (U_Name) then
1181                Check_Formal_Restriction
1182                  ("exit label must name the closest enclosing loop", N);
1183             end if;
1184
1185             Set_Has_Exit (U_Name);
1186          end if;
1187       else
1188          U_Name := Empty;
1189       end if;
1190
1191       for J in reverse 0 .. Scope_Stack.Last loop
1192          Scope_Id := Scope_Stack.Table (J).Entity;
1193          Kind := Ekind (Scope_Id);
1194
1195          if Kind = E_Loop
1196            and then (No (Target) or else Scope_Id = U_Name) then
1197             Set_Has_Exit (Scope_Id);
1198             exit;
1199
1200          elsif Kind = E_Block
1201            or else Kind = E_Loop
1202            or else Kind = E_Return_Statement
1203          then
1204             null;
1205
1206          else
1207             Error_Msg_N
1208               ("cannot exit from program unit or accept statement", N);
1209             return;
1210          end if;
1211       end loop;
1212
1213       --  Verify that if present the condition is a Boolean expression
1214
1215       if Present (Cond) then
1216          Analyze_And_Resolve (Cond, Any_Boolean);
1217          Check_Unset_Reference (Cond);
1218       end if;
1219
1220       --  In formal mode, verify that the exit statement respects the SPARK
1221       --  restrictions.
1222
1223       if Present (Cond) then
1224          if Nkind (Parent (N)) /= N_Loop_Statement then
1225             Check_Formal_Restriction
1226               ("exit with when clause must be directly in loop", N);
1227          end if;
1228
1229       else
1230          if Nkind (Parent (N)) /= N_If_Statement then
1231             if Nkind (Parent (N)) = N_Elsif_Part then
1232                Check_Formal_Restriction
1233                  ("exit must be in IF without ELSIF", N);
1234             else
1235                Check_Formal_Restriction ("exit must be directly in IF", N);
1236             end if;
1237
1238          elsif Nkind (Parent (Parent (N))) /= N_Loop_Statement then
1239             Check_Formal_Restriction
1240               ("exit must be in IF directly in loop", N);
1241
1242             --  First test the presence of ELSE, so that an exit in an ELSE
1243             --  leads to an error mentioning the ELSE.
1244
1245          elsif Present (Else_Statements (Parent (N))) then
1246             Check_Formal_Restriction ("exit must be in IF without ELSE", N);
1247
1248             --  An exit in an ELSIF does not reach here, as it would have been
1249             --  detected in the case (Nkind (Parent (N)) /= N_If_Statement).
1250
1251          elsif Present (Elsif_Parts (Parent (N))) then
1252             Check_Formal_Restriction ("exit must be in IF without ELSIF", N);
1253          end if;
1254       end if;
1255
1256       --  Chain exit statement to associated loop entity
1257
1258       Set_Next_Exit_Statement  (N, First_Exit_Statement (Scope_Id));
1259       Set_First_Exit_Statement (Scope_Id, N);
1260
1261       --  Since the exit may take us out of a loop, any previous assignment
1262       --  statement is not useless, so clear last assignment indications. It
1263       --  is OK to keep other current values, since if the exit statement
1264       --  does not exit, then the current values are still valid.
1265
1266       Kill_Current_Values (Last_Assignment_Only => True);
1267    end Analyze_Exit_Statement;
1268
1269    ----------------------------
1270    -- Analyze_Goto_Statement --
1271    ----------------------------
1272
1273    procedure Analyze_Goto_Statement (N : Node_Id) is
1274       Label       : constant Node_Id := Name (N);
1275       Scope_Id    : Entity_Id;
1276       Label_Scope : Entity_Id;
1277       Label_Ent   : Entity_Id;
1278
1279    begin
1280       Check_Formal_Restriction ("goto statement is not allowed", N);
1281
1282       --  Actual semantic checks
1283
1284       Check_Unreachable_Code (N);
1285       Kill_Current_Values (Last_Assignment_Only => True);
1286
1287       Analyze (Label);
1288       Label_Ent := Entity (Label);
1289
1290       --  Ignore previous error
1291
1292       if Label_Ent = Any_Id then
1293          return;
1294
1295       --  We just have a label as the target of a goto
1296
1297       elsif Ekind (Label_Ent) /= E_Label then
1298          Error_Msg_N ("target of goto statement must be a label", Label);
1299          return;
1300
1301       --  Check that the target of the goto is reachable according to Ada
1302       --  scoping rules. Note: the special gotos we generate for optimizing
1303       --  local handling of exceptions would violate these rules, but we mark
1304       --  such gotos as analyzed when built, so this code is never entered.
1305
1306       elsif not Reachable (Label_Ent) then
1307          Error_Msg_N ("target of goto statement is not reachable", Label);
1308          return;
1309       end if;
1310
1311       --  Here if goto passes initial validity checks
1312
1313       Label_Scope := Enclosing_Scope (Label_Ent);
1314
1315       for J in reverse 0 .. Scope_Stack.Last loop
1316          Scope_Id := Scope_Stack.Table (J).Entity;
1317
1318          if Label_Scope = Scope_Id
1319            or else (Ekind (Scope_Id) /= E_Block
1320                      and then Ekind (Scope_Id) /= E_Loop
1321                      and then Ekind (Scope_Id) /= E_Return_Statement)
1322          then
1323             if Scope_Id /= Label_Scope then
1324                Error_Msg_N
1325                  ("cannot exit from program unit or accept statement", N);
1326             end if;
1327
1328             return;
1329          end if;
1330       end loop;
1331
1332       raise Program_Error;
1333    end Analyze_Goto_Statement;
1334
1335    --------------------------
1336    -- Analyze_If_Statement --
1337    --------------------------
1338
1339    --  A special complication arises in the analysis of if statements
1340
1341    --  The expander has circuitry to completely delete code that it
1342    --  can tell will not be executed (as a result of compile time known
1343    --  conditions). In the analyzer, we ensure that code that will be
1344    --  deleted in this manner is analyzed but not expanded. This is
1345    --  obviously more efficient, but more significantly, difficulties
1346    --  arise if code is expanded and then eliminated (e.g. exception
1347    --  table entries disappear). Similarly, itypes generated in deleted
1348    --  code must be frozen from start, because the nodes on which they
1349    --  depend will not be available at the freeze point.
1350
1351    procedure Analyze_If_Statement (N : Node_Id) is
1352       E : Node_Id;
1353
1354       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1355       --  Recursively save value of this global, will be restored on exit
1356
1357       Save_In_Deleted_Code : Boolean;
1358
1359       Del : Boolean := False;
1360       --  This flag gets set True if a True condition has been found,
1361       --  which means that remaining ELSE/ELSIF parts are deleted.
1362
1363       procedure Analyze_Cond_Then (Cnode : Node_Id);
1364       --  This is applied to either the N_If_Statement node itself or
1365       --  to an N_Elsif_Part node. It deals with analyzing the condition
1366       --  and the THEN statements associated with it.
1367
1368       -----------------------
1369       -- Analyze_Cond_Then --
1370       -----------------------
1371
1372       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1373          Cond : constant Node_Id := Condition (Cnode);
1374          Tstm : constant List_Id := Then_Statements (Cnode);
1375
1376       begin
1377          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1378          Analyze_And_Resolve (Cond, Any_Boolean);
1379          Check_Unset_Reference (Cond);
1380          Set_Current_Value_Condition (Cnode);
1381
1382          --  If already deleting, then just analyze then statements
1383
1384          if Del then
1385             Analyze_Statements (Tstm);
1386
1387          --  Compile time known value, not deleting yet
1388
1389          elsif Compile_Time_Known_Value (Cond) then
1390             Save_In_Deleted_Code := In_Deleted_Code;
1391
1392             --  If condition is True, then analyze the THEN statements
1393             --  and set no expansion for ELSE and ELSIF parts.
1394
1395             if Is_True (Expr_Value (Cond)) then
1396                Analyze_Statements (Tstm);
1397                Del := True;
1398                Expander_Mode_Save_And_Set (False);
1399                In_Deleted_Code := True;
1400
1401             --  If condition is False, analyze THEN with expansion off
1402
1403             else -- Is_False (Expr_Value (Cond))
1404                Expander_Mode_Save_And_Set (False);
1405                In_Deleted_Code := True;
1406                Analyze_Statements (Tstm);
1407                Expander_Mode_Restore;
1408                In_Deleted_Code := Save_In_Deleted_Code;
1409             end if;
1410
1411          --  Not known at compile time, not deleting, normal analysis
1412
1413          else
1414             Analyze_Statements (Tstm);
1415          end if;
1416       end Analyze_Cond_Then;
1417
1418    --  Start of Analyze_If_Statement
1419
1420    begin
1421       --  Initialize exit count for else statements. If there is no else
1422       --  part, this count will stay non-zero reflecting the fact that the
1423       --  uncovered else case is an unblocked exit.
1424
1425       Unblocked_Exit_Count := 1;
1426       Analyze_Cond_Then (N);
1427
1428       --  Now to analyze the elsif parts if any are present
1429
1430       if Present (Elsif_Parts (N)) then
1431          E := First (Elsif_Parts (N));
1432          while Present (E) loop
1433             Analyze_Cond_Then (E);
1434             Next (E);
1435          end loop;
1436       end if;
1437
1438       if Present (Else_Statements (N)) then
1439          Analyze_Statements (Else_Statements (N));
1440       end if;
1441
1442       --  If all our exits were blocked by unconditional transfers of control,
1443       --  then the entire IF statement acts as an unconditional transfer of
1444       --  control, so treat it like one, and check unreachable code.
1445
1446       if Unblocked_Exit_Count = 0 then
1447          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1448          Check_Unreachable_Code (N);
1449       else
1450          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1451       end if;
1452
1453       if Del then
1454          Expander_Mode_Restore;
1455          In_Deleted_Code := Save_In_Deleted_Code;
1456       end if;
1457
1458       if not Expander_Active
1459         and then Compile_Time_Known_Value (Condition (N))
1460         and then Serious_Errors_Detected = 0
1461       then
1462          if Is_True (Expr_Value (Condition (N))) then
1463             Remove_Warning_Messages (Else_Statements (N));
1464
1465             if Present (Elsif_Parts (N)) then
1466                E := First (Elsif_Parts (N));
1467                while Present (E) loop
1468                   Remove_Warning_Messages (Then_Statements (E));
1469                   Next (E);
1470                end loop;
1471             end if;
1472
1473          else
1474             Remove_Warning_Messages (Then_Statements (N));
1475          end if;
1476       end if;
1477    end Analyze_If_Statement;
1478
1479    ----------------------------------------
1480    -- Analyze_Implicit_Label_Declaration --
1481    ----------------------------------------
1482
1483    --  An implicit label declaration is generated in the innermost
1484    --  enclosing declarative part. This is done for labels as well as
1485    --  block and loop names.
1486
1487    --  Note: any changes in this routine may need to be reflected in
1488    --  Analyze_Label_Entity.
1489
1490    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1491       Id : constant Node_Id := Defining_Identifier (N);
1492    begin
1493       Enter_Name          (Id);
1494       Set_Ekind           (Id, E_Label);
1495       Set_Etype           (Id, Standard_Void_Type);
1496       Set_Enclosing_Scope (Id, Current_Scope);
1497    end Analyze_Implicit_Label_Declaration;
1498
1499    ------------------------------
1500    -- Analyze_Iteration_Scheme --
1501    ------------------------------
1502
1503    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1504
1505       procedure Process_Bounds (R : Node_Id);
1506       --  If the iteration is given by a range, create temporaries and
1507       --  assignment statements block to capture the bounds and perform
1508       --  required finalization actions in case a bound includes a function
1509       --  call that uses the temporary stack. We first pre-analyze a copy of
1510       --  the range in order to determine the expected type, and analyze and
1511       --  resolve the original bounds.
1512
1513       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1514       --  If the bounds are given by a 'Range reference on a function call
1515       --  that returns a controlled array, introduce an explicit declaration
1516       --  to capture the bounds, so that the function result can be finalized
1517       --  in timely fashion.
1518
1519       --------------------
1520       -- Process_Bounds --
1521       --------------------
1522
1523       procedure Process_Bounds (R : Node_Id) is
1524          Loc          : constant Source_Ptr := Sloc (N);
1525          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1526          Lo           : constant Node_Id := Low_Bound  (R);
1527          Hi           : constant Node_Id := High_Bound (R);
1528          New_Lo_Bound : Node_Id;
1529          New_Hi_Bound : Node_Id;
1530          Typ          : Entity_Id;
1531          Save_Analysis : Boolean;
1532
1533          function One_Bound
1534            (Original_Bound : Node_Id;
1535             Analyzed_Bound : Node_Id) return Node_Id;
1536          --  Capture value of bound and return captured value
1537
1538          ---------------
1539          -- One_Bound --
1540          ---------------
1541
1542          function One_Bound
1543            (Original_Bound : Node_Id;
1544             Analyzed_Bound : Node_Id) return Node_Id
1545          is
1546             Assign : Node_Id;
1547             Id     : Entity_Id;
1548             Decl   : Node_Id;
1549
1550          begin
1551             --  If the bound is a constant or an object, no need for a separate
1552             --  declaration. If the bound is the result of previous expansion
1553             --  it is already analyzed and should not be modified. Note that
1554             --  the Bound will be resolved later, if needed, as part of the
1555             --  call to Make_Index (literal bounds may need to be resolved to
1556             --  type Integer).
1557
1558             if Analyzed (Original_Bound) then
1559                return Original_Bound;
1560
1561             elsif Nkind_In (Analyzed_Bound, N_Integer_Literal,
1562                                             N_Character_Literal)
1563               or else Is_Entity_Name (Analyzed_Bound)
1564             then
1565                Analyze_And_Resolve (Original_Bound, Typ);
1566                return Original_Bound;
1567             end if;
1568
1569             --  Here we need to capture the value
1570
1571             Analyze_And_Resolve (Original_Bound, Typ);
1572
1573             Id := Make_Temporary (Loc, 'S', Original_Bound);
1574
1575             --  Normally, the best approach is simply to generate a constant
1576             --  declaration that captures the bound. However, there is a nasty
1577             --  case where this is wrong. If the bound is complex, and has a
1578             --  possible use of the secondary stack, we need to generate a
1579             --  separate assignment statement to ensure the creation of a block
1580             --  which will release the secondary stack.
1581
1582             --  We prefer the constant declaration, since it leaves us with a
1583             --  proper trace of the value, useful in optimizations that get rid
1584             --  of junk range checks.
1585
1586             --  Probably we want something like the Side_Effect_Free routine
1587             --  in Exp_Util, but for now, we just optimize the cases of 'Last
1588             --  and 'First applied to an entity, since these are the important
1589             --  cases for range check optimizations.
1590
1591             if Nkind (Original_Bound) = N_Attribute_Reference
1592               and then (Attribute_Name (Original_Bound) = Name_First
1593                           or else
1594                         Attribute_Name (Original_Bound) = Name_Last)
1595               and then Is_Entity_Name (Prefix (Original_Bound))
1596             then
1597                Decl :=
1598                  Make_Object_Declaration (Loc,
1599                    Defining_Identifier => Id,
1600                    Constant_Present    => True,
1601                    Object_Definition   => New_Occurrence_Of (Typ, Loc),
1602                    Expression          => Relocate_Node (Original_Bound));
1603
1604                --  Insert declaration at proper place. If loop comes from an
1605                --  enclosing quantified expression, the insertion point is
1606                --  arbitrarily far up in the tree.
1607
1608                Insert_Action (Parent (N), Decl);
1609                Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1610                return Expression (Decl);
1611             end if;
1612
1613             --  Here we make a declaration with a separate assignment
1614             --   statement, and insert before loop header.
1615
1616             Decl :=
1617               Make_Object_Declaration (Loc,
1618                 Defining_Identifier => Id,
1619                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1620
1621             Assign :=
1622               Make_Assignment_Statement (Loc,
1623                 Name        => New_Occurrence_Of (Id, Loc),
1624                 Expression  => Relocate_Node (Original_Bound));
1625
1626             Insert_Actions (Parent (N), New_List (Decl, Assign));
1627
1628             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1629
1630             if Nkind (Assign) = N_Assignment_Statement then
1631                return Expression (Assign);
1632             else
1633                return Original_Bound;
1634             end if;
1635          end One_Bound;
1636
1637       --  Start of processing for Process_Bounds
1638
1639       begin
1640          --  Determine expected type of range by analyzing separate copy
1641          --  Do the analysis and resolution of the copy of the bounds with
1642          --  expansion disabled, to prevent the generation of finalization
1643          --  actions on each bound. This prevents memory leaks when the
1644          --  bounds contain calls to functions returning controlled arrays.
1645
1646          Set_Parent (R_Copy, Parent (R));
1647          Save_Analysis := Full_Analysis;
1648          Full_Analysis := False;
1649          Expander_Mode_Save_And_Set (False);
1650
1651          Analyze (R_Copy);
1652
1653          if Is_Overloaded (R_Copy) then
1654
1655             --  Apply preference rules for range of predefined integer types,
1656             --  or diagnose true ambiguity.
1657
1658             declare
1659                I     : Interp_Index;
1660                It    : Interp;
1661                Found : Entity_Id := Empty;
1662
1663             begin
1664                Get_First_Interp (R_Copy, I, It);
1665                while Present (It.Typ) loop
1666                   if Is_Discrete_Type (It.Typ) then
1667                      if No (Found) then
1668                         Found := It.Typ;
1669                      else
1670                         if Scope (Found) = Standard_Standard then
1671                            null;
1672
1673                         elsif Scope (It.Typ) = Standard_Standard then
1674                            Found := It.Typ;
1675
1676                         else
1677                            --  Both of them are user-defined
1678
1679                            Error_Msg_N
1680                              ("ambiguous bounds in range of iteration",
1681                                R_Copy);
1682                            Error_Msg_N ("\possible interpretations:", R_Copy);
1683                            Error_Msg_NE ("\\} ", R_Copy, Found);
1684                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1685                            exit;
1686                         end if;
1687                      end if;
1688                   end if;
1689
1690                   Get_Next_Interp (I, It);
1691                end loop;
1692             end;
1693          end if;
1694
1695          Resolve (R_Copy);
1696          Expander_Mode_Restore;
1697          Full_Analysis := Save_Analysis;
1698
1699          Typ := Etype (R_Copy);
1700
1701          --  If the type of the discrete range is Universal_Integer, then
1702          --  the bound's type must be resolved to Integer, and any object
1703          --  used to hold the bound must also have type Integer, unless the
1704          --  literal bounds are constant-folded expressions that carry a user-
1705          --  defined type.
1706
1707          if Typ = Universal_Integer then
1708             if Nkind (Lo) = N_Integer_Literal
1709               and then Present (Etype (Lo))
1710               and then Scope (Etype (Lo)) /= Standard_Standard
1711             then
1712                Typ := Etype (Lo);
1713
1714             elsif Nkind (Hi) = N_Integer_Literal
1715               and then Present (Etype (Hi))
1716               and then Scope (Etype (Hi)) /= Standard_Standard
1717             then
1718                Typ := Etype (Hi);
1719
1720             else
1721                Typ := Standard_Integer;
1722             end if;
1723          end if;
1724
1725          Set_Etype (R, Typ);
1726
1727          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1728          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1729
1730          --  Propagate staticness to loop range itself, in case the
1731          --  corresponding subtype is static.
1732
1733          if New_Lo_Bound /= Lo
1734            and then Is_Static_Expression (New_Lo_Bound)
1735          then
1736             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1737          end if;
1738
1739          if New_Hi_Bound /= Hi
1740            and then Is_Static_Expression (New_Hi_Bound)
1741          then
1742             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1743          end if;
1744       end Process_Bounds;
1745
1746       --------------------------------------
1747       -- Check_Controlled_Array_Attribute --
1748       --------------------------------------
1749
1750       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1751       begin
1752          if Nkind (DS) = N_Attribute_Reference
1753             and then Is_Entity_Name (Prefix (DS))
1754             and then Ekind (Entity (Prefix (DS))) = E_Function
1755             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1756             and then
1757               Is_Controlled (
1758                 Component_Type (Etype (Entity (Prefix (DS)))))
1759             and then Expander_Active
1760          then
1761             declare
1762                Loc  : constant Source_Ptr := Sloc (N);
1763                Arr  : constant Entity_Id := Etype (Entity (Prefix (DS)));
1764                Indx : constant Entity_Id :=
1765                         Base_Type (Etype (First_Index (Arr)));
1766                Subt : constant Entity_Id := Make_Temporary (Loc, 'S');
1767                Decl : Node_Id;
1768
1769             begin
1770                Decl :=
1771                  Make_Subtype_Declaration (Loc,
1772                    Defining_Identifier => Subt,
1773                    Subtype_Indication  =>
1774                       Make_Subtype_Indication (Loc,
1775                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1776                         Constraint =>
1777                           Make_Range_Constraint (Loc,
1778                             Relocate_Node (DS))));
1779                Insert_Before (Parent (N), Decl);
1780                Analyze (Decl);
1781
1782                Rewrite (DS,
1783                   Make_Attribute_Reference (Loc,
1784                     Prefix => New_Reference_To (Subt, Loc),
1785                     Attribute_Name => Attribute_Name (DS)));
1786                Analyze (DS);
1787             end;
1788          end if;
1789       end Check_Controlled_Array_Attribute;
1790
1791    --  Start of processing for Analyze_Iteration_Scheme
1792
1793    begin
1794       --  If this is a rewritten quantified expression, the iteration
1795       --  scheme has been analyzed already. Do no repeat analysis because
1796       --  the loop variable is already declared.
1797
1798       if Analyzed (N) then
1799          return;
1800       end if;
1801
1802       --  For an infinite loop, there is no iteration scheme
1803
1804       if No (N) then
1805          return;
1806       end if;
1807
1808       --  Iteration scheme is present
1809
1810       declare
1811          Cond : constant Node_Id := Condition (N);
1812
1813       begin
1814          --  For WHILE loop, verify that the condition is a Boolean
1815          --  expression and resolve and check it.
1816
1817          if Present (Cond) then
1818             Analyze_And_Resolve (Cond, Any_Boolean);
1819             Check_Unset_Reference (Cond);
1820             Set_Current_Value_Condition (N);
1821             return;
1822
1823          elsif Present (Iterator_Specification (N)) then
1824             Analyze_Iterator_Specification (Iterator_Specification (N));
1825
1826          --  Else we have a FOR loop
1827
1828          else
1829             declare
1830                LP : constant Node_Id   := Loop_Parameter_Specification (N);
1831                Id : constant Entity_Id := Defining_Identifier (LP);
1832                DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1833
1834             begin
1835                Enter_Name (Id);
1836
1837                --  We always consider the loop variable to be referenced,
1838                --  since the loop may be used just for counting purposes.
1839
1840                Generate_Reference (Id, N, ' ');
1841
1842                --  Check for the case of loop variable hiding a local variable
1843                --  (used later on to give a nice warning if the hidden variable
1844                --  is never assigned).
1845
1846                declare
1847                   H : constant Entity_Id := Homonym (Id);
1848                begin
1849                   if Present (H)
1850                     and then Enclosing_Dynamic_Scope (H) =
1851                     Enclosing_Dynamic_Scope (Id)
1852                     and then Ekind (H) = E_Variable
1853                     and then Is_Discrete_Type (Etype (H))
1854                   then
1855                      Set_Hiding_Loop_Variable (H, Id);
1856                   end if;
1857                end;
1858
1859                --  Loop parameter specification must include subtype mark in
1860                --  SPARK or ALFA.
1861
1862                if Nkind (DS) = N_Range then
1863                   Check_Formal_Restriction ("loop parameter specification "
1864                                             & "must include subtype mark", N);
1865                end if;
1866
1867                --  Now analyze the subtype definition. If it is a range, create
1868                --  temporaries for bounds.
1869
1870                if Nkind (DS) = N_Range
1871                  and then Expander_Active
1872                then
1873                   Process_Bounds (DS);
1874
1875                --  Not a range or expander not active (is that right???)
1876
1877                else
1878                   Analyze (DS);
1879
1880                   if Nkind (DS) = N_Function_Call
1881                     or else
1882                       (Is_Entity_Name (DS)
1883                         and then not Is_Type (Entity (DS)))
1884                   then
1885                      --  This is an iterator specification. Rewrite as such
1886                      --  and analyze.
1887
1888                      declare
1889                         I_Spec : constant Node_Id :=
1890                                    Make_Iterator_Specification (Sloc (LP),
1891                                      Defining_Identifier =>
1892                                        Relocate_Node (Id),
1893                                      Name                =>
1894                                        Relocate_Node (DS),
1895                                      Subtype_Indication  =>
1896                                        Empty,
1897                                      Reverse_Present     =>
1898                                        Reverse_Present (LP));
1899                      begin
1900                         Set_Iterator_Specification (N, I_Spec);
1901                         Set_Loop_Parameter_Specification (N, Empty);
1902                         Analyze_Iterator_Specification (I_Spec);
1903                         return;
1904                      end;
1905                   end if;
1906                end if;
1907
1908                if DS = Error then
1909                   return;
1910                end if;
1911
1912                --  Some additional checks if we are iterating through a type
1913
1914                if Is_Entity_Name (DS)
1915                  and then Present (Entity (DS))
1916                  and then Is_Type (Entity (DS))
1917                then
1918                   --  The subtype indication may denote the completion of an
1919                   --  incomplete type declaration.
1920
1921                   if Ekind (Entity (DS)) = E_Incomplete_Type then
1922                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1923                      Set_Etype  (DS, Entity (DS));
1924                   end if;
1925
1926                   --  Attempt to iterate through non-static predicate
1927
1928                   if Is_Discrete_Type (Entity (DS))
1929                     and then Present (Predicate_Function (Entity (DS)))
1930                     and then No (Static_Predicate (Entity (DS)))
1931                   then
1932                      Bad_Predicated_Subtype_Use
1933                        ("cannot use subtype& with non-static "
1934                         & "predicate for loop iteration", DS, Entity (DS));
1935                   end if;
1936                end if;
1937
1938                --  Error if not discrete type
1939
1940                if not Is_Discrete_Type (Etype (DS)) then
1941                   Wrong_Type (DS, Any_Discrete);
1942                   Set_Etype (DS, Any_Type);
1943                end if;
1944
1945                Check_Controlled_Array_Attribute (DS);
1946
1947                Make_Index (DS, LP);
1948
1949                Set_Ekind (Id, E_Loop_Parameter);
1950
1951                --  If the loop is part of a predicate or precondition, it may
1952                --  be analyzed twice, once in the source and once on the copy
1953                --  used to check conformance. Preserve the original itype
1954                --  because the second one may be created in a different scope,
1955                --  e.g. a precondition procedure, leading to a crash in GIGI.
1956
1957                if No (Etype (Id)) or else Etype (Id) = Any_Type then
1958                   Set_Etype (Id, Etype (DS));
1959                end if;
1960
1961                --  Treat a range as an implicit reference to the type, to
1962                --  inhibit spurious warnings.
1963
1964                Generate_Reference (Base_Type (Etype (DS)), N, ' ');
1965                Set_Is_Known_Valid (Id, True);
1966
1967                --  The loop is not a declarative part, so the only entity
1968                --  declared "within" must be frozen explicitly.
1969
1970                declare
1971                   Flist : constant List_Id := Freeze_Entity (Id, N);
1972                begin
1973                   if Is_Non_Empty_List (Flist) then
1974                      Insert_Actions (N, Flist);
1975                   end if;
1976                end;
1977
1978                --  Check for null or possibly null range and issue warning. We
1979                --  suppress such messages in generic templates and instances,
1980                --  because in practice they tend to be dubious in these cases.
1981
1982                if Nkind (DS) = N_Range and then Comes_From_Source (N) then
1983                   declare
1984                      L : constant Node_Id := Low_Bound  (DS);
1985                      H : constant Node_Id := High_Bound (DS);
1986
1987                   begin
1988                      --  If range of loop is null, issue warning
1989
1990                      if Compile_Time_Compare
1991                           (L, H, Assume_Valid => True) = GT
1992                      then
1993                         --  Suppress the warning if inside a generic template
1994                         --  or instance, since in practice they tend to be
1995                         --  dubious in these cases since they can result from
1996                         --  intended parametrization.
1997
1998                         if not Inside_A_Generic
1999                           and then not In_Instance
2000                         then
2001                            --  Specialize msg if invalid values could make
2002                            --  the loop non-null after all.
2003
2004                            if Compile_Time_Compare
2005                                 (L, H, Assume_Valid => False) = GT
2006                            then
2007                               Error_Msg_N
2008                                 ("?loop range is null, loop will not execute",
2009                                  DS);
2010
2011                               --  Since we know the range of the loop is
2012                               --  null, set the appropriate flag to remove
2013                               --  the loop entirely during expansion.
2014
2015                               Set_Is_Null_Loop (Parent (N));
2016
2017                               --  Here is where the loop could execute because
2018                               --  of invalid values, so issue appropriate
2019                               --  message and in this case we do not set the
2020                               --  Is_Null_Loop flag since the loop may execute.
2021
2022                            else
2023                               Error_Msg_N
2024                                 ("?loop range may be null, "
2025                                  & "loop may not execute",
2026                                  DS);
2027                               Error_Msg_N
2028                                 ("?can only execute if invalid values "
2029                                  & "are present",
2030                                  DS);
2031                            end if;
2032                         end if;
2033
2034                         --  In either case, suppress warnings in the body of
2035                         --  the loop, since it is likely that these warnings
2036                         --  will be inappropriate if the loop never actually
2037                         --  executes, which is likely.
2038
2039                         Set_Suppress_Loop_Warnings (Parent (N));
2040
2041                         --  The other case for a warning is a reverse loop
2042                         --  where the upper bound is the integer literal zero
2043                         --  or one, and the lower bound can be positive.
2044
2045                         --  For example, we have
2046
2047                         --     for J in reverse N .. 1 loop
2048
2049                         --  In practice, this is very likely to be a case of
2050                         --  reversing the bounds incorrectly in the range.
2051
2052                      elsif Reverse_Present (LP)
2053                        and then Nkind (Original_Node (H)) =
2054                                                       N_Integer_Literal
2055                        and then (Intval (Original_Node (H)) = Uint_0
2056                                   or else
2057                                     Intval (Original_Node (H)) = Uint_1)
2058                      then
2059                         Error_Msg_N ("?loop range may be null", DS);
2060                         Error_Msg_N ("\?bounds may be wrong way round", DS);
2061                      end if;
2062                   end;
2063                end if;
2064             end;
2065          end if;
2066       end;
2067    end Analyze_Iteration_Scheme;
2068
2069    -------------------------------------
2070    --  Analyze_Iterator_Specification --
2071    -------------------------------------
2072
2073    procedure Analyze_Iterator_Specification (N : Node_Id) is
2074       Def_Id    : constant Node_Id := Defining_Identifier (N);
2075       Subt      : constant Node_Id := Subtype_Indication (N);
2076       Container : constant Node_Id := Name (N);
2077
2078       Ent : Entity_Id;
2079       Typ : Entity_Id;
2080
2081    begin
2082       Enter_Name (Def_Id);
2083       Set_Ekind (Def_Id, E_Variable);
2084
2085       if Present (Subt) then
2086          Analyze (Subt);
2087       end if;
2088
2089       Analyze_And_Resolve (Container);
2090       Typ := Etype (Container);
2091
2092       if Is_Array_Type (Typ) then
2093          if Of_Present (N) then
2094             Set_Etype (Def_Id, Component_Type (Typ));
2095          else
2096             Error_Msg_N
2097               ("to iterate over the elements of an array, use OF", N);
2098             Set_Etype (Def_Id, Etype (First_Index (Typ)));
2099          end if;
2100
2101       --  Iteration over a container
2102
2103       else
2104          Set_Ekind (Def_Id, E_Loop_Parameter);
2105
2106          if Of_Present (N) then
2107
2108             --  Find the Element_Type in the package instance that defines the
2109             --  container type.
2110
2111             Ent := First_Entity (Scope (Typ));
2112             while Present (Ent) loop
2113                if Chars (Ent) = Name_Element_Type then
2114                   Set_Etype (Def_Id, Ent);
2115                   exit;
2116                end if;
2117
2118                Next_Entity (Ent);
2119             end loop;
2120
2121          else
2122             --  Find the Cursor type in similar fashion
2123
2124             Ent := First_Entity (Scope (Typ));
2125             while Present (Ent) loop
2126                if Chars (Ent) = Name_Cursor then
2127                   Set_Etype (Def_Id, Ent);
2128                   exit;
2129                end if;
2130
2131                Next_Entity (Ent);
2132             end loop;
2133          end if;
2134       end if;
2135    end Analyze_Iterator_Specification;
2136
2137    -------------------
2138    -- Analyze_Label --
2139    -------------------
2140
2141    --  Note: the semantic work required for analyzing labels (setting them as
2142    --  reachable) was done in a prepass through the statements in the block,
2143    --  so that forward gotos would be properly handled. See Analyze_Statements
2144    --  for further details. The only processing required here is to deal with
2145    --  optimizations that depend on an assumption of sequential control flow,
2146    --  since of course the occurrence of a label breaks this assumption.
2147
2148    procedure Analyze_Label (N : Node_Id) is
2149       pragma Warnings (Off, N);
2150    begin
2151       Kill_Current_Values;
2152    end Analyze_Label;
2153
2154    --------------------------
2155    -- Analyze_Label_Entity --
2156    --------------------------
2157
2158    procedure Analyze_Label_Entity (E : Entity_Id) is
2159    begin
2160       Set_Ekind           (E, E_Label);
2161       Set_Etype           (E, Standard_Void_Type);
2162       Set_Enclosing_Scope (E, Current_Scope);
2163       Set_Reachable       (E, True);
2164    end Analyze_Label_Entity;
2165
2166    ----------------------------
2167    -- Analyze_Loop_Statement --
2168    ----------------------------
2169
2170    procedure Analyze_Loop_Statement (N : Node_Id) is
2171       Loop_Statement : constant Node_Id := N;
2172
2173       Id   : constant Node_Id := Identifier (Loop_Statement);
2174       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
2175       Ent  : Entity_Id;
2176
2177    begin
2178       if Present (Id) then
2179
2180          --  Make name visible, e.g. for use in exit statements. Loop
2181          --  labels are always considered to be referenced.
2182
2183          Analyze (Id);
2184          Ent := Entity (Id);
2185
2186          --  Guard against serious error (typically, a scope mismatch when
2187          --  semantic analysis is requested) by creating loop entity to
2188          --  continue analysis.
2189
2190          if No (Ent) then
2191             if Total_Errors_Detected /= 0 then
2192                Ent :=
2193                  New_Internal_Entity
2194                    (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2195             else
2196                raise Program_Error;
2197             end if;
2198
2199          else
2200             Generate_Reference  (Ent, Loop_Statement, ' ');
2201             Generate_Definition (Ent);
2202
2203             --  If we found a label, mark its type. If not, ignore it, since it
2204             --  means we have a conflicting declaration, which would already
2205             --  have been diagnosed at declaration time. Set Label_Construct
2206             --  of the implicit label declaration, which is not created by the
2207             --  parser for generic units.
2208
2209             if Ekind (Ent) = E_Label then
2210                Set_Ekind (Ent, E_Loop);
2211
2212                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
2213                   Set_Label_Construct (Parent (Ent), Loop_Statement);
2214                end if;
2215             end if;
2216          end if;
2217
2218       --  Case of no identifier present
2219
2220       else
2221          Ent :=
2222            New_Internal_Entity
2223              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2224          Set_Etype (Ent,  Standard_Void_Type);
2225          Set_Parent (Ent, Loop_Statement);
2226       end if;
2227
2228       --  Kill current values on entry to loop, since statements in body of
2229       --  loop may have been executed before the loop is entered. Similarly we
2230       --  kill values after the loop, since we do not know that the body of the
2231       --  loop was executed.
2232
2233       Kill_Current_Values;
2234       Push_Scope (Ent);
2235       Analyze_Iteration_Scheme (Iter);
2236       Analyze_Statements (Statements (Loop_Statement));
2237       Process_End_Label (Loop_Statement, 'e', Ent);
2238       End_Scope;
2239       Kill_Current_Values;
2240
2241       --  Check for infinite loop. Skip check for generated code, since it
2242       --  justs waste time and makes debugging the routine called harder.
2243
2244       --  Note that we have to wait till the body of the loop is fully analyzed
2245       --  before making this call, since Check_Infinite_Loop_Warning relies on
2246       --  being able to use semantic visibility information to find references.
2247
2248       if Comes_From_Source (N) then
2249          Check_Infinite_Loop_Warning (N);
2250       end if;
2251
2252       --  Code after loop is unreachable if the loop has no WHILE or FOR
2253       --  and contains no EXIT statements within the body of the loop.
2254
2255       if No (Iter) and then not Has_Exit (Ent) then
2256          Check_Unreachable_Code (N);
2257       end if;
2258    end Analyze_Loop_Statement;
2259
2260    ----------------------------
2261    -- Analyze_Null_Statement --
2262    ----------------------------
2263
2264    --  Note: the semantics of the null statement is implemented by a single
2265    --  null statement, too bad everything isn't as simple as this!
2266
2267    procedure Analyze_Null_Statement (N : Node_Id) is
2268       pragma Warnings (Off, N);
2269    begin
2270       null;
2271    end Analyze_Null_Statement;
2272
2273    ------------------------
2274    -- Analyze_Statements --
2275    ------------------------
2276
2277    procedure Analyze_Statements (L : List_Id) is
2278       S   : Node_Id;
2279       Lab : Entity_Id;
2280
2281    begin
2282       --  The labels declared in the statement list are reachable from
2283       --  statements in the list. We do this as a prepass so that any
2284       --  goto statement will be properly flagged if its target is not
2285       --  reachable. This is not required, but is nice behavior!
2286
2287       S := First (L);
2288       while Present (S) loop
2289          if Nkind (S) = N_Label then
2290             Analyze (Identifier (S));
2291             Lab := Entity (Identifier (S));
2292
2293             --  If we found a label mark it as reachable
2294
2295             if Ekind (Lab) = E_Label then
2296                Generate_Definition (Lab);
2297                Set_Reachable (Lab);
2298
2299                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
2300                   Set_Label_Construct (Parent (Lab), S);
2301                end if;
2302
2303             --  If we failed to find a label, it means the implicit declaration
2304             --  of the label was hidden.  A for-loop parameter can do this to
2305             --  a label with the same name inside the loop, since the implicit
2306             --  label declaration is in the innermost enclosing body or block
2307             --  statement.
2308
2309             else
2310                Error_Msg_Sloc := Sloc (Lab);
2311                Error_Msg_N
2312                  ("implicit label declaration for & is hidden#",
2313                   Identifier (S));
2314             end if;
2315          end if;
2316
2317          Next (S);
2318       end loop;
2319
2320       --  Perform semantic analysis on all statements
2321
2322       Conditional_Statements_Begin;
2323
2324       S := First (L);
2325       while Present (S) loop
2326          Analyze (S);
2327          Next (S);
2328       end loop;
2329
2330       Conditional_Statements_End;
2331
2332       --  Make labels unreachable. Visibility is not sufficient, because
2333       --  labels in one if-branch for example are not reachable from the
2334       --  other branch, even though their declarations are in the enclosing
2335       --  declarative part.
2336
2337       S := First (L);
2338       while Present (S) loop
2339          if Nkind (S) = N_Label then
2340             Set_Reachable (Entity (Identifier (S)), False);
2341          end if;
2342
2343          Next (S);
2344       end loop;
2345    end Analyze_Statements;
2346
2347    ----------------------------
2348    -- Check_Unreachable_Code --
2349    ----------------------------
2350
2351    procedure Check_Unreachable_Code (N : Node_Id) is
2352       Error_Loc : Source_Ptr;
2353       P         : Node_Id;
2354
2355    begin
2356       if Is_List_Member (N)
2357         and then Comes_From_Source (N)
2358       then
2359          declare
2360             Nxt : Node_Id;
2361
2362          begin
2363             Nxt := Original_Node (Next (N));
2364
2365             --  If a label follows us, then we never have dead code, since
2366             --  someone could branch to the label, so we just ignore it,
2367             --  unless we are in formal mode where goto statements are not
2368             --  allowed.
2369
2370             if Nkind (Nxt) = N_Label and then not Formal_Verification_Mode then
2371                return;
2372
2373             --  Otherwise see if we have a real statement following us
2374
2375             elsif Present (Nxt)
2376               and then Comes_From_Source (Nxt)
2377               and then Is_Statement (Nxt)
2378             then
2379                --  Special very annoying exception. If we have a return that
2380                --  follows a raise, then we allow it without a warning, since
2381                --  the Ada RM annoyingly requires a useless return here!
2382
2383                if Nkind (Original_Node (N)) /= N_Raise_Statement
2384                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2385                then
2386                   --  The rather strange shenanigans with the warning message
2387                   --  here reflects the fact that Kill_Dead_Code is very good
2388                   --  at removing warnings in deleted code, and this is one
2389                   --  warning we would prefer NOT to have removed.
2390
2391                   Error_Loc := Sloc (Nxt);
2392
2393                   --  If we have unreachable code, analyze and remove the
2394                   --  unreachable code, since it is useless and we don't
2395                   --  want to generate junk warnings.
2396
2397                   --  We skip this step if we are not in code generation mode.
2398                   --  This is the one case where we remove dead code in the
2399                   --  semantics as opposed to the expander, and we do not want
2400                   --  to remove code if we are not in code generation mode,
2401                   --  since this messes up the ASIS trees.
2402
2403                   --  Note that one might react by moving the whole circuit to
2404                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2405
2406                   if Operating_Mode = Generate_Code then
2407                      loop
2408                         Nxt := Next (N);
2409
2410                         --  Quit deleting when we have nothing more to delete
2411                         --  or if we hit a label (since someone could transfer
2412                         --  control to a label, so we should not delete it).
2413
2414                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2415
2416                         --  Statement/declaration is to be deleted
2417
2418                         Analyze (Nxt);
2419                         Remove (Nxt);
2420                         Kill_Dead_Code (Nxt);
2421                      end loop;
2422                   end if;
2423
2424                   --  Now issue the warning (or error in formal mode)
2425
2426                   if Formal_Verification_Mode then
2427                      Error_Msg
2428                        ("|~~unreachable code is not allowed", Error_Loc);
2429                   else
2430                      Error_Msg ("?unreachable code!", Error_Loc);
2431                   end if;
2432                end if;
2433
2434             --  If the unconditional transfer of control instruction is
2435             --  the last statement of a sequence, then see if our parent
2436             --  is one of the constructs for which we count unblocked exits,
2437             --  and if so, adjust the count.
2438
2439             else
2440                P := Parent (N);
2441
2442                --  Statements in THEN part or ELSE part of IF statement
2443
2444                if Nkind (P) = N_If_Statement then
2445                   null;
2446
2447                --  Statements in ELSIF part of an IF statement
2448
2449                elsif Nkind (P) = N_Elsif_Part then
2450                   P := Parent (P);
2451                   pragma Assert (Nkind (P) = N_If_Statement);
2452
2453                --  Statements in CASE statement alternative
2454
2455                elsif Nkind (P) = N_Case_Statement_Alternative then
2456                   P := Parent (P);
2457                   pragma Assert (Nkind (P) = N_Case_Statement);
2458
2459                --  Statements in body of block
2460
2461                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2462                  and then Nkind (Parent (P)) = N_Block_Statement
2463                then
2464                   null;
2465
2466                --  Statements in exception handler in a block
2467
2468                elsif Nkind (P) = N_Exception_Handler
2469                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2470                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2471                then
2472                   null;
2473
2474                --  None of these cases, so return
2475
2476                else
2477                   return;
2478                end if;
2479
2480                --  This was one of the cases we are looking for (i.e. the
2481                --  parent construct was IF, CASE or block) so decrement count.
2482
2483                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2484             end if;
2485          end;
2486       end if;
2487    end Check_Unreachable_Code;
2488
2489 end Sem_Ch5;