gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Case; use Sem_Case;
  42 with Sem_Ch3;  use Sem_Ch3;
  43 with Sem_Ch8;  use Sem_Ch8;
  44 with Sem_Disp; use Sem_Disp;
  45 with Sem_Elab; use Sem_Elab;
  46 with Sem_Eval; use Sem_Eval;
  47 with Sem_Res;  use Sem_Res;
  48 with Sem_Type; use Sem_Type;
  49 with Sem_Util; use Sem_Util;
  50 with Sem_Warn; use Sem_Warn;
  51 with Snames;   use Snames;
  52 with Stand;    use Stand;
  53 with Sinfo;    use Sinfo;
  54 with Targparm; use Targparm;
  55 with Tbuild;   use Tbuild;
  56 with Uintp;    use Uintp;
  57
  58 package body Sem_Ch5 is
  59
  60    Unblocked_Exit_Count : Nat := 0;
  61    --  This variable is used when processing if statements, case statements,
  62    --  and block statements. It counts the number of exit points that are not
  63    --  blocked by unconditional transfer instructions: for IF and CASE, these
  64    --  are the branches of the conditional; for a block, they are the statement
  65    --  sequence of the block, and the statement sequences of any exception
  66    --  handlers that are part of the block. When processing is complete, if
  67    --  this count is zero, it means that control cannot fall through the IF,
  68    --  CASE or block statement. This is used for the generation of warning
  69    --  messages. This variable is recursively saved on entry to processing the
  70    --  construct, and restored on exit.
  71
  72    -----------------------
  73    -- Local Subprograms --
  74    -----------------------
  75
  76    procedure Analyze_Iteration_Scheme (N : Node_Id);
  77
  78    ------------------------
  79    -- Analyze_Assignment --
  80    ------------------------
  81
  82    procedure Analyze_Assignment (N : Node_Id) is
  83       Lhs  : constant Node_Id := Name (N);
  84       Rhs  : constant Node_Id := Expression (N);
  85       T1   : Entity_Id;
  86       T2   : Entity_Id;
  87       Decl : Node_Id;
  88
  89       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  90       --  N is the node for the left hand side of an assignment, and it
  91       --  is not a variable. This routine issues an appropriate diagnostic.
  92
  93       procedure Kill_Lhs;
  94       --  This is called to kill current value settings of a simple variable
  95       --  on the left hand side. We call it if we find any error in analyzing
  96       --  the assignment, and at the end of processing before setting any new
  97       --  current values in place.
  98
  99       procedure Set_Assignment_Type
 100         (Opnd      : Node_Id;
 101          Opnd_Type : in out Entity_Id);
 102       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 103       --  is the nominal subtype. This procedure is used to deal with cases
 104       --  where the nominal subtype must be replaced by the actual subtype.
 105
 106       -------------------------------
 107       -- Diagnose_Non_Variable_Lhs --
 108       -------------------------------
 109
 110       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 111       begin
 112          --  Not worth posting another error if left hand side already
 113          --  flagged as being illegal in some respect.
 114
 115          if Error_Posted (N) then
 116             return;
 117
 118          --  Some special bad cases of entity names
 119
 120          elsif Is_Entity_Name (N) then
 121             declare
 122                Ent : constant Entity_Id := Entity (N);
 123
 124             begin
 125                if Ekind (Ent) = E_In_Parameter then
 126                   Error_Msg_N
 127                     ("assignment to IN mode parameter not allowed", N);
 128
 129                --  Renamings of protected private components are turned into
 130                --  constants when compiling a protected function. In the case
 131                --  of single protected types, the private component appears
 132                --  directly.
 133
 134                elsif (Is_Prival (Ent)
 135                         and then
 136                           (Ekind (Current_Scope) = E_Function
 137                              or else Ekind (Enclosing_Dynamic_Scope (
 138                                        Current_Scope)) = E_Function))
 139                    or else
 140                      (Ekind (Ent) = E_Component
 141                         and then Is_Protected_Type (Scope (Ent)))
 142                then
 143                   Error_Msg_N
 144                     ("protected function cannot modify protected object", N);
 145
 146                elsif Ekind (Ent) = E_Loop_Parameter then
 147                   Error_Msg_N
 148                     ("assignment to loop parameter not allowed", N);
 149
 150                else
 151                   Error_Msg_N
 152                     ("left hand side of assignment must be a variable", N);
 153                end if;
 154             end;
 155
 156          --  For indexed components or selected components, test prefix
 157
 158          elsif Nkind (N) = N_Indexed_Component then
 159             Diagnose_Non_Variable_Lhs (Prefix (N));
 160
 161          --  Another special case for assignment to discriminant
 162
 163          elsif Nkind (N) = N_Selected_Component then
 164             if Present (Entity (Selector_Name (N)))
 165               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 166             then
 167                Error_Msg_N
 168                  ("assignment to discriminant not allowed", N);
 169             else
 170                Diagnose_Non_Variable_Lhs (Prefix (N));
 171             end if;
 172
 173          else
 174             --  If we fall through, we have no special message to issue!
 175
 176             Error_Msg_N ("left hand side of assignment must be a variable", N);
 177          end if;
 178       end Diagnose_Non_Variable_Lhs;
 179
 180       --------------
 181       -- Kill_LHS --
 182       --------------
 183
 184       procedure Kill_Lhs is
 185       begin
 186          if Is_Entity_Name (Lhs) then
 187             declare
 188                Ent : constant Entity_Id := Entity (Lhs);
 189             begin
 190                if Present (Ent) then
 191                   Kill_Current_Values (Ent);
 192                end if;
 193             end;
 194          end if;
 195       end Kill_Lhs;
 196
 197       -------------------------
 198       -- Set_Assignment_Type --
 199       -------------------------
 200
 201       procedure Set_Assignment_Type
 202         (Opnd      : Node_Id;
 203          Opnd_Type : in out Entity_Id)
 204       is
 205       begin
 206          Require_Entity (Opnd);
 207
 208          --  If the assignment operand is an in-out or out parameter, then we
 209          --  get the actual subtype (needed for the unconstrained case).
 210          --  If the operand is the actual in an entry declaration, then within
 211          --  the accept statement it is replaced with a local renaming, which
 212          --  may also have an actual subtype.
 213
 214          if Is_Entity_Name (Opnd)
 215            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 216                       or else Ekind (Entity (Opnd)) =
 217                            E_In_Out_Parameter
 218                       or else Ekind (Entity (Opnd)) =
 219                            E_Generic_In_Out_Parameter
 220                       or else
 221                         (Ekind (Entity (Opnd)) = E_Variable
 222                           and then Nkind (Parent (Entity (Opnd))) =
 223                              N_Object_Renaming_Declaration
 224                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 225                              N_Accept_Statement))
 226          then
 227             Opnd_Type := Get_Actual_Subtype (Opnd);
 228
 229          --  If assignment operand is a component reference, then we get the
 230          --  actual subtype of the component for the unconstrained case.
 231
 232          elsif Nkind_In (Opnd, N_Selected_Component, N_Explicit_Dereference)
 233            and then not Is_Unchecked_Union (Opnd_Type)
 234          then
 235             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 236
 237             if Present (Decl) then
 238                Insert_Action (N, Decl);
 239                Mark_Rewrite_Insertion (Decl);
 240                Analyze (Decl);
 241                Opnd_Type := Defining_Identifier (Decl);
 242                Set_Etype (Opnd, Opnd_Type);
 243                Freeze_Itype (Opnd_Type, N);
 244
 245             elsif Is_Constrained (Etype (Opnd)) then
 246                Opnd_Type := Etype (Opnd);
 247             end if;
 248
 249          --  For slice, use the constrained subtype created for the slice
 250
 251          elsif Nkind (Opnd) = N_Slice then
 252             Opnd_Type := Etype (Opnd);
 253          end if;
 254       end Set_Assignment_Type;
 255
 256    --  Start of processing for Analyze_Assignment
 257
 258    begin
 259       Mark_Coextensions (N, Rhs);
 260
 261       Analyze (Rhs);
 262       Analyze (Lhs);
 263
 264       --  Start type analysis for assignment
 265
 266       T1 := Etype (Lhs);
 267
 268       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 269       --  must compute the intersection of the possible types on each side.
 270
 271       if Is_Overloaded (Lhs) then
 272          declare
 273             I  : Interp_Index;
 274             It : Interp;
 275
 276          begin
 277             T1 := Any_Type;
 278             Get_First_Interp (Lhs, I, It);
 279
 280             while Present (It.Typ) loop
 281                if Has_Compatible_Type (Rhs, It.Typ) then
 282                   if T1 /= Any_Type then
 283
 284                      --  An explicit dereference is overloaded if the prefix
 285                      --  is. Try to remove the ambiguity on the prefix, the
 286                      --  error will be posted there if the ambiguity is real.
 287
 288                      if Nkind (Lhs) = N_Explicit_Dereference then
 289                         declare
 290                            PI    : Interp_Index;
 291                            PI1   : Interp_Index := 0;
 292                            PIt   : Interp;
 293                            Found : Boolean;
 294
 295                         begin
 296                            Found := False;
 297                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 298
 299                            while Present (PIt.Typ) loop
 300                               if Is_Access_Type (PIt.Typ)
 301                                 and then Has_Compatible_Type
 302                                            (Rhs, Designated_Type (PIt.Typ))
 303                               then
 304                                  if Found then
 305                                     PIt :=
 306                                       Disambiguate (Prefix (Lhs),
 307                                         PI1, PI, Any_Type);
 308
 309                                     if PIt = No_Interp then
 310                                        Error_Msg_N
 311                                          ("ambiguous left-hand side"
 312                                             & " in assignment", Lhs);
 313                                        exit;
 314                                     else
 315                                        Resolve (Prefix (Lhs), PIt.Typ);
 316                                     end if;
 317
 318                                     exit;
 319                                  else
 320                                     Found := True;
 321                                     PI1 := PI;
 322                                  end if;
 323                               end if;
 324
 325                               Get_Next_Interp (PI, PIt);
 326                            end loop;
 327                         end;
 328
 329                      else
 330                         Error_Msg_N
 331                           ("ambiguous left-hand side in assignment", Lhs);
 332                         exit;
 333                      end if;
 334                   else
 335                      T1 := It.Typ;
 336                   end if;
 337                end if;
 338
 339                Get_Next_Interp (I, It);
 340             end loop;
 341          end;
 342
 343          if T1 = Any_Type then
 344             Error_Msg_N
 345               ("no valid types for left-hand side for assignment", Lhs);
 346             Kill_Lhs;
 347             return;
 348          end if;
 349       end if;
 350
 351       --  The resulting assignment type is T1, so now we will resolve the
 352       --  left hand side of the assignment using this determined type.
 353
 354       Resolve (Lhs, T1);
 355
 356       --  Cases where Lhs is not a variable
 357
 358       if not Is_Variable (Lhs) then
 359
 360          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 361          --  a protected object.
 362
 363          declare
 364             Ent : Entity_Id;
 365             S   : Entity_Id;
 366
 367          begin
 368             if Ada_Version >= Ada_05 then
 369
 370                --  Handle chains of renamings
 371
 372                Ent := Lhs;
 373                while Nkind (Ent) in N_Has_Entity
 374                  and then Present (Entity (Ent))
 375                  and then Present (Renamed_Object (Entity (Ent)))
 376                loop
 377                   Ent := Renamed_Object (Entity (Ent));
 378                end loop;
 379
 380                if (Nkind (Ent) = N_Attribute_Reference
 381                      and then Attribute_Name (Ent) = Name_Priority)
 382
 383                   --  Renamings of the attribute Priority applied to protected
 384                   --  objects have been previously expanded into calls to the
 385                   --  Get_Ceiling run-time subprogram.
 386
 387                  or else
 388                   (Nkind (Ent) = N_Function_Call
 389                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 390                                 or else
 391                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 392                then
 393                   --  The enclosing subprogram cannot be a protected function
 394
 395                   S := Current_Scope;
 396                   while not (Is_Subprogram (S)
 397                                and then Convention (S) = Convention_Protected)
 398                      and then S /= Standard_Standard
 399                   loop
 400                      S := Scope (S);
 401                   end loop;
 402
 403                   if Ekind (S) = E_Function
 404                     and then Convention (S) = Convention_Protected
 405                   then
 406                      Error_Msg_N
 407                        ("protected function cannot modify protected object",
 408                         Lhs);
 409                   end if;
 410
 411                   --  Changes of the ceiling priority of the protected object
 412                   --  are only effective if the Ceiling_Locking policy is in
 413                   --  effect (AARM D.5.2 (5/2)).
 414
 415                   if Locking_Policy /= 'C' then
 416                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 417                                   "no effect?", Lhs);
 418                      Error_Msg_N ("\since no Locking_Policy has been " &
 419                                   "specified", Lhs);
 420                   end if;
 421
 422                   return;
 423                end if;
 424             end if;
 425          end;
 426
 427          Diagnose_Non_Variable_Lhs (Lhs);
 428          return;
 429
 430       --  Error of assigning to limited type. We do however allow this in
 431       --  certain cases where the front end generates the assignments.
 432
 433       elsif Is_Limited_Type (T1)
 434         and then not Assignment_OK (Lhs)
 435         and then not Assignment_OK (Original_Node (Lhs))
 436         and then not Is_Value_Type (T1)
 437       then
 438          Error_Msg_N
 439            ("left hand of assignment must not be limited type", Lhs);
 440          Explain_Limited_Type (T1, Lhs);
 441          return;
 442
 443       --  Enforce RM 3.9.3 (8): left-hand side cannot be abstract
 444
 445       elsif Is_Interface (T1)
 446         and then not Is_Class_Wide_Type (T1)
 447       then
 448          Error_Msg_N
 449            ("target of assignment operation may not be abstract", Lhs);
 450          return;
 451       end if;
 452
 453       --  Resolution may have updated the subtype, in case the left-hand
 454       --  side is a private protected component. Use the correct subtype
 455       --  to avoid scoping issues in the back-end.
 456
 457       T1 := Etype (Lhs);
 458
 459       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 460       --  type. For example:
 461
 462       --    limited with P;
 463       --    package Pkg is
 464       --      type Acc is access P.T;
 465       --    end Pkg;
 466
 467       --    with Pkg; use Acc;
 468       --    procedure Example is
 469       --       A, B : Acc;
 470       --    begin
 471       --       A.all := B.all;  -- ERROR
 472       --    end Example;
 473
 474       if Nkind (Lhs) = N_Explicit_Dereference
 475         and then Ekind (T1) = E_Incomplete_Type
 476       then
 477          Error_Msg_N ("invalid use of incomplete type", Lhs);
 478          Kill_Lhs;
 479          return;
 480       end if;
 481
 482       --  Now we can complete the resolution of the right hand side
 483
 484       Set_Assignment_Type (Lhs, T1);
 485       Resolve (Rhs, T1);
 486
 487       --  This is the point at which we check for an unset reference
 488
 489       Check_Unset_Reference (Rhs);
 490       Check_Unprotected_Access (Lhs, Rhs);
 491
 492       --  Remaining steps are skipped if Rhs was syntactically in error
 493
 494       if Rhs = Error then
 495          Kill_Lhs;
 496          return;
 497       end if;
 498
 499       T2 := Etype (Rhs);
 500
 501       if not Covers (T1, T2) then
 502          Wrong_Type (Rhs, Etype (Lhs));
 503          Kill_Lhs;
 504          return;
 505       end if;
 506
 507       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 508       --  types, use the non-limited view if available
 509
 510       if Nkind (Rhs) = N_Explicit_Dereference
 511         and then Ekind (T2) = E_Incomplete_Type
 512         and then Is_Tagged_Type (T2)
 513         and then Present (Non_Limited_View (T2))
 514       then
 515          T2 := Non_Limited_View (T2);
 516       end if;
 517
 518       Set_Assignment_Type (Rhs, T2);
 519
 520       if Total_Errors_Detected /= 0 then
 521          if No (T1) then
 522             T1 := Any_Type;
 523          end if;
 524
 525          if No (T2) then
 526             T2 := Any_Type;
 527          end if;
 528       end if;
 529
 530       if T1 = Any_Type or else T2 = Any_Type then
 531          Kill_Lhs;
 532          return;
 533       end if;
 534
 535       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 536       --  to be class-wide. The case where the rhs is a dynamically tagged call
 537       --  to a dispatching operation with a controlling access result is
 538       --  excluded from this check, since the target has an access type (and
 539       --  no tag propagation occurs in that case).
 540
 541       if (Is_Class_Wide_Type (T2)
 542            or else (Is_Dynamically_Tagged (Rhs)
 543                      and then not Is_Access_Type (T1)))
 544         and then not Is_Class_Wide_Type (T1)
 545       then
 546          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 547
 548       elsif Is_Class_Wide_Type (T1)
 549         and then not Is_Class_Wide_Type (T2)
 550         and then not Is_Tag_Indeterminate (Rhs)
 551         and then not Is_Dynamically_Tagged (Rhs)
 552       then
 553          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 554       end if;
 555
 556       --  Propagate the tag from a class-wide target to the rhs when the rhs
 557       --  is a tag-indeterminate call.
 558
 559       if Is_Tag_Indeterminate (Rhs) then
 560          if Is_Class_Wide_Type (T1) then
 561             Propagate_Tag (Lhs, Rhs);
 562
 563          elsif Nkind (Rhs) = N_Function_Call
 564               and then Is_Entity_Name (Name (Rhs))
 565               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 566          then
 567             Error_Msg_N
 568               ("call to abstract function must be dispatching", Name (Rhs));
 569
 570          elsif Nkind (Rhs) = N_Qualified_Expression
 571            and then Nkind (Expression (Rhs)) = N_Function_Call
 572               and then Is_Entity_Name (Name (Expression (Rhs)))
 573               and then
 574                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 575          then
 576             Error_Msg_N
 577               ("call to abstract function must be dispatching",
 578                 Name (Expression (Rhs)));
 579          end if;
 580       end if;
 581
 582       --  Ada 2005 (AI-230 and AI-385): When the lhs type is an anonymous
 583       --  access type, apply an implicit conversion of the rhs to that type
 584       --  to force appropriate static and run-time accessibility checks.
 585
 586       if Ada_Version >= Ada_05
 587         and then Ekind (T1) = E_Anonymous_Access_Type
 588       then
 589          Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 590          Analyze_And_Resolve (Rhs, T1);
 591       end if;
 592
 593       --  Ada 2005 (AI-231): Assignment to not null variable
 594
 595       if Ada_Version >= Ada_05
 596         and then Can_Never_Be_Null (T1)
 597         and then not Assignment_OK (Lhs)
 598       then
 599          --  Case where we know the right hand side is null
 600
 601          if Known_Null (Rhs) then
 602             Apply_Compile_Time_Constraint_Error
 603               (N   => Rhs,
 604                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 605                Reason => CE_Null_Not_Allowed);
 606
 607             --  We still mark this as a possible modification, that's necessary
 608             --  to reset Is_True_Constant, and desirable for xref purposes.
 609
 610             Note_Possible_Modification (Lhs, Sure => True);
 611             return;
 612
 613          --  If we know the right hand side is non-null, then we convert to the
 614          --  target type, since we don't need a run time check in that case.
 615
 616          elsif not Can_Never_Be_Null (T2) then
 617             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 618             Analyze_And_Resolve (Rhs, T1);
 619          end if;
 620       end if;
 621
 622       if Is_Scalar_Type (T1) then
 623          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 624
 625       --  For array types, verify that lengths match. If the right hand side
 626       --  if a function call that has been inlined, the assignment has been
 627       --  rewritten as a block, and the constraint check will be applied to the
 628       --  assignment within the block.
 629
 630       elsif Is_Array_Type (T1)
 631         and then
 632           (Nkind (Rhs) /= N_Type_Conversion
 633             or else Is_Constrained (Etype (Rhs)))
 634         and then
 635           (Nkind (Rhs) /= N_Function_Call
 636             or else Nkind (N) /= N_Block_Statement)
 637       then
 638          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 639          --  but of course the indices do not have to match. If the right-hand
 640          --  side is a type conversion to an unconstrained type, a length check
 641          --  is performed on the expression itself during expansion. In rare
 642          --  cases, the redundant length check is computed on an index type
 643          --  with a different representation, triggering incorrect code in
 644          --  the back end.
 645
 646          Apply_Length_Check (Rhs, Etype (Lhs));
 647
 648       else
 649          --  Discriminant checks are applied in the course of expansion
 650
 651          null;
 652       end if;
 653
 654       --  Note: modifications of the Lhs may only be recorded after
 655       --  checks have been applied.
 656
 657       Note_Possible_Modification (Lhs, Sure => True);
 658
 659       --  ??? a real accessibility check is needed when ???
 660
 661       --  Post warning for redundant assignment or variable to itself
 662
 663       if Warn_On_Redundant_Constructs
 664
 665          --  We only warn for source constructs
 666
 667          and then Comes_From_Source (N)
 668
 669          --  Where the object is the same on both sides
 670
 671          and then Same_Object (Lhs, Original_Node (Rhs))
 672
 673          --  But exclude the case where the right side was an operation
 674          --  that got rewritten (e.g. JUNK + K, where K was known to be
 675          --  zero). We don't want to warn in such a case, since it is
 676          --  reasonable to write such expressions especially when K is
 677          --  defined symbolically in some other package.
 678
 679         and then Nkind (Original_Node (Rhs)) not in N_Op
 680       then
 681          if Nkind (Lhs) in N_Has_Entity then
 682             Error_Msg_NE
 683               ("?useless assignment of & to itself!", N, Entity (Lhs));
 684          else
 685             Error_Msg_N
 686               ("?useless assignment of object to itself!", N);
 687          end if;
 688       end if;
 689
 690       --  Check for non-allowed composite assignment
 691
 692       if not Support_Composite_Assign_On_Target
 693         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 694         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 695       then
 696          Error_Msg_CRT ("composite assignment", N);
 697       end if;
 698
 699       --  Check elaboration warning for left side if not in elab code
 700
 701       if not In_Subprogram_Or_Concurrent_Unit then
 702          Check_Elab_Assign (Lhs);
 703       end if;
 704
 705       --  Set Referenced_As_LHS if appropriate. We only set this flag if the
 706       --  assignment is a source assignment in the extended main source unit.
 707       --  We are not interested in any reference information outside this
 708       --  context, or in compiler generated assignment statements.
 709
 710       if Comes_From_Source (N)
 711         and then In_Extended_Main_Source_Unit (Lhs)
 712       then
 713          Set_Referenced_Modified (Lhs, Out_Param => False);
 714       end if;
 715
 716       --  Final step. If left side is an entity, then we may be able to
 717       --  reset the current tracked values to new safe values. We only have
 718       --  something to do if the left side is an entity name, and expansion
 719       --  has not modified the node into something other than an assignment,
 720       --  and of course we only capture values if it is safe to do so.
 721
 722       if Is_Entity_Name (Lhs)
 723         and then Nkind (N) = N_Assignment_Statement
 724       then
 725          declare
 726             Ent : constant Entity_Id := Entity (Lhs);
 727
 728          begin
 729             if Safe_To_Capture_Value (N, Ent) then
 730
 731                --  If simple variable on left side, warn if this assignment
 732                --  blots out another one (rendering it useless) and note
 733                --  location of assignment in case no one references value.
 734                --  We only do this for source assignments, otherwise we can
 735                --  generate bogus warnings when an assignment is rewritten as
 736                --  another assignment, and gets tied up with itself.
 737
 738                --  Note: we don't use Record_Last_Assignment here, because we
 739                --  have lots of other stuff to do under control of this test.
 740
 741                if Warn_On_Modified_Unread
 742                  and then Is_Assignable (Ent)
 743                  and then Comes_From_Source (N)
 744                  and then In_Extended_Main_Source_Unit (Ent)
 745                then
 746                   Warn_On_Useless_Assignment (Ent, N);
 747                   Set_Last_Assignment (Ent, Lhs);
 748                end if;
 749
 750                --  If we are assigning an access type and the left side is an
 751                --  entity, then make sure that the Is_Known_[Non_]Null flags
 752                --  properly reflect the state of the entity after assignment.
 753
 754                if Is_Access_Type (T1) then
 755                   if Known_Non_Null (Rhs) then
 756                      Set_Is_Known_Non_Null (Ent, True);
 757
 758                   elsif Known_Null (Rhs)
 759                     and then not Can_Never_Be_Null (Ent)
 760                   then
 761                      Set_Is_Known_Null (Ent, True);
 762
 763                   else
 764                      Set_Is_Known_Null (Ent, False);
 765
 766                      if not Can_Never_Be_Null (Ent) then
 767                         Set_Is_Known_Non_Null (Ent, False);
 768                      end if;
 769                   end if;
 770
 771                --  For discrete types, we may be able to set the current value
 772                --  if the value is known at compile time.
 773
 774                elsif Is_Discrete_Type (T1)
 775                  and then Compile_Time_Known_Value (Rhs)
 776                then
 777                   Set_Current_Value (Ent, Rhs);
 778                else
 779                   Set_Current_Value (Ent, Empty);
 780                end if;
 781
 782             --  If not safe to capture values, kill them
 783
 784             else
 785                Kill_Lhs;
 786             end if;
 787          end;
 788       end if;
 789    end Analyze_Assignment;
 790
 791    -----------------------------
 792    -- Analyze_Block_Statement --
 793    -----------------------------
 794
 795    procedure Analyze_Block_Statement (N : Node_Id) is
 796       Decls : constant List_Id := Declarations (N);
 797       Id    : constant Node_Id := Identifier (N);
 798       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 799
 800    begin
 801       --  If no handled statement sequence is present, things are really
 802       --  messed up, and we just return immediately (this is a defence
 803       --  against previous errors).
 804
 805       if No (HSS) then
 806          return;
 807       end if;
 808
 809       --  Normal processing with HSS present
 810
 811       declare
 812          EH  : constant List_Id := Exception_Handlers (HSS);
 813          Ent : Entity_Id        := Empty;
 814          S   : Entity_Id;
 815
 816          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 817          --  Recursively save value of this global, will be restored on exit
 818
 819       begin
 820          --  Initialize unblocked exit count for statements of begin block
 821          --  plus one for each exception handler that is present.
 822
 823          Unblocked_Exit_Count := 1;
 824
 825          if Present (EH) then
 826             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 827          end if;
 828
 829          --  If a label is present analyze it and mark it as referenced
 830
 831          if Present (Id) then
 832             Analyze (Id);
 833             Ent := Entity (Id);
 834
 835             --  An error defense. If we have an identifier, but no entity,
 836             --  then something is wrong. If we have previous errors, then
 837             --  just remove the identifier and continue, otherwise raise
 838             --  an exception.
 839
 840             if No (Ent) then
 841                if Total_Errors_Detected /= 0 then
 842                   Set_Identifier (N, Empty);
 843                else
 844                   raise Program_Error;
 845                end if;
 846
 847             else
 848                Set_Ekind (Ent, E_Block);
 849                Generate_Reference (Ent, N, ' ');
 850                Generate_Definition (Ent);
 851
 852                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 853                   Set_Label_Construct (Parent (Ent), N);
 854                end if;
 855             end if;
 856          end if;
 857
 858          --  If no entity set, create a label entity
 859
 860          if No (Ent) then
 861             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 862             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 863             Set_Parent (Ent, N);
 864          end if;
 865
 866          Set_Etype (Ent, Standard_Void_Type);
 867          Set_Block_Node (Ent, Identifier (N));
 868          Push_Scope (Ent);
 869
 870          if Present (Decls) then
 871             Analyze_Declarations (Decls);
 872             Check_Completion;
 873          end if;
 874
 875          Analyze (HSS);
 876          Process_End_Label (HSS, 'e', Ent);
 877
 878          --  If exception handlers are present, then we indicate that
 879          --  enclosing scopes contain a block with handlers. We only
 880          --  need to mark non-generic scopes.
 881
 882          if Present (EH) then
 883             S := Scope (Ent);
 884             loop
 885                Set_Has_Nested_Block_With_Handler (S);
 886                exit when Is_Overloadable (S)
 887                  or else Ekind (S) = E_Package
 888                  or else Is_Generic_Unit (S);
 889                S := Scope (S);
 890             end loop;
 891          end if;
 892
 893          Check_References (Ent);
 894          Warn_On_Useless_Assignments (Ent);
 895          End_Scope;
 896
 897          if Unblocked_Exit_Count = 0 then
 898             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 899             Check_Unreachable_Code (N);
 900          else
 901             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 902          end if;
 903       end;
 904    end Analyze_Block_Statement;
 905
 906    ----------------------------
 907    -- Analyze_Case_Statement --
 908    ----------------------------
 909
 910    procedure Analyze_Case_Statement (N : Node_Id) is
 911       Exp            : Node_Id;
 912       Exp_Type       : Entity_Id;
 913       Exp_Btype      : Entity_Id;
 914       Last_Choice    : Nat;
 915       Dont_Care      : Boolean;
 916       Others_Present : Boolean;
 917
 918       pragma Warnings (Off, Last_Choice);
 919       pragma Warnings (Off, Dont_Care);
 920       --  Don't care about assigned values
 921
 922       Statements_Analyzed : Boolean := False;
 923       --  Set True if at least some statement sequences get analyzed.
 924       --  If False on exit, means we had a serious error that prevented
 925       --  full analysis of the case statement, and as a result it is not
 926       --  a good idea to output warning messages about unreachable code.
 927
 928       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 929       --  Recursively save value of this global, will be restored on exit
 930
 931       procedure Non_Static_Choice_Error (Choice : Node_Id);
 932       --  Error routine invoked by the generic instantiation below when
 933       --  the case statement has a non static choice.
 934
 935       procedure Process_Statements (Alternative : Node_Id);
 936       --  Analyzes all the statements associated to a case alternative.
 937       --  Needed by the generic instantiation below.
 938
 939       package Case_Choices_Processing is new
 940         Generic_Choices_Processing
 941           (Get_Alternatives          => Alternatives,
 942            Get_Choices               => Discrete_Choices,
 943            Process_Empty_Choice      => No_OP,
 944            Process_Non_Static_Choice => Non_Static_Choice_Error,
 945            Process_Associated_Node   => Process_Statements);
 946       use Case_Choices_Processing;
 947       --  Instantiation of the generic choice processing package
 948
 949       -----------------------------
 950       -- Non_Static_Choice_Error --
 951       -----------------------------
 952
 953       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 954       begin
 955          Flag_Non_Static_Expr
 956            ("choice given in case statement is not static!", Choice);
 957       end Non_Static_Choice_Error;
 958
 959       ------------------------
 960       -- Process_Statements --
 961       ------------------------
 962
 963       procedure Process_Statements (Alternative : Node_Id) is
 964          Choices : constant List_Id := Discrete_Choices (Alternative);
 965          Ent     : Entity_Id;
 966
 967       begin
 968          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 969          Statements_Analyzed := True;
 970
 971          --  An interesting optimization. If the case statement expression
 972          --  is a simple entity, then we can set the current value within
 973          --  an alternative if the alternative has one possible value.
 974
 975          --    case N is
 976          --      when 1      => alpha
 977          --      when 2 | 3  => beta
 978          --      when others => gamma
 979
 980          --  Here we know that N is initially 1 within alpha, but for beta
 981          --  and gamma, we do not know anything more about the initial value.
 982
 983          if Is_Entity_Name (Exp) then
 984             Ent := Entity (Exp);
 985
 986             if Ekind (Ent) = E_Variable
 987                  or else
 988                Ekind (Ent) = E_In_Out_Parameter
 989                  or else
 990                Ekind (Ent) = E_Out_Parameter
 991             then
 992                if List_Length (Choices) = 1
 993                  and then Nkind (First (Choices)) in N_Subexpr
 994                  and then Compile_Time_Known_Value (First (Choices))
 995                then
 996                   Set_Current_Value (Entity (Exp), First (Choices));
 997                end if;
 998
 999                Analyze_Statements (Statements (Alternative));
