gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Aux;  use Sem_Aux;
  42 with Sem_Case; use Sem_Case;
  43 with Sem_Ch3;  use Sem_Ch3;
  44 with Sem_Ch8;  use Sem_Ch8;
  45 with Sem_Disp; use Sem_Disp;
  46 with Sem_Elab; use Sem_Elab;
  47 with Sem_Eval; use Sem_Eval;
  48 with Sem_Res;  use Sem_Res;
  49 with Sem_Type; use Sem_Type;
  50 with Sem_Util; use Sem_Util;
  51 with Sem_Warn; use Sem_Warn;
  52 with Snames;   use Snames;
  53 with Stand;    use Stand;
  54 with Sinfo;    use Sinfo;
  55 with Targparm; use Targparm;
  56 with Tbuild;   use Tbuild;
  57 with Uintp;    use Uintp;
  58
  59 package body Sem_Ch5 is
  60
  61    Unblocked_Exit_Count : Nat := 0;
  62    --  This variable is used when processing if statements, case statements,
  63    --  and block statements. It counts the number of exit points that are not
  64    --  blocked by unconditional transfer instructions: for IF and CASE, these
  65    --  are the branches of the conditional; for a block, they are the statement
  66    --  sequence of the block, and the statement sequences of any exception
  67    --  handlers that are part of the block. When processing is complete, if
  68    --  this count is zero, it means that control cannot fall through the IF,
  69    --  CASE or block statement. This is used for the generation of warning
  70    --  messages. This variable is recursively saved on entry to processing the
  71    --  construct, and restored on exit.
  72
  73    ------------------------
  74    -- Analyze_Assignment --
  75    ------------------------
  76
  77    procedure Analyze_Assignment (N : Node_Id) is
  78       Lhs  : constant Node_Id := Name (N);
  79       Rhs  : constant Node_Id := Expression (N);
  80       T1   : Entity_Id;
  81       T2   : Entity_Id;
  82       Decl : Node_Id;
  83
  84       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  85       --  N is the node for the left hand side of an assignment, and it is not
  86       --  a variable. This routine issues an appropriate diagnostic.
  87
  88       procedure Kill_Lhs;
  89       --  This is called to kill current value settings of a simple variable
  90       --  on the left hand side. We call it if we find any error in analyzing
  91       --  the assignment, and at the end of processing before setting any new
  92       --  current values in place.
  93
  94       procedure Set_Assignment_Type
  95         (Opnd      : Node_Id;
  96          Opnd_Type : in out Entity_Id);
  97       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
  98       --  is the nominal subtype. This procedure is used to deal with cases
  99       --  where the nominal subtype must be replaced by the actual subtype.
 100
 101       -------------------------------
 102       -- Diagnose_Non_Variable_Lhs --
 103       -------------------------------
 104
 105       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 106       begin
 107          --  Not worth posting another error if left hand side already
 108          --  flagged as being illegal in some respect.
 109
 110          if Error_Posted (N) then
 111             return;
 112
 113          --  Some special bad cases of entity names
 114
 115          elsif Is_Entity_Name (N) then
 116             declare
 117                Ent : constant Entity_Id := Entity (N);
 118
 119             begin
 120                if Ekind (Ent) = E_In_Parameter then
 121                   Error_Msg_N
 122                     ("assignment to IN mode parameter not allowed", N);
 123
 124                --  Renamings of protected private components are turned into
 125                --  constants when compiling a protected function. In the case
 126                --  of single protected types, the private component appears
 127                --  directly.
 128
 129                elsif (Is_Prival (Ent)
 130                         and then
 131                           (Ekind (Current_Scope) = E_Function
 132                              or else Ekind (Enclosing_Dynamic_Scope (
 133                                        Current_Scope)) = E_Function))
 134                    or else
 135                      (Ekind (Ent) = E_Component
 136                         and then Is_Protected_Type (Scope (Ent)))
 137                then
 138                   Error_Msg_N
 139                     ("protected function cannot modify protected object", N);
 140
 141                elsif Ekind (Ent) = E_Loop_Parameter then
 142                   Error_Msg_N
 143                     ("assignment to loop parameter not allowed", N);
 144
 145                else
 146                   Error_Msg_N
 147                     ("left hand side of assignment must be a variable", N);
 148                end if;
 149             end;
 150
 151          --  For indexed components or selected components, test prefix
 152
 153          elsif Nkind (N) = N_Indexed_Component then
 154             Diagnose_Non_Variable_Lhs (Prefix (N));
 155
 156          --  Another special case for assignment to discriminant
 157
 158          elsif Nkind (N) = N_Selected_Component then
 159             if Present (Entity (Selector_Name (N)))
 160               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 161             then
 162                Error_Msg_N
 163                  ("assignment to discriminant not allowed", N);
 164             else
 165                Diagnose_Non_Variable_Lhs (Prefix (N));
 166             end if;
 167
 168          else
 169             --  If we fall through, we have no special message to issue!
 170
 171             Error_Msg_N ("left hand side of assignment must be a variable", N);
 172          end if;
 173       end Diagnose_Non_Variable_Lhs;
 174
 175       --------------
 176       -- Kill_LHS --
 177       --------------
 178
 179       procedure Kill_Lhs is
 180       begin
 181          if Is_Entity_Name (Lhs) then
 182             declare
 183                Ent : constant Entity_Id := Entity (Lhs);
 184             begin
 185                if Present (Ent) then
 186                   Kill_Current_Values (Ent);
 187                end if;
 188             end;
 189          end if;
 190       end Kill_Lhs;
 191
 192       -------------------------
 193       -- Set_Assignment_Type --
 194       -------------------------
 195
 196       procedure Set_Assignment_Type
 197         (Opnd      : Node_Id;
 198          Opnd_Type : in out Entity_Id)
 199       is
 200       begin
 201          Require_Entity (Opnd);
 202
 203          --  If the assignment operand is an in-out or out parameter, then we
 204          --  get the actual subtype (needed for the unconstrained case).
 205          --  If the operand is the actual in an entry declaration, then within
 206          --  the accept statement it is replaced with a local renaming, which
 207          --  may also have an actual subtype.
 208
 209          if Is_Entity_Name (Opnd)
 210            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 211                       or else Ekind (Entity (Opnd)) =
 212                            E_In_Out_Parameter
 213                       or else Ekind (Entity (Opnd)) =
 214                            E_Generic_In_Out_Parameter
 215                       or else
 216                         (Ekind (Entity (Opnd)) = E_Variable
 217                           and then Nkind (Parent (Entity (Opnd))) =
 218                              N_Object_Renaming_Declaration
 219                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 220                              N_Accept_Statement))
 221          then
 222             Opnd_Type := Get_Actual_Subtype (Opnd);
 223
 224          --  If assignment operand is a component reference, then we get the
 225          --  actual subtype of the component for the unconstrained case.
 226
 227          elsif Nkind_In (Opnd, N_Selected_Component, N_Explicit_Dereference)
 228            and then not Is_Unchecked_Union (Opnd_Type)
 229          then
 230             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 231
 232             if Present (Decl) then
 233                Insert_Action (N, Decl);
 234                Mark_Rewrite_Insertion (Decl);
 235                Analyze (Decl);
 236                Opnd_Type := Defining_Identifier (Decl);
 237                Set_Etype (Opnd, Opnd_Type);
 238                Freeze_Itype (Opnd_Type, N);
 239
 240             elsif Is_Constrained (Etype (Opnd)) then
 241                Opnd_Type := Etype (Opnd);
 242             end if;
 243
 244          --  For slice, use the constrained subtype created for the slice
 245
 246          elsif Nkind (Opnd) = N_Slice then
 247             Opnd_Type := Etype (Opnd);
 248          end if;
 249       end Set_Assignment_Type;
 250
 251    --  Start of processing for Analyze_Assignment
 252
 253    begin
 254       Mark_Coextensions (N, Rhs);
 255
 256       Analyze (Rhs);
 257       Analyze (Lhs);
 258
 259       --  Start type analysis for assignment
 260
 261       T1 := Etype (Lhs);
 262
 263       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 264       --  must compute the intersection of the possible types on each side.
 265
 266       if Is_Overloaded (Lhs) then
 267          declare
 268             I  : Interp_Index;
 269             It : Interp;
 270
 271          begin
 272             T1 := Any_Type;
 273             Get_First_Interp (Lhs, I, It);
 274
 275             while Present (It.Typ) loop
 276                if Has_Compatible_Type (Rhs, It.Typ) then
 277                   if T1 /= Any_Type then
 278
 279                      --  An explicit dereference is overloaded if the prefix
 280                      --  is. Try to remove the ambiguity on the prefix, the
 281                      --  error will be posted there if the ambiguity is real.
 282
 283                      if Nkind (Lhs) = N_Explicit_Dereference then
 284                         declare
 285                            PI    : Interp_Index;
 286                            PI1   : Interp_Index := 0;
 287                            PIt   : Interp;
 288                            Found : Boolean;
 289
 290                         begin
 291                            Found := False;
 292                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 293
 294                            while Present (PIt.Typ) loop
 295                               if Is_Access_Type (PIt.Typ)
 296                                 and then Has_Compatible_Type
 297                                            (Rhs, Designated_Type (PIt.Typ))
 298                               then
 299                                  if Found then
 300                                     PIt :=
 301                                       Disambiguate (Prefix (Lhs),
 302                                         PI1, PI, Any_Type);
 303
 304                                     if PIt = No_Interp then
 305                                        Error_Msg_N
 306                                          ("ambiguous left-hand side"
 307                                             & " in assignment", Lhs);
 308                                        exit;
 309                                     else
 310                                        Resolve (Prefix (Lhs), PIt.Typ);
 311                                     end if;
 312
 313                                     exit;
 314                                  else
 315                                     Found := True;
 316                                     PI1 := PI;
 317                                  end if;
 318                               end if;
 319
 320                               Get_Next_Interp (PI, PIt);
 321                            end loop;
 322                         end;
 323
 324                      else
 325                         Error_Msg_N
 326                           ("ambiguous left-hand side in assignment", Lhs);
 327                         exit;
 328                      end if;
 329                   else
 330                      T1 := It.Typ;
 331                   end if;
 332                end if;
 333
 334                Get_Next_Interp (I, It);
 335             end loop;
 336          end;
 337
 338          if T1 = Any_Type then
 339             Error_Msg_N
 340               ("no valid types for left-hand side for assignment", Lhs);
 341             Kill_Lhs;
 342             return;
 343          end if;
 344       end if;
 345
 346       --  The resulting assignment type is T1, so now we will resolve the
 347       --  left hand side of the assignment using this determined type.
 348
 349       Resolve (Lhs, T1);
 350
 351       --  Cases where Lhs is not a variable
 352
 353       if not Is_Variable (Lhs) then
 354
 355          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 356          --  a protected object.
 357
 358          declare
 359             Ent : Entity_Id;
 360             S   : Entity_Id;
 361
 362          begin
 363             if Ada_Version >= Ada_2005 then
 364
 365                --  Handle chains of renamings
 366
 367                Ent := Lhs;
 368                while Nkind (Ent) in N_Has_Entity
 369                  and then Present (Entity (Ent))
 370                  and then Present (Renamed_Object (Entity (Ent)))
 371                loop
 372                   Ent := Renamed_Object (Entity (Ent));
 373                end loop;
 374
 375                if (Nkind (Ent) = N_Attribute_Reference
 376                      and then Attribute_Name (Ent) = Name_Priority)
 377
 378                   --  Renamings of the attribute Priority applied to protected
 379                   --  objects have been previously expanded into calls to the
 380                   --  Get_Ceiling run-time subprogram.
 381
 382                  or else
 383                   (Nkind (Ent) = N_Function_Call
 384                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 385                                 or else
 386                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 387                then
 388                   --  The enclosing subprogram cannot be a protected function
 389
 390                   S := Current_Scope;
 391                   while not (Is_Subprogram (S)
 392                                and then Convention (S) = Convention_Protected)
 393                      and then S /= Standard_Standard
 394                   loop
 395                      S := Scope (S);
 396                   end loop;
 397
 398                   if Ekind (S) = E_Function
 399                     and then Convention (S) = Convention_Protected
 400                   then
 401                      Error_Msg_N
 402                        ("protected function cannot modify protected object",
 403                         Lhs);
 404                   end if;
 405
 406                   --  Changes of the ceiling priority of the protected object
 407                   --  are only effective if the Ceiling_Locking policy is in
 408                   --  effect (AARM D.5.2 (5/2)).
 409
 410                   if Locking_Policy /= 'C' then
 411                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 412                                   "no effect?", Lhs);
 413                      Error_Msg_N ("\since no Locking_Policy has been " &
 414                                   "specified", Lhs);
 415                   end if;
 416
 417                   return;
 418                end if;
 419             end if;
 420          end;
 421
 422          Diagnose_Non_Variable_Lhs (Lhs);
 423          return;
 424
 425       --  Error of assigning to limited type. We do however allow this in
 426       --  certain cases where the front end generates the assignments.
 427
 428       elsif Is_Limited_Type (T1)
 429         and then not Assignment_OK (Lhs)
 430         and then not Assignment_OK (Original_Node (Lhs))
 431         and then not Is_Value_Type (T1)
 432       then
 433          --  CPP constructors can only be called in declarations
 434
 435          if Is_CPP_Constructor_Call (Rhs) then
 436             Error_Msg_N ("invalid use of 'C'P'P constructor", Rhs);
 437          else
 438             Error_Msg_N
 439               ("left hand of assignment must not be limited type", Lhs);
 440             Explain_Limited_Type (T1, Lhs);
 441          end if;
 442          return;
 443
 444       --  Enforce RM 3.9.3 (8): the target of an assignment operation cannot be
 445       --  abstract. This is only checked when the assignment Comes_From_Source,
 446       --  because in some cases the expander generates such assignments (such
 447       --  in the _assign operation for an abstract type).
 448
 449       elsif Is_Abstract_Type (T1) and then Comes_From_Source (N) then
 450          Error_Msg_N
 451            ("target of assignment operation must not be abstract", Lhs);
 452       end if;
 453
 454       --  Resolution may have updated the subtype, in case the left-hand
 455       --  side is a private protected component. Use the correct subtype
 456       --  to avoid scoping issues in the back-end.
 457
 458       T1 := Etype (Lhs);
 459
 460       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 461       --  type. For example:
 462
 463       --    limited with P;
 464       --    package Pkg is
 465       --      type Acc is access P.T;
 466       --    end Pkg;
 467
 468       --    with Pkg; use Acc;
 469       --    procedure Example is
 470       --       A, B : Acc;
 471       --    begin
 472       --       A.all := B.all;  -- ERROR
 473       --    end Example;
 474
 475       if Nkind (Lhs) = N_Explicit_Dereference
 476         and then Ekind (T1) = E_Incomplete_Type
 477       then
 478          Error_Msg_N ("invalid use of incomplete type", Lhs);
 479          Kill_Lhs;
 480          return;
 481       end if;
 482
 483       --  Now we can complete the resolution of the right hand side
 484
 485       Set_Assignment_Type (Lhs, T1);
 486       Resolve (Rhs, T1);
 487
 488       --  This is the point at which we check for an unset reference
 489
 490       Check_Unset_Reference (Rhs);
 491       Check_Unprotected_Access (Lhs, Rhs);
 492
 493       --  Remaining steps are skipped if Rhs was syntactically in error
 494
 495       if Rhs = Error then
 496          Kill_Lhs;
 497          return;
 498       end if;
 499
 500       T2 := Etype (Rhs);
 501
 502       if not Covers (T1, T2) then
 503          Wrong_Type (Rhs, Etype (Lhs));
 504          Kill_Lhs;
 505          return;
 506       end if;
 507
 508       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 509       --  types, use the non-limited view if available
 510
 511       if Nkind (Rhs) = N_Explicit_Dereference
 512         and then Ekind (T2) = E_Incomplete_Type
 513         and then Is_Tagged_Type (T2)
 514         and then Present (Non_Limited_View (T2))
 515       then
 516          T2 := Non_Limited_View (T2);
 517       end if;
 518
 519       Set_Assignment_Type (Rhs, T2);
 520
 521       if Total_Errors_Detected /= 0 then
 522          if No (T1) then
 523             T1 := Any_Type;
 524          end if;
 525
 526          if No (T2) then
 527             T2 := Any_Type;
 528          end if;
 529       end if;
 530
 531       if T1 = Any_Type or else T2 = Any_Type then
 532          Kill_Lhs;
 533          return;
 534       end if;
 535
 536       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 537       --  to be class-wide. The case where the rhs is a dynamically tagged call
 538       --  to a dispatching operation with a controlling access result is
 539       --  excluded from this check, since the target has an access type (and
 540       --  no tag propagation occurs in that case).
 541
 542       if (Is_Class_Wide_Type (T2)
 543            or else (Is_Dynamically_Tagged (Rhs)
 544                      and then not Is_Access_Type (T1)))
 545         and then not Is_Class_Wide_Type (T1)
 546       then
 547          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 548
 549       elsif Is_Class_Wide_Type (T1)
 550         and then not Is_Class_Wide_Type (T2)
 551         and then not Is_Tag_Indeterminate (Rhs)
 552         and then not Is_Dynamically_Tagged (Rhs)
 553       then
 554          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 555       end if;
 556
 557       --  Propagate the tag from a class-wide target to the rhs when the rhs
 558       --  is a tag-indeterminate call.
 559
 560       if Is_Tag_Indeterminate (Rhs) then
 561          if Is_Class_Wide_Type (T1) then
 562             Propagate_Tag (Lhs, Rhs);
 563
 564          elsif Nkind (Rhs) = N_Function_Call
 565               and then Is_Entity_Name (Name (Rhs))
 566               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 567          then
 568             Error_Msg_N
 569               ("call to abstract function must be dispatching", Name (Rhs));
 570
 571          elsif Nkind (Rhs) = N_Qualified_Expression
 572            and then Nkind (Expression (Rhs)) = N_Function_Call
 573               and then Is_Entity_Name (Name (Expression (Rhs)))
 574               and then
 575                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 576          then
 577             Error_Msg_N
 578               ("call to abstract function must be dispatching",
 579                 Name (Expression (Rhs)));
 580          end if;
 581       end if;
 582
 583       --  Ada 2005 (AI-385): When the lhs type is an anonymous access type,
 584       --  apply an implicit conversion of the rhs to that type to force
 585       --  appropriate static and run-time accessibility checks. This applies
 586       --  as well to anonymous access-to-subprogram types that are component
 587       --  subtypes or formal parameters.
 588
 589       if Ada_Version >= Ada_2005
 590         and then Is_Access_Type (T1)
 591       then
 592          if Is_Local_Anonymous_Access (T1)
 593            or else Ekind (T2) = E_Anonymous_Access_Subprogram_Type
 594          then
 595             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 596             Analyze_And_Resolve (Rhs, T1);
 597          end if;
 598       end if;
 599
 600       --  Ada 2005 (AI-231): Assignment to not null variable
 601
 602       if Ada_Version >= Ada_2005
 603         and then Can_Never_Be_Null (T1)
 604         and then not Assignment_OK (Lhs)
 605       then
 606          --  Case where we know the right hand side is null
 607
 608          if Known_Null (Rhs) then
 609             Apply_Compile_Time_Constraint_Error
 610               (N   => Rhs,
 611                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 612                Reason => CE_Null_Not_Allowed);
 613
 614             --  We still mark this as a possible modification, that's necessary
 615             --  to reset Is_True_Constant, and desirable for xref purposes.
 616
 617             Note_Possible_Modification (Lhs, Sure => True);
 618             return;
 619
 620          --  If we know the right hand side is non-null, then we convert to the
 621          --  target type, since we don't need a run time check in that case.
 622
 623          elsif not Can_Never_Be_Null (T2) then
 624             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 625             Analyze_And_Resolve (Rhs, T1);
 626          end if;
 627       end if;
 628
 629       if Is_Scalar_Type (T1) then
 630          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 631
 632       --  For array types, verify that lengths match. If the right hand side
 633       --  if a function call that has been inlined, the assignment has been
 634       --  rewritten as a block, and the constraint check will be applied to the
 635       --  assignment within the block.
 636
 637       elsif Is_Array_Type (T1)
 638         and then
 639           (Nkind (Rhs) /= N_Type_Conversion
 640             or else Is_Constrained (Etype (Rhs)))
 641         and then
 642           (Nkind (Rhs) /= N_Function_Call
 643             or else Nkind (N) /= N_Block_Statement)
 644       then
 645          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 646          --  but of course the indexes do not have to match. If the right-hand
 647          --  side is a type conversion to an unconstrained type, a length check
 648          --  is performed on the expression itself during expansion. In rare
 649          --  cases, the redundant length check is computed on an index type
 650          --  with a different representation, triggering incorrect code in
 651          --  the back end.
 652
 653          Apply_Length_Check (Rhs, Etype (Lhs));
 654
 655       else
 656          --  Discriminant checks are applied in the course of expansion
 657
 658          null;
 659       end if;
 660
 661       --  Note: modifications of the Lhs may only be recorded after
 662       --  checks have been applied.
 663
 664       Note_Possible_Modification (Lhs, Sure => True);
 665
 666       --  ??? a real accessibility check is needed when ???
 667
 668       --  Post warning for redundant assignment or variable to itself
 669
 670       if Warn_On_Redundant_Constructs
 671
 672          --  We only warn for source constructs
 673
 674          and then Comes_From_Source (N)
 675
 676          --  Where the object is the same on both sides
 677
 678          and then Same_Object (Lhs, Original_Node (Rhs))
 679
 680          --  But exclude the case where the right side was an operation
 681          --  that got rewritten (e.g. JUNK + K, where K was known to be
 682          --  zero). We don't want to warn in such a case, since it is
 683          --  reasonable to write such expressions especially when K is
 684          --  defined symbolically in some other package.
 685
 686         and then Nkind (Original_Node (Rhs)) not in N_Op
 687       then
 688          if Nkind (Lhs) in N_Has_Entity then
 689             Error_Msg_NE -- CODEFIX
 690               ("?useless assignment of & to itself!", N, Entity (Lhs));
 691          else
 692             Error_Msg_N -- CODEFIX
 693               ("?useless assignment of object to itself!", N);
 694          end if;
 695       end if;
 696
 697       --  Check for non-allowed composite assignment
 698
 699       if not Support_Composite_Assign_On_Target
 700         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 701         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 702       then
 703          Error_Msg_CRT ("composite assignment", N);
 704       end if;
 705
 706       --  Check elaboration warning for left side if not in elab code
 707
 708       if not In_Subprogram_Or_Concurrent_Unit then
 709          Check_Elab_Assign (Lhs);
 710       end if;
 711
 712       --  Set Referenced_As_LHS if appropriate. We only set this flag if the
 713       --  assignment is a source assignment in the extended main source unit.
 714       --  We are not interested in any reference information outside this
 715       --  context, or in compiler generated assignment statements.
 716
 717       if Comes_From_Source (N)
 718         and then In_Extended_Main_Source_Unit (Lhs)
 719       then
 720          Set_Referenced_Modified (Lhs, Out_Param => False);
 721       end if;
 722
 723       --  Final step. If left side is an entity, then we may be able to
 724       --  reset the current tracked values to new safe values. We only have
 725       --  something to do if the left side is an entity name, and expansion
 726       --  has not modified the node into something other than an assignment,
 727       --  and of course we only capture values if it is safe to do so.
 728
 729       if Is_Entity_Name (Lhs)
 730         and then Nkind (N) = N_Assignment_Statement
 731       then
 732          declare
 733             Ent : constant Entity_Id := Entity (Lhs);
 734
 735          begin
 736             if Safe_To_Capture_Value (N, Ent) then
 737
 738                --  If simple variable on left side, warn if this assignment
 739                --  blots out another one (rendering it useless) and note
 740                --  location of assignment in case no one references value.
 741                --  We only do this for source assignments, otherwise we can
 742                --  generate bogus warnings when an assignment is rewritten as
 743                --  another assignment, and gets tied up with itself.
 744
 745                --  Note: we don't use Record_Last_Assignment here, because we
 746                --  have lots of other stuff to do under control of this test.
 747
 748                if Warn_On_Modified_Unread
 749                  and then Is_Assignable (Ent)
 750                  and then Comes_From_Source (N)
 751                  and then In_Extended_Main_Source_Unit (Ent)
 752                then
 753                   Warn_On_Useless_Assignment (Ent, N);
 754                   Set_Last_Assignment (Ent, Lhs);
 755                end if;
 756
 757                --  If we are assigning an access type and the left side is an
 758                --  entity, then make sure that the Is_Known_[Non_]Null flags
 759                --  properly reflect the state of the entity after assignment.
 760
 761                if Is_Access_Type (T1) then
 762                   if Known_Non_Null (Rhs) then
 763                      Set_Is_Known_Non_Null (Ent, True);
 764
 765                   elsif Known_Null (Rhs)
 766                     and then not Can_Never_Be_Null (Ent)
 767                   then
 768                      Set_Is_Known_Null (Ent, True);
 769
 770                   else
 771                      Set_Is_Known_Null (Ent, False);
 772
 773                      if not Can_Never_Be_Null (Ent) then
 774                         Set_Is_Known_Non_Null (Ent, False);
 775                      end if;
 776                   end if;
 777
 778                --  For discrete types, we may be able to set the current value
 779                --  if the value is known at compile time.
 780
 781                elsif Is_Discrete_Type (T1)
 782                  and then Compile_Time_Known_Value (Rhs)
 783                then
 784                   Set_Current_Value (Ent, Rhs);
 785                else
 786                   Set_Current_Value (Ent, Empty);
 787                end if;
 788
 789             --  If not safe to capture values, kill them
 790
 791             else
 792                Kill_Lhs;
 793             end if;
 794          end;
 795       end if;
 796    end Analyze_Assignment;
 797
 798    -----------------------------
 799    -- Analyze_Block_Statement --
 800    -----------------------------
 801
 802    procedure Analyze_Block_Statement (N : Node_Id) is
 803       Decls : constant List_Id := Declarations (N);
 804       Id    : constant Node_Id := Identifier (N);
 805       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 806
 807    begin
 808       --  If no handled statement sequence is present, things are really
 809       --  messed up, and we just return immediately (this is a defence
 810       --  against previous errors).
 811
 812       if No (HSS) then
 813          return;
 814       end if;
 815
 816       --  Normal processing with HSS present
 817
 818       declare
 819          EH  : constant List_Id := Exception_Handlers (HSS);
 820          Ent : Entity_Id        := Empty;
 821          S   : Entity_Id;
 822
 823          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 824          --  Recursively save value of this global, will be restored on exit
 825
 826       begin
 827          --  Initialize unblocked exit count for statements of begin block
 828          --  plus one for each exception handler that is present.
 829
 830          Unblocked_Exit_Count := 1;
 831
 832          if Present (EH) then
 833             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 834          end if;
 835
 836          --  If a label is present analyze it and mark it as referenced
 837
 838          if Present (Id) then
 839             Analyze (Id);
 840             Ent := Entity (Id);
 841
 842             --  An error defense. If we have an identifier, but no entity,
 843             --  then something is wrong. If we have previous errors, then
 844             --  just remove the identifier and continue, otherwise raise
 845             --  an exception.
 846
 847             if No (Ent) then
 848                if Total_Errors_Detected /= 0 then
 849                   Set_Identifier (N, Empty);
 850                else
 851                   raise Program_Error;
 852                end if;
 853
 854             else
 855                Set_Ekind (Ent, E_Block);
 856                Generate_Reference (Ent, N, ' ');
 857                Generate_Definition (Ent);
 858
 859                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 860                   Set_Label_Construct (Parent (Ent), N);
 861                end if;
 862             end if;
 863          end if;
 864
 865          --  If no entity set, create a label entity
 866
 867          if No (Ent) then
 868             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 869             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 870             Set_Parent (Ent, N);
 871          end if;
 872
 873          Set_Etype (Ent, Standard_Void_Type);
 874          Set_Block_Node (Ent, Identifier (N));
 875          Push_Scope (Ent);
 876
 877          if Present (Decls) then
 878             Analyze_Declarations (Decls);
 879             Check_Completion;
 880             Inspect_Deferred_Constant_Completion (Decls);
 881          end if;
 882
 883          Analyze (HSS);
 884          Process_End_Label (HSS, 'e', Ent);
 885
 886          --  If exception handlers are present, then we indicate that
 887          --  enclosing scopes contain a block with handlers. We only
 888          --  need to mark non-generic scopes.
 889
 890          if Present (EH) then
 891             S := Scope (Ent);
 892             loop
 893                Set_Has_Nested_Block_With_Handler (S);
 894                exit when Is_Overloadable (S)
 895                  or else Ekind (S) = E_Package
 896                  or else Is_Generic_Unit (S);
 897                S := Scope (S);
 898             end loop;
 899          end if;
 900
 901          Check_References (Ent);
 902          Warn_On_Useless_Assignments (Ent);
 903          End_Scope;
 904
 905          if Unblocked_Exit_Count = 0 then
 906             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 907             Check_Unreachable_Code (N);
 908          else
 909             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 910          end if;
 911       end;
 912    end Analyze_Block_Statement;
 913
 914    ----------------------------
 915    -- Analyze_Case_Statement --
 916    ----------------------------
 917
 918    procedure Analyze_Case_Statement (N : Node_Id) is
 919       Exp            : Node_Id;
 920       Exp_Type       : Entity_Id;
 921       Exp_Btype      : Entity_Id;
 922       Last_Choice    : Nat;
 923       Dont_Care      : Boolean;
 924       Others_Present : Boolean;
 925
 926       pragma Warnings (Off, Last_Choice);
 927       pragma Warnings (Off, Dont_Care);
 928       --  Don't care about assigned values
 929
 930       Statements_Analyzed : Boolean := False;
 931       --  Set True if at least some statement sequences get analyzed.
 932       --  If False on exit, means we had a serious error that prevented
 933       --  full analysis of the case statement, and as a result it is not
 934       --  a good idea to output warning messages about unreachable code.
 935
 936       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 937       --  Recursively save value of this global, will be restored on exit
 938
 939       procedure Non_Static_Choice_Error (Choice : Node_Id);
 940       --  Error routine invoked by the generic instantiation below when
 941       --  the case statement has a non static choice.
 942
 943       procedure Process_Statements (Alternative : Node_Id);
 944       --  Analyzes all the statements associated with a case alternative.
 945       --  Needed by the generic instantiation below.
 946
 947       package Case_Choices_Processing is new
 948         Generic_Choices_Processing
 949           (Get_Alternatives          => Alternatives,
 950            Get_Choices               => Discrete_Choices,
 951            Process_Empty_Choice      => No_OP,
 952            Process_Non_Static_Choice => Non_Static_Choice_Error,
 953            Process_Associated_Node   => Process_Statements);
 954       use Case_Choices_Processing;
 955       --  Instantiation of the generic choice processing package
 956
 957       -----------------------------
 958       -- Non_Static_Choice_Error --
 959       -----------------------------
 960
 961       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 962       begin
 963          Flag_Non_Static_Expr
 964            ("choice given in case statement is not static!", Choice);
 965       end Non_Static_Choice_Error;
 966
 967       ------------------------
 968       -- Process_Statements --
 969       ------------------------
 970
 971       procedure Process_Statements (Alternative : Node_Id) is
 972          Choices : constant List_Id := Discrete_Choices (Alternative);
 973          Ent     : Entity_Id;
 974
 975       begin
 976          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 977          Statements_Analyzed := True;
 978
 979          --  An interesting optimization. If the case statement expression
 980          --  is a simple entity, then we can set the current value within
 981          --  an alternative if the alternative has one possible value.
 982
 983          --    case N is
 984          --      when 1      => alpha
 985          --      when 2 | 3  => beta
 986          --      when others => gamma
 987
 988          --  Here we know that N is initially 1 within alpha, but for beta
 989          --  and gamma, we do not know anything more about the initial value.
 990
 991          if Is_Entity_Name (Exp) then
 992             Ent := Entity (Exp);
 993
 994             if Ekind_In (Ent, E_Variable,
 995                               E_In_Out_Parameter,
 996                               E_Out_Parameter)
 997             then
 998                if List_Length (Choices) = 1
 999                  and then Nkind (First (Choices)) in N_Subexpr
