gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Case; use Sem_Case;
  42 with Sem_Ch3;  use Sem_Ch3;
  43 with Sem_Ch8;  use Sem_Ch8;
  44 with Sem_Disp; use Sem_Disp;
  45 with Sem_Elab; use Sem_Elab;
  46 with Sem_Eval; use Sem_Eval;
  47 with Sem_Res;  use Sem_Res;
  48 with Sem_Type; use Sem_Type;
  49 with Sem_Util; use Sem_Util;
  50 with Sem_Warn; use Sem_Warn;
  51 with Snames;   use Snames;
  52 with Stand;    use Stand;
  53 with Sinfo;    use Sinfo;
  54 with Targparm; use Targparm;
  55 with Tbuild;   use Tbuild;
  56 with Uintp;    use Uintp;
  57
  58 package body Sem_Ch5 is
  59
  60    Unblocked_Exit_Count : Nat := 0;
  61    --  This variable is used when processing if statements, case statements,
  62    --  and block statements. It counts the number of exit points that are not
  63    --  blocked by unconditional transfer instructions: for IF and CASE, these
  64    --  are the branches of the conditional; for a block, they are the statement
  65    --  sequence of the block, and the statement sequences of any exception
  66    --  handlers that are part of the block. When processing is complete, if
  67    --  this count is zero, it means that control cannot fall through the IF,
  68    --  CASE or block statement. This is used for the generation of warning
  69    --  messages. This variable is recursively saved on entry to processing the
  70    --  construct, and restored on exit.
  71
  72    -----------------------
  73    -- Local Subprograms --
  74    -----------------------
  75
  76    procedure Analyze_Iteration_Scheme (N : Node_Id);
  77
  78    ------------------------
  79    -- Analyze_Assignment --
  80    ------------------------
  81
  82    procedure Analyze_Assignment (N : Node_Id) is
  83       Lhs  : constant Node_Id := Name (N);
  84       Rhs  : constant Node_Id := Expression (N);
  85       T1   : Entity_Id;
  86       T2   : Entity_Id;
  87       Decl : Node_Id;
  88
  89       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  90       --  N is the node for the left hand side of an assignment, and it
  91       --  is not a variable. This routine issues an appropriate diagnostic.
  92
  93       procedure Kill_Lhs;
  94       --  This is called to kill current value settings of a simple variable
  95       --  on the left hand side. We call it if we find any error in analyzing
  96       --  the assignment, and at the end of processing before setting any new
  97       --  current values in place.
  98
  99       procedure Set_Assignment_Type
 100         (Opnd      : Node_Id;
 101          Opnd_Type : in out Entity_Id);
 102       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 103       --  is the nominal subtype. This procedure is used to deal with cases
 104       --  where the nominal subtype must be replaced by the actual subtype.
 105
 106       -------------------------------
 107       -- Diagnose_Non_Variable_Lhs --
 108       -------------------------------
 109
 110       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 111       begin
 112          --  Not worth posting another error if left hand side already
 113          --  flagged as being illegal in some respect.
 114
 115          if Error_Posted (N) then
 116             return;
 117
 118          --  Some special bad cases of entity names
 119
 120          elsif Is_Entity_Name (N) then
 121             if Ekind (Entity (N)) = E_In_Parameter then
 122                Error_Msg_N
 123                  ("assignment to IN mode parameter not allowed", N);
 124
 125             --  Private declarations in a protected object are turned into
 126             --  constants when compiling a protected function.
 127
 128             elsif Present (Scope (Entity (N)))
 129               and then Is_Protected_Type (Scope (Entity (N)))
 130               and then
 131                 (Ekind (Current_Scope) = E_Function
 132                   or else
 133                  Ekind (Enclosing_Dynamic_Scope (Current_Scope)) = E_Function)
 134             then
 135                Error_Msg_N
 136                  ("protected function cannot modify protected object", N);
 137
 138             elsif Ekind (Entity (N)) = E_Loop_Parameter then
 139                Error_Msg_N
 140                  ("assignment to loop parameter not allowed", N);
 141
 142             else
 143                Error_Msg_N
 144                  ("left hand side of assignment must be a variable", N);
 145             end if;
 146
 147          --  For indexed components or selected components, test prefix
 148
 149          elsif Nkind (N) = N_Indexed_Component then
 150             Diagnose_Non_Variable_Lhs (Prefix (N));
 151
 152          --  Another special case for assignment to discriminant
 153
 154          elsif Nkind (N) = N_Selected_Component then
 155             if Present (Entity (Selector_Name (N)))
 156               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 157             then
 158                Error_Msg_N
 159                  ("assignment to discriminant not allowed", N);
 160             else
 161                Diagnose_Non_Variable_Lhs (Prefix (N));
 162             end if;
 163
 164          else
 165             --  If we fall through, we have no special message to issue!
 166
 167             Error_Msg_N ("left hand side of assignment must be a variable", N);
 168          end if;
 169       end Diagnose_Non_Variable_Lhs;
 170
 171       --------------
 172       -- Kill_LHS --
 173       --------------
 174
 175       procedure Kill_Lhs is
 176       begin
 177          if Is_Entity_Name (Lhs) then
 178             declare
 179                Ent : constant Entity_Id := Entity (Lhs);
 180             begin
 181                if Present (Ent) then
 182                   Kill_Current_Values (Ent);
 183                end if;
 184             end;
 185          end if;
 186       end Kill_Lhs;
 187
 188       -------------------------
 189       -- Set_Assignment_Type --
 190       -------------------------
 191
 192       procedure Set_Assignment_Type
 193         (Opnd      : Node_Id;
 194          Opnd_Type : in out Entity_Id)
 195       is
 196       begin
 197          Require_Entity (Opnd);
 198
 199          --  If the assignment operand is an in-out or out parameter, then we
 200          --  get the actual subtype (needed for the unconstrained case).
 201          --  If the operand is the actual in an entry declaration, then within
 202          --  the accept statement it is replaced with a local renaming, which
 203          --  may also have an actual subtype.
 204
 205          if Is_Entity_Name (Opnd)
 206            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 207                       or else Ekind (Entity (Opnd)) =
 208                            E_In_Out_Parameter
 209                       or else Ekind (Entity (Opnd)) =
 210                            E_Generic_In_Out_Parameter
 211                       or else
 212                         (Ekind (Entity (Opnd)) = E_Variable
 213                           and then Nkind (Parent (Entity (Opnd))) =
 214                              N_Object_Renaming_Declaration
 215                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 216                              N_Accept_Statement))
 217          then
 218             Opnd_Type := Get_Actual_Subtype (Opnd);
 219
 220          --  If assignment operand is a component reference, then we get the
 221          --  actual subtype of the component for the unconstrained case.
 222
 223          elsif
 224            (Nkind (Opnd) = N_Selected_Component
 225              or else Nkind (Opnd) = N_Explicit_Dereference)
 226            and then not Is_Unchecked_Union (Opnd_Type)
 227          then
 228             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 229
 230             if Present (Decl) then
 231                Insert_Action (N, Decl);
 232                Mark_Rewrite_Insertion (Decl);
 233                Analyze (Decl);
 234                Opnd_Type := Defining_Identifier (Decl);
 235                Set_Etype (Opnd, Opnd_Type);
 236                Freeze_Itype (Opnd_Type, N);
 237
 238             elsif Is_Constrained (Etype (Opnd)) then
 239                Opnd_Type := Etype (Opnd);
 240             end if;
 241
 242          --  For slice, use the constrained subtype created for the slice
 243
 244          elsif Nkind (Opnd) = N_Slice then
 245             Opnd_Type := Etype (Opnd);
 246          end if;
 247       end Set_Assignment_Type;
 248
 249    --  Start of processing for Analyze_Assignment
 250
 251    begin
 252       Mark_Coextensions (N, Rhs);
 253
 254       Analyze (Rhs);
 255       Analyze (Lhs);
 256
 257       --  Start type analysis for assignment
 258
 259       T1 := Etype (Lhs);
 260
 261       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 262       --  must compute the intersection of the possible types on each side.
 263
 264       if Is_Overloaded (Lhs) then
 265          declare
 266             I  : Interp_Index;
 267             It : Interp;
 268
 269          begin
 270             T1 := Any_Type;
 271             Get_First_Interp (Lhs, I, It);
 272
 273             while Present (It.Typ) loop
 274                if Has_Compatible_Type (Rhs, It.Typ) then
 275                   if T1 /= Any_Type then
 276
 277                      --  An explicit dereference is overloaded if the prefix
 278                      --  is. Try to remove the ambiguity on the prefix, the
 279                      --  error will be posted there if the ambiguity is real.
 280
 281                      if Nkind (Lhs) = N_Explicit_Dereference then
 282                         declare
 283                            PI    : Interp_Index;
 284                            PI1   : Interp_Index := 0;
 285                            PIt   : Interp;
 286                            Found : Boolean;
 287
 288                         begin
 289                            Found := False;
 290                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 291
 292                            while Present (PIt.Typ) loop
 293                               if Is_Access_Type (PIt.Typ)
 294                                 and then Has_Compatible_Type
 295                                            (Rhs, Designated_Type (PIt.Typ))
 296                               then
 297                                  if Found then
 298                                     PIt :=
 299                                       Disambiguate (Prefix (Lhs),
 300                                         PI1, PI, Any_Type);
 301
 302                                     if PIt = No_Interp then
 303                                        Error_Msg_N
 304                                          ("ambiguous left-hand side"
 305                                             & " in assignment", Lhs);
 306                                        exit;
 307                                     else
 308                                        Resolve (Prefix (Lhs), PIt.Typ);
 309                                     end if;
 310
 311                                     exit;
 312                                  else
 313                                     Found := True;
 314                                     PI1 := PI;
 315                                  end if;
 316                               end if;
 317
 318                               Get_Next_Interp (PI, PIt);
 319                            end loop;
 320                         end;
 321
 322                      else
 323                         Error_Msg_N
 324                           ("ambiguous left-hand side in assignment", Lhs);
 325                         exit;
 326                      end if;
 327                   else
 328                      T1 := It.Typ;
 329                   end if;
 330                end if;
 331
 332                Get_Next_Interp (I, It);
 333             end loop;
 334          end;
 335
 336          if T1 = Any_Type then
 337             Error_Msg_N
 338               ("no valid types for left-hand side for assignment", Lhs);
 339             Kill_Lhs;
 340             return;
 341          end if;
 342       end if;
 343
 344       --  The resulting assignment type is T1, so now we will resolve the
 345       --  left hand side of the assignment using this determined type.
 346
 347       Resolve (Lhs, T1);
 348
 349       --  Cases where Lhs is not a variable
 350
 351       if not Is_Variable (Lhs) then
 352
 353          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 354          --  a protected object.
 355
 356          declare
 357             Ent : Entity_Id;
 358             S   : Entity_Id;
 359
 360          begin
 361             if Ada_Version >= Ada_05 then
 362
 363                --  Handle chains of renamings
 364
 365                Ent := Lhs;
 366                while Nkind (Ent) in N_Has_Entity
 367                  and then Present (Entity (Ent))
 368                  and then Present (Renamed_Object (Entity (Ent)))
 369                loop
 370                   Ent := Renamed_Object (Entity (Ent));
 371                end loop;
 372
 373                if (Nkind (Ent) = N_Attribute_Reference
 374                      and then Attribute_Name (Ent) = Name_Priority)
 375
 376                   --  Renamings of the attribute Priority applied to protected
 377                   --  objects have been previously expanded into calls to the
 378                   --  Get_Ceiling run-time subprogram.
 379
 380                  or else
 381                   (Nkind (Ent) = N_Function_Call
 382                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 383                                 or else
 384                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 385                then
 386                   --  The enclosing subprogram cannot be a protected function
 387
 388                   S := Current_Scope;
 389                   while not (Is_Subprogram (S)
 390                                and then Convention (S) = Convention_Protected)
 391                      and then S /= Standard_Standard
 392                   loop
 393                      S := Scope (S);
 394                   end loop;
 395
 396                   if Ekind (S) = E_Function
 397                     and then Convention (S) = Convention_Protected
 398                   then
 399                      Error_Msg_N
 400                        ("protected function cannot modify protected object",
 401                         Lhs);
 402                   end if;
 403
 404                   --  Changes of the ceiling priority of the protected object
 405                   --  are only effective if the Ceiling_Locking policy is in
 406                   --  effect (AARM D.5.2 (5/2)).
 407
 408                   if Locking_Policy /= 'C' then
 409                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 410                                   "no effect?", Lhs);
 411                      Error_Msg_N ("\since no Locking_Policy has been " &
 412                                   "specified", Lhs);
 413                   end if;
 414
 415                   return;
 416                end if;
 417             end if;
 418          end;
 419
 420          Diagnose_Non_Variable_Lhs (Lhs);
 421          return;
 422
 423       --  Error of assigning to limited type. We do however allow this in
 424       --  certain cases where the front end generates the assignments.
 425
 426       elsif Is_Limited_Type (T1)
 427         and then not Assignment_OK (Lhs)
 428         and then not Assignment_OK (Original_Node (Lhs))
 429         and then not Is_Value_Type (T1)
 430       then
 431          Error_Msg_N
 432            ("left hand of assignment must not be limited type", Lhs);
 433          Explain_Limited_Type (T1, Lhs);
 434          return;
 435       end if;
 436
 437       --  Resolution may have updated the subtype, in case the left-hand
 438       --  side is a private protected component. Use the correct subtype
 439       --  to avoid scoping issues in the back-end.
 440
 441       T1 := Etype (Lhs);
 442
 443       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 444       --  type. For example:
 445
 446       --    limited with P;
 447       --    package Pkg is
 448       --      type Acc is access P.T;
 449       --    end Pkg;
 450
 451       --    with Pkg; use Acc;
 452       --    procedure Example is
 453       --       A, B : Acc;
 454       --    begin
 455       --       A.all := B.all;  -- ERROR
 456       --    end Example;
 457
 458       if Nkind (Lhs) = N_Explicit_Dereference
 459         and then Ekind (T1) = E_Incomplete_Type
 460       then
 461          Error_Msg_N ("invalid use of incomplete type", Lhs);
 462          Kill_Lhs;
 463          return;
 464       end if;
 465
 466       --  Now we can complete the resolution of the right hand side
 467
 468       Set_Assignment_Type (Lhs, T1);
 469       Resolve (Rhs, T1);
 470
 471       --  This is the point at which we check for an unset reference
 472
 473       Check_Unset_Reference (Rhs);
 474
 475       --  Remaining steps are skipped if Rhs was syntactically in error
 476
 477       if Rhs = Error then
 478          Kill_Lhs;
 479          return;
 480       end if;
 481
 482       T2 := Etype (Rhs);
 483
 484       if not Covers (T1, T2) then
 485          Wrong_Type (Rhs, Etype (Lhs));
 486          Kill_Lhs;
 487          return;
 488       end if;
 489
 490       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 491       --  types, use the non-limited view if available
 492
 493       if Nkind (Rhs) = N_Explicit_Dereference
 494         and then Ekind (T2) = E_Incomplete_Type
 495         and then Is_Tagged_Type (T2)
 496         and then Present (Non_Limited_View (T2))
 497       then
 498          T2 := Non_Limited_View (T2);
 499       end if;
 500
 501       Set_Assignment_Type (Rhs, T2);
 502
 503       if Total_Errors_Detected /= 0 then
 504          if No (T1) then
 505             T1 := Any_Type;
 506          end if;
 507
 508          if No (T2) then
 509             T2 := Any_Type;
 510          end if;
 511       end if;
 512
 513       if T1 = Any_Type or else T2 = Any_Type then
 514          Kill_Lhs;
 515          return;
 516       end if;
 517
 518       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 519       --  to be class-wide. The case where the rhs is a dynamically tagged call
 520       --  to a dispatching operation with a controlling access result is
 521       --  excluded from this check, since the target has an access type (and
 522       --  no tag propagation occurs in that case).
 523
 524       if (Is_Class_Wide_Type (T2)
 525            or else (Is_Dynamically_Tagged (Rhs)
 526                      and then not Is_Access_Type (T1)))
 527         and then not Is_Class_Wide_Type (T1)
 528       then
 529          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 530
 531       elsif Is_Class_Wide_Type (T1)
 532         and then not Is_Class_Wide_Type (T2)
 533         and then not Is_Tag_Indeterminate (Rhs)
 534         and then not Is_Dynamically_Tagged (Rhs)
 535       then
 536          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 537       end if;
 538
 539       --  Propagate the tag from a class-wide target to the rhs when the rhs
 540       --  is a tag-indeterminate call.
 541
 542       if Is_Tag_Indeterminate (Rhs) then
 543          if Is_Class_Wide_Type (T1) then
 544             Propagate_Tag (Lhs, Rhs);
 545
 546          elsif Nkind (Rhs) = N_Function_Call
 547               and then Is_Entity_Name (Name (Rhs))
 548               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 549          then
 550             Error_Msg_N
 551               ("call to abstract function must be dispatching", Name (Rhs));
 552
 553          elsif Nkind (Rhs) = N_Qualified_Expression
 554            and then Nkind (Expression (Rhs)) = N_Function_Call
 555               and then Is_Entity_Name (Name (Expression (Rhs)))
 556               and then
 557                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 558          then
 559             Error_Msg_N
 560               ("call to abstract function must be dispatching",
 561                 Name (Expression (Rhs)));
 562          end if;
 563       end if;
 564
 565       --  Ada 2005 (AI-230 and AI-385): When the lhs type is an anonymous
 566       --  access type, apply an implicit conversion of the rhs to that type
 567       --  to force appropriate static and run-time accessibility checks.
 568
 569       if Ada_Version >= Ada_05
 570         and then Ekind (T1) = E_Anonymous_Access_Type
 571       then
 572          Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 573          Analyze_And_Resolve (Rhs, T1);
 574       end if;
 575
 576       --  Ada 2005 (AI-231): Assignment to not null variable
 577
 578       if Ada_Version >= Ada_05
 579         and then Can_Never_Be_Null (T1)
 580         and then not Assignment_OK (Lhs)
 581       then
 582          --  Case where we know the right hand side is null
 583
 584          if Known_Null (Rhs) then
 585             Apply_Compile_Time_Constraint_Error
 586               (N   => Rhs,
 587                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 588                Reason => CE_Null_Not_Allowed);
 589
 590             --  We still mark this as a possible modification, that's necessary
 591             --  to reset Is_True_Constant, and desirable for xref purposes.
 592
 593             Note_Possible_Modification (Lhs);
 594             return;
 595
 596          --  If we know the right hand side is non-null, then we convert to the
 597          --  target type, since we don't need a run time check in that case.
 598
 599          elsif not Can_Never_Be_Null (T2) then
 600             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 601             Analyze_And_Resolve (Rhs, T1);
 602          end if;
 603       end if;
 604
 605       if Is_Scalar_Type (T1) then
 606          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 607
 608       --  For array types, verify that lengths match. If the right hand side
 609       --  if a function call that has been inlined, the assignment has been
 610       --  rewritten as a block, and the constraint check will be applied to the
 611       --  assignment within the block.
 612
 613       elsif Is_Array_Type (T1)
 614         and then
 615           (Nkind (Rhs) /= N_Type_Conversion
 616             or else Is_Constrained (Etype (Rhs)))
 617         and then
 618           (Nkind (Rhs) /= N_Function_Call
 619             or else Nkind (N) /= N_Block_Statement)
 620       then
 621          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 622          --  but of course the indices do not have to match. If the right-hand
 623          --  side is a type conversion to an unconstrained type, a length check
 624          --  is performed on the expression itself during expansion. In rare
 625          --  cases, the redundant length check is computed on an index type
 626          --  with a different representation, triggering incorrect code in
 627          --  the back end.
 628
 629          Apply_Length_Check (Rhs, Etype (Lhs));
 630
 631       else
 632          --  Discriminant checks are applied in the course of expansion
 633
 634          null;
 635       end if;
 636
 637       --  Note: modifications of the Lhs may only be recorded after
 638       --  checks have been applied.
 639
 640       Note_Possible_Modification (Lhs);
 641
 642       --  ??? a real accessibility check is needed when ???
 643
 644       --  Post warning for redundant assignment or variable to itself
 645
 646       if Warn_On_Redundant_Constructs
 647
 648          --  We only warn for source constructs
 649
 650          and then Comes_From_Source (N)
 651
 652          --  Where the object is the same on both sides
 653
 654          and then Same_Object (Lhs, Original_Node (Rhs))
 655
 656          --  But exclude the case where the right side was an operation
 657          --  that got rewritten (e.g. JUNK + K, where K was known to be
 658          --  zero). We don't want to warn in such a case, since it is
 659          --  reasonable to write such expressions especially when K is
 660          --  defined symbolically in some other package.
 661
 662         and then Nkind (Original_Node (Rhs)) not in N_Op
 663       then
 664          if Nkind (Lhs) in N_Has_Entity then
 665             Error_Msg_NE
 666               ("?useless assignment of & to itself!", N, Entity (Lhs));
 667          else
 668             Error_Msg_N
 669               ("?useless assignment of object to itself!", N);
 670          end if;
 671       end if;
 672
 673       --  Check for non-allowed composite assignment
 674
 675       if not Support_Composite_Assign_On_Target
 676         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 677         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 678       then
 679          Error_Msg_CRT ("composite assignment", N);
 680       end if;
 681
 682       --  Check elaboration warning for left side if not in elab code
 683
 684       if not In_Subprogram_Or_Concurrent_Unit then
 685          Check_Elab_Assign (Lhs);
 686       end if;
 687
 688       --  Final step. If left side is an entity, then we may be able to
 689       --  reset the current tracked values to new safe values. We only have
 690       --  something to do if the left side is an entity name, and expansion
 691       --  has not modified the node into something other than an assignment,
 692       --  and of course we only capture values if it is safe to do so.
 693
 694       if Is_Entity_Name (Lhs)
 695         and then Nkind (N) = N_Assignment_Statement
 696       then
 697          declare
 698             Ent : constant Entity_Id := Entity (Lhs);
 699
 700          begin
 701             if Safe_To_Capture_Value (N, Ent) then
 702
 703                --  If simple variable on left side, warn if this assignment
 704                --  blots out another one (rendering it useless) and note
 705                --  location of assignment in case no one references value.
 706                --  We only do this for source assignments, otherwise we can
 707                --  generate bogus warnings when an assignment is rewritten as
 708                --  another assignment, and gets tied up with itself.
 709
 710                if Warn_On_Modified_Unread
 711                  and then Ekind (Ent) = E_Variable
 712                  and then Comes_From_Source (N)
 713                  and then In_Extended_Main_Source_Unit (Ent)
 714                then
 715                   Warn_On_Useless_Assignment (Ent, Sloc (N));
 716                   Set_Last_Assignment (Ent, Lhs);
 717                end if;
 718
 719                --  If we are assigning an access type and the left side is an
 720                --  entity, then make sure that the Is_Known_[Non_]Null flags
 721                --  properly reflect the state of the entity after assignment.
 722
 723                if Is_Access_Type (T1) then
 724                   if Known_Non_Null (Rhs) then
 725                      Set_Is_Known_Non_Null (Ent, True);
 726
 727                   elsif Known_Null (Rhs)
 728                     and then not Can_Never_Be_Null (Ent)
 729                   then
 730                      Set_Is_Known_Null (Ent, True);
 731
 732                   else
 733                      Set_Is_Known_Null (Ent, False);
 734
 735                      if not Can_Never_Be_Null (Ent) then
 736                         Set_Is_Known_Non_Null (Ent, False);
 737                      end if;
 738                   end if;
 739
 740                --  For discrete types, we may be able to set the current value
 741                --  if the value is known at compile time.
 742
 743                elsif Is_Discrete_Type (T1)
 744                  and then Compile_Time_Known_Value (Rhs)
 745                then
 746                   Set_Current_Value (Ent, Rhs);
 747                else
 748                   Set_Current_Value (Ent, Empty);
 749                end if;
 750
 751             --  If not safe to capture values, kill them
 752
 753             else
 754                Kill_Lhs;
 755             end if;
 756          end;
 757       end if;
 758    end Analyze_Assignment;
 759
 760    -----------------------------
 761    -- Analyze_Block_Statement --
 762    -----------------------------
 763
 764    procedure Analyze_Block_Statement (N : Node_Id) is
 765       Decls : constant List_Id := Declarations (N);
 766       Id    : constant Node_Id := Identifier (N);
 767       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 768
 769    begin
 770       --  If no handled statement sequence is present, things are really
 771       --  messed up, and we just return immediately (this is a defence
 772       --  against previous errors).
 773
 774       if No (HSS) then
 775          return;
 776       end if;
 777
 778       --  Normal processing with HSS present
 779
 780       declare
 781          EH  : constant List_Id := Exception_Handlers (HSS);
 782          Ent : Entity_Id        := Empty;
 783          S   : Entity_Id;
 784
 785          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 786          --  Recursively save value of this global, will be restored on exit
 787
 788       begin
 789          --  Initialize unblocked exit count for statements of begin block
 790          --  plus one for each excption handler that is present.
 791
 792          Unblocked_Exit_Count := 1;
 793
 794          if Present (EH) then
 795             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 796          end if;
 797
 798          --  If a label is present analyze it and mark it as referenced
 799
 800          if Present (Id) then
 801             Analyze (Id);
 802             Ent := Entity (Id);
 803
 804             --  An error defense. If we have an identifier, but no entity,
 805             --  then something is wrong. If we have previous errors, then
 806             --  just remove the identifier and continue, otherwise raise
 807             --  an exception.
 808
 809             if No (Ent) then
 810                if Total_Errors_Detected /= 0 then
 811                   Set_Identifier (N, Empty);
 812                else
 813                   raise Program_Error;
 814                end if;
 815
 816             else
 817                Set_Ekind (Ent, E_Block);
 818                Generate_Reference (Ent, N, ' ');
 819                Generate_Definition (Ent);
 820
 821                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 822                   Set_Label_Construct (Parent (Ent), N);
 823                end if;
 824             end if;
 825          end if;
 826
 827          --  If no entity set, create a label entity
 828
 829          if No (Ent) then
 830             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 831             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 832             Set_Parent (Ent, N);
 833          end if;
 834
 835          Set_Etype (Ent, Standard_Void_Type);
 836          Set_Block_Node (Ent, Identifier (N));
 837          Push_Scope (Ent);
 838
 839          if Present (Decls) then
 840             Analyze_Declarations (Decls);
 841             Check_Completion;
 842          end if;
 843
 844          Analyze (HSS);
 845          Process_End_Label (HSS, 'e', Ent);
 846
 847          --  If exception handlers are present, then we indicate that
 848          --  enclosing scopes contain a block with handlers. We only
 849          --  need to mark non-generic scopes.
 850
 851          if Present (EH) then
 852             S := Scope (Ent);
 853             loop
 854                Set_Has_Nested_Block_With_Handler (S);
 855                exit when Is_Overloadable (S)
 856                  or else Ekind (S) = E_Package
 857                  or else Is_Generic_Unit (S);
 858                S := Scope (S);
 859             end loop;
 860          end if;
 861
 862          Check_References (Ent);
 863          Warn_On_Useless_Assignments (Ent);
 864          End_Scope;
 865
 866          if Unblocked_Exit_Count = 0 then
 867             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 868             Check_Unreachable_Code (N);
 869          else
 870             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 871          end if;
 872       end;
 873    end Analyze_Block_Statement;
 874
 875    ----------------------------
 876    -- Analyze_Case_Statement --
 877    ----------------------------
 878
 879    procedure Analyze_Case_Statement (N : Node_Id) is
 880       Exp            : Node_Id;
 881       Exp_Type       : Entity_Id;
 882       Exp_Btype      : Entity_Id;
 883       Last_Choice    : Nat;
 884       Dont_Care      : Boolean;
 885       Others_Present : Boolean;
 886
 887       Statements_Analyzed : Boolean := False;
 888       --  Set True if at least some statement sequences get analyzed.
 889       --  If False on exit, means we had a serious error that prevented
 890       --  full analysis of the case statement, and as a result it is not
 891       --  a good idea to output warning messages about unreachable code.
 892
 893       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 894       --  Recursively save value of this global, will be restored on exit
 895
 896       procedure Non_Static_Choice_Error (Choice : Node_Id);
 897       --  Error routine invoked by the generic instantiation below when
 898       --  the case statment has a non static choice.
 899
 900       procedure Process_Statements (Alternative : Node_Id);
 901       --  Analyzes all the statements associated to a case alternative.
 902       --  Needed by the generic instantiation below.
 903
 904       package Case_Choices_Processing is new
 905         Generic_Choices_Processing
 906           (Get_Alternatives          => Alternatives,
 907            Get_Choices               => Discrete_Choices,
 908            Process_Empty_Choice      => No_OP,
 909            Process_Non_Static_Choice => Non_Static_Choice_Error,
 910            Process_Associated_Node   => Process_Statements);
 911       use Case_Choices_Processing;
 912       --  Instantiation of the generic choice processing package
 913
 914       -----------------------------
 915       -- Non_Static_Choice_Error --
 916       -----------------------------
 917
 918       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 919       begin
 920          Flag_Non_Static_Expr
 921            ("choice given in case statement is not static!", Choice);
 922       end Non_Static_Choice_Error;
 923
 924       ------------------------
 925       -- Process_Statements --
 926       ------------------------
 927
 928       procedure Process_Statements (Alternative : Node_Id) is
 929          Choices : constant List_Id := Discrete_Choices (Alternative);
 930          Ent     : Entity_Id;
 931
 932       begin
 933          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 934          Statements_Analyzed := True;
 935
 936          --  An interesting optimization. If the case statement expression
 937          --  is a simple entity, then we can set the current value within
 938          --  an alternative if the alternative has one possible value.
 939
 940          --    case N is
 941          --      when 1      => alpha
 942          --      when 2 | 3  => beta
 943          --      when others => gamma
 944
 945          --  Here we know that N is initially 1 within alpha, but for beta
 946          --  and gamma, we do not know anything more about the initial value.
 947
 948          if Is_Entity_Name (Exp) then
 949             Ent := Entity (Exp);
 950
 951             if Ekind (Ent) = E_Variable
 952                  or else
 953                Ekind (Ent) = E_In_Out_Parameter
 954                  or else
 955                Ekind (Ent) = E_Out_Parameter
 956             then
 957                if List_Length (Choices) = 1
 958                  and then Nkind (First (Choices)) in N_Subexpr
 959                  and then Compile_Time_Known_Value (First (Choices))
 960                then
 961                   Set_Current_Value (Entity (Exp), First (Choices));
 962                end if;
 963
 964                Analyze_Statements (Statements (Alternative));
 965
 966                --  After analyzing the case, set the current value to empty
 967                --  since we won't know what it is for the next alternative
 968                --  (unless reset by this same circuit), or after the case.
 969
 970                Set_Current_Value (Entity (Exp), Empty);
 971                return;
 972             end if;
 973          end if;
 974
 975          --  Case where expression is not an entity name of a variable
 976
 977          Analyze_Statements (Statements (Alternative));
 978       end Process_Statements;
 979
 980       --  Table to record choices. Put after subprograms since we make
 981       --  a call to Number_Of_Choices to get the right number of entries.
 982
 983       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
 984
 985    --  Start of processing for Analyze_Case_Statement
 986
 987    begin
 988       Unblocked_Exit_Count := 0;
 989       Exp := Expression (N);
 990       Analyze (Exp);
 991
 992       --  The expression must be of any discrete type. In rare cases, the
 993       --  expander constructs a case statement whose expression has a private
 994       --  type whose full view is discrete. This can happen when generating
 995       --  a stream operation for a variant type after the type is frozen,
 996       --  when the partial of view of the type of the discriminant is private.
 997       --  In that case, use the full view to analyze case alternatives.
 998
 999       if not Is_Overloaded (Exp)