1000
1001                --  After analyzing the case, set the current value to empty
1002                --  since we won't know what it is for the next alternative
1003                --  (unless reset by this same circuit), or after the case.
1004
1005                Set_Current_Value (Entity (Exp), Empty);
1006                return;
1007             end if;
1008          end if;
1009
1010          --  Case where expression is not an entity name of a variable
1011
1012          Analyze_Statements (Statements (Alternative));
1013       end Process_Statements;
1014
1015       --  Table to record choices. Put after subprograms since we make
1016       --  a call to Number_Of_Choices to get the right number of entries.
1017
1018       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
1019       pragma Warnings (Off, Case_Table);
1020
1021    --  Start of processing for Analyze_Case_Statement
1022
1023    begin
1024       Unblocked_Exit_Count := 0;
1025       Exp := Expression (N);
1026       Analyze (Exp);
1027
1028       --  The expression must be of any discrete type. In rare cases, the
1029       --  expander constructs a case statement whose expression has a private
1030       --  type whose full view is discrete. This can happen when generating
1031       --  a stream operation for a variant type after the type is frozen,
1032       --  when the partial of view of the type of the discriminant is private.
1033       --  In that case, use the full view to analyze case alternatives.
1034
1035       if not Is_Overloaded (Exp)
1036         and then not Comes_From_Source (N)
1037         and then Is_Private_Type (Etype (Exp))
1038         and then Present (Full_View (Etype (Exp)))
1039         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1040       then
1041          Resolve (Exp, Etype (Exp));
1042          Exp_Type := Full_View (Etype (Exp));
1043
1044       else
1045          Analyze_And_Resolve (Exp, Any_Discrete);
1046          Exp_Type := Etype (Exp);
1047       end if;
1048
1049       Check_Unset_Reference (Exp);
1050       Exp_Btype := Base_Type (Exp_Type);
1051
1052       --  The expression must be of a discrete type which must be determinable
1053       --  independently of the context in which the expression occurs, but
1054       --  using the fact that the expression must be of a discrete type.
1055       --  Moreover, the type this expression must not be a character literal
1056       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1057
1058       --  If error already reported by Resolve, nothing more to do
1059
1060       if Exp_Btype = Any_Discrete
1061         or else Exp_Btype = Any_Type
1062       then
1063          return;
1064
1065       elsif Exp_Btype = Any_Character then
1066          Error_Msg_N
1067            ("character literal as case expression is ambiguous", Exp);
1068          return;
1069
1070       elsif Ada_Version = Ada_83
1071         and then (Is_Generic_Type (Exp_Btype)
1072                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1073       then
1074          Error_Msg_N
1075            ("(Ada 83) case expression cannot be of a generic type", Exp);
1076          return;
1077       end if;
1078
1079       --  If the case expression is a formal object of mode in out, then
1080       --  treat it as having a nonstatic subtype by forcing use of the base
1081       --  type (which has to get passed to Check_Case_Choices below).  Also
1082       --  use base type when the case expression is parenthesized.
1083
1084       if Paren_Count (Exp) > 0
1085         or else (Is_Entity_Name (Exp)
1086                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1087       then
1088          Exp_Type := Exp_Btype;
1089       end if;
1090
1091       --  Call instantiated Analyze_Choices which does the rest of the work
1092
1093       Analyze_Choices
1094         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
1095
1096       if Exp_Type = Universal_Integer and then not Others_Present then
1097          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1098       end if;
1099
1100       --  If all our exits were blocked by unconditional transfers of control,
1101       --  then the entire CASE statement acts as an unconditional transfer of
1102       --  control, so treat it like one, and check unreachable code. Skip this
1103       --  test if we had serious errors preventing any statement analysis.
1104
1105       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1106          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1107          Check_Unreachable_Code (N);
1108       else
1109          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1110       end if;
1111
1112       if not Expander_Active
1113         and then Compile_Time_Known_Value (Expression (N))
1114         and then Serious_Errors_Detected = 0
1115       then
1116          declare
1117             Chosen : constant Node_Id := Find_Static_Alternative (N);
1118             Alt    : Node_Id;
1119
1120          begin
1121             Alt := First (Alternatives (N));
1122             while Present (Alt) loop
1123                if Alt /= Chosen then
1124                   Remove_Warning_Messages (Statements (Alt));
1125                end if;
1126
1127                Next (Alt);
1128             end loop;
1129          end;
1130       end if;
1131    end Analyze_Case_Statement;
1132
1133    ----------------------------
1134    -- Analyze_Exit_Statement --
1135    ----------------------------
1136
1137    --  If the exit includes a name, it must be the name of a currently open
1138    --  loop. Otherwise there must be an innermost open loop on the stack,
1139    --  to which the statement implicitly refers.
1140
1141    procedure Analyze_Exit_Statement (N : Node_Id) is
1142       Target   : constant Node_Id := Name (N);
1143       Cond     : constant Node_Id := Condition (N);
1144       Scope_Id : Entity_Id;
1145       U_Name   : Entity_Id;
1146       Kind     : Entity_Kind;
1147
1148    begin
1149       if No (Cond) then
1150          Check_Unreachable_Code (N);
1151       end if;
1152
1153       if Present (Target) then
1154          Analyze (Target);
1155          U_Name := Entity (Target);
1156
1157          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1158             Error_Msg_N ("invalid loop name in exit statement", N);
1159             return;
1160          else
1161             Set_Has_Exit (U_Name);
1162          end if;
1163
1164       else
1165          U_Name := Empty;
1166       end if;
1167
1168       for J in reverse 0 .. Scope_Stack.Last loop
1169          Scope_Id := Scope_Stack.Table (J).Entity;
1170          Kind := Ekind (Scope_Id);
1171
1172          if Kind = E_Loop
1173            and then (No (Target) or else Scope_Id = U_Name) then
1174             Set_Has_Exit (Scope_Id);
1175             exit;
1176
1177          elsif Kind = E_Block
1178            or else Kind = E_Loop
1179            or else Kind = E_Return_Statement
1180          then
1181             null;
1182
1183          else
1184             Error_Msg_N
1185               ("cannot exit from program unit or accept statement", N);
1186             exit;
1187          end if;
1188       end loop;
1189
1190       --  Verify that if present the condition is a Boolean expression
1191
1192       if Present (Cond) then
1193          Analyze_And_Resolve (Cond, Any_Boolean);
1194          Check_Unset_Reference (Cond);
1195       end if;
1196    end Analyze_Exit_Statement;
1197
1198    ----------------------------
1199    -- Analyze_Goto_Statement --
1200    ----------------------------
1201
1202    procedure Analyze_Goto_Statement (N : Node_Id) is
1203       Label       : constant Node_Id := Name (N);
1204       Scope_Id    : Entity_Id;
1205       Label_Scope : Entity_Id;
1206       Label_Ent   : Entity_Id;
1207
1208    begin
1209       Check_Unreachable_Code (N);
1210       Kill_Current_Values (Last_Assignment_Only => True);
1211
1212       Analyze (Label);
1213       Label_Ent := Entity (Label);
1214
1215       --  Ignore previous error
1216
1217       if Label_Ent = Any_Id then
1218          return;
1219
1220       --  We just have a label as the target of a goto
1221
1222       elsif Ekind (Label_Ent) /= E_Label then
1223          Error_Msg_N ("target of goto statement must be a label", Label);
1224          return;
1225
1226       --  Check that the target of the goto is reachable according to Ada
1227       --  scoping rules. Note: the special gotos we generate for optimizing
1228       --  local handling of exceptions would violate these rules, but we mark
1229       --  such gotos as analyzed when built, so this code is never entered.
1230
1231       elsif not Reachable (Label_Ent) then
1232          Error_Msg_N ("target of goto statement is not reachable", Label);
1233          return;
1234       end if;
1235
1236       --  Here if goto passes initial validity checks
1237
1238       Label_Scope := Enclosing_Scope (Label_Ent);
1239
1240       for J in reverse 0 .. Scope_Stack.Last loop
1241          Scope_Id := Scope_Stack.Table (J).Entity;
1242
1243          if Label_Scope = Scope_Id
1244            or else (Ekind (Scope_Id) /= E_Block
1245                      and then Ekind (Scope_Id) /= E_Loop
1246                      and then Ekind (Scope_Id) /= E_Return_Statement)
1247          then
1248             if Scope_Id /= Label_Scope then
1249                Error_Msg_N
1250                  ("cannot exit from program unit or accept statement", N);
1251             end if;
1252
1253             return;
1254          end if;
1255       end loop;
1256
1257       raise Program_Error;
1258    end Analyze_Goto_Statement;
1259
1260    --------------------------
1261    -- Analyze_If_Statement --
1262    --------------------------
1263
1264    --  A special complication arises in the analysis of if statements
1265
1266    --  The expander has circuitry to completely delete code that it
1267    --  can tell will not be executed (as a result of compile time known
1268    --  conditions). In the analyzer, we ensure that code that will be
1269    --  deleted in this manner is analyzed but not expanded. This is
1270    --  obviously more efficient, but more significantly, difficulties
1271    --  arise if code is expanded and then eliminated (e.g. exception
1272    --  table entries disappear). Similarly, itypes generated in deleted
1273    --  code must be frozen from start, because the nodes on which they
1274    --  depend will not be available at the freeze point.
1275
1276    procedure Analyze_If_Statement (N : Node_Id) is
1277       E : Node_Id;
1278
1279       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1280       --  Recursively save value of this global, will be restored on exit
1281
1282       Save_In_Deleted_Code : Boolean;
1283
1284       Del : Boolean := False;
1285       --  This flag gets set True if a True condition has been found,
1286       --  which means that remaining ELSE/ELSIF parts are deleted.
1287
1288       procedure Analyze_Cond_Then (Cnode : Node_Id);
1289       --  This is applied to either the N_If_Statement node itself or
1290       --  to an N_Elsif_Part node. It deals with analyzing the condition
1291       --  and the THEN statements associated with it.
1292
1293       -----------------------
1294       -- Analyze_Cond_Then --
1295       -----------------------
1296
1297       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1298          Cond : constant Node_Id := Condition (Cnode);
1299          Tstm : constant List_Id := Then_Statements (Cnode);
1300
1301       begin
1302          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1303          Analyze_And_Resolve (Cond, Any_Boolean);
1304          Check_Unset_Reference (Cond);
1305          Set_Current_Value_Condition (Cnode);
1306
1307          --  If already deleting, then just analyze then statements
1308
1309          if Del then
1310             Analyze_Statements (Tstm);
1311
1312          --  Compile time known value, not deleting yet
1313
1314          elsif Compile_Time_Known_Value (Cond) then
1315             Save_In_Deleted_Code := In_Deleted_Code;
1316
1317             --  If condition is True, then analyze the THEN statements
1318             --  and set no expansion for ELSE and ELSIF parts.
1319
1320             if Is_True (Expr_Value (Cond)) then
1321                Analyze_Statements (Tstm);
1322                Del := True;
1323                Expander_Mode_Save_And_Set (False);
1324                In_Deleted_Code := True;
1325
1326             --  If condition is False, analyze THEN with expansion off
1327
1328             else -- Is_False (Expr_Value (Cond))
1329                Expander_Mode_Save_And_Set (False);
1330                In_Deleted_Code := True;
1331                Analyze_Statements (Tstm);
1332                Expander_Mode_Restore;
1333                In_Deleted_Code := Save_In_Deleted_Code;
1334             end if;
1335
1336          --  Not known at compile time, not deleting, normal analysis
1337
1338          else
1339             Analyze_Statements (Tstm);
1340          end if;
1341       end Analyze_Cond_Then;
1342
1343    --  Start of Analyze_If_Statement
1344
1345    begin
1346       --  Initialize exit count for else statements. If there is no else
1347       --  part, this count will stay non-zero reflecting the fact that the
1348       --  uncovered else case is an unblocked exit.
1349
1350       Unblocked_Exit_Count := 1;
1351       Analyze_Cond_Then (N);
1352
1353       --  Now to analyze the elsif parts if any are present
1354
1355       if Present (Elsif_Parts (N)) then
1356          E := First (Elsif_Parts (N));
1357          while Present (E) loop
1358             Analyze_Cond_Then (E);
1359             Next (E);
1360          end loop;
1361       end if;
1362
1363       if Present (Else_Statements (N)) then
1364          Analyze_Statements (Else_Statements (N));
1365       end if;
1366
1367       --  If all our exits were blocked by unconditional transfers of control,
1368       --  then the entire IF statement acts as an unconditional transfer of
1369       --  control, so treat it like one, and check unreachable code.
1370
1371       if Unblocked_Exit_Count = 0 then
1372          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1373          Check_Unreachable_Code (N);
1374       else
1375          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1376       end if;
1377
1378       if Del then
1379          Expander_Mode_Restore;
1380          In_Deleted_Code := Save_In_Deleted_Code;
1381       end if;
1382
1383       if not Expander_Active
1384         and then Compile_Time_Known_Value (Condition (N))
1385         and then Serious_Errors_Detected = 0
1386       then
1387          if Is_True (Expr_Value (Condition (N))) then
1388             Remove_Warning_Messages (Else_Statements (N));
1389
1390             if Present (Elsif_Parts (N)) then
1391                E := First (Elsif_Parts (N));
1392                while Present (E) loop
1393                   Remove_Warning_Messages (Then_Statements (E));
1394                   Next (E);
1395                end loop;
1396             end if;
1397
1398          else
1399             Remove_Warning_Messages (Then_Statements (N));
1400          end if;
1401       end if;
1402    end Analyze_If_Statement;
1403
1404    ----------------------------------------
1405    -- Analyze_Implicit_Label_Declaration --
1406    ----------------------------------------
1407
1408    --  An implicit label declaration is generated in the innermost
1409    --  enclosing declarative part. This is done for labels as well as
1410    --  block and loop names.
1411
1412    --  Note: any changes in this routine may need to be reflected in
1413    --  Analyze_Label_Entity.
1414
1415    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1416       Id : constant Node_Id := Defining_Identifier (N);
1417    begin
1418       Enter_Name          (Id);
1419       Set_Ekind           (Id, E_Label);
1420       Set_Etype           (Id, Standard_Void_Type);
1421       Set_Enclosing_Scope (Id, Current_Scope);
1422    end Analyze_Implicit_Label_Declaration;
1423
1424    ------------------------------
1425    -- Analyze_Iteration_Scheme --
1426    ------------------------------
1427
1428    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1429
1430       procedure Process_Bounds (R : Node_Id);
1431       --  If the iteration is given by a range, create temporaries and
1432       --  assignment statements block to capture the bounds and perform
1433       --  required finalization actions in case a bound includes a function
1434       --  call that uses the temporary stack. We first pre-analyze a copy of
1435       --  the range in order to determine the expected type, and analyze and
1436       --  resolve the original bounds.
1437
1438       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1439       --  If the bounds are given by a 'Range reference on a function call
1440       --  that returns a controlled array, introduce an explicit declaration
1441       --  to capture the bounds, so that the function result can be finalized
1442       --  in timely fashion.
1443
1444       --------------------
1445       -- Process_Bounds --
1446       --------------------
1447
1448       procedure Process_Bounds (R : Node_Id) is
1449          Loc          : constant Source_Ptr := Sloc (N);
1450          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1451          Lo           : constant Node_Id := Low_Bound  (R);
1452          Hi           : constant Node_Id := High_Bound (R);
1453          New_Lo_Bound : Node_Id := Empty;
1454          New_Hi_Bound : Node_Id := Empty;
1455          Typ          : Entity_Id;
1456          Save_Analysis : Boolean;
1457
1458          function One_Bound
1459            (Original_Bound : Node_Id;
1460             Analyzed_Bound : Node_Id) return Node_Id;
1461          --  Create one declaration followed by one assignment statement
1462          --  to capture the value of bound. We create a separate assignment
1463          --  in order to force the creation of a block in case the bound
1464          --  contains a call that uses the secondary stack.
1465
1466          ---------------
1467          -- One_Bound --
1468          ---------------
1469
1470          function One_Bound
1471            (Original_Bound : Node_Id;
1472             Analyzed_Bound : Node_Id) return Node_Id
1473          is
1474             Assign : Node_Id;
1475             Id     : Entity_Id;
1476             Decl   : Node_Id;
1477
1478          begin
1479             --  If the bound is a constant or an object, no need for a separate
1480             --  declaration. If the bound is the result of previous expansion
1481             --  it is already analyzed and should not be modified. Note that
1482             --  the Bound will be resolved later, if needed, as part of the
1483             --  call to Make_Index (literal bounds may need to be resolved to
1484             --  type Integer).
1485
1486             if Analyzed (Original_Bound) then
1487                return Original_Bound;
1488
1489             elsif Nkind_In (Analyzed_Bound, N_Integer_Literal,
1490                                             N_Character_Literal)
1491               or else Is_Entity_Name (Analyzed_Bound)
1492             then
1493                Analyze_And_Resolve (Original_Bound, Typ);
1494                return Original_Bound;
1495
1496             else
1497                Analyze_And_Resolve (Original_Bound, Typ);
1498             end if;
1499
1500             Id :=
1501               Make_Defining_Identifier (Loc,
1502                 Chars => New_Internal_Name ('S'));
1503
1504             Decl :=
1505               Make_Object_Declaration (Loc,
1506                 Defining_Identifier => Id,
1507                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1508
1509             Insert_Before (Parent (N), Decl);
1510             Analyze (Decl);
1511
1512             Assign :=
1513               Make_Assignment_Statement (Loc,
1514                 Name        => New_Occurrence_Of (Id, Loc),
1515                 Expression  => Relocate_Node (Original_Bound));
1516
1517             Insert_Before (Parent (N), Assign);
1518             Analyze (Assign);
1519
1520             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1521
1522             if Nkind (Assign) = N_Assignment_Statement then
1523                return Expression (Assign);
1524             else
1525                return Original_Bound;
1526             end if;
1527          end One_Bound;
1528
1529       --  Start of processing for Process_Bounds
1530
1531       begin
1532          --  Determine expected type of range by analyzing separate copy
1533          --  Do the analysis and resolution of the copy of the bounds with
1534          --  expansion disabled, to prevent the generation of finalization
1535          --  actions on each bound. This prevents memory leaks when the
1536          --  bounds contain calls to functions returning controlled arrays.
1537
1538          Set_Parent (R_Copy, Parent (R));
1539          Save_Analysis := Full_Analysis;
1540          Full_Analysis := False;
1541          Expander_Mode_Save_And_Set (False);
1542
1543          Analyze (R_Copy);
1544
1545          if Is_Overloaded (R_Copy) then
1546
1547             --  Apply preference rules for range of predefined integer types,
1548             --  or diagnose true ambiguity.
1549
1550             declare
1551                I     : Interp_Index;
1552                It    : Interp;
1553                Found : Entity_Id := Empty;
1554
1555             begin
1556                Get_First_Interp (R_Copy, I, It);
1557                while Present (It.Typ) loop
1558                   if Is_Discrete_Type (It.Typ) then
1559                      if No (Found) then
1560                         Found := It.Typ;
1561                      else
1562                         if Scope (Found) = Standard_Standard then
1563                            null;
1564
1565                         elsif Scope (It.Typ) = Standard_Standard then
1566                            Found := It.Typ;
1567
1568                         else
1569                            --  Both of them are user-defined
1570
1571                            Error_Msg_N
1572                              ("ambiguous bounds in range of iteration",
1573                                R_Copy);
1574                            Error_Msg_N ("\possible interpretations:", R_Copy);
1575                            Error_Msg_NE ("\\} ", R_Copy, Found);
1576                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1577                            exit;
1578                         end if;
1579                      end if;
1580                   end if;
1581
1582                   Get_Next_Interp (I, It);
1583                end loop;
1584             end;
1585          end if;
1586
1587          Resolve (R_Copy);
1588          Expander_Mode_Restore;
1589          Full_Analysis := Save_Analysis;
1590
1591          Typ := Etype (R_Copy);
1592
1593          --  If the type of the discrete range is Universal_Integer, then
1594          --  the bound's type must be resolved to Integer, and any object
1595          --  used to hold the bound must also have type Integer, unless the
1596          --  literal bounds are constant-folded expressions that carry a user-
1597          --  defined type.
1598
1599          if Typ = Universal_Integer then
1600             if Nkind (Lo) = N_Integer_Literal
1601               and then Present (Etype (Lo))
1602               and then Scope (Etype (Lo)) /= Standard_Standard
1603             then
1604                Typ := Etype (Lo);
1605
1606             elsif Nkind (Hi) = N_Integer_Literal
1607               and then Present (Etype (Hi))
1608               and then Scope (Etype (Hi)) /= Standard_Standard
1609             then
1610                Typ := Etype (Hi);
1611
1612             else
1613                Typ := Standard_Integer;
1614             end if;
1615          end if;
1616
1617          Set_Etype (R, Typ);
1618
1619          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1620          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1621
1622          --  Propagate staticness to loop range itself, in case the
1623          --  corresponding subtype is static.
1624
1625          if New_Lo_Bound /= Lo
1626            and then Is_Static_Expression (New_Lo_Bound)
1627          then
1628             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1629          end if;
1630
1631          if New_Hi_Bound /= Hi
1632            and then Is_Static_Expression (New_Hi_Bound)
1633          then
1634             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1635          end if;
1636       end Process_Bounds;
1637
1638       --------------------------------------
1639       -- Check_Controlled_Array_Attribute --
1640       --------------------------------------
1641
1642       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1643       begin
1644          if Nkind (DS) = N_Attribute_Reference
1645             and then Is_Entity_Name (Prefix (DS))
1646             and then Ekind (Entity (Prefix (DS))) = E_Function
1647             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1648             and then
1649               Is_Controlled (
1650                 Component_Type (Etype (Entity (Prefix (DS)))))
1651             and then Expander_Active
1652          then
1653             declare
1654                Loc  : constant Source_Ptr := Sloc (N);
1655                Arr  : constant Entity_Id :=
1656                         Etype (Entity (Prefix (DS)));
1657                Indx : constant Entity_Id :=
1658                         Base_Type (Etype (First_Index (Arr)));
1659                Subt : constant Entity_Id :=
1660                         Make_Defining_Identifier
1661                           (Loc, New_Internal_Name ('S'));
1662                Decl : Node_Id;
1663
1664             begin
1665                Decl :=
1666                  Make_Subtype_Declaration (Loc,
1667                    Defining_Identifier => Subt,
1668                    Subtype_Indication  =>
1669                       Make_Subtype_Indication (Loc,
1670                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1671                         Constraint =>
1672                           Make_Range_Constraint (Loc,
1673                             Relocate_Node (DS))));
1674                Insert_Before (Parent (N), Decl);
1675                Analyze (Decl);
1676
1677                Rewrite (DS,
1678                   Make_Attribute_Reference (Loc,
1679                     Prefix => New_Reference_To (Subt, Loc),
1680                     Attribute_Name => Attribute_Name (DS)));
1681                Analyze (DS);
1682             end;
1683          end if;
1684       end Check_Controlled_Array_Attribute;
1685
1686    --  Start of processing for Analyze_Iteration_Scheme
1687
1688    begin
1689       --  For an infinite loop, there is no iteration scheme
1690
1691       if No (N) then
1692          return;
1693
1694       else
1695          declare
1696             Cond : constant Node_Id := Condition (N);
1697
1698          begin
1699             --  For WHILE loop, verify that the condition is a Boolean
1700             --  expression and resolve and check it.
1701
1702             if Present (Cond) then
1703                Analyze_And_Resolve (Cond, Any_Boolean);
1704                Check_Unset_Reference (Cond);
1705                Set_Current_Value_Condition (N);
1706                return;
1707
1708             --  Else we have a FOR loop
1709
1710             else
1711                declare
1712                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1713                   Id : constant Entity_Id := Defining_Identifier (LP);
1714                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1715
1716                begin
1717                   Enter_Name (Id);
1718
1719                   --  We always consider the loop variable to be referenced,
1720                   --  since the loop may be used just for counting purposes.
1721
1722                   Generate_Reference (Id, N, ' ');
1723
1724                   --  Check for case of loop variable hiding a local
1725                   --  variable (used later on to give a nice warning
1726                   --  if the hidden variable is never assigned).
1727
1728                   declare
1729                      H : constant Entity_Id := Homonym (Id);
1730                   begin
1731                      if Present (H)
1732                        and then Enclosing_Dynamic_Scope (H) =
1733                                 Enclosing_Dynamic_Scope (Id)
1734                        and then Ekind (H) = E_Variable
1735                        and then Is_Discrete_Type (Etype (H))
1736                      then
1737                         Set_Hiding_Loop_Variable (H, Id);
1738                      end if;
1739                   end;
1740
1741                   --  Now analyze the subtype definition. If it is
1742                   --  a range, create temporaries for bounds.
1743
1744                   if Nkind (DS) = N_Range
1745                     and then Expander_Active
1746                   then
1747                      Process_Bounds (DS);
1748                   else
1749                      Analyze (DS);
1750                   end if;
1751
1752                   if DS = Error then
1753                      return;
1754                   end if;
1755
1756                   --  The subtype indication may denote the completion
1757                   --  of an incomplete type declaration.
1758
1759                   if Is_Entity_Name (DS)
1760                     and then Present (Entity (DS))
1761                     and then Is_Type (Entity (DS))
1762                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1763                   then
1764                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1765                      Set_Etype  (DS, Entity (DS));
1766                   end if;
1767
1768                   if not Is_Discrete_Type (Etype (DS)) then
1769                      Wrong_Type (DS, Any_Discrete);
1770                      Set_Etype (DS, Any_Type);
1771                   end if;
1772
1773                   Check_Controlled_Array_Attribute (DS);
1774
1775                   Make_Index (DS, LP);
1776
1777                   Set_Ekind          (Id, E_Loop_Parameter);
1778                   Set_Etype          (Id, Etype (DS));
1779                   Set_Is_Known_Valid (Id, True);
1780
1781                   --  The loop is not a declarative part, so the only entity
1782                   --  declared "within" must be frozen explicitly.
1783
1784                   declare
1785                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1786                   begin
1787                      if Is_Non_Empty_List (Flist) then
1788                         Insert_Actions (N, Flist);
1789                      end if;
1790                   end;
1791
1792                   --  Check for null or possibly null range and issue warning.
1793                   --  We suppress such messages in generic templates and
1794                   --  instances, because in practice they tend to be dubious
1795                   --  in these cases.
1796
1797                   if Nkind (DS) = N_Range
1798                     and then Comes_From_Source (N)
1799                   then
1800                      declare
1801                         L : constant Node_Id := Low_Bound  (DS);
1802                         H : constant Node_Id := High_Bound (DS);
1803
1804                         Llo : Uint;
1805                         Lhi : Uint;
1806                         LOK : Boolean;
1807                         Hlo : Uint;
1808                         Hhi : Uint;
1809                         HOK : Boolean;
1810
1811                         pragma Warnings (Off, Hlo);
1812
1813                      begin
1814                         Determine_Range (L, LOK, Llo, Lhi);
1815                         Determine_Range (H, HOK, Hlo, Hhi);
1816
1817                         --  If range of loop is null, issue warning
1818
1819                         if (LOK and HOK) and then Llo > Hhi then
1820
1821                            --  Suppress the warning if inside a generic
1822                            --  template or instance, since in practice
1823                            --  they tend to be dubious in these cases since
1824                            --  they can result from intended parametrization.
1825
1826                            if not Inside_A_Generic
1827                               and then not In_Instance
1828                            then
1829                               Error_Msg_N
1830                                 ("?loop range is null, loop will not execute",
1831                                  DS);
1832                            end if;
1833
1834                            --  Since we know the range of the loop is null,
1835                            --  set the appropriate flag to suppress any
1836                            --  warnings that would otherwise be issued in
1837                            --  the body of the loop that will not execute.
1838                            --  We do this even in the generic case, since
1839                            --  if it is dubious to warn on the null loop
1840                            --  itself, it is certainly dubious to warn for
1841                            --  conditions that occur inside it!
1842
1843                            Set_Is_Null_Loop (Parent (N));
1844
1845                         --  The other case for a warning is a reverse loop
1846                         --  where the upper bound is the integer literal
1847                         --  zero or one, and the lower bound can be positive.
1848
1849                         --  For example, we have
1850
1851                         --     for J in reverse N .. 1 loop
1852
1853                         --  In practice, this is very likely to be a case
1854                         --  of reversing the bounds incorrectly in the range.
1855
1856                         elsif Reverse_Present (LP)
1857                           and then Nkind (Original_Node (H)) =
1858                                                           N_Integer_Literal
1859                           and then (Intval (H) = Uint_0
1860                                       or else
1861                                     Intval (H) = Uint_1)
1862                           and then Lhi > Hhi
1863                         then
1864                            Error_Msg_N ("?loop range may be null", DS);
1865                            Error_Msg_N ("\?bounds may be wrong way round", DS);
1866                         end if;
1867                      end;
1868                   end if;
1869                end;
1870             end if;
1871          end;
1872       end if;
1873    end Analyze_Iteration_Scheme;
1874
1875    -------------------
1876    -- Analyze_Label --
1877    -------------------
1878
1879    --  Note: the semantic work required for analyzing labels (setting them as
1880    --  reachable) was done in a prepass through the statements in the block,
1881    --  so that forward gotos would be properly handled. See Analyze_Statements
1882    --  for further details. The only processing required here is to deal with
1883    --  optimizations that depend on an assumption of sequential control flow,
1884    --  since of course the occurrence of a label breaks this assumption.
1885
1886    procedure Analyze_Label (N : Node_Id) is
1887       pragma Warnings (Off, N);
1888    begin
1889       Kill_Current_Values;
1890    end Analyze_Label;
1891
1892    --------------------------
1893    -- Analyze_Label_Entity --
1894    --------------------------
1895
1896    procedure Analyze_Label_Entity (E : Entity_Id) is
1897    begin
1898       Set_Ekind           (E, E_Label);
1899       Set_Etype           (E, Standard_Void_Type);
1900       Set_Enclosing_Scope (E, Current_Scope);
1901       Set_Reachable       (E, True);
1902    end Analyze_Label_Entity;
1903
1904    ----------------------------
1905    -- Analyze_Loop_Statement --
1906    ----------------------------
1907
1908    procedure Analyze_Loop_Statement (N : Node_Id) is
1909       Loop_Statement : constant Node_Id := N;
1910
1911       Id   : constant Node_Id := Identifier (Loop_Statement);
1912       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
1913       Ent  : Entity_Id;
1914
1915    begin
1916       if Present (Id) then
1917
1918          --  Make name visible, e.g. for use in exit statements. Loop
1919          --  labels are always considered to be referenced.
1920
1921          Analyze (Id);
1922          Ent := Entity (Id);
1923
1924          --  Guard against serious error (typically, a scope mismatch when
1925          --  semantic analysis is requested) by creating loop entity to
1926          --  continue analysis.
1927
1928          if No (Ent) then
1929             if Total_Errors_Detected /= 0 then
1930                Ent :=
1931                  New_Internal_Entity
1932                    (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
1933             else
1934                raise Program_Error;
1935             end if;
1936
1937          else
1938             Generate_Reference  (Ent, Loop_Statement, ' ');
1939             Generate_Definition (Ent);
1940
1941             --  If we found a label, mark its type. If not, ignore it, since it
1942             --  means we have a conflicting declaration, which would already
1943             --  have been diagnosed at declaration time. Set Label_Construct
1944             --  of the implicit label declaration, which is not created by the
1945             --  parser for generic units.
1946
1947             if Ekind (Ent) = E_Label then
1948                Set_Ekind (Ent, E_Loop);
1949
1950                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
1951                   Set_Label_Construct (Parent (Ent), Loop_Statement);
1952                end if;
1953             end if;
1954          end if;
1955
1956       --  Case of no identifier present
1957
1958       else
1959          Ent :=
1960            New_Internal_Entity
1961              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
1962          Set_Etype (Ent,  Standard_Void_Type);
1963          Set_Parent (Ent, Loop_Statement);
1964       end if;
1965
1966       --  Kill current values on entry to loop, since statements in body of
1967       --  loop may have been executed before the loop is entered. Similarly we
1968       --  kill values after the loop, since we do not know that the body of the
1969       --  loop was executed.
1970
1971       Kill_Current_Values;
1972       Push_Scope (Ent);
1973       Analyze_Iteration_Scheme (Iter);
1974       Analyze_Statements (Statements (Loop_Statement));
1975       Process_End_Label (Loop_Statement, 'e', Ent);
1976       End_Scope;
1977       Kill_Current_Values;
1978       Check_Infinite_Loop_Warning (N);
1979
1980       --  Code after loop is unreachable if the loop has no WHILE or FOR
1981       --  and contains no EXIT statements within the body of the loop.
1982
1983       if No (Iter) and then not Has_Exit (Ent) then
1984          Check_Unreachable_Code (N);
1985       end if;
1986    end Analyze_Loop_Statement;
1987
1988    ----------------------------
1989    -- Analyze_Null_Statement --
1990    ----------------------------
1991
1992    --  Note: the semantics of the null statement is implemented by a single
1993    --  null statement, too bad everything isn't as simple as this!
1994
1995    procedure Analyze_Null_Statement (N : Node_Id) is
1996       pragma Warnings (Off, N);
1997    begin
1998       null;
1999    end Analyze_Null_Statement;
2000
2001    ------------------------
2002    -- Analyze_Statements --
2003    ------------------------
2004
2005    procedure Analyze_Statements (L : List_Id) is
2006       S   : Node_Id;
2007       Lab : Entity_Id;
2008
2009    begin
2010       --  The labels declared in the statement list are reachable from
2011       --  statements in the list. We do this as a prepass so that any
2012       --  goto statement will be properly flagged if its target is not
2013       --  reachable. This is not required, but is nice behavior!
2014
2015       S := First (L);
2016       while Present (S) loop
2017          if Nkind (S) = N_Label then
2018             Analyze (Identifier (S));
2019             Lab := Entity (Identifier (S));
2020
2021             --  If we found a label mark it as reachable
2022
2023             if Ekind (Lab) = E_Label then
2024                Generate_Definition (Lab);
2025                Set_Reachable (Lab);
2026
2027                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
2028                   Set_Label_Construct (Parent (Lab), S);
2029                end if;
2030
2031             --  If we failed to find a label, it means the implicit declaration
2032             --  of the label was hidden.  A for-loop parameter can do this to
2033             --  a label with the same name inside the loop, since the implicit
2034             --  label declaration is in the innermost enclosing body or block
2035             --  statement.
2036
2037             else
2038                Error_Msg_Sloc := Sloc (Lab);
2039                Error_Msg_N
2040                  ("implicit label declaration for & is hidden#",
2041                   Identifier (S));
2042             end if;
2043          end if;
2044
2045          Next (S);
2046       end loop;
2047
2048       --  Perform semantic analysis on all statements
2049
2050       Conditional_Statements_Begin;
2051
2052       S := First (L);
2053       while Present (S) loop
2054          Analyze (S);
2055          Next (S);
2056       end loop;
2057
2058       Conditional_Statements_End;
2059
2060       --  Make labels unreachable. Visibility is not sufficient, because
2061       --  labels in one if-branch for example are not reachable from the
2062       --  other branch, even though their declarations are in the enclosing
2063       --  declarative part.
2064
2065       S := First (L);
2066       while Present (S) loop
2067          if Nkind (S) = N_Label then
2068             Set_Reachable (Entity (Identifier (S)), False);
2069          end if;
2070
2071          Next (S);
2072       end loop;
2073    end Analyze_Statements;
2074
2075    ----------------------------
2076    -- Check_Unreachable_Code --
2077    ----------------------------
2078
2079    procedure Check_Unreachable_Code (N : Node_Id) is
2080       Error_Loc : Source_Ptr;
2081       P         : Node_Id;
2082
2083    begin
2084       if Is_List_Member (N)
2085         and then Comes_From_Source (N)
2086       then
2087          declare
2088             Nxt : Node_Id;
2089
2090          begin
2091             Nxt := Original_Node (Next (N));
2092
2093             --  If a label follows us, then we never have dead code, since
2094             --  someone could branch to the label, so we just ignore it.
2095
2096             if Nkind (Nxt) = N_Label then
2097                return;
2098
2099             --  Otherwise see if we have a real statement following us
2100
2101             elsif Present (Nxt)
2102               and then Comes_From_Source (Nxt)
2103               and then Is_Statement (Nxt)
2104             then
2105                --  Special very annoying exception. If we have a return that
2106                --  follows a raise, then we allow it without a warning, since
2107                --  the Ada RM annoyingly requires a useless return here!
2108
2109                if Nkind (Original_Node (N)) /= N_Raise_Statement
2110                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2111                then
2112                   --  The rather strange shenanigans with the warning message
2113                   --  here reflects the fact that Kill_Dead_Code is very good
2114                   --  at removing warnings in deleted code, and this is one
2115                   --  warning we would prefer NOT to have removed.
2116
2117                   Error_Loc := Sloc (Nxt);
2118
2119                   --  If we have unreachable code, analyze and remove the
2120                   --  unreachable code, since it is useless and we don't
2121                   --  want to generate junk warnings.
2122
2123                   --  We skip this step if we are not in code generation mode.
2124                   --  This is the one case where we remove dead code in the
2125                   --  semantics as opposed to the expander, and we do not want
2126                   --  to remove code if we are not in code generation mode,
2127                   --  since this messes up the ASIS trees.
2128
2129                   --  Note that one might react by moving the whole circuit to
2130                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2131
2132                   if Operating_Mode = Generate_Code then
2133                      loop
2134                         Nxt := Next (N);
2135
2136                         --  Quit deleting when we have nothing more to delete
2137                         --  or if we hit a label (since someone could transfer
2138                         --  control to a label, so we should not delete it).
2139
2140                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2141
2142                         --  Statement/declaration is to be deleted
2143
2144                         Analyze (Nxt);
2145                         Remove (Nxt);
2146                         Kill_Dead_Code (Nxt);
2147                      end loop;
2148                   end if;
2149
2150                   --  Now issue the warning
2151
2152                   Error_Msg ("?unreachable code!", Error_Loc);
2153                end if;
2154
2155             --  If the unconditional transfer of control instruction is
2156             --  the last statement of a sequence, then see if our parent
2157             --  is one of the constructs for which we count unblocked exits,
2158             --  and if so, adjust the count.
2159
2160             else
2161                P := Parent (N);
2162
2163                --  Statements in THEN part or ELSE part of IF statement
2164
2165                if Nkind (P) = N_If_Statement then
2166                   null;
2167
2168                --  Statements in ELSIF part of an IF statement
2169
2170                elsif Nkind (P) = N_Elsif_Part then
2171                   P := Parent (P);
2172                   pragma Assert (Nkind (P) = N_If_Statement);
2173
2174                --  Statements in CASE statement alternative
2175
2176                elsif Nkind (P) = N_Case_Statement_Alternative then
2177                   P := Parent (P);
2178                   pragma Assert (Nkind (P) = N_Case_Statement);
2179
2180                --  Statements in body of block
2181
2182                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2183                  and then Nkind (Parent (P)) = N_Block_Statement
2184                then
2185                   null;
2186
2187                --  Statements in exception handler in a block
2188
2189                elsif Nkind (P) = N_Exception_Handler
2190                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2191                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2192                then
2193                   null;
2194
2195                --  None of these cases, so return
2196
2197                else
2198                   return;
2199                end if;
2200
2201                --  This was one of the cases we are looking for (i.e. the
2202                --  parent construct was IF, CASE or block) so decrement count.
2203
2204                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2205             end if;
2206          end;
2207       end if;
2208    end Check_Unreachable_Code;
2209
2210 end Sem_Ch5;