gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Case; use Sem_Case;
  42 with Sem_Ch3;  use Sem_Ch3;
  43 with Sem_Ch8;  use Sem_Ch8;
  44 with Sem_Disp; use Sem_Disp;
  45 with Sem_Elab; use Sem_Elab;
  46 with Sem_Eval; use Sem_Eval;
  47 with Sem_Res;  use Sem_Res;
  48 with Sem_Type; use Sem_Type;
  49 with Sem_Util; use Sem_Util;
  50 with Sem_Warn; use Sem_Warn;
  51 with Snames;   use Snames;
  52 with Stand;    use Stand;
  53 with Sinfo;    use Sinfo;
  54 with Targparm; use Targparm;
  55 with Tbuild;   use Tbuild;
  56 with Uintp;    use Uintp;
  57
  58 package body Sem_Ch5 is
  59
  60    Unblocked_Exit_Count : Nat := 0;
  61    --  This variable is used when processing if statements, case statements,
  62    --  and block statements. It counts the number of exit points that are not
  63    --  blocked by unconditional transfer instructions: for IF and CASE, these
  64    --  are the branches of the conditional; for a block, they are the statement
  65    --  sequence of the block, and the statement sequences of any exception
  66    --  handlers that are part of the block. When processing is complete, if
  67    --  this count is zero, it means that control cannot fall through the IF,
  68    --  CASE or block statement. This is used for the generation of warning
  69    --  messages. This variable is recursively saved on entry to processing the
  70    --  construct, and restored on exit.
  71
  72    -----------------------
  73    -- Local Subprograms --
  74    -----------------------
  75
  76    procedure Analyze_Iteration_Scheme (N : Node_Id);
  77
  78    ------------------------
  79    -- Analyze_Assignment --
  80    ------------------------
  81
  82    procedure Analyze_Assignment (N : Node_Id) is
  83       Lhs  : constant Node_Id := Name (N);
  84       Rhs  : constant Node_Id := Expression (N);
  85       T1   : Entity_Id;
  86       T2   : Entity_Id;
  87       Decl : Node_Id;
  88
  89       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  90       --  N is the node for the left hand side of an assignment, and it
  91       --  is not a variable. This routine issues an appropriate diagnostic.
  92
  93       procedure Kill_Lhs;
  94       --  This is called to kill current value settings of a simple variable
  95       --  on the left hand side. We call it if we find any error in analyzing
  96       --  the assignment, and at the end of processing before setting any new
  97       --  current values in place.
  98
  99       procedure Set_Assignment_Type
 100         (Opnd      : Node_Id;
 101          Opnd_Type : in out Entity_Id);
 102       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 103       --  is the nominal subtype. This procedure is used to deal with cases
 104       --  where the nominal subtype must be replaced by the actual subtype.
 105
 106       -------------------------------
 107       -- Diagnose_Non_Variable_Lhs --
 108       -------------------------------
 109
 110       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 111       begin
 112          --  Not worth posting another error if left hand side already
 113          --  flagged as being illegal in some respect.
 114
 115          if Error_Posted (N) then
 116             return;
 117
 118          --  Some special bad cases of entity names
 119
 120          elsif Is_Entity_Name (N) then
 121             if Ekind (Entity (N)) = E_In_Parameter then
 122                Error_Msg_N
 123                  ("assignment to IN mode parameter not allowed", N);
 124
 125             --  Private declarations in a protected object are turned into
 126             --  constants when compiling a protected function.
 127
 128             elsif Present (Scope (Entity (N)))
 129               and then Is_Protected_Type (Scope (Entity (N)))
 130               and then
 131                 (Ekind (Current_Scope) = E_Function
 132                   or else
 133                  Ekind (Enclosing_Dynamic_Scope (Current_Scope)) = E_Function)
 134             then
 135                Error_Msg_N
 136                  ("protected function cannot modify protected object", N);
 137
 138             elsif Ekind (Entity (N)) = E_Loop_Parameter then
 139                Error_Msg_N
 140                  ("assignment to loop parameter not allowed", N);
 141
 142             else
 143                Error_Msg_N
 144                  ("left hand side of assignment must be a variable", N);
 145             end if;
 146
 147          --  For indexed components or selected components, test prefix
 148
 149          elsif Nkind (N) = N_Indexed_Component then
 150             Diagnose_Non_Variable_Lhs (Prefix (N));
 151
 152          --  Another special case for assignment to discriminant
 153
 154          elsif Nkind (N) = N_Selected_Component then
 155             if Present (Entity (Selector_Name (N)))
 156               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 157             then
 158                Error_Msg_N
 159                  ("assignment to discriminant not allowed", N);
 160             else
 161                Diagnose_Non_Variable_Lhs (Prefix (N));
 162             end if;
 163
 164          else
 165             --  If we fall through, we have no special message to issue!
 166
 167             Error_Msg_N ("left hand side of assignment must be a variable", N);
 168          end if;
 169       end Diagnose_Non_Variable_Lhs;
 170
 171       --------------
 172       -- Kill_LHS --
 173       --------------
 174
 175       procedure Kill_Lhs is
 176       begin
 177          if Is_Entity_Name (Lhs) then
 178             declare
 179                Ent : constant Entity_Id := Entity (Lhs);
 180             begin
 181                if Present (Ent) then
 182                   Kill_Current_Values (Ent);
 183                end if;
 184             end;
 185          end if;
 186       end Kill_Lhs;
 187
 188       -------------------------
 189       -- Set_Assignment_Type --
 190       -------------------------
 191
 192       procedure Set_Assignment_Type
 193         (Opnd      : Node_Id;
 194          Opnd_Type : in out Entity_Id)
 195       is
 196       begin
 197          Require_Entity (Opnd);
 198
 199          --  If the assignment operand is an in-out or out parameter, then we
 200          --  get the actual subtype (needed for the unconstrained case).
 201          --  If the operand is the actual in an entry declaration, then within
 202          --  the accept statement it is replaced with a local renaming, which
 203          --  may also have an actual subtype.
 204
 205          if Is_Entity_Name (Opnd)
 206            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 207                       or else Ekind (Entity (Opnd)) =
 208                            E_In_Out_Parameter
 209                       or else Ekind (Entity (Opnd)) =
 210                            E_Generic_In_Out_Parameter
 211                       or else
 212                         (Ekind (Entity (Opnd)) = E_Variable
 213                           and then Nkind (Parent (Entity (Opnd))) =
 214                              N_Object_Renaming_Declaration
 215                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 216                              N_Accept_Statement))
 217          then
 218             Opnd_Type := Get_Actual_Subtype (Opnd);
 219
 220          --  If assignment operand is a component reference, then we get the
 221          --  actual subtype of the component for the unconstrained case.
 222
 223          elsif
 224            (Nkind (Opnd) = N_Selected_Component
 225              or else Nkind (Opnd) = N_Explicit_Dereference)
 226            and then not Is_Unchecked_Union (Opnd_Type)
 227          then
 228             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 229
 230             if Present (Decl) then
 231                Insert_Action (N, Decl);
 232                Mark_Rewrite_Insertion (Decl);
 233                Analyze (Decl);
 234                Opnd_Type := Defining_Identifier (Decl);
 235                Set_Etype (Opnd, Opnd_Type);
 236                Freeze_Itype (Opnd_Type, N);
 237
 238             elsif Is_Constrained (Etype (Opnd)) then
 239                Opnd_Type := Etype (Opnd);
 240             end if;
 241
 242          --  For slice, use the constrained subtype created for the slice
 243
 244          elsif Nkind (Opnd) = N_Slice then
 245             Opnd_Type := Etype (Opnd);
 246          end if;
 247       end Set_Assignment_Type;
 248
 249    --  Start of processing for Analyze_Assignment
 250
 251    begin
 252       Mark_Coextensions (N, Rhs);
 253
 254       Analyze (Rhs);
 255       Analyze (Lhs);
 256
 257       --  Start type analysis for assignment
 258
 259       T1 := Etype (Lhs);
 260
 261       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 262       --  must compute the intersection of the possible types on each side.
 263
 264       if Is_Overloaded (Lhs) then
 265          declare
 266             I  : Interp_Index;
 267             It : Interp;
 268
 269          begin
 270             T1 := Any_Type;
 271             Get_First_Interp (Lhs, I, It);
 272
 273             while Present (It.Typ) loop
 274                if Has_Compatible_Type (Rhs, It.Typ) then
 275                   if T1 /= Any_Type then
 276
 277                      --  An explicit dereference is overloaded if the prefix
 278                      --  is. Try to remove the ambiguity on the prefix, the
 279                      --  error will be posted there if the ambiguity is real.
 280
 281                      if Nkind (Lhs) = N_Explicit_Dereference then
 282                         declare
 283                            PI    : Interp_Index;
 284                            PI1   : Interp_Index := 0;
 285                            PIt   : Interp;
 286                            Found : Boolean;
 287
 288                         begin
 289                            Found := False;
 290                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 291
 292                            while Present (PIt.Typ) loop
 293                               if Is_Access_Type (PIt.Typ)
 294                                 and then Has_Compatible_Type
 295                                            (Rhs, Designated_Type (PIt.Typ))
 296                               then
 297                                  if Found then
 298                                     PIt :=
 299                                       Disambiguate (Prefix (Lhs),
 300                                         PI1, PI, Any_Type);
 301
 302                                     if PIt = No_Interp then
 303                                        Error_Msg_N
 304                                          ("ambiguous left-hand side"
 305                                             & " in assignment", Lhs);
 306                                        exit;
 307                                     else
 308                                        Resolve (Prefix (Lhs), PIt.Typ);
 309                                     end if;
 310
 311                                     exit;
 312                                  else
 313                                     Found := True;
 314                                     PI1 := PI;
 315                                  end if;
 316                               end if;
 317
 318                               Get_Next_Interp (PI, PIt);
 319                            end loop;
 320                         end;
 321
 322                      else
 323                         Error_Msg_N
 324                           ("ambiguous left-hand side in assignment", Lhs);
 325                         exit;
 326                      end if;
 327                   else
 328                      T1 := It.Typ;
 329                   end if;
 330                end if;
 331
 332                Get_Next_Interp (I, It);
 333             end loop;
 334          end;
 335
 336          if T1 = Any_Type then
 337             Error_Msg_N
 338               ("no valid types for left-hand side for assignment", Lhs);
 339             Kill_Lhs;
 340             return;
 341          end if;
 342       end if;
 343
 344       --  The resulting assignment type is T1, so now we will resolve the
 345       --  left hand side of the assignment using this determined type.
 346
 347       Resolve (Lhs, T1);
 348
 349       --  Cases where Lhs is not a variable
 350
 351       if not Is_Variable (Lhs) then
 352
 353          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 354          --  a protected object.
 355
 356          declare
 357             Ent : Entity_Id;
 358             S   : Entity_Id;
 359
 360          begin
 361             if Ada_Version >= Ada_05 then
 362
 363                --  Handle chains of renamings
 364
 365                Ent := Lhs;
 366                while Nkind (Ent) in N_Has_Entity
 367                  and then Present (Entity (Ent))
 368                  and then Present (Renamed_Object (Entity (Ent)))
 369                loop
 370                   Ent := Renamed_Object (Entity (Ent));
 371                end loop;
 372
 373                if (Nkind (Ent) = N_Attribute_Reference
 374                      and then Attribute_Name (Ent) = Name_Priority)
 375
 376                   --  Renamings of the attribute Priority applied to protected
 377                   --  objects have been previously expanded into calls to the
 378                   --  Get_Ceiling run-time subprogram.
 379
 380                  or else
 381                   (Nkind (Ent) = N_Function_Call
 382                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 383                                 or else
 384                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 385                then
 386                   --  The enclosing subprogram cannot be a protected function
 387
 388                   S := Current_Scope;
 389                   while not (Is_Subprogram (S)
 390                                and then Convention (S) = Convention_Protected)
 391                      and then S /= Standard_Standard
 392                   loop
 393                      S := Scope (S);
 394                   end loop;
 395
 396                   if Ekind (S) = E_Function
 397                     and then Convention (S) = Convention_Protected
 398                   then
 399                      Error_Msg_N
 400                        ("protected function cannot modify protected object",
 401                         Lhs);
 402                   end if;
 403
 404                   --  Changes of the ceiling priority of the protected object
 405                   --  are only effective if the Ceiling_Locking policy is in
 406                   --  effect (AARM D.5.2 (5/2)).
 407
 408                   if Locking_Policy /= 'C' then
 409                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 410                                   "no effect?", Lhs);
 411                      Error_Msg_N ("\since no Locking_Policy has been " &
 412                                   "specified", Lhs);
 413                   end if;
 414
 415                   return;
 416                end if;
 417             end if;
 418          end;
 419
 420          Diagnose_Non_Variable_Lhs (Lhs);
 421          return;
 422
 423       --  Error of assigning to limited type. We do however allow this in
 424       --  certain cases where the front end generates the assignments.
 425
 426       elsif Is_Limited_Type (T1)
 427         and then not Assignment_OK (Lhs)
 428         and then not Assignment_OK (Original_Node (Lhs))
 429         and then not Is_Value_Type (T1)
 430       then
 431          Error_Msg_N
 432            ("left hand of assignment must not be limited type", Lhs);
 433          Explain_Limited_Type (T1, Lhs);
 434          return;
 435       end if;
 436
 437       --  Resolution may have updated the subtype, in case the left-hand
 438       --  side is a private protected component. Use the correct subtype
 439       --  to avoid scoping issues in the back-end.
 440
 441       T1 := Etype (Lhs);
 442
 443       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 444       --  type. For example:
 445
 446       --    limited with P;
 447       --    package Pkg is
 448       --      type Acc is access P.T;
 449       --    end Pkg;
 450
 451       --    with Pkg; use Acc;
 452       --    procedure Example is
 453       --       A, B : Acc;
 454       --    begin
 455       --       A.all := B.all;  -- ERROR
 456       --    end Example;
 457
 458       if Nkind (Lhs) = N_Explicit_Dereference
 459         and then Ekind (T1) = E_Incomplete_Type
 460       then
 461          Error_Msg_N ("invalid use of incomplete type", Lhs);
 462          Kill_Lhs;
 463          return;
 464       end if;
 465
 466       --  Now we can complete the resolution of the right hand side
 467
 468       Set_Assignment_Type (Lhs, T1);
 469       Resolve (Rhs, T1);
 470
 471       --  This is the point at which we check for an unset reference
 472
 473       Check_Unset_Reference (Rhs);
 474
 475       --  Remaining steps are skipped if Rhs was syntactically in error
 476
 477       if Rhs = Error then
 478          Kill_Lhs;
 479          return;
 480       end if;
 481
 482       T2 := Etype (Rhs);
 483
 484       if not Covers (T1, T2) then
 485          Wrong_Type (Rhs, Etype (Lhs));
 486          Kill_Lhs;
 487          return;
 488       end if;
 489
 490       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 491       --  types, use the non-limited view if available
 492
 493       if Nkind (Rhs) = N_Explicit_Dereference
 494         and then Ekind (T2) = E_Incomplete_Type
 495         and then Is_Tagged_Type (T2)
 496         and then Present (Non_Limited_View (T2))
 497       then
 498          T2 := Non_Limited_View (T2);
 499       end if;
 500
 501       Set_Assignment_Type (Rhs, T2);
 502
 503       if Total_Errors_Detected /= 0 then
 504          if No (T1) then
 505             T1 := Any_Type;
 506          end if;
 507
 508          if No (T2) then
 509             T2 := Any_Type;
 510          end if;
 511       end if;
 512
 513       if T1 = Any_Type or else T2 = Any_Type then
 514          Kill_Lhs;
 515          return;
 516       end if;
 517
 518       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 519       --  to be class-wide. The case where the rhs is a dynamically tagged call
 520       --  to a dispatching operation with a controlling access result is
 521       --  excluded from this check, since the target has an access type (and
 522       --  no tag propagation occurs in that case).
 523
 524       if (Is_Class_Wide_Type (T2)
 525            or else (Is_Dynamically_Tagged (Rhs)
 526                      and then not Is_Access_Type (T1)))
 527         and then not Is_Class_Wide_Type (T1)
 528       then
 529          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 530
 531       elsif Is_Class_Wide_Type (T1)
 532         and then not Is_Class_Wide_Type (T2)
 533         and then not Is_Tag_Indeterminate (Rhs)
 534         and then not Is_Dynamically_Tagged (Rhs)
 535       then
 536          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 537       end if;
 538
 539       --  Propagate the tag from a class-wide target to the rhs when the rhs
 540       --  is a tag-indeterminate call.
 541
 542       if Is_Tag_Indeterminate (Rhs) then
 543          if Is_Class_Wide_Type (T1) then
 544             Propagate_Tag (Lhs, Rhs);
 545
 546          elsif Nkind (Rhs) = N_Function_Call
 547               and then Is_Entity_Name (Name (Rhs))
 548               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 549          then
 550             Error_Msg_N
 551               ("call to abstract function must be dispatching", Name (Rhs));
 552
 553          elsif Nkind (Rhs) = N_Qualified_Expression
 554            and then Nkind (Expression (Rhs)) = N_Function_Call
 555               and then Is_Entity_Name (Name (Expression (Rhs)))
 556               and then
 557                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 558          then
 559             Error_Msg_N
 560               ("call to abstract function must be dispatching",
 561                 Name (Expression (Rhs)));
 562          end if;
 563       end if;
 564
 565       --  Ada 2005 (AI-230 and AI-385): When the lhs type is an anonymous
 566       --  access type, apply an implicit conversion of the rhs to that type
 567       --  to force appropriate static and run-time accessibility checks.
 568
 569       if Ada_Version >= Ada_05
 570         and then Ekind (T1) = E_Anonymous_Access_Type
 571       then
 572          Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 573          Analyze_And_Resolve (Rhs, T1);
 574       end if;
 575
 576       --  Ada 2005 (AI-231): Assignment to not null variable
 577
 578       if Ada_Version >= Ada_05
 579         and then Can_Never_Be_Null (T1)
 580         and then not Assignment_OK (Lhs)
 581       then
 582          --  Case where we know the right hand side is null
 583
 584          if Known_Null (Rhs) then
 585             Apply_Compile_Time_Constraint_Error
 586               (N   => Rhs,
 587                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 588                Reason => CE_Null_Not_Allowed);
 589
 590             --  We still mark this as a possible modification, that's necessary
 591             --  to reset Is_True_Constant, and desirable for xref purposes.
 592
 593             Note_Possible_Modification (Lhs);
 594             return;
 595
 596          --  If we know the right hand side is non-null, then we convert to the
 597          --  target type, since we don't need a run time check in that case.
 598
 599          elsif not Can_Never_Be_Null (T2) then
 600             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 601             Analyze_And_Resolve (Rhs, T1);
 602          end if;
 603       end if;
 604
 605       if Is_Scalar_Type (T1) then
 606          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 607
 608       --  For array types, verify that lengths match. If the right hand side
 609       --  if a function call that has been inlined, the assignment has been
 610       --  rewritten as a block, and the constraint check will be applied to the
 611       --  assignment within the block.
 612
 613       elsif Is_Array_Type (T1)
 614         and then
 615           (Nkind (Rhs) /= N_Type_Conversion
 616             or else Is_Constrained (Etype (Rhs)))
 617         and then
 618           (Nkind (Rhs) /= N_Function_Call
 619             or else Nkind (N) /= N_Block_Statement)
 620       then
 621          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 622          --  but of course the indices do not have to match. If the right-hand
 623          --  side is a type conversion to an unconstrained type, a length check
 624          --  is performed on the expression itself during expansion. In rare
 625          --  cases, the redundant length check is computed on an index type
 626          --  with a different representation, triggering incorrect code in
 627          --  the back end.
 628
 629          Apply_Length_Check (Rhs, Etype (Lhs));
 630
 631       else
 632          --  Discriminant checks are applied in the course of expansion
 633
 634          null;
 635       end if;
 636
 637       --  Note: modifications of the Lhs may only be recorded after
 638       --  checks have been applied.
 639
 640       Note_Possible_Modification (Lhs);
 641
 642       --  ??? a real accessibility check is needed when ???
 643
 644       --  Post warning for redundant assignment or variable to itself
 645
 646       if Warn_On_Redundant_Constructs
 647
 648          --  We only warn for source constructs
 649
 650          and then Comes_From_Source (N)
 651
 652          --  Where the object is the same on both sides
 653
 654          and then Same_Object (Lhs, Original_Node (Rhs))
 655
 656          --  But exclude the case where the right side was an operation
 657          --  that got rewritten (e.g. JUNK + K, where K was known to be
 658          --  zero). We don't want to warn in such a case, since it is
 659          --  reasonable to write such expressions especially when K is
 660          --  defined symbolically in some other package.
 661
 662         and then Nkind (Original_Node (Rhs)) not in N_Op
 663       then
 664          if Nkind (Lhs) in N_Has_Entity then
 665             Error_Msg_NE
 666               ("?useless assignment of & to itself!", N, Entity (Lhs));
 667          else
 668             Error_Msg_N
 669               ("?useless assignment of object to itself!", N);
 670          end if;
 671       end if;
 672
 673       --  Check for non-allowed composite assignment
 674
 675       if not Support_Composite_Assign_On_Target
 676         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 677         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 678       then
 679          Error_Msg_CRT ("composite assignment", N);
 680       end if;
 681
 682       --  Check elaboration warning for left side if not in elab code
 683
 684       if not In_Subprogram_Or_Concurrent_Unit then
 685          Check_Elab_Assign (Lhs);
 686       end if;
 687
 688       --  Final step. If left side is an entity, then we may be able to
 689       --  reset the current tracked values to new safe values. We only have
 690       --  something to do if the left side is an entity name, and expansion
 691       --  has not modified the node into something other than an assignment,
 692       --  and of course we only capture values if it is safe to do so.
 693
 694       if Is_Entity_Name (Lhs)
 695         and then Nkind (N) = N_Assignment_Statement
 696       then
 697          declare
 698             Ent : constant Entity_Id := Entity (Lhs);
 699
 700          begin
 701             if Safe_To_Capture_Value (N, Ent) then
 702
 703                --  If simple variable on left side, warn if this assignment
 704                --  blots out another one (rendering it useless) and note
 705                --  location of assignment in case no one references value.
 706                --  We only do this for source assignments, otherwise we can
 707                --  generate bogus warnings when an assignment is rewritten as
 708                --  another assignment, and gets tied up with itself.
 709
 710                --  Note: we don't use Record_Last_Assignment here, because we
 711                --  have lots of other stuff to do under control of this test.
 712
 713                if Warn_On_Modified_Unread
 714                  and then Is_Assignable (Ent)
 715                  and then Comes_From_Source (N)
 716                  and then In_Extended_Main_Source_Unit (Ent)
 717                then
 718                   Warn_On_Useless_Assignment (Ent, Sloc (N));
 719                   Set_Last_Assignment (Ent, Lhs);
 720                end if;
 721
 722                --  If we are assigning an access type and the left side is an
 723                --  entity, then make sure that the Is_Known_[Non_]Null flags
 724                --  properly reflect the state of the entity after assignment.
 725
 726                if Is_Access_Type (T1) then
 727                   if Known_Non_Null (Rhs) then
 728                      Set_Is_Known_Non_Null (Ent, True);
 729
 730                   elsif Known_Null (Rhs)
 731                     and then not Can_Never_Be_Null (Ent)
 732                   then
 733                      Set_Is_Known_Null (Ent, True);
 734
 735                   else
 736                      Set_Is_Known_Null (Ent, False);
 737
 738                      if not Can_Never_Be_Null (Ent) then
 739                         Set_Is_Known_Non_Null (Ent, False);
 740                      end if;
 741                   end if;
 742
 743                --  For discrete types, we may be able to set the current value
 744                --  if the value is known at compile time.
 745
 746                elsif Is_Discrete_Type (T1)
 747                  and then Compile_Time_Known_Value (Rhs)
 748                then
 749                   Set_Current_Value (Ent, Rhs);
 750                else
 751                   Set_Current_Value (Ent, Empty);
 752                end if;
 753
 754             --  If not safe to capture values, kill them
 755
 756             else
 757                Kill_Lhs;
 758             end if;
 759          end;
 760       end if;
 761    end Analyze_Assignment;
 762
 763    -----------------------------
 764    -- Analyze_Block_Statement --
 765    -----------------------------
 766
 767    procedure Analyze_Block_Statement (N : Node_Id) is
 768       Decls : constant List_Id := Declarations (N);
 769       Id    : constant Node_Id := Identifier (N);
 770       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 771
 772    begin
 773       --  If no handled statement sequence is present, things are really
 774       --  messed up, and we just return immediately (this is a defence
 775       --  against previous errors).
 776
 777       if No (HSS) then
 778          return;
 779       end if;
 780
 781       --  Normal processing with HSS present
 782
 783       declare
 784          EH  : constant List_Id := Exception_Handlers (HSS);
 785          Ent : Entity_Id        := Empty;
 786          S   : Entity_Id;
 787
 788          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 789          --  Recursively save value of this global, will be restored on exit
 790
 791       begin
 792          --  Initialize unblocked exit count for statements of begin block
 793          --  plus one for each excption handler that is present.
 794
 795          Unblocked_Exit_Count := 1;
 796
 797          if Present (EH) then
 798             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 799          end if;
 800
 801          --  If a label is present analyze it and mark it as referenced
 802
 803          if Present (Id) then
 804             Analyze (Id);
 805             Ent := Entity (Id);
 806
 807             --  An error defense. If we have an identifier, but no entity,
 808             --  then something is wrong. If we have previous errors, then
 809             --  just remove the identifier and continue, otherwise raise
 810             --  an exception.
 811
 812             if No (Ent) then
 813                if Total_Errors_Detected /= 0 then
 814                   Set_Identifier (N, Empty);
 815                else
 816                   raise Program_Error;
 817                end if;
 818
 819             else
 820                Set_Ekind (Ent, E_Block);
 821                Generate_Reference (Ent, N, ' ');
 822                Generate_Definition (Ent);
 823
 824                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 825                   Set_Label_Construct (Parent (Ent), N);
 826                end if;
 827             end if;
 828          end if;
 829
 830          --  If no entity set, create a label entity
 831
 832          if No (Ent) then
 833             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 834             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 835             Set_Parent (Ent, N);
 836          end if;
 837
 838          Set_Etype (Ent, Standard_Void_Type);
 839          Set_Block_Node (Ent, Identifier (N));
 840          Push_Scope (Ent);
 841
 842          if Present (Decls) then
 843             Analyze_Declarations (Decls);
 844             Check_Completion;
 845          end if;
 846
 847          Analyze (HSS);
 848          Process_End_Label (HSS, 'e', Ent);
 849
 850          --  If exception handlers are present, then we indicate that
 851          --  enclosing scopes contain a block with handlers. We only
 852          --  need to mark non-generic scopes.
 853
 854          if Present (EH) then
 855             S := Scope (Ent);
 856             loop
 857                Set_Has_Nested_Block_With_Handler (S);
 858                exit when Is_Overloadable (S)
 859                  or else Ekind (S) = E_Package
 860                  or else Is_Generic_Unit (S);
 861                S := Scope (S);
 862             end loop;
 863          end if;
 864
 865          Check_References (Ent);
 866          Warn_On_Useless_Assignments (Ent);
 867          End_Scope;
 868
 869          if Unblocked_Exit_Count = 0 then
 870             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 871             Check_Unreachable_Code (N);
 872          else
 873             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 874          end if;
 875       end;
 876    end Analyze_Block_Statement;
 877
 878    ----------------------------
 879    -- Analyze_Case_Statement --
 880    ----------------------------
 881
 882    procedure Analyze_Case_Statement (N : Node_Id) is
 883       Exp            : Node_Id;
 884       Exp_Type       : Entity_Id;
 885       Exp_Btype      : Entity_Id;
 886       Last_Choice    : Nat;
 887       Dont_Care      : Boolean;
 888       Others_Present : Boolean;
 889
 890       pragma Warnings (Off, Last_Choice);
 891       pragma Warnings (Off, Dont_Care);
 892       --  Don't care about assigned values
 893
 894       Statements_Analyzed : Boolean := False;
 895       --  Set True if at least some statement sequences get analyzed.
 896       --  If False on exit, means we had a serious error that prevented
 897       --  full analysis of the case statement, and as a result it is not
 898       --  a good idea to output warning messages about unreachable code.
 899
 900       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 901       --  Recursively save value of this global, will be restored on exit
 902
 903       procedure Non_Static_Choice_Error (Choice : Node_Id);
 904       --  Error routine invoked by the generic instantiation below when
 905       --  the case statment has a non static choice.
 906
 907       procedure Process_Statements (Alternative : Node_Id);
 908       --  Analyzes all the statements associated to a case alternative.
 909       --  Needed by the generic instantiation below.
 910
 911       package Case_Choices_Processing is new
 912         Generic_Choices_Processing
 913           (Get_Alternatives          => Alternatives,
 914            Get_Choices               => Discrete_Choices,
 915            Process_Empty_Choice      => No_OP,
 916            Process_Non_Static_Choice => Non_Static_Choice_Error,
 917            Process_Associated_Node   => Process_Statements);
 918       use Case_Choices_Processing;
 919       --  Instantiation of the generic choice processing package
 920
 921       -----------------------------
 922       -- Non_Static_Choice_Error --
 923       -----------------------------
 924
 925       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 926       begin
 927          Flag_Non_Static_Expr
 928            ("choice given in case statement is not static!", Choice);
 929       end Non_Static_Choice_Error;
 930
 931       ------------------------
 932       -- Process_Statements --
 933       ------------------------
 934
 935       procedure Process_Statements (Alternative : Node_Id) is
 936          Choices : constant List_Id := Discrete_Choices (Alternative);
 937          Ent     : Entity_Id;
 938
 939       begin
 940          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 941          Statements_Analyzed := True;
 942
 943          --  An interesting optimization. If the case statement expression
 944          --  is a simple entity, then we can set the current value within
 945          --  an alternative if the alternative has one possible value.
 946
 947          --    case N is
 948          --      when 1      => alpha
 949          --      when 2 | 3  => beta
 950          --      when others => gamma
 951
 952          --  Here we know that N is initially 1 within alpha, but for beta
 953          --  and gamma, we do not know anything more about the initial value.
 954
 955          if Is_Entity_Name (Exp) then
 956             Ent := Entity (Exp);
 957
 958             if Ekind (Ent) = E_Variable
 959                  or else
 960                Ekind (Ent) = E_In_Out_Parameter
 961                  or else
 962                Ekind (Ent) = E_Out_Parameter
 963             then
 964                if List_Length (Choices) = 1
 965                  and then Nkind (First (Choices)) in N_Subexpr
 966                  and then Compile_Time_Known_Value (First (Choices))
 967                then
 968                   Set_Current_Value (Entity (Exp), First (Choices));
 969                end if;
 970
 971                Analyze_Statements (Statements (Alternative));
 972
 973                --  After analyzing the case, set the current value to empty
 974                --  since we won't know what it is for the next alternative
 975                --  (unless reset by this same circuit), or after the case.
 976
 977                Set_Current_Value (Entity (Exp), Empty);
 978                return;
 979             end if;
 980          end if;
 981
 982          --  Case where expression is not an entity name of a variable
 983
 984          Analyze_Statements (Statements (Alternative));
 985       end Process_Statements;
 986
 987       --  Table to record choices. Put after subprograms since we make
 988       --  a call to Number_Of_Choices to get the right number of entries.
 989
 990       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
 991       pragma Warnings (Off, Case_Table);
 992
 993    --  Start of processing for Analyze_Case_Statement
 994
 995    begin
 996       Unblocked_Exit_Count := 0;
 997       Exp := Expression (N);
 998       Analyze (Exp);
 999
