gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Case; use Sem_Case;
  42 with Sem_Ch3;  use Sem_Ch3;
  43 with Sem_Ch8;  use Sem_Ch8;
  44 with Sem_Disp; use Sem_Disp;
  45 with Sem_Elab; use Sem_Elab;
  46 with Sem_Eval; use Sem_Eval;
  47 with Sem_Res;  use Sem_Res;
  48 with Sem_Type; use Sem_Type;
  49 with Sem_Util; use Sem_Util;
  50 with Sem_Warn; use Sem_Warn;
  51 with Snames;   use Snames;
  52 with Stand;    use Stand;
  53 with Sinfo;    use Sinfo;
  54 with Targparm; use Targparm;
  55 with Tbuild;   use Tbuild;
  56 with Uintp;    use Uintp;
  57
  58 package body Sem_Ch5 is
  59
  60    Unblocked_Exit_Count : Nat := 0;
  61    --  This variable is used when processing if statements, case statements,
  62    --  and block statements. It counts the number of exit points that are not
  63    --  blocked by unconditional transfer instructions: for IF and CASE, these
  64    --  are the branches of the conditional; for a block, they are the statement
  65    --  sequence of the block, and the statement sequences of any exception
  66    --  handlers that are part of the block. When processing is complete, if
  67    --  this count is zero, it means that control cannot fall through the IF,
  68    --  CASE or block statement. This is used for the generation of warning
  69    --  messages. This variable is recursively saved on entry to processing the
  70    --  construct, and restored on exit.
  71
  72    -----------------------
  73    -- Local Subprograms --
  74    -----------------------
  75
  76    procedure Analyze_Iteration_Scheme (N : Node_Id);
  77
  78    ------------------------
  79    -- Analyze_Assignment --
  80    ------------------------
  81
  82    procedure Analyze_Assignment (N : Node_Id) is
  83       Lhs  : constant Node_Id := Name (N);
  84       Rhs  : constant Node_Id := Expression (N);
  85       T1   : Entity_Id;
  86       T2   : Entity_Id;
  87       Decl : Node_Id;
  88
  89       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  90       --  N is the node for the left hand side of an assignment, and it
  91       --  is not a variable. This routine issues an appropriate diagnostic.
  92
  93       procedure Kill_Lhs;
  94       --  This is called to kill current value settings of a simple variable
  95       --  on the left hand side. We call it if we find any error in analyzing
  96       --  the assignment, and at the end of processing before setting any new
  97       --  current values in place.
  98
  99       procedure Set_Assignment_Type
 100         (Opnd      : Node_Id;
 101          Opnd_Type : in out Entity_Id);
 102       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 103       --  is the nominal subtype. This procedure is used to deal with cases
 104       --  where the nominal subtype must be replaced by the actual subtype.
 105
 106       -------------------------------
 107       -- Diagnose_Non_Variable_Lhs --
 108       -------------------------------
 109
 110       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 111       begin
 112          --  Not worth posting another error if left hand side already
 113          --  flagged as being illegal in some respect.
 114
 115          if Error_Posted (N) then
 116             return;
 117
 118          --  Some special bad cases of entity names
 119
 120          elsif Is_Entity_Name (N) then
 121             declare
 122                Ent : constant Entity_Id := Entity (N);
 123
 124             begin
 125                if Ekind (Ent) = E_In_Parameter then
 126                   Error_Msg_N
 127                     ("assignment to IN mode parameter not allowed", N);
 128
 129                --  Renamings of protected private components are turned into
 130                --  constants when compiling a protected function. In the case
 131                --  of single protected types, the private component appears
 132                --  directly.
 133
 134                elsif (Is_Prival (Ent)
 135                         and then
 136                           (Ekind (Current_Scope) = E_Function
 137                              or else Ekind (Enclosing_Dynamic_Scope (
 138                                        Current_Scope)) = E_Function))
 139                    or else
 140                      (Ekind (Ent) = E_Component
 141                         and then Is_Protected_Type (Scope (Ent)))
 142                then
 143                   Error_Msg_N
 144                     ("protected function cannot modify protected object", N);
 145
 146                elsif Ekind (Ent) = E_Loop_Parameter then
 147                   Error_Msg_N
 148                     ("assignment to loop parameter not allowed", N);
 149
 150                else
 151                   Error_Msg_N
 152                     ("left hand side of assignment must be a variable", N);
 153                end if;
 154             end;
 155
 156          --  For indexed components or selected components, test prefix
 157
 158          elsif Nkind (N) = N_Indexed_Component then
 159             Diagnose_Non_Variable_Lhs (Prefix (N));
 160
 161          --  Another special case for assignment to discriminant
 162
 163          elsif Nkind (N) = N_Selected_Component then
 164             if Present (Entity (Selector_Name (N)))
 165               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 166             then
 167                Error_Msg_N
 168                  ("assignment to discriminant not allowed", N);
 169             else
 170                Diagnose_Non_Variable_Lhs (Prefix (N));
 171             end if;
 172
 173          else
 174             --  If we fall through, we have no special message to issue!
 175
 176             Error_Msg_N ("left hand side of assignment must be a variable", N);
 177          end if;
 178       end Diagnose_Non_Variable_Lhs;
 179
 180       --------------
 181       -- Kill_LHS --
 182       --------------
 183
 184       procedure Kill_Lhs is
 185       begin
 186          if Is_Entity_Name (Lhs) then
 187             declare
 188                Ent : constant Entity_Id := Entity (Lhs);
 189             begin
 190                if Present (Ent) then
 191                   Kill_Current_Values (Ent);
 192                end if;
 193             end;
 194          end if;
 195       end Kill_Lhs;
 196
 197       -------------------------
 198       -- Set_Assignment_Type --
 199       -------------------------
 200
 201       procedure Set_Assignment_Type
 202         (Opnd      : Node_Id;
 203          Opnd_Type : in out Entity_Id)
 204       is
 205       begin
 206          Require_Entity (Opnd);
 207
 208          --  If the assignment operand is an in-out or out parameter, then we
 209          --  get the actual subtype (needed for the unconstrained case).
 210          --  If the operand is the actual in an entry declaration, then within
 211          --  the accept statement it is replaced with a local renaming, which
 212          --  may also have an actual subtype.
 213
 214          if Is_Entity_Name (Opnd)
 215            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 216                       or else Ekind (Entity (Opnd)) =
 217                            E_In_Out_Parameter
 218                       or else Ekind (Entity (Opnd)) =
 219                            E_Generic_In_Out_Parameter
 220                       or else
 221                         (Ekind (Entity (Opnd)) = E_Variable
 222                           and then Nkind (Parent (Entity (Opnd))) =
 223                              N_Object_Renaming_Declaration
 224                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 225                              N_Accept_Statement))
 226          then
 227             Opnd_Type := Get_Actual_Subtype (Opnd);
 228
 229          --  If assignment operand is a component reference, then we get the
 230          --  actual subtype of the component for the unconstrained case.
 231
 232          elsif Nkind_In (Opnd, N_Selected_Component, N_Explicit_Dereference)
 233            and then not Is_Unchecked_Union (Opnd_Type)
 234          then
 235             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 236
 237             if Present (Decl) then
 238                Insert_Action (N, Decl);
 239                Mark_Rewrite_Insertion (Decl);
 240                Analyze (Decl);
 241                Opnd_Type := Defining_Identifier (Decl);
 242                Set_Etype (Opnd, Opnd_Type);
 243                Freeze_Itype (Opnd_Type, N);
 244
 245             elsif Is_Constrained (Etype (Opnd)) then
 246                Opnd_Type := Etype (Opnd);
 247             end if;
 248
 249          --  For slice, use the constrained subtype created for the slice
 250
 251          elsif Nkind (Opnd) = N_Slice then
 252             Opnd_Type := Etype (Opnd);
 253          end if;
 254       end Set_Assignment_Type;
 255
 256    --  Start of processing for Analyze_Assignment
 257
 258    begin
 259       Mark_Coextensions (N, Rhs);
 260
 261       Analyze (Rhs);
 262       Analyze (Lhs);
 263
 264       --  Start type analysis for assignment
 265
 266       T1 := Etype (Lhs);
 267
 268       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 269       --  must compute the intersection of the possible types on each side.
 270
 271       if Is_Overloaded (Lhs) then
 272          declare
 273             I  : Interp_Index;
 274             It : Interp;
 275
 276          begin
 277             T1 := Any_Type;
 278             Get_First_Interp (Lhs, I, It);
 279
 280             while Present (It.Typ) loop
 281                if Has_Compatible_Type (Rhs, It.Typ) then
 282                   if T1 /= Any_Type then
 283
 284                      --  An explicit dereference is overloaded if the prefix
 285                      --  is. Try to remove the ambiguity on the prefix, the
 286                      --  error will be posted there if the ambiguity is real.
 287
 288                      if Nkind (Lhs) = N_Explicit_Dereference then
 289                         declare
 290                            PI    : Interp_Index;
 291                            PI1   : Interp_Index := 0;
 292                            PIt   : Interp;
 293                            Found : Boolean;
 294
 295                         begin
 296                            Found := False;
 297                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 298
 299                            while Present (PIt.Typ) loop
 300                               if Is_Access_Type (PIt.Typ)
 301                                 and then Has_Compatible_Type
 302                                            (Rhs, Designated_Type (PIt.Typ))
 303                               then
 304                                  if Found then
 305                                     PIt :=
 306                                       Disambiguate (Prefix (Lhs),
 307                                         PI1, PI, Any_Type);
 308
 309                                     if PIt = No_Interp then
 310                                        Error_Msg_N
 311                                          ("ambiguous left-hand side"
 312                                             & " in assignment", Lhs);
 313                                        exit;
 314                                     else
 315                                        Resolve (Prefix (Lhs), PIt.Typ);
 316                                     end if;
 317
 318                                     exit;
 319                                  else
 320                                     Found := True;
 321                                     PI1 := PI;
 322                                  end if;
 323                               end if;
 324
 325                               Get_Next_Interp (PI, PIt);
 326                            end loop;
 327                         end;
 328
 329                      else
 330                         Error_Msg_N
 331                           ("ambiguous left-hand side in assignment", Lhs);
 332                         exit;
 333                      end if;
 334                   else
 335                      T1 := It.Typ;
 336                   end if;
 337                end if;
 338
 339                Get_Next_Interp (I, It);
 340             end loop;
 341          end;
 342
 343          if T1 = Any_Type then
 344             Error_Msg_N
 345               ("no valid types for left-hand side for assignment", Lhs);
 346             Kill_Lhs;
 347             return;
 348          end if;
 349       end if;
 350
 351       --  The resulting assignment type is T1, so now we will resolve the
 352       --  left hand side of the assignment using this determined type.
 353
 354       Resolve (Lhs, T1);
 355
 356       --  Cases where Lhs is not a variable
 357
 358       if not Is_Variable (Lhs) then
 359
 360          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 361          --  a protected object.
 362
 363          declare
 364             Ent : Entity_Id;
 365             S   : Entity_Id;
 366
 367          begin
 368             if Ada_Version >= Ada_05 then
 369
 370                --  Handle chains of renamings
 371
 372                Ent := Lhs;
 373                while Nkind (Ent) in N_Has_Entity
 374                  and then Present (Entity (Ent))
 375                  and then Present (Renamed_Object (Entity (Ent)))
 376                loop
 377                   Ent := Renamed_Object (Entity (Ent));
 378                end loop;
 379
 380                if (Nkind (Ent) = N_Attribute_Reference
 381                      and then Attribute_Name (Ent) = Name_Priority)
 382
 383                   --  Renamings of the attribute Priority applied to protected
 384                   --  objects have been previously expanded into calls to the
 385                   --  Get_Ceiling run-time subprogram.
 386
 387                  or else
 388                   (Nkind (Ent) = N_Function_Call
 389                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 390                                 or else
 391                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 392                then
 393                   --  The enclosing subprogram cannot be a protected function
 394
 395                   S := Current_Scope;
 396                   while not (Is_Subprogram (S)
 397                                and then Convention (S) = Convention_Protected)
 398                      and then S /= Standard_Standard
 399                   loop
 400                      S := Scope (S);
 401                   end loop;
 402
 403                   if Ekind (S) = E_Function
 404                     and then Convention (S) = Convention_Protected
 405                   then
 406                      Error_Msg_N
 407                        ("protected function cannot modify protected object",
 408                         Lhs);
 409                   end if;
 410
 411                   --  Changes of the ceiling priority of the protected object
 412                   --  are only effective if the Ceiling_Locking policy is in
 413                   --  effect (AARM D.5.2 (5/2)).
 414
 415                   if Locking_Policy /= 'C' then
 416                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 417                                   "no effect?", Lhs);
 418                      Error_Msg_N ("\since no Locking_Policy has been " &
 419                                   "specified", Lhs);
 420                   end if;
 421
 422                   return;
 423                end if;
 424             end if;
 425          end;
 426
 427          Diagnose_Non_Variable_Lhs (Lhs);
 428          return;
 429
 430       --  Error of assigning to limited type. We do however allow this in
 431       --  certain cases where the front end generates the assignments.
 432
 433       elsif Is_Limited_Type (T1)
 434         and then not Assignment_OK (Lhs)
 435         and then not Assignment_OK (Original_Node (Lhs))
 436         and then not Is_Value_Type (T1)
 437       then
 438          Error_Msg_N
 439            ("left hand of assignment must not be limited type", Lhs);
 440          Explain_Limited_Type (T1, Lhs);
 441          return;
 442
 443       --  Enforce RM 3.9.3 (8): left-hand side cannot be abstract
 444
 445       elsif Is_Interface (T1)
 446         and then not Is_Class_Wide_Type (T1)
 447       then
 448          Error_Msg_N
 449            ("target of assignment operation may not be abstract", Lhs);
 450          return;
 451       end if;
 452
 453       --  Resolution may have updated the subtype, in case the left-hand
 454       --  side is a private protected component. Use the correct subtype
 455       --  to avoid scoping issues in the back-end.
 456
 457       T1 := Etype (Lhs);
 458
 459       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 460       --  type. For example:
 461
 462       --    limited with P;
 463       --    package Pkg is
 464       --      type Acc is access P.T;
 465       --    end Pkg;
 466
 467       --    with Pkg; use Acc;
 468       --    procedure Example is
 469       --       A, B : Acc;
 470       --    begin
 471       --       A.all := B.all;  -- ERROR
 472       --    end Example;
 473
 474       if Nkind (Lhs) = N_Explicit_Dereference
 475         and then Ekind (T1) = E_Incomplete_Type
 476       then
 477          Error_Msg_N ("invalid use of incomplete type", Lhs);
 478          Kill_Lhs;
 479          return;
 480       end if;
 481
 482       --  Now we can complete the resolution of the right hand side
 483
 484       Set_Assignment_Type (Lhs, T1);
 485       Resolve (Rhs, T1);
 486
 487       --  This is the point at which we check for an unset reference
 488
 489       Check_Unset_Reference (Rhs);
 490       Check_Unprotected_Access (Lhs, Rhs);
 491
 492       --  Remaining steps are skipped if Rhs was syntactically in error
 493
 494       if Rhs = Error then
 495          Kill_Lhs;
 496          return;
 497       end if;
 498
 499       T2 := Etype (Rhs);
 500
 501       if not Covers (T1, T2) then
 502          Wrong_Type (Rhs, Etype (Lhs));
 503          Kill_Lhs;
 504          return;
 505       end if;
 506
 507       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 508       --  types, use the non-limited view if available
 509
 510       if Nkind (Rhs) = N_Explicit_Dereference
 511         and then Ekind (T2) = E_Incomplete_Type
 512         and then Is_Tagged_Type (T2)
 513         and then Present (Non_Limited_View (T2))
 514       then
 515          T2 := Non_Limited_View (T2);
 516       end if;
 517
 518       Set_Assignment_Type (Rhs, T2);
 519
 520       if Total_Errors_Detected /= 0 then
 521          if No (T1) then
 522             T1 := Any_Type;
 523          end if;
 524
 525          if No (T2) then
 526             T2 := Any_Type;
 527          end if;
 528       end if;
 529
 530       if T1 = Any_Type or else T2 = Any_Type then
 531          Kill_Lhs;
 532          return;
 533       end if;
 534
 535       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 536       --  to be class-wide. The case where the rhs is a dynamically tagged call
 537       --  to a dispatching operation with a controlling access result is
 538       --  excluded from this check, since the target has an access type (and
 539       --  no tag propagation occurs in that case).
 540
 541       if (Is_Class_Wide_Type (T2)
 542            or else (Is_Dynamically_Tagged (Rhs)
 543                      and then not Is_Access_Type (T1)))
 544         and then not Is_Class_Wide_Type (T1)
 545       then
 546          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 547
 548       elsif Is_Class_Wide_Type (T1)
 549         and then not Is_Class_Wide_Type (T2)
 550         and then not Is_Tag_Indeterminate (Rhs)
 551         and then not Is_Dynamically_Tagged (Rhs)
 552       then
 553          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 554       end if;
 555
 556       --  Propagate the tag from a class-wide target to the rhs when the rhs
 557       --  is a tag-indeterminate call.
 558
 559       if Is_Tag_Indeterminate (Rhs) then
 560          if Is_Class_Wide_Type (T1) then
 561             Propagate_Tag (Lhs, Rhs);
 562
 563          elsif Nkind (Rhs) = N_Function_Call
 564               and then Is_Entity_Name (Name (Rhs))
 565               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 566          then
 567             Error_Msg_N
 568               ("call to abstract function must be dispatching", Name (Rhs));
 569
 570          elsif Nkind (Rhs) = N_Qualified_Expression
 571            and then Nkind (Expression (Rhs)) = N_Function_Call
 572               and then Is_Entity_Name (Name (Expression (Rhs)))
 573               and then
 574                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 575          then
 576             Error_Msg_N
 577               ("call to abstract function must be dispatching",
 578                 Name (Expression (Rhs)));
 579          end if;
 580       end if;
 581
 582       --  Ada 2005 (AI-230 and AI-385): When the lhs type is an anonymous
 583       --  access type, apply an implicit conversion of the rhs to that type
 584       --  to force appropriate static and run-time accessibility checks.
 585
 586       if Ada_Version >= Ada_05
 587         and then Ekind (T1) = E_Anonymous_Access_Type
 588       then
 589          Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 590          Analyze_And_Resolve (Rhs, T1);
 591       end if;
 592
 593       --  Ada 2005 (AI-231): Assignment to not null variable
 594
 595       if Ada_Version >= Ada_05
 596         and then Can_Never_Be_Null (T1)
 597         and then not Assignment_OK (Lhs)
 598       then
 599          --  Case where we know the right hand side is null
 600
 601          if Known_Null (Rhs) then
 602             Apply_Compile_Time_Constraint_Error
 603               (N   => Rhs,
 604                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 605                Reason => CE_Null_Not_Allowed);
 606
 607             --  We still mark this as a possible modification, that's necessary
 608             --  to reset Is_True_Constant, and desirable for xref purposes.
 609
 610             Note_Possible_Modification (Lhs, Sure => True);
 611             return;
 612
 613          --  If we know the right hand side is non-null, then we convert to the
 614          --  target type, since we don't need a run time check in that case.
 615
 616          elsif not Can_Never_Be_Null (T2) then
 617             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 618             Analyze_And_Resolve (Rhs, T1);
 619          end if;
 620       end if;
 621
 622       if Is_Scalar_Type (T1) then
 623          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 624
 625       --  For array types, verify that lengths match. If the right hand side
 626       --  if a function call that has been inlined, the assignment has been
 627       --  rewritten as a block, and the constraint check will be applied to the
 628       --  assignment within the block.
 629
 630       elsif Is_Array_Type (T1)
 631         and then
 632           (Nkind (Rhs) /= N_Type_Conversion
 633             or else Is_Constrained (Etype (Rhs)))
 634         and then
 635           (Nkind (Rhs) /= N_Function_Call
 636             or else Nkind (N) /= N_Block_Statement)
 637       then
 638          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 639          --  but of course the indices do not have to match. If the right-hand
 640          --  side is a type conversion to an unconstrained type, a length check
 641          --  is performed on the expression itself during expansion. In rare
 642          --  cases, the redundant length check is computed on an index type
 643          --  with a different representation, triggering incorrect code in
 644          --  the back end.
 645
 646          Apply_Length_Check (Rhs, Etype (Lhs));
 647
 648       else
 649          --  Discriminant checks are applied in the course of expansion
 650
 651          null;
 652       end if;
 653
 654       --  Note: modifications of the Lhs may only be recorded after
 655       --  checks have been applied.
 656
 657       Note_Possible_Modification (Lhs, Sure => True);
 658
 659       --  ??? a real accessibility check is needed when ???
 660
 661       --  Post warning for redundant assignment or variable to itself
 662
 663       if Warn_On_Redundant_Constructs
 664
 665          --  We only warn for source constructs
 666
 667          and then Comes_From_Source (N)
 668
 669          --  Where the object is the same on both sides
 670
 671          and then Same_Object (Lhs, Original_Node (Rhs))
 672
 673          --  But exclude the case where the right side was an operation
 674          --  that got rewritten (e.g. JUNK + K, where K was known to be
 675          --  zero). We don't want to warn in such a case, since it is
 676          --  reasonable to write such expressions especially when K is
 677          --  defined symbolically in some other package.
 678
 679         and then Nkind (Original_Node (Rhs)) not in N_Op
 680       then
 681          if Nkind (Lhs) in N_Has_Entity then
 682             Error_Msg_NE
 683               ("?useless assignment of & to itself!", N, Entity (Lhs));
 684          else
 685             Error_Msg_N
 686               ("?useless assignment of object to itself!", N);
 687          end if;
 688       end if;
 689
 690       --  Check for non-allowed composite assignment
 691
 692       if not Support_Composite_Assign_On_Target
 693         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 694         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 695       then
 696          Error_Msg_CRT ("composite assignment", N);
 697       end if;
 698
 699       --  Check elaboration warning for left side if not in elab code
 700
 701       if not In_Subprogram_Or_Concurrent_Unit then
 702          Check_Elab_Assign (Lhs);
 703       end if;
 704
 705       --  Set Referenced_As_LHS if appropriate. We only set this flag if the
 706       --  assignment is a source assignment in the extended main source unit.
 707       --  We are not interested in any reference information outside this
 708       --  context, or in compiler generated assignment statements.
 709
 710       if Comes_From_Source (N)
 711         and then In_Extended_Main_Source_Unit (Lhs)
 712       then
 713          Set_Referenced_Modified (Lhs, Out_Param => False);
 714       end if;
 715
 716       --  Final step. If left side is an entity, then we may be able to
 717       --  reset the current tracked values to new safe values. We only have
 718       --  something to do if the left side is an entity name, and expansion
 719       --  has not modified the node into something other than an assignment,
 720       --  and of course we only capture values if it is safe to do so.
 721
 722       if Is_Entity_Name (Lhs)
 723         and then Nkind (N) = N_Assignment_Statement
 724       then
 725          declare
 726             Ent : constant Entity_Id := Entity (Lhs);
 727
 728          begin
 729             if Safe_To_Capture_Value (N, Ent) then
 730
 731                --  If simple variable on left side, warn if this assignment
 732                --  blots out another one (rendering it useless) and note
 733                --  location of assignment in case no one references value.
 734                --  We only do this for source assignments, otherwise we can
 735                --  generate bogus warnings when an assignment is rewritten as
 736                --  another assignment, and gets tied up with itself.
 737
 738                --  Note: we don't use Record_Last_Assignment here, because we
 739                --  have lots of other stuff to do under control of this test.
 740
 741                if Warn_On_Modified_Unread
 742                  and then Is_Assignable (Ent)
 743                  and then Comes_From_Source (N)
 744                  and then In_Extended_Main_Source_Unit (Ent)
 745                then
 746                   Warn_On_Useless_Assignment (Ent, N);
 747                   Set_Last_Assignment (Ent, Lhs);
 748                end if;
 749
 750                --  If we are assigning an access type and the left side is an
 751                --  entity, then make sure that the Is_Known_[Non_]Null flags
 752                --  properly reflect the state of the entity after assignment.
 753
 754                if Is_Access_Type (T1) then
 755                   if Known_Non_Null (Rhs) then
 756                      Set_Is_Known_Non_Null (Ent, True);
 757
 758                   elsif Known_Null (Rhs)
 759                     and then not Can_Never_Be_Null (Ent)
 760                   then
 761                      Set_Is_Known_Null (Ent, True);
 762
 763                   else
 764                      Set_Is_Known_Null (Ent, False);
 765
 766                      if not Can_Never_Be_Null (Ent) then
 767                         Set_Is_Known_Non_Null (Ent, False);
 768                      end if;
 769                   end if;
 770
 771                --  For discrete types, we may be able to set the current value
 772                --  if the value is known at compile time.
 773
 774                elsif Is_Discrete_Type (T1)
 775                  and then Compile_Time_Known_Value (Rhs)
 776                then
 777                   Set_Current_Value (Ent, Rhs);
 778                else
 779                   Set_Current_Value (Ent, Empty);
 780                end if;
 781
 782             --  If not safe to capture values, kill them
 783
 784             else
 785                Kill_Lhs;
 786             end if;
 787          end;
 788       end if;
 789    end Analyze_Assignment;
 790
 791    -----------------------------
 792    -- Analyze_Block_Statement --
 793    -----------------------------
 794
 795    procedure Analyze_Block_Statement (N : Node_Id) is
 796       Decls : constant List_Id := Declarations (N);
 797       Id    : constant Node_Id := Identifier (N);
 798       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 799
 800    begin
 801       --  If no handled statement sequence is present, things are really
 802       --  messed up, and we just return immediately (this is a defence
 803       --  against previous errors).
 804
 805       if No (HSS) then
 806          return;
 807       end if;
 808
 809       --  Normal processing with HSS present
 810
 811       declare
 812          EH  : constant List_Id := Exception_Handlers (HSS);
 813          Ent : Entity_Id        := Empty;
 814          S   : Entity_Id;
 815
 816          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 817          --  Recursively save value of this global, will be restored on exit
 818
 819       begin
 820          --  Initialize unblocked exit count for statements of begin block
 821          --  plus one for each exception handler that is present.
 822
 823          Unblocked_Exit_Count := 1;
 824
 825          if Present (EH) then
 826             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 827          end if;
 828
 829          --  If a label is present analyze it and mark it as referenced
 830
 831          if Present (Id) then
 832             Analyze (Id);
 833             Ent := Entity (Id);
 834
 835             --  An error defense. If we have an identifier, but no entity,
 836             --  then something is wrong. If we have previous errors, then
 837             --  just remove the identifier and continue, otherwise raise
 838             --  an exception.
 839
 840             if No (Ent) then
 841                if Total_Errors_Detected /= 0 then
 842                   Set_Identifier (N, Empty);
 843                else
 844                   raise Program_Error;
 845                end if;
 846
 847             else
 848                Set_Ekind (Ent, E_Block);
 849                Generate_Reference (Ent, N, ' ');
 850                Generate_Definition (Ent);
 851
 852                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 853                   Set_Label_Construct (Parent (Ent), N);
 854                end if;
 855             end if;
 856          end if;
 857
 858          --  If no entity set, create a label entity
 859
 860          if No (Ent) then
 861             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 862             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 863             Set_Parent (Ent, N);
 864          end if;
 865
 866          Set_Etype (Ent, Standard_Void_Type);
 867          Set_Block_Node (Ent, Identifier (N));
 868          Push_Scope (Ent);
 869
 870          if Present (Decls) then
 871             Analyze_Declarations (Decls);
 872             Check_Completion;
 873             Inspect_Deferred_Constant_Completion (Decls);
 874          end if;
 875
 876          Analyze (HSS);
 877          Process_End_Label (HSS, 'e', Ent);
 878
 879          --  If exception handlers are present, then we indicate that
 880          --  enclosing scopes contain a block with handlers. We only
 881          --  need to mark non-generic scopes.
 882
 883          if Present (EH) then
 884             S := Scope (Ent);
 885             loop
 886                Set_Has_Nested_Block_With_Handler (S);
 887                exit when Is_Overloadable (S)
 888                  or else Ekind (S) = E_Package
 889                  or else Is_Generic_Unit (S);
 890                S := Scope (S);
 891             end loop;
 892          end if;
 893
 894          Check_References (Ent);
 895          Warn_On_Useless_Assignments (Ent);
 896          End_Scope;
 897
 898          if Unblocked_Exit_Count = 0 then
 899             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 900             Check_Unreachable_Code (N);
 901          else
 902             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 903          end if;
 904       end;
 905    end Analyze_Block_Statement;
 906
 907    ----------------------------
 908    -- Analyze_Case_Statement --
 909    ----------------------------
 910
 911    procedure Analyze_Case_Statement (N : Node_Id) is
 912       Exp            : Node_Id;
 913       Exp_Type       : Entity_Id;
 914       Exp_Btype      : Entity_Id;
 915       Last_Choice    : Nat;
 916       Dont_Care      : Boolean;
 917       Others_Present : Boolean;
 918
 919       pragma Warnings (Off, Last_Choice);
 920       pragma Warnings (Off, Dont_Care);
 921       --  Don't care about assigned values
 922
 923       Statements_Analyzed : Boolean := False;
 924       --  Set True if at least some statement sequences get analyzed.
 925       --  If False on exit, means we had a serious error that prevented
 926       --  full analysis of the case statement, and as a result it is not
 927       --  a good idea to output warning messages about unreachable code.
 928
 929       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 930       --  Recursively save value of this global, will be restored on exit
 931
 932       procedure Non_Static_Choice_Error (Choice : Node_Id);
 933       --  Error routine invoked by the generic instantiation below when
 934       --  the case statement has a non static choice.
 935
 936       procedure Process_Statements (Alternative : Node_Id);
 937       --  Analyzes all the statements associated to a case alternative.
 938       --  Needed by the generic instantiation below.
 939
 940       package Case_Choices_Processing is new
 941         Generic_Choices_Processing
 942           (Get_Alternatives          => Alternatives,
 943            Get_Choices               => Discrete_Choices,
 944            Process_Empty_Choice      => No_OP,
 945            Process_Non_Static_Choice => Non_Static_Choice_Error,
 946            Process_Associated_Node   => Process_Statements);
 947       use Case_Choices_Processing;
 948       --  Instantiation of the generic choice processing package
 949
 950       -----------------------------
 951       -- Non_Static_Choice_Error --
 952       -----------------------------
 953
 954       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 955       begin
 956          Flag_Non_Static_Expr
 957            ("choice given in case statement is not static!", Choice);
 958       end Non_Static_Choice_Error;
 959
 960       ------------------------
 961       -- Process_Statements --
 962       ------------------------
 963
 964       procedure Process_Statements (Alternative : Node_Id) is
 965          Choices : constant List_Id := Discrete_Choices (Alternative);
 966          Ent     : Entity_Id;
 967
 968       begin
 969          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 970          Statements_Analyzed := True;
 971
 972          --  An interesting optimization. If the case statement expression
 973          --  is a simple entity, then we can set the current value within
 974          --  an alternative if the alternative has one possible value.
 975
 976          --    case N is
 977          --      when 1      => alpha
 978          --      when 2 | 3  => beta
 979          --      when others => gamma
 980
 981          --  Here we know that N is initially 1 within alpha, but for beta
 982          --  and gamma, we do not know anything more about the initial value.
 983
 984          if Is_Entity_Name (Exp) then
 985             Ent := Entity (Exp);
 986
 987             if Ekind (Ent) = E_Variable
 988                  or else
 989                Ekind (Ent) = E_In_Out_Parameter
 990                  or else
 991                Ekind (Ent) = E_Out_Parameter
 992             then
 993                if List_Length (Choices) = 1
 994                  and then Nkind (First (Choices)) in N_Subexpr
 995                  and then Compile_Time_Known_Value (First (Choices))
 996                then
 997                   Set_Current_Value (Entity (Exp), First (Choices));
 998                end if;
 999
