gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Checks;   use Checks;
  29 with Einfo;    use Einfo;
  30 with Errout;   use Errout;
  31 with Expander; use Expander;
  32 with Exp_Util; use Exp_Util;
  33 with Freeze;   use Freeze;
  34 with Lib;      use Lib;
  35 with Lib.Xref; use Lib.Xref;
  36 with Namet;    use Namet;
  37 with Nlists;   use Nlists;
  38 with Nmake;    use Nmake;
  39 with Opt;      use Opt;
  40 with Rtsfind;  use Rtsfind;
  41 with Sem;      use Sem;
  42 with Sem_Case; use Sem_Case;
  43 with Sem_Ch3;  use Sem_Ch3;
  44 with Sem_Ch8;  use Sem_Ch8;
  45 with Sem_Disp; use Sem_Disp;
  46 with Sem_Elab; use Sem_Elab;
  47 with Sem_Eval; use Sem_Eval;
  48 with Sem_Res;  use Sem_Res;
  49 with Sem_Type; use Sem_Type;
  50 with Sem_Util; use Sem_Util;
  51 with Sem_Warn; use Sem_Warn;
  52 with Snames;   use Snames;
  53 with Stand;    use Stand;
  54 with Sinfo;    use Sinfo;
  55 with Targparm; use Targparm;
  56 with Tbuild;   use Tbuild;
  57 with Uintp;    use Uintp;
  58
  59 package body Sem_Ch5 is
  60
  61    Unblocked_Exit_Count : Nat := 0;
  62    --  This variable is used when processing if statements, case statements,
  63    --  and block statements. It counts the number of exit points that are not
  64    --  blocked by unconditional transfer instructions: for IF and CASE, these
  65    --  are the branches of the conditional; for a block, they are the statement
  66    --  sequence of the block, and the statement sequences of any exception
  67    --  handlers that are part of the block. When processing is complete, if
  68    --  this count is zero, it means that control cannot fall through the IF,
  69    --  CASE or block statement. This is used for the generation of warning
  70    --  messages. This variable is recursively saved on entry to processing the
  71    --  construct, and restored on exit.
  72
  73    -----------------------
  74    -- Local Subprograms --
  75    -----------------------
  76
  77    procedure Analyze_Iteration_Scheme (N : Node_Id);
  78
  79    ------------------------
  80    -- Analyze_Assignment --
  81    ------------------------
  82
  83    procedure Analyze_Assignment (N : Node_Id) is
  84       Lhs  : constant Node_Id := Name (N);
  85       Rhs  : constant Node_Id := Expression (N);
  86       T1   : Entity_Id;
  87       T2   : Entity_Id;
  88       Decl : Node_Id;
  89
  90       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  91       --  N is the node for the left hand side of an assignment, and it
  92       --  is not a variable. This routine issues an appropriate diagnostic.
  93
  94       procedure Kill_Lhs;
  95       --  This is called to kill current value settings of a simple variable
  96       --  on the left hand side. We call it if we find any error in analyzing
  97       --  the assignment, and at the end of processing before setting any new
  98       --  current values in place.
  99
 100       procedure Set_Assignment_Type
 101         (Opnd      : Node_Id;
 102          Opnd_Type : in out Entity_Id);
 103       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 104       --  is the nominal subtype. This procedure is used to deal with cases
 105       --  where the nominal subtype must be replaced by the actual subtype.
 106
 107       -------------------------------
 108       -- Diagnose_Non_Variable_Lhs --
 109       -------------------------------
 110
 111       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 112       begin
 113          --  Not worth posting another error if left hand side already
 114          --  flagged as being illegal in some respect.
 115
 116          if Error_Posted (N) then
 117             return;
 118
 119          --  Some special bad cases of entity names
 120
 121          elsif Is_Entity_Name (N) then
 122             if Ekind (Entity (N)) = E_In_Parameter then
 123                Error_Msg_N
 124                  ("assignment to IN mode parameter not allowed", N);
 125
 126             --  Private declarations in a protected object are turned into
 127             --  constants when compiling a protected function.
 128
 129             elsif Present (Scope (Entity (N)))
 130               and then Is_Protected_Type (Scope (Entity (N)))
 131               and then
 132                 (Ekind (Current_Scope) = E_Function
 133                   or else
 134                  Ekind (Enclosing_Dynamic_Scope (Current_Scope)) = E_Function)
 135             then
 136                Error_Msg_N
 137                  ("protected function cannot modify protected object", N);
 138
 139             elsif Ekind (Entity (N)) = E_Loop_Parameter then
 140                Error_Msg_N
 141                  ("assignment to loop parameter not allowed", N);
 142
 143             else
 144                Error_Msg_N
 145                  ("left hand side of assignment must be a variable", N);
 146             end if;
 147
 148          --  For indexed components or selected components, test prefix
 149
 150          elsif Nkind (N) = N_Indexed_Component then
 151             Diagnose_Non_Variable_Lhs (Prefix (N));
 152
 153          --  Another special case for assignment to discriminant
 154
 155          elsif Nkind (N) = N_Selected_Component then
 156             if Present (Entity (Selector_Name (N)))
 157               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 158             then
 159                Error_Msg_N
 160                  ("assignment to discriminant not allowed", N);
 161             else
 162                Diagnose_Non_Variable_Lhs (Prefix (N));
 163             end if;
 164
 165          else
 166             --  If we fall through, we have no special message to issue!
 167
 168             Error_Msg_N ("left hand side of assignment must be a variable", N);
 169          end if;
 170       end Diagnose_Non_Variable_Lhs;
 171
 172       --------------
 173       -- Kill_LHS --
 174       --------------
 175
 176       procedure Kill_Lhs is
 177       begin
 178          if Is_Entity_Name (Lhs) then
 179             declare
 180                Ent : constant Entity_Id := Entity (Lhs);
 181             begin
 182                if Present (Ent) then
 183                   Kill_Current_Values (Ent);
 184                end if;
 185             end;
 186          end if;
 187       end Kill_Lhs;
 188
 189       -------------------------
 190       -- Set_Assignment_Type --
 191       -------------------------
 192
 193       procedure Set_Assignment_Type
 194         (Opnd      : Node_Id;
 195          Opnd_Type : in out Entity_Id)
 196       is
 197       begin
 198          Require_Entity (Opnd);
 199
 200          --  If the assignment operand is an in-out or out parameter, then we
 201          --  get the actual subtype (needed for the unconstrained case).
 202          --  If the operand is the actual in an entry declaration, then within
 203          --  the accept statement it is replaced with a local renaming, which
 204          --  may also have an actual subtype.
 205
 206          if Is_Entity_Name (Opnd)
 207            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 208                       or else Ekind (Entity (Opnd)) =
 209                            E_In_Out_Parameter
 210                       or else Ekind (Entity (Opnd)) =
 211                            E_Generic_In_Out_Parameter
 212                       or else
 213                         (Ekind (Entity (Opnd)) = E_Variable
 214                           and then Nkind (Parent (Entity (Opnd))) =
 215                              N_Object_Renaming_Declaration
 216                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 217                              N_Accept_Statement))
 218          then
 219             Opnd_Type := Get_Actual_Subtype (Opnd);
 220
 221          --  If assignment operand is a component reference, then we get the
 222          --  actual subtype of the component for the unconstrained case.
 223
 224          elsif
 225            (Nkind (Opnd) = N_Selected_Component
 226              or else Nkind (Opnd) = N_Explicit_Dereference)
 227            and then not Is_Unchecked_Union (Opnd_Type)
 228          then
 229             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 230
 231             if Present (Decl) then
 232                Insert_Action (N, Decl);
 233                Mark_Rewrite_Insertion (Decl);
 234                Analyze (Decl);
 235                Opnd_Type := Defining_Identifier (Decl);
 236                Set_Etype (Opnd, Opnd_Type);
 237                Freeze_Itype (Opnd_Type, N);
 238
 239             elsif Is_Constrained (Etype (Opnd)) then
 240                Opnd_Type := Etype (Opnd);
 241             end if;
 242
 243          --  For slice, use the constrained subtype created for the slice
 244
 245          elsif Nkind (Opnd) = N_Slice then
 246             Opnd_Type := Etype (Opnd);
 247          end if;
 248       end Set_Assignment_Type;
 249
 250    --  Start of processing for Analyze_Assignment
 251
 252    begin
 253       Mark_Static_Coextensions (Rhs);
 254       Analyze (Rhs);
 255       Analyze (Lhs);
 256
 257       --  Start type analysis for assignment
 258
 259       T1 := Etype (Lhs);
 260
 261       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 262       --  must compute the intersection of the possible types on each side.
 263
 264       if Is_Overloaded (Lhs) then
 265          declare
 266             I  : Interp_Index;
 267             It : Interp;
 268
 269          begin
 270             T1 := Any_Type;
 271             Get_First_Interp (Lhs, I, It);
 272
 273             while Present (It.Typ) loop
 274                if Has_Compatible_Type (Rhs, It.Typ) then
 275                   if T1 /= Any_Type then
 276
 277                      --  An explicit dereference is overloaded if the prefix
 278                      --  is. Try to remove the ambiguity on the prefix, the
 279                      --  error will be posted there if the ambiguity is real.
 280
 281                      if Nkind (Lhs) = N_Explicit_Dereference then
 282                         declare
 283                            PI    : Interp_Index;
 284                            PI1   : Interp_Index := 0;
 285                            PIt   : Interp;
 286                            Found : Boolean;
 287
 288                         begin
 289                            Found := False;
 290                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 291
 292                            while Present (PIt.Typ) loop
 293                               if Is_Access_Type (PIt.Typ)
 294                                 and then Has_Compatible_Type
 295                                            (Rhs, Designated_Type (PIt.Typ))
 296                               then
 297                                  if Found then
 298                                     PIt :=
 299                                       Disambiguate (Prefix (Lhs),
 300                                         PI1, PI, Any_Type);
 301
 302                                     if PIt = No_Interp then
 303                                        Error_Msg_N
 304                                          ("ambiguous left-hand side"
 305                                             & " in assignment", Lhs);
 306                                        exit;
 307                                     else
 308                                        Resolve (Prefix (Lhs), PIt.Typ);
 309                                     end if;
 310
 311                                     exit;
 312                                  else
 313                                     Found := True;
 314                                     PI1 := PI;
 315                                  end if;
 316                               end if;
 317
 318                               Get_Next_Interp (PI, PIt);
 319                            end loop;
 320                         end;
 321
 322                      else
 323                         Error_Msg_N
 324                           ("ambiguous left-hand side in assignment", Lhs);
 325                         exit;
 326                      end if;
 327                   else
 328                      T1 := It.Typ;
 329                   end if;
 330                end if;
 331
 332                Get_Next_Interp (I, It);
 333             end loop;
 334          end;
 335
 336          if T1 = Any_Type then
 337             Error_Msg_N
 338               ("no valid types for left-hand side for assignment", Lhs);
 339             Kill_Lhs;
 340             return;
 341          end if;
 342       end if;
 343
 344       --  The resulting assignment type is T1, so now we will resolve the
 345       --  left hand side of the assignment using this determined type.
 346
 347       Resolve (Lhs, T1);
 348
 349       --  Cases where Lhs is not a variable
 350
 351       if not Is_Variable (Lhs) then
 352
 353          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 354          --  a protected object.
 355
 356          declare
 357             Ent : Entity_Id;
 358             S   : Entity_Id;
 359
 360          begin
 361             if Ada_Version >= Ada_05 then
 362
 363                --  Handle chains of renamings
 364
 365                Ent := Lhs;
 366                while Nkind (Ent) in N_Has_Entity
 367                  and then Present (Entity (Ent))
 368                  and then Present (Renamed_Object (Entity (Ent)))
 369                loop
 370                   Ent := Renamed_Object (Entity (Ent));
 371                end loop;
 372
 373                if (Nkind (Ent) = N_Attribute_Reference
 374                      and then Attribute_Name (Ent) = Name_Priority)
 375
 376                   --  Renamings of the attribute Priority applied to protected
 377                   --  objects have been previously expanded into calls to the
 378                   --  Get_Ceiling run-time subprogram.
 379
 380                  or else
 381                   (Nkind (Ent) = N_Function_Call
 382                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 383                                 or else
 384                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 385                then
 386                   --  The enclosing subprogram cannot be a protected function
 387
 388                   S := Current_Scope;
 389                   while not (Is_Subprogram (S)
 390                                and then Convention (S) = Convention_Protected)
 391                      and then S /= Standard_Standard
 392                   loop
 393                      S := Scope (S);
 394                   end loop;
 395
 396                   if Ekind (S) = E_Function
 397                     and then Convention (S) = Convention_Protected
 398                   then
 399                      Error_Msg_N
 400                        ("protected function cannot modify protected object",
 401                         Lhs);
 402                   end if;
 403
 404                   --  Changes of the ceiling priority of the protected object
 405                   --  are only effective if the Ceiling_Locking policy is in
 406                   --  effect (AARM D.5.2 (5/2)).
 407
 408                   if Locking_Policy /= 'C' then
 409                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 410                                   "no effect?", Lhs);
 411                      Error_Msg_N ("\since no Locking_Policy has been " &
 412                                   "specified", Lhs);
 413                   end if;
 414
 415                   return;
 416                end if;
 417             end if;
 418          end;
 419
 420          Diagnose_Non_Variable_Lhs (Lhs);
 421          return;
 422
 423       --  Error of assigning to limited type. We do however allow this in
 424       --  certain cases where the front end generates the assignments.
 425
 426       elsif Is_Limited_Type (T1)
 427         and then not Assignment_OK (Lhs)
 428         and then not Assignment_OK (Original_Node (Lhs))
 429         and then not Is_Value_Type (T1)
 430       then
 431          Error_Msg_N
 432            ("left hand of assignment must not be limited type", Lhs);
 433          Explain_Limited_Type (T1, Lhs);
 434          return;
 435       end if;
 436
 437       --  Resolution may have updated the subtype, in case the left-hand
 438       --  side is a private protected component. Use the correct subtype
 439       --  to avoid scoping issues in the back-end.
 440
 441       T1 := Etype (Lhs);
 442
 443       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 444       --  type. For example:
 445
 446       --    limited with P;
 447       --    package Pkg is
 448       --      type Acc is access P.T;
 449       --    end Pkg;
 450
 451       --    with Pkg; use Acc;
 452       --    procedure Example is
 453       --       A, B : Acc;
 454       --    begin
 455       --       A.all := B.all;  -- ERROR
 456       --    end Example;
 457
 458       if Nkind (Lhs) = N_Explicit_Dereference
 459         and then Ekind (T1) = E_Incomplete_Type
 460       then
 461          Error_Msg_N ("invalid use of incomplete type", Lhs);
 462          Kill_Lhs;
 463          return;
 464       end if;
 465
 466       --  Now we can complete the resolution of the right hand side
 467
 468       Set_Assignment_Type (Lhs, T1);
 469       Resolve (Rhs, T1);
 470
 471       --  This is the point at which we check for an unset reference
 472
 473       Check_Unset_Reference (Rhs);
 474
 475       --  Remaining steps are skipped if Rhs was syntactically in error
 476
 477       if Rhs = Error then
 478          Kill_Lhs;
 479          return;
 480       end if;
 481
 482       T2 := Etype (Rhs);
 483
 484       if not Covers (T1, T2) then
 485          Wrong_Type (Rhs, Etype (Lhs));
 486          Kill_Lhs;
 487          return;
 488       end if;
 489
 490       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 491       --  types, use the non-limited view if available
 492
 493       if Nkind (Rhs) = N_Explicit_Dereference
 494         and then Ekind (T2) = E_Incomplete_Type
 495         and then Is_Tagged_Type (T2)
 496         and then Present (Non_Limited_View (T2))
 497       then
 498          T2 := Non_Limited_View (T2);
 499       end if;
 500
 501       Set_Assignment_Type (Rhs, T2);
 502
 503       if Total_Errors_Detected /= 0 then
 504          if No (T1) then
 505             T1 := Any_Type;
 506          end if;
 507
 508          if No (T2) then
 509             T2 := Any_Type;
 510          end if;
 511       end if;
 512
 513       if T1 = Any_Type or else T2 = Any_Type then
 514          Kill_Lhs;
 515          return;
 516       end if;
 517
 518       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 519       --  to be class-wide. The case where the rhs is a dynamically tagged call
 520       --  to a dispatching operation with a controlling access result is
 521       --  excluded from this check, since the target has an access type (and
 522       --  no tag propagation occurs in that case).
 523
 524       if (Is_Class_Wide_Type (T2)
 525            or else (Is_Dynamically_Tagged (Rhs)
 526                      and then not Is_Access_Type (T1)))
 527         and then not Is_Class_Wide_Type (T1)
 528       then
 529          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 530
 531       elsif Is_Class_Wide_Type (T1)
 532         and then not Is_Class_Wide_Type (T2)
 533         and then not Is_Tag_Indeterminate (Rhs)
 534         and then not Is_Dynamically_Tagged (Rhs)
 535       then
 536          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 537       end if;
 538
 539       --  Propagate the tag from a class-wide target to the rhs when the rhs
 540       --  is a tag-indeterminate call.
 541
 542       if Is_Tag_Indeterminate (Rhs) then
 543          if Is_Class_Wide_Type (T1) then
 544             Propagate_Tag (Lhs, Rhs);
 545
 546          elsif Nkind (Rhs) = N_Function_Call
 547               and then Is_Entity_Name (Name (Rhs))
 548               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 549          then
 550             Error_Msg_N
 551               ("call to abstract function must be dispatching", Name (Rhs));
 552
 553          elsif Nkind (Rhs) = N_Qualified_Expression
 554            and then Nkind (Expression (Rhs)) = N_Function_Call
 555               and then Is_Entity_Name (Name (Expression (Rhs)))
 556               and then
 557                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 558          then
 559             Error_Msg_N
 560               ("call to abstract function must be dispatching",
 561                 Name (Expression (Rhs)));
 562          end if;
 563       end if;
 564
 565       --  Ada 2005 (AI-230 and AI-385): When the lhs type is an anonymous
 566       --  access type, apply an implicit conversion of the rhs to that type
 567       --  to force appropriate static and run-time accessibility checks.
 568
 569       if Ada_Version >= Ada_05
 570         and then Ekind (T1) = E_Anonymous_Access_Type
 571       then
 572          Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 573          Analyze_And_Resolve (Rhs, T1);
 574       end if;
 575
 576       --  Ada 2005 (AI-231)
 577
 578       if Ada_Version >= Ada_05
 579         and then Can_Never_Be_Null (T1)
 580         and then not Assignment_OK (Lhs)
 581       then
 582          if Nkind (Rhs) = N_Null then
 583             Apply_Compile_Time_Constraint_Error
 584               (N   => Rhs,
 585                Msg => "(Ada 2005) NULL not allowed in null-excluding objects?",
 586                Reason => CE_Null_Not_Allowed);
 587             return;
 588
 589          elsif not Can_Never_Be_Null (T2) then
 590             Rewrite (Rhs,
 591               Convert_To (T1, Relocate_Node (Rhs)));
 592             Analyze_And_Resolve (Rhs, T1);
 593          end if;
 594       end if;
 595
 596       if Is_Scalar_Type (T1) then
 597          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 598
 599       --  For array types, verify that lengths match. If the right hand side
 600       --  if a function call that has been inlined, the assignment has been
 601       --  rewritten as a block, and the constraint check will be applied to the
 602       --  assignment within the block.
 603
 604       elsif Is_Array_Type (T1)
 605         and then
 606           (Nkind (Rhs) /= N_Type_Conversion
 607             or else Is_Constrained (Etype (Rhs)))
 608         and then
 609           (Nkind (Rhs) /= N_Function_Call
 610             or else Nkind (N) /= N_Block_Statement)
 611       then
 612          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 613          --  but of course the indices do not have to match. If the right-hand
 614          --  side is a type conversion to an unconstrained type, a length check
 615          --  is performed on the expression itself during expansion. In rare
 616          --  cases, the redundant length check is computed on an index type
 617          --  with a different representation, triggering incorrect code in
 618          --  the back end.
 619
 620          Apply_Length_Check (Rhs, Etype (Lhs));
 621
 622       else
 623          --  Discriminant checks are applied in the course of expansion
 624
 625          null;
 626       end if;
 627
 628       --  Note: modifications of the Lhs may only be recorded after
 629       --  checks have been applied.
 630
 631       Note_Possible_Modification (Lhs);
 632
 633       --  ??? a real accessibility check is needed when ???
 634
 635       --  Post warning for redundant assignment or variable to itself
 636
 637       if Warn_On_Redundant_Constructs
 638
 639          --  We only warn for source constructs
 640
 641          and then Comes_From_Source (N)
 642
 643          --  Where the entity is the same on both sides
 644
 645          and then Is_Entity_Name (Lhs)
 646          and then Is_Entity_Name (Original_Node (Rhs))
 647          and then Entity (Lhs) = Entity (Original_Node (Rhs))
 648
 649          --  But exclude the case where the right side was an operation
 650          --  that got rewritten (e.g. JUNK + K, where K was known to be
 651          --  zero). We don't want to warn in such a case, since it is
 652          --  reasonable to write such expressions especially when K is
 653          --  defined symbolically in some other package.
 654
 655         and then Nkind (Original_Node (Rhs)) not in N_Op
 656       then
 657          Error_Msg_NE
 658            ("?useless assignment of & to itself", N, Entity (Lhs));
 659       end if;
 660
 661       --  Check for non-allowed composite assignment
 662
 663       if not Support_Composite_Assign_On_Target
 664         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 665         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 666       then
 667          Error_Msg_CRT ("composite assignment", N);
 668       end if;
 669
 670       --  Check elaboration warning for left side if not in elab code
 671
 672       if not In_Subprogram_Or_Concurrent_Unit then
 673          Check_Elab_Assign (Lhs);
 674       end if;
 675
 676       --  Final step. If left side is an entity, then we may be able to
 677       --  reset the current tracked values to new safe values. We only have
 678       --  something to do if the left side is an entity name, and expansion
 679       --  has not modified the node into something other than an assignment,
 680       --  and of course we only capture values if it is safe to do so.
 681
 682       if Is_Entity_Name (Lhs)
 683         and then Nkind (N) = N_Assignment_Statement
 684       then
 685          declare
 686             Ent : constant Entity_Id := Entity (Lhs);
 687
 688          begin
 689             if Safe_To_Capture_Value (N, Ent) then
 690
 691                --  If simple variable on left side, warn if this assignment
 692                --  blots out another one (rendering it useless) and note
 693                --  location of assignment in case no one references value.
 694                --  We only do this for source assignments, otherwise we can
 695                --  generate bogus warnings when an assignment is rewritten as
 696                --  another assignment, and gets tied up with itself.
 697
 698                if Warn_On_Modified_Unread
 699                  and then Ekind (Ent) = E_Variable
 700                  and then Comes_From_Source (N)
 701                  and then In_Extended_Main_Source_Unit (Ent)
 702                then
 703                   Warn_On_Useless_Assignment (Ent, Sloc (N));
 704                   Set_Last_Assignment (Ent, Lhs);
 705                end if;
 706
 707                --  If we are assigning an access type and the left side is an
 708                --  entity, then make sure that the Is_Known_[Non_]Null flags
 709                --  properly reflect the state of the entity after assignment.
 710
 711                if Is_Access_Type (T1) then
 712                   if Known_Non_Null (Rhs) then
 713                      Set_Is_Known_Non_Null (Ent, True);
 714
 715                   elsif Known_Null (Rhs)
 716                     and then not Can_Never_Be_Null (Ent)
 717                   then
 718                      Set_Is_Known_Null (Ent, True);
 719
 720                   else
 721                      Set_Is_Known_Null (Ent, False);
 722
 723                      if not Can_Never_Be_Null (Ent) then
 724                         Set_Is_Known_Non_Null (Ent, False);
 725                      end if;
 726                   end if;
 727
 728                --  For discrete types, we may be able to set the current value
 729                --  if the value is known at compile time.
 730
 731                elsif Is_Discrete_Type (T1)
 732                  and then Compile_Time_Known_Value (Rhs)
 733                then
 734                   Set_Current_Value (Ent, Rhs);
 735                else
 736                   Set_Current_Value (Ent, Empty);
 737                end if;
 738
 739             --  If not safe to capture values, kill them
 740
 741             else
 742                Kill_Lhs;
 743             end if;
 744          end;
 745       end if;
 746    end Analyze_Assignment;
 747
 748    -----------------------------
 749    -- Analyze_Block_Statement --
 750    -----------------------------
 751
 752    procedure Analyze_Block_Statement (N : Node_Id) is
 753       Decls : constant List_Id := Declarations (N);
 754       Id    : constant Node_Id := Identifier (N);
 755       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 756
 757    begin
 758       --  If no handled statement sequence is present, things are really
 759       --  messed up, and we just return immediately (this is a defence
 760       --  against previous errors).
 761
 762       if No (HSS) then
 763          return;
 764       end if;
 765
 766       --  Normal processing with HSS present
 767
 768       declare
 769          EH  : constant List_Id := Exception_Handlers (HSS);
 770          Ent : Entity_Id        := Empty;
 771          S   : Entity_Id;
 772
 773          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 774          --  Recursively save value of this global, will be restored on exit
 775
 776       begin
 777          --  Initialize unblocked exit count for statements of begin block
 778          --  plus one for each excption handler that is present.
 779
 780          Unblocked_Exit_Count := 1;
 781
 782          if Present (EH) then
 783             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 784          end if;
 785
 786          --  If a label is present analyze it and mark it as referenced
 787
 788          if Present (Id) then
 789             Analyze (Id);
 790             Ent := Entity (Id);
 791
 792             --  An error defense. If we have an identifier, but no entity,
 793             --  then something is wrong. If we have previous errors, then
 794             --  just remove the identifier and continue, otherwise raise
 795             --  an exception.
 796
 797             if No (Ent) then
 798                if Total_Errors_Detected /= 0 then
 799                   Set_Identifier (N, Empty);
 800                else
 801                   raise Program_Error;
 802                end if;
 803
 804             else
 805                Set_Ekind (Ent, E_Block);
 806                Generate_Reference (Ent, N, ' ');
 807                Generate_Definition (Ent);
 808
 809                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 810                   Set_Label_Construct (Parent (Ent), N);
 811                end if;
 812             end if;
 813          end if;
 814
 815          --  If no entity set, create a label entity
 816
 817          if No (Ent) then
 818             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 819             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 820             Set_Parent (Ent, N);
 821          end if;
 822
 823          Set_Etype (Ent, Standard_Void_Type);
 824          Set_Block_Node (Ent, Identifier (N));
 825          Push_Scope (Ent);
 826
 827          if Present (Decls) then
 828             Analyze_Declarations (Decls);
 829             Check_Completion;
 830          end if;
 831
 832          Analyze (HSS);
 833          Process_End_Label (HSS, 'e', Ent);
 834
 835          --  If exception handlers are present, then we indicate that
 836          --  enclosing scopes contain a block with handlers. We only
 837          --  need to mark non-generic scopes.
 838
 839          if Present (EH) then
 840             S := Scope (Ent);
 841             loop
 842                Set_Has_Nested_Block_With_Handler (S);
 843                exit when Is_Overloadable (S)
 844                  or else Ekind (S) = E_Package
 845                  or else Is_Generic_Unit (S);
 846                S := Scope (S);
 847             end loop;
 848          end if;
 849
 850          Check_References (Ent);
 851          Warn_On_Useless_Assignments (Ent);
 852          End_Scope;
 853
 854          if Unblocked_Exit_Count = 0 then
 855             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 856             Check_Unreachable_Code (N);
 857          else
 858             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 859          end if;
 860       end;
 861    end Analyze_Block_Statement;
 862
 863    ----------------------------
 864    -- Analyze_Case_Statement --
 865    ----------------------------
 866
 867    procedure Analyze_Case_Statement (N : Node_Id) is
 868       Exp            : Node_Id;
 869       Exp_Type       : Entity_Id;
 870       Exp_Btype      : Entity_Id;
 871       Last_Choice    : Nat;
 872       Dont_Care      : Boolean;
 873       Others_Present : Boolean;
 874
 875       Statements_Analyzed : Boolean := False;
 876       --  Set True if at least some statement sequences get analyzed.
 877       --  If False on exit, means we had a serious error that prevented
 878       --  full analysis of the case statement, and as a result it is not
 879       --  a good idea to output warning messages about unreachable code.
 880
 881       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 882       --  Recursively save value of this global, will be restored on exit
 883
 884       procedure Non_Static_Choice_Error (Choice : Node_Id);
 885       --  Error routine invoked by the generic instantiation below when
 886       --  the case statment has a non static choice.
 887
 888       procedure Process_Statements (Alternative : Node_Id);
 889       --  Analyzes all the statements associated to a case alternative.
 890       --  Needed by the generic instantiation below.
 891
 892       package Case_Choices_Processing is new
 893         Generic_Choices_Processing
 894           (Get_Alternatives          => Alternatives,
 895            Get_Choices               => Discrete_Choices,
 896            Process_Empty_Choice      => No_OP,
 897            Process_Non_Static_Choice => Non_Static_Choice_Error,
 898            Process_Associated_Node   => Process_Statements);
 899       use Case_Choices_Processing;
 900       --  Instantiation of the generic choice processing package
 901
 902       -----------------------------
 903       -- Non_Static_Choice_Error --
 904       -----------------------------
 905
 906       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 907       begin
 908          Flag_Non_Static_Expr
 909            ("choice given in case statement is not static!", Choice);
 910       end Non_Static_Choice_Error;
 911
 912       ------------------------
 913       -- Process_Statements --
 914       ------------------------
 915
 916       procedure Process_Statements (Alternative : Node_Id) is
 917          Choices : constant List_Id := Discrete_Choices (Alternative);
 918          Ent     : Entity_Id;
 919
 920       begin
 921          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 922          Statements_Analyzed := True;
 923
 924          --  An interesting optimization. If the case statement expression
 925          --  is a simple entity, then we can set the current value within
 926          --  an alternative if the alternative has one possible value.
 927
 928          --    case N is
 929          --      when 1      => alpha
 930          --      when 2 | 3  => beta
 931          --      when others => gamma
 932
 933          --  Here we know that N is initially 1 within alpha, but for beta
 934          --  and gamma, we do not know anything more about the initial value.
 935
 936          if Is_Entity_Name (Exp) then
 937             Ent := Entity (Exp);
 938
 939             if Ekind (Ent) = E_Variable
 940                  or else
 941                Ekind (Ent) = E_In_Out_Parameter
 942                  or else
 943                Ekind (Ent) = E_Out_Parameter
 944             then
 945                if List_Length (Choices) = 1
 946                  and then Nkind (First (Choices)) in N_Subexpr
 947                  and then Compile_Time_Known_Value (First (Choices))
 948                then
 949                   Set_Current_Value (Entity (Exp), First (Choices));
 950                end if;
 951
 952                Analyze_Statements (Statements (Alternative));
 953
 954                --  After analyzing the case, set the current value to empty
 955                --  since we won't know what it is for the next alternative
 956                --  (unless reset by this same circuit), or after the case.
 957
 958                Set_Current_Value (Entity (Exp), Empty);
 959                return;
 960             end if;
 961          end if;
 962
 963          --  Case where expression is not an entity name of a variable
 964
 965          Analyze_Statements (Statements (Alternative));
 966       end Process_Statements;
 967
 968       --  Table to record choices. Put after subprograms since we make
 969       --  a call to Number_Of_Choices to get the right number of entries.
 970
 971       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
 972
 973    --  Start of processing for Analyze_Case_Statement
 974
 975    begin
 976       Unblocked_Exit_Count := 0;
 977       Exp := Expression (N);
 978       Analyze (Exp);
 979
 980       --  The expression must be of any discrete type. In rare cases, the
 981       --  expander constructs a case statement whose expression has a private
 982       --  type whose full view is discrete. This can happen when generating
 983       --  a stream operation for a variant type after the type is frozen,
 984       --  when the partial of view of the type of the discriminant is private.
 985       --  In that case, use the full view to analyze case alternatives.
 986
 987       if not Is_Overloaded (Exp)
 988         and then not Comes_From_Source (N)
 989         and then Is_Private_Type (Etype (Exp))
 990         and then Present (Full_View (Etype (Exp)))
 991         and then Is_Discrete_Type (Full_View (Etype (Exp)))
 992       then
 993          Resolve (Exp, Etype (Exp));
 994          Exp_Type := Full_View (Etype (Exp));
 995
 996       else
 997          Analyze_And_Resolve (Exp, Any_Discrete);
 998          Exp_Type := Etype (Exp);
 999       end if;