1000       --  The expression must be of any discrete type. In rare cases, the
1001       --  expander constructs a case statement whose expression has a private
1002       --  type whose full view is discrete. This can happen when generating
1003       --  a stream operation for a variant type after the type is frozen,
1004       --  when the partial of view of the type of the discriminant is private.
1005       --  In that case, use the full view to analyze case alternatives.
1006
1007       if not Is_Overloaded (Exp)
1008         and then not Comes_From_Source (N)
1009         and then Is_Private_Type (Etype (Exp))
1010         and then Present (Full_View (Etype (Exp)))
1011         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1012       then
1013          Resolve (Exp, Etype (Exp));
1014          Exp_Type := Full_View (Etype (Exp));
1015
1016       else
1017          Analyze_And_Resolve (Exp, Any_Discrete);
1018          Exp_Type := Etype (Exp);
1019       end if;
1020
1021       Check_Unset_Reference (Exp);
1022       Exp_Btype := Base_Type (Exp_Type);
1023
1024       --  The expression must be of a discrete type which must be determinable
1025       --  independently of the context in which the expression occurs, but
1026       --  using the fact that the expression must be of a discrete type.
1027       --  Moreover, the type this expression must not be a character literal
1028       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1029
1030       --  If error already reported by Resolve, nothing more to do
1031
1032       if Exp_Btype = Any_Discrete
1033         or else Exp_Btype = Any_Type
1034       then
1035          return;
1036
1037       elsif Exp_Btype = Any_Character then
1038          Error_Msg_N
1039            ("character literal as case expression is ambiguous", Exp);
1040          return;
1041
1042       elsif Ada_Version = Ada_83
1043         and then (Is_Generic_Type (Exp_Btype)
1044                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1045       then
1046          Error_Msg_N
1047            ("(Ada 83) case expression cannot be of a generic type", Exp);
1048          return;
1049       end if;
1050
1051       --  If the case expression is a formal object of mode in out, then
1052       --  treat it as having a nonstatic subtype by forcing use of the base
1053       --  type (which has to get passed to Check_Case_Choices below).  Also
1054       --  use base type when the case expression is parenthesized.
1055
1056       if Paren_Count (Exp) > 0
1057         or else (Is_Entity_Name (Exp)
1058                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1059       then
1060          Exp_Type := Exp_Btype;
1061       end if;
1062
1063       --  Call instantiated Analyze_Choices which does the rest of the work
1064
1065       Analyze_Choices
1066         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
1067
1068       if Exp_Type = Universal_Integer and then not Others_Present then
1069          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1070       end if;
1071
1072       --  If all our exits were blocked by unconditional transfers of control,
1073       --  then the entire CASE statement acts as an unconditional transfer of
1074       --  control, so treat it like one, and check unreachable code. Skip this
1075       --  test if we had serious errors preventing any statement analysis.
1076
1077       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1078          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1079          Check_Unreachable_Code (N);
1080       else
1081          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1082       end if;
1083
1084       if not Expander_Active
1085         and then Compile_Time_Known_Value (Expression (N))
1086         and then Serious_Errors_Detected = 0
1087       then
1088          declare
1089             Chosen : constant Node_Id := Find_Static_Alternative (N);
1090             Alt    : Node_Id;
1091
1092          begin
1093             Alt := First (Alternatives (N));
1094             while Present (Alt) loop
1095                if Alt /= Chosen then
1096                   Remove_Warning_Messages (Statements (Alt));
1097                end if;
1098
1099                Next (Alt);
1100             end loop;
1101          end;
1102       end if;
1103    end Analyze_Case_Statement;
1104
1105    ----------------------------
1106    -- Analyze_Exit_Statement --
1107    ----------------------------
1108
1109    --  If the exit includes a name, it must be the name of a currently open
1110    --  loop. Otherwise there must be an innermost open loop on the stack,
1111    --  to which the statement implicitly refers.
1112
1113    procedure Analyze_Exit_Statement (N : Node_Id) is
1114       Target   : constant Node_Id := Name (N);
1115       Cond     : constant Node_Id := Condition (N);
1116       Scope_Id : Entity_Id;
1117       U_Name   : Entity_Id;
1118       Kind     : Entity_Kind;
1119
1120    begin
1121       if No (Cond) then
1122          Check_Unreachable_Code (N);
1123       end if;
1124
1125       if Present (Target) then
1126          Analyze (Target);
1127          U_Name := Entity (Target);
1128
1129          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1130             Error_Msg_N ("invalid loop name in exit statement", N);
1131             return;
1132          else
1133             Set_Has_Exit (U_Name);
1134          end if;
1135
1136       else
1137          U_Name := Empty;
1138       end if;
1139
1140       for J in reverse 0 .. Scope_Stack.Last loop
1141          Scope_Id := Scope_Stack.Table (J).Entity;
1142          Kind := Ekind (Scope_Id);
1143
1144          if Kind = E_Loop
1145            and then (No (Target) or else Scope_Id = U_Name) then
1146             Set_Has_Exit (Scope_Id);
1147             exit;
1148
1149          elsif Kind = E_Block
1150            or else Kind = E_Loop
1151            or else Kind = E_Return_Statement
1152          then
1153             null;
1154
1155          else
1156             Error_Msg_N
1157               ("cannot exit from program unit or accept statement", N);
1158             exit;
1159          end if;
1160       end loop;
1161
1162       --  Verify that if present the condition is a Boolean expression
1163
1164       if Present (Cond) then
1165          Analyze_And_Resolve (Cond, Any_Boolean);
1166          Check_Unset_Reference (Cond);
1167       end if;
1168    end Analyze_Exit_Statement;
1169
1170    ----------------------------
1171    -- Analyze_Goto_Statement --
1172    ----------------------------
1173
1174    procedure Analyze_Goto_Statement (N : Node_Id) is
1175       Label       : constant Node_Id := Name (N);
1176       Scope_Id    : Entity_Id;
1177       Label_Scope : Entity_Id;
1178       Label_Ent   : Entity_Id;
1179
1180    begin
1181       Check_Unreachable_Code (N);
1182       Kill_Current_Values (Last_Assignment_Only => True);
1183
1184       Analyze (Label);
1185       Label_Ent := Entity (Label);
1186
1187       --  Ignore previous error
1188
1189       if Label_Ent = Any_Id then
1190          return;
1191
1192       --  We just have a label as the target of a goto
1193
1194       elsif Ekind (Label_Ent) /= E_Label then
1195          Error_Msg_N ("target of goto statement must be a label", Label);
1196          return;
1197
1198       --  Check that the target of the goto is reachable according to Ada
1199       --  scoping rules. Note: the special gotos we generate for optimizing
1200       --  local handling of exceptions would violate these rules, but we mark
1201       --  such gotos as analyzed when built, so this code is never entered.
1202
1203       elsif not Reachable (Label_Ent) then
1204          Error_Msg_N ("target of goto statement is not reachable", Label);
1205          return;
1206       end if;
1207
1208       --  Here if goto passes initial validity checks
1209
1210       Label_Scope := Enclosing_Scope (Label_Ent);
1211
1212       for J in reverse 0 .. Scope_Stack.Last loop
1213          Scope_Id := Scope_Stack.Table (J).Entity;
1214
1215          if Label_Scope = Scope_Id
1216            or else (Ekind (Scope_Id) /= E_Block
1217                      and then Ekind (Scope_Id) /= E_Loop
1218                      and then Ekind (Scope_Id) /= E_Return_Statement)
1219          then
1220             if Scope_Id /= Label_Scope then
1221                Error_Msg_N
1222                  ("cannot exit from program unit or accept statement", N);
1223             end if;
1224
1225             return;
1226          end if;
1227       end loop;
1228
1229       raise Program_Error;
1230    end Analyze_Goto_Statement;
1231
1232    --------------------------
1233    -- Analyze_If_Statement --
1234    --------------------------
1235
1236    --  A special complication arises in the analysis of if statements
1237
1238    --  The expander has circuitry to completely delete code that it
1239    --  can tell will not be executed (as a result of compile time known
1240    --  conditions). In the analyzer, we ensure that code that will be
1241    --  deleted in this manner is analyzed but not expanded. This is
1242    --  obviously more efficient, but more significantly, difficulties
1243    --  arise if code is expanded and then eliminated (e.g. exception
1244    --  table entries disappear). Similarly, itypes generated in deleted
1245    --  code must be frozen from start, because the nodes on which they
1246    --  depend will not be available at the freeze point.
1247
1248    procedure Analyze_If_Statement (N : Node_Id) is
1249       E : Node_Id;
1250
1251       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1252       --  Recursively save value of this global, will be restored on exit
1253
1254       Save_In_Deleted_Code : Boolean;
1255
1256       Del : Boolean := False;
1257       --  This flag gets set True if a True condition has been found,
1258       --  which means that remaining ELSE/ELSIF parts are deleted.
1259
1260       procedure Analyze_Cond_Then (Cnode : Node_Id);
1261       --  This is applied to either the N_If_Statement node itself or
1262       --  to an N_Elsif_Part node. It deals with analyzing the condition
1263       --  and the THEN statements associated with it.
1264
1265       -----------------------
1266       -- Analyze_Cond_Then --
1267       -----------------------
1268
1269       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1270          Cond : constant Node_Id := Condition (Cnode);
1271          Tstm : constant List_Id := Then_Statements (Cnode);
1272
1273       begin
1274          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1275          Analyze_And_Resolve (Cond, Any_Boolean);
1276          Check_Unset_Reference (Cond);
1277          Set_Current_Value_Condition (Cnode);
1278
1279          --  If already deleting, then just analyze then statements
1280
1281          if Del then
1282             Analyze_Statements (Tstm);
1283
1284          --  Compile time known value, not deleting yet
1285
1286          elsif Compile_Time_Known_Value (Cond) then
1287             Save_In_Deleted_Code := In_Deleted_Code;
1288
1289             --  If condition is True, then analyze the THEN statements
1290             --  and set no expansion for ELSE and ELSIF parts.
1291
1292             if Is_True (Expr_Value (Cond)) then
1293                Analyze_Statements (Tstm);
1294                Del := True;
1295                Expander_Mode_Save_And_Set (False);
1296                In_Deleted_Code := True;
1297
1298             --  If condition is False, analyze THEN with expansion off
1299
1300             else -- Is_False (Expr_Value (Cond))
1301                Expander_Mode_Save_And_Set (False);
1302                In_Deleted_Code := True;
1303                Analyze_Statements (Tstm);
1304                Expander_Mode_Restore;
1305                In_Deleted_Code := Save_In_Deleted_Code;
1306             end if;
1307
1308          --  Not known at compile time, not deleting, normal analysis
1309
1310          else
1311             Analyze_Statements (Tstm);
1312          end if;
1313       end Analyze_Cond_Then;
1314
1315    --  Start of Analyze_If_Statement
1316
1317    begin
1318       --  Initialize exit count for else statements. If there is no else
1319       --  part, this count will stay non-zero reflecting the fact that the
1320       --  uncovered else case is an unblocked exit.
1321
1322       Unblocked_Exit_Count := 1;
1323       Analyze_Cond_Then (N);
1324
1325       --  Now to analyze the elsif parts if any are present
1326
1327       if Present (Elsif_Parts (N)) then
1328          E := First (Elsif_Parts (N));
1329          while Present (E) loop
1330             Analyze_Cond_Then (E);
1331             Next (E);
1332          end loop;
1333       end if;
1334
1335       if Present (Else_Statements (N)) then
1336          Analyze_Statements (Else_Statements (N));
1337       end if;
1338
1339       --  If all our exits were blocked by unconditional transfers of control,
1340       --  then the entire IF statement acts as an unconditional transfer of
1341       --  control, so treat it like one, and check unreachable code.
1342
1343       if Unblocked_Exit_Count = 0 then
1344          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1345          Check_Unreachable_Code (N);
1346       else
1347          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1348       end if;
1349
1350       if Del then
1351          Expander_Mode_Restore;
1352          In_Deleted_Code := Save_In_Deleted_Code;
1353       end if;
1354
1355       if not Expander_Active
1356         and then Compile_Time_Known_Value (Condition (N))
1357         and then Serious_Errors_Detected = 0
1358       then
1359          if Is_True (Expr_Value (Condition (N))) then
1360             Remove_Warning_Messages (Else_Statements (N));
1361
1362             if Present (Elsif_Parts (N)) then
1363                E := First (Elsif_Parts (N));
1364                while Present (E) loop
1365                   Remove_Warning_Messages (Then_Statements (E));
1366                   Next (E);
1367                end loop;
1368             end if;
1369
1370          else
1371             Remove_Warning_Messages (Then_Statements (N));
1372          end if;
1373       end if;
1374    end Analyze_If_Statement;
1375
1376    ----------------------------------------
1377    -- Analyze_Implicit_Label_Declaration --
1378    ----------------------------------------
1379
1380    --  An implicit label declaration is generated in the innermost
1381    --  enclosing declarative part. This is done for labels as well as
1382    --  block and loop names.
1383
1384    --  Note: any changes in this routine may need to be reflected in
1385    --  Analyze_Label_Entity.
1386
1387    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1388       Id : constant Node_Id := Defining_Identifier (N);
1389    begin
1390       Enter_Name          (Id);
1391       Set_Ekind           (Id, E_Label);
1392       Set_Etype           (Id, Standard_Void_Type);
1393       Set_Enclosing_Scope (Id, Current_Scope);
1394    end Analyze_Implicit_Label_Declaration;
1395
1396    ------------------------------
1397    -- Analyze_Iteration_Scheme --
1398    ------------------------------
1399
1400    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1401
1402       procedure Process_Bounds (R : Node_Id);
1403       --  If the iteration is given by a range, create temporaries and
1404       --  assignment statements block to capture the bounds and perform
1405       --  required finalization actions in case a bound includes a function
1406       --  call that uses the temporary stack. We first pre-analyze a copy of
1407       --  the range in order to determine the expected type, and analyze and
1408       --  resolve the original bounds.
1409
1410       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1411       --  If the bounds are given by a 'Range reference on a function call
1412       --  that returns a controlled array, introduce an explicit declaration
1413       --  to capture the bounds, so that the function result can be finalized
1414       --  in timely fashion.
1415
1416       --------------------
1417       -- Process_Bounds --
1418       --------------------
1419
1420       procedure Process_Bounds (R : Node_Id) is
1421          Loc          : constant Source_Ptr := Sloc (N);
1422          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1423          Lo           : constant Node_Id := Low_Bound  (R);
1424          Hi           : constant Node_Id := High_Bound (R);
1425          New_Lo_Bound : Node_Id := Empty;
1426          New_Hi_Bound : Node_Id := Empty;
1427          Typ          : Entity_Id;
1428          Save_Analysis : Boolean;
1429
1430          function One_Bound
1431            (Original_Bound : Node_Id;
1432             Analyzed_Bound : Node_Id) return Node_Id;
1433          --  Create one declaration followed by one assignment statement
1434          --  to capture the value of bound. We create a separate assignment
1435          --  in order to force the creation of a block in case the bound
1436          --  contains a call that uses the secondary stack.
1437
1438          ---------------
1439          -- One_Bound --
1440          ---------------
1441
1442          function One_Bound
1443            (Original_Bound : Node_Id;
1444             Analyzed_Bound : Node_Id) return Node_Id
1445          is
1446             Assign : Node_Id;
1447             Id     : Entity_Id;
1448             Decl   : Node_Id;
1449
1450          begin
1451             --  If the bound is a constant or an object, no need for a separate
1452             --  declaration. If the bound is the result of previous expansion
1453             --  it is already analyzed and should not be modified. Note that
1454             --  the Bound will be resolved later, if needed, as part of the
1455             --  call to Make_Index (literal bounds may need to be resolved to
1456             --  type Integer).
1457
1458             if Analyzed (Original_Bound) then
1459                return Original_Bound;
1460
1461             elsif Nkind (Analyzed_Bound) = N_Integer_Literal
1462               or else Nkind (Analyzed_Bound) = N_Character_Literal
1463               or else Is_Entity_Name (Analyzed_Bound)
1464             then
1465                Analyze_And_Resolve (Original_Bound, Typ);
1466                return Original_Bound;
1467
1468             else
1469                Analyze_And_Resolve (Original_Bound, Typ);
1470             end if;
1471
1472             Id :=
1473               Make_Defining_Identifier (Loc,
1474                 Chars => New_Internal_Name ('S'));
1475
1476             Decl :=
1477               Make_Object_Declaration (Loc,
1478                 Defining_Identifier => Id,
1479                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1480
1481             Insert_Before (Parent (N), Decl);
1482             Analyze (Decl);
1483
1484             Assign :=
1485               Make_Assignment_Statement (Loc,
1486                 Name        => New_Occurrence_Of (Id, Loc),
1487                 Expression  => Relocate_Node (Original_Bound));
1488
1489             Insert_Before (Parent (N), Assign);
1490             Analyze (Assign);
1491
1492             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1493
1494             if Nkind (Assign) = N_Assignment_Statement then
1495                return Expression (Assign);
1496             else
1497                return Original_Bound;
1498             end if;
1499          end One_Bound;
1500
1501       --  Start of processing for Process_Bounds
1502
1503       begin
1504          --  Determine expected type of range by analyzing separate copy
1505          --  Do the analysis and resolution of the copy of the bounds with
1506          --  expansion disabled, to prevent the generation of finalization
1507          --  actions on each bound. This prevents memory leaks when the
1508          --  bounds contain calls to functions returning controlled arrays.
1509
1510          Set_Parent (R_Copy, Parent (R));
1511          Save_Analysis := Full_Analysis;
1512          Full_Analysis := False;
1513          Expander_Mode_Save_And_Set (False);
1514
1515          Analyze (R_Copy);
1516
1517          if Is_Overloaded (R_Copy) then
1518
1519             --  Apply preference rules for range of predefined integer types,
1520             --  or diagnose true ambiguity.
1521
1522             declare
1523                I     : Interp_Index;
1524                It    : Interp;
1525                Found : Entity_Id := Empty;
1526
1527             begin
1528                Get_First_Interp (R_Copy, I, It);
1529                while Present (It.Typ) loop
1530                   if Is_Discrete_Type (It.Typ) then
1531                      if No (Found) then
1532                         Found := It.Typ;
1533                      else
1534                         if Scope (Found) = Standard_Standard then
1535                            null;
1536
1537                         elsif Scope (It.Typ) = Standard_Standard then
1538                            Found := It.Typ;
1539
1540                         else
1541                            --  Both of them are user-defined
1542
1543                            Error_Msg_N
1544                              ("ambiguous bounds in range of iteration",
1545                                R_Copy);
1546                            Error_Msg_N ("\possible interpretations:", R_Copy);
1547                            Error_Msg_NE ("\\} ", R_Copy, Found);
1548                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1549                            exit;
1550                         end if;
1551                      end if;
1552                   end if;
1553
1554                   Get_Next_Interp (I, It);
1555                end loop;
1556             end;
1557          end if;
1558
1559          Resolve (R_Copy);
1560          Expander_Mode_Restore;
1561          Full_Analysis := Save_Analysis;
1562
1563          Typ := Etype (R_Copy);
1564
1565          --  If the type of the discrete range is Universal_Integer, then
1566          --  the bound's type must be resolved to Integer, and any object
1567          --  used to hold the bound must also have type Integer, unless the
1568          --  literal bounds are constant-folded expressions that carry a user-
1569          --  defined type.
1570
1571          if Typ = Universal_Integer then
1572             if Nkind (Lo) = N_Integer_Literal
1573               and then Present (Etype (Lo))
1574               and then Scope (Etype (Lo)) /= Standard_Standard
1575             then
1576                Typ := Etype (Lo);
1577
1578             elsif Nkind (Hi) = N_Integer_Literal
1579               and then Present (Etype (Hi))
1580               and then Scope (Etype (Hi)) /= Standard_Standard
1581             then
1582                Typ := Etype (Hi);
1583
1584             else
1585                Typ := Standard_Integer;
1586             end if;
1587          end if;
1588
1589          Set_Etype (R, Typ);
1590
1591          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1592          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1593
1594          --  Propagate staticness to loop range itself, in case the
1595          --  corresponding subtype is static.
1596
1597          if New_Lo_Bound /= Lo
1598            and then Is_Static_Expression (New_Lo_Bound)
1599          then
1600             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1601          end if;
1602
1603          if New_Hi_Bound /= Hi
1604            and then Is_Static_Expression (New_Hi_Bound)
1605          then
1606             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1607          end if;
1608       end Process_Bounds;
1609
1610       --------------------------------------
1611       -- Check_Controlled_Array_Attribute --
1612       --------------------------------------
1613
1614       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1615       begin
1616          if Nkind (DS) = N_Attribute_Reference
1617             and then Is_Entity_Name (Prefix (DS))
1618             and then Ekind (Entity (Prefix (DS))) = E_Function
1619             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1620             and then
1621               Is_Controlled (
1622                 Component_Type (Etype (Entity (Prefix (DS)))))
1623             and then Expander_Active
1624          then
1625             declare
1626                Loc  : constant Source_Ptr := Sloc (N);
1627                Arr  : constant Entity_Id :=
1628                         Etype (Entity (Prefix (DS)));
1629                Indx : constant Entity_Id :=
1630                         Base_Type (Etype (First_Index (Arr)));
1631                Subt : constant Entity_Id :=
1632                         Make_Defining_Identifier
1633                           (Loc, New_Internal_Name ('S'));
1634                Decl : Node_Id;
1635
1636             begin
1637                Decl :=
1638                  Make_Subtype_Declaration (Loc,
1639                    Defining_Identifier => Subt,
1640                    Subtype_Indication  =>
1641                       Make_Subtype_Indication (Loc,
1642                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1643                         Constraint =>
1644                           Make_Range_Constraint (Loc,
1645                             Relocate_Node (DS))));
1646                Insert_Before (Parent (N), Decl);
1647                Analyze (Decl);
1648
1649                Rewrite (DS,
1650                   Make_Attribute_Reference (Loc,
1651                     Prefix => New_Reference_To (Subt, Loc),
1652                     Attribute_Name => Attribute_Name (DS)));
1653                Analyze (DS);
1654             end;
1655          end if;
1656       end Check_Controlled_Array_Attribute;
1657
1658    --  Start of processing for Analyze_Iteration_Scheme
1659
1660    begin
1661       --  For an infinite loop, there is no iteration scheme
1662
1663       if No (N) then
1664          return;
1665
1666       else
1667          declare
1668             Cond : constant Node_Id := Condition (N);
1669
1670          begin
1671             --  For WHILE loop, verify that the condition is a Boolean
1672             --  expression and resolve and check it.
1673
1674             if Present (Cond) then
1675                Analyze_And_Resolve (Cond, Any_Boolean);
1676                Check_Unset_Reference (Cond);
1677                Set_Current_Value_Condition (N);
1678                return;
1679
1680             --  Else we have a FOR loop
1681
1682             else
1683                declare
1684                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1685                   Id : constant Entity_Id := Defining_Identifier (LP);
1686                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1687
1688                begin
1689                   Enter_Name (Id);
1690
1691                   --  We always consider the loop variable to be referenced,
1692                   --  since the loop may be used just for counting purposes.
1693
1694                   Generate_Reference (Id, N, ' ');
1695
1696                   --  Check for case of loop variable hiding a local
1697                   --  variable (used later on to give a nice warning
1698                   --  if the hidden variable is never assigned).
1699
1700                   declare
1701                      H : constant Entity_Id := Homonym (Id);
1702                   begin
1703                      if Present (H)
1704                        and then Enclosing_Dynamic_Scope (H) =
1705                                 Enclosing_Dynamic_Scope (Id)
1706                        and then Ekind (H) = E_Variable
1707                        and then Is_Discrete_Type (Etype (H))
1708                      then
1709                         Set_Hiding_Loop_Variable (H, Id);
1710                      end if;
1711                   end;
1712
1713                   --  Now analyze the subtype definition. If it is
1714                   --  a range, create temporaries for bounds.
1715
1716                   if Nkind (DS) = N_Range
1717                     and then Expander_Active
1718                   then
1719                      Process_Bounds (DS);
1720                   else
1721                      Analyze (DS);
1722                   end if;
1723
1724                   if DS = Error then
1725                      return;
1726                   end if;
1727
1728                   --  The subtype indication may denote the completion
1729                   --  of an incomplete type declaration.
1730
1731                   if Is_Entity_Name (DS)
1732                     and then Present (Entity (DS))
1733                     and then Is_Type (Entity (DS))
1734                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1735                   then
1736                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1737                      Set_Etype  (DS, Entity (DS));
1738                   end if;
1739
1740                   if not Is_Discrete_Type (Etype (DS)) then
1741                      Wrong_Type (DS, Any_Discrete);
1742                      Set_Etype (DS, Any_Type);
1743                   end if;
1744
1745                   Check_Controlled_Array_Attribute (DS);
1746
1747                   Make_Index (DS, LP);
1748
1749                   Set_Ekind          (Id, E_Loop_Parameter);
1750                   Set_Etype          (Id, Etype (DS));
1751                   Set_Is_Known_Valid (Id, True);
1752
1753                   --  The loop is not a declarative part, so the only entity
1754                   --  declared "within" must be frozen explicitly.
1755
1756                   declare
1757                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1758                   begin
1759                      if Is_Non_Empty_List (Flist) then
1760                         Insert_Actions (N, Flist);
1761                      end if;
1762                   end;
1763
1764                   --  Check for null or possibly null range and issue warning.
1765                   --  We suppress such messages in generic templates and
1766                   --  instances, because in practice they tend to be dubious
1767                   --  in these cases.
1768
1769                   if Nkind (DS) = N_Range
1770                     and then Comes_From_Source (N)
1771                   then
1772                      declare
1773                         L : constant Node_Id := Low_Bound  (DS);
1774                         H : constant Node_Id := High_Bound (DS);
1775
1776                         Llo : Uint;
1777                         Lhi : Uint;
1778                         LOK : Boolean;
1779                         Hlo : Uint;
1780                         Hhi : Uint;
1781                         HOK : Boolean;
1782
1783                         pragma Warnings (Off, Hlo);
1784
1785                      begin
1786                         Determine_Range (L, LOK, Llo, Lhi);
1787                         Determine_Range (H, HOK, Hlo, Hhi);
1788
1789                         --  If range of loop is null, issue warning
1790
1791                         if (LOK and HOK) and then Llo > Hhi then
1792
1793                            --  Suppress the warning if inside a generic
1794                            --  template or instance, since in practice
1795                            --  they tend to be dubious in these cases since
1796                            --  they can result from intended parametrization.
1797
1798                            if not Inside_A_Generic
1799                               and then not In_Instance
1800                            then
1801                               Error_Msg_N
1802                                 ("?loop range is null, loop will not execute",
1803                                  DS);
1804                            end if;
1805
1806                            --  Since we know the range of the loop is null,
1807                            --  set the appropriate flag to suppress any
1808                            --  warnings that would otherwise be issued in
1809                            --  the body of the loop that will not execute.
1810                            --  We do this even in the generic case, since
1811                            --  if it is dubious to warn on the null loop
1812                            --  itself, it is certainly dubious to warn for
1813                            --  conditions that occur inside it!
1814
1815                            Set_Is_Null_Loop (Parent (N));
1816
1817                         --  The other case for a warning is a reverse loop
1818                         --  where the upper bound is the integer literal
1819                         --  zero or one, and the lower bound can be positive.
1820
1821                         --  For example, we have
1822
1823                         --     for J in reverse N .. 1 loop
1824
1825                         --  In practice, this is very likely to be a case
1826                         --  of reversing the bounds incorrectly in the range.
1827
1828                         elsif Reverse_Present (LP)
1829                           and then Nkind (Original_Node (H)) =
1830                                                           N_Integer_Literal
1831                           and then (Intval (H) = Uint_0
1832                                       or else
1833                                     Intval (H) = Uint_1)
1834                           and then Lhi > Hhi
1835                         then
1836                            Error_Msg_N ("?loop range may be null", DS);
1837                            Error_Msg_N ("\?bounds may be wrong way round", DS);
1838                         end if;
1839                      end;
1840                   end if;
1841                end;
1842             end if;
1843          end;
1844       end if;
1845    end Analyze_Iteration_Scheme;
1846
1847    -------------------
1848    -- Analyze_Label --
1849    -------------------
1850
1851    --  Note: the semantic work required for analyzing labels (setting them as
1852    --  reachable) was done in a prepass through the statements in the block,
1853    --  so that forward gotos would be properly handled. See Analyze_Statements
1854    --  for further details. The only processing required here is to deal with
1855    --  optimizations that depend on an assumption of sequential control flow,
1856    --  since of course the occurrence of a label breaks this assumption.
1857
1858    procedure Analyze_Label (N : Node_Id) is
1859       pragma Warnings (Off, N);
1860    begin
1861       Kill_Current_Values;
1862    end Analyze_Label;
1863
1864    --------------------------
1865    -- Analyze_Label_Entity --
1866    --------------------------
1867
1868    procedure Analyze_Label_Entity (E : Entity_Id) is
1869    begin
1870       Set_Ekind           (E, E_Label);
1871       Set_Etype           (E, Standard_Void_Type);
1872       Set_Enclosing_Scope (E, Current_Scope);
1873       Set_Reachable       (E, True);
1874    end Analyze_Label_Entity;
1875
1876    ----------------------------
1877    -- Analyze_Loop_Statement --
1878    ----------------------------
1879
1880    procedure Analyze_Loop_Statement (N : Node_Id) is
1881       Loop_Statement : constant Node_Id := N;
1882
1883       Id   : constant Node_Id := Identifier (Loop_Statement);
1884       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
1885       Ent  : Entity_Id;
1886
1887    begin
1888       if Present (Id) then
1889
1890          --  Make name visible, e.g. for use in exit statements. Loop
1891          --  labels are always considered to be referenced.
1892
1893          Analyze (Id);
1894          Ent := Entity (Id);
1895          Generate_Reference  (Ent, Loop_Statement, ' ');
1896          Generate_Definition (Ent);
1897
1898          --  If we found a label, mark its type. If not, ignore it, since it
1899          --  means we have a conflicting declaration, which would already have
1900          --  been diagnosed at declaration time. Set Label_Construct of the
1901          --  implicit label declaration, which is not created by the parser
1902          --  for generic units.
1903
1904          if Ekind (Ent) = E_Label then
1905             Set_Ekind (Ent, E_Loop);
1906
1907             if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
1908                Set_Label_Construct (Parent (Ent), Loop_Statement);
1909             end if;
1910          end if;
1911
1912       --  Case of no identifier present
1913
1914       else
1915          Ent :=
1916            New_Internal_Entity
1917              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
1918          Set_Etype (Ent,  Standard_Void_Type);
1919          Set_Parent (Ent, Loop_Statement);
1920       end if;
1921
1922       --  Kill current values on entry to loop, since statements in body
1923       --  of loop may have been executed before the loop is entered.
1924       --  Similarly we kill values after the loop, since we do not know
1925       --  that the body of the loop was executed.
1926
1927       Kill_Current_Values;
1928       Push_Scope (Ent);
1929       Analyze_Iteration_Scheme (Iter);
1930       Analyze_Statements (Statements (Loop_Statement));
1931       Process_End_Label (Loop_Statement, 'e', Ent);
1932       End_Scope;
1933       Kill_Current_Values;
1934       Check_Infinite_Loop_Warning (N);
1935    end Analyze_Loop_Statement;
1936
1937    ----------------------------
1938    -- Analyze_Null_Statement --
1939    ----------------------------
1940
1941    --  Note: the semantics of the null statement is implemented by a single
1942    --  null statement, too bad everything isn't as simple as this!
1943
1944    procedure Analyze_Null_Statement (N : Node_Id) is
1945       pragma Warnings (Off, N);
1946    begin
1947       null;
1948    end Analyze_Null_Statement;
1949
1950    ------------------------
1951    -- Analyze_Statements --
1952    ------------------------
1953
1954    procedure Analyze_Statements (L : List_Id) is
1955       S   : Node_Id;
1956       Lab : Entity_Id;
1957
1958    begin
1959       --  The labels declared in the statement list are reachable from
1960       --  statements in the list. We do this as a prepass so that any
1961       --  goto statement will be properly flagged if its target is not
1962       --  reachable. This is not required, but is nice behavior!
1963
1964       S := First (L);
1965       while Present (S) loop
1966          if Nkind (S) = N_Label then
1967             Analyze (Identifier (S));
1968             Lab := Entity (Identifier (S));
1969
1970             --  If we found a label mark it as reachable
1971
1972             if Ekind (Lab) = E_Label then
1973                Generate_Definition (Lab);
1974                Set_Reachable (Lab);
1975
1976                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
1977                   Set_Label_Construct (Parent (Lab), S);
1978                end if;
1979
1980             --  If we failed to find a label, it means the implicit declaration
1981             --  of the label was hidden.  A for-loop parameter can do this to
1982             --  a label with the same name inside the loop, since the implicit
1983             --  label declaration is in the innermost enclosing body or block
1984             --  statement.
1985
1986             else
1987                Error_Msg_Sloc := Sloc (Lab);
1988                Error_Msg_N
1989                  ("implicit label declaration for & is hidden#",
1990                   Identifier (S));
1991             end if;
1992          end if;
1993
1994          Next (S);
1995       end loop;
1996
1997       --  Perform semantic analysis on all statements
1998
1999       Conditional_Statements_Begin;
2000
2001       S := First (L);
2002       while Present (S) loop
2003          Analyze (S);
2004          Next (S);
2005       end loop;
2006
2007       Conditional_Statements_End;
2008
2009       --  Make labels unreachable. Visibility is not sufficient, because
2010       --  labels in one if-branch for example are not reachable from the
2011       --  other branch, even though their declarations are in the enclosing
2012       --  declarative part.
2013
2014       S := First (L);
2015       while Present (S) loop
2016          if Nkind (S) = N_Label then
2017             Set_Reachable (Entity (Identifier (S)), False);
2018          end if;
2019
2020          Next (S);
2021       end loop;
2022    end Analyze_Statements;
2023
2024    ----------------------------
2025    -- Check_Unreachable_Code --
2026    ----------------------------
2027
2028    procedure Check_Unreachable_Code (N : Node_Id) is
2029       Error_Loc : Source_Ptr;
2030       P         : Node_Id;
2031
2032    begin
2033       if Is_List_Member (N)
2034         and then Comes_From_Source (N)
2035       then
2036          declare
2037             Nxt : Node_Id;
2038
2039          begin
2040             Nxt := Original_Node (Next (N));
2041
2042             --  If a label follows us, then we never have dead code, since
2043             --  someone could branch to the label, so we just ignore it.
2044
2045             if Nkind (Nxt) = N_Label then
2046                return;
2047
2048             --  Otherwise see if we have a real statement following us
2049
2050             elsif Present (Nxt)
2051               and then Comes_From_Source (Nxt)
2052               and then Is_Statement (Nxt)
2053             then
2054                --  Special very annoying exception. If we have a return that
2055                --  follows a raise, then we allow it without a warning, since
2056                --  the Ada RM annoyingly requires a useless return here!
2057
2058                if Nkind (Original_Node (N)) /= N_Raise_Statement
2059                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2060                then
2061                   --  The rather strange shenanigans with the warning message
2062                   --  here reflects the fact that Kill_Dead_Code is very good
2063                   --  at removing warnings in deleted code, and this is one
2064                   --  warning we would prefer NOT to have removed.
2065
2066                   Error_Loc := Sloc (Nxt);
2067
2068                   --  If we have unreachable code, analyze and remove the
2069                   --  unreachable code, since it is useless and we don't
2070                   --  want to generate junk warnings.
2071
2072                   --  We skip this step if we are not in code generation mode.
2073                   --  This is the one case where we remove dead code in the
2074                   --  semantics as opposed to the expander, and we do not want
2075                   --  to remove code if we are not in code generation mode,
2076                   --  since this messes up the ASIS trees.
2077
2078                   --  Note that one might react by moving the whole circuit to
2079                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2080
2081                   if Operating_Mode = Generate_Code then
2082                      loop
2083                         Nxt := Next (N);
2084
2085                         --  Quit deleting when we have nothing more to delete
2086                         --  or if we hit a label (since someone could transfer
2087                         --  control to a label, so we should not delete it).
2088
2089                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2090
2091                         --  Statement/declaration is to be deleted
2092
2093                         Analyze (Nxt);
2094                         Remove (Nxt);
2095                         Kill_Dead_Code (Nxt);
2096                      end loop;
2097                   end if;
2098
2099                   --  Now issue the warning
2100
2101                   Error_Msg ("?unreachable code!", Error_Loc);
2102                end if;
2103
2104             --  If the unconditional transfer of control instruction is
2105             --  the last statement of a sequence, then see if our parent
2106             --  is one of the constructs for which we count unblocked exits,
2107             --  and if so, adjust the count.
2108
2109             else
2110                P := Parent (N);
2111
2112                --  Statements in THEN part or ELSE part of IF statement
2113
2114                if Nkind (P) = N_If_Statement then
2115                   null;
2116
2117                --  Statements in ELSIF part of an IF statement
2118
2119                elsif Nkind (P) = N_Elsif_Part then
2120                   P := Parent (P);
2121                   pragma Assert (Nkind (P) = N_If_Statement);
2122
2123                --  Statements in CASE statement alternative
2124
2125                elsif Nkind (P) = N_Case_Statement_Alternative then
2126                   P := Parent (P);
2127                   pragma Assert (Nkind (P) = N_Case_Statement);
2128
2129                --  Statements in body of block
2130
2131                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2132                  and then Nkind (Parent (P)) = N_Block_Statement
2133                then
2134                   null;
2135
2136                --  Statements in exception handler in a block
2137
2138                elsif Nkind (P) = N_Exception_Handler
2139                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2140                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2141                then
2142                   null;
2143
2144                --  None of these cases, so return
2145
2146                else
2147                   return;
2148                end if;
2149
2150                --  This was one of the cases we are looking for (i.e. the
2151                --  parent construct was IF, CASE or block) so decrement count.
2152
2153                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2154             end if;
2155          end;
2156       end if;
2157    end Check_Unreachable_Code;
2158
2159 end Sem_Ch5;