1000                  and then Compile_Time_Known_Value (First (Choices))
1001                then
1002                   Set_Current_Value (Entity (Exp), First (Choices));
1003                end if;
1004
1005                Analyze_Statements (Statements (Alternative));
1006
1007                --  After analyzing the case, set the current value to empty
1008                --  since we won't know what it is for the next alternative
1009                --  (unless reset by this same circuit), or after the case.
1010
1011                Set_Current_Value (Entity (Exp), Empty);
1012                return;
1013             end if;
1014          end if;
1015
1016          --  Case where expression is not an entity name of a variable
1017
1018          Analyze_Statements (Statements (Alternative));
1019       end Process_Statements;
1020
1021    --  Start of processing for Analyze_Case_Statement
1022
1023    begin
1024       Unblocked_Exit_Count := 0;
1025       Exp := Expression (N);
1026       Analyze (Exp);
1027
1028       --  The expression must be of any discrete type. In rare cases, the
1029       --  expander constructs a case statement whose expression has a private
1030       --  type whose full view is discrete. This can happen when generating
1031       --  a stream operation for a variant type after the type is frozen,
1032       --  when the partial of view of the type of the discriminant is private.
1033       --  In that case, use the full view to analyze case alternatives.
1034
1035       if not Is_Overloaded (Exp)
1036         and then not Comes_From_Source (N)
1037         and then Is_Private_Type (Etype (Exp))
1038         and then Present (Full_View (Etype (Exp)))
1039         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1040       then
1041          Resolve (Exp, Etype (Exp));
1042          Exp_Type := Full_View (Etype (Exp));
1043
1044       else
1045          Analyze_And_Resolve (Exp, Any_Discrete);
1046          Exp_Type := Etype (Exp);
1047       end if;
1048
1049       Check_Unset_Reference (Exp);
1050       Exp_Btype := Base_Type (Exp_Type);
1051
1052       --  The expression must be of a discrete type which must be determinable
1053       --  independently of the context in which the expression occurs, but
1054       --  using the fact that the expression must be of a discrete type.
1055       --  Moreover, the type this expression must not be a character literal
1056       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1057
1058       --  If error already reported by Resolve, nothing more to do
1059
1060       if Exp_Btype = Any_Discrete
1061         or else Exp_Btype = Any_Type
1062       then
1063          return;
1064
1065       elsif Exp_Btype = Any_Character then
1066          Error_Msg_N
1067            ("character literal as case expression is ambiguous", Exp);
1068          return;
1069
1070       elsif Ada_Version = Ada_83
1071         and then (Is_Generic_Type (Exp_Btype)
1072                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1073       then
1074          Error_Msg_N
1075            ("(Ada 83) case expression cannot be of a generic type", Exp);
1076          return;
1077       end if;
1078
1079       --  If the case expression is a formal object of mode in out, then
1080       --  treat it as having a nonstatic subtype by forcing use of the base
1081       --  type (which has to get passed to Check_Case_Choices below).  Also
1082       --  use base type when the case expression is parenthesized.
1083
1084       if Paren_Count (Exp) > 0
1085         or else (Is_Entity_Name (Exp)
1086                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1087       then
1088          Exp_Type := Exp_Btype;
1089       end if;
1090
1091       --  Call instantiated Analyze_Choices which does the rest of the work
1092
1093       Analyze_Choices (N, Exp_Type, Dont_Care, Others_Present);
1094
1095       if Exp_Type = Universal_Integer and then not Others_Present then
1096          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1097       end if;
1098
1099       --  If all our exits were blocked by unconditional transfers of control,
1100       --  then the entire CASE statement acts as an unconditional transfer of
1101       --  control, so treat it like one, and check unreachable code. Skip this
1102       --  test if we had serious errors preventing any statement analysis.
1103
1104       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1105          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1106          Check_Unreachable_Code (N);
1107       else
1108          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1109       end if;
1110
1111       if not Expander_Active
1112         and then Compile_Time_Known_Value (Expression (N))
1113         and then Serious_Errors_Detected = 0
1114       then
1115          declare
1116             Chosen : constant Node_Id := Find_Static_Alternative (N);
1117             Alt    : Node_Id;
1118
1119          begin
1120             Alt := First (Alternatives (N));
1121             while Present (Alt) loop
1122                if Alt /= Chosen then
1123                   Remove_Warning_Messages (Statements (Alt));
1124                end if;
1125
1126                Next (Alt);
1127             end loop;
1128          end;
1129       end if;
1130    end Analyze_Case_Statement;
1131
1132    ----------------------------
1133    -- Analyze_Exit_Statement --
1134    ----------------------------
1135
1136    --  If the exit includes a name, it must be the name of a currently open
1137    --  loop. Otherwise there must be an innermost open loop on the stack,
1138    --  to which the statement implicitly refers.
1139
1140    procedure Analyze_Exit_Statement (N : Node_Id) is
1141       Target   : constant Node_Id := Name (N);
1142       Cond     : constant Node_Id := Condition (N);
1143       Scope_Id : Entity_Id;
1144       U_Name   : Entity_Id;
1145       Kind     : Entity_Kind;
1146
1147    begin
1148       if No (Cond) then
1149          Check_Unreachable_Code (N);
1150       end if;
1151
1152       if Present (Target) then
1153          Analyze (Target);
1154          U_Name := Entity (Target);
1155
1156          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1157             Error_Msg_N ("invalid loop name in exit statement", N);
1158             return;
1159          else
1160             Set_Has_Exit (U_Name);
1161          end if;
1162
1163       else
1164          U_Name := Empty;
1165       end if;
1166
1167       for J in reverse 0 .. Scope_Stack.Last loop
1168          Scope_Id := Scope_Stack.Table (J).Entity;
1169          Kind := Ekind (Scope_Id);
1170
1171          if Kind = E_Loop
1172            and then (No (Target) or else Scope_Id = U_Name) then
1173             Set_Has_Exit (Scope_Id);
1174             exit;
1175
1176          elsif Kind = E_Block
1177            or else Kind = E_Loop
1178            or else Kind = E_Return_Statement
1179          then
1180             null;
1181
1182          else
1183             Error_Msg_N
1184               ("cannot exit from program unit or accept statement", N);
1185             return;
1186          end if;
1187       end loop;
1188
1189       --  Verify that if present the condition is a Boolean expression
1190
1191       if Present (Cond) then
1192          Analyze_And_Resolve (Cond, Any_Boolean);
1193          Check_Unset_Reference (Cond);
1194       end if;
1195
1196       --  Chain exit statement to associated loop entity
1197
1198       Set_Next_Exit_Statement  (N, First_Exit_Statement (Scope_Id));
1199       Set_First_Exit_Statement (Scope_Id, N);
1200
1201       --  Since the exit may take us out of a loop, any previous assignment
1202       --  statement is not useless, so clear last assignment indications. It
1203       --  is OK to keep other current values, since if the exit statement
1204       --  does not exit, then the current values are still valid.
1205
1206       Kill_Current_Values (Last_Assignment_Only => True);
1207    end Analyze_Exit_Statement;
1208
1209    ----------------------------
1210    -- Analyze_Goto_Statement --
1211    ----------------------------
1212
1213    procedure Analyze_Goto_Statement (N : Node_Id) is
1214       Label       : constant Node_Id := Name (N);
1215       Scope_Id    : Entity_Id;
1216       Label_Scope : Entity_Id;
1217       Label_Ent   : Entity_Id;
1218
1219    begin
1220       Check_Unreachable_Code (N);
1221       Kill_Current_Values (Last_Assignment_Only => True);
1222
1223       Analyze (Label);
1224       Label_Ent := Entity (Label);
1225
1226       --  Ignore previous error
1227
1228       if Label_Ent = Any_Id then
1229          return;
1230
1231       --  We just have a label as the target of a goto
1232
1233       elsif Ekind (Label_Ent) /= E_Label then
1234          Error_Msg_N ("target of goto statement must be a label", Label);
1235          return;
1236
1237       --  Check that the target of the goto is reachable according to Ada
1238       --  scoping rules. Note: the special gotos we generate for optimizing
1239       --  local handling of exceptions would violate these rules, but we mark
1240       --  such gotos as analyzed when built, so this code is never entered.
1241
1242       elsif not Reachable (Label_Ent) then
1243          Error_Msg_N ("target of goto statement is not reachable", Label);
1244          return;
1245       end if;
1246
1247       --  Here if goto passes initial validity checks
1248
1249       Label_Scope := Enclosing_Scope (Label_Ent);
1250
1251       for J in reverse 0 .. Scope_Stack.Last loop
1252          Scope_Id := Scope_Stack.Table (J).Entity;
1253
1254          if Label_Scope = Scope_Id
1255            or else (Ekind (Scope_Id) /= E_Block
1256                      and then Ekind (Scope_Id) /= E_Loop
1257                      and then Ekind (Scope_Id) /= E_Return_Statement)
1258          then
1259             if Scope_Id /= Label_Scope then
1260                Error_Msg_N
1261                  ("cannot exit from program unit or accept statement", N);
1262             end if;
1263
1264             return;
1265          end if;
1266       end loop;
1267
1268       raise Program_Error;
1269    end Analyze_Goto_Statement;
1270
1271    --------------------------
1272    -- Analyze_If_Statement --
1273    --------------------------
1274
1275    --  A special complication arises in the analysis of if statements
1276
1277    --  The expander has circuitry to completely delete code that it
1278    --  can tell will not be executed (as a result of compile time known
1279    --  conditions). In the analyzer, we ensure that code that will be
1280    --  deleted in this manner is analyzed but not expanded. This is
1281    --  obviously more efficient, but more significantly, difficulties
1282    --  arise if code is expanded and then eliminated (e.g. exception
1283    --  table entries disappear). Similarly, itypes generated in deleted
1284    --  code must be frozen from start, because the nodes on which they
1285    --  depend will not be available at the freeze point.
1286
1287    procedure Analyze_If_Statement (N : Node_Id) is
1288       E : Node_Id;
1289
1290       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1291       --  Recursively save value of this global, will be restored on exit
1292
1293       Save_In_Deleted_Code : Boolean;
1294
1295       Del : Boolean := False;
1296       --  This flag gets set True if a True condition has been found,
1297       --  which means that remaining ELSE/ELSIF parts are deleted.
1298
1299       procedure Analyze_Cond_Then (Cnode : Node_Id);
1300       --  This is applied to either the N_If_Statement node itself or
1301       --  to an N_Elsif_Part node. It deals with analyzing the condition
1302       --  and the THEN statements associated with it.
1303
1304       -----------------------
1305       -- Analyze_Cond_Then --
1306       -----------------------
1307
1308       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1309          Cond : constant Node_Id := Condition (Cnode);
1310          Tstm : constant List_Id := Then_Statements (Cnode);
1311
1312       begin
1313          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1314          Analyze_And_Resolve (Cond, Any_Boolean);
1315          Check_Unset_Reference (Cond);
1316          Set_Current_Value_Condition (Cnode);
1317
1318          --  If already deleting, then just analyze then statements
1319
1320          if Del then
1321             Analyze_Statements (Tstm);
1322
1323          --  Compile time known value, not deleting yet
1324
1325          elsif Compile_Time_Known_Value (Cond) then
1326             Save_In_Deleted_Code := In_Deleted_Code;
1327
1328             --  If condition is True, then analyze the THEN statements
1329             --  and set no expansion for ELSE and ELSIF parts.
1330
1331             if Is_True (Expr_Value (Cond)) then
1332                Analyze_Statements (Tstm);
1333                Del := True;
1334                Expander_Mode_Save_And_Set (False);
1335                In_Deleted_Code := True;
1336
1337             --  If condition is False, analyze THEN with expansion off
1338
1339             else -- Is_False (Expr_Value (Cond))
1340                Expander_Mode_Save_And_Set (False);
1341                In_Deleted_Code := True;
1342                Analyze_Statements (Tstm);
1343                Expander_Mode_Restore;
1344                In_Deleted_Code := Save_In_Deleted_Code;
1345             end if;
1346
1347          --  Not known at compile time, not deleting, normal analysis
1348
1349          else
1350             Analyze_Statements (Tstm);
1351          end if;
1352       end Analyze_Cond_Then;
1353
1354    --  Start of Analyze_If_Statement
1355
1356    begin
1357       --  Initialize exit count for else statements. If there is no else
1358       --  part, this count will stay non-zero reflecting the fact that the
1359       --  uncovered else case is an unblocked exit.
1360
1361       Unblocked_Exit_Count := 1;
1362       Analyze_Cond_Then (N);
1363
1364       --  Now to analyze the elsif parts if any are present
1365
1366       if Present (Elsif_Parts (N)) then
1367          E := First (Elsif_Parts (N));
1368          while Present (E) loop
1369             Analyze_Cond_Then (E);
1370             Next (E);
1371          end loop;
1372       end if;
1373
1374       if Present (Else_Statements (N)) then
1375          Analyze_Statements (Else_Statements (N));
1376       end if;
1377
1378       --  If all our exits were blocked by unconditional transfers of control,
1379       --  then the entire IF statement acts as an unconditional transfer of
1380       --  control, so treat it like one, and check unreachable code.
1381
1382       if Unblocked_Exit_Count = 0 then
1383          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1384          Check_Unreachable_Code (N);
1385       else
1386          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1387       end if;
1388
1389       if Del then
1390          Expander_Mode_Restore;
1391          In_Deleted_Code := Save_In_Deleted_Code;
1392       end if;
1393
1394       if not Expander_Active
1395         and then Compile_Time_Known_Value (Condition (N))
1396         and then Serious_Errors_Detected = 0
1397       then
1398          if Is_True (Expr_Value (Condition (N))) then
1399             Remove_Warning_Messages (Else_Statements (N));
1400
1401             if Present (Elsif_Parts (N)) then
1402                E := First (Elsif_Parts (N));
1403                while Present (E) loop
1404                   Remove_Warning_Messages (Then_Statements (E));
1405                   Next (E);
1406                end loop;
1407             end if;
1408
1409          else
1410             Remove_Warning_Messages (Then_Statements (N));
1411          end if;
1412       end if;
1413    end Analyze_If_Statement;
1414
1415    ----------------------------------------
1416    -- Analyze_Implicit_Label_Declaration --
1417    ----------------------------------------
1418
1419    --  An implicit label declaration is generated in the innermost
1420    --  enclosing declarative part. This is done for labels as well as
1421    --  block and loop names.
1422
1423    --  Note: any changes in this routine may need to be reflected in
1424    --  Analyze_Label_Entity.
1425
1426    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1427       Id : constant Node_Id := Defining_Identifier (N);
1428    begin
1429       Enter_Name          (Id);
1430       Set_Ekind           (Id, E_Label);
1431       Set_Etype           (Id, Standard_Void_Type);
1432       Set_Enclosing_Scope (Id, Current_Scope);
1433    end Analyze_Implicit_Label_Declaration;
1434
1435    ------------------------------
1436    -- Analyze_Iteration_Scheme --
1437    ------------------------------
1438
1439    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1440
1441       procedure Process_Bounds (R : Node_Id);
1442       --  If the iteration is given by a range, create temporaries and
1443       --  assignment statements block to capture the bounds and perform
1444       --  required finalization actions in case a bound includes a function
1445       --  call that uses the temporary stack. We first pre-analyze a copy of
1446       --  the range in order to determine the expected type, and analyze and
1447       --  resolve the original bounds.
1448
1449       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1450       --  If the bounds are given by a 'Range reference on a function call
1451       --  that returns a controlled array, introduce an explicit declaration
1452       --  to capture the bounds, so that the function result can be finalized
1453       --  in timely fashion.
1454
1455       --------------------
1456       -- Process_Bounds --
1457       --------------------
1458
1459       procedure Process_Bounds (R : Node_Id) is
1460          Loc          : constant Source_Ptr := Sloc (N);
1461          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1462          Lo           : constant Node_Id := Low_Bound  (R);
1463          Hi           : constant Node_Id := High_Bound (R);
1464          New_Lo_Bound : Node_Id;
1465          New_Hi_Bound : Node_Id;
1466          Typ          : Entity_Id;
1467          Save_Analysis : Boolean;
1468
1469          function One_Bound
1470            (Original_Bound : Node_Id;
1471             Analyzed_Bound : Node_Id) return Node_Id;
1472          --  Capture value of bound and return captured value
1473
1474          ---------------
1475          -- One_Bound --
1476          ---------------
1477
1478          function One_Bound
1479            (Original_Bound : Node_Id;
1480             Analyzed_Bound : Node_Id) return Node_Id
1481          is
1482             Assign : Node_Id;
1483             Id     : Entity_Id;
1484             Decl   : Node_Id;
1485
1486          begin
1487             --  If the bound is a constant or an object, no need for a separate
1488             --  declaration. If the bound is the result of previous expansion
1489             --  it is already analyzed and should not be modified. Note that
1490             --  the Bound will be resolved later, if needed, as part of the
1491             --  call to Make_Index (literal bounds may need to be resolved to
1492             --  type Integer).
1493
1494             if Analyzed (Original_Bound) then
1495                return Original_Bound;
1496
1497             elsif Nkind_In (Analyzed_Bound, N_Integer_Literal,
1498                                             N_Character_Literal)
1499               or else Is_Entity_Name (Analyzed_Bound)
1500             then
1501                Analyze_And_Resolve (Original_Bound, Typ);
1502                return Original_Bound;
1503             end if;
1504
1505             --  Here we need to capture the value
1506
1507             Analyze_And_Resolve (Original_Bound, Typ);
1508
1509             Id := Make_Temporary (Loc, 'S', Original_Bound);
1510
1511             --  Normally, the best approach is simply to generate a constant
1512             --  declaration that captures the bound. However, there is a nasty
1513             --  case where this is wrong. If the bound is complex, and has a
1514             --  possible use of the secondary stack, we need to generate a
1515             --  separate assignment statement to ensure the creation of a block
1516             --  which will release the secondary stack.
1517
1518             --  We prefer the constant declaration, since it leaves us with a
1519             --  proper trace of the value, useful in optimizations that get rid
1520             --  of junk range checks.
1521
1522             --  Probably we want something like the Side_Effect_Free routine
1523             --  in Exp_Util, but for now, we just optimize the cases of 'Last
1524             --  and 'First applied to an entity, since these are the important
1525             --  cases for range check optimizations.
1526
1527             if Nkind (Original_Bound) = N_Attribute_Reference
1528               and then (Attribute_Name (Original_Bound) = Name_First
1529                           or else
1530                         Attribute_Name (Original_Bound) = Name_Last)
1531               and then Is_Entity_Name (Prefix (Original_Bound))
1532             then
1533                Decl :=
1534                  Make_Object_Declaration (Loc,
1535                    Defining_Identifier => Id,
1536                    Constant_Present    => True,
1537                    Object_Definition   => New_Occurrence_Of (Typ, Loc),
1538                    Expression          => Relocate_Node (Original_Bound));
1539
1540                Insert_Before (Parent (N), Decl);
1541                Analyze (Decl);
1542                Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1543                return Expression (Decl);
1544             end if;
1545
1546             --  Here we make a declaration with a separate assignment
1547             --   statement, and insert before loop header.
1548
1549             Decl :=
1550               Make_Object_Declaration (Loc,
1551                 Defining_Identifier => Id,
1552                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1553
1554             Assign :=
1555               Make_Assignment_Statement (Loc,
1556                 Name        => New_Occurrence_Of (Id, Loc),
1557                 Expression  => Relocate_Node (Original_Bound));
1558
1559             Insert_Actions (Parent (N), New_List (Decl, Assign));
1560
1561             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1562
1563             if Nkind (Assign) = N_Assignment_Statement then
1564                return Expression (Assign);
1565             else
1566                return Original_Bound;
1567             end if;
1568          end One_Bound;
1569
1570       --  Start of processing for Process_Bounds
1571
1572       begin
1573          --  Determine expected type of range by analyzing separate copy
1574          --  Do the analysis and resolution of the copy of the bounds with
1575          --  expansion disabled, to prevent the generation of finalization
1576          --  actions on each bound. This prevents memory leaks when the
1577          --  bounds contain calls to functions returning controlled arrays.
1578
1579          Set_Parent (R_Copy, Parent (R));
1580          Save_Analysis := Full_Analysis;
1581          Full_Analysis := False;
1582          Expander_Mode_Save_And_Set (False);
1583
1584          Analyze (R_Copy);
1585
1586          if Is_Overloaded (R_Copy) then
1587
1588             --  Apply preference rules for range of predefined integer types,
1589             --  or diagnose true ambiguity.
1590
1591             declare
1592                I     : Interp_Index;
1593                It    : Interp;
1594                Found : Entity_Id := Empty;
1595
1596             begin
1597                Get_First_Interp (R_Copy, I, It);
1598                while Present (It.Typ) loop
1599                   if Is_Discrete_Type (It.Typ) then
1600                      if No (Found) then
1601                         Found := It.Typ;
1602                      else
1603                         if Scope (Found) = Standard_Standard then
1604                            null;
1605
1606                         elsif Scope (It.Typ) = Standard_Standard then
1607                            Found := It.Typ;
1608
1609                         else
1610                            --  Both of them are user-defined
1611
1612                            Error_Msg_N
1613                              ("ambiguous bounds in range of iteration",
1614                                R_Copy);
1615                            Error_Msg_N ("\possible interpretations:", R_Copy);
1616                            Error_Msg_NE ("\\} ", R_Copy, Found);
1617                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1618                            exit;
1619                         end if;
1620                      end if;
1621                   end if;
1622
1623                   Get_Next_Interp (I, It);
1624                end loop;
1625             end;
1626          end if;
1627
1628          Resolve (R_Copy);
1629          Expander_Mode_Restore;
1630          Full_Analysis := Save_Analysis;
1631
1632          Typ := Etype (R_Copy);
1633
1634          --  If the type of the discrete range is Universal_Integer, then
1635          --  the bound's type must be resolved to Integer, and any object
1636          --  used to hold the bound must also have type Integer, unless the
1637          --  literal bounds are constant-folded expressions that carry a user-
1638          --  defined type.
1639
1640          if Typ = Universal_Integer then
1641             if Nkind (Lo) = N_Integer_Literal
1642               and then Present (Etype (Lo))
1643               and then Scope (Etype (Lo)) /= Standard_Standard
1644             then
1645                Typ := Etype (Lo);
1646
1647             elsif Nkind (Hi) = N_Integer_Literal
1648               and then Present (Etype (Hi))
1649               and then Scope (Etype (Hi)) /= Standard_Standard
1650             then
1651                Typ := Etype (Hi);
1652
1653             else
1654                Typ := Standard_Integer;
1655             end if;
1656          end if;
1657
1658          Set_Etype (R, Typ);
1659
1660          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1661          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1662
1663          --  Propagate staticness to loop range itself, in case the
1664          --  corresponding subtype is static.
1665
1666          if New_Lo_Bound /= Lo
1667            and then Is_Static_Expression (New_Lo_Bound)
1668          then
1669             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1670          end if;
1671
1672          if New_Hi_Bound /= Hi
1673            and then Is_Static_Expression (New_Hi_Bound)
1674          then
1675             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1676          end if;
1677       end Process_Bounds;
1678
1679       --------------------------------------
1680       -- Check_Controlled_Array_Attribute --
1681       --------------------------------------
1682
1683       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1684       begin
1685          if Nkind (DS) = N_Attribute_Reference
1686             and then Is_Entity_Name (Prefix (DS))
1687             and then Ekind (Entity (Prefix (DS))) = E_Function
1688             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1689             and then
1690               Is_Controlled (
1691                 Component_Type (Etype (Entity (Prefix (DS)))))
1692             and then Expander_Active
1693          then
1694             declare
1695                Loc  : constant Source_Ptr := Sloc (N);
1696                Arr  : constant Entity_Id := Etype (Entity (Prefix (DS)));
1697                Indx : constant Entity_Id :=
1698                         Base_Type (Etype (First_Index (Arr)));
1699                Subt : constant Entity_Id := Make_Temporary (Loc, 'S');
1700                Decl : Node_Id;
1701
1702             begin
1703                Decl :=
1704                  Make_Subtype_Declaration (Loc,
1705                    Defining_Identifier => Subt,
1706                    Subtype_Indication  =>
1707                       Make_Subtype_Indication (Loc,
1708                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1709                         Constraint =>
1710                           Make_Range_Constraint (Loc,
1711                             Relocate_Node (DS))));
1712                Insert_Before (Parent (N), Decl);
1713                Analyze (Decl);
1714
1715                Rewrite (DS,
1716                   Make_Attribute_Reference (Loc,
1717                     Prefix => New_Reference_To (Subt, Loc),
1718                     Attribute_Name => Attribute_Name (DS)));
1719                Analyze (DS);
1720             end;
1721          end if;
1722       end Check_Controlled_Array_Attribute;
1723
1724    --  Start of processing for Analyze_Iteration_Scheme
1725
1726    begin
1727       --  Why is following check needed ???
1728
1729       if Analyzed (N) then
1730          return;
1731       end if;
1732
1733       --  For an infinite loop, there is no iteration scheme
1734
1735       if No (N) then
1736          return;
1737       end if;
1738
1739       --  Iteration scheme is present
1740
1741       declare
1742          Cond : constant Node_Id := Condition (N);
1743
1744       begin
1745          --  For WHILE loop, verify that the condition is a Boolean
1746          --  expression and resolve and check it.
1747
1748          if Present (Cond) then
1749             Analyze_And_Resolve (Cond, Any_Boolean);
1750             Check_Unset_Reference (Cond);
1751             Set_Current_Value_Condition (N);
1752             return;
1753
1754          elsif Present (Iterator_Specification (N)) then
1755             Analyze_Iterator_Specification (Iterator_Specification (N));
1756
1757          --  Else we have a FOR loop
1758
1759          else
1760             declare
1761                LP : constant Node_Id   := Loop_Parameter_Specification (N);
1762                Id : constant Entity_Id := Defining_Identifier (LP);
1763                DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1764
1765             begin
1766                Enter_Name (Id);
1767
1768                --  We always consider the loop variable to be referenced,
1769                --  since the loop may be used just for counting purposes.
1770
1771                Generate_Reference (Id, N, ' ');
1772
1773                --  Check for the case of loop variable hiding a local variable
1774                --  (used later on to give a nice warning if the hidden variable
1775                --  is never assigned).
1776
1777                declare
1778                   H : constant Entity_Id := Homonym (Id);
1779                begin
1780                   if Present (H)
1781                     and then Enclosing_Dynamic_Scope (H) =
1782                     Enclosing_Dynamic_Scope (Id)
1783                     and then Ekind (H) = E_Variable
1784                     and then Is_Discrete_Type (Etype (H))
1785                   then
1786                      Set_Hiding_Loop_Variable (H, Id);
1787                   end if;
1788                end;
1789
1790                --  Now analyze the subtype definition. If it is a range, create
1791                --  temporaries for bounds.
1792
1793                if Nkind (DS) = N_Range
1794                  and then Expander_Active
1795                then
1796                   Process_Bounds (DS);
1797
1798                --  Not a range or expander not active (is that right???)
1799
1800                else
1801                   Analyze (DS);
1802
1803                   if Nkind (DS) = N_Function_Call
1804                     or else
1805                       (Is_Entity_Name (DS)
1806                         and then not Is_Type (Entity (DS)))
1807                   then
1808                      --  This is an iterator specification. Rewrite as such
1809                      --  and analyze.
1810
1811                      declare
1812                         I_Spec : constant Node_Id :=
1813                                    Make_Iterator_Specification (Sloc (LP),
1814                                      Defining_Identifier =>
1815                                        Relocate_Node (Id),
1816                                      Name                =>
1817                                        Relocate_Node (DS),
1818                                      Subtype_Indication  =>
1819                                        Empty,
1820                                      Reverse_Present     =>
1821                                        Reverse_Present (LP));
1822                      begin
1823                         Set_Iterator_Specification (N, I_Spec);
1824                         Set_Loop_Parameter_Specification (N, Empty);
1825                         Analyze_Iterator_Specification (I_Spec);
1826                         return;
1827                      end;
1828                   end if;
1829                end if;
1830
1831                if DS = Error then
1832                   return;
1833                end if;
1834
1835                --  The subtype indication may denote the completion of an
1836                --  incomplete type declaration.
1837
1838                if Is_Entity_Name (DS)
1839                  and then Present (Entity (DS))
1840                  and then Is_Type (Entity (DS))
1841                  and then Ekind (Entity (DS)) = E_Incomplete_Type
1842                then
1843                   Set_Entity (DS, Get_Full_View (Entity (DS)));
1844                   Set_Etype  (DS, Entity (DS));
1845                end if;
1846
1847                if not Is_Discrete_Type (Etype (DS)) then
1848                   Wrong_Type (DS, Any_Discrete);
1849                   Set_Etype (DS, Any_Type);
1850                end if;
1851
1852                Check_Controlled_Array_Attribute (DS);
1853
1854                Make_Index (DS, LP);
1855
1856                Set_Ekind (Id, E_Loop_Parameter);
1857                Set_Etype (Id, Etype (DS));
1858
1859                --  Treat a range as an implicit reference to the type, to
1860                --  inhibit spurious warnings.
1861
1862                Generate_Reference (Base_Type (Etype (DS)), N, ' ');
1863                Set_Is_Known_Valid (Id, True);
1864
1865                --  The loop is not a declarative part, so the only entity
1866                --  declared "within" must be frozen explicitly.
1867
1868                declare
1869                   Flist : constant List_Id := Freeze_Entity (Id, N);
1870                begin
1871                   if Is_Non_Empty_List (Flist) then
1872                      Insert_Actions (N, Flist);
1873                   end if;
1874                end;
1875
1876                --  Check for null or possibly null range and issue warning. We
1877                --  suppress such messages in generic templates and instances,
1878                --  because in practice they tend to be dubious in these cases.
1879
1880                if Nkind (DS) = N_Range and then Comes_From_Source (N) then
1881                   declare
1882                      L : constant Node_Id := Low_Bound  (DS);
1883                      H : constant Node_Id := High_Bound (DS);
1884
1885                   begin
1886                      --  If range of loop is null, issue warning
1887
1888                      if Compile_Time_Compare
1889                           (L, H, Assume_Valid => True) = GT
1890                      then
1891                         --  Suppress the warning if inside a generic template
1892                         --  or instance, since in practice they tend to be
1893                         --  dubious in these cases since they can result from
1894                         --  intended parametrization.
1895
1896                         if not Inside_A_Generic
1897                           and then not In_Instance
1898                         then
1899                            --  Specialize msg if invalid values could make
1900                            --  the loop non-null after all.
1901
1902                            if Compile_Time_Compare
1903                                 (L, H, Assume_Valid => False) = GT
1904                            then
1905                               Error_Msg_N
1906                                 ("?loop range is null, loop will not execute",
1907                                  DS);
1908
1909                               --  Since we know the range of the loop is
1910                               --  null, set the appropriate flag to remove
1911                               --  the loop entirely during expansion.
1912
1913                               Set_Is_Null_Loop (Parent (N));
1914
1915                               --  Here is where the loop could execute because
1916                               --  of invalid values, so issue appropriate
1917                               --  message and in this case we do not set the
1918                               --  Is_Null_Loop flag since the loop may execute.
1919
1920                            else
1921                               Error_Msg_N
1922                                 ("?loop range may be null, "
1923                                  & "loop may not execute",
1924                                  DS);
1925                               Error_Msg_N
1926                                 ("?can only execute if invalid values "
1927                                  & "are present",
1928                                  DS);
1929                            end if;
1930                         end if;
1931
1932                         --  In either case, suppress warnings in the body of
1933                         --  the loop, since it is likely that these warnings
1934                         --  will be inappropriate if the loop never actually
1935                         --  executes, which is likely.
1936
1937                         Set_Suppress_Loop_Warnings (Parent (N));
1938
1939                         --  The other case for a warning is a reverse loop
1940                         --  where the upper bound is the integer literal zero
1941                         --  or one, and the lower bound can be positive.
1942
1943                         --  For example, we have
1944
1945                         --     for J in reverse N .. 1 loop
1946
1947                         --  In practice, this is very likely to be a case of
1948                         --  reversing the bounds incorrectly in the range.
1949
1950                      elsif Reverse_Present (LP)
1951                        and then Nkind (Original_Node (H)) =
1952                                                       N_Integer_Literal
1953                        and then (Intval (Original_Node (H)) = Uint_0
1954                                   or else
1955                                     Intval (Original_Node (H)) = Uint_1)
1956                      then
1957                         Error_Msg_N ("?loop range may be null", DS);
1958                         Error_Msg_N ("\?bounds may be wrong way round", DS);
1959                      end if;
1960                   end;
1961                end if;
1962             end;
1963          end if;
1964       end;
1965    end Analyze_Iteration_Scheme;
1966
1967    -------------------------------------
1968    --  Analyze_Iterator_Specification --
1969    -------------------------------------
1970
1971    procedure Analyze_Iterator_Specification (N : Node_Id) is
1972       Def_Id    : constant Node_Id := Defining_Identifier (N);
1973       Subt      : constant Node_Id := Subtype_Indication (N);
1974       Container : constant Node_Id := Name (N);
1975
1976       Ent : Entity_Id;
1977       Typ : Entity_Id;
1978
1979    begin
1980       Enter_Name (Def_Id);
1981       Set_Ekind (Def_Id, E_Variable);
1982
1983       if Present (Subt) then
1984          Analyze (Subt);
1985       end if;
1986
1987       Analyze_And_Resolve (Container);
1988       Typ := Etype (Container);
1989
1990       if Is_Array_Type (Typ) then
1991          if Of_Present (N) then
1992             Set_Etype (Def_Id, Component_Type (Typ));
1993          else
1994             Set_Etype (Def_Id, Etype (First_Index (Typ)));
1995          end if;
1996
1997       --  Iteration over a container
1998
1999       else
2000          Set_Ekind (Def_Id, E_Loop_Parameter);
2001
2002          if Of_Present (N) then
2003
2004             --  Find the Element_Type in the package instance that defines the
2005             --  container type.
2006
2007             Ent := First_Entity (Scope (Typ));
2008             while Present (Ent) loop
2009                if Chars (Ent) = Name_Element_Type then
2010                   Set_Etype (Def_Id, Ent);
2011                   exit;
2012                end if;
2013
2014                Next_Entity (Ent);
2015             end loop;
2016
2017          else
2018             --  Find the Cursor type in similar fashion
2019
2020             Ent := First_Entity (Scope (Typ));
2021             while Present (Ent) loop
2022                if Chars (Ent) = Name_Cursor then
2023                   Set_Etype (Def_Id, Ent);
2024                   exit;
2025                end if;
2026
2027                Next_Entity (Ent);
2028             end loop;
2029          end if;
2030       end if;
2031    end Analyze_Iterator_Specification;
2032
2033    -------------------
2034    -- Analyze_Label --
2035    -------------------
2036
2037    --  Note: the semantic work required for analyzing labels (setting them as
2038    --  reachable) was done in a prepass through the statements in the block,
2039    --  so that forward gotos would be properly handled. See Analyze_Statements
2040    --  for further details. The only processing required here is to deal with
2041    --  optimizations that depend on an assumption of sequential control flow,
2042    --  since of course the occurrence of a label breaks this assumption.
2043
2044    procedure Analyze_Label (N : Node_Id) is
2045       pragma Warnings (Off, N);
2046    begin
2047       Kill_Current_Values;
2048    end Analyze_Label;
2049
2050    --------------------------
2051    -- Analyze_Label_Entity --
2052    --------------------------
2053
2054    procedure Analyze_Label_Entity (E : Entity_Id) is
2055    begin
2056       Set_Ekind           (E, E_Label);
2057       Set_Etype           (E, Standard_Void_Type);
2058       Set_Enclosing_Scope (E, Current_Scope);
2059       Set_Reachable       (E, True);
2060    end Analyze_Label_Entity;
2061
2062    ----------------------------
2063    -- Analyze_Loop_Statement --
2064    ----------------------------
2065
2066    procedure Analyze_Loop_Statement (N : Node_Id) is
2067       Loop_Statement : constant Node_Id := N;
2068
2069       Id   : constant Node_Id := Identifier (Loop_Statement);
2070       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
2071       Ent  : Entity_Id;
2072
2073    begin
2074       if Present (Id) then
2075
2076          --  Make name visible, e.g. for use in exit statements. Loop
2077          --  labels are always considered to be referenced.
2078
2079          Analyze (Id);
2080          Ent := Entity (Id);
2081
2082          --  Guard against serious error (typically, a scope mismatch when
2083          --  semantic analysis is requested) by creating loop entity to
2084          --  continue analysis.
2085
2086          if No (Ent) then
2087             if Total_Errors_Detected /= 0 then
2088                Ent :=
2089                  New_Internal_Entity
2090                    (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2091             else
2092                raise Program_Error;
2093             end if;
2094
2095          else
2096             Generate_Reference  (Ent, Loop_Statement, ' ');
2097             Generate_Definition (Ent);
2098
2099             --  If we found a label, mark its type. If not, ignore it, since it
2100             --  means we have a conflicting declaration, which would already
2101             --  have been diagnosed at declaration time. Set Label_Construct
2102             --  of the implicit label declaration, which is not created by the
2103             --  parser for generic units.
2104
2105             if Ekind (Ent) = E_Label then
2106                Set_Ekind (Ent, E_Loop);
2107
2108                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
2109                   Set_Label_Construct (Parent (Ent), Loop_Statement);
2110                end if;
2111             end if;
2112          end if;
2113
2114       --  Case of no identifier present
2115
2116       else
2117          Ent :=
2118            New_Internal_Entity
2119              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2120          Set_Etype (Ent,  Standard_Void_Type);
2121          Set_Parent (Ent, Loop_Statement);
2122       end if;
2123
2124       --  Kill current values on entry to loop, since statements in body of
2125       --  loop may have been executed before the loop is entered. Similarly we
2126       --  kill values after the loop, since we do not know that the body of the
2127       --  loop was executed.
2128
2129       Kill_Current_Values;
2130       Push_Scope (Ent);
2131       Analyze_Iteration_Scheme (Iter);
2132       Analyze_Statements (Statements (Loop_Statement));
2133       Process_End_Label (Loop_Statement, 'e', Ent);
2134       End_Scope;
2135       Kill_Current_Values;
2136
2137       --  Check for infinite loop. Skip check for generated code, since it
2138       --  justs waste time and makes debugging the routine called harder.
2139
2140       --  Note that we have to wait till the body of the loop is fully analyzed
2141       --  before making this call, since Check_Infinite_Loop_Warning relies on
2142       --  being able to use semantic visibility information to find references.
2143
2144       if Comes_From_Source (N) then
2145          Check_Infinite_Loop_Warning (N);
2146       end if;
2147
2148       --  Code after loop is unreachable if the loop has no WHILE or FOR
2149       --  and contains no EXIT statements within the body of the loop.
2150
2151       if No (Iter) and then not Has_Exit (Ent) then
2152          Check_Unreachable_Code (N);
2153       end if;
2154    end Analyze_Loop_Statement;
2155
2156    ----------------------------
2157    -- Analyze_Null_Statement --
2158    ----------------------------
2159
2160    --  Note: the semantics of the null statement is implemented by a single
2161    --  null statement, too bad everything isn't as simple as this!
2162
2163    procedure Analyze_Null_Statement (N : Node_Id) is
2164       pragma Warnings (Off, N);
2165    begin
2166       null;
2167    end Analyze_Null_Statement;
2168
2169    ------------------------
2170    -- Analyze_Statements --
2171    ------------------------
2172
2173    procedure Analyze_Statements (L : List_Id) is
2174       S   : Node_Id;
2175       Lab : Entity_Id;
2176
2177    begin
2178       --  The labels declared in the statement list are reachable from
2179       --  statements in the list. We do this as a prepass so that any
2180       --  goto statement will be properly flagged if its target is not
2181       --  reachable. This is not required, but is nice behavior!
2182
2183       S := First (L);
2184       while Present (S) loop
2185          if Nkind (S) = N_Label then
2186             Analyze (Identifier (S));
2187             Lab := Entity (Identifier (S));
2188
2189             --  If we found a label mark it as reachable
2190
2191             if Ekind (Lab) = E_Label then
2192                Generate_Definition (Lab);
2193                Set_Reachable (Lab);
2194
2195                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
2196                   Set_Label_Construct (Parent (Lab), S);
2197                end if;
2198
2199             --  If we failed to find a label, it means the implicit declaration
2200             --  of the label was hidden.  A for-loop parameter can do this to
2201             --  a label with the same name inside the loop, since the implicit
2202             --  label declaration is in the innermost enclosing body or block
2203             --  statement.
2204
2205             else
2206                Error_Msg_Sloc := Sloc (Lab);
2207                Error_Msg_N
2208                  ("implicit label declaration for & is hidden#",
2209                   Identifier (S));
2210             end if;
2211          end if;
2212
2213          Next (S);
2214       end loop;
2215
2216       --  Perform semantic analysis on all statements
2217
2218       Conditional_Statements_Begin;
2219
2220       S := First (L);
2221       while Present (S) loop
2222          Analyze (S);
2223          Next (S);
2224       end loop;
2225
2226       Conditional_Statements_End;
2227
2228       --  Make labels unreachable. Visibility is not sufficient, because
2229       --  labels in one if-branch for example are not reachable from the
2230       --  other branch, even though their declarations are in the enclosing
2231       --  declarative part.
2232
2233       S := First (L);
2234       while Present (S) loop
2235          if Nkind (S) = N_Label then
2236             Set_Reachable (Entity (Identifier (S)), False);
2237          end if;
2238
2239          Next (S);
2240       end loop;
2241    end Analyze_Statements;
2242
2243    ----------------------------
2244    -- Check_Unreachable_Code --
2245    ----------------------------
2246
2247    procedure Check_Unreachable_Code (N : Node_Id) is
2248       Error_Loc : Source_Ptr;
2249       P         : Node_Id;
2250
2251    begin
2252       if Is_List_Member (N)
2253         and then Comes_From_Source (N)
2254       then
2255          declare
2256             Nxt : Node_Id;
2257
2258          begin
2259             Nxt := Original_Node (Next (N));
2260
2261             --  If a label follows us, then we never have dead code, since
2262             --  someone could branch to the label, so we just ignore it.
2263
2264             if Nkind (Nxt) = N_Label then
2265                return;
2266
2267             --  Otherwise see if we have a real statement following us
2268
2269             elsif Present (Nxt)
2270               and then Comes_From_Source (Nxt)
2271               and then Is_Statement (Nxt)
2272             then
2273                --  Special very annoying exception. If we have a return that
2274                --  follows a raise, then we allow it without a warning, since
2275                --  the Ada RM annoyingly requires a useless return here!
2276
2277                if Nkind (Original_Node (N)) /= N_Raise_Statement
2278                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2279                then
2280                   --  The rather strange shenanigans with the warning message
2281                   --  here reflects the fact that Kill_Dead_Code is very good
2282                   --  at removing warnings in deleted code, and this is one
2283                   --  warning we would prefer NOT to have removed.
2284
2285                   Error_Loc := Sloc (Nxt);
2286
2287                   --  If we have unreachable code, analyze and remove the
2288                   --  unreachable code, since it is useless and we don't
2289                   --  want to generate junk warnings.
2290
2291                   --  We skip this step if we are not in code generation mode.
2292                   --  This is the one case where we remove dead code in the
2293                   --  semantics as opposed to the expander, and we do not want
2294                   --  to remove code if we are not in code generation mode,
2295                   --  since this messes up the ASIS trees.
2296
2297                   --  Note that one might react by moving the whole circuit to
2298                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2299
2300                   if Operating_Mode = Generate_Code then
2301                      loop
2302                         Nxt := Next (N);
2303
2304                         --  Quit deleting when we have nothing more to delete
2305                         --  or if we hit a label (since someone could transfer
2306                         --  control to a label, so we should not delete it).
2307
2308                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2309
2310                         --  Statement/declaration is to be deleted
2311
2312                         Analyze (Nxt);
2313                         Remove (Nxt);
2314                         Kill_Dead_Code (Nxt);
2315                      end loop;
2316                   end if;
2317
2318                   --  Now issue the warning
2319
2320                   Error_Msg ("?unreachable code!", Error_Loc);
2321                end if;
2322
2323             --  If the unconditional transfer of control instruction is
2324             --  the last statement of a sequence, then see if our parent
2325             --  is one of the constructs for which we count unblocked exits,
2326             --  and if so, adjust the count.
2327
2328             else
2329                P := Parent (N);
2330
2331                --  Statements in THEN part or ELSE part of IF statement
2332
2333                if Nkind (P) = N_If_Statement then
2334                   null;
2335
2336                --  Statements in ELSIF part of an IF statement
2337
2338                elsif Nkind (P) = N_Elsif_Part then
2339                   P := Parent (P);
2340                   pragma Assert (Nkind (P) = N_If_Statement);
2341
2342                --  Statements in CASE statement alternative
2343
2344                elsif Nkind (P) = N_Case_Statement_Alternative then
2345                   P := Parent (P);
2346                   pragma Assert (Nkind (P) = N_Case_Statement);
2347
2348                --  Statements in body of block
2349
2350                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2351                  and then Nkind (Parent (P)) = N_Block_Statement
2352                then
2353                   null;
2354
2355                --  Statements in exception handler in a block
2356
2357                elsif Nkind (P) = N_Exception_Handler
2358                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2359                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2360                then
2361                   null;
2362
2363                --  None of these cases, so return
2364
2365                else
2366                   return;
2367                end if;
2368
2369                --  This was one of the cases we are looking for (i.e. the
2370                --  parent construct was IF, CASE or block) so decrement count.
2371
2372                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2373             end if;
2374          end;
2375       end if;
2376    end Check_Unreachable_Code;
2377
2378 end Sem_Ch5;