gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Checks;   use Checks;
  29 with Einfo;    use Einfo;
  30 with Errout;   use Errout;
  31 with Expander; use Expander;
  32 with Exp_Util; use Exp_Util;
  33 with Freeze;   use Freeze;
  34 with Lib.Xref; use Lib.Xref;
  35 with Nlists;   use Nlists;
  36 with Nmake;    use Nmake;
  37 with Opt;      use Opt;
  38 with Sem;      use Sem;
  39 with Sem_Case; use Sem_Case;
  40 with Sem_Ch3;  use Sem_Ch3;
  41 with Sem_Ch8;  use Sem_Ch8;
  42 with Sem_Disp; use Sem_Disp;
  43 with Sem_Eval; use Sem_Eval;
  44 with Sem_Res;  use Sem_Res;
  45 with Sem_Type; use Sem_Type;
  46 with Sem_Util; use Sem_Util;
  47 with Sem_Warn; use Sem_Warn;
  48 with Stand;    use Stand;
  49 with Sinfo;    use Sinfo;
  50 with Targparm; use Targparm;
  51 with Tbuild;   use Tbuild;
  52 with Uintp;    use Uintp;
  53
  54 package body Sem_Ch5 is
  55
  56    Unblocked_Exit_Count : Nat := 0;
  57    --  This variable is used when processing if statements, case statements,
  58    --  and block statements. It counts the number of exit points that are
  59    --  not blocked by unconditional transfer instructions (for IF and CASE,
  60    --  these are the branches of the conditional, for a block, they are the
  61    --  statement sequence of the block, and the statement sequences of any
  62    --  exception handlers that are part of the block. When processing is
  63    --  complete, if this count is zero, it means that control cannot fall
  64    --  through the IF, CASE or block statement. This is used for the
  65    --  generation of warning messages. This variable is recursively saved
  66    --  on entry to processing the construct, and restored on exit.
  67
  68    -----------------------
  69    -- Local Subprograms --
  70    -----------------------
  71
  72    procedure Analyze_Iteration_Scheme (N : Node_Id);
  73
  74    procedure Check_Possible_Current_Value_Condition (Cnode : Node_Id);
  75    --  Cnode is N_If_Statement, N_Elsif_Part, or N_Iteration_Scheme
  76    --  (the latter when a WHILE condition is present). This call checks
  77    --  if Condition (Cnode) is of the form ([NOT] var op val), where var
  78    --  is a simple object, val is known at compile time, and op is one
  79    --  of the six relational operators. If this is the case, and the
  80    --  Current_Value field of "var" is not set, then it is set to Cnode.
  81    --  See Exp_Util.Set_Current_Value_Condition for further details.
  82
  83    ------------------------
  84    -- Analyze_Assignment --
  85    ------------------------
  86
  87    procedure Analyze_Assignment (N : Node_Id) is
  88       Lhs  : constant Node_Id := Name (N);
  89       Rhs  : constant Node_Id := Expression (N);
  90       T1   : Entity_Id;
  91       T2   : Entity_Id;
  92       Decl : Node_Id;
  93       Ent  : Entity_Id;
  94
  95       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  96       --  N is the node for the left hand side of an assignment, and it
  97       --  is not a variable. This routine issues an appropriate diagnostic.
  98
  99       procedure Set_Assignment_Type
 100         (Opnd      : Node_Id;
 101          Opnd_Type : in out Entity_Id);
 102       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 103       --  is the nominal subtype. This procedure is used to deal with cases
 104       --  where the nominal subtype must be replaced by the actual subtype.
 105
 106       -------------------------------
 107       -- Diagnose_Non_Variable_Lhs --
 108       -------------------------------
 109
 110       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 111       begin
 112          --  Not worth posting another error if left hand side already
 113          --  flagged as being illegal in some respect
 114
 115          if Error_Posted (N) then
 116             return;
 117
 118          --  Some special bad cases of entity names
 119
 120          elsif Is_Entity_Name (N) then
 121             if Ekind (Entity (N)) = E_In_Parameter then
 122                Error_Msg_N
 123                  ("assignment to IN mode parameter not allowed", N);
 124
 125             --  Private declarations in a protected object are turned into
 126             --  constants when compiling a protected function.
 127
 128             elsif Present (Scope (Entity (N)))
 129               and then Is_Protected_Type (Scope (Entity (N)))
 130               and then
 131                 (Ekind (Current_Scope) = E_Function
 132                   or else
 133                  Ekind (Enclosing_Dynamic_Scope (Current_Scope)) = E_Function)
 134             then
 135                Error_Msg_N
 136                  ("protected function cannot modify protected object", N);
 137
 138             elsif Ekind (Entity (N)) = E_Loop_Parameter then
 139                Error_Msg_N
 140                  ("assignment to loop parameter not allowed", N);
 141
 142             else
 143                Error_Msg_N
 144                  ("left hand side of assignment must be a variable", N);
 145             end if;
 146
 147          --  For indexed components or selected components, test prefix
 148
 149          elsif Nkind (N) = N_Indexed_Component then
 150             Diagnose_Non_Variable_Lhs (Prefix (N));
 151
 152          --  Another special case for assignment to discriminant
 153
 154          elsif Nkind (N) = N_Selected_Component then
 155             if Present (Entity (Selector_Name (N)))
 156               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 157             then
 158                Error_Msg_N
 159                  ("assignment to discriminant not allowed", N);
 160             else
 161                Diagnose_Non_Variable_Lhs (Prefix (N));
 162             end if;
 163
 164          else
 165             --  If we fall through, we have no special message to issue!
 166
 167             Error_Msg_N ("left hand side of assignment must be a variable", N);
 168          end if;
 169       end Diagnose_Non_Variable_Lhs;
 170
 171       -------------------------
 172       -- Set_Assignment_Type --
 173       -------------------------
 174
 175       procedure Set_Assignment_Type
 176         (Opnd      : Node_Id;
 177          Opnd_Type : in out Entity_Id)
 178       is
 179       begin
 180          Require_Entity (Opnd);
 181
 182          --  If the assignment operand is an in-out or out parameter, then we
 183          --  get the actual subtype (needed for the unconstrained case).
 184          --  If the operand is the actual in an entry declaration, then within
 185          --  the accept statement it is replaced with a local renaming, which
 186          --  may also have an actual subtype.
 187
 188          if Is_Entity_Name (Opnd)
 189            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 190                       or else Ekind (Entity (Opnd)) =
 191                            E_In_Out_Parameter
 192                       or else Ekind (Entity (Opnd)) =
 193                            E_Generic_In_Out_Parameter
 194                       or else
 195                         (Ekind (Entity (Opnd)) = E_Variable
 196                           and then Nkind (Parent (Entity (Opnd))) =
 197                              N_Object_Renaming_Declaration
 198                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 199                              N_Accept_Statement))
 200          then
 201             Opnd_Type := Get_Actual_Subtype (Opnd);
 202
 203          --  If assignment operand is a component reference, then we get the
 204          --  actual subtype of the component for the unconstrained case.
 205
 206          elsif
 207            (Nkind (Opnd) = N_Selected_Component
 208              or else Nkind (Opnd) = N_Explicit_Dereference)
 209            and then not Is_Unchecked_Union (Opnd_Type)
 210          then
 211             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 212
 213             if Present (Decl) then
 214                Insert_Action (N, Decl);
 215                Mark_Rewrite_Insertion (Decl);
 216                Analyze (Decl);
 217                Opnd_Type := Defining_Identifier (Decl);
 218                Set_Etype (Opnd, Opnd_Type);
 219                Freeze_Itype (Opnd_Type, N);
 220
 221             elsif Is_Constrained (Etype (Opnd)) then
 222                Opnd_Type := Etype (Opnd);
 223             end if;
 224
 225          --  For slice, use the constrained subtype created for the slice
 226
 227          elsif Nkind (Opnd) = N_Slice then
 228             Opnd_Type := Etype (Opnd);
 229          end if;
 230       end Set_Assignment_Type;
 231
 232    --  Start of processing for Analyze_Assignment
 233
 234    begin
 235       Analyze (Rhs);
 236       Analyze (Lhs);
 237       T1 := Etype (Lhs);
 238
 239       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 240       --  must compute the intersection of the possible types on each side.
 241
 242       if Is_Overloaded (Lhs) then
 243          declare
 244             I  : Interp_Index;
 245             It : Interp;
 246
 247          begin
 248             T1 := Any_Type;
 249             Get_First_Interp (Lhs, I, It);
 250
 251             while Present (It.Typ) loop
 252                if Has_Compatible_Type (Rhs, It.Typ) then
 253                   if T1 /= Any_Type then
 254
 255                      --  An explicit dereference is overloaded if the prefix
 256                      --  is. Try to remove the ambiguity on the prefix, the
 257                      --  error will be posted there if the ambiguity is real.
 258
 259                      if Nkind (Lhs) = N_Explicit_Dereference then
 260                         declare
 261                            PI    : Interp_Index;
 262                            PI1   : Interp_Index := 0;
 263                            PIt   : Interp;
 264                            Found : Boolean;
 265
 266                         begin
 267                            Found := False;
 268                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 269
 270                            while Present (PIt.Typ) loop
 271                               if Is_Access_Type (PIt.Typ)
 272                                 and then Has_Compatible_Type
 273                                            (Rhs, Designated_Type (PIt.Typ))
 274                               then
 275                                  if Found then
 276                                     PIt :=
 277                                       Disambiguate (Prefix (Lhs),
 278                                         PI1, PI, Any_Type);
 279
 280                                     if PIt = No_Interp then
 281                                        Error_Msg_N
 282                                          ("ambiguous left-hand side"
 283                                             & " in assignment", Lhs);
 284                                        exit;
 285                                     else
 286                                        Resolve (Prefix (Lhs), PIt.Typ);
 287                                     end if;
 288
 289                                     exit;
 290                                  else
 291                                     Found := True;
 292                                     PI1 := PI;
 293                                  end if;
 294                               end if;
 295
 296                               Get_Next_Interp (PI, PIt);
 297                            end loop;
 298                         end;
 299
 300                      else
 301                         Error_Msg_N
 302                           ("ambiguous left-hand side in assignment", Lhs);
 303                         exit;
 304                      end if;
 305                   else
 306                      T1 := It.Typ;
 307                   end if;
 308                end if;
 309
 310                Get_Next_Interp (I, It);
 311             end loop;
 312          end;
 313
 314          if T1 = Any_Type then
 315             Error_Msg_N
 316               ("no valid types for left-hand side for assignment", Lhs);
 317             return;
 318          end if;
 319       end if;
 320
 321       Resolve (Lhs, T1);
 322
 323       if not Is_Variable (Lhs) then
 324          Diagnose_Non_Variable_Lhs (Lhs);
 325          return;
 326
 327       elsif Is_Limited_Type (T1)
 328         and then not Assignment_OK (Lhs)
 329         and then not Assignment_OK (Original_Node (Lhs))
 330       then
 331          Error_Msg_N
 332            ("left hand of assignment must not be limited type", Lhs);
 333          Explain_Limited_Type (T1, Lhs);
 334          return;
 335       end if;
 336
 337       --  Resolution may have updated the subtype, in case the left-hand
 338       --  side is a private protected component. Use the correct subtype
 339       --  to avoid scoping issues in the back-end.
 340
 341       T1 := Etype (Lhs);
 342       Set_Assignment_Type (Lhs, T1);
 343
 344       Resolve (Rhs, T1);
 345       Check_Unset_Reference (Rhs);
 346
 347       --  Remaining steps are skipped if Rhs was syntactically in error
 348
 349       if Rhs = Error then
 350          return;
 351       end if;
 352
 353       T2 := Etype (Rhs);
 354
 355       if Covers (T1, T2) then
 356          null;
 357       else
 358          Wrong_Type (Rhs, Etype (Lhs));
 359          return;
 360       end if;
 361
 362       Set_Assignment_Type (Rhs, T2);
 363
 364       if Total_Errors_Detected /= 0 then
 365          if No (T1) then
 366             T1 := Any_Type;
 367          end if;
 368
 369          if No (T2) then
 370             T2 := Any_Type;
 371          end if;
 372       end if;
 373
 374       if T1 = Any_Type or else T2 = Any_Type then
 375          return;
 376       end if;
 377
 378       if (Is_Class_Wide_Type (T2) or else Is_Dynamically_Tagged (Rhs))
 379         and then not Is_Class_Wide_Type (T1)
 380       then
 381          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 382
 383       elsif Is_Class_Wide_Type (T1)
 384         and then not Is_Class_Wide_Type (T2)
 385         and then not Is_Tag_Indeterminate (Rhs)
 386         and then not Is_Dynamically_Tagged (Rhs)
 387       then
 388          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 389       end if;
 390
 391       --  Tag propagation is done only in semantics mode only. If expansion
 392       --  is on, the rhs tag indeterminate function call has been expanded
 393       --  and tag propagation would have happened too late, so the
 394       --  propagation take place in expand_call instead.
 395
 396       if not Expander_Active
 397         and then Is_Class_Wide_Type (T1)
 398         and then Is_Tag_Indeterminate (Rhs)
 399       then
 400          Propagate_Tag (Lhs, Rhs);
 401       end if;
 402
 403       --  Ada 2005 (AI-231)
 404
 405       if Ada_Version >= Ada_05
 406         and then Nkind (Rhs) = N_Null
 407         and then Is_Access_Type (T1)
 408         and then not Assignment_OK (Lhs)
 409         and then ((Is_Entity_Name (Lhs)
 410                      and then Can_Never_Be_Null (Entity (Lhs)))
 411                    or else Can_Never_Be_Null (Etype (Lhs)))
 412       then
 413          Apply_Compile_Time_Constraint_Error
 414            (N      => Lhs,
 415             Msg    => "(Ada 2005) NULL not allowed in null-excluding objects?",
 416             Reason => CE_Null_Not_Allowed);
 417       end if;
 418
 419       if Is_Scalar_Type (T1) then
 420          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 421
 422       elsif Is_Array_Type (T1)
 423         and then
 424           (Nkind (Rhs) /= N_Type_Conversion
 425              or else Is_Constrained (Etype (Rhs)))
 426       then
 427          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 428          --  but of course the indices do not have to match. If the right-hand
 429          --  side is a type conversion to an unconstrained type, a length check
 430          --  is performed on the expression itself during expansion. In rare
 431          --  cases, the redundant length check is computed on an index type
 432          --  with a different representation, triggering incorrect code in
 433          --  the back end.
 434
 435          Apply_Length_Check (Rhs, Etype (Lhs));
 436
 437       else
 438          --  Discriminant checks are applied in the course of expansion
 439
 440          null;
 441       end if;
 442
 443       --  Note: modifications of the Lhs may only be recorded after
 444       --  checks have been applied.
 445
 446       Note_Possible_Modification (Lhs);
 447
 448       --  ??? a real accessibility check is needed when ???
 449
 450       --  Post warning for useless assignment
 451
 452       if Warn_On_Redundant_Constructs
 453
 454          --  We only warn for source constructs
 455
 456          and then Comes_From_Source (N)
 457
 458          --  Where the entity is the same on both sides
 459
 460          and then Is_Entity_Name (Lhs)
 461          and then Is_Entity_Name (Original_Node (Rhs))
 462          and then Entity (Lhs) = Entity (Original_Node (Rhs))
 463
 464          --  But exclude the case where the right side was an operation
 465          --  that got rewritten (e.g. JUNK + K, where K was known to be
 466          --  zero). We don't want to warn in such a case, since it is
 467          --  reasonable to write such expressions especially when K is
 468          --  defined symbolically in some other package.
 469
 470         and then Nkind (Original_Node (Rhs)) not in N_Op
 471       then
 472          Error_Msg_NE
 473            ("?useless assignment of & to itself", N, Entity (Lhs));
 474       end if;
 475
 476       --  Check for non-allowed composite assignment
 477
 478       if not Support_Composite_Assign_On_Target
 479         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 480         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 481       then
 482          Error_Msg_CRT ("composite assignment", N);
 483       end if;
 484
 485       --  One more step. Let's see if we have a simple assignment of a
 486       --  known at compile time value to a simple variable. If so, we
 487       --  can record the value as the current value providing that:
 488
 489       --    We still have a simple assignment statement (no expansion
 490       --    activity has modified it in some peculiar manner)
 491
 492       --    The type is a discrete type
 493
 494       --    The assignment is to a named entity
 495
 496       --    The value is known at compile time
 497
 498       if Nkind (N) /= N_Assignment_Statement
 499         or else not Is_Discrete_Type (T1)
 500         or else not Is_Entity_Name (Lhs)
 501         or else not Compile_Time_Known_Value (Rhs)
 502       then
 503          return;
 504       end if;
 505
 506       Ent := Entity (Lhs);
 507
 508       --  Capture value if save to do so
 509
 510       if Safe_To_Capture_Value (N, Ent) then
 511          Set_Current_Value (Ent, Rhs);
 512       end if;
 513    end Analyze_Assignment;
 514
 515    -----------------------------
 516    -- Analyze_Block_Statement --
 517    -----------------------------
 518
 519    procedure Analyze_Block_Statement (N : Node_Id) is
 520       Decls : constant List_Id := Declarations (N);
 521       Id    : constant Node_Id := Identifier (N);
 522       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 523
 524    begin
 525       --  If no handled statement sequence is present, things are really
 526       --  messed up, and we just return immediately (this is a defence
 527       --  against previous errors).
 528
 529       if No (HSS) then
 530          return;
 531       end if;
 532
 533       --  Normal processing with HSS present
 534
 535       declare
 536          EH  : constant List_Id := Exception_Handlers (HSS);
 537          Ent : Entity_Id        := Empty;
 538          S   : Entity_Id;
 539
 540          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 541          --  Recursively save value of this global, will be restored on exit
 542
 543       begin
 544          --  Initialize unblocked exit count for statements of begin block
 545          --  plus one for each excption handler that is present.
 546
 547          Unblocked_Exit_Count := 1;
 548
 549          if Present (EH) then
 550             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 551          end if;
 552
 553          --  If a label is present analyze it and mark it as referenced
 554
 555          if Present (Id) then
 556             Analyze (Id);
 557             Ent := Entity (Id);
 558
 559             --  An error defense. If we have an identifier, but no entity,
 560             --  then something is wrong. If we have previous errors, then
 561             --  just remove the identifier and continue, otherwise raise
 562             --  an exception.
 563
 564             if No (Ent) then
 565                if Total_Errors_Detected /= 0 then
 566                   Set_Identifier (N, Empty);
 567                else
 568                   raise Program_Error;
 569                end if;
 570
 571             else
 572                Set_Ekind (Ent, E_Block);
 573                Generate_Reference (Ent, N, ' ');
 574                Generate_Definition (Ent);
 575
 576                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 577                   Set_Label_Construct (Parent (Ent), N);
 578                end if;
 579             end if;
 580          end if;
 581
 582          --  If no entity set, create a label entity
 583
 584          if No (Ent) then
 585             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 586             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 587             Set_Parent (Ent, N);
 588          end if;
 589
 590          Set_Etype (Ent, Standard_Void_Type);
 591          Set_Block_Node (Ent, Identifier (N));
 592          New_Scope (Ent);
 593
 594          if Present (Decls) then
 595             Analyze_Declarations (Decls);
 596             Check_Completion;
 597          end if;
 598
 599          Analyze (HSS);
 600          Process_End_Label (HSS, 'e', Ent);
 601
 602          --  If exception handlers are present, then we indicate that
 603          --  enclosing scopes contain a block with handlers. We only
 604          --  need to mark non-generic scopes.
 605
 606          if Present (EH) then
 607             S := Scope (Ent);
 608             loop
 609                Set_Has_Nested_Block_With_Handler (S);
 610                exit when Is_Overloadable (S)
 611                  or else Ekind (S) = E_Package
 612                  or else Is_Generic_Unit (S);
 613                S := Scope (S);
 614             end loop;
 615          end if;
 616
 617          Check_References (Ent);
 618          End_Scope;
 619
 620          if Unblocked_Exit_Count = 0 then
 621             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 622             Check_Unreachable_Code (N);
 623          else
 624             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 625          end if;
 626       end;
 627    end Analyze_Block_Statement;
 628
 629    ----------------------------
 630    -- Analyze_Case_Statement --
 631    ----------------------------
 632
 633    procedure Analyze_Case_Statement (N : Node_Id) is
 634       Exp            : Node_Id;
 635       Exp_Type       : Entity_Id;
 636       Exp_Btype      : Entity_Id;
 637       Last_Choice    : Nat;
 638       Dont_Care      : Boolean;
 639       Others_Present : Boolean;
 640
 641       Statements_Analyzed : Boolean := False;
 642       --  Set True if at least some statement sequences get analyzed.
 643       --  If False on exit, means we had a serious error that prevented
 644       --  full analysis of the case statement, and as a result it is not
 645       --  a good idea to output warning messages about unreachable code.
 646
 647       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 648       --  Recursively save value of this global, will be restored on exit
 649
 650       procedure Non_Static_Choice_Error (Choice : Node_Id);
 651       --  Error routine invoked by the generic instantiation below when
 652       --  the case statment has a non static choice.
 653
 654       procedure Process_Statements (Alternative : Node_Id);
 655       --  Analyzes all the statements associated to a case alternative.
 656       --  Needed by the generic instantiation below.
 657
 658       package Case_Choices_Processing is new
 659         Generic_Choices_Processing
 660           (Get_Alternatives          => Alternatives,
 661            Get_Choices               => Discrete_Choices,
 662            Process_Empty_Choice      => No_OP,
 663            Process_Non_Static_Choice => Non_Static_Choice_Error,
 664            Process_Associated_Node   => Process_Statements);
 665       use Case_Choices_Processing;
 666       --  Instantiation of the generic choice processing package
 667
 668       -----------------------------
 669       -- Non_Static_Choice_Error --
 670       -----------------------------
 671
 672       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 673       begin
 674          Flag_Non_Static_Expr
 675            ("choice given in case statement is not static!", Choice);
 676       end Non_Static_Choice_Error;
 677
 678       ------------------------
 679       -- Process_Statements --
 680       ------------------------
 681
 682       procedure Process_Statements (Alternative : Node_Id) is
 683          Choices : constant List_Id := Discrete_Choices (Alternative);
 684          Ent     : Entity_Id;
 685
 686       begin
 687          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 688          Statements_Analyzed := True;
 689
 690          --  An interesting optimization. If the case statement expression
 691          --  is a simple entity, then we can set the current value within
 692          --  an alternative if the alternative has one possible value.
 693
 694          --    case N is
 695          --      when 1      => alpha
 696          --      when 2 | 3  => beta
 697          --      when others => gamma
 698
 699          --  Here we know that N is initially 1 within alpha, but for beta
 700          --  and gamma, we do not know anything more about the initial value.
 701
 702          if Is_Entity_Name (Exp) then
 703             Ent := Entity (Exp);
 704
 705             if Ekind (Ent) = E_Variable
 706                  or else
 707                Ekind (Ent) = E_In_Out_Parameter
 708                  or else
 709                Ekind (Ent) = E_Out_Parameter
 710             then
 711                if List_Length (Choices) = 1
 712                  and then Nkind (First (Choices)) in N_Subexpr
 713                  and then Compile_Time_Known_Value (First (Choices))
 714                then
 715                   Set_Current_Value (Entity (Exp), First (Choices));
 716                end if;
 717
 718                Analyze_Statements (Statements (Alternative));
 719
 720                --  After analyzing the case, set the current value to empty
 721                --  since we won't know what it is for the next alternative
 722                --  (unless reset by this same circuit), or after the case.
 723
 724                Set_Current_Value (Entity (Exp), Empty);
 725                return;
 726             end if;
 727          end if;
 728
 729          --  Case where expression is not an entity name of a variable
 730
 731          Analyze_Statements (Statements (Alternative));
 732       end Process_Statements;
 733
 734       --  Table to record choices. Put after subprograms since we make
 735       --  a call to Number_Of_Choices to get the right number of entries.
 736
 737       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
 738
 739    --  Start of processing for Analyze_Case_Statement
 740
 741    begin
 742       Unblocked_Exit_Count := 0;
 743       Exp := Expression (N);
 744       Analyze_And_Resolve (Exp, Any_Discrete);
 745       Check_Unset_Reference (Exp);
 746       Exp_Type  := Etype (Exp);
 747       Exp_Btype := Base_Type (Exp_Type);
 748
 749       --  The expression must be of a discrete type which must be determinable
 750       --  independently of the context in which the expression occurs, but
 751       --  using the fact that the expression must be of a discrete type.
 752       --  Moreover, the type this expression must not be a character literal
 753       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
 754
 755       --  If error already reported by Resolve, nothing more to do
 756
 757       if Exp_Btype = Any_Discrete
 758         or else Exp_Btype = Any_Type
 759       then
 760          return;
 761
 762       elsif Exp_Btype = Any_Character then
 763          Error_Msg_N
 764            ("character literal as case expression is ambiguous", Exp);
 765          return;
 766
 767       elsif Ada_Version = Ada_83
 768         and then (Is_Generic_Type (Exp_Btype)
 769                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
 770       then
 771          Error_Msg_N
 772            ("(Ada 83) case expression cannot be of a generic type", Exp);
 773          return;
 774       end if;
 775
 776       --  If the case expression is a formal object of mode in out, then
 777       --  treat it as having a nonstatic subtype by forcing use of the base
 778       --  type (which has to get passed to Check_Case_Choices below).  Also
 779       --  use base type when the case expression is parenthesized.
 780
 781       if Paren_Count (Exp) > 0
 782         or else (Is_Entity_Name (Exp)
 783                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
 784       then
 785          Exp_Type := Exp_Btype;
 786       end if;
 787
 788       --  Call instantiated Analyze_Choices which does the rest of the work
 789
 790       Analyze_Choices
 791         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
 792
 793       if Exp_Type = Universal_Integer and then not Others_Present then
 794          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
 795       end if;
 796
 797       --  If all our exits were blocked by unconditional transfers of control,
 798       --  then the entire CASE statement acts as an unconditional transfer of
 799       --  control, so treat it like one, and check unreachable code. Skip this
 800       --  test if we had serious errors preventing any statement analysis.
 801
 802       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
 803          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 804          Check_Unreachable_Code (N);
 805       else
 806          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 807       end if;
 808
 809       if not Expander_Active
 810         and then Compile_Time_Known_Value (Expression (N))
 811         and then Serious_Errors_Detected = 0
 812       then
 813          declare
 814             Chosen : constant Node_Id := Find_Static_Alternative (N);
 815             Alt    : Node_Id;
 816
 817          begin
 818             Alt := First (Alternatives (N));
 819
 820             while Present (Alt) loop
 821                if Alt /= Chosen then
 822                   Remove_Warning_Messages (Statements (Alt));
 823                end if;
 824
 825                Next (Alt);
 826             end loop;
 827          end;
 828       end if;
 829    end Analyze_Case_Statement;
 830
 831    ----------------------------
 832    -- Analyze_Exit_Statement --
 833    ----------------------------
 834
 835    --  If the exit includes a name, it must be the name of a currently open
 836    --  loop. Otherwise there must be an innermost open loop on the stack,
 837    --  to which the statement implicitly refers.
 838
 839    procedure Analyze_Exit_Statement (N : Node_Id) is
 840       Target   : constant Node_Id := Name (N);
 841       Cond     : constant Node_Id := Condition (N);
 842       Scope_Id : Entity_Id;
 843       U_Name   : Entity_Id;
 844       Kind     : Entity_Kind;
 845
 846    begin
 847       if No (Cond) then
 848          Check_Unreachable_Code (N);
 849       end if;
 850
 851       if Present (Target) then
 852          Analyze (Target);
 853          U_Name := Entity (Target);
 854
 855          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
 856             Error_Msg_N ("invalid loop name in exit statement", N);
 857             return;
 858          else
 859             Set_Has_Exit (U_Name);
 860          end if;
 861
 862       else
 863          U_Name := Empty;
 864       end if;
 865
 866       for J in reverse 0 .. Scope_Stack.Last loop
 867          Scope_Id := Scope_Stack.Table (J).Entity;
 868          Kind := Ekind (Scope_Id);
 869
 870          if Kind = E_Loop
 871            and then (No (Target) or else Scope_Id = U_Name) then
 872             Set_Has_Exit (Scope_Id);
 873             exit;
 874
 875          elsif Kind = E_Block or else Kind = E_Loop then
 876             null;
 877
 878          else
 879             Error_Msg_N
 880               ("cannot exit from program unit or accept statement", N);
 881             exit;
 882          end if;
 883       end loop;
 884
 885       --  Verify that if present the condition is a Boolean expression
 886
 887       if Present (Cond) then
 888          Analyze_And_Resolve (Cond, Any_Boolean);
 889          Check_Unset_Reference (Cond);
 890       end if;
 891    end Analyze_Exit_Statement;
 892
 893    ----------------------------
 894    -- Analyze_Goto_Statement --
 895    ----------------------------
 896
 897    procedure Analyze_Goto_Statement (N : Node_Id) is
 898       Label       : constant Node_Id := Name (N);
 899       Scope_Id    : Entity_Id;
 900       Label_Scope : Entity_Id;
 901
 902    begin
 903       Check_Unreachable_Code (N);
 904
 905       Analyze (Label);
 906
 907       if Entity (Label) = Any_Id then
 908          return;
 909
 910       elsif Ekind (Entity (Label)) /= E_Label then
 911          Error_Msg_N ("target of goto statement must be a label", Label);
 912          return;
 913
 914       elsif not Reachable (Entity (Label)) then
 915          Error_Msg_N ("target of goto statement is not reachable", Label);
 916          return;
 917       end if;
 918
 919       Label_Scope := Enclosing_Scope (Entity (Label));
 920
 921       for J in reverse 0 .. Scope_Stack.Last loop
 922          Scope_Id := Scope_Stack.Table (J).Entity;
 923
 924          if Label_Scope = Scope_Id
 925            or else (Ekind (Scope_Id) /= E_Block
 926                      and then Ekind (Scope_Id) /= E_Loop)
 927          then
 928             if Scope_Id /= Label_Scope then
 929                Error_Msg_N
 930                  ("cannot exit from program unit or accept statement", N);
 931             end if;
 932
 933             return;
 934          end if;
 935       end loop;
 936
 937       raise Program_Error;
 938    end Analyze_Goto_Statement;
 939
 940    --------------------------
 941    -- Analyze_If_Statement --
 942    --------------------------
 943
 944    --  A special complication arises in the analysis of if statements
 945
 946    --  The expander has circuitry to completely delete code that it
 947    --  can tell will not be executed (as a result of compile time known
 948    --  conditions). In the analyzer, we ensure that code that will be
 949    --  deleted in this manner is analyzed but not expanded. This is
 950    --  obviously more efficient, but more significantly, difficulties
 951    --  arise if code is expanded and then eliminated (e.g. exception
 952    --  table entries disappear). Similarly, itypes generated in deleted
 953    --  code must be frozen from start, because the nodes on which they
 954    --  depend will not be available at the freeze point.
 955
 956    procedure Analyze_If_Statement (N : Node_Id) is
 957       E : Node_Id;
 958
 959       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 960       --  Recursively save value of this global, will be restored on exit
 961
 962       Save_In_Deleted_Code : Boolean;
 963
 964       Del : Boolean := False;
 965       --  This flag gets set True if a True condition has been found,
 966       --  which means that remaining ELSE/ELSIF parts are deleted.
 967
 968       procedure Analyze_Cond_Then (Cnode : Node_Id);
 969       --  This is applied to either the N_If_Statement node itself or
 970       --  to an N_Elsif_Part node. It deals with analyzing the condition
 971       --  and the THEN statements associated with it.
 972
 973       -----------------------
 974       -- Analyze_Cond_Then --
 975       -----------------------
 976
 977       procedure Analyze_Cond_Then (Cnode : Node_Id) is
 978          Cond : constant Node_Id := Condition (Cnode);
 979          Tstm : constant List_Id := Then_Statements (Cnode);
 980
 981       begin
 982          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 983          Analyze_And_Resolve (Cond, Any_Boolean);
 984          Check_Unset_Reference (Cond);
 985          Check_Possible_Current_Value_Condition (Cnode);
 986
 987          --  If already deleting, then just analyze then statements
 988
 989          if Del then
 990             Analyze_Statements (Tstm);
 991
 992          --  Compile time known value, not deleting yet
 993
 994          elsif Compile_Time_Known_Value (Cond) then
 995             Save_In_Deleted_Code := In_Deleted_Code;
 996
 997             --  If condition is True, then analyze the THEN statements
 998             --  and set no expansion for ELSE and ELSIF parts.
 999
1000             if Is_True (Expr_Value (Cond)) then
1001                Analyze_Statements (Tstm);
1002                Del := True;
1003                Expander_Mode_Save_And_Set (False);
1004                In_Deleted_Code := True;
1005
1006             --  If condition is False, analyze THEN with expansion off
1007
1008             else -- Is_False (Expr_Value (Cond))
1009                Expander_Mode_Save_And_Set (False);
1010                In_Deleted_Code := True;
1011                Analyze_Statements (Tstm);
1012                Expander_Mode_Restore;
1013                In_Deleted_Code := Save_In_Deleted_Code;
1014             end if;
1015
1016          --  Not known at compile time, not deleting, normal analysis
1017
1018          else
1019             Analyze_Statements (Tstm);
1020          end if;
1021       end Analyze_Cond_Then;
1022
1023    --  Start of Analyze_If_Statement
1024
1025    begin
1026       --  Initialize exit count for else statements. If there is no else
1027       --  part, this count will stay non-zero reflecting the fact that the
1028       --  uncovered else case is an unblocked exit.
1029
1030       Unblocked_Exit_Count := 1;
1031       Analyze_Cond_Then (N);
1032
1033       --  Now to analyze the elsif parts if any are present
1034
1035       if Present (Elsif_Parts (N)) then
1036          E := First (Elsif_Parts (N));
1037          while Present (E) loop
1038             Analyze_Cond_Then (E);
1039             Next (E);
1040          end loop;
1041       end if;
1042
1043       if Present (Else_Statements (N)) then
1044          Analyze_Statements (Else_Statements (N));
1045       end if;
1046
1047       --  If all our exits were blocked by unconditional transfers of control,
1048       --  then the entire IF statement acts as an unconditional transfer of
1049       --  control, so treat it like one, and check unreachable code.
1050
1051       if Unblocked_Exit_Count = 0 then
1052          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1053          Check_Unreachable_Code (N);
1054       else
1055          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1056       end if;
1057
1058       if Del then
1059          Expander_Mode_Restore;
1060          In_Deleted_Code := Save_In_Deleted_Code;
1061       end if;
1062
1063       if not Expander_Active
1064         and then Compile_Time_Known_Value (Condition (N))
1065         and then Serious_Errors_Detected = 0
1066       then
1067          if Is_True (Expr_Value (Condition (N))) then
1068             Remove_Warning_Messages (Else_Statements (N));
1069
1070             if Present (Elsif_Parts (N)) then
1071                E := First (Elsif_Parts (N));
1072
1073                while Present (E) loop
1074                   Remove_Warning_Messages (Then_Statements (E));
1075                   Next (E);
1076                end loop;
1077             end if;
1078
1079          else
1080             Remove_Warning_Messages (Then_Statements (N));
1081          end if;
1082       end if;
1083    end Analyze_If_Statement;
1084
1085    ----------------------------------------
1086    -- Analyze_Implicit_Label_Declaration --
1087    ----------------------------------------
1088
1089    --  An implicit label declaration is generated in the innermost
1090    --  enclosing declarative part. This is done for labels as well as
1091    --  block and loop names.
1092
1093    --  Note: any changes in this routine may need to be reflected in
1094    --  Analyze_Label_Entity.
1095
1096    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1097       Id : constant Node_Id := Defining_Identifier (N);
1098    begin
1099       Enter_Name          (Id);
1100       Set_Ekind           (Id, E_Label);
1101       Set_Etype           (Id, Standard_Void_Type);
1102       Set_Enclosing_Scope (Id, Current_Scope);
1103    end Analyze_Implicit_Label_Declaration;
1104
1105    ------------------------------
1106    -- Analyze_Iteration_Scheme --
1107    ------------------------------
1108
1109    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1110
1111       procedure Process_Bounds (R : Node_Id);
1112       --  If the iteration is given by a range, create temporaries and
1113       --  assignment statements block to capture the bounds and perform
1114       --  required finalization actions in case a bound includes a function
1115       --  call that uses the temporary stack. We first pre-analyze a copy of
1116       --  the range in order to determine the expected type, and analyze
1117       --  and resolve the original bounds.
1118
1119       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1120       --  If the bounds are given by a 'Range reference on a function call
1121       --  that returns a controlled array, introduce an explicit declaration
1122       --  to capture the bounds, so that the function result can be finalized
1123       --  in timely fashion.
1124
1125       --------------------
1126       -- Process_Bounds --
1127       --------------------
1128
1129       procedure Process_Bounds (R : Node_Id) is
1130          Loc          : constant Source_Ptr := Sloc (N);
1131          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1132          Lo           : constant Node_Id := Low_Bound  (R);
1133          Hi           : constant Node_Id := High_Bound (R);
1134          New_Lo_Bound : Node_Id := Empty;
1135          New_Hi_Bound : Node_Id := Empty;
1136          Typ          : Entity_Id;
1137
1138          function One_Bound
1139            (Original_Bound : Node_Id;
1140             Analyzed_Bound : Node_Id) return Node_Id;
1141          --  Create one declaration followed by one assignment statement
1142          --  to capture the value of bound. We create a separate assignment
1143          --  in order to force the creation of a block in case the bound
1144          --  contains a call that uses the secondary stack.
1145
1146          ---------------
1147          -- One_Bound --
1148          ---------------
1149
1150          function One_Bound
1151            (Original_Bound : Node_Id;
1152             Analyzed_Bound : Node_Id) return Node_Id
1153          is
1154             Assign   : Node_Id;
1155             Id       : Entity_Id;
1156             Decl     : Node_Id;
1157             Decl_Typ : Entity_Id;
1158
1159          begin
1160             --  If the bound is a constant or an object, no need for a
1161             --  separate declaration. If the bound is the result of previous
1162             --  expansion it is already analyzed and should not be modified.
1163             --  Note that the Bound will be resolved later, if needed, as
1164             --  part of the call to Make_Index (literal bounds may need to
1165             --  be resolved to type Integer).
1166
1167             if Analyzed (Original_Bound) then
1168                return Original_Bound;
1169
1170             elsif Nkind (Analyzed_Bound) = N_Integer_Literal
1171               or else Is_Entity_Name (Analyzed_Bound)
1172             then
1173                Analyze_And_Resolve (Original_Bound, Typ);
1174                return Original_Bound;
1175
1176             else
1177                Analyze_And_Resolve (Original_Bound, Typ);
1178             end if;
1179
1180             Id :=
1181               Make_Defining_Identifier (Loc,
1182                 Chars => New_Internal_Name ('S'));
1183
1184             --  If the type of the discrete range is Universal_Integer, then
1185             --  the bound's type must be resolved to Integer, so the object
1186             --  used to hold the bound must also have type Integer.
1187
1188             if Typ = Universal_Integer then
1189                Decl_Typ := Standard_Integer;
1190             else
1191                Decl_Typ := Typ;
1192             end if;
1193
1194             Decl :=
1195               Make_Object_Declaration (Loc,
1196                 Defining_Identifier => Id,
1197                 Object_Definition   => New_Occurrence_Of (Decl_Typ, Loc));
1198
1199             Insert_Before (Parent (N), Decl);
1200             Analyze (Decl);
1201
1202             Assign :=
1203               Make_Assignment_Statement (Loc,
1204                 Name        => New_Occurrence_Of (Id, Loc),
1205                 Expression  => Relocate_Node (Original_Bound));
1206
1207             Insert_Before (Parent (N), Assign);
1208             Analyze (Assign);
1209
1210             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1211
1212             if Nkind (Assign) = N_Assignment_Statement then
1213                return Expression (Assign);
1214             else
1215                return Original_Bound;
1216             end if;
1217          end One_Bound;
1218
1219       --  Start of processing for Process_Bounds
1220
1221       begin
1222          --  Determine expected type of range by analyzing separate copy.
1223
1224          Set_Parent (R_Copy, Parent (R));
1225          Pre_Analyze_And_Resolve (R_Copy);
1226          Typ := Etype (R_Copy);
1227          Set_Etype (R, Typ);
1228
1229          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1230          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1231
1232          --  Propagate staticness to loop range itself, in case the
1233          --  corresponding subtype is static.
1234
1235          if New_Lo_Bound /= Lo
1236            and then Is_Static_Expression (New_Lo_Bound)
1237          then
1238             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1239          end if;
1240
1241          if New_Hi_Bound /= Hi
1242            and then Is_Static_Expression (New_Hi_Bound)
1243          then
1244             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1245          end if;
1246       end Process_Bounds;
1247
1248       --------------------------------------
1249       -- Check_Controlled_Array_Attribute --
1250       --------------------------------------
1251
1252       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1253       begin
1254          if Nkind (DS) = N_Attribute_Reference
1255             and then Is_Entity_Name (Prefix (DS))
1256             and then Ekind (Entity (Prefix (DS))) = E_Function
1257             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1258             and then
1259               Is_Controlled (
1260                 Component_Type (Etype (Entity (Prefix (DS)))))
1261             and then Expander_Active
1262          then
1263             declare
1264                Loc  : constant Source_Ptr := Sloc (N);
1265                Arr  : constant Entity_Id :=
1266                         Etype (Entity (Prefix (DS)));
1267                Indx : constant Entity_Id :=
1268                         Base_Type (Etype (First_Index (Arr)));
1269                Subt : constant Entity_Id :=
1270                         Make_Defining_Identifier
1271                           (Loc, New_Internal_Name ('S'));
1272                Decl : Node_Id;
1273
1274             begin
1275                Decl :=
1276                  Make_Subtype_Declaration (Loc,
1277                    Defining_Identifier => Subt,
1278                    Subtype_Indication  =>
1279                       Make_Subtype_Indication (Loc,
1280                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1281                         Constraint =>
1282                           Make_Range_Constraint (Loc,
1283                             Relocate_Node (DS))));
1284                Insert_Before (Parent (N), Decl);
1285                Analyze (Decl);
1286
1287                Rewrite (DS,
1288                   Make_Attribute_Reference (Loc,
1289                     Prefix => New_Reference_To (Subt, Loc),
1290                     Attribute_Name => Attribute_Name (DS)));
1291                Analyze (DS);
1292             end;
1293          end if;
1294       end Check_Controlled_Array_Attribute;
1295
1296    --  Start of processing for Analyze_Iteration_Scheme
1297
1298    begin
1299       --  For an infinite loop, there is no iteration scheme
1300
1301       if No (N) then
1302          return;
1303
1304       else
1305          declare
1306             Cond : constant Node_Id := Condition (N);
1307
1308          begin
1309             --  For WHILE loop, verify that the condition is a Boolean
1310             --  expression and resolve and check it.
1311
1312             if Present (Cond) then
1313                Analyze_And_Resolve (Cond, Any_Boolean);
1314                Check_Unset_Reference (Cond);
1315
1316             --  Else we have a FOR loop
1317
1318             else
1319                declare
1320                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1321                   Id : constant Entity_Id := Defining_Identifier (LP);
1322                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1323
1324                begin
1325                   Enter_Name (Id);
1326
1327                   --  We always consider the loop variable to be referenced,
1328                   --  since the loop may be used just for counting purposes.
1329
1330                   Generate_Reference (Id, N, ' ');
1331
1332                   --  Check for case of loop variable hiding a local
1333                   --  variable (used later on to give a nice warning
1334                   --  if the hidden variable is never assigned).
1335
1336                   declare
1337                      H : constant Entity_Id := Homonym (Id);
1338                   begin
1339                      if Present (H)
1340                        and then Enclosing_Dynamic_Scope (H) =
1341                                 Enclosing_Dynamic_Scope (Id)
1342                        and then Ekind (H) = E_Variable
1343                        and then Is_Discrete_Type (Etype (H))
1344                      then
1345                         Set_Hiding_Loop_Variable (H, Id);
1346                      end if;
1347                   end;
1348
1349                   --  Now analyze the subtype definition. If it is
1350                   --  a range, create temporaries for bounds.
1351
1352                   if Nkind (DS) = N_Range
1353                     and then Expander_Active
1354                   then
1355                      Process_Bounds (DS);
1356                   else
1357                      Analyze (DS);
1358                   end if;
1359
1360                   if DS = Error then
1361                      return;
1362                   end if;
1363
1364                   --  The subtype indication may denote the completion
1365                   --  of an incomplete type declaration.
1366
1367                   if Is_Entity_Name (DS)
1368                     and then Present (Entity (DS))
1369                     and then Is_Type (Entity (DS))
1370                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1371                   then
1372                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1373                      Set_Etype  (DS, Entity (DS));
1374                   end if;
1375
1376                   if not Is_Discrete_Type (Etype (DS)) then
1377                      Wrong_Type (DS, Any_Discrete);
1378                      Set_Etype (DS, Any_Type);
1379                   end if;
1380
1381                   Check_Controlled_Array_Attribute (DS);
1382
1383                   Make_Index (DS, LP);
1384
1385                   Set_Ekind          (Id, E_Loop_Parameter);
1386                   Set_Etype          (Id, Etype (DS));
1387                   Set_Is_Known_Valid (Id, True);
1388
1389                   --  The loop is not a declarative part, so the only entity
1390                   --  declared "within" must be frozen explicitly.
1391
1392                   declare
1393                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1394                   begin
1395                      if Is_Non_Empty_List (Flist) then
1396                         Insert_Actions (N, Flist);
1397                      end if;
1398                   end;
1399
1400                   --  Check for null or possibly null range and issue warning.
1401                   --  We suppress such messages in generic templates and
1402                   --  instances, because in practice they tend to be dubious
1403                   --  in these cases.
1404
1405                   if Nkind (DS) = N_Range
1406                     and then Comes_From_Source (N)
1407                   then
1408                      declare
1409                         L : constant Node_Id := Low_Bound  (DS);
1410                         H : constant Node_Id := High_Bound (DS);
1411
1412                         Llo : Uint;
1413                         Lhi : Uint;
1414                         LOK : Boolean;
1415                         Hlo : Uint;
1416                         Hhi : Uint;
1417                         HOK : Boolean;
1418
1419                      begin
1420                         Determine_Range (L, LOK, Llo, Lhi);
1421                         Determine_Range (H, HOK, Hlo, Hhi);
1422
1423                         --  If range of loop is null, issue warning
1424
1425                         if (LOK and HOK) and then Llo > Hhi then
1426
1427                            --  Suppress the warning if inside a generic
1428                            --  template or instance, since in practice
1429                            --  they tend to be dubious in these cases since
1430                            --  they can result from intended parametrization.
1431
1432                            if not Inside_A_Generic
1433                               and then not In_Instance
1434                            then
1435                               Error_Msg_N
1436                                 ("?loop range is null, loop will not execute",
1437                                  DS);
1438                            end if;
1439
1440                            --  Since we know the range of the loop is null,
1441                            --  set the appropriate flag to suppress any
1442                            --  warnings that would otherwise be issued in
1443                            --  the body of the loop that will not execute.
1444                            --  We do this even in the generic case, since
1445                            --  if it is dubious to warn on the null loop
1446                            --  itself, it is certainly dubious to warn for
1447                            --  conditions that occur inside it!
1448
1449                            Set_Is_Null_Loop (Parent (N));
1450
1451                         --  The other case for a warning is a reverse loop
1452                         --  where the upper bound is the integer literal
1453                         --  zero or one, and the lower bound can be positive.
1454
1455                         --  For example, we have
1456
1457                         --     for J in reverse N .. 1 loop
1458
1459                         --  In practice, this is very likely to be a case
1460                         --  of reversing the bounds incorrectly in the range.
1461
1462                         elsif Reverse_Present (LP)
1463                           and then Nkind (H) = N_Integer_Literal
1464                           and then (Intval (H) = Uint_0
1465                                       or else
1466                                     Intval (H) = Uint_1)
1467                           and then Lhi > Hhi
1468                         then
1469                            Error_Msg_N ("?loop range may be null", DS);
1470                         end if;
1471                      end;
1472                   end if;
1473                end;
1474             end if;
1475          end;
1476       end if;
1477    end Analyze_Iteration_Scheme;
1478
1479    -------------------
1480    -- Analyze_Label --
1481    -------------------
1482
1483    --  Note: the semantic work required for analyzing labels (setting them as
1484    --  reachable) was done in a prepass through the statements in the block,
1485    --  so that forward gotos would be properly handled. See Analyze_Statements
1486    --  for further details. The only processing required here is to deal with
1487    --  optimizations that depend on an assumption of sequential control flow,
1488    --  since of course the occurrence of a label breaks this assumption.
1489
1490    procedure Analyze_Label (N : Node_Id) is
1491       pragma Warnings (Off, N);
1492    begin
1493       Kill_Current_Values;
1494    end Analyze_Label;
1495
1496    --------------------------
1497    -- Analyze_Label_Entity --
1498    --------------------------
1499
1500    procedure Analyze_Label_Entity (E : Entity_Id) is
1501    begin
1502       Set_Ekind           (E, E_Label);
1503       Set_Etype           (E, Standard_Void_Type);
1504       Set_Enclosing_Scope (E, Current_Scope);
1505       Set_Reachable       (E, True);
1506    end Analyze_Label_Entity;
1507
1508    ----------------------------
1509    -- Analyze_Loop_Statement --
1510    ----------------------------
1511
1512    procedure Analyze_Loop_Statement (N : Node_Id) is
1513       Id  : constant Node_Id := Identifier (N);
1514       Ent : Entity_Id;
1515
1516    begin
1517       if Present (Id) then
1518
1519          --  Make name visible, e.g. for use in exit statements. Loop
1520          --  labels are always considered to be referenced.
1521
1522          Analyze (Id);
1523          Ent := Entity (Id);
1524          Generate_Reference  (Ent, N, ' ');
1525          Generate_Definition (Ent);
1526
1527          --  If we found a label, mark its type. If not, ignore it, since it
1528          --  means we have a conflicting declaration, which would already have
1529          --  been diagnosed at declaration time. Set Label_Construct of the
1530          --  implicit label declaration, which is not created by the parser
1531          --  for generic units.
1532
1533          if Ekind (Ent) = E_Label then
1534             Set_Ekind (Ent, E_Loop);
1535
1536             if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
1537                Set_Label_Construct (Parent (Ent), N);
1538             end if;
1539          end if;
1540
1541       --  Case of no identifier present
1542
1543       else
1544          Ent := New_Internal_Entity (E_Loop, Current_Scope, Sloc (N), 'L');
1545          Set_Etype (Ent,  Standard_Void_Type);
1546          Set_Parent (Ent, N);
1547       end if;
1548
1549       --  Kill current values on entry to loop, since statements in body
1550       --  of loop may have been executed before the loop is entered.
1551       --  Similarly we kill values after the loop, since we do not know
1552       --  that the body of the loop was executed.
1553
1554       Kill_Current_Values;
1555       New_Scope (Ent);
1556       Analyze_Iteration_Scheme (Iteration_Scheme (N));
1557       Analyze_Statements (Statements (N));
1558       Process_End_Label (N, 'e', Ent);
1559       End_Scope;
1560       Kill_Current_Values;
1561    end Analyze_Loop_Statement;
1562
1563    ----------------------------
1564    -- Analyze_Null_Statement --
1565    ----------------------------
1566
1567    --  Note: the semantics of the null statement is implemented by a single
1568    --  null statement, too bad everything isn't as simple as this!
1569
1570    procedure Analyze_Null_Statement (N : Node_Id) is
1571       pragma Warnings (Off, N);
1572    begin
1573       null;
1574    end Analyze_Null_Statement;
1575
1576    ------------------------
1577    -- Analyze_Statements --
1578    ------------------------
1579
1580    procedure Analyze_Statements (L : List_Id) is
1581       S   : Node_Id;
1582       Lab : Entity_Id;
1583
1584    begin
1585       --  The labels declared in the statement list are reachable from
1586       --  statements in the list. We do this as a prepass so that any
1587       --  goto statement will be properly flagged if its target is not
1588       --  reachable. This is not required, but is nice behavior!
1589
1590       S := First (L);
1591       while Present (S) loop
1592          if Nkind (S) = N_Label then
1593             Analyze (Identifier (S));
1594             Lab := Entity (Identifier (S));
1595
1596             --  If we found a label mark it as reachable
1597
1598             if Ekind (Lab) = E_Label then
1599                Generate_Definition (Lab);
1600                Set_Reachable (Lab);
1601
1602                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
1603                   Set_Label_Construct (Parent (Lab), S);
1604                end if;
1605
1606             --  If we failed to find a label, it means the implicit declaration
1607             --  of the label was hidden.  A for-loop parameter can do this to
1608             --  a label with the same name inside the loop, since the implicit
1609             --  label declaration is in the innermost enclosing body or block
1610             --  statement.
1611
1612             else
1613                Error_Msg_Sloc := Sloc (Lab);
1614                Error_Msg_N
1615                  ("implicit label declaration for & is hidden#",
1616                   Identifier (S));
1617             end if;
1618          end if;
1619
1620          Next (S);
1621       end loop;
1622
1623       --  Perform semantic analysis on all statements
1624
1625       Conditional_Statements_Begin;
1626
1627       S := First (L);
1628       while Present (S) loop
1629          Analyze (S);
1630          Next (S);
1631       end loop;
1632
1633       Conditional_Statements_End;
1634
1635       --  Make labels unreachable. Visibility is not sufficient, because
1636       --  labels in one if-branch for example are not reachable from the
1637       --  other branch, even though their declarations are in the enclosing
1638       --  declarative part.
1639
1640       S := First (L);
1641       while Present (S) loop
1642          if Nkind (S) = N_Label then
1643             Set_Reachable (Entity (Identifier (S)), False);
1644          end if;
1645
1646          Next (S);
1647       end loop;
1648    end Analyze_Statements;
1649
1650    --------------------------------------------
1651    -- Check_Possible_Current_Value_Condition --
1652    --------------------------------------------
1653
1654    procedure Check_Possible_Current_Value_Condition (Cnode : Node_Id) is
1655       Cond : Node_Id;
1656
1657    begin
1658       --  Loop to deal with (ignore for now) any NOT operators present
1659
1660       Cond := Condition (Cnode);
1661       while Nkind (Cond) = N_Op_Not loop
1662          Cond := Right_Opnd (Cond);
1663       end loop;
1664
1665       --  Check possible relational operator
1666
1667       if Nkind (Cond) = N_Op_Eq
1668            or else
1669          Nkind (Cond) = N_Op_Ne
1670            or else
1671          Nkind (Cond) = N_Op_Ge
1672            or else
1673          Nkind (Cond) = N_Op_Le
1674            or else
1675          Nkind (Cond) = N_Op_Gt
1676            or else
1677          Nkind (Cond) = N_Op_Lt
1678       then
1679          if Compile_Time_Known_Value (Right_Opnd (Cond))
1680            and then Nkind (Left_Opnd (Cond)) = N_Identifier
1681          then
1682             declare
1683                Ent : constant Entity_Id := Entity (Left_Opnd (Cond));
1684
1685             begin
1686                if Ekind (Ent) = E_Variable
1687                     or else
1688                   Ekind (Ent) = E_Constant
1689                     or else
1690                   Is_Formal (Ent)
1691                     or else
1692                   Ekind (Ent) = E_Loop_Parameter
1693                then
1694                   --  Here we have a case where the Current_Value field
1695                   --  may need to be set. We set it if it is not already
1696                   --  set to a compile time expression value.
1697
1698                   --  Note that this represents a decision that one
1699                   --  condition blots out another previous one. That's
1700                   --  certainly right if they occur at the same level.
1701                   --  If the second one is nested, then the decision is
1702                   --  neither right nor wrong (it would be equally OK
1703                   --  to leave the outer one in place, or take the new
1704                   --  inner one. Really we should record both, but our
1705                   --  data structures are not that elaborate.
1706
1707                   if Nkind (Current_Value (Ent)) not in N_Subexpr then
1708                      Set_Current_Value (Ent, Cnode);
1709                   end if;
1710                end if;
1711             end;
1712          end if;
1713       end if;
1714    end Check_Possible_Current_Value_Condition;
1715
1716    ----------------------------
1717    -- Check_Unreachable_Code --
1718    ----------------------------
1719
1720    procedure Check_Unreachable_Code (N : Node_Id) is
1721       Error_Loc : Source_Ptr;
1722       P         : Node_Id;
1723
1724    begin
1725       if Is_List_Member (N)
1726         and then Comes_From_Source (N)
1727       then
1728          declare
1729             Nxt : Node_Id;
1730
1731          begin
1732             Nxt := Original_Node (Next (N));
1733
1734             --  If a label follows us, then we never have dead code, since
1735             --  someone could branch to the label, so we just ignore it.
1736
1737             if Nkind (Nxt) = N_Label then
1738                return;
1739
1740             --  Otherwise see if we have a real statement following us
1741
1742             elsif Present (Nxt)
1743               and then Comes_From_Source (Nxt)
1744               and then Is_Statement (Nxt)
1745             then
1746                --  Special very annoying exception. If we have a return that
1747                --  follows a raise, then we allow it without a warning, since
1748                --  the Ada RM annoyingly requires a useless return here!
1749
1750                if Nkind (Original_Node (N)) /= N_Raise_Statement
1751                  or else Nkind (Nxt) /= N_Return_Statement
1752                then
1753                   --  The rather strange shenanigans with the warning message
1754                   --  here reflects the fact that Kill_Dead_Code is very good
1755                   --  at removing warnings in deleted code, and this is one
1756                   --  warning we would prefer NOT to have removed :-)
1757
1758                   Error_Loc := Sloc (Nxt);
1759
1760                   --  If we have unreachable code, analyze and remove the
1761                   --  unreachable code, since it is useless and we don't
1762                   --  want to generate junk warnings.
1763
1764                   --  We skip this step if we are not in code generation mode.
1765                   --  This is the one case where we remove dead code in the
1766                   --  semantics as opposed to the expander, and we do not want
1767                   --  to remove code if we are not in code generation mode,
1768                   --  since this messes up the ASIS trees.
1769
1770                   --  Note that one might react by moving the whole circuit to
1771                   --  exp_ch5, but then we lose the warning in -gnatc mode.
1772
1773                   if Operating_Mode = Generate_Code then
1774                      loop
1775                         Nxt := Next (N);
1776
1777                         --  Quit deleting when we have nothing more to delete
1778                         --  or if we hit a label (since someone could transfer
1779                         --  control to a label, so we should not delete it).
1780
1781                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
1782
1783                         --  Statement/declaration is to be deleted
1784
1785                         Analyze (Nxt);
1786                         Remove (Nxt);
1787                         Kill_Dead_Code (Nxt);
1788                      end loop;
1789                   end if;
1790
1791                   --  Now issue the warning
1792
1793                   Error_Msg ("?unreachable code", Error_Loc);
1794                end if;
1795
1796             --  If the unconditional transfer of control instruction is
1797             --  the last statement of a sequence, then see if our parent
1798             --  is one of the constructs for which we count unblocked exits,
1799             --  and if so, adjust the count.
1800
1801             else
1802                P := Parent (N);
1803
1804                --  Statements in THEN part or ELSE part of IF statement
1805
1806                if Nkind (P) = N_If_Statement then
1807                   null;
1808
1809                --  Statements in ELSIF part of an IF statement
1810
1811                elsif Nkind (P) = N_Elsif_Part then
1812                   P := Parent (P);
1813                   pragma Assert (Nkind (P) = N_If_Statement);
1814
1815                --  Statements in CASE statement alternative
1816
1817                elsif Nkind (P) = N_Case_Statement_Alternative then
1818                   P := Parent (P);
1819                   pragma Assert (Nkind (P) = N_Case_Statement);
1820
1821                --  Statements in body of block
1822
1823                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
1824                  and then Nkind (Parent (P)) = N_Block_Statement
1825                then
1826                   null;
1827
1828                --  Statements in exception handler in a block
1829
1830                elsif Nkind (P) = N_Exception_Handler
1831                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
1832                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
1833                then
1834                   null;
1835
1836                --  None of these cases, so return
1837
1838                else
1839                   return;
1840                end if;
1841
1842                --  This was one of the cases we are looking for (i.e. the
1843                --  parent construct was IF, CASE or block) so decrement count.
1844
1845                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
1846             end if;
1847          end;
1848       end if;
1849    end Check_Unreachable_Code;
1850
1851 end Sem_Ch5;