gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Aux;  use Sem_Aux;
  42 with Sem_Case; use Sem_Case;
  43 with Sem_Ch3;  use Sem_Ch3;
  44 with Sem_Ch8;  use Sem_Ch8;
  45 with Sem_Disp; use Sem_Disp;
  46 with Sem_Elab; use Sem_Elab;
  47 with Sem_Eval; use Sem_Eval;
  48 with Sem_Res;  use Sem_Res;
  49 with Sem_SCIL; use Sem_SCIL;
  50 with Sem_Type; use Sem_Type;
  51 with Sem_Util; use Sem_Util;
  52 with Sem_Warn; use Sem_Warn;
  53 with Snames;   use Snames;
  54 with Stand;    use Stand;
  55 with Sinfo;    use Sinfo;
  56 with Targparm; use Targparm;
  57 with Tbuild;   use Tbuild;
  58 with Uintp;    use Uintp;
  59
  60 package body Sem_Ch5 is
  61
  62    Unblocked_Exit_Count : Nat := 0;
  63    --  This variable is used when processing if statements, case statements,
  64    --  and block statements. It counts the number of exit points that are not
  65    --  blocked by unconditional transfer instructions: for IF and CASE, these
  66    --  are the branches of the conditional; for a block, they are the statement
  67    --  sequence of the block, and the statement sequences of any exception
  68    --  handlers that are part of the block. When processing is complete, if
  69    --  this count is zero, it means that control cannot fall through the IF,
  70    --  CASE or block statement. This is used for the generation of warning
  71    --  messages. This variable is recursively saved on entry to processing the
  72    --  construct, and restored on exit.
  73
  74    -----------------------
  75    -- Local Subprograms --
  76    -----------------------
  77
  78    procedure Analyze_Iteration_Scheme (N : Node_Id);
  79
  80    ------------------------
  81    -- Analyze_Assignment --
  82    ------------------------
  83
  84    procedure Analyze_Assignment (N : Node_Id) is
  85       Lhs  : constant Node_Id := Name (N);
  86       Rhs  : constant Node_Id := Expression (N);
  87       T1   : Entity_Id;
  88       T2   : Entity_Id;
  89       Decl : Node_Id;
  90
  91       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  92       --  N is the node for the left hand side of an assignment, and it is not
  93       --  a variable. This routine issues an appropriate diagnostic.
  94
  95       procedure Kill_Lhs;
  96       --  This is called to kill current value settings of a simple variable
  97       --  on the left hand side. We call it if we find any error in analyzing
  98       --  the assignment, and at the end of processing before setting any new
  99       --  current values in place.
 100
 101       procedure Set_Assignment_Type
 102         (Opnd      : Node_Id;
 103          Opnd_Type : in out Entity_Id);
 104       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 105       --  is the nominal subtype. This procedure is used to deal with cases
 106       --  where the nominal subtype must be replaced by the actual subtype.
 107
 108       -------------------------------
 109       -- Diagnose_Non_Variable_Lhs --
 110       -------------------------------
 111
 112       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 113       begin
 114          --  Not worth posting another error if left hand side already
 115          --  flagged as being illegal in some respect.
 116
 117          if Error_Posted (N) then
 118             return;
 119
 120          --  Some special bad cases of entity names
 121
 122          elsif Is_Entity_Name (N) then
 123             declare
 124                Ent : constant Entity_Id := Entity (N);
 125
 126             begin
 127                if Ekind (Ent) = E_In_Parameter then
 128                   Error_Msg_N
 129                     ("assignment to IN mode parameter not allowed", N);
 130
 131                --  Renamings of protected private components are turned into
 132                --  constants when compiling a protected function. In the case
 133                --  of single protected types, the private component appears
 134                --  directly.
 135
 136                elsif (Is_Prival (Ent)
 137                         and then
 138                           (Ekind (Current_Scope) = E_Function
 139                              or else Ekind (Enclosing_Dynamic_Scope (
 140                                        Current_Scope)) = E_Function))
 141                    or else
 142                      (Ekind (Ent) = E_Component
 143                         and then Is_Protected_Type (Scope (Ent)))
 144                then
 145                   Error_Msg_N
 146                     ("protected function cannot modify protected object", N);
 147
 148                elsif Ekind (Ent) = E_Loop_Parameter then
 149                   Error_Msg_N
 150                     ("assignment to loop parameter not allowed", N);
 151
 152                else
 153                   Error_Msg_N
 154                     ("left hand side of assignment must be a variable", N);
 155                end if;
 156             end;
 157
 158          --  For indexed components or selected components, test prefix
 159
 160          elsif Nkind (N) = N_Indexed_Component then
 161             Diagnose_Non_Variable_Lhs (Prefix (N));
 162
 163          --  Another special case for assignment to discriminant
 164
 165          elsif Nkind (N) = N_Selected_Component then
 166             if Present (Entity (Selector_Name (N)))
 167               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 168             then
 169                Error_Msg_N
 170                  ("assignment to discriminant not allowed", N);
 171             else
 172                Diagnose_Non_Variable_Lhs (Prefix (N));
 173             end if;
 174
 175          else
 176             --  If we fall through, we have no special message to issue!
 177
 178             Error_Msg_N ("left hand side of assignment must be a variable", N);
 179          end if;
 180       end Diagnose_Non_Variable_Lhs;
 181
 182       --------------
 183       -- Kill_LHS --
 184       --------------
 185
 186       procedure Kill_Lhs is
 187       begin
 188          if Is_Entity_Name (Lhs) then
 189             declare
 190                Ent : constant Entity_Id := Entity (Lhs);
 191             begin
 192                if Present (Ent) then
 193                   Kill_Current_Values (Ent);
 194                end if;
 195             end;
 196          end if;
 197       end Kill_Lhs;
 198
 199       -------------------------
 200       -- Set_Assignment_Type --
 201       -------------------------
 202
 203       procedure Set_Assignment_Type
 204         (Opnd      : Node_Id;
 205          Opnd_Type : in out Entity_Id)
 206       is
 207       begin
 208          Require_Entity (Opnd);
 209
 210          --  If the assignment operand is an in-out or out parameter, then we
 211          --  get the actual subtype (needed for the unconstrained case).
 212          --  If the operand is the actual in an entry declaration, then within
 213          --  the accept statement it is replaced with a local renaming, which
 214          --  may also have an actual subtype.
 215
 216          if Is_Entity_Name (Opnd)
 217            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 218                       or else Ekind (Entity (Opnd)) =
 219                            E_In_Out_Parameter
 220                       or else Ekind (Entity (Opnd)) =
 221                            E_Generic_In_Out_Parameter
 222                       or else
 223                         (Ekind (Entity (Opnd)) = E_Variable
 224                           and then Nkind (Parent (Entity (Opnd))) =
 225                              N_Object_Renaming_Declaration
 226                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 227                              N_Accept_Statement))
 228          then
 229             Opnd_Type := Get_Actual_Subtype (Opnd);
 230
 231          --  If assignment operand is a component reference, then we get the
 232          --  actual subtype of the component for the unconstrained case.
 233
 234          elsif Nkind_In (Opnd, N_Selected_Component, N_Explicit_Dereference)
 235            and then not Is_Unchecked_Union (Opnd_Type)
 236          then
 237             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 238
 239             if Present (Decl) then
 240                Insert_Action (N, Decl);
 241                Mark_Rewrite_Insertion (Decl);
 242                Analyze (Decl);
 243                Opnd_Type := Defining_Identifier (Decl);
 244                Set_Etype (Opnd, Opnd_Type);
 245                Freeze_Itype (Opnd_Type, N);
 246
 247             elsif Is_Constrained (Etype (Opnd)) then
 248                Opnd_Type := Etype (Opnd);
 249             end if;
 250
 251          --  For slice, use the constrained subtype created for the slice
 252
 253          elsif Nkind (Opnd) = N_Slice then
 254             Opnd_Type := Etype (Opnd);
 255          end if;
 256       end Set_Assignment_Type;
 257
 258    --  Start of processing for Analyze_Assignment
 259
 260    begin
 261       Mark_Coextensions (N, Rhs);
 262
 263       Analyze (Rhs);
 264       Analyze (Lhs);
 265
 266       --  Start type analysis for assignment
 267
 268       T1 := Etype (Lhs);
 269
 270       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 271       --  must compute the intersection of the possible types on each side.
 272
 273       if Is_Overloaded (Lhs) then
 274          declare
 275             I  : Interp_Index;
 276             It : Interp;
 277
 278          begin
 279             T1 := Any_Type;
 280             Get_First_Interp (Lhs, I, It);
 281
 282             while Present (It.Typ) loop
 283                if Has_Compatible_Type (Rhs, It.Typ) then
 284                   if T1 /= Any_Type then
 285
 286                      --  An explicit dereference is overloaded if the prefix
 287                      --  is. Try to remove the ambiguity on the prefix, the
 288                      --  error will be posted there if the ambiguity is real.
 289
 290                      if Nkind (Lhs) = N_Explicit_Dereference then
 291                         declare
 292                            PI    : Interp_Index;
 293                            PI1   : Interp_Index := 0;
 294                            PIt   : Interp;
 295                            Found : Boolean;
 296
 297                         begin
 298                            Found := False;
 299                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 300
 301                            while Present (PIt.Typ) loop
 302                               if Is_Access_Type (PIt.Typ)
 303                                 and then Has_Compatible_Type
 304                                            (Rhs, Designated_Type (PIt.Typ))
 305                               then
 306                                  if Found then
 307                                     PIt :=
 308                                       Disambiguate (Prefix (Lhs),
 309                                         PI1, PI, Any_Type);
 310
 311                                     if PIt = No_Interp then
 312                                        Error_Msg_N
 313                                          ("ambiguous left-hand side"
 314                                             & " in assignment", Lhs);
 315                                        exit;
 316                                     else
 317                                        Resolve (Prefix (Lhs), PIt.Typ);
 318                                     end if;
 319
 320                                     exit;
 321                                  else
 322                                     Found := True;
 323                                     PI1 := PI;
 324                                  end if;
 325                               end if;
 326
 327                               Get_Next_Interp (PI, PIt);
 328                            end loop;
 329                         end;
 330
 331                      else
 332                         Error_Msg_N
 333                           ("ambiguous left-hand side in assignment", Lhs);
 334                         exit;
 335                      end if;
 336                   else
 337                      T1 := It.Typ;
 338                   end if;
 339                end if;
 340
 341                Get_Next_Interp (I, It);
 342             end loop;
 343          end;
 344
 345          if T1 = Any_Type then
 346             Error_Msg_N
 347               ("no valid types for left-hand side for assignment", Lhs);
 348             Kill_Lhs;
 349             return;
 350          end if;
 351       end if;
 352
 353       --  The resulting assignment type is T1, so now we will resolve the
 354       --  left hand side of the assignment using this determined type.
 355
 356       Resolve (Lhs, T1);
 357
 358       --  Cases where Lhs is not a variable
 359
 360       if not Is_Variable (Lhs) then
 361
 362          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 363          --  a protected object.
 364
 365          declare
 366             Ent : Entity_Id;
 367             S   : Entity_Id;
 368
 369          begin
 370             if Ada_Version >= Ada_05 then
 371
 372                --  Handle chains of renamings
 373
 374                Ent := Lhs;
 375                while Nkind (Ent) in N_Has_Entity
 376                  and then Present (Entity (Ent))
 377                  and then Present (Renamed_Object (Entity (Ent)))
 378                loop
 379                   Ent := Renamed_Object (Entity (Ent));
 380                end loop;
 381
 382                if (Nkind (Ent) = N_Attribute_Reference
 383                      and then Attribute_Name (Ent) = Name_Priority)
 384
 385                   --  Renamings of the attribute Priority applied to protected
 386                   --  objects have been previously expanded into calls to the
 387                   --  Get_Ceiling run-time subprogram.
 388
 389                  or else
 390                   (Nkind (Ent) = N_Function_Call
 391                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 392                                 or else
 393                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 394                then
 395                   --  The enclosing subprogram cannot be a protected function
 396
 397                   S := Current_Scope;
 398                   while not (Is_Subprogram (S)
 399                                and then Convention (S) = Convention_Protected)
 400                      and then S /= Standard_Standard
 401                   loop
 402                      S := Scope (S);
 403                   end loop;
 404
 405                   if Ekind (S) = E_Function
 406                     and then Convention (S) = Convention_Protected
 407                   then
 408                      Error_Msg_N
 409                        ("protected function cannot modify protected object",
 410                         Lhs);
 411                   end if;
 412
 413                   --  Changes of the ceiling priority of the protected object
 414                   --  are only effective if the Ceiling_Locking policy is in
 415                   --  effect (AARM D.5.2 (5/2)).
 416
 417                   if Locking_Policy /= 'C' then
 418                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 419                                   "no effect?", Lhs);
 420                      Error_Msg_N ("\since no Locking_Policy has been " &
 421                                   "specified", Lhs);
 422                   end if;
 423
 424                   return;
 425                end if;
 426             end if;
 427          end;
 428
 429          Diagnose_Non_Variable_Lhs (Lhs);
 430          return;
 431
 432       --  Error of assigning to limited type. We do however allow this in
 433       --  certain cases where the front end generates the assignments.
 434
 435       elsif Is_Limited_Type (T1)
 436         and then not Assignment_OK (Lhs)
 437         and then not Assignment_OK (Original_Node (Lhs))
 438         and then not Is_Value_Type (T1)
 439       then
 440          --  CPP constructors can only be called in declarations
 441
 442          if Is_CPP_Constructor_Call (Rhs) then
 443             Error_Msg_N ("invalid use of 'C'P'P constructor", Rhs);
 444          else
 445             Error_Msg_N
 446               ("left hand of assignment must not be limited type", Lhs);
 447             Explain_Limited_Type (T1, Lhs);
 448          end if;
 449          return;
 450
 451       --  Enforce RM 3.9.3 (8): the target of an assignment operation cannot be
 452       --  abstract. This is only checked when the assignment Comes_From_Source,
 453       --  because in some cases the expander generates such assignments (such
 454       --  in the _assign operation for an abstract type).
 455
 456       elsif Is_Abstract_Type (T1) and then Comes_From_Source (N) then
 457          Error_Msg_N
 458            ("target of assignment operation must not be abstract", Lhs);
 459       end if;
 460
 461       --  Resolution may have updated the subtype, in case the left-hand
 462       --  side is a private protected component. Use the correct subtype
 463       --  to avoid scoping issues in the back-end.
 464
 465       T1 := Etype (Lhs);
 466
 467       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 468       --  type. For example:
 469
 470       --    limited with P;
 471       --    package Pkg is
 472       --      type Acc is access P.T;
 473       --    end Pkg;
 474
 475       --    with Pkg; use Acc;
 476       --    procedure Example is
 477       --       A, B : Acc;
 478       --    begin
 479       --       A.all := B.all;  -- ERROR
 480       --    end Example;
 481
 482       if Nkind (Lhs) = N_Explicit_Dereference
 483         and then Ekind (T1) = E_Incomplete_Type
 484       then
 485          Error_Msg_N ("invalid use of incomplete type", Lhs);
 486          Kill_Lhs;
 487          return;
 488       end if;
 489
 490       --  Now we can complete the resolution of the right hand side
 491
 492       Set_Assignment_Type (Lhs, T1);
 493       Resolve (Rhs, T1);
 494
 495       --  This is the point at which we check for an unset reference
 496
 497       Check_Unset_Reference (Rhs);
 498       Check_Unprotected_Access (Lhs, Rhs);
 499
 500       --  Remaining steps are skipped if Rhs was syntactically in error
 501
 502       if Rhs = Error then
 503          Kill_Lhs;
 504          return;
 505       end if;
 506
 507       T2 := Etype (Rhs);
 508
 509       if not Covers (T1, T2) then
 510          Wrong_Type (Rhs, Etype (Lhs));
 511          Kill_Lhs;
 512          return;
 513       end if;
 514
 515       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 516       --  types, use the non-limited view if available
 517
 518       if Nkind (Rhs) = N_Explicit_Dereference
 519         and then Ekind (T2) = E_Incomplete_Type
 520         and then Is_Tagged_Type (T2)
 521         and then Present (Non_Limited_View (T2))
 522       then
 523          T2 := Non_Limited_View (T2);
 524       end if;
 525
 526       Set_Assignment_Type (Rhs, T2);
 527
 528       if Total_Errors_Detected /= 0 then
 529          if No (T1) then
 530             T1 := Any_Type;
 531          end if;
 532
 533          if No (T2) then
 534             T2 := Any_Type;
 535          end if;
 536       end if;
 537
 538       if T1 = Any_Type or else T2 = Any_Type then
 539          Kill_Lhs;
 540          return;
 541       end if;
 542
 543       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 544       --  to be class-wide. The case where the rhs is a dynamically tagged call
 545       --  to a dispatching operation with a controlling access result is
 546       --  excluded from this check, since the target has an access type (and
 547       --  no tag propagation occurs in that case).
 548
 549       if (Is_Class_Wide_Type (T2)
 550            or else (Is_Dynamically_Tagged (Rhs)
 551                      and then not Is_Access_Type (T1)))
 552         and then not Is_Class_Wide_Type (T1)
 553       then
 554          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 555
 556       elsif Is_Class_Wide_Type (T1)
 557         and then not Is_Class_Wide_Type (T2)
 558         and then not Is_Tag_Indeterminate (Rhs)
 559         and then not Is_Dynamically_Tagged (Rhs)
 560       then
 561          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 562       end if;
 563
 564       --  Propagate the tag from a class-wide target to the rhs when the rhs
 565       --  is a tag-indeterminate call.
 566
 567       if Is_Tag_Indeterminate (Rhs) then
 568          if Is_Class_Wide_Type (T1) then
 569             Propagate_Tag (Lhs, Rhs);
 570
 571          elsif Nkind (Rhs) = N_Function_Call
 572               and then Is_Entity_Name (Name (Rhs))
 573               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 574          then
 575             Error_Msg_N
 576               ("call to abstract function must be dispatching", Name (Rhs));
 577
 578          elsif Nkind (Rhs) = N_Qualified_Expression
 579            and then Nkind (Expression (Rhs)) = N_Function_Call
 580               and then Is_Entity_Name (Name (Expression (Rhs)))
 581               and then
 582                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 583          then
 584             Error_Msg_N
 585               ("call to abstract function must be dispatching",
 586                 Name (Expression (Rhs)));
 587          end if;
 588       end if;
 589
 590       --  Ada 2005 (AI-385): When the lhs type is an anonymous access type,
 591       --  apply an implicit conversion of the rhs to that type to force
 592       --  appropriate static and run-time accessibility checks. This applies
 593       --  as well to anonymous access-to-subprogram types that are component
 594       --  subtypes or formal parameters.
 595
 596       if Ada_Version >= Ada_05
 597         and then Is_Access_Type (T1)
 598       then
 599          if Is_Local_Anonymous_Access (T1)
 600            or else Ekind (T2) = E_Anonymous_Access_Subprogram_Type
 601          then
 602             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 603             Analyze_And_Resolve (Rhs, T1);
 604          end if;
 605       end if;
 606
 607       --  Ada 2005 (AI-231): Assignment to not null variable
 608
 609       if Ada_Version >= Ada_05
 610         and then Can_Never_Be_Null (T1)
 611         and then not Assignment_OK (Lhs)
 612       then
 613          --  Case where we know the right hand side is null
 614
 615          if Known_Null (Rhs) then
 616             Apply_Compile_Time_Constraint_Error
 617               (N   => Rhs,
 618                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 619                Reason => CE_Null_Not_Allowed);
 620
 621             --  We still mark this as a possible modification, that's necessary
 622             --  to reset Is_True_Constant, and desirable for xref purposes.
 623
 624             Note_Possible_Modification (Lhs, Sure => True);
 625             return;
 626
 627          --  If we know the right hand side is non-null, then we convert to the
 628          --  target type, since we don't need a run time check in that case.
 629
 630          elsif not Can_Never_Be_Null (T2) then
 631             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 632             Analyze_And_Resolve (Rhs, T1);
 633          end if;
 634       end if;
 635
 636       if Is_Scalar_Type (T1) then
 637          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 638
 639       --  For array types, verify that lengths match. If the right hand side
 640       --  if a function call that has been inlined, the assignment has been
 641       --  rewritten as a block, and the constraint check will be applied to the
 642       --  assignment within the block.
 643
 644       elsif Is_Array_Type (T1)
 645         and then
 646           (Nkind (Rhs) /= N_Type_Conversion
 647             or else Is_Constrained (Etype (Rhs)))
 648         and then
 649           (Nkind (Rhs) /= N_Function_Call
 650             or else Nkind (N) /= N_Block_Statement)
 651       then
 652          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 653          --  but of course the indices do not have to match. If the right-hand
 654          --  side is a type conversion to an unconstrained type, a length check
 655          --  is performed on the expression itself during expansion. In rare
 656          --  cases, the redundant length check is computed on an index type
 657          --  with a different representation, triggering incorrect code in
 658          --  the back end.
 659
 660          Apply_Length_Check (Rhs, Etype (Lhs));
 661
 662       else
 663          --  Discriminant checks are applied in the course of expansion
 664
 665          null;
 666       end if;
 667
 668       --  Note: modifications of the Lhs may only be recorded after
 669       --  checks have been applied.
 670
 671       Note_Possible_Modification (Lhs, Sure => True);
 672
 673       --  ??? a real accessibility check is needed when ???
 674
 675       --  Post warning for redundant assignment or variable to itself
 676
 677       if Warn_On_Redundant_Constructs
 678
 679          --  We only warn for source constructs
 680
 681          and then Comes_From_Source (N)
 682
 683          --  Where the object is the same on both sides
 684
 685          and then Same_Object (Lhs, Original_Node (Rhs))
 686
 687          --  But exclude the case where the right side was an operation
 688          --  that got rewritten (e.g. JUNK + K, where K was known to be
 689          --  zero). We don't want to warn in such a case, since it is
 690          --  reasonable to write such expressions especially when K is
 691          --  defined symbolically in some other package.
 692
 693         and then Nkind (Original_Node (Rhs)) not in N_Op
 694       then
 695          if Nkind (Lhs) in N_Has_Entity then
 696             Error_Msg_NE -- CODEFIX
 697               ("?useless assignment of & to itself!", N, Entity (Lhs));
 698          else
 699             Error_Msg_N -- CODEFIX
 700               ("?useless assignment of object to itself!", N);
 701          end if;
 702       end if;
 703
 704       --  Check for non-allowed composite assignment
 705
 706       if not Support_Composite_Assign_On_Target
 707         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 708         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 709       then
 710          Error_Msg_CRT ("composite assignment", N);
 711       end if;
 712
 713       --  Check elaboration warning for left side if not in elab code
 714
 715       if not In_Subprogram_Or_Concurrent_Unit then
 716          Check_Elab_Assign (Lhs);
 717       end if;
 718
 719       --  Set Referenced_As_LHS if appropriate. We only set this flag if the
 720       --  assignment is a source assignment in the extended main source unit.
 721       --  We are not interested in any reference information outside this
 722       --  context, or in compiler generated assignment statements.
 723
 724       if Comes_From_Source (N)
 725         and then In_Extended_Main_Source_Unit (Lhs)
 726       then
 727          Set_Referenced_Modified (Lhs, Out_Param => False);
 728       end if;
 729
 730       --  Final step. If left side is an entity, then we may be able to
 731       --  reset the current tracked values to new safe values. We only have
 732       --  something to do if the left side is an entity name, and expansion
 733       --  has not modified the node into something other than an assignment,
 734       --  and of course we only capture values if it is safe to do so.
 735
 736       if Is_Entity_Name (Lhs)
 737         and then Nkind (N) = N_Assignment_Statement
 738       then
 739          declare
 740             Ent : constant Entity_Id := Entity (Lhs);
 741
 742          begin
 743             if Safe_To_Capture_Value (N, Ent) then
 744
 745                --  If simple variable on left side, warn if this assignment
 746                --  blots out another one (rendering it useless) and note
 747                --  location of assignment in case no one references value.
 748                --  We only do this for source assignments, otherwise we can
 749                --  generate bogus warnings when an assignment is rewritten as
 750                --  another assignment, and gets tied up with itself.
 751
 752                --  Note: we don't use Record_Last_Assignment here, because we
 753                --  have lots of other stuff to do under control of this test.
 754
 755                if Warn_On_Modified_Unread
 756                  and then Is_Assignable (Ent)
 757                  and then Comes_From_Source (N)
 758                  and then In_Extended_Main_Source_Unit (Ent)
 759                then
 760                   Warn_On_Useless_Assignment (Ent, N);
 761                   Set_Last_Assignment (Ent, Lhs);
 762                end if;
 763
 764                --  If we are assigning an access type and the left side is an
 765                --  entity, then make sure that the Is_Known_[Non_]Null flags
 766                --  properly reflect the state of the entity after assignment.
 767
 768                if Is_Access_Type (T1) then
 769                   if Known_Non_Null (Rhs) then
 770                      Set_Is_Known_Non_Null (Ent, True);
 771
 772                   elsif Known_Null (Rhs)
 773                     and then not Can_Never_Be_Null (Ent)
 774                   then
 775                      Set_Is_Known_Null (Ent, True);
 776
 777                   else
 778                      Set_Is_Known_Null (Ent, False);
 779
 780                      if not Can_Never_Be_Null (Ent) then
 781                         Set_Is_Known_Non_Null (Ent, False);
 782                      end if;
 783                   end if;
 784
 785                --  For discrete types, we may be able to set the current value
 786                --  if the value is known at compile time.
 787
 788                elsif Is_Discrete_Type (T1)
 789                  and then Compile_Time_Known_Value (Rhs)
 790                then
 791                   Set_Current_Value (Ent, Rhs);
 792                else
 793                   Set_Current_Value (Ent, Empty);
 794                end if;
 795
 796             --  If not safe to capture values, kill them
 797
 798             else
 799                Kill_Lhs;
 800             end if;
 801          end;
 802       end if;
 803    end Analyze_Assignment;
 804
 805    -----------------------------
 806    -- Analyze_Block_Statement --
 807    -----------------------------
 808
 809    procedure Analyze_Block_Statement (N : Node_Id) is
 810       Decls : constant List_Id := Declarations (N);
 811       Id    : constant Node_Id := Identifier (N);
 812       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 813
 814    begin
 815       --  If no handled statement sequence is present, things are really
 816       --  messed up, and we just return immediately (this is a defence
 817       --  against previous errors).
 818
 819       if No (HSS) then
 820          return;
 821       end if;
 822
 823       --  Normal processing with HSS present
 824
 825       declare
 826          EH  : constant List_Id := Exception_Handlers (HSS);
 827          Ent : Entity_Id        := Empty;
 828          S   : Entity_Id;
 829
 830          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 831          --  Recursively save value of this global, will be restored on exit
 832
 833       begin
 834          --  Initialize unblocked exit count for statements of begin block
 835          --  plus one for each exception handler that is present.
 836
 837          Unblocked_Exit_Count := 1;
 838
 839          if Present (EH) then
 840             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 841          end if;
 842
 843          --  If a label is present analyze it and mark it as referenced
 844
 845          if Present (Id) then
 846             Analyze (Id);
 847             Ent := Entity (Id);
 848
 849             --  An error defense. If we have an identifier, but no entity,
 850             --  then something is wrong. If we have previous errors, then
 851             --  just remove the identifier and continue, otherwise raise
 852             --  an exception.
 853
 854             if No (Ent) then
 855                if Total_Errors_Detected /= 0 then
 856                   Set_Identifier (N, Empty);
 857                else
 858                   raise Program_Error;
 859                end if;
 860
 861             else
 862                Set_Ekind (Ent, E_Block);
 863                Generate_Reference (Ent, N, ' ');
 864                Generate_Definition (Ent);
 865
 866                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 867                   Set_Label_Construct (Parent (Ent), N);
 868                end if;
 869             end if;
 870          end if;
 871
 872          --  If no entity set, create a label entity
 873
 874          if No (Ent) then
 875             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 876             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 877             Set_Parent (Ent, N);
 878          end if;
 879
 880          Set_Etype (Ent, Standard_Void_Type);
 881          Set_Block_Node (Ent, Identifier (N));
 882          Push_Scope (Ent);
 883
 884          if Present (Decls) then
 885             Analyze_Declarations (Decls);
 886             Check_Completion;
 887             Inspect_Deferred_Constant_Completion (Decls);
 888          end if;
 889
 890          Analyze (HSS);
 891          Process_End_Label (HSS, 'e', Ent);
 892
 893          --  If exception handlers are present, then we indicate that
 894          --  enclosing scopes contain a block with handlers. We only
 895          --  need to mark non-generic scopes.
 896
 897          if Present (EH) then
 898             S := Scope (Ent);
 899             loop
 900                Set_Has_Nested_Block_With_Handler (S);
 901                exit when Is_Overloadable (S)
 902                  or else Ekind (S) = E_Package
 903                  or else Is_Generic_Unit (S);
 904                S := Scope (S);
 905             end loop;
 906          end if;
 907
 908          Check_References (Ent);
 909          Warn_On_Useless_Assignments (Ent);
 910          End_Scope;
 911
 912          if Unblocked_Exit_Count = 0 then
 913             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 914             Check_Unreachable_Code (N);
 915          else
 916             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 917          end if;
 918       end;
 919    end Analyze_Block_Statement;
 920
 921    ----------------------------
 922    -- Analyze_Case_Statement --
 923    ----------------------------
 924
 925    procedure Analyze_Case_Statement (N : Node_Id) is
 926       Exp            : Node_Id;
 927       Exp_Type       : Entity_Id;
 928       Exp_Btype      : Entity_Id;
 929       Last_Choice    : Nat;
 930       Dont_Care      : Boolean;
 931       Others_Present : Boolean;
 932
 933       pragma Warnings (Off, Last_Choice);
 934       pragma Warnings (Off, Dont_Care);
 935       --  Don't care about assigned values
 936
 937       Statements_Analyzed : Boolean := False;
 938       --  Set True if at least some statement sequences get analyzed.
 939       --  If False on exit, means we had a serious error that prevented
 940       --  full analysis of the case statement, and as a result it is not
 941       --  a good idea to output warning messages about unreachable code.
 942
 943       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 944       --  Recursively save value of this global, will be restored on exit
 945
 946       procedure Non_Static_Choice_Error (Choice : Node_Id);
 947       --  Error routine invoked by the generic instantiation below when
 948       --  the case statement has a non static choice.
 949
 950       procedure Process_Statements (Alternative : Node_Id);
 951       --  Analyzes all the statements associated with a case alternative.
 952       --  Needed by the generic instantiation below.
 953
 954       package Case_Choices_Processing is new
 955         Generic_Choices_Processing
 956           (Get_Alternatives          => Alternatives,
 957            Get_Choices               => Discrete_Choices,
 958            Process_Empty_Choice      => No_OP,
 959            Process_Non_Static_Choice => Non_Static_Choice_Error,
 960            Process_Associated_Node   => Process_Statements);
 961       use Case_Choices_Processing;
 962       --  Instantiation of the generic choice processing package
 963
 964       -----------------------------
 965       -- Non_Static_Choice_Error --
 966       -----------------------------
 967
 968       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 969       begin
 970          Flag_Non_Static_Expr
 971            ("choice given in case statement is not static!", Choice);
 972       end Non_Static_Choice_Error;
 973
 974       ------------------------
 975       -- Process_Statements --
 976       ------------------------
 977
 978       procedure Process_Statements (Alternative : Node_Id) is
 979          Choices : constant List_Id := Discrete_Choices (Alternative);
 980          Ent     : Entity_Id;
 981
 982       begin
 983          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 984          Statements_Analyzed := True;
 985
 986          --  An interesting optimization. If the case statement expression
 987          --  is a simple entity, then we can set the current value within
 988          --  an alternative if the alternative has one possible value.
 989
 990          --    case N is
 991          --      when 1      => alpha
 992          --      when 2 | 3  => beta
 993          --      when others => gamma
 994
 995          --  Here we know that N is initially 1 within alpha, but for beta
 996          --  and gamma, we do not know anything more about the initial value.
 997
 998          if Is_Entity_Name (Exp) then
 999             Ent := Entity (Exp);
