gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Aux;  use Sem_Aux;
  42 with Sem_Case; use Sem_Case;
  43 with Sem_Ch3;  use Sem_Ch3;
  44 with Sem_Ch8;  use Sem_Ch8;
  45 with Sem_Disp; use Sem_Disp;
  46 with Sem_Elab; use Sem_Elab;
  47 with Sem_Eval; use Sem_Eval;
  48 with Sem_Res;  use Sem_Res;
  49 with Sem_Type; use Sem_Type;
  50 with Sem_Util; use Sem_Util;
  51 with Sem_Warn; use Sem_Warn;
  52 with Snames;   use Snames;
  53 with Stand;    use Stand;
  54 with Sinfo;    use Sinfo;
  55 with Targparm; use Targparm;
  56 with Tbuild;   use Tbuild;
  57 with Uintp;    use Uintp;
  58
  59 package body Sem_Ch5 is
  60
  61    Unblocked_Exit_Count : Nat := 0;
  62    --  This variable is used when processing if statements, case statements,
  63    --  and block statements. It counts the number of exit points that are not
  64    --  blocked by unconditional transfer instructions: for IF and CASE, these
  65    --  are the branches of the conditional; for a block, they are the statement
  66    --  sequence of the block, and the statement sequences of any exception
  67    --  handlers that are part of the block. When processing is complete, if
  68    --  this count is zero, it means that control cannot fall through the IF,
  69    --  CASE or block statement. This is used for the generation of warning
  70    --  messages. This variable is recursively saved on entry to processing the
  71    --  construct, and restored on exit.
  72
  73    ------------------------
  74    -- Analyze_Assignment --
  75    ------------------------
  76
  77    procedure Analyze_Assignment (N : Node_Id) is
  78       Lhs  : constant Node_Id := Name (N);
  79       Rhs  : constant Node_Id := Expression (N);
  80       T1   : Entity_Id;
  81       T2   : Entity_Id;
  82       Decl : Node_Id;
  83
  84       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  85       --  N is the node for the left hand side of an assignment, and it is not
  86       --  a variable. This routine issues an appropriate diagnostic.
  87
  88       procedure Kill_Lhs;
  89       --  This is called to kill current value settings of a simple variable
  90       --  on the left hand side. We call it if we find any error in analyzing
  91       --  the assignment, and at the end of processing before setting any new
  92       --  current values in place.
  93
  94       procedure Set_Assignment_Type
  95         (Opnd      : Node_Id;
  96          Opnd_Type : in out Entity_Id);
  97       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
  98       --  is the nominal subtype. This procedure is used to deal with cases
  99       --  where the nominal subtype must be replaced by the actual subtype.
 100
 101       -------------------------------
 102       -- Diagnose_Non_Variable_Lhs --
 103       -------------------------------
 104
 105       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 106       begin
 107          --  Not worth posting another error if left hand side already
 108          --  flagged as being illegal in some respect.
 109
 110          if Error_Posted (N) then
 111             return;
 112
 113          --  Some special bad cases of entity names
 114
 115          elsif Is_Entity_Name (N) then
 116             declare
 117                Ent : constant Entity_Id := Entity (N);
 118
 119             begin
 120                if Ekind (Ent) = E_In_Parameter then
 121                   Error_Msg_N
 122                     ("assignment to IN mode parameter not allowed", N);
 123
 124                --  Renamings of protected private components are turned into
 125                --  constants when compiling a protected function. In the case
 126                --  of single protected types, the private component appears
 127                --  directly.
 128
 129                elsif (Is_Prival (Ent)
 130                         and then
 131                           (Ekind (Current_Scope) = E_Function
 132                              or else Ekind (Enclosing_Dynamic_Scope (
 133                                        Current_Scope)) = E_Function))
 134                    or else
 135                      (Ekind (Ent) = E_Component
 136                         and then Is_Protected_Type (Scope (Ent)))
 137                then
 138                   Error_Msg_N
 139                     ("protected function cannot modify protected object", N);
 140
 141                elsif Ekind (Ent) = E_Loop_Parameter then
 142                   Error_Msg_N
 143                     ("assignment to loop parameter not allowed", N);
 144
 145                else
 146                   Error_Msg_N
 147                     ("left hand side of assignment must be a variable", N);
 148                end if;
 149             end;
 150
 151          --  For indexed components or selected components, test prefix
 152
 153          elsif Nkind (N) = N_Indexed_Component then
 154             Diagnose_Non_Variable_Lhs (Prefix (N));
 155
 156          --  Another special case for assignment to discriminant
 157
 158          elsif Nkind (N) = N_Selected_Component then
 159             if Present (Entity (Selector_Name (N)))
 160               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 161             then
 162                Error_Msg_N
 163                  ("assignment to discriminant not allowed", N);
 164             else
 165                Diagnose_Non_Variable_Lhs (Prefix (N));
 166             end if;
 167
 168          else
 169             --  If we fall through, we have no special message to issue!
 170
 171             Error_Msg_N ("left hand side of assignment must be a variable", N);
 172          end if;
 173       end Diagnose_Non_Variable_Lhs;
 174
 175       --------------
 176       -- Kill_LHS --
 177       --------------
 178
 179       procedure Kill_Lhs is
 180       begin
 181          if Is_Entity_Name (Lhs) then
 182             declare
 183                Ent : constant Entity_Id := Entity (Lhs);
 184             begin
 185                if Present (Ent) then
 186                   Kill_Current_Values (Ent);
 187                end if;
 188             end;
 189          end if;
 190       end Kill_Lhs;
 191
 192       -------------------------
 193       -- Set_Assignment_Type --
 194       -------------------------
 195
 196       procedure Set_Assignment_Type
 197         (Opnd      : Node_Id;
 198          Opnd_Type : in out Entity_Id)
 199       is
 200       begin
 201          Require_Entity (Opnd);
 202
 203          --  If the assignment operand is an in-out or out parameter, then we
 204          --  get the actual subtype (needed for the unconstrained case).
 205          --  If the operand is the actual in an entry declaration, then within
 206          --  the accept statement it is replaced with a local renaming, which
 207          --  may also have an actual subtype.
 208
 209          if Is_Entity_Name (Opnd)
 210            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 211                       or else Ekind (Entity (Opnd)) =
 212                            E_In_Out_Parameter
 213                       or else Ekind (Entity (Opnd)) =
 214                            E_Generic_In_Out_Parameter
 215                       or else
 216                         (Ekind (Entity (Opnd)) = E_Variable
 217                           and then Nkind (Parent (Entity (Opnd))) =
 218                              N_Object_Renaming_Declaration
 219                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 220                              N_Accept_Statement))
 221          then
 222             Opnd_Type := Get_Actual_Subtype (Opnd);
 223
 224          --  If assignment operand is a component reference, then we get the
 225          --  actual subtype of the component for the unconstrained case.
 226
 227          elsif Nkind_In (Opnd, N_Selected_Component, N_Explicit_Dereference)
 228            and then not Is_Unchecked_Union (Opnd_Type)
 229          then
 230             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 231
 232             if Present (Decl) then
 233                Insert_Action (N, Decl);
 234                Mark_Rewrite_Insertion (Decl);
 235                Analyze (Decl);
 236                Opnd_Type := Defining_Identifier (Decl);
 237                Set_Etype (Opnd, Opnd_Type);
 238                Freeze_Itype (Opnd_Type, N);
 239
 240             elsif Is_Constrained (Etype (Opnd)) then
 241                Opnd_Type := Etype (Opnd);
 242             end if;
 243
 244          --  For slice, use the constrained subtype created for the slice
 245
 246          elsif Nkind (Opnd) = N_Slice then
 247             Opnd_Type := Etype (Opnd);
 248          end if;
 249       end Set_Assignment_Type;
 250
 251    --  Start of processing for Analyze_Assignment
 252
 253    begin
 254       Mark_Coextensions (N, Rhs);
 255
 256       Analyze (Rhs);
 257       Analyze (Lhs);
 258
 259       --  Start type analysis for assignment
 260
 261       T1 := Etype (Lhs);
 262
 263       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 264       --  must compute the intersection of the possible types on each side.
 265
 266       if Is_Overloaded (Lhs) then
 267          declare
 268             I  : Interp_Index;
 269             It : Interp;
 270
 271          begin
 272             T1 := Any_Type;
 273             Get_First_Interp (Lhs, I, It);
 274
 275             while Present (It.Typ) loop
 276                if Has_Compatible_Type (Rhs, It.Typ) then
 277                   if T1 /= Any_Type then
 278
 279                      --  An explicit dereference is overloaded if the prefix
 280                      --  is. Try to remove the ambiguity on the prefix, the
 281                      --  error will be posted there if the ambiguity is real.
 282
 283                      if Nkind (Lhs) = N_Explicit_Dereference then
 284                         declare
 285                            PI    : Interp_Index;
 286                            PI1   : Interp_Index := 0;
 287                            PIt   : Interp;
 288                            Found : Boolean;
 289
 290                         begin
 291                            Found := False;
 292                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 293
 294                            while Present (PIt.Typ) loop
 295                               if Is_Access_Type (PIt.Typ)
 296                                 and then Has_Compatible_Type
 297                                            (Rhs, Designated_Type (PIt.Typ))
 298                               then
 299                                  if Found then
 300                                     PIt :=
 301                                       Disambiguate (Prefix (Lhs),
 302                                         PI1, PI, Any_Type);
 303
 304                                     if PIt = No_Interp then
 305                                        Error_Msg_N
 306                                          ("ambiguous left-hand side"
 307                                             & " in assignment", Lhs);
 308                                        exit;
 309                                     else
 310                                        Resolve (Prefix (Lhs), PIt.Typ);
 311                                     end if;
 312
 313                                     exit;
 314                                  else
 315                                     Found := True;
 316                                     PI1 := PI;
 317                                  end if;
 318                               end if;
 319
 320                               Get_Next_Interp (PI, PIt);
 321                            end loop;
 322                         end;
 323
 324                      else
 325                         Error_Msg_N
 326                           ("ambiguous left-hand side in assignment", Lhs);
 327                         exit;
 328                      end if;
 329                   else
 330                      T1 := It.Typ;
 331                   end if;
 332                end if;
 333
 334                Get_Next_Interp (I, It);
 335             end loop;
 336          end;
 337
 338          if T1 = Any_Type then
 339             Error_Msg_N
 340               ("no valid types for left-hand side for assignment", Lhs);
 341             Kill_Lhs;
 342             return;
 343          end if;
 344       end if;
 345
 346       --  The resulting assignment type is T1, so now we will resolve the
 347       --  left hand side of the assignment using this determined type.
 348
 349       Resolve (Lhs, T1);
 350
 351       --  Cases where Lhs is not a variable
 352
 353       if not Is_Variable (Lhs) then
 354
 355          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 356          --  a protected object.
 357
 358          declare
 359             Ent : Entity_Id;
 360             S   : Entity_Id;
 361
 362          begin
 363             if Ada_Version >= Ada_2005 then
 364
 365                --  Handle chains of renamings
 366
 367                Ent := Lhs;
 368                while Nkind (Ent) in N_Has_Entity
 369                  and then Present (Entity (Ent))
 370                  and then Present (Renamed_Object (Entity (Ent)))
 371                loop
 372                   Ent := Renamed_Object (Entity (Ent));
 373                end loop;
 374
 375                if (Nkind (Ent) = N_Attribute_Reference
 376                      and then Attribute_Name (Ent) = Name_Priority)
 377
 378                   --  Renamings of the attribute Priority applied to protected
 379                   --  objects have been previously expanded into calls to the
 380                   --  Get_Ceiling run-time subprogram.
 381
 382                  or else
 383                   (Nkind (Ent) = N_Function_Call
 384                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 385                                 or else
 386                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 387                then
 388                   --  The enclosing subprogram cannot be a protected function
 389
 390                   S := Current_Scope;
 391                   while not (Is_Subprogram (S)
 392                                and then Convention (S) = Convention_Protected)
 393                      and then S /= Standard_Standard
 394                   loop
 395                      S := Scope (S);
 396                   end loop;
 397
 398                   if Ekind (S) = E_Function
 399                     and then Convention (S) = Convention_Protected
 400                   then
 401                      Error_Msg_N
 402                        ("protected function cannot modify protected object",
 403                         Lhs);
 404                   end if;
 405
 406                   --  Changes of the ceiling priority of the protected object
 407                   --  are only effective if the Ceiling_Locking policy is in
 408                   --  effect (AARM D.5.2 (5/2)).
 409
 410                   if Locking_Policy /= 'C' then
 411                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 412                                   "no effect?", Lhs);
 413                      Error_Msg_N ("\since no Locking_Policy has been " &
 414                                   "specified", Lhs);
 415                   end if;
 416
 417                   return;
 418                end if;
 419             end if;
 420          end;
 421
 422          Diagnose_Non_Variable_Lhs (Lhs);
 423          return;
 424
 425       --  Error of assigning to limited type. We do however allow this in
 426       --  certain cases where the front end generates the assignments.
 427
 428       elsif Is_Limited_Type (T1)
 429         and then not Assignment_OK (Lhs)
 430         and then not Assignment_OK (Original_Node (Lhs))
 431         and then not Is_Value_Type (T1)
 432       then
 433          --  CPP constructors can only be called in declarations
 434
 435          if Is_CPP_Constructor_Call (Rhs) then
 436             Error_Msg_N ("invalid use of 'C'P'P constructor", Rhs);
 437          else
 438             Error_Msg_N
 439               ("left hand of assignment must not be limited type", Lhs);
 440             Explain_Limited_Type (T1, Lhs);
 441          end if;
 442          return;
 443
 444       --  Enforce RM 3.9.3 (8): the target of an assignment operation cannot be
 445       --  abstract. This is only checked when the assignment Comes_From_Source,
 446       --  because in some cases the expander generates such assignments (such
 447       --  in the _assign operation for an abstract type).
 448
 449       elsif Is_Abstract_Type (T1) and then Comes_From_Source (N) then
 450          Error_Msg_N
 451            ("target of assignment operation must not be abstract", Lhs);
 452       end if;
 453
 454       --  Resolution may have updated the subtype, in case the left-hand
 455       --  side is a private protected component. Use the correct subtype
 456       --  to avoid scoping issues in the back-end.
 457
 458       T1 := Etype (Lhs);
 459
 460       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 461       --  type. For example:
 462
 463       --    limited with P;
 464       --    package Pkg is
 465       --      type Acc is access P.T;
 466       --    end Pkg;
 467
 468       --    with Pkg; use Acc;
 469       --    procedure Example is
 470       --       A, B : Acc;
 471       --    begin
 472       --       A.all := B.all;  -- ERROR
 473       --    end Example;
 474
 475       if Nkind (Lhs) = N_Explicit_Dereference
 476         and then Ekind (T1) = E_Incomplete_Type
 477       then
 478          Error_Msg_N ("invalid use of incomplete type", Lhs);
 479          Kill_Lhs;
 480          return;
 481       end if;
 482
 483       --  Now we can complete the resolution of the right hand side
 484
 485       Set_Assignment_Type (Lhs, T1);
 486       Resolve (Rhs, T1);
 487
 488       --  This is the point at which we check for an unset reference
 489
 490       Check_Unset_Reference (Rhs);
 491       Check_Unprotected_Access (Lhs, Rhs);
 492
 493       --  Remaining steps are skipped if Rhs was syntactically in error
 494
 495       if Rhs = Error then
 496          Kill_Lhs;
 497          return;
 498       end if;
 499
 500       T2 := Etype (Rhs);
 501
 502       if not Covers (T1, T2) then
 503          Wrong_Type (Rhs, Etype (Lhs));
 504          Kill_Lhs;
 505          return;
 506       end if;
 507
 508       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 509       --  types, use the non-limited view if available
 510
 511       if Nkind (Rhs) = N_Explicit_Dereference
 512         and then Ekind (T2) = E_Incomplete_Type
 513         and then Is_Tagged_Type (T2)
 514         and then Present (Non_Limited_View (T2))
 515       then
 516          T2 := Non_Limited_View (T2);
 517       end if;
 518
 519       Set_Assignment_Type (Rhs, T2);
 520
 521       if Total_Errors_Detected /= 0 then
 522          if No (T1) then
 523             T1 := Any_Type;
 524          end if;
 525
 526          if No (T2) then
 527             T2 := Any_Type;
 528          end if;
 529       end if;
 530
 531       if T1 = Any_Type or else T2 = Any_Type then
 532          Kill_Lhs;
 533          return;
 534       end if;
 535
 536       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 537       --  to be class-wide. The case where the rhs is a dynamically tagged call
 538       --  to a dispatching operation with a controlling access result is
 539       --  excluded from this check, since the target has an access type (and
 540       --  no tag propagation occurs in that case).
 541
 542       if (Is_Class_Wide_Type (T2)
 543            or else (Is_Dynamically_Tagged (Rhs)
 544                      and then not Is_Access_Type (T1)))
 545         and then not Is_Class_Wide_Type (T1)
 546       then
 547          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 548
 549       elsif Is_Class_Wide_Type (T1)
 550         and then not Is_Class_Wide_Type (T2)
 551         and then not Is_Tag_Indeterminate (Rhs)
 552         and then not Is_Dynamically_Tagged (Rhs)
 553       then
 554          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 555       end if;
 556
 557       --  Propagate the tag from a class-wide target to the rhs when the rhs
 558       --  is a tag-indeterminate call.
 559
 560       if Is_Tag_Indeterminate (Rhs) then
 561          if Is_Class_Wide_Type (T1) then
 562             Propagate_Tag (Lhs, Rhs);
 563
 564          elsif Nkind (Rhs) = N_Function_Call
 565               and then Is_Entity_Name (Name (Rhs))
 566               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 567          then
 568             Error_Msg_N
 569               ("call to abstract function must be dispatching", Name (Rhs));
 570
 571          elsif Nkind (Rhs) = N_Qualified_Expression
 572            and then Nkind (Expression (Rhs)) = N_Function_Call
 573               and then Is_Entity_Name (Name (Expression (Rhs)))
 574               and then
 575                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 576          then
 577             Error_Msg_N
 578               ("call to abstract function must be dispatching",
 579                 Name (Expression (Rhs)));
 580          end if;
 581       end if;
 582
 583       --  Ada 2005 (AI-385): When the lhs type is an anonymous access type,
 584       --  apply an implicit conversion of the rhs to that type to force
 585       --  appropriate static and run-time accessibility checks. This applies
 586       --  as well to anonymous access-to-subprogram types that are component
 587       --  subtypes or formal parameters.
 588
 589       if Ada_Version >= Ada_2005
 590         and then Is_Access_Type (T1)
 591       then
 592          if Is_Local_Anonymous_Access (T1)
 593            or else Ekind (T2) = E_Anonymous_Access_Subprogram_Type
 594          then
 595             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 596             Analyze_And_Resolve (Rhs, T1);
 597          end if;
 598       end if;
 599
 600       --  Ada 2005 (AI-231): Assignment to not null variable
 601
 602       if Ada_Version >= Ada_2005
 603         and then Can_Never_Be_Null (T1)
 604         and then not Assignment_OK (Lhs)
 605       then
 606          --  Case where we know the right hand side is null
 607
 608          if Known_Null (Rhs) then
 609             Apply_Compile_Time_Constraint_Error
 610               (N   => Rhs,
 611                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 612                Reason => CE_Null_Not_Allowed);
 613
 614             --  We still mark this as a possible modification, that's necessary
 615             --  to reset Is_True_Constant, and desirable for xref purposes.
 616
 617             Note_Possible_Modification (Lhs, Sure => True);
 618             return;
 619
 620          --  If we know the right hand side is non-null, then we convert to the
 621          --  target type, since we don't need a run time check in that case.
 622
 623          elsif not Can_Never_Be_Null (T2) then
 624             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 625             Analyze_And_Resolve (Rhs, T1);
 626          end if;
 627       end if;
 628
 629       if Is_Scalar_Type (T1) then
 630          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 631
 632       --  For array types, verify that lengths match. If the right hand side
 633       --  if a function call that has been inlined, the assignment has been
 634       --  rewritten as a block, and the constraint check will be applied to the
 635       --  assignment within the block.
 636
 637       elsif Is_Array_Type (T1)
 638         and then
 639           (Nkind (Rhs) /= N_Type_Conversion
 640             or else Is_Constrained (Etype (Rhs)))
 641         and then
 642           (Nkind (Rhs) /= N_Function_Call
 643             or else Nkind (N) /= N_Block_Statement)
 644       then
 645          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 646          --  but of course the indexes do not have to match. If the right-hand
 647          --  side is a type conversion to an unconstrained type, a length check
 648          --  is performed on the expression itself during expansion. In rare
 649          --  cases, the redundant length check is computed on an index type
 650          --  with a different representation, triggering incorrect code in
 651          --  the back end.
 652
 653          Apply_Length_Check (Rhs, Etype (Lhs));
 654
 655       else
 656          --  Discriminant checks are applied in the course of expansion
 657
 658          null;
 659       end if;
 660
 661       --  Note: modifications of the Lhs may only be recorded after
 662       --  checks have been applied.
 663
 664       Note_Possible_Modification (Lhs, Sure => True);
 665       Check_Order_Dependence;
 666
 667       --  ??? a real accessibility check is needed when ???
 668
 669       --  Post warning for redundant assignment or variable to itself
 670
 671       if Warn_On_Redundant_Constructs
 672
 673          --  We only warn for source constructs
 674
 675          and then Comes_From_Source (N)
 676
 677          --  Where the object is the same on both sides
 678
 679          and then Same_Object (Lhs, Original_Node (Rhs))
 680
 681          --  But exclude the case where the right side was an operation
 682          --  that got rewritten (e.g. JUNK + K, where K was known to be
 683          --  zero). We don't want to warn in such a case, since it is
 684          --  reasonable to write such expressions especially when K is
 685          --  defined symbolically in some other package.
 686
 687         and then Nkind (Original_Node (Rhs)) not in N_Op
 688       then
 689          if Nkind (Lhs) in N_Has_Entity then
 690             Error_Msg_NE -- CODEFIX
 691               ("?useless assignment of & to itself!", N, Entity (Lhs));
 692          else
 693             Error_Msg_N -- CODEFIX
 694               ("?useless assignment of object to itself!", N);
 695          end if;
 696       end if;
 697
 698       --  Check for non-allowed composite assignment
 699
 700       if not Support_Composite_Assign_On_Target
 701         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 702         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 703       then
 704          Error_Msg_CRT ("composite assignment", N);
 705       end if;
 706
 707       --  Check elaboration warning for left side if not in elab code
 708
 709       if not In_Subprogram_Or_Concurrent_Unit then
 710          Check_Elab_Assign (Lhs);
 711       end if;
 712
 713       --  Set Referenced_As_LHS if appropriate. We only set this flag if the
 714       --  assignment is a source assignment in the extended main source unit.
 715       --  We are not interested in any reference information outside this
 716       --  context, or in compiler generated assignment statements.
 717
 718       if Comes_From_Source (N)
 719         and then In_Extended_Main_Source_Unit (Lhs)
 720       then
 721          Set_Referenced_Modified (Lhs, Out_Param => False);
 722       end if;
 723
 724       --  Final step. If left side is an entity, then we may be able to
 725       --  reset the current tracked values to new safe values. We only have
 726       --  something to do if the left side is an entity name, and expansion
 727       --  has not modified the node into something other than an assignment,
 728       --  and of course we only capture values if it is safe to do so.
 729
 730       if Is_Entity_Name (Lhs)
 731         and then Nkind (N) = N_Assignment_Statement
 732       then
 733          declare
 734             Ent : constant Entity_Id := Entity (Lhs);
 735
 736          begin
 737             if Safe_To_Capture_Value (N, Ent) then
 738
 739                --  If simple variable on left side, warn if this assignment
 740                --  blots out another one (rendering it useless) and note
 741                --  location of assignment in case no one references value.
 742                --  We only do this for source assignments, otherwise we can
 743                --  generate bogus warnings when an assignment is rewritten as
 744                --  another assignment, and gets tied up with itself.
 745
 746                --  Note: we don't use Record_Last_Assignment here, because we
 747                --  have lots of other stuff to do under control of this test.
 748
 749                if Warn_On_Modified_Unread
 750                  and then Is_Assignable (Ent)
 751                  and then Comes_From_Source (N)
 752                  and then In_Extended_Main_Source_Unit (Ent)
 753                then
 754                   Warn_On_Useless_Assignment (Ent, N);
 755                   Set_Last_Assignment (Ent, Lhs);
 756                end if;
 757
 758                --  If we are assigning an access type and the left side is an
 759                --  entity, then make sure that the Is_Known_[Non_]Null flags
 760                --  properly reflect the state of the entity after assignment.
 761
 762                if Is_Access_Type (T1) then
 763                   if Known_Non_Null (Rhs) then
 764                      Set_Is_Known_Non_Null (Ent, True);
 765
 766                   elsif Known_Null (Rhs)
 767                     and then not Can_Never_Be_Null (Ent)
 768                   then
 769                      Set_Is_Known_Null (Ent, True);
 770
 771                   else
 772                      Set_Is_Known_Null (Ent, False);
 773
 774                      if not Can_Never_Be_Null (Ent) then
 775                         Set_Is_Known_Non_Null (Ent, False);
 776                      end if;
 777                   end if;
 778
 779                --  For discrete types, we may be able to set the current value
 780                --  if the value is known at compile time.
 781
 782                elsif Is_Discrete_Type (T1)
 783                  and then Compile_Time_Known_Value (Rhs)
 784                then
 785                   Set_Current_Value (Ent, Rhs);
 786                else
 787                   Set_Current_Value (Ent, Empty);
 788                end if;
 789
 790             --  If not safe to capture values, kill them
 791
 792             else
 793                Kill_Lhs;
 794             end if;
 795          end;
 796       end if;
 797    end Analyze_Assignment;
 798
 799    -----------------------------
 800    -- Analyze_Block_Statement --
 801    -----------------------------
 802
 803    procedure Analyze_Block_Statement (N : Node_Id) is
 804       Decls : constant List_Id := Declarations (N);
 805       Id    : constant Node_Id := Identifier (N);
 806       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 807
 808    begin
 809       --  Block statement is not allowed in SPARK or ALFA
 810
 811       if Formal_Verification_Mode
 812         and then Comes_From_Source (N)
 813       then
 814          Error_Msg_F ("|~~block statement is not allowed", N);
 815       end if;
 816
 817       --  If no handled statement sequence is present, things are really
 818       --  messed up, and we just return immediately (this is a defence
 819       --  against previous errors).
 820
 821       if No (HSS) then
 822          return;
 823       end if;
 824
 825       --  Normal processing with HSS present
 826
 827       declare
 828          EH  : constant List_Id := Exception_Handlers (HSS);
 829          Ent : Entity_Id        := Empty;
 830          S   : Entity_Id;
 831
 832          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 833          --  Recursively save value of this global, will be restored on exit
 834
 835       begin
 836          --  Initialize unblocked exit count for statements of begin block
 837          --  plus one for each exception handler that is present.
 838
 839          Unblocked_Exit_Count := 1;
 840
 841          if Present (EH) then
 842             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 843          end if;
 844
 845          --  If a label is present analyze it and mark it as referenced
 846
 847          if Present (Id) then
 848             Analyze (Id);
 849             Ent := Entity (Id);
 850
 851             --  An error defense. If we have an identifier, but no entity,
 852             --  then something is wrong. If we have previous errors, then
 853             --  just remove the identifier and continue, otherwise raise
 854             --  an exception.
 855
 856             if No (Ent) then
 857                if Total_Errors_Detected /= 0 then
 858                   Set_Identifier (N, Empty);
 859                else
 860                   raise Program_Error;
 861                end if;
 862
 863             else
 864                Set_Ekind (Ent, E_Block);
 865                Generate_Reference (Ent, N, ' ');
 866                Generate_Definition (Ent);
 867
 868                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 869                   Set_Label_Construct (Parent (Ent), N);
 870                end if;
 871             end if;
 872          end if;
 873
 874          --  If no entity set, create a label entity
 875
 876          if No (Ent) then
 877             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 878             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 879             Set_Parent (Ent, N);
 880          end if;
 881
 882          Set_Etype (Ent, Standard_Void_Type);
 883          Set_Block_Node (Ent, Identifier (N));
 884          Push_Scope (Ent);
 885
 886          if Present (Decls) then
 887             Analyze_Declarations (Decls);
 888             Check_Completion;
 889             Inspect_Deferred_Constant_Completion (Decls);
 890          end if;
 891
 892          Analyze (HSS);
 893          Process_End_Label (HSS, 'e', Ent);
 894
 895          --  If exception handlers are present, then we indicate that
 896          --  enclosing scopes contain a block with handlers. We only
 897          --  need to mark non-generic scopes.
 898
 899          if Present (EH) then
 900             S := Scope (Ent);
 901             loop
 902                Set_Has_Nested_Block_With_Handler (S);
 903                exit when Is_Overloadable (S)
 904                  or else Ekind (S) = E_Package
 905                  or else Is_Generic_Unit (S);
 906                S := Scope (S);
 907             end loop;
 908          end if;
 909
 910          Check_References (Ent);
 911          Warn_On_Useless_Assignments (Ent);
 912          End_Scope;
 913
 914          if Unblocked_Exit_Count = 0 then
 915             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 916             Check_Unreachable_Code (N);
 917          else
 918             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 919          end if;
 920       end;
 921    end Analyze_Block_Statement;
 922
 923    ----------------------------
 924    -- Analyze_Case_Statement --
 925    ----------------------------
 926
 927    procedure Analyze_Case_Statement (N : Node_Id) is
 928       Exp            : Node_Id;
 929       Exp_Type       : Entity_Id;
 930       Exp_Btype      : Entity_Id;
 931       Last_Choice    : Nat;
 932       Dont_Care      : Boolean;
 933       Others_Present : Boolean;
 934
 935       pragma Warnings (Off, Last_Choice);
 936       pragma Warnings (Off, Dont_Care);
 937       --  Don't care about assigned values
 938
 939       Statements_Analyzed : Boolean := False;
 940       --  Set True if at least some statement sequences get analyzed.
 941       --  If False on exit, means we had a serious error that prevented
 942       --  full analysis of the case statement, and as a result it is not
 943       --  a good idea to output warning messages about unreachable code.
 944
 945       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 946       --  Recursively save value of this global, will be restored on exit
 947
 948       procedure Non_Static_Choice_Error (Choice : Node_Id);
 949       --  Error routine invoked by the generic instantiation below when
 950       --  the case statement has a non static choice.
 951
 952       procedure Process_Statements (Alternative : Node_Id);
 953       --  Analyzes all the statements associated with a case alternative.
 954       --  Needed by the generic instantiation below.
 955
 956       package Case_Choices_Processing is new
 957         Generic_Choices_Processing
 958           (Get_Alternatives          => Alternatives,
 959            Get_Choices               => Discrete_Choices,
 960            Process_Empty_Choice      => No_OP,
 961            Process_Non_Static_Choice => Non_Static_Choice_Error,
 962            Process_Associated_Node   => Process_Statements);
 963       use Case_Choices_Processing;
 964       --  Instantiation of the generic choice processing package
 965
 966       -----------------------------
 967       -- Non_Static_Choice_Error --
 968       -----------------------------
 969
 970       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 971       begin
 972          Flag_Non_Static_Expr
 973            ("choice given in case statement is not static!", Choice);
 974       end Non_Static_Choice_Error;
 975
 976       ------------------------
 977       -- Process_Statements --
 978       ------------------------
 979
 980       procedure Process_Statements (Alternative : Node_Id) is
 981          Choices : constant List_Id := Discrete_Choices (Alternative);
 982          Ent     : Entity_Id;
 983
 984       begin
 985          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 986          Statements_Analyzed := True;
 987
 988          --  An interesting optimization. If the case statement expression
 989          --  is a simple entity, then we can set the current value within
 990          --  an alternative if the alternative has one possible value.
 991
 992          --    case N is
 993          --      when 1      => alpha
 994          --      when 2 | 3  => beta
 995          --      when others => gamma
 996
 997          --  Here we know that N is initially 1 within alpha, but for beta
 998          --  and gamma, we do not know anything more about the initial value.
 999