1000         and then not Comes_From_Source (N)
1001         and then Is_Private_Type (Etype (Exp))
1002         and then Present (Full_View (Etype (Exp)))
1003         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1004       then
1005          Resolve (Exp, Etype (Exp));
1006          Exp_Type := Full_View (Etype (Exp));
1007
1008       else
1009          Analyze_And_Resolve (Exp, Any_Discrete);
1010          Exp_Type := Etype (Exp);
1011       end if;
1012
1013       Check_Unset_Reference (Exp);
1014       Exp_Btype := Base_Type (Exp_Type);
1015
1016       --  The expression must be of a discrete type which must be determinable
1017       --  independently of the context in which the expression occurs, but
1018       --  using the fact that the expression must be of a discrete type.
1019       --  Moreover, the type this expression must not be a character literal
1020       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1021
1022       --  If error already reported by Resolve, nothing more to do
1023
1024       if Exp_Btype = Any_Discrete
1025         or else Exp_Btype = Any_Type
1026       then
1027          return;
1028
1029       elsif Exp_Btype = Any_Character then
1030          Error_Msg_N
1031            ("character literal as case expression is ambiguous", Exp);
1032          return;
1033
1034       elsif Ada_Version = Ada_83
1035         and then (Is_Generic_Type (Exp_Btype)
1036                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1037       then
1038          Error_Msg_N
1039            ("(Ada 83) case expression cannot be of a generic type", Exp);
1040          return;
1041       end if;
1042
1043       --  If the case expression is a formal object of mode in out, then
1044       --  treat it as having a nonstatic subtype by forcing use of the base
1045       --  type (which has to get passed to Check_Case_Choices below).  Also
1046       --  use base type when the case expression is parenthesized.
1047
1048       if Paren_Count (Exp) > 0
1049         or else (Is_Entity_Name (Exp)
1050                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1051       then
1052          Exp_Type := Exp_Btype;
1053       end if;
1054
1055       --  Call instantiated Analyze_Choices which does the rest of the work
1056
1057       Analyze_Choices
1058         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
1059
1060       if Exp_Type = Universal_Integer and then not Others_Present then
1061          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1062       end if;
1063
1064       --  If all our exits were blocked by unconditional transfers of control,
1065       --  then the entire CASE statement acts as an unconditional transfer of
1066       --  control, so treat it like one, and check unreachable code. Skip this
1067       --  test if we had serious errors preventing any statement analysis.
1068
1069       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1070          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1071          Check_Unreachable_Code (N);
1072       else
1073          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1074       end if;
1075
1076       if not Expander_Active
1077         and then Compile_Time_Known_Value (Expression (N))
1078         and then Serious_Errors_Detected = 0
1079       then
1080          declare
1081             Chosen : constant Node_Id := Find_Static_Alternative (N);
1082             Alt    : Node_Id;
1083
1084          begin
1085             Alt := First (Alternatives (N));
1086             while Present (Alt) loop
1087                if Alt /= Chosen then
1088                   Remove_Warning_Messages (Statements (Alt));
1089                end if;
1090
1091                Next (Alt);
1092             end loop;
1093          end;
1094       end if;
1095    end Analyze_Case_Statement;
1096
1097    ----------------------------
1098    -- Analyze_Exit_Statement --
1099    ----------------------------
1100
1101    --  If the exit includes a name, it must be the name of a currently open
1102    --  loop. Otherwise there must be an innermost open loop on the stack,
1103    --  to which the statement implicitly refers.
1104
1105    procedure Analyze_Exit_Statement (N : Node_Id) is
1106       Target   : constant Node_Id := Name (N);
1107       Cond     : constant Node_Id := Condition (N);
1108       Scope_Id : Entity_Id;
1109       U_Name   : Entity_Id;
1110       Kind     : Entity_Kind;
1111
1112    begin
1113       if No (Cond) then
1114          Check_Unreachable_Code (N);
1115       end if;
1116
1117       if Present (Target) then
1118          Analyze (Target);
1119          U_Name := Entity (Target);
1120
1121          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1122             Error_Msg_N ("invalid loop name in exit statement", N);
1123             return;
1124          else
1125             Set_Has_Exit (U_Name);
1126          end if;
1127
1128       else
1129          U_Name := Empty;
1130       end if;
1131
1132       for J in reverse 0 .. Scope_Stack.Last loop
1133          Scope_Id := Scope_Stack.Table (J).Entity;
1134          Kind := Ekind (Scope_Id);
1135
1136          if Kind = E_Loop
1137            and then (No (Target) or else Scope_Id = U_Name) then
1138             Set_Has_Exit (Scope_Id);
1139             exit;
1140
1141          elsif Kind = E_Block
1142            or else Kind = E_Loop
1143            or else Kind = E_Return_Statement
1144          then
1145             null;
1146
1147          else
1148             Error_Msg_N
1149               ("cannot exit from program unit or accept statement", N);
1150             exit;
1151          end if;
1152       end loop;
1153
1154       --  Verify that if present the condition is a Boolean expression
1155
1156       if Present (Cond) then
1157          Analyze_And_Resolve (Cond, Any_Boolean);
1158          Check_Unset_Reference (Cond);
1159       end if;
1160    end Analyze_Exit_Statement;
1161
1162    ----------------------------
1163    -- Analyze_Goto_Statement --
1164    ----------------------------
1165
1166    procedure Analyze_Goto_Statement (N : Node_Id) is
1167       Label       : constant Node_Id := Name (N);
1168       Scope_Id    : Entity_Id;
1169       Label_Scope : Entity_Id;
1170       Label_Ent   : Entity_Id;
1171
1172    begin
1173       Check_Unreachable_Code (N);
1174
1175       Analyze (Label);
1176       Label_Ent := Entity (Label);
1177
1178       --  Ignore previous error
1179
1180       if Label_Ent = Any_Id then
1181          return;
1182
1183       --  We just have a label as the target of a goto
1184
1185       elsif Ekind (Label_Ent) /= E_Label then
1186          Error_Msg_N ("target of goto statement must be a label", Label);
1187          return;
1188
1189       --  Check that the target of the goto is reachable according to Ada
1190       --  scoping rules. Note: the special gotos we generate for optimizing
1191       --  local handling of exceptions would violate these rules, but we mark
1192       --  such gotos as analyzed when built, so this code is never entered.
1193
1194       elsif not Reachable (Label_Ent) then
1195          Error_Msg_N ("target of goto statement is not reachable", Label);
1196          return;
1197       end if;
1198
1199       --  Here if goto passes initial validity checks
1200
1201       Label_Scope := Enclosing_Scope (Label_Ent);
1202
1203       for J in reverse 0 .. Scope_Stack.Last loop
1204          Scope_Id := Scope_Stack.Table (J).Entity;
1205
1206          if Label_Scope = Scope_Id
1207            or else (Ekind (Scope_Id) /= E_Block
1208                      and then Ekind (Scope_Id) /= E_Loop
1209                      and then Ekind (Scope_Id) /= E_Return_Statement)
1210          then
1211             if Scope_Id /= Label_Scope then
1212                Error_Msg_N
1213                  ("cannot exit from program unit or accept statement", N);
1214             end if;
1215
1216             return;
1217          end if;
1218       end loop;
1219
1220       raise Program_Error;
1221    end Analyze_Goto_Statement;
1222
1223    --------------------------
1224    -- Analyze_If_Statement --
1225    --------------------------
1226
1227    --  A special complication arises in the analysis of if statements
1228
1229    --  The expander has circuitry to completely delete code that it
1230    --  can tell will not be executed (as a result of compile time known
1231    --  conditions). In the analyzer, we ensure that code that will be
1232    --  deleted in this manner is analyzed but not expanded. This is
1233    --  obviously more efficient, but more significantly, difficulties
1234    --  arise if code is expanded and then eliminated (e.g. exception
1235    --  table entries disappear). Similarly, itypes generated in deleted
1236    --  code must be frozen from start, because the nodes on which they
1237    --  depend will not be available at the freeze point.
1238
1239    procedure Analyze_If_Statement (N : Node_Id) is
1240       E : Node_Id;
1241
1242       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1243       --  Recursively save value of this global, will be restored on exit
1244
1245       Save_In_Deleted_Code : Boolean;
1246
1247       Del : Boolean := False;
1248       --  This flag gets set True if a True condition has been found,
1249       --  which means that remaining ELSE/ELSIF parts are deleted.
1250
1251       procedure Analyze_Cond_Then (Cnode : Node_Id);
1252       --  This is applied to either the N_If_Statement node itself or
1253       --  to an N_Elsif_Part node. It deals with analyzing the condition
1254       --  and the THEN statements associated with it.
1255
1256       -----------------------
1257       -- Analyze_Cond_Then --
1258       -----------------------
1259
1260       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1261          Cond : constant Node_Id := Condition (Cnode);
1262          Tstm : constant List_Id := Then_Statements (Cnode);
1263
1264       begin
1265          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1266          Analyze_And_Resolve (Cond, Any_Boolean);
1267          Check_Unset_Reference (Cond);
1268          Set_Current_Value_Condition (Cnode);
1269
1270          --  If already deleting, then just analyze then statements
1271
1272          if Del then
1273             Analyze_Statements (Tstm);
1274
1275          --  Compile time known value, not deleting yet
1276
1277          elsif Compile_Time_Known_Value (Cond) then
1278             Save_In_Deleted_Code := In_Deleted_Code;
1279
1280             --  If condition is True, then analyze the THEN statements
1281             --  and set no expansion for ELSE and ELSIF parts.
1282
1283             if Is_True (Expr_Value (Cond)) then
1284                Analyze_Statements (Tstm);
1285                Del := True;
1286                Expander_Mode_Save_And_Set (False);
1287                In_Deleted_Code := True;
1288
1289             --  If condition is False, analyze THEN with expansion off
1290
1291             else -- Is_False (Expr_Value (Cond))
1292                Expander_Mode_Save_And_Set (False);
1293                In_Deleted_Code := True;
1294                Analyze_Statements (Tstm);
1295                Expander_Mode_Restore;
1296                In_Deleted_Code := Save_In_Deleted_Code;
1297             end if;
1298
1299          --  Not known at compile time, not deleting, normal analysis
1300
1301          else
1302             Analyze_Statements (Tstm);
1303          end if;
1304       end Analyze_Cond_Then;
1305
1306    --  Start of Analyze_If_Statement
1307
1308    begin
1309       --  Initialize exit count for else statements. If there is no else
1310       --  part, this count will stay non-zero reflecting the fact that the
1311       --  uncovered else case is an unblocked exit.
1312
1313       Unblocked_Exit_Count := 1;
1314       Analyze_Cond_Then (N);
1315
1316       --  Now to analyze the elsif parts if any are present
1317
1318       if Present (Elsif_Parts (N)) then
1319          E := First (Elsif_Parts (N));
1320          while Present (E) loop
1321             Analyze_Cond_Then (E);
1322             Next (E);
1323          end loop;
1324       end if;
1325
1326       if Present (Else_Statements (N)) then
1327          Analyze_Statements (Else_Statements (N));
1328       end if;
1329
1330       --  If all our exits were blocked by unconditional transfers of control,
1331       --  then the entire IF statement acts as an unconditional transfer of
1332       --  control, so treat it like one, and check unreachable code.
1333
1334       if Unblocked_Exit_Count = 0 then
1335          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1336          Check_Unreachable_Code (N);
1337       else
1338          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1339       end if;
1340
1341       if Del then
1342          Expander_Mode_Restore;
1343          In_Deleted_Code := Save_In_Deleted_Code;
1344       end if;
1345
1346       if not Expander_Active
1347         and then Compile_Time_Known_Value (Condition (N))
1348         and then Serious_Errors_Detected = 0
1349       then
1350          if Is_True (Expr_Value (Condition (N))) then
1351             Remove_Warning_Messages (Else_Statements (N));
1352
1353             if Present (Elsif_Parts (N)) then
1354                E := First (Elsif_Parts (N));
1355                while Present (E) loop
1356                   Remove_Warning_Messages (Then_Statements (E));
1357                   Next (E);
1358                end loop;
1359             end if;
1360
1361          else
1362             Remove_Warning_Messages (Then_Statements (N));
1363          end if;
1364       end if;
1365    end Analyze_If_Statement;
1366
1367    ----------------------------------------
1368    -- Analyze_Implicit_Label_Declaration --
1369    ----------------------------------------
1370
1371    --  An implicit label declaration is generated in the innermost
1372    --  enclosing declarative part. This is done for labels as well as
1373    --  block and loop names.
1374
1375    --  Note: any changes in this routine may need to be reflected in
1376    --  Analyze_Label_Entity.
1377
1378    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1379       Id : constant Node_Id := Defining_Identifier (N);
1380    begin
1381       Enter_Name          (Id);
1382       Set_Ekind           (Id, E_Label);
1383       Set_Etype           (Id, Standard_Void_Type);
1384       Set_Enclosing_Scope (Id, Current_Scope);
1385    end Analyze_Implicit_Label_Declaration;
1386
1387    ------------------------------
1388    -- Analyze_Iteration_Scheme --
1389    ------------------------------
1390
1391    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1392
1393       procedure Process_Bounds (R : Node_Id);
1394       --  If the iteration is given by a range, create temporaries and
1395       --  assignment statements block to capture the bounds and perform
1396       --  required finalization actions in case a bound includes a function
1397       --  call that uses the temporary stack. We first pre-analyze a copy of
1398       --  the range in order to determine the expected type, and analyze and
1399       --  resolve the original bounds.
1400
1401       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1402       --  If the bounds are given by a 'Range reference on a function call
1403       --  that returns a controlled array, introduce an explicit declaration
1404       --  to capture the bounds, so that the function result can be finalized
1405       --  in timely fashion.
1406
1407       --------------------
1408       -- Process_Bounds --
1409       --------------------
1410
1411       procedure Process_Bounds (R : Node_Id) is
1412          Loc          : constant Source_Ptr := Sloc (N);
1413          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1414          Lo           : constant Node_Id := Low_Bound  (R);
1415          Hi           : constant Node_Id := High_Bound (R);
1416          New_Lo_Bound : Node_Id := Empty;
1417          New_Hi_Bound : Node_Id := Empty;
1418          Typ          : Entity_Id;
1419          Save_Analysis : Boolean;
1420
1421          function One_Bound
1422            (Original_Bound : Node_Id;
1423             Analyzed_Bound : Node_Id) return Node_Id;
1424          --  Create one declaration followed by one assignment statement
1425          --  to capture the value of bound. We create a separate assignment
1426          --  in order to force the creation of a block in case the bound
1427          --  contains a call that uses the secondary stack.
1428
1429          ---------------
1430          -- One_Bound --
1431          ---------------
1432
1433          function One_Bound
1434            (Original_Bound : Node_Id;
1435             Analyzed_Bound : Node_Id) return Node_Id
1436          is
1437             Assign : Node_Id;
1438             Id     : Entity_Id;
1439             Decl   : Node_Id;
1440
1441          begin
1442             --  If the bound is a constant or an object, no need for a separate
1443             --  declaration. If the bound is the result of previous expansion
1444             --  it is already analyzed and should not be modified. Note that
1445             --  the Bound will be resolved later, if needed, as part of the
1446             --  call to Make_Index (literal bounds may need to be resolved to
1447             --  type Integer).
1448
1449             if Analyzed (Original_Bound) then
1450                return Original_Bound;
1451
1452             elsif Nkind (Analyzed_Bound) = N_Integer_Literal
1453               or else Nkind (Analyzed_Bound) = N_Character_Literal
1454               or else Is_Entity_Name (Analyzed_Bound)
1455             then
1456                Analyze_And_Resolve (Original_Bound, Typ);
1457                return Original_Bound;
1458
1459             else
1460                Analyze_And_Resolve (Original_Bound, Typ);
1461             end if;
1462
1463             Id :=
1464               Make_Defining_Identifier (Loc,
1465                 Chars => New_Internal_Name ('S'));
1466
1467             Decl :=
1468               Make_Object_Declaration (Loc,
1469                 Defining_Identifier => Id,
1470                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1471
1472             Insert_Before (Parent (N), Decl);
1473             Analyze (Decl);
1474
1475             Assign :=
1476               Make_Assignment_Statement (Loc,
1477                 Name        => New_Occurrence_Of (Id, Loc),
1478                 Expression  => Relocate_Node (Original_Bound));
1479
1480             Insert_Before (Parent (N), Assign);
1481             Analyze (Assign);
1482
1483             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1484
1485             if Nkind (Assign) = N_Assignment_Statement then
1486                return Expression (Assign);
1487             else
1488                return Original_Bound;
1489             end if;
1490          end One_Bound;
1491
1492       --  Start of processing for Process_Bounds
1493
1494       begin
1495          --  Determine expected type of range by analyzing separate copy
1496          --  Do the analysis and resolution of the copy of the bounds with
1497          --  expansion disabled, to prevent the generation of finalization
1498          --  actions on each bound. This prevents memory leaks when the
1499          --  bounds contain calls to functions returning controlled arrays.
1500
1501          Set_Parent (R_Copy, Parent (R));
1502          Save_Analysis := Full_Analysis;
1503          Full_Analysis := False;
1504          Expander_Mode_Save_And_Set (False);
1505
1506          Analyze (R_Copy);
1507
1508          if Is_Overloaded (R_Copy) then
1509
1510             --  Apply preference rules for range of predefined integer types,
1511             --  or diagnose true ambiguity.
1512
1513             declare
1514                I     : Interp_Index;
1515                It    : Interp;
1516                Found : Entity_Id := Empty;
1517
1518             begin
1519                Get_First_Interp (R_Copy, I, It);
1520                while Present (It.Typ) loop
1521                   if Is_Discrete_Type (It.Typ) then
1522                      if No (Found) then
1523                         Found := It.Typ;
1524                      else
1525                         if Scope (Found) = Standard_Standard then
1526                            null;
1527
1528                         elsif Scope (It.Typ) = Standard_Standard then
1529                            Found := It.Typ;
1530
1531                         else
1532                            --  Both of them are user-defined
1533
1534                            Error_Msg_N
1535                              ("ambiguous bounds in range of iteration",
1536                                R_Copy);
1537                            Error_Msg_N ("\possible interpretations:", R_Copy);
1538                            Error_Msg_NE ("\\} ", R_Copy, Found);
1539                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1540                            exit;
1541                         end if;
1542                      end if;
1543                   end if;
1544
1545                   Get_Next_Interp (I, It);
1546                end loop;
1547             end;
1548          end if;
1549
1550          Resolve (R_Copy);
1551          Expander_Mode_Restore;
1552          Full_Analysis := Save_Analysis;
1553
1554          Typ := Etype (R_Copy);
1555
1556          --  If the type of the discrete range is Universal_Integer, then
1557          --  the bound's type must be resolved to Integer, and any object
1558          --  used to hold the bound must also have type Integer, unless the
1559          --  literal bounds are constant-folded expressions that carry a user-
1560          --  defined type.
1561
1562          if Typ = Universal_Integer then
1563             if Nkind (Lo) = N_Integer_Literal
1564               and then Present (Etype (Lo))
1565               and then Scope (Etype (Lo)) /= Standard_Standard
1566             then
1567                Typ := Etype (Lo);
1568
1569             elsif Nkind (Hi) = N_Integer_Literal
1570               and then Present (Etype (Hi))
1571               and then Scope (Etype (Hi)) /= Standard_Standard
1572             then
1573                Typ := Etype (Hi);
1574
1575             else
1576                Typ := Standard_Integer;
1577             end if;
1578          end if;
1579
1580          Set_Etype (R, Typ);
1581
1582          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1583          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1584
1585          --  Propagate staticness to loop range itself, in case the
1586          --  corresponding subtype is static.
1587
1588          if New_Lo_Bound /= Lo
1589            and then Is_Static_Expression (New_Lo_Bound)
1590          then
1591             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1592          end if;
1593
1594          if New_Hi_Bound /= Hi
1595            and then Is_Static_Expression (New_Hi_Bound)
1596          then
1597             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1598          end if;
1599       end Process_Bounds;
1600
1601       --------------------------------------
1602       -- Check_Controlled_Array_Attribute --
1603       --------------------------------------
1604
1605       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1606       begin
1607          if Nkind (DS) = N_Attribute_Reference
1608             and then Is_Entity_Name (Prefix (DS))
1609             and then Ekind (Entity (Prefix (DS))) = E_Function
1610             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1611             and then
1612               Is_Controlled (
1613                 Component_Type (Etype (Entity (Prefix (DS)))))
1614             and then Expander_Active
1615          then
1616             declare
1617                Loc  : constant Source_Ptr := Sloc (N);
1618                Arr  : constant Entity_Id :=
1619                         Etype (Entity (Prefix (DS)));
1620                Indx : constant Entity_Id :=
1621                         Base_Type (Etype (First_Index (Arr)));
1622                Subt : constant Entity_Id :=
1623                         Make_Defining_Identifier
1624                           (Loc, New_Internal_Name ('S'));
1625                Decl : Node_Id;
1626
1627             begin
1628                Decl :=
1629                  Make_Subtype_Declaration (Loc,
1630                    Defining_Identifier => Subt,
1631                    Subtype_Indication  =>
1632                       Make_Subtype_Indication (Loc,
1633                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1634                         Constraint =>
1635                           Make_Range_Constraint (Loc,
1636                             Relocate_Node (DS))));
1637                Insert_Before (Parent (N), Decl);
1638                Analyze (Decl);
1639
1640                Rewrite (DS,
1641                   Make_Attribute_Reference (Loc,
1642                     Prefix => New_Reference_To (Subt, Loc),
1643                     Attribute_Name => Attribute_Name (DS)));
1644                Analyze (DS);
1645             end;
1646          end if;
1647       end Check_Controlled_Array_Attribute;
1648
1649    --  Start of processing for Analyze_Iteration_Scheme
1650
1651    begin
1652       --  For an infinite loop, there is no iteration scheme
1653
1654       if No (N) then
1655          return;
1656
1657       else
1658          declare
1659             Cond : constant Node_Id := Condition (N);
1660
1661          begin
1662             --  For WHILE loop, verify that the condition is a Boolean
1663             --  expression and resolve and check it.
1664
1665             if Present (Cond) then
1666                Analyze_And_Resolve (Cond, Any_Boolean);
1667                Check_Unset_Reference (Cond);
1668                Set_Current_Value_Condition (N);
1669                return;
1670
1671             --  Else we have a FOR loop
1672
1673             else
1674                declare
1675                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1676                   Id : constant Entity_Id := Defining_Identifier (LP);
1677                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1678
1679                begin
1680                   Enter_Name (Id);
1681
1682                   --  We always consider the loop variable to be referenced,
1683                   --  since the loop may be used just for counting purposes.
1684
1685                   Generate_Reference (Id, N, ' ');
1686
1687                   --  Check for case of loop variable hiding a local
1688                   --  variable (used later on to give a nice warning
1689                   --  if the hidden variable is never assigned).
1690
1691                   declare
1692                      H : constant Entity_Id := Homonym (Id);
1693                   begin
1694                      if Present (H)
1695                        and then Enclosing_Dynamic_Scope (H) =
1696                                 Enclosing_Dynamic_Scope (Id)
1697                        and then Ekind (H) = E_Variable
1698                        and then Is_Discrete_Type (Etype (H))
1699                      then
1700                         Set_Hiding_Loop_Variable (H, Id);
1701                      end if;
1702                   end;
1703
1704                   --  Now analyze the subtype definition. If it is
1705                   --  a range, create temporaries for bounds.
1706
1707                   if Nkind (DS) = N_Range
1708                     and then Expander_Active
1709                   then
1710                      Process_Bounds (DS);
1711                   else
1712                      Analyze (DS);
1713                   end if;
1714
1715                   if DS = Error then
1716                      return;
1717                   end if;
1718
1719                   --  The subtype indication may denote the completion
1720                   --  of an incomplete type declaration.
1721
1722                   if Is_Entity_Name (DS)
1723                     and then Present (Entity (DS))
1724                     and then Is_Type (Entity (DS))
1725                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1726                   then
1727                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1728                      Set_Etype  (DS, Entity (DS));
1729                   end if;
1730
1731                   if not Is_Discrete_Type (Etype (DS)) then
1732                      Wrong_Type (DS, Any_Discrete);
1733                      Set_Etype (DS, Any_Type);
1734                   end if;
1735
1736                   Check_Controlled_Array_Attribute (DS);
1737
1738                   Make_Index (DS, LP);
1739
1740                   Set_Ekind          (Id, E_Loop_Parameter);
1741                   Set_Etype          (Id, Etype (DS));
1742                   Set_Is_Known_Valid (Id, True);
1743
1744                   --  The loop is not a declarative part, so the only entity
1745                   --  declared "within" must be frozen explicitly.
1746
1747                   declare
1748                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1749                   begin
1750                      if Is_Non_Empty_List (Flist) then
1751                         Insert_Actions (N, Flist);
1752                      end if;
1753                   end;
1754
1755                   --  Check for null or possibly null range and issue warning.
1756                   --  We suppress such messages in generic templates and
1757                   --  instances, because in practice they tend to be dubious
1758                   --  in these cases.
1759
1760                   if Nkind (DS) = N_Range
1761                     and then Comes_From_Source (N)
1762                   then
1763                      declare
1764                         L : constant Node_Id := Low_Bound  (DS);
1765                         H : constant Node_Id := High_Bound (DS);
1766
1767                         Llo : Uint;
1768                         Lhi : Uint;
1769                         LOK : Boolean;
1770                         Hlo : Uint;
1771                         Hhi : Uint;
1772                         HOK : Boolean;
1773
1774                      begin
1775                         Determine_Range (L, LOK, Llo, Lhi);
1776                         Determine_Range (H, HOK, Hlo, Hhi);
1777
1778                         --  If range of loop is null, issue warning
1779
1780                         if (LOK and HOK) and then Llo > Hhi then
1781
1782                            --  Suppress the warning if inside a generic
1783                            --  template or instance, since in practice
1784                            --  they tend to be dubious in these cases since
1785                            --  they can result from intended parametrization.
1786
1787                            if not Inside_A_Generic
1788                               and then not In_Instance
1789                            then
1790                               Error_Msg_N
1791                                 ("?loop range is null, loop will not execute",
1792                                  DS);
1793                            end if;
1794
1795                            --  Since we know the range of the loop is null,
1796                            --  set the appropriate flag to suppress any
1797                            --  warnings that would otherwise be issued in
1798                            --  the body of the loop that will not execute.
1799                            --  We do this even in the generic case, since
1800                            --  if it is dubious to warn on the null loop
1801                            --  itself, it is certainly dubious to warn for
1802                            --  conditions that occur inside it!
1803
1804                            Set_Is_Null_Loop (Parent (N));
1805
1806                         --  The other case for a warning is a reverse loop
1807                         --  where the upper bound is the integer literal
1808                         --  zero or one, and the lower bound can be positive.
1809
1810                         --  For example, we have
1811
1812                         --     for J in reverse N .. 1 loop
1813
1814                         --  In practice, this is very likely to be a case
1815                         --  of reversing the bounds incorrectly in the range.
1816
1817                         elsif Reverse_Present (LP)
1818                           and then Nkind (Original_Node (H)) =
1819                                                           N_Integer_Literal
1820                           and then (Intval (H) = Uint_0
1821                                       or else
1822                                     Intval (H) = Uint_1)
1823                           and then Lhi > Hhi
1824                         then
1825                            Error_Msg_N ("?loop range may be null", DS);
1826                            Error_Msg_N ("\?bounds may be wrong way round", DS);
1827                         end if;
1828                      end;
1829                   end if;
1830                end;
1831             end if;
1832          end;
1833       end if;
1834    end Analyze_Iteration_Scheme;
1835
1836    -------------------
1837    -- Analyze_Label --
1838    -------------------
1839
1840    --  Note: the semantic work required for analyzing labels (setting them as
1841    --  reachable) was done in a prepass through the statements in the block,
1842    --  so that forward gotos would be properly handled. See Analyze_Statements
1843    --  for further details. The only processing required here is to deal with
1844    --  optimizations that depend on an assumption of sequential control flow,
1845    --  since of course the occurrence of a label breaks this assumption.
1846
1847    procedure Analyze_Label (N : Node_Id) is
1848       pragma Warnings (Off, N);
1849    begin
1850       Kill_Current_Values;
1851    end Analyze_Label;
1852
1853    --------------------------
1854    -- Analyze_Label_Entity --
1855    --------------------------
1856
1857    procedure Analyze_Label_Entity (E : Entity_Id) is
1858    begin
1859       Set_Ekind           (E, E_Label);
1860       Set_Etype           (E, Standard_Void_Type);
1861       Set_Enclosing_Scope (E, Current_Scope);
1862       Set_Reachable       (E, True);
1863    end Analyze_Label_Entity;
1864
1865    ----------------------------
1866    -- Analyze_Loop_Statement --
1867    ----------------------------
1868
1869    procedure Analyze_Loop_Statement (N : Node_Id) is
1870       Loop_Statement : constant Node_Id := N;
1871
1872       Id   : constant Node_Id := Identifier (Loop_Statement);
1873       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
1874       Ent  : Entity_Id;
1875
1876    begin
1877       if Present (Id) then
1878
1879          --  Make name visible, e.g. for use in exit statements. Loop
1880          --  labels are always considered to be referenced.
1881
1882          Analyze (Id);
1883          Ent := Entity (Id);
1884          Generate_Reference  (Ent, Loop_Statement, ' ');
1885          Generate_Definition (Ent);
1886
1887          --  If we found a label, mark its type. If not, ignore it, since it
1888          --  means we have a conflicting declaration, which would already have
1889          --  been diagnosed at declaration time. Set Label_Construct of the
1890          --  implicit label declaration, which is not created by the parser
1891          --  for generic units.
1892
1893          if Ekind (Ent) = E_Label then
1894             Set_Ekind (Ent, E_Loop);
1895
1896             if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
1897                Set_Label_Construct (Parent (Ent), Loop_Statement);
1898             end if;
1899          end if;
1900
1901       --  Case of no identifier present
1902
1903       else
1904          Ent :=
1905            New_Internal_Entity
1906              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
1907          Set_Etype (Ent,  Standard_Void_Type);
1908          Set_Parent (Ent, Loop_Statement);
1909       end if;
1910
1911       --  Kill current values on entry to loop, since statements in body
1912       --  of loop may have been executed before the loop is entered.
1913       --  Similarly we kill values after the loop, since we do not know
1914       --  that the body of the loop was executed.
1915
1916       Kill_Current_Values;
1917       Push_Scope (Ent);
1918       Analyze_Iteration_Scheme (Iter);
1919       Analyze_Statements (Statements (Loop_Statement));
1920       Process_End_Label (Loop_Statement, 'e', Ent);
1921       End_Scope;
1922       Kill_Current_Values;
1923       Check_Infinite_Loop_Warning (N);
1924    end Analyze_Loop_Statement;
1925
1926    ----------------------------
1927    -- Analyze_Null_Statement --
1928    ----------------------------
1929
1930    --  Note: the semantics of the null statement is implemented by a single
1931    --  null statement, too bad everything isn't as simple as this!
1932
1933    procedure Analyze_Null_Statement (N : Node_Id) is
1934       pragma Warnings (Off, N);
1935    begin
1936       null;
1937    end Analyze_Null_Statement;
1938
1939    ------------------------
1940    -- Analyze_Statements --
1941    ------------------------
1942
1943    procedure Analyze_Statements (L : List_Id) is
1944       S   : Node_Id;
1945       Lab : Entity_Id;
1946
1947    begin
1948       --  The labels declared in the statement list are reachable from
1949       --  statements in the list. We do this as a prepass so that any
1950       --  goto statement will be properly flagged if its target is not
1951       --  reachable. This is not required, but is nice behavior!
1952
1953       S := First (L);
1954       while Present (S) loop
1955          if Nkind (S) = N_Label then
1956             Analyze (Identifier (S));
1957             Lab := Entity (Identifier (S));
1958
1959             --  If we found a label mark it as reachable
1960
1961             if Ekind (Lab) = E_Label then
1962                Generate_Definition (Lab);
1963                Set_Reachable (Lab);
1964
1965                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
1966                   Set_Label_Construct (Parent (Lab), S);
1967                end if;
1968
1969             --  If we failed to find a label, it means the implicit declaration
1970             --  of the label was hidden.  A for-loop parameter can do this to
1971             --  a label with the same name inside the loop, since the implicit
1972             --  label declaration is in the innermost enclosing body or block
1973             --  statement.
1974
1975             else
1976                Error_Msg_Sloc := Sloc (Lab);
1977                Error_Msg_N
1978                  ("implicit label declaration for & is hidden#",
1979                   Identifier (S));
1980             end if;
1981          end if;
1982
1983          Next (S);
1984       end loop;
1985
1986       --  Perform semantic analysis on all statements
1987
1988       Conditional_Statements_Begin;
1989
1990       S := First (L);
1991       while Present (S) loop
1992          Analyze (S);
1993          Next (S);
1994       end loop;
1995
1996       Conditional_Statements_End;
1997
1998       --  Make labels unreachable. Visibility is not sufficient, because
1999       --  labels in one if-branch for example are not reachable from the
2000       --  other branch, even though their declarations are in the enclosing
2001       --  declarative part.
2002
2003       S := First (L);
2004       while Present (S) loop
2005          if Nkind (S) = N_Label then
2006             Set_Reachable (Entity (Identifier (S)), False);
2007          end if;
2008
2009          Next (S);
2010       end loop;
2011    end Analyze_Statements;
2012
2013    ----------------------------
2014    -- Check_Unreachable_Code --
2015    ----------------------------
2016
2017    procedure Check_Unreachable_Code (N : Node_Id) is
2018       Error_Loc : Source_Ptr;
2019       P         : Node_Id;
2020
2021    begin
2022       if Is_List_Member (N)
2023         and then Comes_From_Source (N)
2024       then
2025          declare
2026             Nxt : Node_Id;
2027
2028          begin
2029             Nxt := Original_Node (Next (N));
2030
2031             --  If a label follows us, then we never have dead code, since
2032             --  someone could branch to the label, so we just ignore it.
2033
2034             if Nkind (Nxt) = N_Label then
2035                return;
2036
2037             --  Otherwise see if we have a real statement following us
2038
2039             elsif Present (Nxt)
2040               and then Comes_From_Source (Nxt)
2041               and then Is_Statement (Nxt)
2042             then
2043                --  Special very annoying exception. If we have a return that
2044                --  follows a raise, then we allow it without a warning, since
2045                --  the Ada RM annoyingly requires a useless return here!
2046
2047                if Nkind (Original_Node (N)) /= N_Raise_Statement
2048                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2049                then
2050                   --  The rather strange shenanigans with the warning message
2051                   --  here reflects the fact that Kill_Dead_Code is very good
2052                   --  at removing warnings in deleted code, and this is one
2053                   --  warning we would prefer NOT to have removed.
2054
2055                   Error_Loc := Sloc (Nxt);
2056
2057                   --  If we have unreachable code, analyze and remove the
2058                   --  unreachable code, since it is useless and we don't
2059                   --  want to generate junk warnings.
2060
2061                   --  We skip this step if we are not in code generation mode.
2062                   --  This is the one case where we remove dead code in the
2063                   --  semantics as opposed to the expander, and we do not want
2064                   --  to remove code if we are not in code generation mode,
2065                   --  since this messes up the ASIS trees.
2066
2067                   --  Note that one might react by moving the whole circuit to
2068                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2069
2070                   if Operating_Mode = Generate_Code then
2071                      loop
2072                         Nxt := Next (N);
2073
2074                         --  Quit deleting when we have nothing more to delete
2075                         --  or if we hit a label (since someone could transfer
2076                         --  control to a label, so we should not delete it).
2077
2078                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2079
2080                         --  Statement/declaration is to be deleted
2081
2082                         Analyze (Nxt);
2083                         Remove (Nxt);
2084                         Kill_Dead_Code (Nxt);
2085                      end loop;
2086                   end if;
2087
2088                   --  Now issue the warning
2089
2090                   Error_Msg ("?unreachable code!", Error_Loc);
2091                end if;
2092
2093             --  If the unconditional transfer of control instruction is
2094             --  the last statement of a sequence, then see if our parent
2095             --  is one of the constructs for which we count unblocked exits,
2096             --  and if so, adjust the count.
2097
2098             else
2099                P := Parent (N);
2100
2101                --  Statements in THEN part or ELSE part of IF statement
2102
2103                if Nkind (P) = N_If_Statement then
2104                   null;
2105
2106                --  Statements in ELSIF part of an IF statement
2107
2108                elsif Nkind (P) = N_Elsif_Part then
2109                   P := Parent (P);
2110                   pragma Assert (Nkind (P) = N_If_Statement);
2111
2112                --  Statements in CASE statement alternative
2113
2114                elsif Nkind (P) = N_Case_Statement_Alternative then
2115                   P := Parent (P);
2116                   pragma Assert (Nkind (P) = N_Case_Statement);
2117
2118                --  Statements in body of block
2119
2120                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2121                  and then Nkind (Parent (P)) = N_Block_Statement
2122                then
2123                   null;
2124
2125                --  Statements in exception handler in a block
2126
2127                elsif Nkind (P) = N_Exception_Handler
2128                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2129                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2130                then
2131                   null;
2132
2133                --  None of these cases, so return
2134
2135                else
2136                   return;
2137                end if;
2138
2139                --  This was one of the cases we are looking for (i.e. the
2140                --  parent construct was IF, CASE or block) so decrement count.
2141
2142                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2143             end if;
2144          end;
2145       end if;
2146    end Check_Unreachable_Code;
2147
2148 end Sem_Ch5;