gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Aux;  use Sem_Aux;
  42 with Sem_Case; use Sem_Case;
  43 with Sem_Ch3;  use Sem_Ch3;
  44 with Sem_Ch8;  use Sem_Ch8;
  45 with Sem_Disp; use Sem_Disp;
  46 with Sem_Elab; use Sem_Elab;
  47 with Sem_Eval; use Sem_Eval;
  48 with Sem_Res;  use Sem_Res;
  49 with Sem_Type; use Sem_Type;
  50 with Sem_Util; use Sem_Util;
  51 with Sem_Warn; use Sem_Warn;
  52 with Snames;   use Snames;
  53 with Stand;    use Stand;
  54 with Sinfo;    use Sinfo;
  55 with Targparm; use Targparm;
  56 with Tbuild;   use Tbuild;
  57 with Uintp;    use Uintp;
  58
  59 package body Sem_Ch5 is
  60
  61    Unblocked_Exit_Count : Nat := 0;
  62    --  This variable is used when processing if statements, case statements,
  63    --  and block statements. It counts the number of exit points that are not
  64    --  blocked by unconditional transfer instructions: for IF and CASE, these
  65    --  are the branches of the conditional; for a block, they are the statement
  66    --  sequence of the block, and the statement sequences of any exception
  67    --  handlers that are part of the block. When processing is complete, if
  68    --  this count is zero, it means that control cannot fall through the IF,
  69    --  CASE or block statement. This is used for the generation of warning
  70    --  messages. This variable is recursively saved on entry to processing the
  71    --  construct, and restored on exit.
  72
  73    ------------------------
  74    -- Analyze_Assignment --
  75    ------------------------
  76
  77    procedure Analyze_Assignment (N : Node_Id) is
  78       Lhs  : constant Node_Id := Name (N);
  79       Rhs  : constant Node_Id := Expression (N);
  80       T1   : Entity_Id;
  81       T2   : Entity_Id;
  82       Decl : Node_Id;
  83
  84       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  85       --  N is the node for the left hand side of an assignment, and it is not
  86       --  a variable. This routine issues an appropriate diagnostic.
  87
  88       procedure Kill_Lhs;
  89       --  This is called to kill current value settings of a simple variable
  90       --  on the left hand side. We call it if we find any error in analyzing
  91       --  the assignment, and at the end of processing before setting any new
  92       --  current values in place.
  93
  94       procedure Set_Assignment_Type
  95         (Opnd      : Node_Id;
  96          Opnd_Type : in out Entity_Id);
  97       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
  98       --  is the nominal subtype. This procedure is used to deal with cases
  99       --  where the nominal subtype must be replaced by the actual subtype.
 100
 101       -------------------------------
 102       -- Diagnose_Non_Variable_Lhs --
 103       -------------------------------
 104
 105       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 106       begin
 107          --  Not worth posting another error if left hand side already
 108          --  flagged as being illegal in some respect.
 109
 110          if Error_Posted (N) then
 111             return;
 112
 113          --  Some special bad cases of entity names
 114
 115          elsif Is_Entity_Name (N) then
 116             declare
 117                Ent : constant Entity_Id := Entity (N);
 118
 119             begin
 120                if Ekind (Ent) = E_In_Parameter then
 121                   Error_Msg_N
 122                     ("assignment to IN mode parameter not allowed", N);
 123
 124                --  Renamings of protected private components are turned into
 125                --  constants when compiling a protected function. In the case
 126                --  of single protected types, the private component appears
 127                --  directly.
 128
 129                elsif (Is_Prival (Ent)
 130                         and then
 131                           (Ekind (Current_Scope) = E_Function
 132                              or else Ekind (Enclosing_Dynamic_Scope (
 133                                        Current_Scope)) = E_Function))
 134                    or else
 135                      (Ekind (Ent) = E_Component
 136                         and then Is_Protected_Type (Scope (Ent)))
 137                then
 138                   Error_Msg_N
 139                     ("protected function cannot modify protected object", N);
 140
 141                elsif Ekind (Ent) = E_Loop_Parameter then
 142                   Error_Msg_N
 143                     ("assignment to loop parameter not allowed", N);
 144
 145                else
 146                   Error_Msg_N
 147                     ("left hand side of assignment must be a variable", N);
 148                end if;
 149             end;
 150
 151          --  For indexed components or selected components, test prefix
 152
 153          elsif Nkind (N) = N_Indexed_Component then
 154             Diagnose_Non_Variable_Lhs (Prefix (N));
 155
 156          --  Another special case for assignment to discriminant
 157
 158          elsif Nkind (N) = N_Selected_Component then
 159             if Present (Entity (Selector_Name (N)))
 160               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 161             then
 162                Error_Msg_N
 163                  ("assignment to discriminant not allowed", N);
 164             else
 165                Diagnose_Non_Variable_Lhs (Prefix (N));
 166             end if;
 167
 168          else
 169             --  If we fall through, we have no special message to issue!
 170
 171             Error_Msg_N ("left hand side of assignment must be a variable", N);
 172          end if;
 173       end Diagnose_Non_Variable_Lhs;
 174
 175       --------------
 176       -- Kill_LHS --
 177       --------------
 178
 179       procedure Kill_Lhs is
 180       begin
 181          if Is_Entity_Name (Lhs) then
 182             declare
 183                Ent : constant Entity_Id := Entity (Lhs);
 184             begin
 185                if Present (Ent) then
 186                   Kill_Current_Values (Ent);
 187                end if;
 188             end;
 189          end if;
 190       end Kill_Lhs;
 191
 192       -------------------------
 193       -- Set_Assignment_Type --
 194       -------------------------
 195
 196       procedure Set_Assignment_Type
 197         (Opnd      : Node_Id;
 198          Opnd_Type : in out Entity_Id)
 199       is
 200       begin
 201          Require_Entity (Opnd);
 202
 203          --  If the assignment operand is an in-out or out parameter, then we
 204          --  get the actual subtype (needed for the unconstrained case).
 205          --  If the operand is the actual in an entry declaration, then within
 206          --  the accept statement it is replaced with a local renaming, which
 207          --  may also have an actual subtype.
 208
 209          if Is_Entity_Name (Opnd)
 210            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 211                       or else Ekind (Entity (Opnd)) =
 212                            E_In_Out_Parameter
 213                       or else Ekind (Entity (Opnd)) =
 214                            E_Generic_In_Out_Parameter
 215                       or else
 216                         (Ekind (Entity (Opnd)) = E_Variable
 217                           and then Nkind (Parent (Entity (Opnd))) =
 218                              N_Object_Renaming_Declaration
 219                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 220                              N_Accept_Statement))
 221          then
 222             Opnd_Type := Get_Actual_Subtype (Opnd);
 223
 224          --  If assignment operand is a component reference, then we get the
 225          --  actual subtype of the component for the unconstrained case.
 226
 227          elsif Nkind_In (Opnd, N_Selected_Component, N_Explicit_Dereference)
 228            and then not Is_Unchecked_Union (Opnd_Type)
 229          then
 230             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 231
 232             if Present (Decl) then
 233                Insert_Action (N, Decl);
 234                Mark_Rewrite_Insertion (Decl);
 235                Analyze (Decl);
 236                Opnd_Type := Defining_Identifier (Decl);
 237                Set_Etype (Opnd, Opnd_Type);
 238                Freeze_Itype (Opnd_Type, N);
 239
 240             elsif Is_Constrained (Etype (Opnd)) then
 241                Opnd_Type := Etype (Opnd);
 242             end if;
 243
 244          --  For slice, use the constrained subtype created for the slice
 245
 246          elsif Nkind (Opnd) = N_Slice then
 247             Opnd_Type := Etype (Opnd);
 248          end if;
 249       end Set_Assignment_Type;
 250
 251    --  Start of processing for Analyze_Assignment
 252
 253    begin
 254       Mark_Coextensions (N, Rhs);
 255
 256       Analyze (Rhs);
 257       Analyze (Lhs);
 258
 259       --  Start type analysis for assignment
 260
 261       T1 := Etype (Lhs);
 262
 263       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 264       --  must compute the intersection of the possible types on each side.
 265
 266       if Is_Overloaded (Lhs) then
 267          declare
 268             I  : Interp_Index;
 269             It : Interp;
 270
 271          begin
 272             T1 := Any_Type;
 273             Get_First_Interp (Lhs, I, It);
 274
 275             while Present (It.Typ) loop
 276                if Has_Compatible_Type (Rhs, It.Typ) then
 277                   if T1 /= Any_Type then
 278
 279                      --  An explicit dereference is overloaded if the prefix
 280                      --  is. Try to remove the ambiguity on the prefix, the
 281                      --  error will be posted there if the ambiguity is real.
 282
 283                      if Nkind (Lhs) = N_Explicit_Dereference then
 284                         declare
 285                            PI    : Interp_Index;
 286                            PI1   : Interp_Index := 0;
 287                            PIt   : Interp;
 288                            Found : Boolean;
 289
 290                         begin
 291                            Found := False;
 292                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 293
 294                            while Present (PIt.Typ) loop
 295                               if Is_Access_Type (PIt.Typ)
 296                                 and then Has_Compatible_Type
 297                                            (Rhs, Designated_Type (PIt.Typ))
 298                               then
 299                                  if Found then
 300                                     PIt :=
 301                                       Disambiguate (Prefix (Lhs),
 302                                         PI1, PI, Any_Type);
 303
 304                                     if PIt = No_Interp then
 305                                        Error_Msg_N
 306                                          ("ambiguous left-hand side"
 307                                             & " in assignment", Lhs);
 308                                        exit;
 309                                     else
 310                                        Resolve (Prefix (Lhs), PIt.Typ);
 311                                     end if;
 312
 313                                     exit;
 314                                  else
 315                                     Found := True;
 316                                     PI1 := PI;
 317                                  end if;
 318                               end if;
 319
 320                               Get_Next_Interp (PI, PIt);
 321                            end loop;
 322                         end;
 323
 324                      else
 325                         Error_Msg_N
 326                           ("ambiguous left-hand side in assignment", Lhs);
 327                         exit;
 328                      end if;
 329                   else
 330                      T1 := It.Typ;
 331                   end if;
 332                end if;
 333
 334                Get_Next_Interp (I, It);
 335             end loop;
 336          end;
 337
 338          if T1 = Any_Type then
 339             Error_Msg_N
 340               ("no valid types for left-hand side for assignment", Lhs);
 341             Kill_Lhs;
 342             return;
 343          end if;
 344       end if;
 345
 346       --  The resulting assignment type is T1, so now we will resolve the
 347       --  left hand side of the assignment using this determined type.
 348
 349       Resolve (Lhs, T1);
 350
 351       --  Cases where Lhs is not a variable
 352
 353       if not Is_Variable (Lhs) then
 354
 355          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 356          --  a protected object.
 357
 358          declare
 359             Ent : Entity_Id;
 360             S   : Entity_Id;
 361
 362          begin
 363             if Ada_Version >= Ada_2005 then
 364
 365                --  Handle chains of renamings
 366
 367                Ent := Lhs;
 368                while Nkind (Ent) in N_Has_Entity
 369                  and then Present (Entity (Ent))
 370                  and then Present (Renamed_Object (Entity (Ent)))
 371                loop
 372                   Ent := Renamed_Object (Entity (Ent));
 373                end loop;
 374
 375                if (Nkind (Ent) = N_Attribute_Reference
 376                      and then Attribute_Name (Ent) = Name_Priority)
 377
 378                   --  Renamings of the attribute Priority applied to protected
 379                   --  objects have been previously expanded into calls to the
 380                   --  Get_Ceiling run-time subprogram.
 381
 382                  or else
 383                   (Nkind (Ent) = N_Function_Call
 384                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 385                                 or else
 386                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 387                then
 388                   --  The enclosing subprogram cannot be a protected function
 389
 390                   S := Current_Scope;
 391                   while not (Is_Subprogram (S)
 392                                and then Convention (S) = Convention_Protected)
 393                      and then S /= Standard_Standard
 394                   loop
 395                      S := Scope (S);
 396                   end loop;
 397
 398                   if Ekind (S) = E_Function
 399                     and then Convention (S) = Convention_Protected
 400                   then
 401                      Error_Msg_N
 402                        ("protected function cannot modify protected object",
 403                         Lhs);
 404                   end if;
 405
 406                   --  Changes of the ceiling priority of the protected object
 407                   --  are only effective if the Ceiling_Locking policy is in
 408                   --  effect (AARM D.5.2 (5/2)).
 409
 410                   if Locking_Policy /= 'C' then
 411                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 412                                   "no effect?", Lhs);
 413                      Error_Msg_N ("\since no Locking_Policy has been " &
 414                                   "specified", Lhs);
 415                   end if;
 416
 417                   return;
 418                end if;
 419             end if;
 420          end;
 421
 422          Diagnose_Non_Variable_Lhs (Lhs);
 423          return;
 424
 425       --  Error of assigning to limited type. We do however allow this in
 426       --  certain cases where the front end generates the assignments.
 427
 428       elsif Is_Limited_Type (T1)
 429         and then not Assignment_OK (Lhs)
 430         and then not Assignment_OK (Original_Node (Lhs))
 431         and then not Is_Value_Type (T1)
 432       then
 433          --  CPP constructors can only be called in declarations
 434
 435          if Is_CPP_Constructor_Call (Rhs) then
 436             Error_Msg_N ("invalid use of 'C'P'P constructor", Rhs);
 437          else
 438             Error_Msg_N
 439               ("left hand of assignment must not be limited type", Lhs);
 440             Explain_Limited_Type (T1, Lhs);
 441          end if;
 442          return;
 443
 444       --  Enforce RM 3.9.3 (8): the target of an assignment operation cannot be
 445       --  abstract. This is only checked when the assignment Comes_From_Source,
 446       --  because in some cases the expander generates such assignments (such
 447       --  in the _assign operation for an abstract type).
 448
 449       elsif Is_Abstract_Type (T1) and then Comes_From_Source (N) then
 450          Error_Msg_N
 451            ("target of assignment operation must not be abstract", Lhs);
 452       end if;
 453
 454       --  Resolution may have updated the subtype, in case the left-hand
 455       --  side is a private protected component. Use the correct subtype
 456       --  to avoid scoping issues in the back-end.
 457
 458       T1 := Etype (Lhs);
 459
 460       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 461       --  type. For example:
 462
 463       --    limited with P;
 464       --    package Pkg is
 465       --      type Acc is access P.T;
 466       --    end Pkg;
 467
 468       --    with Pkg; use Acc;
 469       --    procedure Example is
 470       --       A, B : Acc;
 471       --    begin
 472       --       A.all := B.all;  -- ERROR
 473       --    end Example;
 474
 475       if Nkind (Lhs) = N_Explicit_Dereference
 476         and then Ekind (T1) = E_Incomplete_Type
 477       then
 478          Error_Msg_N ("invalid use of incomplete type", Lhs);
 479          Kill_Lhs;
 480          return;
 481       end if;
 482
 483       --  Now we can complete the resolution of the right hand side
 484
 485       Set_Assignment_Type (Lhs, T1);
 486       Resolve (Rhs, T1);
 487
 488       --  This is the point at which we check for an unset reference
 489
 490       Check_Unset_Reference (Rhs);
 491       Check_Unprotected_Access (Lhs, Rhs);
 492
 493       --  Remaining steps are skipped if Rhs was syntactically in error
 494
 495       if Rhs = Error then
 496          Kill_Lhs;
 497          return;
 498       end if;
 499
 500       T2 := Etype (Rhs);
 501
 502       if not Covers (T1, T2) then
 503          Wrong_Type (Rhs, Etype (Lhs));
 504          Kill_Lhs;
 505          return;
 506       end if;
 507
 508       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 509       --  types, use the non-limited view if available
 510
 511       if Nkind (Rhs) = N_Explicit_Dereference
 512         and then Ekind (T2) = E_Incomplete_Type
 513         and then Is_Tagged_Type (T2)
 514         and then Present (Non_Limited_View (T2))
 515       then
 516          T2 := Non_Limited_View (T2);
 517       end if;
 518
 519       Set_Assignment_Type (Rhs, T2);
 520
 521       if Total_Errors_Detected /= 0 then
 522          if No (T1) then
 523             T1 := Any_Type;
 524          end if;
 525
 526          if No (T2) then
 527             T2 := Any_Type;
 528          end if;
 529       end if;
 530
 531       if T1 = Any_Type or else T2 = Any_Type then
 532          Kill_Lhs;
 533          return;
 534       end if;
 535
 536       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 537       --  to be class-wide. The case where the rhs is a dynamically tagged call
 538       --  to a dispatching operation with a controlling access result is
 539       --  excluded from this check, since the target has an access type (and
 540       --  no tag propagation occurs in that case).
 541
 542       if (Is_Class_Wide_Type (T2)
 543            or else (Is_Dynamically_Tagged (Rhs)
 544                      and then not Is_Access_Type (T1)))
 545         and then not Is_Class_Wide_Type (T1)
 546       then
 547          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 548
 549       elsif Is_Class_Wide_Type (T1)
 550         and then not Is_Class_Wide_Type (T2)
 551         and then not Is_Tag_Indeterminate (Rhs)
 552         and then not Is_Dynamically_Tagged (Rhs)
 553       then
 554          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 555       end if;
 556
 557       --  Propagate the tag from a class-wide target to the rhs when the rhs
 558       --  is a tag-indeterminate call.
 559
 560       if Is_Tag_Indeterminate (Rhs) then
 561          if Is_Class_Wide_Type (T1) then
 562             Propagate_Tag (Lhs, Rhs);
 563
 564          elsif Nkind (Rhs) = N_Function_Call
 565               and then Is_Entity_Name (Name (Rhs))
 566               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 567          then
 568             Error_Msg_N
 569               ("call to abstract function must be dispatching", Name (Rhs));
 570
 571          elsif Nkind (Rhs) = N_Qualified_Expression
 572            and then Nkind (Expression (Rhs)) = N_Function_Call
 573               and then Is_Entity_Name (Name (Expression (Rhs)))
 574               and then
 575                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 576          then
 577             Error_Msg_N
 578               ("call to abstract function must be dispatching",
 579                 Name (Expression (Rhs)));
 580          end if;
 581       end if;
 582
 583       --  Ada 2005 (AI-385): When the lhs type is an anonymous access type,
 584       --  apply an implicit conversion of the rhs to that type to force
 585       --  appropriate static and run-time accessibility checks. This applies
 586       --  as well to anonymous access-to-subprogram types that are component
 587       --  subtypes or formal parameters.
 588
 589       if Ada_Version >= Ada_2005
 590         and then Is_Access_Type (T1)
 591       then
 592          if Is_Local_Anonymous_Access (T1)
 593            or else Ekind (T2) = E_Anonymous_Access_Subprogram_Type
 594          then
 595             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 596             Analyze_And_Resolve (Rhs, T1);
 597          end if;
 598       end if;
 599
 600       --  Ada 2005 (AI-231): Assignment to not null variable
 601
 602       if Ada_Version >= Ada_2005
 603         and then Can_Never_Be_Null (T1)
 604         and then not Assignment_OK (Lhs)
 605       then
 606          --  Case where we know the right hand side is null
 607
 608          if Known_Null (Rhs) then
 609             Apply_Compile_Time_Constraint_Error
 610               (N   => Rhs,
 611                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 612                Reason => CE_Null_Not_Allowed);
 613
 614             --  We still mark this as a possible modification, that's necessary
 615             --  to reset Is_True_Constant, and desirable for xref purposes.
 616
 617             Note_Possible_Modification (Lhs, Sure => True);
 618             return;
 619
 620          --  If we know the right hand side is non-null, then we convert to the
 621          --  target type, since we don't need a run time check in that case.
 622
 623          elsif not Can_Never_Be_Null (T2) then
 624             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 625             Analyze_And_Resolve (Rhs, T1);
 626          end if;
 627       end if;
 628
 629       if Is_Scalar_Type (T1) then
 630          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 631
 632       --  For array types, verify that lengths match. If the right hand side
 633       --  if a function call that has been inlined, the assignment has been
 634       --  rewritten as a block, and the constraint check will be applied to the
 635       --  assignment within the block.
 636
 637       elsif Is_Array_Type (T1)
 638         and then
 639           (Nkind (Rhs) /= N_Type_Conversion
 640             or else Is_Constrained (Etype (Rhs)))
 641         and then
 642           (Nkind (Rhs) /= N_Function_Call
 643             or else Nkind (N) /= N_Block_Statement)
 644       then
 645          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 646          --  but of course the indexes do not have to match. If the right-hand
 647          --  side is a type conversion to an unconstrained type, a length check
 648          --  is performed on the expression itself during expansion. In rare
 649          --  cases, the redundant length check is computed on an index type
 650          --  with a different representation, triggering incorrect code in
 651          --  the back end.
 652
 653          Apply_Length_Check (Rhs, Etype (Lhs));
 654
 655       else
 656          --  Discriminant checks are applied in the course of expansion
 657
 658          null;
 659       end if;
 660
 661       --  Note: modifications of the Lhs may only be recorded after
 662       --  checks have been applied.
 663
 664       Note_Possible_Modification (Lhs, Sure => True);
 665
 666       --  ??? a real accessibility check is needed when ???
 667
 668       --  Post warning for redundant assignment or variable to itself
 669
 670       if Warn_On_Redundant_Constructs
 671
 672          --  We only warn for source constructs
 673
 674          and then Comes_From_Source (N)
 675
 676          --  Where the object is the same on both sides
 677
 678          and then Same_Object (Lhs, Original_Node (Rhs))
 679
 680          --  But exclude the case where the right side was an operation
 681          --  that got rewritten (e.g. JUNK + K, where K was known to be
 682          --  zero). We don't want to warn in such a case, since it is
 683          --  reasonable to write such expressions especially when K is
 684          --  defined symbolically in some other package.
 685
 686         and then Nkind (Original_Node (Rhs)) not in N_Op
 687       then
 688          if Nkind (Lhs) in N_Has_Entity then
 689             Error_Msg_NE -- CODEFIX
 690               ("?useless assignment of & to itself!", N, Entity (Lhs));
 691          else
 692             Error_Msg_N -- CODEFIX
 693               ("?useless assignment of object to itself!", N);
 694          end if;
 695       end if;
 696
 697       --  Check for non-allowed composite assignment
 698
 699       if not Support_Composite_Assign_On_Target
 700         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 701         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 702       then
 703          Error_Msg_CRT ("composite assignment", N);
 704       end if;
 705
 706       --  Check elaboration warning for left side if not in elab code
 707
 708       if not In_Subprogram_Or_Concurrent_Unit then
 709          Check_Elab_Assign (Lhs);
 710       end if;
 711
 712       --  Set Referenced_As_LHS if appropriate. We only set this flag if the
 713       --  assignment is a source assignment in the extended main source unit.
 714       --  We are not interested in any reference information outside this
 715       --  context, or in compiler generated assignment statements.
 716
 717       if Comes_From_Source (N)
 718         and then In_Extended_Main_Source_Unit (Lhs)
 719       then
 720          Set_Referenced_Modified (Lhs, Out_Param => False);
 721       end if;
 722
 723       --  Final step. If left side is an entity, then we may be able to
 724       --  reset the current tracked values to new safe values. We only have
 725       --  something to do if the left side is an entity name, and expansion
 726       --  has not modified the node into something other than an assignment,
 727       --  and of course we only capture values if it is safe to do so.
 728
 729       if Is_Entity_Name (Lhs)
 730         and then Nkind (N) = N_Assignment_Statement
 731       then
 732          declare
 733             Ent : constant Entity_Id := Entity (Lhs);
 734
 735          begin
 736             if Safe_To_Capture_Value (N, Ent) then
 737
 738                --  If simple variable on left side, warn if this assignment
 739                --  blots out another one (rendering it useless) and note
 740                --  location of assignment in case no one references value.
 741                --  We only do this for source assignments, otherwise we can
 742                --  generate bogus warnings when an assignment is rewritten as
 743                --  another assignment, and gets tied up with itself.
 744
 745                --  Note: we don't use Record_Last_Assignment here, because we
 746                --  have lots of other stuff to do under control of this test.
 747
 748                if Warn_On_Modified_Unread
 749                  and then Is_Assignable (Ent)
 750                  and then Comes_From_Source (N)
 751                  and then In_Extended_Main_Source_Unit (Ent)
 752                then
 753                   Warn_On_Useless_Assignment (Ent, N);
 754                   Set_Last_Assignment (Ent, Lhs);
 755                end if;
 756
 757                --  If we are assigning an access type and the left side is an
 758                --  entity, then make sure that the Is_Known_[Non_]Null flags
 759                --  properly reflect the state of the entity after assignment.
 760
 761                if Is_Access_Type (T1) then
 762                   if Known_Non_Null (Rhs) then
 763                      Set_Is_Known_Non_Null (Ent, True);
 764
 765                   elsif Known_Null (Rhs)
 766                     and then not Can_Never_Be_Null (Ent)
 767                   then
 768                      Set_Is_Known_Null (Ent, True);
 769
 770                   else
 771                      Set_Is_Known_Null (Ent, False);
 772
 773                      if not Can_Never_Be_Null (Ent) then
 774                         Set_Is_Known_Non_Null (Ent, False);
 775                      end if;
 776                   end if;
 777
 778                --  For discrete types, we may be able to set the current value
 779                --  if the value is known at compile time.
 780
 781                elsif Is_Discrete_Type (T1)
 782                  and then Compile_Time_Known_Value (Rhs)
 783                then
 784                   Set_Current_Value (Ent, Rhs);
 785                else
 786                   Set_Current_Value (Ent, Empty);
 787                end if;
 788
 789             --  If not safe to capture values, kill them
 790
 791             else
 792                Kill_Lhs;
 793             end if;
 794          end;
 795       end if;
 796    end Analyze_Assignment;
 797
 798    -----------------------------
 799    -- Analyze_Block_Statement --
 800    -----------------------------
 801
 802    procedure Analyze_Block_Statement (N : Node_Id) is
 803       Decls : constant List_Id := Declarations (N);
 804       Id    : constant Node_Id := Identifier (N);
 805       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 806
 807    begin
 808       --  If no handled statement sequence is present, things are really
 809       --  messed up, and we just return immediately (this is a defence
 810       --  against previous errors).
 811
 812       if No (HSS) then
 813          return;
 814       end if;
 815
 816       --  Normal processing with HSS present
 817
 818       declare
 819          EH  : constant List_Id := Exception_Handlers (HSS);
 820          Ent : Entity_Id        := Empty;
 821          S   : Entity_Id;
 822
 823          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 824          --  Recursively save value of this global, will be restored on exit
 825
 826       begin
 827          --  Initialize unblocked exit count for statements of begin block
 828          --  plus one for each exception handler that is present.
 829
 830          Unblocked_Exit_Count := 1;
 831
 832          if Present (EH) then
 833             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 834          end if;
 835
 836          --  If a label is present analyze it and mark it as referenced
 837
 838          if Present (Id) then
 839             Analyze (Id);
 840             Ent := Entity (Id);
 841
 842             --  An error defense. If we have an identifier, but no entity,
 843             --  then something is wrong. If we have previous errors, then
 844             --  just remove the identifier and continue, otherwise raise
 845             --  an exception.
 846
 847             if No (Ent) then
 848                if Total_Errors_Detected /= 0 then
 849                   Set_Identifier (N, Empty);
 850                else
 851                   raise Program_Error;
 852                end if;
 853
 854             else
 855                Set_Ekind (Ent, E_Block);
 856                Generate_Reference (Ent, N, ' ');
 857                Generate_Definition (Ent);
 858
 859                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 860                   Set_Label_Construct (Parent (Ent), N);
 861                end if;
 862             end if;
 863          end if;
 864
 865          --  If no entity set, create a label entity
 866
 867          if No (Ent) then
 868             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 869             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 870             Set_Parent (Ent, N);
 871          end if;
 872
 873          Set_Etype (Ent, Standard_Void_Type);
 874          Set_Block_Node (Ent, Identifier (N));
 875          Push_Scope (Ent);
 876
 877          if Present (Decls) then
 878             Analyze_Declarations (Decls);
 879             Check_Completion;
 880             Inspect_Deferred_Constant_Completion (Decls);
 881          end if;
 882
 883          Analyze (HSS);
 884          Process_End_Label (HSS, 'e', Ent);
 885
 886          --  If exception handlers are present, then we indicate that
 887          --  enclosing scopes contain a block with handlers. We only
 888          --  need to mark non-generic scopes.
 889
 890          if Present (EH) then
 891             S := Scope (Ent);
 892             loop
 893                Set_Has_Nested_Block_With_Handler (S);
 894                exit when Is_Overloadable (S)
 895                  or else Ekind (S) = E_Package
 896                  or else Is_Generic_Unit (S);
 897                S := Scope (S);
 898             end loop;
 899          end if;
 900
 901          Check_References (Ent);
 902          Warn_On_Useless_Assignments (Ent);
 903          End_Scope;
 904
 905          if Unblocked_Exit_Count = 0 then
 906             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 907             Check_Unreachable_Code (N);
 908          else
 909             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 910          end if;
 911       end;
 912    end Analyze_Block_Statement;
 913
 914    ----------------------------
 915    -- Analyze_Case_Statement --
 916    ----------------------------
 917
 918    procedure Analyze_Case_Statement (N : Node_Id) is
 919       Exp            : Node_Id;
 920       Exp_Type       : Entity_Id;
 921       Exp_Btype      : Entity_Id;
 922       Last_Choice    : Nat;
 923       Dont_Care      : Boolean;
 924       Others_Present : Boolean;
 925
 926       pragma Warnings (Off, Last_Choice);
 927       pragma Warnings (Off, Dont_Care);
 928       --  Don't care about assigned values
 929
 930       Statements_Analyzed : Boolean := False;
 931       --  Set True if at least some statement sequences get analyzed.
 932       --  If False on exit, means we had a serious error that prevented
 933       --  full analysis of the case statement, and as a result it is not
 934       --  a good idea to output warning messages about unreachable code.
 935
 936       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 937       --  Recursively save value of this global, will be restored on exit
 938
 939       procedure Non_Static_Choice_Error (Choice : Node_Id);
 940       --  Error routine invoked by the generic instantiation below when
 941       --  the case statement has a non static choice.
 942
 943       procedure Process_Statements (Alternative : Node_Id);
 944       --  Analyzes all the statements associated with a case alternative.
 945       --  Needed by the generic instantiation below.
 946
 947       package Case_Choices_Processing is new
 948         Generic_Choices_Processing
 949           (Get_Alternatives          => Alternatives,
 950            Get_Choices               => Discrete_Choices,
 951            Process_Empty_Choice      => No_OP,
 952            Process_Non_Static_Choice => Non_Static_Choice_Error,
 953            Process_Associated_Node   => Process_Statements);
 954       use Case_Choices_Processing;
 955       --  Instantiation of the generic choice processing package
 956
 957       -----------------------------
 958       -- Non_Static_Choice_Error --
 959       -----------------------------
 960
 961       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 962       begin
 963          Flag_Non_Static_Expr
 964            ("choice given in case statement is not static!", Choice);
 965       end Non_Static_Choice_Error;
 966
 967       ------------------------
 968       -- Process_Statements --
 969       ------------------------
 970
 971       procedure Process_Statements (Alternative : Node_Id) is
 972          Choices : constant List_Id := Discrete_Choices (Alternative);
 973          Ent     : Entity_Id;
 974
 975       begin
 976          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 977          Statements_Analyzed := True;
 978
 979          --  An interesting optimization. If the case statement expression
 980          --  is a simple entity, then we can set the current value within
 981          --  an alternative if the alternative has one possible value.
 982
 983          --    case N is
 984          --      when 1      => alpha
 985          --      when 2 | 3  => beta
 986          --      when others => gamma
 987
 988          --  Here we know that N is initially 1 within alpha, but for beta
 989          --  and gamma, we do not know anything more about the initial value.
 990
 991          if Is_Entity_Name (Exp) then
 992             Ent := Entity (Exp);
 993
 994             if Ekind_In (Ent, E_Variable,
 995                               E_In_Out_Parameter,
 996                               E_Out_Parameter)
 997             then
 998                if List_Length (Choices) = 1
 999                  and then Nkind (First (Choices)) in N_Subexpr