1000          if Is_Entity_Name (Exp) then
1001             Ent := Entity (Exp);
1002
1003             if Ekind_In (Ent, E_Variable,
1004                               E_In_Out_Parameter,
1005                               E_Out_Parameter)
1006             then
1007                if List_Length (Choices) = 1
1008                  and then Nkind (First (Choices)) in N_Subexpr
1009                  and then Compile_Time_Known_Value (First (Choices))
1010                then
1011                   Set_Current_Value (Entity (Exp), First (Choices));
1012                end if;
1013
1014                Analyze_Statements (Statements (Alternative));
1015
1016                --  After analyzing the case, set the current value to empty
1017                --  since we won't know what it is for the next alternative
1018                --  (unless reset by this same circuit), or after the case.
1019
1020                Set_Current_Value (Entity (Exp), Empty);
1021                return;
1022             end if;
1023          end if;
1024
1025          --  Case where expression is not an entity name of a variable
1026
1027          Analyze_Statements (Statements (Alternative));
1028       end Process_Statements;
1029
1030    --  Start of processing for Analyze_Case_Statement
1031
1032    begin
1033       Unblocked_Exit_Count := 0;
1034       Exp := Expression (N);
1035       Analyze (Exp);
1036
1037       --  The expression must be of any discrete type. In rare cases, the
1038       --  expander constructs a case statement whose expression has a private
1039       --  type whose full view is discrete. This can happen when generating
1040       --  a stream operation for a variant type after the type is frozen,
1041       --  when the partial of view of the type of the discriminant is private.
1042       --  In that case, use the full view to analyze case alternatives.
1043
1044       if not Is_Overloaded (Exp)
1045         and then not Comes_From_Source (N)
1046         and then Is_Private_Type (Etype (Exp))
1047         and then Present (Full_View (Etype (Exp)))
1048         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1049       then
1050          Resolve (Exp, Etype (Exp));
1051          Exp_Type := Full_View (Etype (Exp));
1052
1053       else
1054          Analyze_And_Resolve (Exp, Any_Discrete);
1055          Exp_Type := Etype (Exp);
1056       end if;
1057
1058       Check_Unset_Reference (Exp);
1059       Exp_Btype := Base_Type (Exp_Type);
1060
1061       --  The expression must be of a discrete type which must be determinable
1062       --  independently of the context in which the expression occurs, but
1063       --  using the fact that the expression must be of a discrete type.
1064       --  Moreover, the type this expression must not be a character literal
1065       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1066
1067       --  If error already reported by Resolve, nothing more to do
1068
1069       if Exp_Btype = Any_Discrete
1070         or else Exp_Btype = Any_Type
1071       then
1072          return;
1073
1074       elsif Exp_Btype = Any_Character then
1075          Error_Msg_N
1076            ("character literal as case expression is ambiguous", Exp);
1077          return;
1078
1079       elsif Ada_Version = Ada_83
1080         and then (Is_Generic_Type (Exp_Btype)
1081                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1082       then
1083          Error_Msg_N
1084            ("(Ada 83) case expression cannot be of a generic type", Exp);
1085          return;
1086       end if;
1087
1088       --  If the case expression is a formal object of mode in out, then
1089       --  treat it as having a nonstatic subtype by forcing use of the base
1090       --  type (which has to get passed to Check_Case_Choices below).  Also
1091       --  use base type when the case expression is parenthesized.
1092
1093       if Paren_Count (Exp) > 0
1094         or else (Is_Entity_Name (Exp)
1095                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1096       then
1097          Exp_Type := Exp_Btype;
1098       end if;
1099
1100       --  Call instantiated Analyze_Choices which does the rest of the work
1101
1102       Analyze_Choices (N, Exp_Type, Dont_Care, Others_Present);
1103
1104       --  A case statement with a single "others" alternative is not allowed
1105       --  in SPARK or ALFA.
1106
1107       if Formal_Verification_Mode
1108         and then Others_Present
1109         and then List_Length (Alternatives (N)) = 1
1110       then
1111          Error_Msg_F
1112            ("|~~OTHERS as unique case alternative is not allowed", N);
1113       end if;
1114
1115       if Exp_Type = Universal_Integer and then not Others_Present then
1116          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1117       end if;
1118
1119       --  If all our exits were blocked by unconditional transfers of control,
1120       --  then the entire CASE statement acts as an unconditional transfer of
1121       --  control, so treat it like one, and check unreachable code. Skip this
1122       --  test if we had serious errors preventing any statement analysis.
1123
1124       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1125          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1126          Check_Unreachable_Code (N);
1127       else
1128          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1129       end if;
1130
1131       if not Expander_Active
1132         and then Compile_Time_Known_Value (Expression (N))
1133         and then Serious_Errors_Detected = 0
1134       then
1135          declare
1136             Chosen : constant Node_Id := Find_Static_Alternative (N);
1137             Alt    : Node_Id;
1138
1139          begin
1140             Alt := First (Alternatives (N));
1141             while Present (Alt) loop
1142                if Alt /= Chosen then
1143                   Remove_Warning_Messages (Statements (Alt));
1144                end if;
1145
1146                Next (Alt);
1147             end loop;
1148          end;
1149       end if;
1150    end Analyze_Case_Statement;
1151
1152    ----------------------------
1153    -- Analyze_Exit_Statement --
1154    ----------------------------
1155
1156    --  If the exit includes a name, it must be the name of a currently open
1157    --  loop. Otherwise there must be an innermost open loop on the stack,
1158    --  to which the statement implicitly refers.
1159
1160    --  Additionally, in formal mode:
1161    --  * the exit can only name the closest enclosing loop;
1162    --  * an exit with a when clause must be directly contained in a loop;
1163    --  * an exit without a when clause must be directly contained in an
1164    --    if-statement with no elsif or else, which is itself directly contained
1165    --    in a loop. The exit must be the last statement in the if-statement.
1166
1167    procedure Analyze_Exit_Statement (N : Node_Id) is
1168       Target   : constant Node_Id := Name (N);
1169       Cond     : constant Node_Id := Condition (N);
1170       Scope_Id : Entity_Id;
1171       U_Name   : Entity_Id;
1172       Kind     : Entity_Kind;
1173
1174    begin
1175       if No (Cond) then
1176          Check_Unreachable_Code (N);
1177       end if;
1178
1179       if Present (Target) then
1180          Analyze (Target);
1181          U_Name := Entity (Target);
1182
1183          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1184             Error_Msg_N ("invalid loop name in exit statement", N);
1185             return;
1186          elsif Formal_Verification_Mode
1187            and then Has_Loop_In_Inner_Open_Scopes (U_Name)
1188          then
1189             Error_Msg_F
1190               ("|~~exit label must name the closest enclosing loop", N);
1191             return;
1192          else
1193             Set_Has_Exit (U_Name);
1194          end if;
1195
1196       else
1197          U_Name := Empty;
1198       end if;
1199
1200       for J in reverse 0 .. Scope_Stack.Last loop
1201          Scope_Id := Scope_Stack.Table (J).Entity;
1202          Kind := Ekind (Scope_Id);
1203
1204          if Kind = E_Loop
1205            and then (No (Target) or else Scope_Id = U_Name) then
1206             Set_Has_Exit (Scope_Id);
1207             exit;
1208
1209          elsif Kind = E_Block
1210            or else Kind = E_Loop
1211            or else Kind = E_Return_Statement
1212          then
1213             null;
1214
1215          else
1216             Error_Msg_N
1217               ("cannot exit from program unit or accept statement", N);
1218             return;
1219          end if;
1220       end loop;
1221
1222       --  Verify that if present the condition is a Boolean expression
1223
1224       if Present (Cond) then
1225          Analyze_And_Resolve (Cond, Any_Boolean);
1226          Check_Unset_Reference (Cond);
1227       end if;
1228
1229       --  In formal mode, verify that the exit statement respects the SPARK
1230       --  restrictions.
1231
1232       if Formal_Verification_Mode then
1233          if Present (Cond) then
1234             if Nkind (Parent (N)) /= N_Loop_Statement then
1235                Error_Msg_F
1236                  ("|~~exit with when clause must be directly in loop", N);
1237             end if;
1238
1239          else
1240             if Nkind (Parent (N)) /= N_If_Statement then
1241                if Nkind (Parent (N)) = N_Elsif_Part then
1242                   Error_Msg_F ("|~~exit must be in IF without ELSIF", N);
1243                else
1244                   Error_Msg_F ("|~~exit must be directly in IF", N);
1245                end if;
1246
1247             elsif Nkind (Parent (Parent (N))) /= N_Loop_Statement then
1248                Error_Msg_F ("|~~exit must be in IF directly in loop", N);
1249
1250             --  First test the presence of ELSE, so that an exit in an ELSE
1251             --  leads to an error mentioning the ELSE.
1252
1253             elsif Present (Else_Statements (Parent (N))) then
1254                Error_Msg_F ("|~~exit must be in IF without ELSE", N);
1255
1256             --  An exit in an ELSIF does not reach here, as it would have been
1257             --  detected in the case (Nkind (Parent (N)) /= N_If_Statement).
1258
1259             elsif Present (Elsif_Parts (Parent (N))) then
1260                Error_Msg_F ("|~~exit must be in IF without ELSIF", N);
1261             end if;
1262          end if;
1263       end if;
1264
1265       --  Chain exit statement to associated loop entity
1266
1267       Set_Next_Exit_Statement  (N, First_Exit_Statement (Scope_Id));
1268       Set_First_Exit_Statement (Scope_Id, N);
1269
1270       --  Since the exit may take us out of a loop, any previous assignment
1271       --  statement is not useless, so clear last assignment indications. It
1272       --  is OK to keep other current values, since if the exit statement
1273       --  does not exit, then the current values are still valid.
1274
1275       Kill_Current_Values (Last_Assignment_Only => True);
1276    end Analyze_Exit_Statement;
1277
1278    ----------------------------
1279    -- Analyze_Goto_Statement --
1280    ----------------------------
1281
1282    procedure Analyze_Goto_Statement (N : Node_Id) is
1283       Label       : constant Node_Id := Name (N);
1284       Scope_Id    : Entity_Id;
1285       Label_Scope : Entity_Id;
1286       Label_Ent   : Entity_Id;
1287
1288    begin
1289       --  Goto statement is not allowed in SPARK or ALFA
1290
1291       if Formal_Verification_Mode then
1292          Error_Msg_F ("|~~goto statement is not allowed", N);
1293       end if;
1294
1295       --  Actual semantic checks
1296
1297       Check_Unreachable_Code (N);
1298       Kill_Current_Values (Last_Assignment_Only => True);
1299
1300       Analyze (Label);
1301       Label_Ent := Entity (Label);
1302
1303       --  Ignore previous error
1304
1305       if Label_Ent = Any_Id then
1306          return;
1307
1308       --  We just have a label as the target of a goto
1309
1310       elsif Ekind (Label_Ent) /= E_Label then
1311          Error_Msg_N ("target of goto statement must be a label", Label);
1312          return;
1313
1314       --  Check that the target of the goto is reachable according to Ada
1315       --  scoping rules. Note: the special gotos we generate for optimizing
1316       --  local handling of exceptions would violate these rules, but we mark
1317       --  such gotos as analyzed when built, so this code is never entered.
1318
1319       elsif not Reachable (Label_Ent) then
1320          Error_Msg_N ("target of goto statement is not reachable", Label);
1321          return;
1322       end if;
1323
1324       --  Here if goto passes initial validity checks
1325
1326       Label_Scope := Enclosing_Scope (Label_Ent);
1327
1328       for J in reverse 0 .. Scope_Stack.Last loop
1329          Scope_Id := Scope_Stack.Table (J).Entity;
1330
1331          if Label_Scope = Scope_Id
1332            or else (Ekind (Scope_Id) /= E_Block
1333                      and then Ekind (Scope_Id) /= E_Loop
1334                      and then Ekind (Scope_Id) /= E_Return_Statement)
1335          then
1336             if Scope_Id /= Label_Scope then
1337                Error_Msg_N
1338                  ("cannot exit from program unit or accept statement", N);
1339             end if;
1340
1341             return;
1342          end if;
1343       end loop;
1344
1345       raise Program_Error;
1346    end Analyze_Goto_Statement;
1347
1348    --------------------------
1349    -- Analyze_If_Statement --
1350    --------------------------
1351
1352    --  A special complication arises in the analysis of if statements
1353
1354    --  The expander has circuitry to completely delete code that it
1355    --  can tell will not be executed (as a result of compile time known
1356    --  conditions). In the analyzer, we ensure that code that will be
1357    --  deleted in this manner is analyzed but not expanded. This is
1358    --  obviously more efficient, but more significantly, difficulties
1359    --  arise if code is expanded and then eliminated (e.g. exception
1360    --  table entries disappear). Similarly, itypes generated in deleted
1361    --  code must be frozen from start, because the nodes on which they
1362    --  depend will not be available at the freeze point.
1363
1364    procedure Analyze_If_Statement (N : Node_Id) is
1365       E : Node_Id;
1366
1367       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1368       --  Recursively save value of this global, will be restored on exit
1369
1370       Save_In_Deleted_Code : Boolean;
1371
1372       Del : Boolean := False;
1373       --  This flag gets set True if a True condition has been found,
1374       --  which means that remaining ELSE/ELSIF parts are deleted.
1375
1376       procedure Analyze_Cond_Then (Cnode : Node_Id);
1377       --  This is applied to either the N_If_Statement node itself or
1378       --  to an N_Elsif_Part node. It deals with analyzing the condition
1379       --  and the THEN statements associated with it.
1380
1381       -----------------------
1382       -- Analyze_Cond_Then --
1383       -----------------------
1384
1385       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1386          Cond : constant Node_Id := Condition (Cnode);
1387          Tstm : constant List_Id := Then_Statements (Cnode);
1388
1389       begin
1390          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1391          Analyze_And_Resolve (Cond, Any_Boolean);
1392          Check_Unset_Reference (Cond);
1393          Set_Current_Value_Condition (Cnode);
1394
1395          --  If already deleting, then just analyze then statements
1396
1397          if Del then
1398             Analyze_Statements (Tstm);
1399
1400          --  Compile time known value, not deleting yet
1401
1402          elsif Compile_Time_Known_Value (Cond) then
1403             Save_In_Deleted_Code := In_Deleted_Code;
1404
1405             --  If condition is True, then analyze the THEN statements
1406             --  and set no expansion for ELSE and ELSIF parts.
1407
1408             if Is_True (Expr_Value (Cond)) then
1409                Analyze_Statements (Tstm);
1410                Del := True;
1411                Expander_Mode_Save_And_Set (False);
1412                In_Deleted_Code := True;
1413
1414             --  If condition is False, analyze THEN with expansion off
1415
1416             else -- Is_False (Expr_Value (Cond))
1417                Expander_Mode_Save_And_Set (False);
1418                In_Deleted_Code := True;
1419                Analyze_Statements (Tstm);
1420                Expander_Mode_Restore;
1421                In_Deleted_Code := Save_In_Deleted_Code;
1422             end if;
1423
1424          --  Not known at compile time, not deleting, normal analysis
1425
1426          else
1427             Analyze_Statements (Tstm);
1428          end if;
1429       end Analyze_Cond_Then;
1430
1431    --  Start of Analyze_If_Statement
1432
1433    begin
1434       --  Initialize exit count for else statements. If there is no else
1435       --  part, this count will stay non-zero reflecting the fact that the
1436       --  uncovered else case is an unblocked exit.
1437
1438       Unblocked_Exit_Count := 1;
1439       Analyze_Cond_Then (N);
1440
1441       --  Now to analyze the elsif parts if any are present
1442
1443       if Present (Elsif_Parts (N)) then
1444          E := First (Elsif_Parts (N));
1445          while Present (E) loop
1446             Analyze_Cond_Then (E);
1447             Next (E);
1448          end loop;
1449       end if;
1450
1451       if Present (Else_Statements (N)) then
1452          Analyze_Statements (Else_Statements (N));
1453       end if;
1454
1455       --  If all our exits were blocked by unconditional transfers of control,
1456       --  then the entire IF statement acts as an unconditional transfer of
1457       --  control, so treat it like one, and check unreachable code.
1458
1459       if Unblocked_Exit_Count = 0 then
1460          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1461          Check_Unreachable_Code (N);
1462       else
1463          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1464       end if;
1465
1466       if Del then
1467          Expander_Mode_Restore;
1468          In_Deleted_Code := Save_In_Deleted_Code;
1469       end if;
1470
1471       if not Expander_Active
1472         and then Compile_Time_Known_Value (Condition (N))
1473         and then Serious_Errors_Detected = 0
1474       then
1475          if Is_True (Expr_Value (Condition (N))) then
1476             Remove_Warning_Messages (Else_Statements (N));
1477
1478             if Present (Elsif_Parts (N)) then
1479                E := First (Elsif_Parts (N));
1480                while Present (E) loop
1481                   Remove_Warning_Messages (Then_Statements (E));
1482                   Next (E);
1483                end loop;
1484             end if;
1485
1486          else
1487             Remove_Warning_Messages (Then_Statements (N));
1488          end if;
1489       end if;
1490    end Analyze_If_Statement;
1491
1492    ----------------------------------------
1493    -- Analyze_Implicit_Label_Declaration --
1494    ----------------------------------------
1495
1496    --  An implicit label declaration is generated in the innermost
1497    --  enclosing declarative part. This is done for labels as well as
1498    --  block and loop names.
1499
1500    --  Note: any changes in this routine may need to be reflected in
1501    --  Analyze_Label_Entity.
1502
1503    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1504       Id : constant Node_Id := Defining_Identifier (N);
1505    begin
1506       Enter_Name          (Id);
1507       Set_Ekind           (Id, E_Label);
1508       Set_Etype           (Id, Standard_Void_Type);
1509       Set_Enclosing_Scope (Id, Current_Scope);
1510    end Analyze_Implicit_Label_Declaration;
1511
1512    ------------------------------
1513    -- Analyze_Iteration_Scheme --
1514    ------------------------------
1515
1516    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1517
1518       procedure Process_Bounds (R : Node_Id);
1519       --  If the iteration is given by a range, create temporaries and
1520       --  assignment statements block to capture the bounds and perform
1521       --  required finalization actions in case a bound includes a function
1522       --  call that uses the temporary stack. We first pre-analyze a copy of
1523       --  the range in order to determine the expected type, and analyze and
1524       --  resolve the original bounds.
1525
1526       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1527       --  If the bounds are given by a 'Range reference on a function call
1528       --  that returns a controlled array, introduce an explicit declaration
1529       --  to capture the bounds, so that the function result can be finalized
1530       --  in timely fashion.
1531
1532       --------------------
1533       -- Process_Bounds --
1534       --------------------
1535
1536       procedure Process_Bounds (R : Node_Id) is
1537          Loc          : constant Source_Ptr := Sloc (N);
1538          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1539          Lo           : constant Node_Id := Low_Bound  (R);
1540          Hi           : constant Node_Id := High_Bound (R);
1541          New_Lo_Bound : Node_Id;
1542          New_Hi_Bound : Node_Id;
1543          Typ          : Entity_Id;
1544          Save_Analysis : Boolean;
1545
1546          function One_Bound
1547            (Original_Bound : Node_Id;
1548             Analyzed_Bound : Node_Id) return Node_Id;
1549          --  Capture value of bound and return captured value
1550
1551          ---------------
1552          -- One_Bound --
1553          ---------------
1554
1555          function One_Bound
1556            (Original_Bound : Node_Id;
1557             Analyzed_Bound : Node_Id) return Node_Id
1558          is
1559             Assign : Node_Id;
1560             Id     : Entity_Id;
1561             Decl   : Node_Id;
1562
1563          begin
1564             --  If the bound is a constant or an object, no need for a separate
1565             --  declaration. If the bound is the result of previous expansion
1566             --  it is already analyzed and should not be modified. Note that
1567             --  the Bound will be resolved later, if needed, as part of the
1568             --  call to Make_Index (literal bounds may need to be resolved to
1569             --  type Integer).
1570
1571             if Analyzed (Original_Bound) then
1572                return Original_Bound;
1573
1574             elsif Nkind_In (Analyzed_Bound, N_Integer_Literal,
1575                                             N_Character_Literal)
1576               or else Is_Entity_Name (Analyzed_Bound)
1577             then
1578                Analyze_And_Resolve (Original_Bound, Typ);
1579                return Original_Bound;
1580             end if;
1581
1582             --  Here we need to capture the value
1583
1584             Analyze_And_Resolve (Original_Bound, Typ);
1585
1586             Id := Make_Temporary (Loc, 'S', Original_Bound);
1587
1588             --  Normally, the best approach is simply to generate a constant
1589             --  declaration that captures the bound. However, there is a nasty
1590             --  case where this is wrong. If the bound is complex, and has a
1591             --  possible use of the secondary stack, we need to generate a
1592             --  separate assignment statement to ensure the creation of a block
1593             --  which will release the secondary stack.
1594
1595             --  We prefer the constant declaration, since it leaves us with a
1596             --  proper trace of the value, useful in optimizations that get rid
1597             --  of junk range checks.
1598
1599             --  Probably we want something like the Side_Effect_Free routine
1600             --  in Exp_Util, but for now, we just optimize the cases of 'Last
1601             --  and 'First applied to an entity, since these are the important
1602             --  cases for range check optimizations.
1603
1604             if Nkind (Original_Bound) = N_Attribute_Reference
1605               and then (Attribute_Name (Original_Bound) = Name_First
1606                           or else
1607                         Attribute_Name (Original_Bound) = Name_Last)
1608               and then Is_Entity_Name (Prefix (Original_Bound))
1609             then
1610                Decl :=
1611                  Make_Object_Declaration (Loc,
1612                    Defining_Identifier => Id,
1613                    Constant_Present    => True,
1614                    Object_Definition   => New_Occurrence_Of (Typ, Loc),
1615                    Expression          => Relocate_Node (Original_Bound));
1616
1617                --  Insert declaration at proper place. If loop comes from an
1618                --  enclosing quantified expression, the insertion point is
1619                --  arbitrarily far up in the tree.
1620
1621                Insert_Action (Parent (N), Decl);
1622                Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1623                return Expression (Decl);
1624             end if;
1625
1626             --  Here we make a declaration with a separate assignment
1627             --   statement, and insert before loop header.
1628
1629             Decl :=
1630               Make_Object_Declaration (Loc,
1631                 Defining_Identifier => Id,
1632                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1633
1634             Assign :=
1635               Make_Assignment_Statement (Loc,
1636                 Name        => New_Occurrence_Of (Id, Loc),
1637                 Expression  => Relocate_Node (Original_Bound));
1638
1639             Insert_Actions (Parent (N), New_List (Decl, Assign));
1640
1641             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1642
1643             if Nkind (Assign) = N_Assignment_Statement then
1644                return Expression (Assign);
1645             else
1646                return Original_Bound;
1647             end if;
1648          end One_Bound;
1649
1650       --  Start of processing for Process_Bounds
1651
1652       begin
1653          --  Determine expected type of range by analyzing separate copy
1654          --  Do the analysis and resolution of the copy of the bounds with
1655          --  expansion disabled, to prevent the generation of finalization
1656          --  actions on each bound. This prevents memory leaks when the
1657          --  bounds contain calls to functions returning controlled arrays.
1658
1659          Set_Parent (R_Copy, Parent (R));
1660          Save_Analysis := Full_Analysis;
1661          Full_Analysis := False;
1662          Expander_Mode_Save_And_Set (False);
1663
1664          Analyze (R_Copy);
1665
1666          if Is_Overloaded (R_Copy) then
1667
1668             --  Apply preference rules for range of predefined integer types,
1669             --  or diagnose true ambiguity.
1670
1671             declare
1672                I     : Interp_Index;
1673                It    : Interp;
1674                Found : Entity_Id := Empty;
1675
1676             begin
1677                Get_First_Interp (R_Copy, I, It);
1678                while Present (It.Typ) loop
1679                   if Is_Discrete_Type (It.Typ) then
1680                      if No (Found) then
1681                         Found := It.Typ;
1682                      else
1683                         if Scope (Found) = Standard_Standard then
1684                            null;
1685
1686                         elsif Scope (It.Typ) = Standard_Standard then
1687                            Found := It.Typ;
1688
1689                         else
1690                            --  Both of them are user-defined
1691
1692                            Error_Msg_N
1693                              ("ambiguous bounds in range of iteration",
1694                                R_Copy);
1695                            Error_Msg_N ("\possible interpretations:", R_Copy);
1696                            Error_Msg_NE ("\\} ", R_Copy, Found);
1697                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1698                            exit;
1699                         end if;
1700                      end if;
1701                   end if;
1702
1703                   Get_Next_Interp (I, It);
1704                end loop;
1705             end;
1706          end if;
1707
1708          Resolve (R_Copy);
1709          Expander_Mode_Restore;
1710          Full_Analysis := Save_Analysis;
1711
1712          Typ := Etype (R_Copy);
1713
1714          --  If the type of the discrete range is Universal_Integer, then
1715          --  the bound's type must be resolved to Integer, and any object
1716          --  used to hold the bound must also have type Integer, unless the
1717          --  literal bounds are constant-folded expressions that carry a user-
1718          --  defined type.
1719
1720          if Typ = Universal_Integer then
1721             if Nkind (Lo) = N_Integer_Literal
1722               and then Present (Etype (Lo))
1723               and then Scope (Etype (Lo)) /= Standard_Standard
1724             then
1725                Typ := Etype (Lo);
1726
1727             elsif Nkind (Hi) = N_Integer_Literal
1728               and then Present (Etype (Hi))
1729               and then Scope (Etype (Hi)) /= Standard_Standard
1730             then
1731                Typ := Etype (Hi);
1732
1733             else
1734                Typ := Standard_Integer;
1735             end if;
1736          end if;
1737
1738          Set_Etype (R, Typ);
1739
1740          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1741          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1742
1743          --  Propagate staticness to loop range itself, in case the
1744          --  corresponding subtype is static.
1745
1746          if New_Lo_Bound /= Lo
1747            and then Is_Static_Expression (New_Lo_Bound)
1748          then
1749             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1750          end if;
1751
1752          if New_Hi_Bound /= Hi
1753            and then Is_Static_Expression (New_Hi_Bound)
1754          then
1755             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1756          end if;
1757       end Process_Bounds;
1758
1759       --------------------------------------
1760       -- Check_Controlled_Array_Attribute --
1761       --------------------------------------
1762
1763       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1764       begin
1765          if Nkind (DS) = N_Attribute_Reference
1766             and then Is_Entity_Name (Prefix (DS))
1767             and then Ekind (Entity (Prefix (DS))) = E_Function
1768             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1769             and then
1770               Is_Controlled (
1771                 Component_Type (Etype (Entity (Prefix (DS)))))
1772             and then Expander_Active
1773          then
1774             declare
1775                Loc  : constant Source_Ptr := Sloc (N);
1776                Arr  : constant Entity_Id := Etype (Entity (Prefix (DS)));
1777                Indx : constant Entity_Id :=
1778                         Base_Type (Etype (First_Index (Arr)));
1779                Subt : constant Entity_Id := Make_Temporary (Loc, 'S');
1780                Decl : Node_Id;
1781
1782             begin
1783                Decl :=
1784                  Make_Subtype_Declaration (Loc,
1785                    Defining_Identifier => Subt,
1786                    Subtype_Indication  =>
1787                       Make_Subtype_Indication (Loc,
1788                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1789                         Constraint =>
1790                           Make_Range_Constraint (Loc,
1791                             Relocate_Node (DS))));
1792                Insert_Before (Parent (N), Decl);
1793                Analyze (Decl);
1794
1795                Rewrite (DS,
1796                   Make_Attribute_Reference (Loc,
1797                     Prefix => New_Reference_To (Subt, Loc),
1798                     Attribute_Name => Attribute_Name (DS)));
1799                Analyze (DS);
1800             end;
1801          end if;
1802       end Check_Controlled_Array_Attribute;
1803
1804    --  Start of processing for Analyze_Iteration_Scheme
1805
1806    begin
1807       --  If this is a rewritten quantified expression, the iteration
1808       --  scheme has been analyzed already. Do no repeat analysis because
1809       --  the loop variable is already declared.
1810
1811       if Analyzed (N) then
1812          return;
1813       end if;
1814
1815       --  For an infinite loop, there is no iteration scheme
1816
1817       if No (N) then
1818          return;
1819       end if;
1820
1821       --  Iteration scheme is present
1822
1823       declare
1824          Cond : constant Node_Id := Condition (N);
1825
1826       begin
1827          --  For WHILE loop, verify that the condition is a Boolean
1828          --  expression and resolve and check it.
1829
1830          if Present (Cond) then
1831             Analyze_And_Resolve (Cond, Any_Boolean);
1832             Check_Unset_Reference (Cond);
1833             Set_Current_Value_Condition (N);
1834             return;
1835
1836          elsif Present (Iterator_Specification (N)) then
1837             Analyze_Iterator_Specification (Iterator_Specification (N));
1838
1839          --  Else we have a FOR loop
1840
1841          else
1842             declare
1843                LP : constant Node_Id   := Loop_Parameter_Specification (N);
1844                Id : constant Entity_Id := Defining_Identifier (LP);
1845                DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1846
1847             begin
1848                Enter_Name (Id);
1849
1850                --  We always consider the loop variable to be referenced,
1851                --  since the loop may be used just for counting purposes.
1852
1853                Generate_Reference (Id, N, ' ');
1854
1855                --  Check for the case of loop variable hiding a local variable
1856                --  (used later on to give a nice warning if the hidden variable
1857                --  is never assigned).
1858
1859                declare
1860                   H : constant Entity_Id := Homonym (Id);
1861                begin
1862                   if Present (H)
1863                     and then Enclosing_Dynamic_Scope (H) =
1864                     Enclosing_Dynamic_Scope (Id)
1865                     and then Ekind (H) = E_Variable
1866                     and then Is_Discrete_Type (Etype (H))
1867                   then
1868                      Set_Hiding_Loop_Variable (H, Id);
1869                   end if;
1870                end;
1871
1872                --  Loop parameter specification must include subtype mark in
1873                --  SPARK or ALFA.
1874
1875                if Formal_Verification_Mode
1876                  and then Nkind (DS) = N_Range
1877                then
1878                   Error_Msg_F ("|~~loop parameter specification must "
1879                                & "include subtype mark", N);
1880                end if;
1881
1882                --  Now analyze the subtype definition. If it is a range, create
1883                --  temporaries for bounds.
1884
1885                if Nkind (DS) = N_Range
1886                  and then Expander_Active
1887                then
1888                   Process_Bounds (DS);
1889
1890                --  Not a range or expander not active (is that right???)
1891
1892                else
1893                   Analyze (DS);
1894
1895                   if Nkind (DS) = N_Function_Call
1896                     or else
1897                       (Is_Entity_Name (DS)
1898                         and then not Is_Type (Entity (DS)))
1899                   then
1900                      --  This is an iterator specification. Rewrite as such
1901                      --  and analyze.
1902
1903                      declare
1904                         I_Spec : constant Node_Id :=
1905                                    Make_Iterator_Specification (Sloc (LP),
1906                                      Defining_Identifier =>
1907                                        Relocate_Node (Id),
1908                                      Name                =>
1909                                        Relocate_Node (DS),
1910                                      Subtype_Indication  =>
1911                                        Empty,
1912                                      Reverse_Present     =>
1913                                        Reverse_Present (LP));
1914                      begin
1915                         Set_Iterator_Specification (N, I_Spec);
1916                         Set_Loop_Parameter_Specification (N, Empty);
1917                         Analyze_Iterator_Specification (I_Spec);
1918                         return;
1919                      end;
1920                   end if;
1921                end if;
1922
1923                if DS = Error then
1924                   return;
1925                end if;
1926
1927                --  Some additional checks if we are iterating through a type
1928
1929                if Is_Entity_Name (DS)
1930                  and then Present (Entity (DS))
1931                  and then Is_Type (Entity (DS))
1932                then
1933                   --  The subtype indication may denote the completion of an
1934                   --  incomplete type declaration.
1935
1936                   if Ekind (Entity (DS)) = E_Incomplete_Type then
1937                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1938                      Set_Etype  (DS, Entity (DS));
1939                   end if;
1940
1941                   --  Attempt to iterate through non-static predicate
1942
1943                   if Is_Discrete_Type (Entity (DS))
1944                     and then Present (Predicate_Function (Entity (DS)))
1945                     and then No (Static_Predicate (Entity (DS)))
1946                   then
1947                      Bad_Predicated_Subtype_Use
1948                        ("cannot use subtype& with non-static "
1949                         & "predicate for loop iteration", DS, Entity (DS));
1950                   end if;
1951                end if;
1952
1953                --  Error if not discrete type
1954
1955                if not Is_Discrete_Type (Etype (DS)) then
1956                   Wrong_Type (DS, Any_Discrete);
1957                   Set_Etype (DS, Any_Type);
1958                end if;
1959
1960                Check_Controlled_Array_Attribute (DS);
1961
1962                Make_Index (DS, LP);
1963
1964                Set_Ekind (Id, E_Loop_Parameter);
1965
1966                --  If the loop is part of a predicate or precondition, it may
1967                --  be analyzed twice, once in the source and once on the copy
1968                --  used to check conformance. Preserve the original itype
1969                --  because the second one may be created in a different scope,
1970                --  e.g. a precondition procedure, leading to a crash in GIGI.
1971
1972                if No (Etype (Id)) or else Etype (Id) = Any_Type then
1973                   Set_Etype (Id, Etype (DS));
1974                end if;
1975
1976                --  Treat a range as an implicit reference to the type, to
1977                --  inhibit spurious warnings.
1978
1979                Generate_Reference (Base_Type (Etype (DS)), N, ' ');
1980                Set_Is_Known_Valid (Id, True);
1981
1982                --  The loop is not a declarative part, so the only entity
1983                --  declared "within" must be frozen explicitly.
1984
1985                declare
1986                   Flist : constant List_Id := Freeze_Entity (Id, N);
1987                begin
1988                   if Is_Non_Empty_List (Flist) then
1989                      Insert_Actions (N, Flist);
1990                   end if;
1991                end;
1992
1993                --  Check for null or possibly null range and issue warning. We
1994                --  suppress such messages in generic templates and instances,
1995                --  because in practice they tend to be dubious in these cases.
1996
1997                if Nkind (DS) = N_Range and then Comes_From_Source (N) then
1998                   declare
1999                      L : constant Node_Id := Low_Bound  (DS);
2000                      H : constant Node_Id := High_Bound (DS);
2001
2002                   begin
2003                      --  If range of loop is null, issue warning
2004
2005                      if Compile_Time_Compare
2006                           (L, H, Assume_Valid => True) = GT
2007                      then
2008                         --  Suppress the warning if inside a generic template
2009                         --  or instance, since in practice they tend to be
2010                         --  dubious in these cases since they can result from
2011                         --  intended parametrization.
2012
2013                         if not Inside_A_Generic
2014                           and then not In_Instance
2015                         then
2016                            --  Specialize msg if invalid values could make
2017                            --  the loop non-null after all.
2018
2019                            if Compile_Time_Compare
2020                                 (L, H, Assume_Valid => False) = GT
2021                            then
2022                               Error_Msg_N
2023                                 ("?loop range is null, loop will not execute",
2024                                  DS);
2025
2026                               --  Since we know the range of the loop is
2027                               --  null, set the appropriate flag to remove
2028                               --  the loop entirely during expansion.
2029
2030                               Set_Is_Null_Loop (Parent (N));
2031
2032                               --  Here is where the loop could execute because
2033                               --  of invalid values, so issue appropriate
2034                               --  message and in this case we do not set the
2035                               --  Is_Null_Loop flag since the loop may execute.
2036
2037                            else
2038                               Error_Msg_N
2039                                 ("?loop range may be null, "
2040                                  & "loop may not execute",
2041                                  DS);
2042                               Error_Msg_N
2043                                 ("?can only execute if invalid values "
2044                                  & "are present",
2045                                  DS);
2046                            end if;
2047                         end if;
2048
2049                         --  In either case, suppress warnings in the body of
2050                         --  the loop, since it is likely that these warnings
2051                         --  will be inappropriate if the loop never actually
2052                         --  executes, which is likely.
2053
2054                         Set_Suppress_Loop_Warnings (Parent (N));
2055
2056                         --  The other case for a warning is a reverse loop
2057                         --  where the upper bound is the integer literal zero
2058                         --  or one, and the lower bound can be positive.
2059
2060                         --  For example, we have
2061
2062                         --     for J in reverse N .. 1 loop
2063
2064                         --  In practice, this is very likely to be a case of
2065                         --  reversing the bounds incorrectly in the range.
2066
2067                      elsif Reverse_Present (LP)
2068                        and then Nkind (Original_Node (H)) =
2069                                                       N_Integer_Literal
2070                        and then (Intval (Original_Node (H)) = Uint_0
2071                                   or else
2072                                     Intval (Original_Node (H)) = Uint_1)
2073                      then
2074                         Error_Msg_N ("?loop range may be null", DS);
2075                         Error_Msg_N ("\?bounds may be wrong way round", DS);
2076                      end if;
2077                   end;
2078                end if;
2079             end;
2080          end if;
2081       end;
2082    end Analyze_Iteration_Scheme;
2083
2084    -------------------------------------
2085    --  Analyze_Iterator_Specification --
2086    -------------------------------------
2087
2088    procedure Analyze_Iterator_Specification (N : Node_Id) is
2089       Def_Id    : constant Node_Id := Defining_Identifier (N);
2090       Subt      : constant Node_Id := Subtype_Indication (N);
2091       Container : constant Node_Id := Name (N);
2092
2093       Ent : Entity_Id;
2094       Typ : Entity_Id;
2095
2096    begin
2097       Enter_Name (Def_Id);
2098       Set_Ekind (Def_Id, E_Variable);
2099
2100       if Present (Subt) then
2101          Analyze (Subt);
2102       end if;
2103
2104       Analyze_And_Resolve (Container);
2105       Typ := Etype (Container);
2106
2107       if Is_Array_Type (Typ) then
2108          if Of_Present (N) then
2109             Set_Etype (Def_Id, Component_Type (Typ));
2110          else
2111             Error_Msg_N
2112               ("to iterate over the elements of an array, use OF", N);
2113             Set_Etype (Def_Id, Etype (First_Index (Typ)));
2114          end if;
2115
2116       --  Iteration over a container
2117
2118       else
2119          Set_Ekind (Def_Id, E_Loop_Parameter);
2120
2121          if Of_Present (N) then
2122
2123             --  Find the Element_Type in the package instance that defines the
2124             --  container type.
2125
2126             Ent := First_Entity (Scope (Typ));
2127             while Present (Ent) loop
2128                if Chars (Ent) = Name_Element_Type then
2129                   Set_Etype (Def_Id, Ent);
2130                   exit;
2131                end if;
2132
2133                Next_Entity (Ent);
2134             end loop;
2135
2136          else
2137             --  Find the Cursor type in similar fashion
2138
2139             Ent := First_Entity (Scope (Typ));
2140             while Present (Ent) loop
2141                if Chars (Ent) = Name_Cursor then
2142                   Set_Etype (Def_Id, Ent);
2143                   exit;
2144                end if;
2145
2146                Next_Entity (Ent);
2147             end loop;
2148          end if;
2149       end if;
2150    end Analyze_Iterator_Specification;
2151
2152    -------------------
2153    -- Analyze_Label --
2154    -------------------
2155
2156    --  Note: the semantic work required for analyzing labels (setting them as
2157    --  reachable) was done in a prepass through the statements in the block,
2158    --  so that forward gotos would be properly handled. See Analyze_Statements
2159    --  for further details. The only processing required here is to deal with
2160    --  optimizations that depend on an assumption of sequential control flow,
2161    --  since of course the occurrence of a label breaks this assumption.
2162
2163    procedure Analyze_Label (N : Node_Id) is
2164       pragma Warnings (Off, N);
2165    begin
2166       Kill_Current_Values;
2167    end Analyze_Label;
2168
2169    --------------------------
2170    -- Analyze_Label_Entity --
2171    --------------------------
2172
2173    procedure Analyze_Label_Entity (E : Entity_Id) is
2174    begin
2175       Set_Ekind           (E, E_Label);
2176       Set_Etype           (E, Standard_Void_Type);
2177       Set_Enclosing_Scope (E, Current_Scope);
2178       Set_Reachable       (E, True);
2179    end Analyze_Label_Entity;
2180
2181    ----------------------------
2182    -- Analyze_Loop_Statement --
2183    ----------------------------
2184
2185    procedure Analyze_Loop_Statement (N : Node_Id) is
2186       Loop_Statement : constant Node_Id := N;
2187
2188       Id   : constant Node_Id := Identifier (Loop_Statement);
2189       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
2190       Ent  : Entity_Id;
2191
2192    begin
2193       if Present (Id) then
2194
2195          --  Make name visible, e.g. for use in exit statements. Loop
2196          --  labels are always considered to be referenced.
2197
2198          Analyze (Id);
2199          Ent := Entity (Id);
2200
2201          --  Guard against serious error (typically, a scope mismatch when
2202          --  semantic analysis is requested) by creating loop entity to
2203          --  continue analysis.
2204
2205          if No (Ent) then
2206             if Total_Errors_Detected /= 0 then
2207                Ent :=
2208                  New_Internal_Entity
2209                    (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2210             else
2211                raise Program_Error;
2212             end if;
2213
2214          else
2215             Generate_Reference  (Ent, Loop_Statement, ' ');
2216             Generate_Definition (Ent);
2217
2218             --  If we found a label, mark its type. If not, ignore it, since it
2219             --  means we have a conflicting declaration, which would already
2220             --  have been diagnosed at declaration time. Set Label_Construct
2221             --  of the implicit label declaration, which is not created by the
2222             --  parser for generic units.
2223
2224             if Ekind (Ent) = E_Label then
2225                Set_Ekind (Ent, E_Loop);
2226
2227                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
2228                   Set_Label_Construct (Parent (Ent), Loop_Statement);
2229                end if;
2230             end if;
2231          end if;
2232
2233       --  Case of no identifier present
2234
2235       else
2236          Ent :=
2237            New_Internal_Entity
2238              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2239          Set_Etype (Ent,  Standard_Void_Type);
2240          Set_Parent (Ent, Loop_Statement);
2241       end if;
2242
2243       --  Kill current values on entry to loop, since statements in body of
2244       --  loop may have been executed before the loop is entered. Similarly we
2245       --  kill values after the loop, since we do not know that the body of the
2246       --  loop was executed.
2247
2248       Kill_Current_Values;
2249       Push_Scope (Ent);
2250       Analyze_Iteration_Scheme (Iter);
2251       Analyze_Statements (Statements (Loop_Statement));
2252       Process_End_Label (Loop_Statement, 'e', Ent);
2253       End_Scope;
2254       Kill_Current_Values;
2255
2256       --  Check for infinite loop. Skip check for generated code, since it
2257       --  justs waste time and makes debugging the routine called harder.
2258
2259       --  Note that we have to wait till the body of the loop is fully analyzed
2260       --  before making this call, since Check_Infinite_Loop_Warning relies on
2261       --  being able to use semantic visibility information to find references.
2262
2263       if Comes_From_Source (N) then
2264          Check_Infinite_Loop_Warning (N);
2265       end if;
2266
2267       --  Code after loop is unreachable if the loop has no WHILE or FOR
2268       --  and contains no EXIT statements within the body of the loop.
2269
2270       if No (Iter) and then not Has_Exit (Ent) then
2271          Check_Unreachable_Code (N);
2272       end if;
2273    end Analyze_Loop_Statement;
2274
2275    ----------------------------
2276    -- Analyze_Null_Statement --
2277    ----------------------------
2278
2279    --  Note: the semantics of the null statement is implemented by a single
2280    --  null statement, too bad everything isn't as simple as this!
2281
2282    procedure Analyze_Null_Statement (N : Node_Id) is
2283       pragma Warnings (Off, N);
2284    begin
2285       null;
2286    end Analyze_Null_Statement;
2287
2288    ------------------------
2289    -- Analyze_Statements --
2290    ------------------------
2291
2292    procedure Analyze_Statements (L : List_Id) is
2293       S   : Node_Id;
2294       Lab : Entity_Id;
2295
2296    begin
2297       --  The labels declared in the statement list are reachable from
2298       --  statements in the list. We do this as a prepass so that any
2299       --  goto statement will be properly flagged if its target is not
2300       --  reachable. This is not required, but is nice behavior!
2301
2302       S := First (L);
2303       while Present (S) loop
2304          if Nkind (S) = N_Label then
2305             Analyze (Identifier (S));
2306             Lab := Entity (Identifier (S));
2307
2308             --  If we found a label mark it as reachable
2309
2310             if Ekind (Lab) = E_Label then
2311                Generate_Definition (Lab);
2312                Set_Reachable (Lab);
2313
2314                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
2315                   Set_Label_Construct (Parent (Lab), S);
2316                end if;
2317
2318             --  If we failed to find a label, it means the implicit declaration
2319             --  of the label was hidden.  A for-loop parameter can do this to
2320             --  a label with the same name inside the loop, since the implicit
2321             --  label declaration is in the innermost enclosing body or block
2322             --  statement.
2323
2324             else
2325                Error_Msg_Sloc := Sloc (Lab);
2326                Error_Msg_N
2327                  ("implicit label declaration for & is hidden#",
2328                   Identifier (S));
2329             end if;
2330          end if;
2331
2332          Next (S);
2333       end loop;
2334
2335       --  Perform semantic analysis on all statements
2336
2337       Conditional_Statements_Begin;
2338
2339       S := First (L);
2340       while Present (S) loop
2341          Analyze (S);
2342          Next (S);
2343       end loop;
2344
2345       Conditional_Statements_End;
2346
2347       --  Make labels unreachable. Visibility is not sufficient, because
2348       --  labels in one if-branch for example are not reachable from the
2349       --  other branch, even though their declarations are in the enclosing
2350       --  declarative part.
2351
2352       S := First (L);
2353       while Present (S) loop
2354          if Nkind (S) = N_Label then
2355             Set_Reachable (Entity (Identifier (S)), False);
2356          end if;
2357
2358          Next (S);
2359       end loop;
2360    end Analyze_Statements;
2361
2362    ----------------------------
2363    -- Check_Unreachable_Code --
2364    ----------------------------
2365
2366    procedure Check_Unreachable_Code (N : Node_Id) is
2367       Error_Loc : Source_Ptr;
2368       P         : Node_Id;
2369
2370    begin
2371       if Is_List_Member (N)
2372         and then Comes_From_Source (N)
2373       then
2374          declare
2375             Nxt : Node_Id;
2376
2377          begin
2378             Nxt := Original_Node (Next (N));
2379
2380             --  If a label follows us, then we never have dead code, since
2381             --  someone could branch to the label, so we just ignore it,
2382             --  unless we are in formal mode where goto statements are not
2383             --  allowed.
2384
2385             if Nkind (Nxt) = N_Label and then not Formal_Verification_Mode then
2386                return;
2387
2388             --  Otherwise see if we have a real statement following us
2389
2390             elsif Present (Nxt)
2391               and then Comes_From_Source (Nxt)
2392               and then Is_Statement (Nxt)
2393             then
2394                --  Special very annoying exception. If we have a return that
2395                --  follows a raise, then we allow it without a warning, since
2396                --  the Ada RM annoyingly requires a useless return here!
2397
2398                if Nkind (Original_Node (N)) /= N_Raise_Statement
2399                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2400                then
2401                   --  The rather strange shenanigans with the warning message
2402                   --  here reflects the fact that Kill_Dead_Code is very good
2403                   --  at removing warnings in deleted code, and this is one
2404                   --  warning we would prefer NOT to have removed.
2405
2406                   Error_Loc := Sloc (Nxt);
2407
2408                   --  If we have unreachable code, analyze and remove the
2409                   --  unreachable code, since it is useless and we don't
2410                   --  want to generate junk warnings.
2411
2412                   --  We skip this step if we are not in code generation mode.
2413                   --  This is the one case where we remove dead code in the
2414                   --  semantics as opposed to the expander, and we do not want
2415                   --  to remove code if we are not in code generation mode,
2416                   --  since this messes up the ASIS trees.
2417
2418                   --  Note that one might react by moving the whole circuit to
2419                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2420
2421                   if Operating_Mode = Generate_Code then
2422                      loop
2423                         Nxt := Next (N);
2424
2425                         --  Quit deleting when we have nothing more to delete
2426                         --  or if we hit a label (since someone could transfer
2427                         --  control to a label, so we should not delete it).
2428
2429                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2430
2431                         --  Statement/declaration is to be deleted
2432
2433                         Analyze (Nxt);
2434                         Remove (Nxt);
2435                         Kill_Dead_Code (Nxt);
2436                      end loop;
2437                   end if;
2438
2439                   --  Now issue the warning (or error in formal mode)
2440
2441                   if Formal_Verification_Mode then
2442                      Error_Msg
2443                        ("|~~unreachable code is not allowed", Error_Loc);
2444                   else
2445                      Error_Msg ("?unreachable code!", Error_Loc);
2446                   end if;
2447                end if;
2448
2449             --  If the unconditional transfer of control instruction is
2450             --  the last statement of a sequence, then see if our parent
2451             --  is one of the constructs for which we count unblocked exits,
2452             --  and if so, adjust the count.
2453
2454             else
2455                P := Parent (N);
2456
2457                --  Statements in THEN part or ELSE part of IF statement
2458
2459                if Nkind (P) = N_If_Statement then
2460                   null;
2461
2462                --  Statements in ELSIF part of an IF statement
2463
2464                elsif Nkind (P) = N_Elsif_Part then
2465                   P := Parent (P);
2466                   pragma Assert (Nkind (P) = N_If_Statement);
2467
2468                --  Statements in CASE statement alternative
2469
2470                elsif Nkind (P) = N_Case_Statement_Alternative then
2471                   P := Parent (P);
2472                   pragma Assert (Nkind (P) = N_Case_Statement);
2473
2474                --  Statements in body of block
2475
2476                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2477                  and then Nkind (Parent (P)) = N_Block_Statement
2478                then
2479                   null;
2480
2481                --  Statements in exception handler in a block
2482
2483                elsif Nkind (P) = N_Exception_Handler
2484                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2485                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2486                then
2487                   null;
2488
2489                --  None of these cases, so return
2490
2491                else
2492                   return;
2493                end if;
2494
2495                --  This was one of the cases we are looking for (i.e. the
2496                --  parent construct was IF, CASE or block) so decrement count.
2497
2498                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2499             end if;
2500          end;
2501       end if;
2502    end Check_Unreachable_Code;
2503
2504 end Sem_Ch5;