1000
1001       Check_Unset_Reference (Exp);
1002       Exp_Btype := Base_Type (Exp_Type);
1003
1004       --  The expression must be of a discrete type which must be determinable
1005       --  independently of the context in which the expression occurs, but
1006       --  using the fact that the expression must be of a discrete type.
1007       --  Moreover, the type this expression must not be a character literal
1008       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1009
1010       --  If error already reported by Resolve, nothing more to do
1011
1012       if Exp_Btype = Any_Discrete
1013         or else Exp_Btype = Any_Type
1014       then
1015          return;
1016
1017       elsif Exp_Btype = Any_Character then
1018          Error_Msg_N
1019            ("character literal as case expression is ambiguous", Exp);
1020          return;
1021
1022       elsif Ada_Version = Ada_83
1023         and then (Is_Generic_Type (Exp_Btype)
1024                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1025       then
1026          Error_Msg_N
1027            ("(Ada 83) case expression cannot be of a generic type", Exp);
1028          return;
1029       end if;
1030
1031       --  If the case expression is a formal object of mode in out, then
1032       --  treat it as having a nonstatic subtype by forcing use of the base
1033       --  type (which has to get passed to Check_Case_Choices below).  Also
1034       --  use base type when the case expression is parenthesized.
1035
1036       if Paren_Count (Exp) > 0
1037         or else (Is_Entity_Name (Exp)
1038                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1039       then
1040          Exp_Type := Exp_Btype;
1041       end if;
1042
1043       --  Call instantiated Analyze_Choices which does the rest of the work
1044
1045       Analyze_Choices
1046         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
1047
1048       if Exp_Type = Universal_Integer and then not Others_Present then
1049          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1050       end if;
1051
1052       --  If all our exits were blocked by unconditional transfers of control,
1053       --  then the entire CASE statement acts as an unconditional transfer of
1054       --  control, so treat it like one, and check unreachable code. Skip this
1055       --  test if we had serious errors preventing any statement analysis.
1056
1057       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1058          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1059          Check_Unreachable_Code (N);
1060       else
1061          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1062       end if;
1063
1064       if not Expander_Active
1065         and then Compile_Time_Known_Value (Expression (N))
1066         and then Serious_Errors_Detected = 0
1067       then
1068          declare
1069             Chosen : constant Node_Id := Find_Static_Alternative (N);
1070             Alt    : Node_Id;
1071
1072          begin
1073             Alt := First (Alternatives (N));
1074
1075             while Present (Alt) loop
1076                if Alt /= Chosen then
1077                   Remove_Warning_Messages (Statements (Alt));
1078                end if;
1079
1080                Next (Alt);
1081             end loop;
1082          end;
1083       end if;
1084    end Analyze_Case_Statement;
1085
1086    ----------------------------
1087    -- Analyze_Exit_Statement --
1088    ----------------------------
1089
1090    --  If the exit includes a name, it must be the name of a currently open
1091    --  loop. Otherwise there must be an innermost open loop on the stack,
1092    --  to which the statement implicitly refers.
1093
1094    procedure Analyze_Exit_Statement (N : Node_Id) is
1095       Target   : constant Node_Id := Name (N);
1096       Cond     : constant Node_Id := Condition (N);
1097       Scope_Id : Entity_Id;
1098       U_Name   : Entity_Id;
1099       Kind     : Entity_Kind;
1100
1101    begin
1102       if No (Cond) then
1103          Check_Unreachable_Code (N);
1104       end if;
1105
1106       if Present (Target) then
1107          Analyze (Target);
1108          U_Name := Entity (Target);
1109
1110          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1111             Error_Msg_N ("invalid loop name in exit statement", N);
1112             return;
1113          else
1114             Set_Has_Exit (U_Name);
1115          end if;
1116
1117       else
1118          U_Name := Empty;
1119       end if;
1120
1121       for J in reverse 0 .. Scope_Stack.Last loop
1122          Scope_Id := Scope_Stack.Table (J).Entity;
1123          Kind := Ekind (Scope_Id);
1124
1125          if Kind = E_Loop
1126            and then (No (Target) or else Scope_Id = U_Name) then
1127             Set_Has_Exit (Scope_Id);
1128             exit;
1129
1130          elsif Kind = E_Block
1131            or else Kind = E_Loop
1132            or else Kind = E_Return_Statement
1133          then
1134             null;
1135
1136          else
1137             Error_Msg_N
1138               ("cannot exit from program unit or accept statement", N);
1139             exit;
1140          end if;
1141       end loop;
1142
1143       --  Verify that if present the condition is a Boolean expression
1144
1145       if Present (Cond) then
1146          Analyze_And_Resolve (Cond, Any_Boolean);
1147          Check_Unset_Reference (Cond);
1148       end if;
1149    end Analyze_Exit_Statement;
1150
1151    ----------------------------
1152    -- Analyze_Goto_Statement --
1153    ----------------------------
1154
1155    procedure Analyze_Goto_Statement (N : Node_Id) is
1156       Label       : constant Node_Id := Name (N);
1157       Scope_Id    : Entity_Id;
1158       Label_Scope : Entity_Id;
1159       Label_Ent   : Entity_Id;
1160
1161    begin
1162       Check_Unreachable_Code (N);
1163
1164       Analyze (Label);
1165       Label_Ent := Entity (Label);
1166
1167       --  Ignore previous error
1168
1169       if Label_Ent = Any_Id then
1170          return;
1171
1172       --  We just have a label as the target of a goto
1173
1174       elsif Ekind (Label_Ent) /= E_Label then
1175          Error_Msg_N ("target of goto statement must be a label", Label);
1176          return;
1177
1178       --  Check that the target of the goto is reachable according to Ada
1179       --  scoping rules. Note: the special gotos we generate for optimizing
1180       --  local handling of exceptions would violate these rules, but we mark
1181       --  such gotos as analyzed when built, so this code is never entered.
1182
1183       elsif not Reachable (Label_Ent) then
1184          Error_Msg_N ("target of goto statement is not reachable", Label);
1185          return;
1186       end if;
1187
1188       --  Here if goto passes initial validity checks
1189
1190       Label_Scope := Enclosing_Scope (Label_Ent);
1191
1192       for J in reverse 0 .. Scope_Stack.Last loop
1193          Scope_Id := Scope_Stack.Table (J).Entity;
1194
1195          if Label_Scope = Scope_Id
1196            or else (Ekind (Scope_Id) /= E_Block
1197                      and then Ekind (Scope_Id) /= E_Loop
1198                      and then Ekind (Scope_Id) /= E_Return_Statement)
1199          then
1200             if Scope_Id /= Label_Scope then
1201                Error_Msg_N
1202                  ("cannot exit from program unit or accept statement", N);
1203             end if;
1204
1205             return;
1206          end if;
1207       end loop;
1208
1209       raise Program_Error;
1210    end Analyze_Goto_Statement;
1211
1212    --------------------------
1213    -- Analyze_If_Statement --
1214    --------------------------
1215
1216    --  A special complication arises in the analysis of if statements
1217
1218    --  The expander has circuitry to completely delete code that it
1219    --  can tell will not be executed (as a result of compile time known
1220    --  conditions). In the analyzer, we ensure that code that will be
1221    --  deleted in this manner is analyzed but not expanded. This is
1222    --  obviously more efficient, but more significantly, difficulties
1223    --  arise if code is expanded and then eliminated (e.g. exception
1224    --  table entries disappear). Similarly, itypes generated in deleted
1225    --  code must be frozen from start, because the nodes on which they
1226    --  depend will not be available at the freeze point.
1227
1228    procedure Analyze_If_Statement (N : Node_Id) is
1229       E : Node_Id;
1230
1231       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1232       --  Recursively save value of this global, will be restored on exit
1233
1234       Save_In_Deleted_Code : Boolean;
1235
1236       Del : Boolean := False;
1237       --  This flag gets set True if a True condition has been found,
1238       --  which means that remaining ELSE/ELSIF parts are deleted.
1239
1240       procedure Analyze_Cond_Then (Cnode : Node_Id);
1241       --  This is applied to either the N_If_Statement node itself or
1242       --  to an N_Elsif_Part node. It deals with analyzing the condition
1243       --  and the THEN statements associated with it.
1244
1245       -----------------------
1246       -- Analyze_Cond_Then --
1247       -----------------------
1248
1249       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1250          Cond : constant Node_Id := Condition (Cnode);
1251          Tstm : constant List_Id := Then_Statements (Cnode);
1252
1253       begin
1254          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1255          Analyze_And_Resolve (Cond, Any_Boolean);
1256          Check_Unset_Reference (Cond);
1257          Set_Current_Value_Condition (Cnode);
1258
1259          --  If already deleting, then just analyze then statements
1260
1261          if Del then
1262             Analyze_Statements (Tstm);
1263
1264          --  Compile time known value, not deleting yet
1265
1266          elsif Compile_Time_Known_Value (Cond) then
1267             Save_In_Deleted_Code := In_Deleted_Code;
1268
1269             --  If condition is True, then analyze the THEN statements
1270             --  and set no expansion for ELSE and ELSIF parts.
1271
1272             if Is_True (Expr_Value (Cond)) then
1273                Analyze_Statements (Tstm);
1274                Del := True;
1275                Expander_Mode_Save_And_Set (False);
1276                In_Deleted_Code := True;
1277
1278             --  If condition is False, analyze THEN with expansion off
1279
1280             else -- Is_False (Expr_Value (Cond))
1281                Expander_Mode_Save_And_Set (False);
1282                In_Deleted_Code := True;
1283                Analyze_Statements (Tstm);
1284                Expander_Mode_Restore;
1285                In_Deleted_Code := Save_In_Deleted_Code;
1286             end if;
1287
1288          --  Not known at compile time, not deleting, normal analysis
1289
1290          else
1291             Analyze_Statements (Tstm);
1292          end if;
1293       end Analyze_Cond_Then;
1294
1295    --  Start of Analyze_If_Statement
1296
1297    begin
1298       --  Initialize exit count for else statements. If there is no else
1299       --  part, this count will stay non-zero reflecting the fact that the
1300       --  uncovered else case is an unblocked exit.
1301
1302       Unblocked_Exit_Count := 1;
1303       Analyze_Cond_Then (N);
1304
1305       --  Now to analyze the elsif parts if any are present
1306
1307       if Present (Elsif_Parts (N)) then
1308          E := First (Elsif_Parts (N));
1309          while Present (E) loop
1310             Analyze_Cond_Then (E);
1311             Next (E);
1312          end loop;
1313       end if;
1314
1315       if Present (Else_Statements (N)) then
1316          Analyze_Statements (Else_Statements (N));
1317       end if;
1318
1319       --  If all our exits were blocked by unconditional transfers of control,
1320       --  then the entire IF statement acts as an unconditional transfer of
1321       --  control, so treat it like one, and check unreachable code.
1322
1323       if Unblocked_Exit_Count = 0 then
1324          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1325          Check_Unreachable_Code (N);
1326       else
1327          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1328       end if;
1329
1330       if Del then
1331          Expander_Mode_Restore;
1332          In_Deleted_Code := Save_In_Deleted_Code;
1333       end if;
1334
1335       if not Expander_Active
1336         and then Compile_Time_Known_Value (Condition (N))
1337         and then Serious_Errors_Detected = 0
1338       then
1339          if Is_True (Expr_Value (Condition (N))) then
1340             Remove_Warning_Messages (Else_Statements (N));
1341
1342             if Present (Elsif_Parts (N)) then
1343                E := First (Elsif_Parts (N));
1344
1345                while Present (E) loop
1346                   Remove_Warning_Messages (Then_Statements (E));
1347                   Next (E);
1348                end loop;
1349             end if;
1350
1351          else
1352             Remove_Warning_Messages (Then_Statements (N));
1353          end if;
1354       end if;
1355    end Analyze_If_Statement;
1356
1357    ----------------------------------------
1358    -- Analyze_Implicit_Label_Declaration --
1359    ----------------------------------------
1360
1361    --  An implicit label declaration is generated in the innermost
1362    --  enclosing declarative part. This is done for labels as well as
1363    --  block and loop names.
1364
1365    --  Note: any changes in this routine may need to be reflected in
1366    --  Analyze_Label_Entity.
1367
1368    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1369       Id : constant Node_Id := Defining_Identifier (N);
1370    begin
1371       Enter_Name          (Id);
1372       Set_Ekind           (Id, E_Label);
1373       Set_Etype           (Id, Standard_Void_Type);
1374       Set_Enclosing_Scope (Id, Current_Scope);
1375    end Analyze_Implicit_Label_Declaration;
1376
1377    ------------------------------
1378    -- Analyze_Iteration_Scheme --
1379    ------------------------------
1380
1381    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1382
1383       procedure Process_Bounds (R : Node_Id);
1384       --  If the iteration is given by a range, create temporaries and
1385       --  assignment statements block to capture the bounds and perform
1386       --  required finalization actions in case a bound includes a function
1387       --  call that uses the temporary stack. We first pre-analyze a copy of
1388       --  the range in order to determine the expected type, and analyze and
1389       --  resolve the original bounds.
1390
1391       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1392       --  If the bounds are given by a 'Range reference on a function call
1393       --  that returns a controlled array, introduce an explicit declaration
1394       --  to capture the bounds, so that the function result can be finalized
1395       --  in timely fashion.
1396
1397       --------------------
1398       -- Process_Bounds --
1399       --------------------
1400
1401       procedure Process_Bounds (R : Node_Id) is
1402          Loc          : constant Source_Ptr := Sloc (N);
1403          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1404          Lo           : constant Node_Id := Low_Bound  (R);
1405          Hi           : constant Node_Id := High_Bound (R);
1406          New_Lo_Bound : Node_Id := Empty;
1407          New_Hi_Bound : Node_Id := Empty;
1408          Typ          : Entity_Id;
1409          Save_Analysis : Boolean;
1410
1411          function One_Bound
1412            (Original_Bound : Node_Id;
1413             Analyzed_Bound : Node_Id) return Node_Id;
1414          --  Create one declaration followed by one assignment statement
1415          --  to capture the value of bound. We create a separate assignment
1416          --  in order to force the creation of a block in case the bound
1417          --  contains a call that uses the secondary stack.
1418
1419          ---------------
1420          -- One_Bound --
1421          ---------------
1422
1423          function One_Bound
1424            (Original_Bound : Node_Id;
1425             Analyzed_Bound : Node_Id) return Node_Id
1426          is
1427             Assign : Node_Id;
1428             Id     : Entity_Id;
1429             Decl   : Node_Id;
1430
1431          begin
1432             --  If the bound is a constant or an object, no need for a separate
1433             --  declaration. If the bound is the result of previous expansion
1434             --  it is already analyzed and should not be modified. Note that
1435             --  the Bound will be resolved later, if needed, as part of the
1436             --  call to Make_Index (literal bounds may need to be resolved to
1437             --  type Integer).
1438
1439             if Analyzed (Original_Bound) then
1440                return Original_Bound;
1441
1442             elsif Nkind (Analyzed_Bound) = N_Integer_Literal
1443               or else Nkind (Analyzed_Bound) = N_Character_Literal
1444               or else Is_Entity_Name (Analyzed_Bound)
1445             then
1446                Analyze_And_Resolve (Original_Bound, Typ);
1447                return Original_Bound;
1448
1449             else
1450                Analyze_And_Resolve (Original_Bound, Typ);
1451             end if;
1452
1453             Id :=
1454               Make_Defining_Identifier (Loc,
1455                 Chars => New_Internal_Name ('S'));
1456
1457             Decl :=
1458               Make_Object_Declaration (Loc,
1459                 Defining_Identifier => Id,
1460                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1461
1462             Insert_Before (Parent (N), Decl);
1463             Analyze (Decl);
1464
1465             Assign :=
1466               Make_Assignment_Statement (Loc,
1467                 Name        => New_Occurrence_Of (Id, Loc),
1468                 Expression  => Relocate_Node (Original_Bound));
1469
1470             Insert_Before (Parent (N), Assign);
1471             Analyze (Assign);
1472
1473             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1474
1475             if Nkind (Assign) = N_Assignment_Statement then
1476                return Expression (Assign);
1477             else
1478                return Original_Bound;
1479             end if;
1480          end One_Bound;
1481
1482       --  Start of processing for Process_Bounds
1483
1484       begin
1485          --  Determine expected type of range by analyzing separate copy
1486          --  Do the analysis and resolution of the copy of the bounds with
1487          --  expansion disabled, to prevent the generation of finalization
1488          --  actions on each bound. This prevents memory leaks when the
1489          --  bounds contain calls to functions returning controlled arrays.
1490
1491          Set_Parent (R_Copy, Parent (R));
1492          Save_Analysis := Full_Analysis;
1493          Full_Analysis := False;
1494          Expander_Mode_Save_And_Set (False);
1495
1496          Analyze (R_Copy);
1497
1498          if Is_Overloaded (R_Copy) then
1499
1500             --  Apply preference rules for range of predefined integer types,
1501             --  or diagnose true ambiguity.
1502
1503             declare
1504                I     : Interp_Index;
1505                It    : Interp;
1506                Found : Entity_Id := Empty;
1507
1508             begin
1509                Get_First_Interp (R_Copy, I, It);
1510                while Present (It.Typ) loop
1511                   if Is_Discrete_Type (It.Typ) then
1512                      if No (Found) then
1513                         Found := It.Typ;
1514                      else
1515                         if Scope (Found) = Standard_Standard then
1516                            null;
1517
1518                         elsif Scope (It.Typ) = Standard_Standard then
1519                            Found := It.Typ;
1520
1521                         else
1522                            --  Both of them are user-defined
1523
1524                            Error_Msg_N
1525                              ("ambiguous bounds in range of iteration",
1526                                R_Copy);
1527                            Error_Msg_N ("\possible interpretations:", R_Copy);
1528                            Error_Msg_NE ("\\} ", R_Copy, Found);
1529                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1530                            exit;
1531                         end if;
1532                      end if;
1533                   end if;
1534
1535                   Get_Next_Interp (I, It);
1536                end loop;
1537             end;
1538          end if;
1539
1540          Resolve (R_Copy);
1541          Expander_Mode_Restore;
1542          Full_Analysis := Save_Analysis;
1543
1544          Typ := Etype (R_Copy);
1545
1546          --  If the type of the discrete range is Universal_Integer, then
1547          --  the bound's type must be resolved to Integer, and any object
1548          --  used to hold the bound must also have type Integer, unless the
1549          --  literal bounds are constant-folded expressions that carry a user-
1550          --  defined type.
1551
1552          if Typ = Universal_Integer then
1553             if Nkind (Lo) = N_Integer_Literal
1554               and then Present (Etype (Lo))
1555               and then Scope (Etype (Lo)) /= Standard_Standard
1556             then
1557                Typ := Etype (Lo);
1558
1559             elsif Nkind (Hi) = N_Integer_Literal
1560               and then Present (Etype (Hi))
1561               and then Scope (Etype (Hi)) /= Standard_Standard
1562             then
1563                Typ := Etype (Hi);
1564
1565             else
1566                Typ := Standard_Integer;
1567             end if;
1568          end if;
1569
1570          Set_Etype (R, Typ);
1571
1572          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1573          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1574
1575          --  Propagate staticness to loop range itself, in case the
1576          --  corresponding subtype is static.
1577
1578          if New_Lo_Bound /= Lo
1579            and then Is_Static_Expression (New_Lo_Bound)
1580          then
1581             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1582          end if;
1583
1584          if New_Hi_Bound /= Hi
1585            and then Is_Static_Expression (New_Hi_Bound)
1586          then
1587             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1588          end if;
1589       end Process_Bounds;
1590
1591       --------------------------------------
1592       -- Check_Controlled_Array_Attribute --
1593       --------------------------------------
1594
1595       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1596       begin
1597          if Nkind (DS) = N_Attribute_Reference
1598             and then Is_Entity_Name (Prefix (DS))
1599             and then Ekind (Entity (Prefix (DS))) = E_Function
1600             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1601             and then
1602               Is_Controlled (
1603                 Component_Type (Etype (Entity (Prefix (DS)))))
1604             and then Expander_Active
1605          then
1606             declare
1607                Loc  : constant Source_Ptr := Sloc (N);
1608                Arr  : constant Entity_Id :=
1609                         Etype (Entity (Prefix (DS)));
1610                Indx : constant Entity_Id :=
1611                         Base_Type (Etype (First_Index (Arr)));
1612                Subt : constant Entity_Id :=
1613                         Make_Defining_Identifier
1614                           (Loc, New_Internal_Name ('S'));
1615                Decl : Node_Id;
1616
1617             begin
1618                Decl :=
1619                  Make_Subtype_Declaration (Loc,
1620                    Defining_Identifier => Subt,
1621                    Subtype_Indication  =>
1622                       Make_Subtype_Indication (Loc,
1623                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1624                         Constraint =>
1625                           Make_Range_Constraint (Loc,
1626                             Relocate_Node (DS))));
1627                Insert_Before (Parent (N), Decl);
1628                Analyze (Decl);
1629
1630                Rewrite (DS,
1631                   Make_Attribute_Reference (Loc,
1632                     Prefix => New_Reference_To (Subt, Loc),
1633                     Attribute_Name => Attribute_Name (DS)));
1634                Analyze (DS);
1635             end;
1636          end if;
1637       end Check_Controlled_Array_Attribute;
1638
1639    --  Start of processing for Analyze_Iteration_Scheme
1640
1641    begin
1642       --  For an infinite loop, there is no iteration scheme
1643
1644       if No (N) then
1645          return;
1646
1647       else
1648          declare
1649             Cond : constant Node_Id := Condition (N);
1650
1651          begin
1652             --  For WHILE loop, verify that the condition is a Boolean
1653             --  expression and resolve and check it.
1654
1655             if Present (Cond) then
1656                Analyze_And_Resolve (Cond, Any_Boolean);
1657                Check_Unset_Reference (Cond);
1658                Set_Current_Value_Condition (N);
1659                return;
1660
1661             --  Else we have a FOR loop
1662
1663             else
1664                declare
1665                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1666                   Id : constant Entity_Id := Defining_Identifier (LP);
1667                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1668
1669                begin
1670                   Enter_Name (Id);
1671
1672                   --  We always consider the loop variable to be referenced,
1673                   --  since the loop may be used just for counting purposes.
1674
1675                   Generate_Reference (Id, N, ' ');
1676
1677                   --  Check for case of loop variable hiding a local
1678                   --  variable (used later on to give a nice warning
1679                   --  if the hidden variable is never assigned).
1680
1681                   declare
1682                      H : constant Entity_Id := Homonym (Id);
1683                   begin
1684                      if Present (H)
1685                        and then Enclosing_Dynamic_Scope (H) =
1686                                 Enclosing_Dynamic_Scope (Id)
1687                        and then Ekind (H) = E_Variable
1688                        and then Is_Discrete_Type (Etype (H))
1689                      then
1690                         Set_Hiding_Loop_Variable (H, Id);
1691                      end if;
1692                   end;
1693
1694                   --  Now analyze the subtype definition. If it is
1695                   --  a range, create temporaries for bounds.
1696
1697                   if Nkind (DS) = N_Range
1698                     and then Expander_Active
1699                   then
1700                      Process_Bounds (DS);
1701                   else
1702                      Analyze (DS);
1703                   end if;
1704
1705                   if DS = Error then
1706                      return;
1707                   end if;
1708
1709                   --  The subtype indication may denote the completion
1710                   --  of an incomplete type declaration.
1711
1712                   if Is_Entity_Name (DS)
1713                     and then Present (Entity (DS))
1714                     and then Is_Type (Entity (DS))
1715                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1716                   then
1717                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1718                      Set_Etype  (DS, Entity (DS));
1719                   end if;
1720
1721                   if not Is_Discrete_Type (Etype (DS)) then
1722                      Wrong_Type (DS, Any_Discrete);
1723                      Set_Etype (DS, Any_Type);
1724                   end if;
1725
1726                   Check_Controlled_Array_Attribute (DS);
1727
1728                   Make_Index (DS, LP);
1729
1730                   Set_Ekind          (Id, E_Loop_Parameter);
1731                   Set_Etype          (Id, Etype (DS));
1732                   Set_Is_Known_Valid (Id, True);
1733
1734                   --  The loop is not a declarative part, so the only entity
1735                   --  declared "within" must be frozen explicitly.
1736
1737                   declare
1738                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1739                   begin
1740                      if Is_Non_Empty_List (Flist) then
1741                         Insert_Actions (N, Flist);
1742                      end if;
1743                   end;
1744
1745                   --  Check for null or possibly null range and issue warning.
1746                   --  We suppress such messages in generic templates and
1747                   --  instances, because in practice they tend to be dubious
1748                   --  in these cases.
1749
1750                   if Nkind (DS) = N_Range
1751                     and then Comes_From_Source (N)
1752                   then
1753                      declare
1754                         L : constant Node_Id := Low_Bound  (DS);
1755                         H : constant Node_Id := High_Bound (DS);
1756
1757                         Llo : Uint;
1758                         Lhi : Uint;
1759                         LOK : Boolean;
1760                         Hlo : Uint;
1761                         Hhi : Uint;
1762                         HOK : Boolean;
1763
1764                      begin
1765                         Determine_Range (L, LOK, Llo, Lhi);
1766                         Determine_Range (H, HOK, Hlo, Hhi);
1767
1768                         --  If range of loop is null, issue warning
1769
1770                         if (LOK and HOK) and then Llo > Hhi then
1771
1772                            --  Suppress the warning if inside a generic
1773                            --  template or instance, since in practice
1774                            --  they tend to be dubious in these cases since
1775                            --  they can result from intended parametrization.
1776
1777                            if not Inside_A_Generic
1778                               and then not In_Instance
1779                            then
1780                               Error_Msg_N
1781                                 ("?loop range is null, loop will not execute",
1782                                  DS);
1783                            end if;
1784
1785                            --  Since we know the range of the loop is null,
1786                            --  set the appropriate flag to suppress any
1787                            --  warnings that would otherwise be issued in
1788                            --  the body of the loop that will not execute.
1789                            --  We do this even in the generic case, since
1790                            --  if it is dubious to warn on the null loop
1791                            --  itself, it is certainly dubious to warn for
1792                            --  conditions that occur inside it!
1793
1794                            Set_Is_Null_Loop (Parent (N));
1795
1796                         --  The other case for a warning is a reverse loop
1797                         --  where the upper bound is the integer literal
1798                         --  zero or one, and the lower bound can be positive.
1799
1800                         --  For example, we have
1801
1802                         --     for J in reverse N .. 1 loop
1803
1804                         --  In practice, this is very likely to be a case
1805                         --  of reversing the bounds incorrectly in the range.
1806
1807                         elsif Reverse_Present (LP)
1808                           and then Nkind (Original_Node (H)) =
1809                                                           N_Integer_Literal
1810                           and then (Intval (H) = Uint_0
1811                                       or else
1812                                     Intval (H) = Uint_1)
1813                           and then Lhi > Hhi
1814                         then
1815                            Error_Msg_N ("?loop range may be null", DS);
1816                            Error_Msg_N ("\?bounds may be wrong way round", DS);
1817                         end if;
1818                      end;
1819                   end if;
1820                end;
1821             end if;
1822          end;
1823       end if;
1824    end Analyze_Iteration_Scheme;
1825
1826    -------------------
1827    -- Analyze_Label --
1828    -------------------
1829
1830    --  Note: the semantic work required for analyzing labels (setting them as
1831    --  reachable) was done in a prepass through the statements in the block,
1832    --  so that forward gotos would be properly handled. See Analyze_Statements
1833    --  for further details. The only processing required here is to deal with
1834    --  optimizations that depend on an assumption of sequential control flow,
1835    --  since of course the occurrence of a label breaks this assumption.
1836
1837    procedure Analyze_Label (N : Node_Id) is
1838       pragma Warnings (Off, N);
1839    begin
1840       Kill_Current_Values;
1841    end Analyze_Label;
1842
1843    --------------------------
1844    -- Analyze_Label_Entity --
1845    --------------------------
1846
1847    procedure Analyze_Label_Entity (E : Entity_Id) is
1848    begin
1849       Set_Ekind           (E, E_Label);
1850       Set_Etype           (E, Standard_Void_Type);
1851       Set_Enclosing_Scope (E, Current_Scope);
1852       Set_Reachable       (E, True);
1853    end Analyze_Label_Entity;
1854
1855    ----------------------------
1856    -- Analyze_Loop_Statement --
1857    ----------------------------
1858
1859    procedure Analyze_Loop_Statement (N : Node_Id) is
1860       Loop_Statement : constant Node_Id := N;
1861
1862       Id   : constant Node_Id := Identifier (Loop_Statement);
1863       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
1864       Ent  : Entity_Id;
1865
1866    begin
1867       if Present (Id) then
1868
1869          --  Make name visible, e.g. for use in exit statements. Loop
1870          --  labels are always considered to be referenced.
1871
1872          Analyze (Id);
1873          Ent := Entity (Id);
1874          Generate_Reference  (Ent, Loop_Statement, ' ');
1875          Generate_Definition (Ent);
1876
1877          --  If we found a label, mark its type. If not, ignore it, since it
1878          --  means we have a conflicting declaration, which would already have
1879          --  been diagnosed at declaration time. Set Label_Construct of the
1880          --  implicit label declaration, which is not created by the parser
1881          --  for generic units.
1882
1883          if Ekind (Ent) = E_Label then
1884             Set_Ekind (Ent, E_Loop);
1885
1886             if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
1887                Set_Label_Construct (Parent (Ent), Loop_Statement);
1888             end if;
1889          end if;
1890
1891       --  Case of no identifier present
1892
1893       else
1894          Ent :=
1895            New_Internal_Entity
1896              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
1897          Set_Etype (Ent,  Standard_Void_Type);
1898          Set_Parent (Ent, Loop_Statement);
1899       end if;
1900
1901       --  Kill current values on entry to loop, since statements in body
1902       --  of loop may have been executed before the loop is entered.
1903       --  Similarly we kill values after the loop, since we do not know
1904       --  that the body of the loop was executed.
1905
1906       Kill_Current_Values;
1907       Push_Scope (Ent);
1908       Analyze_Iteration_Scheme (Iter);
1909       Analyze_Statements (Statements (Loop_Statement));
1910       Process_End_Label (Loop_Statement, 'e', Ent);
1911       End_Scope;
1912       Kill_Current_Values;
1913       Check_Infinite_Loop_Warning (N);
1914    end Analyze_Loop_Statement;
1915
1916    ----------------------------
1917    -- Analyze_Null_Statement --
1918    ----------------------------
1919
1920    --  Note: the semantics of the null statement is implemented by a single
1921    --  null statement, too bad everything isn't as simple as this!
1922
1923    procedure Analyze_Null_Statement (N : Node_Id) is
1924       pragma Warnings (Off, N);
1925    begin
1926       null;
1927    end Analyze_Null_Statement;
1928
1929    ------------------------
1930    -- Analyze_Statements --
1931    ------------------------
1932
1933    procedure Analyze_Statements (L : List_Id) is
1934       S   : Node_Id;
1935       Lab : Entity_Id;
1936
1937    begin
1938       --  The labels declared in the statement list are reachable from
1939       --  statements in the list. We do this as a prepass so that any
1940       --  goto statement will be properly flagged if its target is not
1941       --  reachable. This is not required, but is nice behavior!
1942
1943       S := First (L);
1944       while Present (S) loop
1945          if Nkind (S) = N_Label then
1946             Analyze (Identifier (S));
1947             Lab := Entity (Identifier (S));
1948
1949             --  If we found a label mark it as reachable
1950
1951             if Ekind (Lab) = E_Label then
1952                Generate_Definition (Lab);
1953                Set_Reachable (Lab);
1954
1955                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
1956                   Set_Label_Construct (Parent (Lab), S);
1957                end if;
1958
1959             --  If we failed to find a label, it means the implicit declaration
1960             --  of the label was hidden.  A for-loop parameter can do this to
1961             --  a label with the same name inside the loop, since the implicit
1962             --  label declaration is in the innermost enclosing body or block
1963             --  statement.
1964
1965             else
1966                Error_Msg_Sloc := Sloc (Lab);
1967                Error_Msg_N
1968                  ("implicit label declaration for & is hidden#",
1969                   Identifier (S));
1970             end if;
1971          end if;
1972
1973          Next (S);
1974       end loop;
1975
1976       --  Perform semantic analysis on all statements
1977
1978       Conditional_Statements_Begin;
1979
1980       S := First (L);
1981       while Present (S) loop
1982          Analyze (S);
1983          Next (S);
1984       end loop;
1985
1986       Conditional_Statements_End;
1987
1988       --  Make labels unreachable. Visibility is not sufficient, because
1989       --  labels in one if-branch for example are not reachable from the
1990       --  other branch, even though their declarations are in the enclosing
1991       --  declarative part.
1992
1993       S := First (L);
1994       while Present (S) loop
1995          if Nkind (S) = N_Label then
1996             Set_Reachable (Entity (Identifier (S)), False);
1997          end if;
1998
1999          Next (S);
2000       end loop;
2001    end Analyze_Statements;
2002
2003    ----------------------------
2004    -- Check_Unreachable_Code --
2005    ----------------------------
2006
2007    procedure Check_Unreachable_Code (N : Node_Id) is
2008       Error_Loc : Source_Ptr;
2009       P         : Node_Id;
2010
2011    begin
2012       if Is_List_Member (N)
2013         and then Comes_From_Source (N)
2014       then
2015          declare
2016             Nxt : Node_Id;
2017
2018          begin
2019             Nxt := Original_Node (Next (N));
2020
2021             --  If a label follows us, then we never have dead code, since
2022             --  someone could branch to the label, so we just ignore it.
2023
2024             if Nkind (Nxt) = N_Label then
2025                return;
2026
2027             --  Otherwise see if we have a real statement following us
2028
2029             elsif Present (Nxt)
2030               and then Comes_From_Source (Nxt)
2031               and then Is_Statement (Nxt)
2032             then
2033                --  Special very annoying exception. If we have a return that
2034                --  follows a raise, then we allow it without a warning, since
2035                --  the Ada RM annoyingly requires a useless return here!
2036
2037                if Nkind (Original_Node (N)) /= N_Raise_Statement
2038                  or else Nkind (Nxt) /= N_Return_Statement
2039                then
2040                   --  The rather strange shenanigans with the warning message
2041                   --  here reflects the fact that Kill_Dead_Code is very good
2042                   --  at removing warnings in deleted code, and this is one
2043                   --  warning we would prefer NOT to have removed.
2044
2045                   Error_Loc := Sloc (Nxt);
2046
2047                   --  If we have unreachable code, analyze and remove the
2048                   --  unreachable code, since it is useless and we don't
2049                   --  want to generate junk warnings.
2050
2051                   --  We skip this step if we are not in code generation mode.
2052                   --  This is the one case where we remove dead code in the
2053                   --  semantics as opposed to the expander, and we do not want
2054                   --  to remove code if we are not in code generation mode,
2055                   --  since this messes up the ASIS trees.
2056
2057                   --  Note that one might react by moving the whole circuit to
2058                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2059
2060                   if Operating_Mode = Generate_Code then
2061                      loop
2062                         Nxt := Next (N);
2063
2064                         --  Quit deleting when we have nothing more to delete
2065                         --  or if we hit a label (since someone could transfer
2066                         --  control to a label, so we should not delete it).
2067
2068                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2069
2070                         --  Statement/declaration is to be deleted
2071
2072                         Analyze (Nxt);
2073                         Remove (Nxt);
2074                         Kill_Dead_Code (Nxt);
2075                      end loop;
2076                   end if;
2077
2078                   --  Now issue the warning
2079
2080                   Error_Msg ("?unreachable code", Error_Loc);
2081                end if;
2082
2083             --  If the unconditional transfer of control instruction is
2084             --  the last statement of a sequence, then see if our parent
2085             --  is one of the constructs for which we count unblocked exits,
2086             --  and if so, adjust the count.
2087
2088             else
2089                P := Parent (N);
2090
2091                --  Statements in THEN part or ELSE part of IF statement
2092
2093                if Nkind (P) = N_If_Statement then
2094                   null;
2095
2096                --  Statements in ELSIF part of an IF statement
2097
2098                elsif Nkind (P) = N_Elsif_Part then
2099                   P := Parent (P);
2100                   pragma Assert (Nkind (P) = N_If_Statement);
2101
2102                --  Statements in CASE statement alternative
2103
2104                elsif Nkind (P) = N_Case_Statement_Alternative then
2105                   P := Parent (P);
2106                   pragma Assert (Nkind (P) = N_Case_Statement);
2107
2108                --  Statements in body of block
2109
2110                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2111                  and then Nkind (Parent (P)) = N_Block_Statement
2112                then
2113                   null;
2114
2115                --  Statements in exception handler in a block
2116
2117                elsif Nkind (P) = N_Exception_Handler
2118                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2119                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2120                then
2121                   null;
2122
2123                --  None of these cases, so return
2124
2125                else
2126                   return;
2127                end if;
2128
2129                --  This was one of the cases we are looking for (i.e. the
2130                --  parent construct was IF, CASE or block) so decrement count.
2131
2132                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2133             end if;
2134          end;
2135       end if;
2136    end Check_Unreachable_Code;
2137
2138 end Sem_Ch5;