1000                  and then Compile_Time_Known_Value (First (Choices))
1001                then
1002                   Set_Current_Value (Entity (Exp), First (Choices));
1003                end if;
1004
1005                Analyze_Statements (Statements (Alternative));
1006
1007                --  After analyzing the case, set the current value to empty
1008                --  since we won't know what it is for the next alternative
1009                --  (unless reset by this same circuit), or after the case.
1010
1011                Set_Current_Value (Entity (Exp), Empty);
1012                return;
1013             end if;
1014          end if;
1015
1016          --  Case where expression is not an entity name of a variable
1017
1018          Analyze_Statements (Statements (Alternative));
1019       end Process_Statements;
1020
1021       --  Table to record choices. Put after subprograms since we make
1022       --  a call to Number_Of_Choices to get the right number of entries.
1023
1024       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
1025       pragma Warnings (Off, Case_Table);
1026
1027    --  Start of processing for Analyze_Case_Statement
1028
1029    begin
1030       Unblocked_Exit_Count := 0;
1031       Exp := Expression (N);
1032       Analyze (Exp);
1033
1034       --  The expression must be of any discrete type. In rare cases, the
1035       --  expander constructs a case statement whose expression has a private
1036       --  type whose full view is discrete. This can happen when generating
1037       --  a stream operation for a variant type after the type is frozen,
1038       --  when the partial of view of the type of the discriminant is private.
1039       --  In that case, use the full view to analyze case alternatives.
1040
1041       if not Is_Overloaded (Exp)
1042         and then not Comes_From_Source (N)
1043         and then Is_Private_Type (Etype (Exp))
1044         and then Present (Full_View (Etype (Exp)))
1045         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1046       then
1047          Resolve (Exp, Etype (Exp));
1048          Exp_Type := Full_View (Etype (Exp));
1049
1050       else
1051          Analyze_And_Resolve (Exp, Any_Discrete);
1052          Exp_Type := Etype (Exp);
1053       end if;
1054
1055       Check_Unset_Reference (Exp);
1056       Exp_Btype := Base_Type (Exp_Type);
1057
1058       --  The expression must be of a discrete type which must be determinable
1059       --  independently of the context in which the expression occurs, but
1060       --  using the fact that the expression must be of a discrete type.
1061       --  Moreover, the type this expression must not be a character literal
1062       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1063
1064       --  If error already reported by Resolve, nothing more to do
1065
1066       if Exp_Btype = Any_Discrete
1067         or else Exp_Btype = Any_Type
1068       then
1069          return;
1070
1071       elsif Exp_Btype = Any_Character then
1072          Error_Msg_N
1073            ("character literal as case expression is ambiguous", Exp);
1074          return;
1075
1076       elsif Ada_Version = Ada_83
1077         and then (Is_Generic_Type (Exp_Btype)
1078                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1079       then
1080          Error_Msg_N
1081            ("(Ada 83) case expression cannot be of a generic type", Exp);
1082          return;
1083       end if;
1084
1085       --  If the case expression is a formal object of mode in out, then
1086       --  treat it as having a nonstatic subtype by forcing use of the base
1087       --  type (which has to get passed to Check_Case_Choices below).  Also
1088       --  use base type when the case expression is parenthesized.
1089
1090       if Paren_Count (Exp) > 0
1091         or else (Is_Entity_Name (Exp)
1092                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1093       then
1094          Exp_Type := Exp_Btype;
1095       end if;
1096
1097       --  Call instantiated Analyze_Choices which does the rest of the work
1098
1099       Analyze_Choices
1100         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
1101
1102       if Exp_Type = Universal_Integer and then not Others_Present then
1103          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1104       end if;
1105
1106       --  If all our exits were blocked by unconditional transfers of control,
1107       --  then the entire CASE statement acts as an unconditional transfer of
1108       --  control, so treat it like one, and check unreachable code. Skip this
1109       --  test if we had serious errors preventing any statement analysis.
1110
1111       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1112          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1113          Check_Unreachable_Code (N);
1114       else
1115          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1116       end if;
1117
1118       if not Expander_Active
1119         and then Compile_Time_Known_Value (Expression (N))
1120         and then Serious_Errors_Detected = 0
1121       then
1122          declare
1123             Chosen : constant Node_Id := Find_Static_Alternative (N);
1124             Alt    : Node_Id;
1125
1126          begin
1127             Alt := First (Alternatives (N));
1128             while Present (Alt) loop
1129                if Alt /= Chosen then
1130                   Remove_Warning_Messages (Statements (Alt));
1131                end if;
1132
1133                Next (Alt);
1134             end loop;
1135          end;
1136       end if;
1137    end Analyze_Case_Statement;
1138
1139    ----------------------------
1140    -- Analyze_Exit_Statement --
1141    ----------------------------
1142
1143    --  If the exit includes a name, it must be the name of a currently open
1144    --  loop. Otherwise there must be an innermost open loop on the stack,
1145    --  to which the statement implicitly refers.
1146
1147    procedure Analyze_Exit_Statement (N : Node_Id) is
1148       Target   : constant Node_Id := Name (N);
1149       Cond     : constant Node_Id := Condition (N);
1150       Scope_Id : Entity_Id;
1151       U_Name   : Entity_Id;
1152       Kind     : Entity_Kind;
1153
1154    begin
1155       if No (Cond) then
1156          Check_Unreachable_Code (N);
1157       end if;
1158
1159       if Present (Target) then
1160          Analyze (Target);
1161          U_Name := Entity (Target);
1162
1163          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1164             Error_Msg_N ("invalid loop name in exit statement", N);
1165             return;
1166          else
1167             Set_Has_Exit (U_Name);
1168          end if;
1169
1170       else
1171          U_Name := Empty;
1172       end if;
1173
1174       for J in reverse 0 .. Scope_Stack.Last loop
1175          Scope_Id := Scope_Stack.Table (J).Entity;
1176          Kind := Ekind (Scope_Id);
1177
1178          if Kind = E_Loop
1179            and then (No (Target) or else Scope_Id = U_Name) then
1180             Set_Has_Exit (Scope_Id);
1181             exit;
1182
1183          elsif Kind = E_Block
1184            or else Kind = E_Loop
1185            or else Kind = E_Return_Statement
1186          then
1187             null;
1188
1189          else
1190             Error_Msg_N
1191               ("cannot exit from program unit or accept statement", N);
1192             return;
1193          end if;
1194       end loop;
1195
1196       --  Verify that if present the condition is a Boolean expression
1197
1198       if Present (Cond) then
1199          Analyze_And_Resolve (Cond, Any_Boolean);
1200          Check_Unset_Reference (Cond);
1201       end if;
1202
1203       --  Chain exit statement to associated loop entity
1204
1205       Set_Next_Exit_Statement  (N, First_Exit_Statement (Scope_Id));
1206       Set_First_Exit_Statement (Scope_Id, N);
1207
1208       --  Since the exit may take us out of a loop, any previous assignment
1209       --  statement is not useless, so clear last assignment indications. It
1210       --  is OK to keep other current values, since if the exit statement
1211       --  does not exit, then the current values are still valid.
1212
1213       Kill_Current_Values (Last_Assignment_Only => True);
1214    end Analyze_Exit_Statement;
1215
1216    ----------------------------
1217    -- Analyze_Goto_Statement --
1218    ----------------------------
1219
1220    procedure Analyze_Goto_Statement (N : Node_Id) is
1221       Label       : constant Node_Id := Name (N);
1222       Scope_Id    : Entity_Id;
1223       Label_Scope : Entity_Id;
1224       Label_Ent   : Entity_Id;
1225
1226    begin
1227       Check_Unreachable_Code (N);
1228       Kill_Current_Values (Last_Assignment_Only => True);
1229
1230       Analyze (Label);
1231       Label_Ent := Entity (Label);
1232
1233       --  Ignore previous error
1234
1235       if Label_Ent = Any_Id then
1236          return;
1237
1238       --  We just have a label as the target of a goto
1239
1240       elsif Ekind (Label_Ent) /= E_Label then
1241          Error_Msg_N ("target of goto statement must be a label", Label);
1242          return;
1243
1244       --  Check that the target of the goto is reachable according to Ada
1245       --  scoping rules. Note: the special gotos we generate for optimizing
1246       --  local handling of exceptions would violate these rules, but we mark
1247       --  such gotos as analyzed when built, so this code is never entered.
1248
1249       elsif not Reachable (Label_Ent) then
1250          Error_Msg_N ("target of goto statement is not reachable", Label);
1251          return;
1252       end if;
1253
1254       --  Here if goto passes initial validity checks
1255
1256       Label_Scope := Enclosing_Scope (Label_Ent);
1257
1258       for J in reverse 0 .. Scope_Stack.Last loop
1259          Scope_Id := Scope_Stack.Table (J).Entity;
1260
1261          if Label_Scope = Scope_Id
1262            or else (Ekind (Scope_Id) /= E_Block
1263                      and then Ekind (Scope_Id) /= E_Loop
1264                      and then Ekind (Scope_Id) /= E_Return_Statement)
1265          then
1266             if Scope_Id /= Label_Scope then
1267                Error_Msg_N
1268                  ("cannot exit from program unit or accept statement", N);
1269             end if;
1270
1271             return;
1272          end if;
1273       end loop;
1274
1275       raise Program_Error;
1276    end Analyze_Goto_Statement;
1277
1278    --------------------------
1279    -- Analyze_If_Statement --
1280    --------------------------
1281
1282    --  A special complication arises in the analysis of if statements
1283
1284    --  The expander has circuitry to completely delete code that it
1285    --  can tell will not be executed (as a result of compile time known
1286    --  conditions). In the analyzer, we ensure that code that will be
1287    --  deleted in this manner is analyzed but not expanded. This is
1288    --  obviously more efficient, but more significantly, difficulties
1289    --  arise if code is expanded and then eliminated (e.g. exception
1290    --  table entries disappear). Similarly, itypes generated in deleted
1291    --  code must be frozen from start, because the nodes on which they
1292    --  depend will not be available at the freeze point.
1293
1294    procedure Analyze_If_Statement (N : Node_Id) is
1295       E : Node_Id;
1296
1297       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1298       --  Recursively save value of this global, will be restored on exit
1299
1300       Save_In_Deleted_Code : Boolean;
1301
1302       Del : Boolean := False;
1303       --  This flag gets set True if a True condition has been found,
1304       --  which means that remaining ELSE/ELSIF parts are deleted.
1305
1306       procedure Analyze_Cond_Then (Cnode : Node_Id);
1307       --  This is applied to either the N_If_Statement node itself or
1308       --  to an N_Elsif_Part node. It deals with analyzing the condition
1309       --  and the THEN statements associated with it.
1310
1311       -----------------------
1312       -- Analyze_Cond_Then --
1313       -----------------------
1314
1315       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1316          Cond : constant Node_Id := Condition (Cnode);
1317          Tstm : constant List_Id := Then_Statements (Cnode);
1318
1319       begin
1320          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1321          Analyze_And_Resolve (Cond, Any_Boolean);
1322          Check_Unset_Reference (Cond);
1323          Set_Current_Value_Condition (Cnode);
1324
1325          --  If already deleting, then just analyze then statements
1326
1327          if Del then
1328             Analyze_Statements (Tstm);
1329
1330          --  Compile time known value, not deleting yet
1331
1332          elsif Compile_Time_Known_Value (Cond) then
1333             Save_In_Deleted_Code := In_Deleted_Code;
1334
1335             --  If condition is True, then analyze the THEN statements
1336             --  and set no expansion for ELSE and ELSIF parts.
1337
1338             if Is_True (Expr_Value (Cond)) then
1339                Analyze_Statements (Tstm);
1340                Del := True;
1341                Expander_Mode_Save_And_Set (False);
1342                In_Deleted_Code := True;
1343
1344             --  If condition is False, analyze THEN with expansion off
1345
1346             else -- Is_False (Expr_Value (Cond))
1347                Expander_Mode_Save_And_Set (False);
1348                In_Deleted_Code := True;
1349                Analyze_Statements (Tstm);
1350                Expander_Mode_Restore;
1351                In_Deleted_Code := Save_In_Deleted_Code;
1352             end if;
1353
1354          --  Not known at compile time, not deleting, normal analysis
1355
1356          else
1357             Analyze_Statements (Tstm);
1358          end if;
1359       end Analyze_Cond_Then;
1360
1361    --  Start of Analyze_If_Statement
1362
1363    begin
1364       --  Initialize exit count for else statements. If there is no else
1365       --  part, this count will stay non-zero reflecting the fact that the
1366       --  uncovered else case is an unblocked exit.
1367
1368       Unblocked_Exit_Count := 1;
1369       Analyze_Cond_Then (N);
1370
1371       --  Now to analyze the elsif parts if any are present
1372
1373       if Present (Elsif_Parts (N)) then
1374          E := First (Elsif_Parts (N));
1375          while Present (E) loop
1376             Analyze_Cond_Then (E);
1377             Next (E);
1378          end loop;
1379       end if;
1380
1381       if Present (Else_Statements (N)) then
1382          Analyze_Statements (Else_Statements (N));
1383       end if;
1384
1385       --  If all our exits were blocked by unconditional transfers of control,
1386       --  then the entire IF statement acts as an unconditional transfer of
1387       --  control, so treat it like one, and check unreachable code.
1388
1389       if Unblocked_Exit_Count = 0 then
1390          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1391          Check_Unreachable_Code (N);
1392       else
1393          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1394       end if;
1395
1396       if Del then
1397          Expander_Mode_Restore;
1398          In_Deleted_Code := Save_In_Deleted_Code;
1399       end if;
1400
1401       if not Expander_Active
1402         and then Compile_Time_Known_Value (Condition (N))
1403         and then Serious_Errors_Detected = 0
1404       then
1405          if Is_True (Expr_Value (Condition (N))) then
1406             Remove_Warning_Messages (Else_Statements (N));
1407
1408             if Present (Elsif_Parts (N)) then
1409                E := First (Elsif_Parts (N));
1410                while Present (E) loop
1411                   Remove_Warning_Messages (Then_Statements (E));
1412                   Next (E);
1413                end loop;
1414             end if;
1415
1416          else
1417             Remove_Warning_Messages (Then_Statements (N));
1418          end if;
1419       end if;
1420    end Analyze_If_Statement;
1421
1422    ----------------------------------------
1423    -- Analyze_Implicit_Label_Declaration --
1424    ----------------------------------------
1425
1426    --  An implicit label declaration is generated in the innermost
1427    --  enclosing declarative part. This is done for labels as well as
1428    --  block and loop names.
1429
1430    --  Note: any changes in this routine may need to be reflected in
1431    --  Analyze_Label_Entity.
1432
1433    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1434       Id : constant Node_Id := Defining_Identifier (N);
1435    begin
1436       Enter_Name          (Id);
1437       Set_Ekind           (Id, E_Label);
1438       Set_Etype           (Id, Standard_Void_Type);
1439       Set_Enclosing_Scope (Id, Current_Scope);
1440    end Analyze_Implicit_Label_Declaration;
1441
1442    ------------------------------
1443    -- Analyze_Iteration_Scheme --
1444    ------------------------------
1445
1446    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1447
1448       procedure Process_Bounds (R : Node_Id);
1449       --  If the iteration is given by a range, create temporaries and
1450       --  assignment statements block to capture the bounds and perform
1451       --  required finalization actions in case a bound includes a function
1452       --  call that uses the temporary stack. We first pre-analyze a copy of
1453       --  the range in order to determine the expected type, and analyze and
1454       --  resolve the original bounds.
1455
1456       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1457       --  If the bounds are given by a 'Range reference on a function call
1458       --  that returns a controlled array, introduce an explicit declaration
1459       --  to capture the bounds, so that the function result can be finalized
1460       --  in timely fashion.
1461
1462       --------------------
1463       -- Process_Bounds --
1464       --------------------
1465
1466       procedure Process_Bounds (R : Node_Id) is
1467          Loc          : constant Source_Ptr := Sloc (N);
1468          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1469          Lo           : constant Node_Id := Low_Bound  (R);
1470          Hi           : constant Node_Id := High_Bound (R);
1471          New_Lo_Bound : Node_Id;
1472          New_Hi_Bound : Node_Id;
1473          Typ          : Entity_Id;
1474          Save_Analysis : Boolean;
1475
1476          function One_Bound
1477            (Original_Bound : Node_Id;
1478             Analyzed_Bound : Node_Id) return Node_Id;
1479          --  Capture value of bound and return captured value
1480
1481          ---------------
1482          -- One_Bound --
1483          ---------------
1484
1485          function One_Bound
1486            (Original_Bound : Node_Id;
1487             Analyzed_Bound : Node_Id) return Node_Id
1488          is
1489             Assign : Node_Id;
1490             Id     : Entity_Id;
1491             Decl   : Node_Id;
1492
1493          begin
1494             --  If the bound is a constant or an object, no need for a separate
1495             --  declaration. If the bound is the result of previous expansion
1496             --  it is already analyzed and should not be modified. Note that
1497             --  the Bound will be resolved later, if needed, as part of the
1498             --  call to Make_Index (literal bounds may need to be resolved to
1499             --  type Integer).
1500
1501             if Analyzed (Original_Bound) then
1502                return Original_Bound;
1503
1504             elsif Nkind_In (Analyzed_Bound, N_Integer_Literal,
1505                                             N_Character_Literal)
1506               or else Is_Entity_Name (Analyzed_Bound)
1507             then
1508                Analyze_And_Resolve (Original_Bound, Typ);
1509                return Original_Bound;
1510             end if;
1511
1512             --  Here we need to capture the value
1513
1514             Analyze_And_Resolve (Original_Bound, Typ);
1515
1516             Id := Make_Temporary (Loc, 'S', Original_Bound);
1517
1518             --  Normally, the best approach is simply to generate a constant
1519             --  declaration that captures the bound. However, there is a nasty
1520             --  case where this is wrong. If the bound is complex, and has a
1521             --  possible use of the secondary stack, we need to generate a
1522             --  separate assignment statement to ensure the creation of a block
1523             --  which will release the secondary stack.
1524
1525             --  We prefer the constant declaration, since it leaves us with a
1526             --  proper trace of the value, useful in optimizations that get rid
1527             --  of junk range checks.
1528
1529             --  Probably we want something like the Side_Effect_Free routine
1530             --  in Exp_Util, but for now, we just optimize the cases of 'Last
1531             --  and 'First applied to an entity, since these are the important
1532             --  cases for range check optimizations.
1533
1534             if Nkind (Original_Bound) = N_Attribute_Reference
1535               and then (Attribute_Name (Original_Bound) = Name_First
1536                           or else
1537                         Attribute_Name (Original_Bound) = Name_Last)
1538               and then Is_Entity_Name (Prefix (Original_Bound))
1539             then
1540                Decl :=
1541                  Make_Object_Declaration (Loc,
1542                    Defining_Identifier => Id,
1543                    Constant_Present    => True,
1544                    Object_Definition   => New_Occurrence_Of (Typ, Loc),
1545                    Expression          => Relocate_Node (Original_Bound));
1546
1547                Insert_Before (Parent (N), Decl);
1548                Analyze (Decl);
1549                Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1550                return Expression (Decl);
1551             end if;
1552
1553             --  Here we make a declaration with a separate assignment statement
1554
1555             Decl :=
1556               Make_Object_Declaration (Loc,
1557                 Defining_Identifier => Id,
1558                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1559
1560             Insert_Before (Parent (N), Decl);
1561             Analyze (Decl);
1562
1563             Assign :=
1564               Make_Assignment_Statement (Loc,
1565                 Name        => New_Occurrence_Of (Id, Loc),
1566                 Expression  => Relocate_Node (Original_Bound));
1567
1568             Insert_Before (Parent (N), Assign);
1569             Analyze (Assign);
1570
1571             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1572
1573             if Nkind (Assign) = N_Assignment_Statement then
1574                return Expression (Assign);
1575             else
1576                return Original_Bound;
1577             end if;
1578          end One_Bound;
1579
1580       --  Start of processing for Process_Bounds
1581
1582       begin
1583          --  Determine expected type of range by analyzing separate copy
1584          --  Do the analysis and resolution of the copy of the bounds with
1585          --  expansion disabled, to prevent the generation of finalization
1586          --  actions on each bound. This prevents memory leaks when the
1587          --  bounds contain calls to functions returning controlled arrays.
1588
1589          Set_Parent (R_Copy, Parent (R));
1590          Save_Analysis := Full_Analysis;
1591          Full_Analysis := False;
1592          Expander_Mode_Save_And_Set (False);
1593
1594          Analyze (R_Copy);
1595
1596          if Is_Overloaded (R_Copy) then
1597
1598             --  Apply preference rules for range of predefined integer types,
1599             --  or diagnose true ambiguity.
1600
1601             declare
1602                I     : Interp_Index;
1603                It    : Interp;
1604                Found : Entity_Id := Empty;
1605
1606             begin
1607                Get_First_Interp (R_Copy, I, It);
1608                while Present (It.Typ) loop
1609                   if Is_Discrete_Type (It.Typ) then
1610                      if No (Found) then
1611                         Found := It.Typ;
1612                      else
1613                         if Scope (Found) = Standard_Standard then
1614                            null;
1615
1616                         elsif Scope (It.Typ) = Standard_Standard then
1617                            Found := It.Typ;
1618
1619                         else
1620                            --  Both of them are user-defined
1621
1622                            Error_Msg_N
1623                              ("ambiguous bounds in range of iteration",
1624                                R_Copy);
1625                            Error_Msg_N ("\possible interpretations:", R_Copy);
1626                            Error_Msg_NE ("\\} ", R_Copy, Found);
1627                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1628                            exit;
1629                         end if;
1630                      end if;
1631                   end if;
1632
1633                   Get_Next_Interp (I, It);
1634                end loop;
1635             end;
1636          end if;
1637
1638          Resolve (R_Copy);
1639          Expander_Mode_Restore;
1640          Full_Analysis := Save_Analysis;
1641
1642          Typ := Etype (R_Copy);
1643
1644          --  If the type of the discrete range is Universal_Integer, then
1645          --  the bound's type must be resolved to Integer, and any object
1646          --  used to hold the bound must also have type Integer, unless the
1647          --  literal bounds are constant-folded expressions that carry a user-
1648          --  defined type.
1649
1650          if Typ = Universal_Integer then
1651             if Nkind (Lo) = N_Integer_Literal
1652               and then Present (Etype (Lo))
1653               and then Scope (Etype (Lo)) /= Standard_Standard
1654             then
1655                Typ := Etype (Lo);
1656
1657             elsif Nkind (Hi) = N_Integer_Literal
1658               and then Present (Etype (Hi))
1659               and then Scope (Etype (Hi)) /= Standard_Standard
1660             then
1661                Typ := Etype (Hi);
1662
1663             else
1664                Typ := Standard_Integer;
1665             end if;
1666          end if;
1667
1668          Set_Etype (R, Typ);
1669
1670          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1671          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1672
1673          --  Propagate staticness to loop range itself, in case the
1674          --  corresponding subtype is static.
1675
1676          if New_Lo_Bound /= Lo
1677            and then Is_Static_Expression (New_Lo_Bound)
1678          then
1679             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1680          end if;
1681
1682          if New_Hi_Bound /= Hi
1683            and then Is_Static_Expression (New_Hi_Bound)
1684          then
1685             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1686          end if;
1687       end Process_Bounds;
1688
1689       --------------------------------------
1690       -- Check_Controlled_Array_Attribute --
1691       --------------------------------------
1692
1693       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1694       begin
1695          if Nkind (DS) = N_Attribute_Reference
1696             and then Is_Entity_Name (Prefix (DS))
1697             and then Ekind (Entity (Prefix (DS))) = E_Function
1698             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1699             and then
1700               Is_Controlled (
1701                 Component_Type (Etype (Entity (Prefix (DS)))))
1702             and then Expander_Active
1703          then
1704             declare
1705                Loc  : constant Source_Ptr := Sloc (N);
1706                Arr  : constant Entity_Id := Etype (Entity (Prefix (DS)));
1707                Indx : constant Entity_Id :=
1708                         Base_Type (Etype (First_Index (Arr)));
1709                Subt : constant Entity_Id := Make_Temporary (Loc, 'S');
1710                Decl : Node_Id;
1711
1712             begin
1713                Decl :=
1714                  Make_Subtype_Declaration (Loc,
1715                    Defining_Identifier => Subt,
1716                    Subtype_Indication  =>
1717                       Make_Subtype_Indication (Loc,
1718                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1719                         Constraint =>
1720                           Make_Range_Constraint (Loc,
1721                             Relocate_Node (DS))));
1722                Insert_Before (Parent (N), Decl);
1723                Analyze (Decl);
1724
1725                Rewrite (DS,
1726                   Make_Attribute_Reference (Loc,
1727                     Prefix => New_Reference_To (Subt, Loc),
1728                     Attribute_Name => Attribute_Name (DS)));
1729                Analyze (DS);
1730             end;
1731          end if;
1732       end Check_Controlled_Array_Attribute;
1733
1734    --  Start of processing for Analyze_Iteration_Scheme
1735
1736    begin
1737       if Analyzed (N) then
1738          return;
1739       end if;
1740
1741       --  For an infinite loop, there is no iteration scheme
1742
1743       if No (N) then
1744          return;
1745
1746       else
1747          declare
1748             Cond : constant Node_Id := Condition (N);
1749
1750          begin
1751             --  For WHILE loop, verify that the condition is a Boolean
1752             --  expression and resolve and check it.
1753
1754             if Present (Cond) then
1755                Analyze_And_Resolve (Cond, Any_Boolean);
1756                Check_Unset_Reference (Cond);
1757                Set_Current_Value_Condition (N);
1758                return;
1759
1760             elsif Present (Iterator_Specification (N)) then
1761                Analyze_Iterator_Specification (Iterator_Specification (N));
1762
1763             --  Else we have a FOR loop
1764
1765             else
1766                declare
1767                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1768                   Id : constant Entity_Id := Defining_Identifier (LP);
1769                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1770
1771                begin
1772                   Enter_Name (Id);
1773
1774                   --  We always consider the loop variable to be referenced,
1775                   --  since the loop may be used just for counting purposes.
1776
1777                   Generate_Reference (Id, N, ' ');
1778
1779                   --  Check for case of loop variable hiding a local
1780                   --  variable (used later on to give a nice warning
1781                   --  if the hidden variable is never assigned).
1782
1783                   declare
1784                      H : constant Entity_Id := Homonym (Id);
1785                   begin
1786                      if Present (H)
1787                        and then Enclosing_Dynamic_Scope (H) =
1788                                 Enclosing_Dynamic_Scope (Id)
1789                        and then Ekind (H) = E_Variable
1790                        and then Is_Discrete_Type (Etype (H))
1791                      then
1792                         Set_Hiding_Loop_Variable (H, Id);
1793                      end if;
1794                   end;
1795
1796                   --  Now analyze the subtype definition. If it is
1797                   --  a range, create temporaries for bounds.
1798
1799                   if Nkind (DS) = N_Range
1800                     and then Expander_Active
1801                   then
1802                      Process_Bounds (DS);
1803                   else
1804                      Analyze (DS);
1805
1806                      if Nkind (DS) = N_Function_Call
1807                        or else
1808                          (Is_Entity_Name (DS)
1809                             and then not Is_Type (Entity (DS)))
1810                      then
1811
1812                         --  This is an iterator specification. Rewrite as such
1813                         --  and analyze.
1814
1815                         declare
1816                            I_Spec : constant Node_Id :=
1817                                       Make_Iterator_Specification (Sloc (LP),
1818                                         Defining_Identifier =>
1819                                           Relocate_Node (Id),
1820                                         Name                =>
1821                                           Relocate_Node (DS),
1822                                         Subtype_Indication  =>
1823                                           Empty,
1824                                         Reverse_Present     =>
1825                                           Reverse_Present (LP));
1826
1827                         begin
1828                            Set_Iterator_Specification (N, I_Spec);
1829                            Set_Loop_Parameter_Specification (N, Empty);
1830                            Analyze_Iterator_Specification (I_Spec);
1831                            return;
1832                         end;
1833                      end if;
1834                   end if;
1835
1836                   if DS = Error then
1837                      return;
1838                   end if;
1839
1840                   --  The subtype indication may denote the completion of an
1841                   --  incomplete type declaration.
1842
1843                   if Is_Entity_Name (DS)
1844                     and then Present (Entity (DS))
1845                     and then Is_Type (Entity (DS))
1846                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1847                   then
1848                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1849                      Set_Etype  (DS, Entity (DS));
1850                   end if;
1851
1852                   if not Is_Discrete_Type (Etype (DS)) then
1853                      Wrong_Type (DS, Any_Discrete);
1854                      Set_Etype (DS, Any_Type);
1855                   end if;
1856
1857                   Check_Controlled_Array_Attribute (DS);
1858
1859                   Make_Index (DS, LP);
1860
1861                   Set_Ekind (Id, E_Loop_Parameter);
1862                   Set_Etype (Id, Etype (DS));
1863
1864                   --  Treat a range as an implicit reference to the type, to
1865                   --  inhibit spurious warnings.
1866
1867                   Generate_Reference (Base_Type (Etype (DS)), N, ' ');
1868                   Set_Is_Known_Valid (Id, True);
1869
1870                   --  The loop is not a declarative part, so the only entity
1871                   --  declared "within" must be frozen explicitly.
1872
1873                   declare
1874                      Flist : constant List_Id := Freeze_Entity (Id, N);
1875                   begin
1876                      if Is_Non_Empty_List (Flist) then
1877                         Insert_Actions (N, Flist);
1878                      end if;
1879                   end;
1880
1881                   --  Check for null or possibly null range and issue warning.
1882                   --  We suppress such messages in generic templates and
1883                   --  instances, because in practice they tend to be dubious
1884                   --  in these cases.
1885
1886                   if Nkind (DS) = N_Range and then Comes_From_Source (N) then
1887                      declare
1888                         L : constant Node_Id := Low_Bound  (DS);
1889                         H : constant Node_Id := High_Bound (DS);
1890
1891                      begin
1892                         --  If range of loop is null, issue warning
1893
1894                         if Compile_Time_Compare
1895                             (L, H, Assume_Valid => True) = GT
1896                         then
1897                            --  Suppress the warning if inside a generic
1898                            --  template or instance, since in practice they
1899                            --  tend to be dubious in these cases since they can
1900                            --  result from intended parametrization.
1901
1902                            if not Inside_A_Generic
1903                               and then not In_Instance
1904                            then
1905                               --  Specialize msg if invalid values could make
1906                               --  the loop non-null after all.
1907
1908                               if Compile_Time_Compare
1909                                    (L, H, Assume_Valid => False) = GT
1910                               then
1911                                  Error_Msg_N
1912                                    ("?loop range is null, "
1913                                     & "loop will not execute",
1914                                     DS);
1915
1916                                  --  Since we know the range of the loop is
1917                                  --  null, set the appropriate flag to remove
1918                                  --  the loop entirely during expansion.
1919
1920                                  Set_Is_Null_Loop (Parent (N));
1921
1922                               --  Here is where the loop could execute because
1923                               --  of invalid values, so issue appropriate
1924                               --  message and in this case we do not set the
1925                               --  Is_Null_Loop flag since the loop may execute.
1926
1927                               else
1928                                  Error_Msg_N
1929                                    ("?loop range may be null, "
1930                                     & "loop may not execute",
1931                                     DS);
1932                                  Error_Msg_N
1933                                    ("?can only execute if invalid values "
1934                                     & "are present",
1935                                     DS);
1936                               end if;
1937                            end if;
1938
1939                            --  In either case, suppress warnings in the body of
1940                            --  the loop, since it is likely that these warnings
1941                            --  will be inappropriate if the loop never actually
1942                            --  executes, which is likely.
1943
1944                            Set_Suppress_Loop_Warnings (Parent (N));
1945
1946                         --  The other case for a warning is a reverse loop
1947                         --  where the upper bound is the integer literal zero
1948                         --  or one, and the lower bound can be positive.
1949
1950                         --  For example, we have
1951
1952                         --     for J in reverse N .. 1 loop
1953
1954                         --  In practice, this is very likely to be a case of
1955                         --  reversing the bounds incorrectly in the range.
1956
1957                         elsif Reverse_Present (LP)
1958                           and then Nkind (Original_Node (H)) =
1959                                                           N_Integer_Literal
1960                           and then (Intval (Original_Node (H)) = Uint_0
1961                                       or else
1962                                     Intval (Original_Node (H)) = Uint_1)
1963                         then
1964                            Error_Msg_N ("?loop range may be null", DS);
1965                            Error_Msg_N ("\?bounds may be wrong way round", DS);
1966                         end if;
1967                      end;
1968                   end if;
1969                end;
1970             end if;
1971          end;
1972       end if;
1973    end Analyze_Iteration_Scheme;
1974
1975    -------------------------------------
1976    --  Analyze_Iterator_Specification --
1977    -------------------------------------
1978
1979    procedure Analyze_Iterator_Specification (N : Node_Id) is
1980       Def_Id    : constant Node_Id := Defining_Identifier (N);
1981       Subt      : constant Node_Id := Subtype_Indication (N);
1982       Container : constant Node_Id := Name (N);
1983
1984       Ent       : Entity_Id;
1985       Typ       : Entity_Id;
1986
1987    begin
1988       Enter_Name (Def_Id);
1989       Set_Ekind (Def_Id, E_Variable);
1990
1991       if Present (Subt) then
1992          Analyze (Subt);
1993       end if;
1994
1995       Analyze_And_Resolve (Container);
1996       Typ := Etype (Container);
1997
1998       if Is_Array_Type (Typ) then
1999          if Of_Present (N) then
2000             Set_Etype (Def_Id, Component_Type (Typ));
2001
2002          else
2003             Set_Etype (Def_Id, Etype (First_Index (Typ)));
2004          end if;
2005
2006       else
2007          --  Iteration over a container
2008
2009          Set_Ekind (Def_Id, E_Loop_Parameter);
2010          if Of_Present (N) then
2011
2012             --  Find the Element_Type in the package instance that defines the
2013             --  container type.
2014
2015             Ent := First_Entity (Scope (Typ));
2016             while Present (Ent) loop
2017                if Chars (Ent) = Name_Element_Type then
2018                   Set_Etype (Def_Id, Ent);
2019                   exit;
2020                end if;
2021
2022                Next_Entity (Ent);
2023             end loop;
2024
2025          else
2026
2027             --  Find the Cursor type in similar fashion
2028
2029             Ent := First_Entity (Scope (Typ));
2030             while Present (Ent) loop
2031                if Chars (Ent) = Name_Cursor then
2032                   Set_Etype (Def_Id, Ent);
2033                   exit;
2034                end if;
2035
2036                Next_Entity (Ent);
2037             end loop;
2038          end if;
2039       end if;
2040    end Analyze_Iterator_Specification;
2041
2042    -------------------
2043    -- Analyze_Label --
2044    -------------------
2045
2046    --  Note: the semantic work required for analyzing labels (setting them as
2047    --  reachable) was done in a prepass through the statements in the block,
2048    --  so that forward gotos would be properly handled. See Analyze_Statements
2049    --  for further details. The only processing required here is to deal with
2050    --  optimizations that depend on an assumption of sequential control flow,
2051    --  since of course the occurrence of a label breaks this assumption.
2052
2053    procedure Analyze_Label (N : Node_Id) is
2054       pragma Warnings (Off, N);
2055    begin
2056       Kill_Current_Values;
2057    end Analyze_Label;
2058
2059    --------------------------
2060    -- Analyze_Label_Entity --
2061    --------------------------
2062
2063    procedure Analyze_Label_Entity (E : Entity_Id) is
2064    begin
2065       Set_Ekind           (E, E_Label);
2066       Set_Etype           (E, Standard_Void_Type);
2067       Set_Enclosing_Scope (E, Current_Scope);
2068       Set_Reachable       (E, True);
2069    end Analyze_Label_Entity;
2070
2071    ----------------------------
2072    -- Analyze_Loop_Statement --
2073    ----------------------------
2074
2075    procedure Analyze_Loop_Statement (N : Node_Id) is
2076       Loop_Statement : constant Node_Id := N;
2077
2078       Id   : constant Node_Id := Identifier (Loop_Statement);
2079       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
2080       Ent  : Entity_Id;
2081
2082    begin
2083       if Present (Id) then
2084
2085          --  Make name visible, e.g. for use in exit statements. Loop
2086          --  labels are always considered to be referenced.
2087
2088          Analyze (Id);
2089          Ent := Entity (Id);
2090
2091          --  Guard against serious error (typically, a scope mismatch when
2092          --  semantic analysis is requested) by creating loop entity to
2093          --  continue analysis.
2094
2095          if No (Ent) then
2096             if Total_Errors_Detected /= 0 then
2097                Ent :=
2098                  New_Internal_Entity
2099                    (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2100             else
2101                raise Program_Error;
2102             end if;
2103
2104          else
2105             Generate_Reference  (Ent, Loop_Statement, ' ');
2106             Generate_Definition (Ent);
2107
2108             --  If we found a label, mark its type. If not, ignore it, since it
2109             --  means we have a conflicting declaration, which would already
2110             --  have been diagnosed at declaration time. Set Label_Construct
2111             --  of the implicit label declaration, which is not created by the
2112             --  parser for generic units.
2113
2114             if Ekind (Ent) = E_Label then
2115                Set_Ekind (Ent, E_Loop);
2116
2117                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
2118                   Set_Label_Construct (Parent (Ent), Loop_Statement);
2119                end if;
2120             end if;
2121          end if;
2122
2123       --  Case of no identifier present
2124
2125       else
2126          Ent :=
2127            New_Internal_Entity
2128              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2129          Set_Etype (Ent,  Standard_Void_Type);
2130          Set_Parent (Ent, Loop_Statement);
2131       end if;
2132
2133       --  Kill current values on entry to loop, since statements in body of
2134       --  loop may have been executed before the loop is entered. Similarly we
2135       --  kill values after the loop, since we do not know that the body of the
2136       --  loop was executed.
2137
2138       Kill_Current_Values;
2139       Push_Scope (Ent);
2140       Analyze_Iteration_Scheme (Iter);
2141       Analyze_Statements (Statements (Loop_Statement));
2142       Process_End_Label (Loop_Statement, 'e', Ent);
2143       End_Scope;
2144       Kill_Current_Values;
2145
2146       --  Check for infinite loop. Skip check for generated code, since it
2147       --  justs waste time and makes debugging the routine called harder.
2148
2149       --  Note that we have to wait till the body of the loop is fully analyzed
2150       --  before making this call, since Check_Infinite_Loop_Warning relies on
2151       --  being able to use semantic visibility information to find references.
2152
2153       if Comes_From_Source (N) then
2154          Check_Infinite_Loop_Warning (N);
2155       end if;
2156
2157       --  Code after loop is unreachable if the loop has no WHILE or FOR
2158       --  and contains no EXIT statements within the body of the loop.
2159
2160       if No (Iter) and then not Has_Exit (Ent) then
2161          Check_Unreachable_Code (N);
2162       end if;
2163    end Analyze_Loop_Statement;
2164
2165    ----------------------------
2166    -- Analyze_Null_Statement --
2167    ----------------------------
2168
2169    --  Note: the semantics of the null statement is implemented by a single
2170    --  null statement, too bad everything isn't as simple as this!
2171
2172    procedure Analyze_Null_Statement (N : Node_Id) is
2173       pragma Warnings (Off, N);
2174    begin
2175       null;
2176    end Analyze_Null_Statement;
2177
2178    ------------------------
2179    -- Analyze_Statements --
2180    ------------------------
2181
2182    procedure Analyze_Statements (L : List_Id) is
2183       S   : Node_Id;
2184       Lab : Entity_Id;
2185
2186    begin
2187       --  The labels declared in the statement list are reachable from
2188       --  statements in the list. We do this as a prepass so that any
2189       --  goto statement will be properly flagged if its target is not
2190       --  reachable. This is not required, but is nice behavior!
2191
2192       S := First (L);
2193       while Present (S) loop
2194          if Nkind (S) = N_Label then
2195             Analyze (Identifier (S));
2196             Lab := Entity (Identifier (S));
2197
2198             --  If we found a label mark it as reachable
2199
2200             if Ekind (Lab) = E_Label then
2201                Generate_Definition (Lab);
2202                Set_Reachable (Lab);
2203
2204                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
2205                   Set_Label_Construct (Parent (Lab), S);
2206                end if;
2207
2208             --  If we failed to find a label, it means the implicit declaration
2209             --  of the label was hidden.  A for-loop parameter can do this to
2210             --  a label with the same name inside the loop, since the implicit
2211             --  label declaration is in the innermost enclosing body or block
2212             --  statement.
2213
2214             else
2215                Error_Msg_Sloc := Sloc (Lab);
2216                Error_Msg_N
2217                  ("implicit label declaration for & is hidden#",
2218                   Identifier (S));
2219             end if;
2220          end if;
2221
2222          Next (S);
2223       end loop;
2224
2225       --  Perform semantic analysis on all statements
2226
2227       Conditional_Statements_Begin;
2228
2229       S := First (L);
2230       while Present (S) loop
2231          Analyze (S);
2232          Next (S);
2233       end loop;
2234
2235       Conditional_Statements_End;
2236
2237       --  Make labels unreachable. Visibility is not sufficient, because
2238       --  labels in one if-branch for example are not reachable from the
2239       --  other branch, even though their declarations are in the enclosing
2240       --  declarative part.
2241
2242       S := First (L);
2243       while Present (S) loop
2244          if Nkind (S) = N_Label then
2245             Set_Reachable (Entity (Identifier (S)), False);
2246          end if;
2247
2248          Next (S);
2249       end loop;
2250    end Analyze_Statements;
2251
2252    ----------------------------
2253    -- Check_Unreachable_Code --
2254    ----------------------------
2255
2256    procedure Check_Unreachable_Code (N : Node_Id) is
2257       Error_Loc : Source_Ptr;
2258       P         : Node_Id;
2259
2260    begin
2261       if Is_List_Member (N)
2262         and then Comes_From_Source (N)
2263       then
2264          declare
2265             Nxt : Node_Id;
2266
2267          begin
2268             Nxt := Original_Node (Next (N));
2269
2270             --  If a label follows us, then we never have dead code, since
2271             --  someone could branch to the label, so we just ignore it.
2272
2273             if Nkind (Nxt) = N_Label then
2274                return;
2275
2276             --  Otherwise see if we have a real statement following us
2277
2278             elsif Present (Nxt)
2279               and then Comes_From_Source (Nxt)
2280               and then Is_Statement (Nxt)
2281             then
2282                --  Special very annoying exception. If we have a return that
2283                --  follows a raise, then we allow it without a warning, since
2284                --  the Ada RM annoyingly requires a useless return here!
2285
2286                if Nkind (Original_Node (N)) /= N_Raise_Statement
2287                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2288                then
2289                   --  The rather strange shenanigans with the warning message
2290                   --  here reflects the fact that Kill_Dead_Code is very good
2291                   --  at removing warnings in deleted code, and this is one
2292                   --  warning we would prefer NOT to have removed.
2293
2294                   Error_Loc := Sloc (Nxt);
2295
2296                   --  If we have unreachable code, analyze and remove the
2297                   --  unreachable code, since it is useless and we don't
2298                   --  want to generate junk warnings.
2299
2300                   --  We skip this step if we are not in code generation mode.
2301                   --  This is the one case where we remove dead code in the
2302                   --  semantics as opposed to the expander, and we do not want
2303                   --  to remove code if we are not in code generation mode,
2304                   --  since this messes up the ASIS trees.
2305
2306                   --  Note that one might react by moving the whole circuit to
2307                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2308
2309                   if Operating_Mode = Generate_Code then
2310                      loop
2311                         Nxt := Next (N);
2312
2313                         --  Quit deleting when we have nothing more to delete
2314                         --  or if we hit a label (since someone could transfer
2315                         --  control to a label, so we should not delete it).
2316
2317                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2318
2319                         --  Statement/declaration is to be deleted
2320
2321                         Analyze (Nxt);
2322                         Remove (Nxt);
2323                         Kill_Dead_Code (Nxt);
2324                      end loop;
2325                   end if;
2326
2327                   --  Now issue the warning
2328
2329                   Error_Msg ("?unreachable code!", Error_Loc);
2330                end if;
2331
2332             --  If the unconditional transfer of control instruction is
2333             --  the last statement of a sequence, then see if our parent
2334             --  is one of the constructs for which we count unblocked exits,
2335             --  and if so, adjust the count.
2336
2337             else
2338                P := Parent (N);
2339
2340                --  Statements in THEN part or ELSE part of IF statement
2341
2342                if Nkind (P) = N_If_Statement then
2343                   null;
2344
2345                --  Statements in ELSIF part of an IF statement
2346
2347                elsif Nkind (P) = N_Elsif_Part then
2348                   P := Parent (P);
2349                   pragma Assert (Nkind (P) = N_If_Statement);
2350
2351                --  Statements in CASE statement alternative
2352
2353                elsif Nkind (P) = N_Case_Statement_Alternative then
2354                   P := Parent (P);
2355                   pragma Assert (Nkind (P) = N_Case_Statement);
2356
2357                --  Statements in body of block
2358
2359                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2360                  and then Nkind (Parent (P)) = N_Block_Statement
2361                then
2362                   null;
2363
2364                --  Statements in exception handler in a block
2365
2366                elsif Nkind (P) = N_Exception_Handler
2367                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2368                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2369                then
2370                   null;
2371
2372                --  None of these cases, so return
2373
2374                else
2375                   return;
2376                end if;
2377
2378                --  This was one of the cases we are looking for (i.e. the
2379                --  parent construct was IF, CASE or block) so decrement count.
2380
2381                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2382             end if;
2383          end;
2384       end if;
2385    end Check_Unreachable_Code;
2386
2387 end Sem_Ch5;