1000
1001             if Ekind_In (Ent, E_Variable,
1002                               E_In_Out_Parameter,
1003                               E_Out_Parameter)
1004             then
1005                if List_Length (Choices) = 1
1006                  and then Nkind (First (Choices)) in N_Subexpr
1007                  and then Compile_Time_Known_Value (First (Choices))
1008                then
1009                   Set_Current_Value (Entity (Exp), First (Choices));
1010                end if;
1011
1012                Analyze_Statements (Statements (Alternative));
1013
1014                --  After analyzing the case, set the current value to empty
1015                --  since we won't know what it is for the next alternative
1016                --  (unless reset by this same circuit), or after the case.
1017
1018                Set_Current_Value (Entity (Exp), Empty);
1019                return;
1020             end if;
1021          end if;
1022
1023          --  Case where expression is not an entity name of a variable
1024
1025          Analyze_Statements (Statements (Alternative));
1026       end Process_Statements;
1027
1028       --  Table to record choices. Put after subprograms since we make
1029       --  a call to Number_Of_Choices to get the right number of entries.
1030
1031       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
1032       pragma Warnings (Off, Case_Table);
1033
1034    --  Start of processing for Analyze_Case_Statement
1035
1036    begin
1037       Unblocked_Exit_Count := 0;
1038       Exp := Expression (N);
1039       Analyze (Exp);
1040
1041       --  The expression must be of any discrete type. In rare cases, the
1042       --  expander constructs a case statement whose expression has a private
1043       --  type whose full view is discrete. This can happen when generating
1044       --  a stream operation for a variant type after the type is frozen,
1045       --  when the partial of view of the type of the discriminant is private.
1046       --  In that case, use the full view to analyze case alternatives.
1047
1048       if not Is_Overloaded (Exp)
1049         and then not Comes_From_Source (N)
1050         and then Is_Private_Type (Etype (Exp))
1051         and then Present (Full_View (Etype (Exp)))
1052         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1053       then
1054          Resolve (Exp, Etype (Exp));
1055          Exp_Type := Full_View (Etype (Exp));
1056
1057       else
1058          Analyze_And_Resolve (Exp, Any_Discrete);
1059          Exp_Type := Etype (Exp);
1060       end if;
1061
1062       Check_Unset_Reference (Exp);
1063       Exp_Btype := Base_Type (Exp_Type);
1064
1065       --  The expression must be of a discrete type which must be determinable
1066       --  independently of the context in which the expression occurs, but
1067       --  using the fact that the expression must be of a discrete type.
1068       --  Moreover, the type this expression must not be a character literal
1069       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1070
1071       --  If error already reported by Resolve, nothing more to do
1072
1073       if Exp_Btype = Any_Discrete
1074         or else Exp_Btype = Any_Type
1075       then
1076          return;
1077
1078       elsif Exp_Btype = Any_Character then
1079          Error_Msg_N
1080            ("character literal as case expression is ambiguous", Exp);
1081          return;
1082
1083       elsif Ada_Version = Ada_83
1084         and then (Is_Generic_Type (Exp_Btype)
1085                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1086       then
1087          Error_Msg_N
1088            ("(Ada 83) case expression cannot be of a generic type", Exp);
1089          return;
1090       end if;
1091
1092       --  If the case expression is a formal object of mode in out, then
1093       --  treat it as having a nonstatic subtype by forcing use of the base
1094       --  type (which has to get passed to Check_Case_Choices below).  Also
1095       --  use base type when the case expression is parenthesized.
1096
1097       if Paren_Count (Exp) > 0
1098         or else (Is_Entity_Name (Exp)
1099                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1100       then
1101          Exp_Type := Exp_Btype;
1102       end if;
1103
1104       --  Call instantiated Analyze_Choices which does the rest of the work
1105
1106       Analyze_Choices
1107         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
1108
1109       if Exp_Type = Universal_Integer and then not Others_Present then
1110          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1111       end if;
1112
1113       --  If all our exits were blocked by unconditional transfers of control,
1114       --  then the entire CASE statement acts as an unconditional transfer of
1115       --  control, so treat it like one, and check unreachable code. Skip this
1116       --  test if we had serious errors preventing any statement analysis.
1117
1118       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1119          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1120          Check_Unreachable_Code (N);
1121       else
1122          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1123       end if;
1124
1125       if not Expander_Active
1126         and then Compile_Time_Known_Value (Expression (N))
1127         and then Serious_Errors_Detected = 0
1128       then
1129          declare
1130             Chosen : constant Node_Id := Find_Static_Alternative (N);
1131             Alt    : Node_Id;
1132
1133          begin
1134             Alt := First (Alternatives (N));
1135             while Present (Alt) loop
1136                if Alt /= Chosen then
1137                   Remove_Warning_Messages (Statements (Alt));
1138                end if;
1139
1140                Next (Alt);
1141             end loop;
1142          end;
1143       end if;
1144    end Analyze_Case_Statement;
1145
1146    ----------------------------
1147    -- Analyze_Exit_Statement --
1148    ----------------------------
1149
1150    --  If the exit includes a name, it must be the name of a currently open
1151    --  loop. Otherwise there must be an innermost open loop on the stack,
1152    --  to which the statement implicitly refers.
1153
1154    procedure Analyze_Exit_Statement (N : Node_Id) is
1155       Target   : constant Node_Id := Name (N);
1156       Cond     : constant Node_Id := Condition (N);
1157       Scope_Id : Entity_Id;
1158       U_Name   : Entity_Id;
1159       Kind     : Entity_Kind;
1160
1161    begin
1162       if No (Cond) then
1163          Check_Unreachable_Code (N);
1164       end if;
1165
1166       if Present (Target) then
1167          Analyze (Target);
1168          U_Name := Entity (Target);
1169
1170          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1171             Error_Msg_N ("invalid loop name in exit statement", N);
1172             return;
1173          else
1174             Set_Has_Exit (U_Name);
1175          end if;
1176
1177       else
1178          U_Name := Empty;
1179       end if;
1180
1181       for J in reverse 0 .. Scope_Stack.Last loop
1182          Scope_Id := Scope_Stack.Table (J).Entity;
1183          Kind := Ekind (Scope_Id);
1184
1185          if Kind = E_Loop
1186            and then (No (Target) or else Scope_Id = U_Name) then
1187             Set_Has_Exit (Scope_Id);
1188             exit;
1189
1190          elsif Kind = E_Block
1191            or else Kind = E_Loop
1192            or else Kind = E_Return_Statement
1193          then
1194             null;
1195
1196          else
1197             Error_Msg_N
1198               ("cannot exit from program unit or accept statement", N);
1199             return;
1200          end if;
1201       end loop;
1202
1203       --  Verify that if present the condition is a Boolean expression
1204
1205       if Present (Cond) then
1206          Analyze_And_Resolve (Cond, Any_Boolean);
1207          Check_Unset_Reference (Cond);
1208       end if;
1209
1210       --  Chain exit statement to associated loop entity
1211
1212       Set_Next_Exit_Statement  (N, First_Exit_Statement (Scope_Id));
1213       Set_First_Exit_Statement (Scope_Id, N);
1214
1215       --  Since the exit may take us out of a loop, any previous assignment
1216       --  statement is not useless, so clear last assignment indications. It
1217       --  is OK to keep other current values, since if the exit statement
1218       --  does not exit, then the current values are still valid.
1219
1220       Kill_Current_Values (Last_Assignment_Only => True);
1221    end Analyze_Exit_Statement;
1222
1223    ----------------------------
1224    -- Analyze_Goto_Statement --
1225    ----------------------------
1226
1227    procedure Analyze_Goto_Statement (N : Node_Id) is
1228       Label       : constant Node_Id := Name (N);
1229       Scope_Id    : Entity_Id;
1230       Label_Scope : Entity_Id;
1231       Label_Ent   : Entity_Id;
1232
1233    begin
1234       Check_Unreachable_Code (N);
1235       Kill_Current_Values (Last_Assignment_Only => True);
1236
1237       Analyze (Label);
1238       Label_Ent := Entity (Label);
1239
1240       --  Ignore previous error
1241
1242       if Label_Ent = Any_Id then
1243          return;
1244
1245       --  We just have a label as the target of a goto
1246
1247       elsif Ekind (Label_Ent) /= E_Label then
1248          Error_Msg_N ("target of goto statement must be a label", Label);
1249          return;
1250
1251       --  Check that the target of the goto is reachable according to Ada
1252       --  scoping rules. Note: the special gotos we generate for optimizing
1253       --  local handling of exceptions would violate these rules, but we mark
1254       --  such gotos as analyzed when built, so this code is never entered.
1255
1256       elsif not Reachable (Label_Ent) then
1257          Error_Msg_N ("target of goto statement is not reachable", Label);
1258          return;
1259       end if;
1260
1261       --  Here if goto passes initial validity checks
1262
1263       Label_Scope := Enclosing_Scope (Label_Ent);
1264
1265       for J in reverse 0 .. Scope_Stack.Last loop
1266          Scope_Id := Scope_Stack.Table (J).Entity;
1267
1268          if Label_Scope = Scope_Id
1269            or else (Ekind (Scope_Id) /= E_Block
1270                      and then Ekind (Scope_Id) /= E_Loop
1271                      and then Ekind (Scope_Id) /= E_Return_Statement)
1272          then
1273             if Scope_Id /= Label_Scope then
1274                Error_Msg_N
1275                  ("cannot exit from program unit or accept statement", N);
1276             end if;
1277
1278             return;
1279          end if;
1280       end loop;
1281
1282       raise Program_Error;
1283    end Analyze_Goto_Statement;
1284
1285    --------------------------
1286    -- Analyze_If_Statement --
1287    --------------------------
1288
1289    --  A special complication arises in the analysis of if statements
1290
1291    --  The expander has circuitry to completely delete code that it
1292    --  can tell will not be executed (as a result of compile time known
1293    --  conditions). In the analyzer, we ensure that code that will be
1294    --  deleted in this manner is analyzed but not expanded. This is
1295    --  obviously more efficient, but more significantly, difficulties
1296    --  arise if code is expanded and then eliminated (e.g. exception
1297    --  table entries disappear). Similarly, itypes generated in deleted
1298    --  code must be frozen from start, because the nodes on which they
1299    --  depend will not be available at the freeze point.
1300
1301    procedure Analyze_If_Statement (N : Node_Id) is
1302       E : Node_Id;
1303
1304       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1305       --  Recursively save value of this global, will be restored on exit
1306
1307       Save_In_Deleted_Code : Boolean;
1308
1309       Del : Boolean := False;
1310       --  This flag gets set True if a True condition has been found,
1311       --  which means that remaining ELSE/ELSIF parts are deleted.
1312
1313       procedure Analyze_Cond_Then (Cnode : Node_Id);
1314       --  This is applied to either the N_If_Statement node itself or
1315       --  to an N_Elsif_Part node. It deals with analyzing the condition
1316       --  and the THEN statements associated with it.
1317
1318       -----------------------
1319       -- Analyze_Cond_Then --
1320       -----------------------
1321
1322       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1323          Cond : constant Node_Id := Condition (Cnode);
1324          Tstm : constant List_Id := Then_Statements (Cnode);
1325
1326       begin
1327          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1328          Analyze_And_Resolve (Cond, Any_Boolean);
1329          Check_Unset_Reference (Cond);
1330          Set_Current_Value_Condition (Cnode);
1331
1332          --  If already deleting, then just analyze then statements
1333
1334          if Del then
1335             Analyze_Statements (Tstm);
1336
1337          --  Compile time known value, not deleting yet
1338
1339          elsif Compile_Time_Known_Value (Cond) then
1340             Save_In_Deleted_Code := In_Deleted_Code;
1341
1342             --  If condition is True, then analyze the THEN statements
1343             --  and set no expansion for ELSE and ELSIF parts.
1344
1345             if Is_True (Expr_Value (Cond)) then
1346                Analyze_Statements (Tstm);
1347                Del := True;
1348                Expander_Mode_Save_And_Set (False);
1349                In_Deleted_Code := True;
1350
1351             --  If condition is False, analyze THEN with expansion off
1352
1353             else -- Is_False (Expr_Value (Cond))
1354                Expander_Mode_Save_And_Set (False);
1355                In_Deleted_Code := True;
1356                Analyze_Statements (Tstm);
1357                Expander_Mode_Restore;
1358                In_Deleted_Code := Save_In_Deleted_Code;
1359             end if;
1360
1361          --  Not known at compile time, not deleting, normal analysis
1362
1363          else
1364             Analyze_Statements (Tstm);
1365          end if;
1366       end Analyze_Cond_Then;
1367
1368    --  Start of Analyze_If_Statement
1369
1370    begin
1371       --  Initialize exit count for else statements. If there is no else
1372       --  part, this count will stay non-zero reflecting the fact that the
1373       --  uncovered else case is an unblocked exit.
1374
1375       Unblocked_Exit_Count := 1;
1376       Analyze_Cond_Then (N);
1377
1378       --  Now to analyze the elsif parts if any are present
1379
1380       if Present (Elsif_Parts (N)) then
1381          E := First (Elsif_Parts (N));
1382          while Present (E) loop
1383             Analyze_Cond_Then (E);
1384             Next (E);
1385          end loop;
1386       end if;
1387
1388       if Present (Else_Statements (N)) then
1389          Analyze_Statements (Else_Statements (N));
1390       end if;
1391
1392       --  If all our exits were blocked by unconditional transfers of control,
1393       --  then the entire IF statement acts as an unconditional transfer of
1394       --  control, so treat it like one, and check unreachable code.
1395
1396       if Unblocked_Exit_Count = 0 then
1397          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1398          Check_Unreachable_Code (N);
1399       else
1400          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1401       end if;
1402
1403       if Del then
1404          Expander_Mode_Restore;
1405          In_Deleted_Code := Save_In_Deleted_Code;
1406       end if;
1407
1408       if not Expander_Active
1409         and then Compile_Time_Known_Value (Condition (N))
1410         and then Serious_Errors_Detected = 0
1411       then
1412          if Is_True (Expr_Value (Condition (N))) then
1413             Remove_Warning_Messages (Else_Statements (N));
1414
1415             if Present (Elsif_Parts (N)) then
1416                E := First (Elsif_Parts (N));
1417                while Present (E) loop
1418                   Remove_Warning_Messages (Then_Statements (E));
1419                   Next (E);
1420                end loop;
1421             end if;
1422
1423          else
1424             Remove_Warning_Messages (Then_Statements (N));
1425          end if;
1426       end if;
1427    end Analyze_If_Statement;
1428
1429    ----------------------------------------
1430    -- Analyze_Implicit_Label_Declaration --
1431    ----------------------------------------
1432
1433    --  An implicit label declaration is generated in the innermost
1434    --  enclosing declarative part. This is done for labels as well as
1435    --  block and loop names.
1436
1437    --  Note: any changes in this routine may need to be reflected in
1438    --  Analyze_Label_Entity.
1439
1440    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1441       Id : constant Node_Id := Defining_Identifier (N);
1442    begin
1443       Enter_Name          (Id);
1444       Set_Ekind           (Id, E_Label);
1445       Set_Etype           (Id, Standard_Void_Type);
1446       Set_Enclosing_Scope (Id, Current_Scope);
1447    end Analyze_Implicit_Label_Declaration;
1448
1449    ------------------------------
1450    -- Analyze_Iteration_Scheme --
1451    ------------------------------
1452
1453    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1454
1455       procedure Process_Bounds (R : Node_Id);
1456       --  If the iteration is given by a range, create temporaries and
1457       --  assignment statements block to capture the bounds and perform
1458       --  required finalization actions in case a bound includes a function
1459       --  call that uses the temporary stack. We first pre-analyze a copy of
1460       --  the range in order to determine the expected type, and analyze and
1461       --  resolve the original bounds.
1462
1463       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1464       --  If the bounds are given by a 'Range reference on a function call
1465       --  that returns a controlled array, introduce an explicit declaration
1466       --  to capture the bounds, so that the function result can be finalized
1467       --  in timely fashion.
1468
1469       --------------------
1470       -- Process_Bounds --
1471       --------------------
1472
1473       procedure Process_Bounds (R : Node_Id) is
1474          Loc          : constant Source_Ptr := Sloc (N);
1475          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1476          Lo           : constant Node_Id := Low_Bound  (R);
1477          Hi           : constant Node_Id := High_Bound (R);
1478          New_Lo_Bound : Node_Id := Empty;
1479          New_Hi_Bound : Node_Id := Empty;
1480          Typ          : Entity_Id;
1481          Save_Analysis : Boolean;
1482
1483          function One_Bound
1484            (Original_Bound : Node_Id;
1485             Analyzed_Bound : Node_Id) return Node_Id;
1486          --  Capture value of bound and return captured value
1487
1488          ---------------
1489          -- One_Bound --
1490          ---------------
1491
1492          function One_Bound
1493            (Original_Bound : Node_Id;
1494             Analyzed_Bound : Node_Id) return Node_Id
1495          is
1496             Assign : Node_Id;
1497             Id     : Entity_Id;
1498             Decl   : Node_Id;
1499
1500          begin
1501             --  If the bound is a constant or an object, no need for a separate
1502             --  declaration. If the bound is the result of previous expansion
1503             --  it is already analyzed and should not be modified. Note that
1504             --  the Bound will be resolved later, if needed, as part of the
1505             --  call to Make_Index (literal bounds may need to be resolved to
1506             --  type Integer).
1507
1508             if Analyzed (Original_Bound) then
1509                return Original_Bound;
1510
1511             elsif Nkind_In (Analyzed_Bound, N_Integer_Literal,
1512                                             N_Character_Literal)
1513               or else Is_Entity_Name (Analyzed_Bound)
1514             then
1515                Analyze_And_Resolve (Original_Bound, Typ);
1516                return Original_Bound;
1517             end if;
1518
1519             --  Here we need to capture the value
1520
1521             Analyze_And_Resolve (Original_Bound, Typ);
1522
1523             Id := Make_Temporary (Loc, 'S', Original_Bound);
1524
1525             --  Normally, the best approach is simply to generate a constant
1526             --  declaration that captures the bound. However, there is a nasty
1527             --  case where this is wrong. If the bound is complex, and has a
1528             --  possible use of the secondary stack, we need to generate a
1529             --  separate assignment statement to ensure the creation of a block
1530             --  which will release the secondary stack.
1531
1532             --  We prefer the constant declaration, since it leaves us with a
1533             --  proper trace of the value, useful in optimizations that get rid
1534             --  of junk range checks.
1535
1536             --  Probably we want something like the Side_Effect_Free routine
1537             --  in Exp_Util, but for now, we just optimize the cases of 'Last
1538             --  and 'First applied to an entity, since these are the important
1539             --  cases for range check optimizations.
1540
1541             if Nkind (Original_Bound) = N_Attribute_Reference
1542               and then (Attribute_Name (Original_Bound) = Name_First
1543                           or else
1544                         Attribute_Name (Original_Bound) = Name_Last)
1545               and then Is_Entity_Name (Prefix (Original_Bound))
1546             then
1547                Decl :=
1548                  Make_Object_Declaration (Loc,
1549                    Defining_Identifier => Id,
1550                    Constant_Present    => True,
1551                    Object_Definition   => New_Occurrence_Of (Typ, Loc),
1552                    Expression          => Relocate_Node (Original_Bound));
1553
1554                Insert_Before (Parent (N), Decl);
1555                Analyze (Decl);
1556                Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1557                return Expression (Decl);
1558             end if;
1559
1560             --  Here we make a declaration with a separate assignment statement
1561
1562             Decl :=
1563               Make_Object_Declaration (Loc,
1564                 Defining_Identifier => Id,
1565                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1566
1567             Insert_Before (Parent (N), Decl);
1568             Analyze (Decl);
1569
1570             Assign :=
1571               Make_Assignment_Statement (Loc,
1572                 Name        => New_Occurrence_Of (Id, Loc),
1573                 Expression  => Relocate_Node (Original_Bound));
1574
1575             --  If the relocated node is a function call then check if some
1576             --  SCIL node references it and needs readjustment.
1577
1578             if Generate_SCIL
1579               and then Nkind (Original_Bound) = N_Function_Call
1580             then
1581                Adjust_SCIL_Node (Original_Bound, Expression (Assign));
1582             end if;
1583
1584             Insert_Before (Parent (N), Assign);
1585             Analyze (Assign);
1586
1587             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1588
1589             if Nkind (Assign) = N_Assignment_Statement then
1590                return Expression (Assign);
1591             else
1592                return Original_Bound;
1593             end if;
1594          end One_Bound;
1595
1596       --  Start of processing for Process_Bounds
1597
1598       begin
1599          --  Determine expected type of range by analyzing separate copy
1600          --  Do the analysis and resolution of the copy of the bounds with
1601          --  expansion disabled, to prevent the generation of finalization
1602          --  actions on each bound. This prevents memory leaks when the
1603          --  bounds contain calls to functions returning controlled arrays.
1604
1605          Set_Parent (R_Copy, Parent (R));
1606          Save_Analysis := Full_Analysis;
1607          Full_Analysis := False;
1608          Expander_Mode_Save_And_Set (False);
1609
1610          Analyze (R_Copy);
1611
1612          if Is_Overloaded (R_Copy) then
1613
1614             --  Apply preference rules for range of predefined integer types,
1615             --  or diagnose true ambiguity.
1616
1617             declare
1618                I     : Interp_Index;
1619                It    : Interp;
1620                Found : Entity_Id := Empty;
1621
1622             begin
1623                Get_First_Interp (R_Copy, I, It);
1624                while Present (It.Typ) loop
1625                   if Is_Discrete_Type (It.Typ) then
1626                      if No (Found) then
1627                         Found := It.Typ;
1628                      else
1629                         if Scope (Found) = Standard_Standard then
1630                            null;
1631
1632                         elsif Scope (It.Typ) = Standard_Standard then
1633                            Found := It.Typ;
1634
1635                         else
1636                            --  Both of them are user-defined
1637
1638                            Error_Msg_N
1639                              ("ambiguous bounds in range of iteration",
1640                                R_Copy);
1641                            Error_Msg_N ("\possible interpretations:", R_Copy);
1642                            Error_Msg_NE ("\\} ", R_Copy, Found);
1643                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1644                            exit;
1645                         end if;
1646                      end if;
1647                   end if;
1648
1649                   Get_Next_Interp (I, It);
1650                end loop;
1651             end;
1652          end if;
1653
1654          Resolve (R_Copy);
1655          Expander_Mode_Restore;
1656          Full_Analysis := Save_Analysis;
1657
1658          Typ := Etype (R_Copy);
1659
1660          --  If the type of the discrete range is Universal_Integer, then
1661          --  the bound's type must be resolved to Integer, and any object
1662          --  used to hold the bound must also have type Integer, unless the
1663          --  literal bounds are constant-folded expressions that carry a user-
1664          --  defined type.
1665
1666          if Typ = Universal_Integer then
1667             if Nkind (Lo) = N_Integer_Literal
1668               and then Present (Etype (Lo))
1669               and then Scope (Etype (Lo)) /= Standard_Standard
1670             then
1671                Typ := Etype (Lo);
1672
1673             elsif Nkind (Hi) = N_Integer_Literal
1674               and then Present (Etype (Hi))
1675               and then Scope (Etype (Hi)) /= Standard_Standard
1676             then
1677                Typ := Etype (Hi);
1678
1679             else
1680                Typ := Standard_Integer;
1681             end if;
1682          end if;
1683
1684          Set_Etype (R, Typ);
1685
1686          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1687          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1688
1689          --  Propagate staticness to loop range itself, in case the
1690          --  corresponding subtype is static.
1691
1692          if New_Lo_Bound /= Lo
1693            and then Is_Static_Expression (New_Lo_Bound)
1694          then
1695             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1696          end if;
1697
1698          if New_Hi_Bound /= Hi
1699            and then Is_Static_Expression (New_Hi_Bound)
1700          then
1701             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1702          end if;
1703       end Process_Bounds;
1704
1705       --------------------------------------
1706       -- Check_Controlled_Array_Attribute --
1707       --------------------------------------
1708
1709       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1710       begin
1711          if Nkind (DS) = N_Attribute_Reference
1712             and then Is_Entity_Name (Prefix (DS))
1713             and then Ekind (Entity (Prefix (DS))) = E_Function
1714             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1715             and then
1716               Is_Controlled (
1717                 Component_Type (Etype (Entity (Prefix (DS)))))
1718             and then Expander_Active
1719          then
1720             declare
1721                Loc  : constant Source_Ptr := Sloc (N);
1722                Arr  : constant Entity_Id := Etype (Entity (Prefix (DS)));
1723                Indx : constant Entity_Id :=
1724                         Base_Type (Etype (First_Index (Arr)));
1725                Subt : constant Entity_Id := Make_Temporary (Loc, 'S');
1726                Decl : Node_Id;
1727
1728             begin
1729                Decl :=
1730                  Make_Subtype_Declaration (Loc,
1731                    Defining_Identifier => Subt,
1732                    Subtype_Indication  =>
1733                       Make_Subtype_Indication (Loc,
1734                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1735                         Constraint =>
1736                           Make_Range_Constraint (Loc,
1737                             Relocate_Node (DS))));
1738                Insert_Before (Parent (N), Decl);
1739                Analyze (Decl);
1740
1741                Rewrite (DS,
1742                   Make_Attribute_Reference (Loc,
1743                     Prefix => New_Reference_To (Subt, Loc),
1744                     Attribute_Name => Attribute_Name (DS)));
1745                Analyze (DS);
1746             end;
1747          end if;
1748       end Check_Controlled_Array_Attribute;
1749
1750    --  Start of processing for Analyze_Iteration_Scheme
1751
1752    begin
1753       --  For an infinite loop, there is no iteration scheme
1754
1755       if No (N) then
1756          return;
1757
1758       else
1759          declare
1760             Cond : constant Node_Id := Condition (N);
1761
1762          begin
1763             --  For WHILE loop, verify that the condition is a Boolean
1764             --  expression and resolve and check it.
1765
1766             if Present (Cond) then
1767                Analyze_And_Resolve (Cond, Any_Boolean);
1768                Check_Unset_Reference (Cond);
1769                Set_Current_Value_Condition (N);
1770                return;
1771
1772             --  Else we have a FOR loop
1773
1774             else
1775                declare
1776                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1777                   Id : constant Entity_Id := Defining_Identifier (LP);
1778                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1779
1780                begin
1781                   Enter_Name (Id);
1782
1783                   --  We always consider the loop variable to be referenced,
1784                   --  since the loop may be used just for counting purposes.
1785
1786                   Generate_Reference (Id, N, ' ');
1787
1788                   --  Check for case of loop variable hiding a local
1789                   --  variable (used later on to give a nice warning
1790                   --  if the hidden variable is never assigned).
1791
1792                   declare
1793                      H : constant Entity_Id := Homonym (Id);
1794                   begin
1795                      if Present (H)
1796                        and then Enclosing_Dynamic_Scope (H) =
1797                                 Enclosing_Dynamic_Scope (Id)
1798                        and then Ekind (H) = E_Variable
1799                        and then Is_Discrete_Type (Etype (H))
1800                      then
1801                         Set_Hiding_Loop_Variable (H, Id);
1802                      end if;
1803                   end;
1804
1805                   --  Now analyze the subtype definition. If it is
1806                   --  a range, create temporaries for bounds.
1807
1808                   if Nkind (DS) = N_Range
1809                     and then Expander_Active
1810                   then
1811                      Process_Bounds (DS);
1812                   else
1813                      Analyze (DS);
1814                   end if;
1815
1816                   if DS = Error then
1817                      return;
1818                   end if;
1819
1820                   --  The subtype indication may denote the completion
1821                   --  of an incomplete type declaration.
1822
1823                   if Is_Entity_Name (DS)
1824                     and then Present (Entity (DS))
1825                     and then Is_Type (Entity (DS))
1826                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1827                   then
1828                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1829                      Set_Etype  (DS, Entity (DS));
1830                   end if;
1831
1832                   if not Is_Discrete_Type (Etype (DS)) then
1833                      Wrong_Type (DS, Any_Discrete);
1834                      Set_Etype (DS, Any_Type);
1835                   end if;
1836
1837                   Check_Controlled_Array_Attribute (DS);
1838
1839                   Make_Index (DS, LP);
1840
1841                   Set_Ekind          (Id, E_Loop_Parameter);
1842                   Set_Etype          (Id, Etype (DS));
1843
1844                   --  Treat a range as an implicit reference to the type, to
1845                   --  inhibit spurious warnings.
1846
1847                   Generate_Reference (Base_Type (Etype (DS)), N, ' ');
1848                   Set_Is_Known_Valid (Id, True);
1849
1850                   --  The loop is not a declarative part, so the only entity
1851                   --  declared "within" must be frozen explicitly.
1852
1853                   declare
1854                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1855                   begin
1856                      if Is_Non_Empty_List (Flist) then
1857                         Insert_Actions (N, Flist);
1858                      end if;
1859                   end;
1860
1861                   --  Check for null or possibly null range and issue warning.
1862                   --  We suppress such messages in generic templates and
1863                   --  instances, because in practice they tend to be dubious
1864                   --  in these cases.
1865
1866                   if Nkind (DS) = N_Range
1867                     and then Comes_From_Source (N)
1868                   then
1869                      declare
1870                         L : constant Node_Id := Low_Bound  (DS);
1871                         H : constant Node_Id := High_Bound (DS);
1872
1873                      begin
1874                         --  If range of loop is null, issue warning
1875
1876                         if Compile_Time_Compare
1877                             (L, H, Assume_Valid => True) = GT
1878                         then
1879                            --  Suppress the warning if inside a generic
1880                            --  template or instance, since in practice
1881                            --  they tend to be dubious in these cases since
1882                            --  they can result from intended parametrization.
1883
1884                            if not Inside_A_Generic
1885                               and then not In_Instance
1886                            then
1887                               --  Specialize msg if invalid values could make
1888                               --  the loop non-null after all.
1889
1890                               if Compile_Time_Compare
1891                                    (L, H, Assume_Valid => False) = GT
1892                               then
1893                                  Error_Msg_N
1894                                    ("?loop range is null, "
1895                                     & "loop will not execute",
1896                                     DS);
1897
1898                                  --  Since we know the range of the loop is
1899                                  --  null, set the appropriate flag to remove
1900                                  --  the loop entirely during expansion.
1901
1902                                  Set_Is_Null_Loop (Parent (N));
1903
1904                               --  Here is where the loop could execute because
1905                               --  of invalid values, so issue appropriate
1906                               --  message and in this case we do not set the
1907                               --  Is_Null_Loop flag since the loop may execute.
1908
1909                               else
1910                                  Error_Msg_N
1911                                    ("?loop range may be null, "
1912                                     & "loop may not execute",
1913                                     DS);
1914                                  Error_Msg_N
1915                                    ("?can only execute if invalid values "
1916                                     & "are present",
1917                                     DS);
1918                               end if;
1919                            end if;
1920
1921                            --  In either case, suppress warnings in the body of
1922                            --  the loop, since it is likely that these warnings
1923                            --  will be inappropriate if the loop never actually
1924                            --  executes, which is unlikely.
1925
1926                            Set_Suppress_Loop_Warnings (Parent (N));
1927
1928                         --  The other case for a warning is a reverse loop
1929                         --  where the upper bound is the integer literal
1930                         --  zero or one, and the lower bound can be positive.
1931
1932                         --  For example, we have
1933
1934                         --     for J in reverse N .. 1 loop
1935
1936                         --  In practice, this is very likely to be a case
1937                         --  of reversing the bounds incorrectly in the range.
1938
1939                         elsif Reverse_Present (LP)
1940                           and then Nkind (Original_Node (H)) =
1941                                                           N_Integer_Literal
1942                           and then (Intval (Original_Node (H)) = Uint_0
1943                                       or else
1944                                     Intval (Original_Node (H)) = Uint_1)
1945                         then
1946                            Error_Msg_N ("?loop range may be null", DS);
1947                            Error_Msg_N ("\?bounds may be wrong way round", DS);
1948                         end if;
1949                      end;
1950                   end if;
1951                end;
1952             end if;
1953          end;
1954       end if;
1955    end Analyze_Iteration_Scheme;
1956
1957    -------------------
1958    -- Analyze_Label --
1959    -------------------
1960
1961    --  Note: the semantic work required for analyzing labels (setting them as
1962    --  reachable) was done in a prepass through the statements in the block,
1963    --  so that forward gotos would be properly handled. See Analyze_Statements
1964    --  for further details. The only processing required here is to deal with
1965    --  optimizations that depend on an assumption of sequential control flow,
1966    --  since of course the occurrence of a label breaks this assumption.
1967
1968    procedure Analyze_Label (N : Node_Id) is
1969       pragma Warnings (Off, N);
1970    begin
1971       Kill_Current_Values;
1972    end Analyze_Label;
1973
1974    --------------------------
1975    -- Analyze_Label_Entity --
1976    --------------------------
1977
1978    procedure Analyze_Label_Entity (E : Entity_Id) is
1979    begin
1980       Set_Ekind           (E, E_Label);
1981       Set_Etype           (E, Standard_Void_Type);
1982       Set_Enclosing_Scope (E, Current_Scope);
1983       Set_Reachable       (E, True);
1984    end Analyze_Label_Entity;
1985
1986    ----------------------------
1987    -- Analyze_Loop_Statement --
1988    ----------------------------
1989
1990    procedure Analyze_Loop_Statement (N : Node_Id) is
1991       Loop_Statement : constant Node_Id := N;
1992
1993       Id   : constant Node_Id := Identifier (Loop_Statement);
1994       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
1995       Ent  : Entity_Id;
1996
1997    begin
1998       if Present (Id) then
1999
2000          --  Make name visible, e.g. for use in exit statements. Loop
2001          --  labels are always considered to be referenced.
2002
2003          Analyze (Id);
2004          Ent := Entity (Id);
2005
2006          --  Guard against serious error (typically, a scope mismatch when
2007          --  semantic analysis is requested) by creating loop entity to
2008          --  continue analysis.
2009
2010          if No (Ent) then
2011             if Total_Errors_Detected /= 0 then
2012                Ent :=
2013                  New_Internal_Entity
2014                    (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2015             else
2016                raise Program_Error;
2017             end if;
2018
2019          else
2020             Generate_Reference  (Ent, Loop_Statement, ' ');
2021             Generate_Definition (Ent);
2022
2023             --  If we found a label, mark its type. If not, ignore it, since it
2024             --  means we have a conflicting declaration, which would already
2025             --  have been diagnosed at declaration time. Set Label_Construct
2026             --  of the implicit label declaration, which is not created by the
2027             --  parser for generic units.
2028
2029             if Ekind (Ent) = E_Label then
2030                Set_Ekind (Ent, E_Loop);
2031
2032                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
2033                   Set_Label_Construct (Parent (Ent), Loop_Statement);
2034                end if;
2035             end if;
2036          end if;
2037
2038       --  Case of no identifier present
2039
2040       else
2041          Ent :=
2042            New_Internal_Entity
2043              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2044          Set_Etype (Ent,  Standard_Void_Type);
2045          Set_Parent (Ent, Loop_Statement);
2046       end if;
2047
2048       --  Kill current values on entry to loop, since statements in body of
2049       --  loop may have been executed before the loop is entered. Similarly we
2050       --  kill values after the loop, since we do not know that the body of the
2051       --  loop was executed.
2052
2053       Kill_Current_Values;
2054       Push_Scope (Ent);
2055       Analyze_Iteration_Scheme (Iter);
2056       Analyze_Statements (Statements (Loop_Statement));
2057       Process_End_Label (Loop_Statement, 'e', Ent);
2058       End_Scope;
2059       Kill_Current_Values;
2060
2061       --  Check for infinite loop. Skip check for generated code, since it
2062       --  justs waste time and makes debugging the routine called harder.
2063
2064       --  Note that we have to wait till the body of the loop is fully analyzed
2065       --  before making this call, since Check_Infinite_Loop_Warning relies on
2066       --  being able to use semantic visibility information to find references.
2067
2068       if Comes_From_Source (N) then
2069          Check_Infinite_Loop_Warning (N);
2070       end if;
2071
2072       --  Code after loop is unreachable if the loop has no WHILE or FOR
2073       --  and contains no EXIT statements within the body of the loop.
2074
2075       if No (Iter) and then not Has_Exit (Ent) then
2076          Check_Unreachable_Code (N);
2077       end if;
2078    end Analyze_Loop_Statement;
2079
2080    ----------------------------
2081    -- Analyze_Null_Statement --
2082    ----------------------------
2083
2084    --  Note: the semantics of the null statement is implemented by a single
2085    --  null statement, too bad everything isn't as simple as this!
2086
2087    procedure Analyze_Null_Statement (N : Node_Id) is
2088       pragma Warnings (Off, N);
2089    begin
2090       null;
2091    end Analyze_Null_Statement;
2092
2093    ------------------------
2094    -- Analyze_Statements --
2095    ------------------------
2096
2097    procedure Analyze_Statements (L : List_Id) is
2098       S   : Node_Id;
2099       Lab : Entity_Id;
2100
2101    begin
2102       --  The labels declared in the statement list are reachable from
2103       --  statements in the list. We do this as a prepass so that any
2104       --  goto statement will be properly flagged if its target is not
2105       --  reachable. This is not required, but is nice behavior!
2106
2107       S := First (L);
2108       while Present (S) loop
2109          if Nkind (S) = N_Label then
2110             Analyze (Identifier (S));
2111             Lab := Entity (Identifier (S));
2112
2113             --  If we found a label mark it as reachable
2114
2115             if Ekind (Lab) = E_Label then
2116                Generate_Definition (Lab);
2117                Set_Reachable (Lab);
2118
2119                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
2120                   Set_Label_Construct (Parent (Lab), S);
2121                end if;
2122
2123             --  If we failed to find a label, it means the implicit declaration
2124             --  of the label was hidden.  A for-loop parameter can do this to
2125             --  a label with the same name inside the loop, since the implicit
2126             --  label declaration is in the innermost enclosing body or block
2127             --  statement.
2128
2129             else
2130                Error_Msg_Sloc := Sloc (Lab);
2131                Error_Msg_N
2132                  ("implicit label declaration for & is hidden#",
2133                   Identifier (S));
2134             end if;
2135          end if;
2136
2137          Next (S);
2138       end loop;
2139
2140       --  Perform semantic analysis on all statements
2141
2142       Conditional_Statements_Begin;
2143
2144       S := First (L);
2145       while Present (S) loop
2146          Analyze (S);
2147          Next (S);
2148       end loop;
2149
2150       Conditional_Statements_End;
2151
2152       --  Make labels unreachable. Visibility is not sufficient, because
2153       --  labels in one if-branch for example are not reachable from the
2154       --  other branch, even though their declarations are in the enclosing
2155       --  declarative part.
2156
2157       S := First (L);
2158       while Present (S) loop
2159          if Nkind (S) = N_Label then
2160             Set_Reachable (Entity (Identifier (S)), False);
2161          end if;
2162
2163          Next (S);
2164       end loop;
2165    end Analyze_Statements;
2166
2167    ----------------------------
2168    -- Check_Unreachable_Code --
2169    ----------------------------
2170
2171    procedure Check_Unreachable_Code (N : Node_Id) is
2172       Error_Loc : Source_Ptr;
2173       P         : Node_Id;
2174
2175    begin
2176       if Is_List_Member (N)
2177         and then Comes_From_Source (N)
2178       then
2179          declare
2180             Nxt : Node_Id;
2181
2182          begin
2183             Nxt := Original_Node (Next (N));
2184
2185             --  If a label follows us, then we never have dead code, since
2186             --  someone could branch to the label, so we just ignore it.
2187
2188             if Nkind (Nxt) = N_Label then
2189                return;
2190
2191             --  Otherwise see if we have a real statement following us
2192
2193             elsif Present (Nxt)
2194               and then Comes_From_Source (Nxt)
2195               and then Is_Statement (Nxt)
2196             then
2197                --  Special very annoying exception. If we have a return that
2198                --  follows a raise, then we allow it without a warning, since
2199                --  the Ada RM annoyingly requires a useless return here!
2200
2201                if Nkind (Original_Node (N)) /= N_Raise_Statement
2202                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2203                then
2204                   --  The rather strange shenanigans with the warning message
2205                   --  here reflects the fact that Kill_Dead_Code is very good
2206                   --  at removing warnings in deleted code, and this is one
2207                   --  warning we would prefer NOT to have removed.
2208
2209                   Error_Loc := Sloc (Nxt);
2210
2211                   --  If we have unreachable code, analyze and remove the
2212                   --  unreachable code, since it is useless and we don't
2213                   --  want to generate junk warnings.
2214
2215                   --  We skip this step if we are not in code generation mode.
2216                   --  This is the one case where we remove dead code in the
2217                   --  semantics as opposed to the expander, and we do not want
2218                   --  to remove code if we are not in code generation mode,
2219                   --  since this messes up the ASIS trees.
2220
2221                   --  Note that one might react by moving the whole circuit to
2222                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2223
2224                   if Operating_Mode = Generate_Code then
2225                      loop
2226                         Nxt := Next (N);
2227
2228                         --  Quit deleting when we have nothing more to delete
2229                         --  or if we hit a label (since someone could transfer
2230                         --  control to a label, so we should not delete it).
2231
2232                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2233
2234                         --  Statement/declaration is to be deleted
2235
2236                         Analyze (Nxt);
2237                         Remove (Nxt);
2238                         Kill_Dead_Code (Nxt);
2239                      end loop;
2240                   end if;
2241
2242                   --  Now issue the warning
2243
2244                   Error_Msg ("?unreachable code!", Error_Loc);
2245                end if;
2246
2247             --  If the unconditional transfer of control instruction is
2248             --  the last statement of a sequence, then see if our parent
2249             --  is one of the constructs for which we count unblocked exits,
2250             --  and if so, adjust the count.
2251
2252             else
2253                P := Parent (N);
2254
2255                --  Statements in THEN part or ELSE part of IF statement
2256
2257                if Nkind (P) = N_If_Statement then
2258                   null;
2259
2260                --  Statements in ELSIF part of an IF statement
2261
2262                elsif Nkind (P) = N_Elsif_Part then
2263                   P := Parent (P);
2264                   pragma Assert (Nkind (P) = N_If_Statement);
2265
2266                --  Statements in CASE statement alternative
2267
2268                elsif Nkind (P) = N_Case_Statement_Alternative then
2269                   P := Parent (P);
2270                   pragma Assert (Nkind (P) = N_Case_Statement);
2271
2272                --  Statements in body of block
2273
2274                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2275                  and then Nkind (Parent (P)) = N_Block_Statement
2276                then
2277                   null;
2278
2279                --  Statements in exception handler in a block
2280
2281                elsif Nkind (P) = N_Exception_Handler
2282                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2283                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2284                then
2285                   null;
2286
2287                --  None of these cases, so return
2288
2289                else
2290                   return;
2291                end if;
2292
2293                --  This was one of the cases we are looking for (i.e. the
2294                --  parent construct was IF, CASE or block) so decrement count.
2295
2296                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2297             end if;
2298          end;
2299       end if;
2300    end Check_Unreachable_Code;
2301
2302 end Sem_Ch5;