1000                Analyze_Statements (Statements (Alternative));
1001
1002                --  After analyzing the case, set the current value to empty
1003                --  since we won't know what it is for the next alternative
1004                --  (unless reset by this same circuit), or after the case.
1005
1006                Set_Current_Value (Entity (Exp), Empty);
1007                return;
1008             end if;
1009          end if;
1010
1011          --  Case where expression is not an entity name of a variable
1012
1013          Analyze_Statements (Statements (Alternative));
1014       end Process_Statements;
1015
1016       --  Table to record choices. Put after subprograms since we make
1017       --  a call to Number_Of_Choices to get the right number of entries.
1018
1019       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
1020       pragma Warnings (Off, Case_Table);
1021
1022    --  Start of processing for Analyze_Case_Statement
1023
1024    begin
1025       Unblocked_Exit_Count := 0;
1026       Exp := Expression (N);
1027       Analyze (Exp);
1028
1029       --  The expression must be of any discrete type. In rare cases, the
1030       --  expander constructs a case statement whose expression has a private
1031       --  type whose full view is discrete. This can happen when generating
1032       --  a stream operation for a variant type after the type is frozen,
1033       --  when the partial of view of the type of the discriminant is private.
1034       --  In that case, use the full view to analyze case alternatives.
1035
1036       if not Is_Overloaded (Exp)
1037         and then not Comes_From_Source (N)
1038         and then Is_Private_Type (Etype (Exp))
1039         and then Present (Full_View (Etype (Exp)))
1040         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1041       then
1042          Resolve (Exp, Etype (Exp));
1043          Exp_Type := Full_View (Etype (Exp));
1044
1045       else
1046          Analyze_And_Resolve (Exp, Any_Discrete);
1047          Exp_Type := Etype (Exp);
1048       end if;
1049
1050       Check_Unset_Reference (Exp);
1051       Exp_Btype := Base_Type (Exp_Type);
1052
1053       --  The expression must be of a discrete type which must be determinable
1054       --  independently of the context in which the expression occurs, but
1055       --  using the fact that the expression must be of a discrete type.
1056       --  Moreover, the type this expression must not be a character literal
1057       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1058
1059       --  If error already reported by Resolve, nothing more to do
1060
1061       if Exp_Btype = Any_Discrete
1062         or else Exp_Btype = Any_Type
1063       then
1064          return;
1065
1066       elsif Exp_Btype = Any_Character then
1067          Error_Msg_N
1068            ("character literal as case expression is ambiguous", Exp);
1069          return;
1070
1071       elsif Ada_Version = Ada_83
1072         and then (Is_Generic_Type (Exp_Btype)
1073                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1074       then
1075          Error_Msg_N
1076            ("(Ada 83) case expression cannot be of a generic type", Exp);
1077          return;
1078       end if;
1079
1080       --  If the case expression is a formal object of mode in out, then
1081       --  treat it as having a nonstatic subtype by forcing use of the base
1082       --  type (which has to get passed to Check_Case_Choices below).  Also
1083       --  use base type when the case expression is parenthesized.
1084
1085       if Paren_Count (Exp) > 0
1086         or else (Is_Entity_Name (Exp)
1087                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1088       then
1089          Exp_Type := Exp_Btype;
1090       end if;
1091
1092       --  Call instantiated Analyze_Choices which does the rest of the work
1093
1094       Analyze_Choices
1095         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
1096
1097       if Exp_Type = Universal_Integer and then not Others_Present then
1098          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1099       end if;
1100
1101       --  If all our exits were blocked by unconditional transfers of control,
1102       --  then the entire CASE statement acts as an unconditional transfer of
1103       --  control, so treat it like one, and check unreachable code. Skip this
1104       --  test if we had serious errors preventing any statement analysis.
1105
1106       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1107          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1108          Check_Unreachable_Code (N);
1109       else
1110          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1111       end if;
1112
1113       if not Expander_Active
1114         and then Compile_Time_Known_Value (Expression (N))
1115         and then Serious_Errors_Detected = 0
1116       then
1117          declare
1118             Chosen : constant Node_Id := Find_Static_Alternative (N);
1119             Alt    : Node_Id;
1120
1121          begin
1122             Alt := First (Alternatives (N));
1123             while Present (Alt) loop
1124                if Alt /= Chosen then
1125                   Remove_Warning_Messages (Statements (Alt));
1126                end if;
1127
1128                Next (Alt);
1129             end loop;
1130          end;
1131       end if;
1132    end Analyze_Case_Statement;
1133
1134    ----------------------------
1135    -- Analyze_Exit_Statement --
1136    ----------------------------
1137
1138    --  If the exit includes a name, it must be the name of a currently open
1139    --  loop. Otherwise there must be an innermost open loop on the stack,
1140    --  to which the statement implicitly refers.
1141
1142    procedure Analyze_Exit_Statement (N : Node_Id) is
1143       Target   : constant Node_Id := Name (N);
1144       Cond     : constant Node_Id := Condition (N);
1145       Scope_Id : Entity_Id;
1146       U_Name   : Entity_Id;
1147       Kind     : Entity_Kind;
1148
1149    begin
1150       if No (Cond) then
1151          Check_Unreachable_Code (N);
1152       end if;
1153
1154       if Present (Target) then
1155          Analyze (Target);
1156          U_Name := Entity (Target);
1157
1158          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1159             Error_Msg_N ("invalid loop name in exit statement", N);
1160             return;
1161          else
1162             Set_Has_Exit (U_Name);
1163          end if;
1164
1165       else
1166          U_Name := Empty;
1167       end if;
1168
1169       for J in reverse 0 .. Scope_Stack.Last loop
1170          Scope_Id := Scope_Stack.Table (J).Entity;
1171          Kind := Ekind (Scope_Id);
1172
1173          if Kind = E_Loop
1174            and then (No (Target) or else Scope_Id = U_Name) then
1175             Set_Has_Exit (Scope_Id);
1176             exit;
1177
1178          elsif Kind = E_Block
1179            or else Kind = E_Loop
1180            or else Kind = E_Return_Statement
1181          then
1182             null;
1183
1184          else
1185             Error_Msg_N
1186               ("cannot exit from program unit or accept statement", N);
1187             exit;
1188          end if;
1189       end loop;
1190
1191       --  Verify that if present the condition is a Boolean expression
1192
1193       if Present (Cond) then
1194          Analyze_And_Resolve (Cond, Any_Boolean);
1195          Check_Unset_Reference (Cond);
1196       end if;
1197    end Analyze_Exit_Statement;
1198
1199    ----------------------------
1200    -- Analyze_Goto_Statement --
1201    ----------------------------
1202
1203    procedure Analyze_Goto_Statement (N : Node_Id) is
1204       Label       : constant Node_Id := Name (N);
1205       Scope_Id    : Entity_Id;
1206       Label_Scope : Entity_Id;
1207       Label_Ent   : Entity_Id;
1208
1209    begin
1210       Check_Unreachable_Code (N);
1211       Kill_Current_Values (Last_Assignment_Only => True);
1212
1213       Analyze (Label);
1214       Label_Ent := Entity (Label);
1215
1216       --  Ignore previous error
1217
1218       if Label_Ent = Any_Id then
1219          return;
1220
1221       --  We just have a label as the target of a goto
1222
1223       elsif Ekind (Label_Ent) /= E_Label then
1224          Error_Msg_N ("target of goto statement must be a label", Label);
1225          return;
1226
1227       --  Check that the target of the goto is reachable according to Ada
1228       --  scoping rules. Note: the special gotos we generate for optimizing
1229       --  local handling of exceptions would violate these rules, but we mark
1230       --  such gotos as analyzed when built, so this code is never entered.
1231
1232       elsif not Reachable (Label_Ent) then
1233          Error_Msg_N ("target of goto statement is not reachable", Label);
1234          return;
1235       end if;
1236
1237       --  Here if goto passes initial validity checks
1238
1239       Label_Scope := Enclosing_Scope (Label_Ent);
1240
1241       for J in reverse 0 .. Scope_Stack.Last loop
1242          Scope_Id := Scope_Stack.Table (J).Entity;
1243
1244          if Label_Scope = Scope_Id
1245            or else (Ekind (Scope_Id) /= E_Block
1246                      and then Ekind (Scope_Id) /= E_Loop
1247                      and then Ekind (Scope_Id) /= E_Return_Statement)
1248          then
1249             if Scope_Id /= Label_Scope then
1250                Error_Msg_N
1251                  ("cannot exit from program unit or accept statement", N);
1252             end if;
1253
1254             return;
1255          end if;
1256       end loop;
1257
1258       raise Program_Error;
1259    end Analyze_Goto_Statement;
1260
1261    --------------------------
1262    -- Analyze_If_Statement --
1263    --------------------------
1264
1265    --  A special complication arises in the analysis of if statements
1266
1267    --  The expander has circuitry to completely delete code that it
1268    --  can tell will not be executed (as a result of compile time known
1269    --  conditions). In the analyzer, we ensure that code that will be
1270    --  deleted in this manner is analyzed but not expanded. This is
1271    --  obviously more efficient, but more significantly, difficulties
1272    --  arise if code is expanded and then eliminated (e.g. exception
1273    --  table entries disappear). Similarly, itypes generated in deleted
1274    --  code must be frozen from start, because the nodes on which they
1275    --  depend will not be available at the freeze point.
1276
1277    procedure Analyze_If_Statement (N : Node_Id) is
1278       E : Node_Id;
1279
1280       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1281       --  Recursively save value of this global, will be restored on exit
1282
1283       Save_In_Deleted_Code : Boolean;
1284
1285       Del : Boolean := False;
1286       --  This flag gets set True if a True condition has been found,
1287       --  which means that remaining ELSE/ELSIF parts are deleted.
1288
1289       procedure Analyze_Cond_Then (Cnode : Node_Id);
1290       --  This is applied to either the N_If_Statement node itself or
1291       --  to an N_Elsif_Part node. It deals with analyzing the condition
1292       --  and the THEN statements associated with it.
1293
1294       -----------------------
1295       -- Analyze_Cond_Then --
1296       -----------------------
1297
1298       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1299          Cond : constant Node_Id := Condition (Cnode);
1300          Tstm : constant List_Id := Then_Statements (Cnode);
1301
1302       begin
1303          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1304          Analyze_And_Resolve (Cond, Any_Boolean);
1305          Check_Unset_Reference (Cond);
1306          Set_Current_Value_Condition (Cnode);
1307
1308          --  If already deleting, then just analyze then statements
1309
1310          if Del then
1311             Analyze_Statements (Tstm);
1312
1313          --  Compile time known value, not deleting yet
1314
1315          elsif Compile_Time_Known_Value (Cond) then
1316             Save_In_Deleted_Code := In_Deleted_Code;
1317
1318             --  If condition is True, then analyze the THEN statements
1319             --  and set no expansion for ELSE and ELSIF parts.
1320
1321             if Is_True (Expr_Value (Cond)) then
1322                Analyze_Statements (Tstm);
1323                Del := True;
1324                Expander_Mode_Save_And_Set (False);
1325                In_Deleted_Code := True;
1326
1327             --  If condition is False, analyze THEN with expansion off
1328
1329             else -- Is_False (Expr_Value (Cond))
1330                Expander_Mode_Save_And_Set (False);
1331                In_Deleted_Code := True;
1332                Analyze_Statements (Tstm);
1333                Expander_Mode_Restore;
1334                In_Deleted_Code := Save_In_Deleted_Code;
1335             end if;
1336
1337          --  Not known at compile time, not deleting, normal analysis
1338
1339          else
1340             Analyze_Statements (Tstm);
1341          end if;
1342       end Analyze_Cond_Then;
1343
1344    --  Start of Analyze_If_Statement
1345
1346    begin
1347       --  Initialize exit count for else statements. If there is no else
1348       --  part, this count will stay non-zero reflecting the fact that the
1349       --  uncovered else case is an unblocked exit.
1350
1351       Unblocked_Exit_Count := 1;
1352       Analyze_Cond_Then (N);
1353
1354       --  Now to analyze the elsif parts if any are present
1355
1356       if Present (Elsif_Parts (N)) then
1357          E := First (Elsif_Parts (N));
1358          while Present (E) loop
1359             Analyze_Cond_Then (E);
1360             Next (E);
1361          end loop;
1362       end if;
1363
1364       if Present (Else_Statements (N)) then
1365          Analyze_Statements (Else_Statements (N));
1366       end if;
1367
1368       --  If all our exits were blocked by unconditional transfers of control,
1369       --  then the entire IF statement acts as an unconditional transfer of
1370       --  control, so treat it like one, and check unreachable code.
1371
1372       if Unblocked_Exit_Count = 0 then
1373          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1374          Check_Unreachable_Code (N);
1375       else
1376          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1377       end if;
1378
1379       if Del then
1380          Expander_Mode_Restore;
1381          In_Deleted_Code := Save_In_Deleted_Code;
1382       end if;
1383
1384       if not Expander_Active
1385         and then Compile_Time_Known_Value (Condition (N))
1386         and then Serious_Errors_Detected = 0
1387       then
1388          if Is_True (Expr_Value (Condition (N))) then
1389             Remove_Warning_Messages (Else_Statements (N));
1390
1391             if Present (Elsif_Parts (N)) then
1392                E := First (Elsif_Parts (N));
1393                while Present (E) loop
1394                   Remove_Warning_Messages (Then_Statements (E));
1395                   Next (E);
1396                end loop;
1397             end if;
1398
1399          else
1400             Remove_Warning_Messages (Then_Statements (N));
1401          end if;
1402       end if;
1403    end Analyze_If_Statement;
1404
1405    ----------------------------------------
1406    -- Analyze_Implicit_Label_Declaration --
1407    ----------------------------------------
1408
1409    --  An implicit label declaration is generated in the innermost
1410    --  enclosing declarative part. This is done for labels as well as
1411    --  block and loop names.
1412
1413    --  Note: any changes in this routine may need to be reflected in
1414    --  Analyze_Label_Entity.
1415
1416    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1417       Id : constant Node_Id := Defining_Identifier (N);
1418    begin
1419       Enter_Name          (Id);
1420       Set_Ekind           (Id, E_Label);
1421       Set_Etype           (Id, Standard_Void_Type);
1422       Set_Enclosing_Scope (Id, Current_Scope);
1423    end Analyze_Implicit_Label_Declaration;
1424
1425    ------------------------------
1426    -- Analyze_Iteration_Scheme --
1427    ------------------------------
1428
1429    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1430
1431       procedure Process_Bounds (R : Node_Id);
1432       --  If the iteration is given by a range, create temporaries and
1433       --  assignment statements block to capture the bounds and perform
1434       --  required finalization actions in case a bound includes a function
1435       --  call that uses the temporary stack. We first pre-analyze a copy of
1436       --  the range in order to determine the expected type, and analyze and
1437       --  resolve the original bounds.
1438
1439       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1440       --  If the bounds are given by a 'Range reference on a function call
1441       --  that returns a controlled array, introduce an explicit declaration
1442       --  to capture the bounds, so that the function result can be finalized
1443       --  in timely fashion.
1444
1445       --------------------
1446       -- Process_Bounds --
1447       --------------------
1448
1449       procedure Process_Bounds (R : Node_Id) is
1450          Loc          : constant Source_Ptr := Sloc (N);
1451          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1452          Lo           : constant Node_Id := Low_Bound  (R);
1453          Hi           : constant Node_Id := High_Bound (R);
1454          New_Lo_Bound : Node_Id := Empty;
1455          New_Hi_Bound : Node_Id := Empty;
1456          Typ          : Entity_Id;
1457          Save_Analysis : Boolean;
1458
1459          function One_Bound
1460            (Original_Bound : Node_Id;
1461             Analyzed_Bound : Node_Id) return Node_Id;
1462          --  Create one declaration followed by one assignment statement
1463          --  to capture the value of bound. We create a separate assignment
1464          --  in order to force the creation of a block in case the bound
1465          --  contains a call that uses the secondary stack.
1466
1467          ---------------
1468          -- One_Bound --
1469          ---------------
1470
1471          function One_Bound
1472            (Original_Bound : Node_Id;
1473             Analyzed_Bound : Node_Id) return Node_Id
1474          is
1475             Assign : Node_Id;
1476             Id     : Entity_Id;
1477             Decl   : Node_Id;
1478
1479          begin
1480             --  If the bound is a constant or an object, no need for a separate
1481             --  declaration. If the bound is the result of previous expansion
1482             --  it is already analyzed and should not be modified. Note that
1483             --  the Bound will be resolved later, if needed, as part of the
1484             --  call to Make_Index (literal bounds may need to be resolved to
1485             --  type Integer).
1486
1487             if Analyzed (Original_Bound) then
1488                return Original_Bound;
1489
1490             elsif Nkind_In (Analyzed_Bound, N_Integer_Literal,
1491                                             N_Character_Literal)
1492               or else Is_Entity_Name (Analyzed_Bound)
1493             then
1494                Analyze_And_Resolve (Original_Bound, Typ);
1495                return Original_Bound;
1496
1497             else
1498                Analyze_And_Resolve (Original_Bound, Typ);
1499             end if;
1500
1501             Id :=
1502               Make_Defining_Identifier (Loc,
1503                 Chars => New_Internal_Name ('S'));
1504
1505             Decl :=
1506               Make_Object_Declaration (Loc,
1507                 Defining_Identifier => Id,
1508                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1509
1510             Insert_Before (Parent (N), Decl);
1511             Analyze (Decl);
1512
1513             Assign :=
1514               Make_Assignment_Statement (Loc,
1515                 Name        => New_Occurrence_Of (Id, Loc),
1516                 Expression  => Relocate_Node (Original_Bound));
1517
1518             Insert_Before (Parent (N), Assign);
1519             Analyze (Assign);
1520
1521             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1522
1523             if Nkind (Assign) = N_Assignment_Statement then
1524                return Expression (Assign);
1525             else
1526                return Original_Bound;
1527             end if;
1528          end One_Bound;
1529
1530       --  Start of processing for Process_Bounds
1531
1532       begin
1533          --  Determine expected type of range by analyzing separate copy
1534          --  Do the analysis and resolution of the copy of the bounds with
1535          --  expansion disabled, to prevent the generation of finalization
1536          --  actions on each bound. This prevents memory leaks when the
1537          --  bounds contain calls to functions returning controlled arrays.
1538
1539          Set_Parent (R_Copy, Parent (R));
1540          Save_Analysis := Full_Analysis;
1541          Full_Analysis := False;
1542          Expander_Mode_Save_And_Set (False);
1543
1544          Analyze (R_Copy);
1545
1546          if Is_Overloaded (R_Copy) then
1547
1548             --  Apply preference rules for range of predefined integer types,
1549             --  or diagnose true ambiguity.
1550
1551             declare
1552                I     : Interp_Index;
1553                It    : Interp;
1554                Found : Entity_Id := Empty;
1555
1556             begin
1557                Get_First_Interp (R_Copy, I, It);
1558                while Present (It.Typ) loop
1559                   if Is_Discrete_Type (It.Typ) then
1560                      if No (Found) then
1561                         Found := It.Typ;
1562                      else
1563                         if Scope (Found) = Standard_Standard then
1564                            null;
1565
1566                         elsif Scope (It.Typ) = Standard_Standard then
1567                            Found := It.Typ;
1568
1569                         else
1570                            --  Both of them are user-defined
1571
1572                            Error_Msg_N
1573                              ("ambiguous bounds in range of iteration",
1574                                R_Copy);
1575                            Error_Msg_N ("\possible interpretations:", R_Copy);
1576                            Error_Msg_NE ("\\} ", R_Copy, Found);
1577                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1578                            exit;
1579                         end if;
1580                      end if;
1581                   end if;
1582
1583                   Get_Next_Interp (I, It);
1584                end loop;
1585             end;
1586          end if;
1587
1588          Resolve (R_Copy);
1589          Expander_Mode_Restore;
1590          Full_Analysis := Save_Analysis;
1591
1592          Typ := Etype (R_Copy);
1593
1594          --  If the type of the discrete range is Universal_Integer, then
1595          --  the bound's type must be resolved to Integer, and any object
1596          --  used to hold the bound must also have type Integer, unless the
1597          --  literal bounds are constant-folded expressions that carry a user-
1598          --  defined type.
1599
1600          if Typ = Universal_Integer then
1601             if Nkind (Lo) = N_Integer_Literal
1602               and then Present (Etype (Lo))
1603               and then Scope (Etype (Lo)) /= Standard_Standard
1604             then
1605                Typ := Etype (Lo);
1606
1607             elsif Nkind (Hi) = N_Integer_Literal
1608               and then Present (Etype (Hi))
1609               and then Scope (Etype (Hi)) /= Standard_Standard
1610             then
1611                Typ := Etype (Hi);
1612
1613             else
1614                Typ := Standard_Integer;
1615             end if;
1616          end if;
1617
1618          Set_Etype (R, Typ);
1619
1620          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1621          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1622
1623          --  Propagate staticness to loop range itself, in case the
1624          --  corresponding subtype is static.
1625
1626          if New_Lo_Bound /= Lo
1627            and then Is_Static_Expression (New_Lo_Bound)
1628          then
1629             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1630          end if;
1631
1632          if New_Hi_Bound /= Hi
1633            and then Is_Static_Expression (New_Hi_Bound)
1634          then
1635             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1636          end if;
1637       end Process_Bounds;
1638
1639       --------------------------------------
1640       -- Check_Controlled_Array_Attribute --
1641       --------------------------------------
1642
1643       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1644       begin
1645          if Nkind (DS) = N_Attribute_Reference
1646             and then Is_Entity_Name (Prefix (DS))
1647             and then Ekind (Entity (Prefix (DS))) = E_Function
1648             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1649             and then
1650               Is_Controlled (
1651                 Component_Type (Etype (Entity (Prefix (DS)))))
1652             and then Expander_Active
1653          then
1654             declare
1655                Loc  : constant Source_Ptr := Sloc (N);
1656                Arr  : constant Entity_Id :=
1657                         Etype (Entity (Prefix (DS)));
1658                Indx : constant Entity_Id :=
1659                         Base_Type (Etype (First_Index (Arr)));
1660                Subt : constant Entity_Id :=
1661                         Make_Defining_Identifier
1662                           (Loc, New_Internal_Name ('S'));
1663                Decl : Node_Id;
1664
1665             begin
1666                Decl :=
1667                  Make_Subtype_Declaration (Loc,
1668                    Defining_Identifier => Subt,
1669                    Subtype_Indication  =>
1670                       Make_Subtype_Indication (Loc,
1671                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1672                         Constraint =>
1673                           Make_Range_Constraint (Loc,
1674                             Relocate_Node (DS))));
1675                Insert_Before (Parent (N), Decl);
1676                Analyze (Decl);
1677
1678                Rewrite (DS,
1679                   Make_Attribute_Reference (Loc,
1680                     Prefix => New_Reference_To (Subt, Loc),
1681                     Attribute_Name => Attribute_Name (DS)));
1682                Analyze (DS);
1683             end;
1684          end if;
1685       end Check_Controlled_Array_Attribute;
1686
1687    --  Start of processing for Analyze_Iteration_Scheme
1688
1689    begin
1690       --  For an infinite loop, there is no iteration scheme
1691
1692       if No (N) then
1693          return;
1694
1695       else
1696          declare
1697             Cond : constant Node_Id := Condition (N);
1698
1699          begin
1700             --  For WHILE loop, verify that the condition is a Boolean
1701             --  expression and resolve and check it.
1702
1703             if Present (Cond) then
1704                Analyze_And_Resolve (Cond, Any_Boolean);
1705                Check_Unset_Reference (Cond);
1706                Set_Current_Value_Condition (N);
1707                return;
1708
1709             --  Else we have a FOR loop
1710
1711             else
1712                declare
1713                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1714                   Id : constant Entity_Id := Defining_Identifier (LP);
1715                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1716
1717                begin
1718                   Enter_Name (Id);
1719
1720                   --  We always consider the loop variable to be referenced,
1721                   --  since the loop may be used just for counting purposes.
1722
1723                   Generate_Reference (Id, N, ' ');
1724
1725                   --  Check for case of loop variable hiding a local
1726                   --  variable (used later on to give a nice warning
1727                   --  if the hidden variable is never assigned).
1728
1729                   declare
1730                      H : constant Entity_Id := Homonym (Id);
1731                   begin
1732                      if Present (H)
1733                        and then Enclosing_Dynamic_Scope (H) =
1734                                 Enclosing_Dynamic_Scope (Id)
1735                        and then Ekind (H) = E_Variable
1736                        and then Is_Discrete_Type (Etype (H))
1737                      then
1738                         Set_Hiding_Loop_Variable (H, Id);
1739                      end if;
1740                   end;
1741
1742                   --  Now analyze the subtype definition. If it is
1743                   --  a range, create temporaries for bounds.
1744
1745                   if Nkind (DS) = N_Range
1746                     and then Expander_Active
1747                   then
1748                      Process_Bounds (DS);
1749                   else
1750                      Analyze (DS);
1751                   end if;
1752
1753                   if DS = Error then
1754                      return;
1755                   end if;
1756
1757                   --  The subtype indication may denote the completion
1758                   --  of an incomplete type declaration.
1759
1760                   if Is_Entity_Name (DS)
1761                     and then Present (Entity (DS))
1762                     and then Is_Type (Entity (DS))
1763                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1764                   then
1765                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1766                      Set_Etype  (DS, Entity (DS));
1767                   end if;
1768
1769                   if not Is_Discrete_Type (Etype (DS)) then
1770                      Wrong_Type (DS, Any_Discrete);
1771                      Set_Etype (DS, Any_Type);
1772                   end if;
1773
1774                   Check_Controlled_Array_Attribute (DS);
1775
1776                   Make_Index (DS, LP);
1777
1778                   Set_Ekind          (Id, E_Loop_Parameter);
1779                   Set_Etype          (Id, Etype (DS));
1780                   Set_Is_Known_Valid (Id, True);
1781
1782                   --  The loop is not a declarative part, so the only entity
1783                   --  declared "within" must be frozen explicitly.
1784
1785                   declare
1786                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1787                   begin
1788                      if Is_Non_Empty_List (Flist) then
1789                         Insert_Actions (N, Flist);
1790                      end if;
1791                   end;
1792
1793                   --  Check for null or possibly null range and issue warning.
1794                   --  We suppress such messages in generic templates and
1795                   --  instances, because in practice they tend to be dubious
1796                   --  in these cases.
1797
1798                   if Nkind (DS) = N_Range
1799                     and then Comes_From_Source (N)
1800                   then
1801                      declare
1802                         L : constant Node_Id := Low_Bound  (DS);
1803                         H : constant Node_Id := High_Bound (DS);
1804
1805                         Llo : Uint;
1806                         Lhi : Uint;
1807                         LOK : Boolean;
1808                         Hlo : Uint;
1809                         Hhi : Uint;
1810                         HOK : Boolean;
1811
1812                         pragma Warnings (Off, Hlo);
1813
1814                      begin
1815                         Determine_Range (L, LOK, Llo, Lhi);
1816                         Determine_Range (H, HOK, Hlo, Hhi);
1817
1818                         --  If range of loop is null, issue warning
1819
1820                         if (LOK and HOK) and then Llo > Hhi then
1821
1822                            --  Suppress the warning if inside a generic
1823                            --  template or instance, since in practice
1824                            --  they tend to be dubious in these cases since
1825                            --  they can result from intended parametrization.
1826
1827                            if not Inside_A_Generic
1828                               and then not In_Instance
1829                            then
1830                               Error_Msg_N
1831                                 ("?loop range is null, loop will not execute",
1832                                  DS);
1833                            end if;
1834
1835                            --  Since we know the range of the loop is null,
1836                            --  set the appropriate flag to suppress any
1837                            --  warnings that would otherwise be issued in
1838                            --  the body of the loop that will not execute.
1839                            --  We do this even in the generic case, since
1840                            --  if it is dubious to warn on the null loop
1841                            --  itself, it is certainly dubious to warn for
1842                            --  conditions that occur inside it!
1843
1844                            Set_Is_Null_Loop (Parent (N));
1845
1846                         --  The other case for a warning is a reverse loop
1847                         --  where the upper bound is the integer literal
1848                         --  zero or one, and the lower bound can be positive.
1849
1850                         --  For example, we have
1851
1852                         --     for J in reverse N .. 1 loop
1853
1854                         --  In practice, this is very likely to be a case
1855                         --  of reversing the bounds incorrectly in the range.
1856
1857                         elsif Reverse_Present (LP)
1858                           and then Nkind (Original_Node (H)) =
1859                                                           N_Integer_Literal
1860                           and then (Intval (H) = Uint_0
1861                                       or else
1862                                     Intval (H) = Uint_1)
1863                           and then Lhi > Hhi
1864                         then
1865                            Error_Msg_N ("?loop range may be null", DS);
1866                            Error_Msg_N ("\?bounds may be wrong way round", DS);
1867                         end if;
1868                      end;
1869                   end if;
1870                end;
1871             end if;
1872          end;
1873       end if;
1874    end Analyze_Iteration_Scheme;
1875
1876    -------------------
1877    -- Analyze_Label --
1878    -------------------
1879
1880    --  Note: the semantic work required for analyzing labels (setting them as
1881    --  reachable) was done in a prepass through the statements in the block,
1882    --  so that forward gotos would be properly handled. See Analyze_Statements
1883    --  for further details. The only processing required here is to deal with
1884    --  optimizations that depend on an assumption of sequential control flow,
1885    --  since of course the occurrence of a label breaks this assumption.
1886
1887    procedure Analyze_Label (N : Node_Id) is
1888       pragma Warnings (Off, N);
1889    begin
1890       Kill_Current_Values;
1891    end Analyze_Label;
1892
1893    --------------------------
1894    -- Analyze_Label_Entity --
1895    --------------------------
1896
1897    procedure Analyze_Label_Entity (E : Entity_Id) is
1898    begin
1899       Set_Ekind           (E, E_Label);
1900       Set_Etype           (E, Standard_Void_Type);
1901       Set_Enclosing_Scope (E, Current_Scope);
1902       Set_Reachable       (E, True);
1903    end Analyze_Label_Entity;
1904
1905    ----------------------------
1906    -- Analyze_Loop_Statement --
1907    ----------------------------
1908
1909    procedure Analyze_Loop_Statement (N : Node_Id) is
1910       Loop_Statement : constant Node_Id := N;
1911
1912       Id   : constant Node_Id := Identifier (Loop_Statement);
1913       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
1914       Ent  : Entity_Id;
1915
1916    begin
1917       if Present (Id) then
1918
1919          --  Make name visible, e.g. for use in exit statements. Loop
1920          --  labels are always considered to be referenced.
1921
1922          Analyze (Id);
1923          Ent := Entity (Id);
1924
1925          --  Guard against serious error (typically, a scope mismatch when
1926          --  semantic analysis is requested) by creating loop entity to
1927          --  continue analysis.
1928
1929          if No (Ent) then
1930             if Total_Errors_Detected /= 0 then
1931                Ent :=
1932                  New_Internal_Entity
1933                    (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
1934             else
1935                raise Program_Error;
1936             end if;
1937
1938          else
1939             Generate_Reference  (Ent, Loop_Statement, ' ');
1940             Generate_Definition (Ent);
1941
1942             --  If we found a label, mark its type. If not, ignore it, since it
1943             --  means we have a conflicting declaration, which would already
1944             --  have been diagnosed at declaration time. Set Label_Construct
1945             --  of the implicit label declaration, which is not created by the
1946             --  parser for generic units.
1947
1948             if Ekind (Ent) = E_Label then
1949                Set_Ekind (Ent, E_Loop);
1950
1951                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
1952                   Set_Label_Construct (Parent (Ent), Loop_Statement);
1953                end if;
1954             end if;
1955          end if;
1956
1957       --  Case of no identifier present
1958
1959       else
1960          Ent :=
1961            New_Internal_Entity
1962              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
1963          Set_Etype (Ent,  Standard_Void_Type);
1964          Set_Parent (Ent, Loop_Statement);
1965       end if;
1966
1967       --  Kill current values on entry to loop, since statements in body of
1968       --  loop may have been executed before the loop is entered. Similarly we
1969       --  kill values after the loop, since we do not know that the body of the
1970       --  loop was executed.
1971
1972       Kill_Current_Values;
1973       Push_Scope (Ent);
1974       Analyze_Iteration_Scheme (Iter);
1975       Analyze_Statements (Statements (Loop_Statement));
1976       Process_End_Label (Loop_Statement, 'e', Ent);
1977       End_Scope;
1978       Kill_Current_Values;
1979       Check_Infinite_Loop_Warning (N);
1980
1981       --  Code after loop is unreachable if the loop has no WHILE or FOR
1982       --  and contains no EXIT statements within the body of the loop.
1983
1984       if No (Iter) and then not Has_Exit (Ent) then
1985          Check_Unreachable_Code (N);
1986       end if;
1987    end Analyze_Loop_Statement;
1988
1989    ----------------------------
1990    -- Analyze_Null_Statement --
1991    ----------------------------
1992
1993    --  Note: the semantics of the null statement is implemented by a single
1994    --  null statement, too bad everything isn't as simple as this!
1995
1996    procedure Analyze_Null_Statement (N : Node_Id) is
1997       pragma Warnings (Off, N);
1998    begin
1999       null;
2000    end Analyze_Null_Statement;
2001
2002    ------------------------
2003    -- Analyze_Statements --
2004    ------------------------
2005
2006    procedure Analyze_Statements (L : List_Id) is
2007       S   : Node_Id;
2008       Lab : Entity_Id;
2009
2010    begin
2011       --  The labels declared in the statement list are reachable from
2012       --  statements in the list. We do this as a prepass so that any
2013       --  goto statement will be properly flagged if its target is not
2014       --  reachable. This is not required, but is nice behavior!
2015
2016       S := First (L);
2017       while Present (S) loop
2018          if Nkind (S) = N_Label then
2019             Analyze (Identifier (S));
2020             Lab := Entity (Identifier (S));
2021
2022             --  If we found a label mark it as reachable
2023
2024             if Ekind (Lab) = E_Label then
2025                Generate_Definition (Lab);
2026                Set_Reachable (Lab);
2027
2028                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
2029                   Set_Label_Construct (Parent (Lab), S);
2030                end if;
2031
2032             --  If we failed to find a label, it means the implicit declaration
2033             --  of the label was hidden.  A for-loop parameter can do this to
2034             --  a label with the same name inside the loop, since the implicit
2035             --  label declaration is in the innermost enclosing body or block
2036             --  statement.
2037
2038             else
2039                Error_Msg_Sloc := Sloc (Lab);
2040                Error_Msg_N
2041                  ("implicit label declaration for & is hidden#",
2042                   Identifier (S));
2043             end if;
2044          end if;
2045
2046          Next (S);
2047       end loop;
2048
2049       --  Perform semantic analysis on all statements
2050
2051       Conditional_Statements_Begin;
2052
2053       S := First (L);
2054       while Present (S) loop
2055          Analyze (S);
2056          Next (S);
2057       end loop;
2058
2059       Conditional_Statements_End;
2060
2061       --  Make labels unreachable. Visibility is not sufficient, because
2062       --  labels in one if-branch for example are not reachable from the
2063       --  other branch, even though their declarations are in the enclosing
2064       --  declarative part.
2065
2066       S := First (L);
2067       while Present (S) loop
2068          if Nkind (S) = N_Label then
2069             Set_Reachable (Entity (Identifier (S)), False);
2070          end if;
2071
2072          Next (S);
2073       end loop;
2074    end Analyze_Statements;
2075
2076    ----------------------------
2077    -- Check_Unreachable_Code --
2078    ----------------------------
2079
2080    procedure Check_Unreachable_Code (N : Node_Id) is
2081       Error_Loc : Source_Ptr;
2082       P         : Node_Id;
2083
2084    begin
2085       if Is_List_Member (N)
2086         and then Comes_From_Source (N)
2087       then
2088          declare
2089             Nxt : Node_Id;
2090
2091          begin
2092             Nxt := Original_Node (Next (N));
2093
2094             --  If a label follows us, then we never have dead code, since
2095             --  someone could branch to the label, so we just ignore it.
2096
2097             if Nkind (Nxt) = N_Label then
2098                return;
2099
2100             --  Otherwise see if we have a real statement following us
2101
2102             elsif Present (Nxt)
2103               and then Comes_From_Source (Nxt)
2104               and then Is_Statement (Nxt)
2105             then
2106                --  Special very annoying exception. If we have a return that
2107                --  follows a raise, then we allow it without a warning, since
2108                --  the Ada RM annoyingly requires a useless return here!
2109
2110                if Nkind (Original_Node (N)) /= N_Raise_Statement
2111                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2112                then
2113                   --  The rather strange shenanigans with the warning message
2114                   --  here reflects the fact that Kill_Dead_Code is very good
2115                   --  at removing warnings in deleted code, and this is one
2116                   --  warning we would prefer NOT to have removed.
2117
2118                   Error_Loc := Sloc (Nxt);
2119
2120                   --  If we have unreachable code, analyze and remove the
2121                   --  unreachable code, since it is useless and we don't
2122                   --  want to generate junk warnings.
2123
2124                   --  We skip this step if we are not in code generation mode.
2125                   --  This is the one case where we remove dead code in the
2126                   --  semantics as opposed to the expander, and we do not want
2127                   --  to remove code if we are not in code generation mode,
2128                   --  since this messes up the ASIS trees.
2129
2130                   --  Note that one might react by moving the whole circuit to
2131                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2132
2133                   if Operating_Mode = Generate_Code then
2134                      loop
2135                         Nxt := Next (N);
2136
2137                         --  Quit deleting when we have nothing more to delete
2138                         --  or if we hit a label (since someone could transfer
2139                         --  control to a label, so we should not delete it).
2140
2141                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2142
2143                         --  Statement/declaration is to be deleted
2144
2145                         Analyze (Nxt);
2146                         Remove (Nxt);
2147                         Kill_Dead_Code (Nxt);
2148                      end loop;
2149                   end if;
2150
2151                   --  Now issue the warning
2152
2153                   Error_Msg ("?unreachable code!", Error_Loc);
2154                end if;
2155
2156             --  If the unconditional transfer of control instruction is
2157             --  the last statement of a sequence, then see if our parent
2158             --  is one of the constructs for which we count unblocked exits,
2159             --  and if so, adjust the count.
2160
2161             else
2162                P := Parent (N);
2163
2164                --  Statements in THEN part or ELSE part of IF statement
2165
2166                if Nkind (P) = N_If_Statement then
2167                   null;
2168
2169                --  Statements in ELSIF part of an IF statement
2170
2171                elsif Nkind (P) = N_Elsif_Part then
2172                   P := Parent (P);
2173                   pragma Assert (Nkind (P) = N_If_Statement);
2174
2175                --  Statements in CASE statement alternative
2176
2177                elsif Nkind (P) = N_Case_Statement_Alternative then
2178                   P := Parent (P);
2179                   pragma Assert (Nkind (P) = N_Case_Statement);
2180
2181                --  Statements in body of block
2182
2183                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2184                  and then Nkind (Parent (P)) = N_Block_Statement
2185                then
2186                   null;
2187
2188                --  Statements in exception handler in a block
2189
2190                elsif Nkind (P) = N_Exception_Handler
2191                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2192                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2193                then
2194                   null;
2195
2196                --  None of these cases, so return
2197
2198                else
2199                   return;
2200                end if;
2201
2202                --  This was one of the cases we are looking for (i.e. the
2203                --  parent construct was IF, CASE or block) so decrement count.
2204
2205                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2206             end if;
2207          end;
2208       end if;
2209    end Check_Unreachable_Code;
2210
2211 end Sem_Ch5;