gcc/ada/sem_ch4.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 4                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Debug;    use Debug;
  28 with Einfo;    use Einfo;
  29 with Elists;   use Elists;
  30 with Errout;   use Errout;
  31 with Exp_Util; use Exp_Util;
  32 with Fname;    use Fname;
  33 with Itypes;   use Itypes;
  34 with Lib;      use Lib;
  35 with Lib.Xref; use Lib.Xref;
  36 with Namet;    use Namet;
  37 with Namet.Sp; use Namet.Sp;
  38 with Nlists;   use Nlists;
  39 with Nmake;    use Nmake;
  40 with Opt;      use Opt;
  41 with Output;   use Output;
  42 with Restrict; use Restrict;
  43 with Rident;   use Rident;
  44 with Sem;      use Sem;
  45 with Sem_Aux;  use Sem_Aux;
  46 with Sem_Case; use Sem_Case;
  47 with Sem_Cat;  use Sem_Cat;
  48 with Sem_Ch3;  use Sem_Ch3;
  49 with Sem_Ch5;  use Sem_Ch5;
  50 with Sem_Ch6;  use Sem_Ch6;
  51 with Sem_Ch8;  use Sem_Ch8;
  52 with Sem_Disp; use Sem_Disp;
  53 with Sem_Dist; use Sem_Dist;
  54 with Sem_Eval; use Sem_Eval;
  55 with Sem_Res;  use Sem_Res;
  56 with Sem_Type; use Sem_Type;
  57 with Sem_Util; use Sem_Util;
  58 with Sem_Warn; use Sem_Warn;
  59 with Stand;    use Stand;
  60 with Sinfo;    use Sinfo;
  61 with Snames;   use Snames;
  62 with Tbuild;   use Tbuild;
  63
  64 package body Sem_Ch4 is
  65
  66    -----------------------
  67    -- Local Subprograms --
  68    -----------------------
  69
  70    procedure Analyze_Concatenation_Rest (N : Node_Id);
  71    --  Does the "rest" of the work of Analyze_Concatenation, after the left
  72    --  operand has been analyzed. See Analyze_Concatenation for details.
  73
  74    procedure Analyze_Expression (N : Node_Id);
  75    --  For expressions that are not names, this is just a call to analyze.
  76    --  If the expression is a name, it may be a call to a parameterless
  77    --  function, and if so must be converted into an explicit call node
  78    --  and analyzed as such. This deproceduring must be done during the first
  79    --  pass of overload resolution, because otherwise a procedure call with
  80    --  overloaded actuals may fail to resolve.
  81
  82    procedure Analyze_Operator_Call (N : Node_Id; Op_Id : Entity_Id);
  83    --  Analyze a call of the form "+"(x, y), etc. The prefix of the call
  84    --  is an operator name or an expanded name whose selector is an operator
  85    --  name, and one possible interpretation is as a predefined operator.
  86
  87    procedure Analyze_Overloaded_Selected_Component (N : Node_Id);
  88    --  If the prefix of a selected_component is overloaded, the proper
  89    --  interpretation that yields a record type with the proper selector
  90    --  name must be selected.
  91
  92    procedure Analyze_User_Defined_Binary_Op (N : Node_Id; Op_Id : Entity_Id);
  93    --  Procedure to analyze a user defined binary operator, which is resolved
  94    --  like a function, but instead of a list of actuals it is presented
  95    --  with the left and right operands of an operator node.
  96
  97    procedure Analyze_User_Defined_Unary_Op (N : Node_Id; Op_Id : Entity_Id);
  98    --  Procedure to analyze a user defined unary operator, which is resolved
  99    --  like a function, but instead of a list of actuals, it is presented with
 100    --  the operand of the operator node.
 101
 102    procedure Ambiguous_Operands (N : Node_Id);
 103    --  For equality, membership, and comparison operators with overloaded
 104    --  arguments, list possible interpretations.
 105
 106    procedure Analyze_One_Call
 107       (N          : Node_Id;
 108        Nam        : Entity_Id;
 109        Report     : Boolean;
 110        Success    : out Boolean;
 111        Skip_First : Boolean := False);
 112    --  Check one interpretation of an overloaded subprogram name for
 113    --  compatibility with the types of the actuals in a call. If there is a
 114    --  single interpretation which does not match, post error if Report is
 115    --  set to True.
 116    --
 117    --  Nam is the entity that provides the formals against which the actuals
 118    --  are checked. Nam is either the name of a subprogram, or the internal
 119    --  subprogram type constructed for an access_to_subprogram. If the actuals
 120    --  are compatible with Nam, then Nam is added to the list of candidate
 121    --  interpretations for N, and Success is set to True.
 122    --
 123    --  The flag Skip_First is used when analyzing a call that was rewritten
 124    --  from object notation. In this case the first actual may have to receive
 125    --  an explicit dereference, depending on the first formal of the operation
 126    --  being called. The caller will have verified that the object is legal
 127    --  for the call. If the remaining parameters match, the first parameter
 128    --  will rewritten as a dereference if needed, prior to completing analysis.
 129
 130    procedure Check_Misspelled_Selector
 131      (Prefix : Entity_Id;
 132       Sel    : Node_Id);
 133    --  Give possible misspelling diagnostic if Sel is likely to be a mis-
 134    --  spelling of one of the selectors of the Prefix. This is called by
 135    --  Analyze_Selected_Component after producing an invalid selector error
 136    --  message.
 137
 138    function Defined_In_Scope (T : Entity_Id; S : Entity_Id) return Boolean;
 139    --  Verify that type T is declared in scope S. Used to find interpretations
 140    --  for operators given by expanded names. This is abstracted as a separate
 141    --  function to handle extensions to System, where S is System, but T is
 142    --  declared in the extension.
 143
 144    procedure Find_Arithmetic_Types
 145      (L, R  : Node_Id;
 146       Op_Id : Entity_Id;
 147       N     : Node_Id);
 148    --  L and R are the operands of an arithmetic operator. Find
 149    --  consistent pairs of interpretations for L and R that have a
 150    --  numeric type consistent with the semantics of the operator.
 151
 152    procedure Find_Comparison_Types
 153      (L, R  : Node_Id;
 154       Op_Id : Entity_Id;
 155       N     : Node_Id);
 156    --  L and R are operands of a comparison operator. Find consistent
 157    --  pairs of interpretations for L and R.
 158
 159    procedure Find_Concatenation_Types
 160      (L, R  : Node_Id;
 161       Op_Id : Entity_Id;
 162       N     : Node_Id);
 163    --  For the four varieties of concatenation
 164
 165    procedure Find_Equality_Types
 166      (L, R  : Node_Id;
 167       Op_Id : Entity_Id;
 168       N     : Node_Id);
 169    --  Ditto for equality operators
 170
 171    procedure Find_Boolean_Types
 172      (L, R  : Node_Id;
 173       Op_Id : Entity_Id;
 174       N     : Node_Id);
 175    --  Ditto for binary logical operations
 176
 177    procedure Find_Negation_Types
 178      (R     : Node_Id;
 179       Op_Id : Entity_Id;
 180       N     : Node_Id);
 181    --  Find consistent interpretation for operand of negation operator
 182
 183    procedure Find_Non_Universal_Interpretations
 184      (N     : Node_Id;
 185       R     : Node_Id;
 186       Op_Id : Entity_Id;
 187       T1    : Entity_Id);
 188    --  For equality and comparison operators, the result is always boolean,
 189    --  and the legality of the operation is determined from the visibility
 190    --  of the operand types. If one of the operands has a universal interpre-
 191    --  tation,  the legality check uses some compatible non-universal
 192    --  interpretation of the other operand. N can be an operator node, or
 193    --  a function call whose name is an operator designator.
 194
 195    function Find_Primitive_Operation (N : Node_Id) return Boolean;
 196    --  Find candidate interpretations for the name Obj.Proc when it appears
 197    --  in a subprogram renaming declaration.
 198
 199    procedure Find_Unary_Types
 200      (R     : Node_Id;
 201       Op_Id : Entity_Id;
 202       N     : Node_Id);
 203    --  Unary arithmetic types: plus, minus, abs
 204
 205    procedure Check_Arithmetic_Pair
 206      (T1, T2 : Entity_Id;
 207       Op_Id  : Entity_Id;
 208       N      : Node_Id);
 209    --  Subsidiary procedure to Find_Arithmetic_Types. T1 and T2 are valid
 210    --  types for left and right operand. Determine whether they constitute
 211    --  a valid pair for the given operator, and record the corresponding
 212    --  interpretation of the operator node. The node N may be an operator
 213    --  node (the usual case) or a function call whose prefix is an operator
 214    --  designator. In both cases Op_Id is the operator name itself.
 215
 216    procedure Diagnose_Call (N : Node_Id; Nam : Node_Id);
 217    --  Give detailed information on overloaded call where none of the
 218    --  interpretations match. N is the call node, Nam the designator for
 219    --  the overloaded entity being called.
 220
 221    function Junk_Operand (N : Node_Id) return Boolean;
 222    --  Test for an operand that is an inappropriate entity (e.g. a package
 223    --  name or a label). If so, issue an error message and return True. If
 224    --  the operand is not an inappropriate entity kind, return False.
 225
 226    procedure Operator_Check (N : Node_Id);
 227    --  Verify that an operator has received some valid interpretation. If none
 228    --  was found, determine whether a use clause would make the operation
 229    --  legal. The variable Candidate_Type (defined in Sem_Type) is set for
 230    --  every type compatible with the operator, even if the operator for the
 231    --  type is not directly visible. The routine uses this type to emit a more
 232    --  informative message.
 233
 234    function Process_Implicit_Dereference_Prefix
 235      (E : Entity_Id;
 236       P : Node_Id) return Entity_Id;
 237    --  Called when P is the prefix of an implicit dereference, denoting an
 238    --  object E. The function returns the designated type of the prefix, taking
 239    --  into account that the designated type of an anonymous access type may be
 240    --  a limited view, when the non-limited view is visible.
 241    --  If in semantics only mode (-gnatc or generic), the function also records
 242    --  that the prefix is a reference to E, if any. Normally, such a reference
 243    --  is generated only when the implicit dereference is expanded into an
 244    --  explicit one, but for consistency we must generate the reference when
 245    --  expansion is disabled as well.
 246
 247    procedure Remove_Abstract_Operations (N : Node_Id);
 248    --  Ada 2005: implementation of AI-310. An abstract non-dispatching
 249    --  operation is not a candidate interpretation.
 250
 251    function Try_Indexed_Call
 252      (N          : Node_Id;
 253       Nam        : Entity_Id;
 254       Typ        : Entity_Id;
 255       Skip_First : Boolean) return Boolean;
 256    --  If a function has defaults for all its actuals, a call to it may in fact
 257    --  be an indexing on the result of the call. Try_Indexed_Call attempts the
 258    --  interpretation as an indexing, prior to analysis as a call. If both are
 259    --  possible, the node is overloaded with both interpretations (same symbol
 260    --  but two different types). If the call is written in prefix form, the
 261    --  prefix becomes the first parameter in the call, and only the remaining
 262    --  actuals must be checked for the presence of defaults.
 263
 264    function Try_Indirect_Call
 265      (N   : Node_Id;
 266       Nam : Entity_Id;
 267       Typ : Entity_Id) return Boolean;
 268    --  Similarly, a function F that needs no actuals can return an access to a
 269    --  subprogram, and the call F (X) interpreted as F.all (X). In this case
 270    --  the call may be overloaded with both interpretations.
 271
 272    function Try_Object_Operation (N : Node_Id) return Boolean;
 273    --  Ada 2005 (AI-252): Support the object.operation notation. If node N
 274    --  is a call in this notation, it is transformed into a normal subprogram
 275    --  call where the prefix is a parameter, and True is returned. If node
 276    --  N is not of this form, it is unchanged, and False is returned.
 277
 278    procedure wpo (T : Entity_Id);
 279    pragma Warnings (Off, wpo);
 280    --  Used for debugging: obtain list of primitive operations even if
 281    --  type is not frozen and dispatch table is not built yet.
 282
 283    ------------------------
 284    -- Ambiguous_Operands --
 285    ------------------------
 286
 287    procedure Ambiguous_Operands (N : Node_Id) is
 288       procedure List_Operand_Interps (Opnd : Node_Id);
 289
 290       --------------------------
 291       -- List_Operand_Interps --
 292       --------------------------
 293
 294       procedure List_Operand_Interps (Opnd : Node_Id) is
 295          Nam   : Node_Id;
 296          Err   : Node_Id := N;
 297
 298       begin
 299          if Is_Overloaded (Opnd) then
 300             if Nkind (Opnd) in N_Op then
 301                Nam := Opnd;
 302             elsif Nkind (Opnd) = N_Function_Call then
 303                Nam := Name (Opnd);
 304             else
 305                return;
 306             end if;
 307
 308          else
 309             return;
 310          end if;
 311
 312          if Opnd = Left_Opnd (N) then
 313             Error_Msg_N ("\left operand has the following interpretations", N);
 314          else
 315             Error_Msg_N
 316               ("\right operand has the following interpretations", N);
 317             Err := Opnd;
 318          end if;
 319
 320          List_Interps (Nam, Err);
 321       end List_Operand_Interps;
 322
 323    --  Start of processing for Ambiguous_Operands
 324
 325    begin
 326       if Nkind (N) in N_Membership_Test then
 327          Error_Msg_N ("ambiguous operands for membership",  N);
 328
 329       elsif Nkind_In (N, N_Op_Eq, N_Op_Ne) then
 330          Error_Msg_N ("ambiguous operands for equality",  N);
 331
 332       else
 333          Error_Msg_N ("ambiguous operands for comparison",  N);
 334       end if;
 335
 336       if All_Errors_Mode then
 337          List_Operand_Interps (Left_Opnd  (N));
 338          List_Operand_Interps (Right_Opnd (N));
 339       else
 340          Error_Msg_N ("\use -gnatf switch for details", N);
 341       end if;
 342    end Ambiguous_Operands;
 343
 344    -----------------------
 345    -- Analyze_Aggregate --
 346    -----------------------
 347
 348    --  Most of the analysis of Aggregates requires that the type be known,
 349    --  and is therefore put off until resolution.
 350
 351    procedure Analyze_Aggregate (N : Node_Id) is
 352    begin
 353       if No (Etype (N)) then
 354          Set_Etype (N, Any_Composite);
 355       end if;
 356    end Analyze_Aggregate;
 357
 358    -----------------------
 359    -- Analyze_Allocator --
 360    -----------------------
 361
 362    procedure Analyze_Allocator (N : Node_Id) is
 363       Loc      : constant Source_Ptr := Sloc (N);
 364       Sav_Errs : constant Nat        := Serious_Errors_Detected;
 365       E        : Node_Id             := Expression (N);
 366       Acc_Type : Entity_Id;
 367       Type_Id  : Entity_Id;
 368       P        : Node_Id;
 369       C        : Node_Id;
 370
 371    begin
 372       --  Deal with allocator restrictions
 373
 374       --  In accordance with H.4(7), the No_Allocators restriction only applies
 375       --  to user-written allocators. The same consideration applies to the
 376       --  No_Allocators_Before_Elaboration restriction.
 377
 378       if Comes_From_Source (N) then
 379          Check_Restriction (No_Allocators, N);
 380
 381          --  Processing for No_Allocators_After_Elaboration, loop to look at
 382          --  enclosing context, checking task case and main subprogram case.
 383
 384          C := N;
 385          P := Parent (C);
 386          while Present (P) loop
 387
 388             --  In both cases we need a handled sequence of statements, where
 389             --  the occurrence of the allocator is within the statements.
 390
 391             if Nkind (P) = N_Handled_Sequence_Of_Statements
 392               and then Is_List_Member (C)
 393               and then List_Containing (C) = Statements (P)
 394             then
 395                --  Check for allocator within task body, this is a definite
 396                --  violation of No_Allocators_After_Elaboration we can detect.
 397
 398                if Nkind (Original_Node (Parent (P))) = N_Task_Body then
 399                   Check_Restriction (No_Allocators_After_Elaboration, N);
 400                   exit;
 401                end if;
 402
 403                --  The other case is appearence in a subprogram body. This may
 404                --  be a violation if this is a library level subprogram, and it
 405                --  turns out to be used as the main program, but only the
 406                --  binder knows that, so just record the occurrence.
 407
 408                if Nkind (Original_Node (Parent (P))) = N_Subprogram_Body
 409                  and then Nkind (Parent (Parent (P))) = N_Compilation_Unit
 410                then
 411                   Set_Has_Allocator (Current_Sem_Unit);
 412                end if;
 413             end if;
 414
 415             C := P;
 416             P := Parent (C);
 417          end loop;
 418       end if;
 419
 420       --  Analyze the allocator
 421
 422       if Nkind (E) = N_Qualified_Expression then
 423          Acc_Type := Create_Itype (E_Allocator_Type, N);
 424          Set_Etype (Acc_Type, Acc_Type);
 425          Find_Type (Subtype_Mark (E));
 426
 427          --  Analyze the qualified expression, and apply the name resolution
 428          --  rule given in  4.7 (3).
 429
 430          Analyze (E);
 431          Type_Id := Etype (E);
 432          Set_Directly_Designated_Type (Acc_Type, Type_Id);
 433
 434          Resolve (Expression (E), Type_Id);
 435
 436          if Is_Limited_Type (Type_Id)
 437            and then Comes_From_Source (N)
 438            and then not In_Instance_Body
 439          then
 440             if not OK_For_Limited_Init (Type_Id, Expression (E)) then
 441                Error_Msg_N ("initialization not allowed for limited types", N);
 442                Explain_Limited_Type (Type_Id, N);
 443             end if;
 444          end if;
 445
 446          --  A qualified expression requires an exact match of the type,
 447          --  class-wide matching is not allowed.
 448
 449          --  if Is_Class_Wide_Type (Type_Id)
 450          --    and then Base_Type
 451          --       (Etype (Expression (E))) /= Base_Type (Type_Id)
 452          --  then
 453          --     Wrong_Type (Expression (E), Type_Id);
 454          --  end if;
 455
 456          Check_Non_Static_Context (Expression (E));
 457
 458          --  We don't analyze the qualified expression itself because it's
 459          --  part of the allocator
 460
 461          Set_Etype  (E, Type_Id);
 462
 463       --  Case where allocator has a subtype indication
 464
 465       else
 466          declare
 467             Def_Id   : Entity_Id;
 468             Base_Typ : Entity_Id;
 469
 470          begin
 471             --  If the allocator includes a N_Subtype_Indication then a
 472             --  constraint is present, otherwise the node is a subtype mark.
 473             --  Introduce an explicit subtype declaration into the tree
 474             --  defining some anonymous subtype and rewrite the allocator to
 475             --  use this subtype rather than the subtype indication.
 476
 477             --  It is important to introduce the explicit subtype declaration
 478             --  so that the bounds of the subtype indication are attached to
 479             --  the tree in case the allocator is inside a generic unit.
 480
 481             if Nkind (E) = N_Subtype_Indication then
 482
 483                --  A constraint is only allowed for a composite type in Ada
 484                --  95. In Ada 83, a constraint is also allowed for an
 485                --  access-to-composite type, but the constraint is ignored.
 486
 487                Find_Type (Subtype_Mark (E));
 488                Base_Typ := Entity (Subtype_Mark (E));
 489
 490                if Is_Elementary_Type (Base_Typ) then
 491                   if not (Ada_Version = Ada_83
 492                            and then Is_Access_Type (Base_Typ))
 493                   then
 494                      Error_Msg_N ("constraint not allowed here", E);
 495
 496                      if Nkind (Constraint (E)) =
 497                        N_Index_Or_Discriminant_Constraint
 498                      then
 499                         Error_Msg_N -- CODEFIX
 500                           ("\if qualified expression was meant, " &
 501                               "use apostrophe", Constraint (E));
 502                      end if;
 503                   end if;
 504
 505                   --  Get rid of the bogus constraint:
 506
 507                   Rewrite (E, New_Copy_Tree (Subtype_Mark (E)));
 508                   Analyze_Allocator (N);
 509                   return;
 510
 511                --  Ada 2005, AI-363: if the designated type has a constrained
 512                --  partial view, it cannot receive a discriminant constraint,
 513                --  and the allocated object is unconstrained.
 514
 515                elsif Ada_Version >= Ada_2005
 516                  and then Has_Constrained_Partial_View (Base_Typ)
 517                then
 518                   Error_Msg_N
 519                     ("constraint no allowed when type " &
 520                       "has a constrained partial view", Constraint (E));
 521                end if;
 522
 523                if Expander_Active then
 524                   Def_Id := Make_Temporary (Loc, 'S');
 525
 526                   Insert_Action (E,
 527                     Make_Subtype_Declaration (Loc,
 528                       Defining_Identifier => Def_Id,
 529                       Subtype_Indication  => Relocate_Node (E)));
 530
 531                   if Sav_Errs /= Serious_Errors_Detected
 532                     and then Nkind (Constraint (E)) =
 533                                N_Index_Or_Discriminant_Constraint
 534                   then
 535                      Error_Msg_N -- CODEFIX
 536                        ("if qualified expression was meant, " &
 537                            "use apostrophe!", Constraint (E));
 538                   end if;
 539
 540                   E := New_Occurrence_Of (Def_Id, Loc);
 541                   Rewrite (Expression (N), E);
 542                end if;
 543             end if;
 544
 545             Type_Id := Process_Subtype (E, N);
 546             Acc_Type := Create_Itype (E_Allocator_Type, N);
 547             Set_Etype                    (Acc_Type, Acc_Type);
 548             Set_Directly_Designated_Type (Acc_Type, Type_Id);
 549             Check_Fully_Declared (Type_Id, N);
 550
 551             --  Ada 2005 (AI-231): If the designated type is itself an access
 552             --  type that excludes null, its default initialization will
 553             --  be a null object, and we can insert an unconditional raise
 554             --  before the allocator.
 555
 556             --  Ada 2012 (AI-104): A not null indication here is altogether
 557             --  illegal.
 558
 559             if Can_Never_Be_Null (Type_Id) then
 560                declare
 561                   Not_Null_Check : constant Node_Id :=
 562                                      Make_Raise_Constraint_Error (Sloc (E),
 563                                        Reason => CE_Null_Not_Allowed);
 564
 565                begin
 566                   if Ada_Version >= Ada_2012 then
 567                      Error_Msg_N
 568                        ("an uninitialized allocator cannot have"
 569                          & " a null exclusion", N);
 570
 571                   elsif Expander_Active then
 572                      Insert_Action (N, Not_Null_Check);
 573                      Analyze (Not_Null_Check);
 574
 575                   else
 576                      Error_Msg_N ("null value not allowed here?", E);
 577                   end if;
 578                end;
 579             end if;
 580
 581             --  Check restriction against dynamically allocated protected
 582             --  objects. Note that when limited aggregates are supported,
 583             --  a similar test should be applied to an allocator with a
 584             --  qualified expression ???
 585
 586             if Is_Protected_Type (Type_Id) then
 587                Check_Restriction (No_Protected_Type_Allocators, N);
 588             end if;
 589
 590             --  Check for missing initialization. Skip this check if we already
 591             --  had errors on analyzing the allocator, since in that case these
 592             --  are probably cascaded errors.
 593
 594             if Is_Indefinite_Subtype (Type_Id)
 595               and then Serious_Errors_Detected = Sav_Errs
 596             then
 597                if Is_Class_Wide_Type (Type_Id) then
 598                   Error_Msg_N
 599                     ("initialization required in class-wide allocation", N);
 600                else
 601                   if Ada_Version < Ada_2005
 602                     and then Is_Limited_Type (Type_Id)
 603                   then
 604                      Error_Msg_N ("unconstrained allocation not allowed", N);
 605
 606                      if Is_Array_Type (Type_Id) then
 607                         Error_Msg_N
 608                           ("\constraint with array bounds required", N);
 609
 610                      elsif Has_Unknown_Discriminants (Type_Id) then
 611                         null;
 612
 613                      else pragma Assert (Has_Discriminants (Type_Id));
 614                         Error_Msg_N
 615                           ("\constraint with discriminant values required", N);
 616                      end if;
 617
 618                   --  Limited Ada 2005 and general non-limited case
 619
 620                   else
 621                      Error_Msg_N
 622                        ("uninitialized unconstrained allocation not allowed",
 623                         N);
 624
 625                      if Is_Array_Type (Type_Id) then
 626                         Error_Msg_N
 627                           ("\qualified expression or constraint with " &
 628                            "array bounds required", N);
 629
 630                      elsif Has_Unknown_Discriminants (Type_Id) then
 631                         Error_Msg_N ("\qualified expression required", N);
 632
 633                      else pragma Assert (Has_Discriminants (Type_Id));
 634                         Error_Msg_N
 635                           ("\qualified expression or constraint with " &
 636                            "discriminant values required", N);
 637                      end if;
 638                   end if;
 639                end if;
 640             end if;
 641          end;
 642       end if;
 643
 644       if Is_Abstract_Type (Type_Id) then
 645          Error_Msg_N ("cannot allocate abstract object", E);
 646       end if;
 647
 648       if Has_Task (Designated_Type (Acc_Type)) then
 649          Check_Restriction (No_Tasking, N);
 650          Check_Restriction (Max_Tasks, N);
 651          Check_Restriction (No_Task_Allocators, N);
 652
 653          --  Check that an allocator with task parts isn't for a nested access
 654          --  type when restriction No_Task_Hierarchy applies.
 655
 656          if not Is_Library_Level_Entity (Acc_Type) then
 657             Check_Restriction (No_Task_Hierarchy, N);
 658          end if;
 659       end if;
 660
 661       --  Check that an allocator of a nested access type doesn't create a
 662       --  protected object when restriction No_Local_Protected_Objects applies.
 663       --  We don't have an equivalent to Has_Task for protected types, so only
 664       --  cases where the designated type itself is a protected type are
 665       --  currently checked. ???
 666
 667       if Is_Protected_Type (Designated_Type (Acc_Type))
 668         and then not Is_Library_Level_Entity (Acc_Type)
 669       then
 670          Check_Restriction (No_Local_Protected_Objects, N);
 671       end if;
 672
 673       --  If the No_Streams restriction is set, check that the type of the
 674       --  object is not, and does not contain, any subtype derived from
 675       --  Ada.Streams.Root_Stream_Type. Note that we guard the call to
 676       --  Has_Stream just for efficiency reasons. There is no point in
 677       --  spending time on a Has_Stream check if the restriction is not set.
 678
 679       if Restriction_Check_Required (No_Streams) then
 680          if Has_Stream (Designated_Type (Acc_Type)) then
 681             Check_Restriction (No_Streams, N);
 682          end if;
 683       end if;
 684
 685       Set_Etype (N, Acc_Type);
 686
 687       if not Is_Library_Level_Entity (Acc_Type) then
 688          Check_Restriction (No_Local_Allocators, N);
 689       end if;
 690
 691       if Serious_Errors_Detected > Sav_Errs then
 692          Set_Error_Posted (N);
 693          Set_Etype (N, Any_Type);
 694       end if;
 695    end Analyze_Allocator;
 696
 697    ---------------------------
 698    -- Analyze_Arithmetic_Op --
 699    ---------------------------
 700
 701    procedure Analyze_Arithmetic_Op (N : Node_Id) is
 702       L     : constant Node_Id := Left_Opnd (N);
 703       R     : constant Node_Id := Right_Opnd (N);
 704       Op_Id : Entity_Id;
 705
 706    begin
 707       Candidate_Type := Empty;
 708       Analyze_Expression (L);
 709       Analyze_Expression (R);
 710
 711       --  If the entity is already set, the node is the instantiation of a
 712       --  generic node with a non-local reference, or was manufactured by a
 713       --  call to Make_Op_xxx. In either case the entity is known to be valid,
 714       --  and we do not need to collect interpretations, instead we just get
 715       --  the single possible interpretation.
 716
 717       Op_Id := Entity (N);
 718
 719       if Present (Op_Id) then
 720          if Ekind (Op_Id) = E_Operator then
 721
 722             if Nkind_In (N, N_Op_Divide, N_Op_Mod, N_Op_Multiply, N_Op_Rem)
 723               and then Treat_Fixed_As_Integer (N)
 724             then
 725                null;
 726             else
 727                Set_Etype (N, Any_Type);
 728                Find_Arithmetic_Types (L, R, Op_Id, N);
 729             end if;
 730
 731          else
 732             Set_Etype (N, Any_Type);
 733             Add_One_Interp (N, Op_Id, Etype (Op_Id));
 734          end if;
 735
 736       --  Entity is not already set, so we do need to collect interpretations
 737
 738       else
 739          Op_Id := Get_Name_Entity_Id (Chars (N));
 740          Set_Etype (N, Any_Type);
 741
 742          while Present (Op_Id) loop
 743             if Ekind (Op_Id) = E_Operator
 744               and then Present (Next_Entity (First_Entity (Op_Id)))
 745             then
 746                Find_Arithmetic_Types (L, R, Op_Id, N);
 747
 748             --  The following may seem superfluous, because an operator cannot
 749             --  be generic, but this ignores the cleverness of the author of
 750             --  ACVC bc1013a.
 751
 752             elsif Is_Overloadable (Op_Id) then
 753                Analyze_User_Defined_Binary_Op (N, Op_Id);
 754             end if;
 755
 756             Op_Id := Homonym (Op_Id);
 757          end loop;
 758       end if;
 759
 760       Operator_Check (N);
 761    end Analyze_Arithmetic_Op;
 762
 763    ------------------
 764    -- Analyze_Call --
 765    ------------------
 766
 767    --  Function, procedure, and entry calls are checked here. The Name in
 768    --  the call may be overloaded. The actuals have been analyzed and may
 769    --  themselves be overloaded. On exit from this procedure, the node N
 770    --  may have zero, one or more interpretations. In the first case an
 771    --  error message is produced. In the last case, the node is flagged
 772    --  as overloaded and the interpretations are collected in All_Interp.
 773
 774    --  If the name is an Access_To_Subprogram, it cannot be overloaded, but
 775    --  the type-checking is similar to that of other calls.
 776
 777    procedure Analyze_Call (N : Node_Id) is
 778       Actuals : constant List_Id := Parameter_Associations (N);
 779       Nam     : Node_Id;
 780       X       : Interp_Index;
 781       It      : Interp;
 782       Nam_Ent : Entity_Id;
 783       Success : Boolean := False;
 784
 785       Deref : Boolean := False;
 786       --  Flag indicates whether an interpretation of the prefix is a
 787       --  parameterless call that returns an access_to_subprogram.
 788
 789       function Name_Denotes_Function return Boolean;
 790       --  If the type of the name is an access to subprogram, this may be the
 791       --  type of a name, or the return type of the function being called. If
 792       --  the name is not an entity then it can denote a protected function.
 793       --  Until we distinguish Etype from Return_Type, we must use this routine
 794       --  to resolve the meaning of the name in the call.
 795
 796       procedure No_Interpretation;
 797       --  Output error message when no valid interpretation exists
 798
 799       ---------------------------
 800       -- Name_Denotes_Function --
 801       ---------------------------
 802
 803       function Name_Denotes_Function return Boolean is
 804       begin
 805          if Is_Entity_Name (Nam) then
 806             return Ekind (Entity (Nam)) = E_Function;
 807
 808          elsif Nkind (Nam) = N_Selected_Component then
 809             return Ekind (Entity (Selector_Name (Nam))) = E_Function;
 810
 811          else
 812             return False;
 813          end if;
 814       end Name_Denotes_Function;
 815
 816       -----------------------
 817       -- No_Interpretation --
 818       -----------------------
 819
 820       procedure No_Interpretation is
 821          L : constant Boolean   := Is_List_Member (N);
 822          K : constant Node_Kind := Nkind (Parent (N));
 823
 824       begin
 825          --  If the node is in a list whose parent is not an expression then it
 826          --  must be an attempted procedure call.
 827
 828          if L and then K not in N_Subexpr then
 829             if Ekind (Entity (Nam)) = E_Generic_Procedure then
 830                Error_Msg_NE
 831                  ("must instantiate generic procedure& before call",
 832                   Nam, Entity (Nam));
 833             else
 834                Error_Msg_N
 835                  ("procedure or entry name expected", Nam);
 836             end if;
 837
 838          --  Check for tasking cases where only an entry call will do
 839
 840          elsif not L
 841            and then Nkind_In (K, N_Entry_Call_Alternative,
 842                                  N_Triggering_Alternative)
 843          then
 844             Error_Msg_N ("entry name expected", Nam);
 845
 846          --  Otherwise give general error message
 847
 848          else
 849             Error_Msg_N ("invalid prefix in call", Nam);
 850          end if;
 851       end No_Interpretation;
 852
 853    --  Start of processing for Analyze_Call
 854
 855    begin
 856       --  Initialize the type of the result of the call to the error type,
 857       --  which will be reset if the type is successfully resolved.
 858
 859       Set_Etype (N, Any_Type);
 860
 861       Nam := Name (N);
 862
 863       if not Is_Overloaded (Nam) then
 864
 865          --  Only one interpretation to check
 866
 867          if Ekind (Etype (Nam)) = E_Subprogram_Type then
 868             Nam_Ent := Etype (Nam);
 869
 870          --  If the prefix is an access_to_subprogram, this may be an indirect
 871          --  call. This is the case if the name in the call is not an entity
 872          --  name, or if it is a function name in the context of a procedure
 873          --  call. In this latter case, we have a call to a parameterless
 874          --  function that returns a pointer_to_procedure which is the entity
 875          --  being called. Finally, F (X) may be a call to a parameterless
 876          --  function that returns a pointer to a function with parameters.
 877
 878          elsif Is_Access_Type (Etype (Nam))
 879            and then Ekind (Designated_Type (Etype (Nam))) = E_Subprogram_Type
 880            and then
 881              (not Name_Denotes_Function
 882                 or else Nkind (N) = N_Procedure_Call_Statement
 883                 or else
 884                   (Nkind (Parent (N)) /= N_Explicit_Dereference
 885                      and then Is_Entity_Name (Nam)
 886                      and then No (First_Formal (Entity (Nam)))
 887                      and then Present (Actuals)))
 888          then
 889             Nam_Ent := Designated_Type (Etype (Nam));
 890             Insert_Explicit_Dereference (Nam);
 891
 892          --  Selected component case. Simple entry or protected operation,
 893          --  where the entry name is given by the selector name.
 894
 895          elsif Nkind (Nam) = N_Selected_Component then
 896             Nam_Ent := Entity (Selector_Name (Nam));
 897
 898             if not Ekind_In (Nam_Ent, E_Entry,
 899                                       E_Entry_Family,
 900                                       E_Function,
 901                                       E_Procedure)
 902             then
 903                Error_Msg_N ("name in call is not a callable entity", Nam);
 904                Set_Etype (N, Any_Type);
 905                return;
 906             end if;
 907
 908          --  If the name is an Indexed component, it can be a call to a member
 909          --  of an entry family. The prefix must be a selected component whose
 910          --  selector is the entry. Analyze_Procedure_Call normalizes several
 911          --  kinds of call into this form.
 912
 913          elsif Nkind (Nam) = N_Indexed_Component then
 914             if Nkind (Prefix (Nam)) = N_Selected_Component then
 915                Nam_Ent := Entity (Selector_Name (Prefix (Nam)));
 916             else
 917                Error_Msg_N ("name in call is not a callable entity", Nam);
 918                Set_Etype (N, Any_Type);
 919                return;
 920             end if;
 921
 922          elsif not Is_Entity_Name (Nam) then
 923             Error_Msg_N ("name in call is not a callable entity", Nam);
 924             Set_Etype (N, Any_Type);
 925             return;
 926
 927          else
 928             Nam_Ent := Entity (Nam);
 929
 930             --  If no interpretations, give error message
 931
 932             if not Is_Overloadable (Nam_Ent) then
 933                No_Interpretation;
 934                return;
 935             end if;
 936          end if;
 937
 938          --  Operations generated for RACW stub types are called only through
 939          --  dispatching, and can never be the static interpretation of a call.
 940
 941          if Is_RACW_Stub_Type_Operation (Nam_Ent) then
 942             No_Interpretation;
 943             return;
 944          end if;
 945
 946          Analyze_One_Call (N, Nam_Ent, True, Success);
 947
 948          --  If this is an indirect call, the return type of the access_to
 949          --  subprogram may be an incomplete type. At the point of the call,
 950          --  use the full type if available, and at the same time update the
 951          --  return type of the access_to_subprogram.
 952
 953          if Success
 954            and then Nkind (Nam) = N_Explicit_Dereference
 955            and then Ekind (Etype (N)) = E_Incomplete_Type
 956            and then Present (Full_View (Etype (N)))
 957          then
 958             Set_Etype (N, Full_View (Etype (N)));
 959             Set_Etype (Nam_Ent, Etype (N));
 960          end if;
 961
 962       else
 963          --  An overloaded selected component must denote overloaded operations
 964          --  of a concurrent type. The interpretations are attached to the
 965          --  simple name of those operations.
 966
 967          if Nkind (Nam) = N_Selected_Component then
 968             Nam := Selector_Name (Nam);
 969          end if;
 970
 971          Get_First_Interp (Nam, X, It);
 972
 973          while Present (It.Nam) loop
 974             Nam_Ent := It.Nam;
 975             Deref   := False;
 976
 977             --  Name may be call that returns an access to subprogram, or more
 978             --  generally an overloaded expression one of whose interpretations
 979             --  yields an access to subprogram. If the name is an entity, we do
 980             --  not dereference, because the node is a call that returns the
 981             --  access type: note difference between f(x), where the call may
 982             --  return an access subprogram type, and f(x)(y), where the type
 983             --  returned by the call to f is implicitly dereferenced to analyze
 984             --  the outer call.
 985
 986             if Is_Access_Type (Nam_Ent) then
 987                Nam_Ent := Designated_Type (Nam_Ent);
 988
 989             elsif Is_Access_Type (Etype (Nam_Ent))
 990               and then
 991                 (not Is_Entity_Name (Nam)
 992                    or else Nkind (N) = N_Procedure_Call_Statement)
 993               and then Ekind (Designated_Type (Etype (Nam_Ent)))
 994                                                           = E_Subprogram_Type
 995             then
 996                Nam_Ent := Designated_Type (Etype (Nam_Ent));
 997
 998                if Is_Entity_Name (Nam) then
 999                   Deref := True;
1000                end if;
1001             end if;
1002
1003             --  If the call has been rewritten from a prefixed call, the first
1004             --  parameter has been analyzed, but may need a subsequent
1005             --  dereference, so skip its analysis now.
1006
1007             if N /= Original_Node (N)
1008               and then Nkind (Original_Node (N)) = Nkind (N)
1009               and then Nkind (Name (N)) /= Nkind (Name (Original_Node (N)))
1010               and then Present (Parameter_Associations (N))
1011               and then Present (Etype (First (Parameter_Associations (N))))
1012             then
1013                Analyze_One_Call
1014                  (N, Nam_Ent, False, Success, Skip_First => True);
1015             else
1016                Analyze_One_Call (N, Nam_Ent, False, Success);
1017             end if;
1018
1019             --  If the interpretation succeeds, mark the proper type of the
1020             --  prefix (any valid candidate will do). If not, remove the
1021             --  candidate interpretation. This only needs to be done for
1022             --  overloaded protected operations, for other entities disambi-
1023             --  guation is done directly in Resolve.
1024
1025             if Success then
1026                if Deref
1027                  and then Nkind (Parent (N)) /= N_Explicit_Dereference
1028                then
1029                   Set_Entity (Nam, It.Nam);
1030                   Insert_Explicit_Dereference (Nam);
1031                   Set_Etype (Nam, Nam_Ent);
1032
1033                else
1034                   Set_Etype (Nam, It.Typ);
1035                end if;
1036
1037             elsif Nkind_In (Name (N), N_Selected_Component,
1038                                       N_Function_Call)
1039             then
1040                Remove_Interp (X);
1041             end if;
1042
1043             Get_Next_Interp (X, It);
1044          end loop;
1045
1046          --  If the name is the result of a function call, it can only
1047          --  be a call to a function returning an access to subprogram.
1048          --  Insert explicit dereference.
1049
1050          if Nkind (Nam) = N_Function_Call then
1051             Insert_Explicit_Dereference (Nam);
1052          end if;
1053
1054          if Etype (N) = Any_Type then
1055
1056             --  None of the interpretations is compatible with the actuals
1057
1058             Diagnose_Call (N, Nam);
1059
1060             --  Special checks for uninstantiated put routines
1061
1062             if Nkind (N) = N_Procedure_Call_Statement
1063               and then Is_Entity_Name (Nam)
1064               and then Chars (Nam) = Name_Put
1065               and then List_Length (Actuals) = 1
1066             then
1067                declare
1068                   Arg : constant Node_Id := First (Actuals);
1069                   Typ : Entity_Id;
1070
1071                begin
1072                   if Nkind (Arg) = N_Parameter_Association then
1073                      Typ := Etype (Explicit_Actual_Parameter (Arg));
1074                   else
1075                      Typ := Etype (Arg);
1076                   end if;
1077
1078                   if Is_Signed_Integer_Type (Typ) then
1079                      Error_Msg_N
1080                        ("possible missing instantiation of " &
1081                           "'Text_'I'O.'Integer_'I'O!", Nam);
1082
1083                   elsif Is_Modular_Integer_Type (Typ) then
1084                      Error_Msg_N
1085                        ("possible missing instantiation of " &
1086                           "'Text_'I'O.'Modular_'I'O!", Nam);
1087
1088                   elsif Is_Floating_Point_Type (Typ) then
1089                      Error_Msg_N
1090                        ("possible missing instantiation of " &
1091                           "'Text_'I'O.'Float_'I'O!", Nam);
1092
1093                   elsif Is_Ordinary_Fixed_Point_Type (Typ) then
1094                      Error_Msg_N
1095                        ("possible missing instantiation of " &
1096                           "'Text_'I'O.'Fixed_'I'O!", Nam);
1097
1098                   elsif Is_Decimal_Fixed_Point_Type (Typ) then
1099                      Error_Msg_N
1100                        ("possible missing instantiation of " &
1101                           "'Text_'I'O.'Decimal_'I'O!", Nam);
1102
1103                   elsif Is_Enumeration_Type (Typ) then
1104                      Error_Msg_N
1105                        ("possible missing instantiation of " &
1106                           "'Text_'I'O.'Enumeration_'I'O!", Nam);
1107                   end if;
1108                end;
1109             end if;
1110
1111          elsif not Is_Overloaded (N)
1112            and then Is_Entity_Name (Nam)
1113          then
1114             --  Resolution yields a single interpretation. Verify that the
1115             --  reference has capitalization consistent with the declaration.
1116
1117             Set_Entity_With_Style_Check (Nam, Entity (Nam));
1118             Generate_Reference (Entity (Nam), Nam);
1119
1120             Set_Etype (Nam, Etype (Entity (Nam)));
1121          else
1122             Remove_Abstract_Operations (N);
1123          end if;
1124
1125          End_Interp_List;
1126       end if;
1127    end Analyze_Call;
1128
1129    -----------------------------
1130    -- Analyze_Case_Expression --
1131    -----------------------------
1132
1133    procedure Analyze_Case_Expression (N : Node_Id) is
1134       Expr      : constant Node_Id := Expression (N);
1135       FirstX    : constant Node_Id := Expression (First (Alternatives (N)));
1136       Alt       : Node_Id;
1137       Exp_Type  : Entity_Id;
1138       Exp_Btype : Entity_Id;
1139
1140       Last_Choice    : Nat;
1141       Dont_Care      : Boolean;
1142       Others_Present : Boolean;
1143
1144       procedure Non_Static_Choice_Error (Choice : Node_Id);
1145       --  Error routine invoked by the generic instantiation below when
1146       --  the case expression has a non static choice.
1147
1148       package Case_Choices_Processing is new
1149         Generic_Choices_Processing
1150           (Get_Alternatives          => Alternatives,
1151            Get_Choices               => Discrete_Choices,
1152            Process_Empty_Choice      => No_OP,
1153            Process_Non_Static_Choice => Non_Static_Choice_Error,
1154            Process_Associated_Node   => No_OP);
1155       use Case_Choices_Processing;
1156
1157       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
1158
1159       -----------------------------
1160       -- Non_Static_Choice_Error --
1161       -----------------------------
1162
1163       procedure Non_Static_Choice_Error (Choice : Node_Id) is
1164       begin
1165          Flag_Non_Static_Expr
1166            ("choice given in case expression is not static!", Choice);
1167       end Non_Static_Choice_Error;
1168
1169    --  Start of processing for Analyze_Case_Expression
1170
1171    begin
1172       if Comes_From_Source (N) then
1173          Check_Compiler_Unit (N);
1174       end if;
1175
1176       Analyze_And_Resolve (Expr, Any_Discrete);
1177       Check_Unset_Reference (Expr);
1178       Exp_Type := Etype (Expr);
1179       Exp_Btype := Base_Type (Exp_Type);
1180
1181       Alt := First (Alternatives (N));
1182       while Present (Alt) loop
1183          Analyze (Expression (Alt));
1184          Next (Alt);
1185       end loop;
1186
1187       if not Is_Overloaded (FirstX) then
1188          Set_Etype (N, Etype (FirstX));
1189
1190       else
1191          declare
1192             I  : Interp_Index;
1193             It : Interp;
1194
1195          begin
1196             Set_Etype (N, Any_Type);
1197
1198             Get_First_Interp (FirstX, I, It);
1199             while Present (It.Nam) loop
1200
1201                --  For each intepretation of the first expression, we only
1202                --  add the intepretation if every other expression in the
1203                --  case expression alternatives has a compatible type.
1204
1205                Alt := Next (First (Alternatives (N)));
1206                while Present (Alt) loop
1207                   exit when not Has_Compatible_Type (Expression (Alt), It.Typ);
1208                   Next (Alt);
1209                end loop;
1210
1211                if No (Alt) then
1212                   Add_One_Interp (N, It.Typ, It.Typ);
1213                end if;
1214
1215                Get_Next_Interp (I, It);
1216             end loop;
1217          end;
1218       end if;
1219
1220       Exp_Btype := Base_Type (Exp_Type);
1221
1222       --  The expression must be of a discrete type which must be determinable
1223       --  independently of the context in which the expression occurs, but
1224       --  using the fact that the expression must be of a discrete type.
1225       --  Moreover, the type this expression must not be a character literal
1226       --  (which is always ambiguous).
1227
1228       --  If error already reported by Resolve, nothing more to do
1229
1230       if Exp_Btype = Any_Discrete
1231         or else Exp_Btype = Any_Type
1232       then
1233          return;
1234
1235       elsif Exp_Btype = Any_Character then
1236          Error_Msg_N
1237            ("character literal as case expression is ambiguous", Expr);
1238          return;
1239       end if;
1240
1241       --  If the case expression is a formal object of mode in out, then
1242       --  treat it as having a nonstatic subtype by forcing use of the base
1243       --  type (which has to get passed to Check_Case_Choices below).  Also
1244       --  use base type when the case expression is parenthesized.
1245
1246       if Paren_Count (Expr) > 0
1247         or else (Is_Entity_Name (Expr)
1248                   and then Ekind (Entity (Expr)) = E_Generic_In_Out_Parameter)
1249       then
1250          Exp_Type := Exp_Btype;
1251       end if;
1252
1253       --  Call instantiated Analyze_Choices which does the rest of the work
1254
1255       Analyze_Choices
1256         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
1257
1258       if Exp_Type = Universal_Integer and then not Others_Present then
1259          Error_Msg_N
1260            ("case on universal integer requires OTHERS choice", Expr);
1261       end if;
1262    end Analyze_Case_Expression;
1263
1264    ---------------------------
1265    -- Analyze_Comparison_Op --
1266    ---------------------------
1267
1268    procedure Analyze_Comparison_Op (N : Node_Id) is
1269       L     : constant Node_Id := Left_Opnd (N);
1270       R     : constant Node_Id := Right_Opnd (N);
1271       Op_Id : Entity_Id        := Entity (N);
1272
1273    begin
1274       Set_Etype (N, Any_Type);
1275       Candidate_Type := Empty;
1276
1277       Analyze_Expression (L);
1278       Analyze_Expression (R);
1279
1280       if Present (Op_Id) then
1281          if Ekind (Op_Id) = E_Operator then
1282             Find_Comparison_Types (L, R, Op_Id, N);
1283          else
1284             Add_One_Interp (N, Op_Id, Etype (Op_Id));
1285          end if;
1286
1287          if Is_Overloaded (L) then
1288             Set_Etype (L, Intersect_Types (L, R));
1289          end if;
1290
1291       else
1292          Op_Id := Get_Name_Entity_Id (Chars (N));
1293          while Present (Op_Id) loop
1294             if Ekind (Op_Id) = E_Operator then
1295                Find_Comparison_Types (L, R, Op_Id, N);
1296             else
1297                Analyze_User_Defined_Binary_Op (N, Op_Id);
1298             end if;
1299
1300             Op_Id := Homonym (Op_Id);
1301          end loop;
1302       end if;
1303
1304       Operator_Check (N);
1305    end Analyze_Comparison_Op;
1306
1307    ---------------------------
1308    -- Analyze_Concatenation --
1309    ---------------------------
1310
1311    procedure Analyze_Concatenation (N : Node_Id) is
1312
1313       --  We wish to avoid deep recursion, because concatenations are often
1314       --  deeply nested, as in A&B&...&Z. Therefore, we walk down the left
1315       --  operands nonrecursively until we find something that is not a
1316       --  concatenation (A in this case), or has already been analyzed. We
1317       --  analyze that, and then walk back up the tree following Parent
1318       --  pointers, calling Analyze_Concatenation_Rest to do the rest of the
1319       --  work at each level. The Parent pointers allow us to avoid recursion,
1320       --  and thus avoid running out of memory.
1321
1322       NN : Node_Id := N;
1323       L  : Node_Id;
1324
1325    begin
1326       Candidate_Type := Empty;
1327
1328       --  The following code is equivalent to:
1329
1330       --    Set_Etype (N, Any_Type);
1331       --    Analyze_Expression (Left_Opnd (N));
1332       --    Analyze_Concatenation_Rest (N);
1333
1334       --  where the Analyze_Expression call recurses back here if the left
1335       --  operand is a concatenation.
1336
1337       --  Walk down left operands
1338
1339       loop
1340          Set_Etype (NN, Any_Type);
1341          L := Left_Opnd (NN);
1342          exit when Nkind (L) /= N_Op_Concat or else Analyzed (L);
1343          NN := L;
1344       end loop;
1345
1346       --  Now (given the above example) NN is A&B and L is A
1347
1348       --  First analyze L ...
1349
1350       Analyze_Expression (L);
1351
1352       --  ... then walk NN back up until we reach N (where we started), calling
1353       --  Analyze_Concatenation_Rest along the way.
1354
1355       loop
1356          Analyze_Concatenation_Rest (NN);
1357          exit when NN = N;
1358          NN := Parent (NN);
1359       end loop;
1360    end Analyze_Concatenation;
1361
1362    --------------------------------
1363    -- Analyze_Concatenation_Rest --
1364    --------------------------------
1365
1366    --  If the only one-dimensional array type in scope is String,
1367    --  this is the resulting type of the operation. Otherwise there
1368    --  will be a concatenation operation defined for each user-defined
1369    --  one-dimensional array.
1370
1371    procedure Analyze_Concatenation_Rest (N : Node_Id) is
1372       L     : constant Node_Id := Left_Opnd (N);
1373       R     : constant Node_Id := Right_Opnd (N);
1374       Op_Id : Entity_Id        := Entity (N);
1375       LT    : Entity_Id;
1376       RT    : Entity_Id;
1377
1378    begin
1379       Analyze_Expression (R);
1380
1381       --  If the entity is present, the node appears in an instance, and
1382       --  denotes a predefined concatenation operation. The resulting type is
1383       --  obtained from the arguments when possible. If the arguments are
1384       --  aggregates, the array type and the concatenation type must be
1385       --  visible.
1386
1387       if Present (Op_Id) then
1388          if Ekind (Op_Id) = E_Operator then
1389             LT := Base_Type (Etype (L));
1390             RT := Base_Type (Etype (R));
1391
1392             if Is_Array_Type (LT)
1393               and then (RT = LT or else RT = Base_Type (Component_Type (LT)))
1394             then
1395                Add_One_Interp (N, Op_Id, LT);
1396
1397             elsif Is_Array_Type (RT)
1398               and then LT = Base_Type (Component_Type (RT))
1399             then
1400                Add_One_Interp (N, Op_Id, RT);
1401
1402             --  If one operand is a string type or a user-defined array type,
1403             --  and the other is a literal, result is of the specific type.
1404
1405             elsif
1406               (Root_Type (LT) = Standard_String
1407                  or else Scope (LT) /= Standard_Standard)
1408               and then Etype (R) = Any_String
1409             then
1410                Add_One_Interp (N, Op_Id, LT);
1411
1412             elsif
1413               (Root_Type (RT) = Standard_String
1414                  or else Scope (RT) /= Standard_Standard)
1415               and then Etype (L) = Any_String
1416             then
1417                Add_One_Interp (N, Op_Id, RT);
1418
1419             elsif not Is_Generic_Type (Etype (Op_Id)) then
1420                Add_One_Interp (N, Op_Id, Etype (Op_Id));
1421
1422             else
1423                --  Type and its operations must be visible
1424
1425                Set_Entity (N, Empty);
1426                Analyze_Concatenation (N);
1427             end if;
1428
1429          else
1430             Add_One_Interp (N, Op_Id, Etype (Op_Id));
1431          end if;
1432
1433       else
1434          Op_Id := Get_Name_Entity_Id (Name_Op_Concat);
1435          while Present (Op_Id) loop
1436             if Ekind (Op_Id) = E_Operator then
1437
1438                --  Do not consider operators declared in dead code, they can
1439                --  not be part of the resolution.
1440
1441                if Is_Eliminated (Op_Id) then
1442                   null;
1443                else
1444                   Find_Concatenation_Types (L, R, Op_Id, N);
1445                end if;
1446
1447             else
1448                Analyze_User_Defined_Binary_Op (N, Op_Id);
1449             end if;
1450
1451             Op_Id := Homonym (Op_Id);
1452          end loop;
1453       end if;
1454
1455       Operator_Check (N);
1456    end Analyze_Concatenation_Rest;
1457
1458    ------------------------------------
1459    -- Analyze_Conditional_Expression --
1460    ------------------------------------
1461
1462    procedure Analyze_Conditional_Expression (N : Node_Id) is
1463       Condition : constant Node_Id := First (Expressions (N));
1464       Then_Expr : constant Node_Id := Next (Condition);
1465       Else_Expr : Node_Id;
1466
1467    begin
1468       --  Defend against error of missing expressions from previous error
1469
1470       if No (Then_Expr) then
1471          return;
1472       end if;
1473
1474       Else_Expr := Next (Then_Expr);
1475
1476       if Comes_From_Source (N) then
1477          Check_Compiler_Unit (N);
1478       end if;
1479
1480       Analyze_Expression (Condition);
1481       Analyze_Expression (Then_Expr);
1482
1483       if Present (Else_Expr) then
1484          Analyze_Expression (Else_Expr);
1485       end if;
1486
1487       --  If then expression not overloaded, then that decides the type
1488
1489       if not Is_Overloaded (Then_Expr) then
1490          Set_Etype (N, Etype (Then_Expr));
1491
1492       --  Case where then expression is overloaded
1493
1494       else
1495          declare
1496             I  : Interp_Index;
1497             It : Interp;
1498
1499          begin
1500             Set_Etype (N, Any_Type);
1501             Get_First_Interp (Then_Expr, I, It);
1502             while Present (It.Nam) loop
1503
1504                --  For each possible intepretation of the Then Expression,
1505                --  add it only if the else expression has a compatible type.
1506
1507                --  Is this right if Else_Expr is empty?
1508
1509                if Has_Compatible_Type (Else_Expr, It.Typ) then
1510                   Add_One_Interp (N, It.Typ, It.Typ);
1511                end if;
1512
1513                Get_Next_Interp (I, It);
1514             end loop;
1515          end;
1516       end if;
1517    end Analyze_Conditional_Expression;
1518
1519    -------------------------
1520    -- Analyze_Equality_Op --
1521    -------------------------
1522
1523    procedure Analyze_Equality_Op (N : Node_Id) is
1524       Loc   : constant Source_Ptr := Sloc (N);
1525       L     : constant Node_Id := Left_Opnd (N);
1526       R     : constant Node_Id := Right_Opnd (N);
1527       Op_Id : Entity_Id;
1528
1529    begin
1530       Set_Etype (N, Any_Type);
1531       Candidate_Type := Empty;
1532
1533       Analyze_Expression (L);
1534       Analyze_Expression (R);
1535
1536       --  If the entity is set, the node is a generic instance with a non-local
1537       --  reference to the predefined operator or to a user-defined function.
1538       --  It can also be an inequality that is expanded into the negation of a
1539       --  call to a user-defined equality operator.
1540
1541       --  For the predefined case, the result is Boolean, regardless of the
1542       --  type of the  operands. The operands may even be limited, if they are
1543       --  generic actuals. If they are overloaded, label the left argument with
1544       --  the common type that must be present, or with the type of the formal
1545       --  of the user-defined function.
1546
1547       if Present (Entity (N)) then
1548          Op_Id := Entity (N);
1549
1550          if Ekind (Op_Id) = E_Operator then
1551             Add_One_Interp (N, Op_Id, Standard_Boolean);
1552          else
1553             Add_One_Interp (N, Op_Id, Etype (Op_Id));
1554          end if;
1555
1556          if Is_Overloaded (L) then
1557             if Ekind (Op_Id) = E_Operator then
1558                Set_Etype (L, Intersect_Types (L, R));
1559             else
1560                Set_Etype (L, Etype (First_Formal (Op_Id)));
1561             end if;
1562          end if;
1563
1564       else
1565          Op_Id := Get_Name_Entity_Id (Chars (N));
1566          while Present (Op_Id) loop
1567             if Ekind (Op_Id) = E_Operator then
1568                Find_Equality_Types (L, R, Op_Id, N);
1569             else
1570                Analyze_User_Defined_Binary_Op (N, Op_Id);
1571             end if;
1572
1573             Op_Id := Homonym (Op_Id);
1574          end loop;
1575       end if;
1576
1577       --  If there was no match, and the operator is inequality, this may
1578       --  be a case where inequality has not been made explicit, as for
1579       --  tagged types. Analyze the node as the negation of an equality
1580       --  operation. This cannot be done earlier, because before analysis
1581       --  we cannot rule out the presence of an explicit inequality.
1582
1583       if Etype (N) = Any_Type
1584         and then Nkind (N) = N_Op_Ne
1585       then
1586          Op_Id := Get_Name_Entity_Id (Name_Op_Eq);
1587          while Present (Op_Id) loop
1588             if Ekind (Op_Id) = E_Operator then
1589                Find_Equality_Types (L, R, Op_Id, N);
1590             else
1591                Analyze_User_Defined_Binary_Op (N, Op_Id);
1592             end if;
1593
1594             Op_Id := Homonym (Op_Id);
1595          end loop;
1596
1597          if Etype (N) /= Any_Type then
1598             Op_Id := Entity (N);
1599
1600             Rewrite (N,
1601               Make_Op_Not (Loc,
1602                 Right_Opnd =>
1603                   Make_Op_Eq (Loc,
1604                     Left_Opnd  => Left_Opnd (N),
1605                     Right_Opnd => Right_Opnd (N))));
1606
1607             Set_Entity (Right_Opnd (N), Op_Id);
1608             Analyze (N);
1609          end if;
1610       end if;
1611
1612       Operator_Check (N);
1613    end Analyze_Equality_Op;
1614
1615    ----------------------------------
1616    -- Analyze_Explicit_Dereference --
1617    ----------------------------------
1618
1619    procedure Analyze_Explicit_Dereference (N : Node_Id) is
1620       Loc   : constant Source_Ptr := Sloc (N);
1621       P     : constant Node_Id := Prefix (N);
1622       T     : Entity_Id;
1623       I     : Interp_Index;
1624       It    : Interp;
1625       New_N : Node_Id;
1626
1627       function Is_Function_Type return Boolean;
1628       --  Check whether node may be interpreted as an implicit function call
1629
1630       ----------------------
1631       -- Is_Function_Type --
1632       ----------------------
1633
1634       function Is_Function_Type return Boolean is
1635          I  : Interp_Index;
1636          It : Interp;
1637
1638       begin
1639          if not Is_Overloaded (N) then
1640             return Ekind (Base_Type (Etype (N))) = E_Subprogram_Type
1641               and then Etype (Base_Type (Etype (N))) /= Standard_Void_Type;
1642
1643          else
1644             Get_First_Interp (N, I, It);
1645             while Present (It.Nam) loop
1646                if Ekind (Base_Type (It.Typ)) /= E_Subprogram_Type
1647                  or else Etype (Base_Type (It.Typ)) = Standard_Void_Type
1648                then
1649                   return False;
1650                end if;
1651
1652                Get_Next_Interp (I, It);
1653             end loop;
1654
1655             return True;
1656          end if;
1657       end Is_Function_Type;
1658
1659    --  Start of processing for Analyze_Explicit_Dereference
1660
1661    begin
1662       Analyze (P);
1663       Set_Etype (N, Any_Type);
1664
1665       --  Test for remote access to subprogram type, and if so return
1666       --  after rewriting the original tree.
1667
1668       if Remote_AST_E_Dereference (P) then
1669          return;
1670       end if;
1671
1672       --  Normal processing for other than remote access to subprogram type
1673
1674       if not Is_Overloaded (P) then
1675          if Is_Access_Type (Etype (P)) then
1676
1677             --  Set the Etype. We need to go through Is_For_Access_Subtypes to
1678             --  avoid other problems caused by the Private_Subtype and it is
1679             --  safe to go to the Base_Type because this is the same as
1680             --  converting the access value to its Base_Type.
1681
1682             declare
1683                DT : Entity_Id := Designated_Type (Etype (P));
1684
1685             begin
1686                if Ekind (DT) = E_Private_Subtype
1687                  and then Is_For_Access_Subtype (DT)
1688                then
1689                   DT := Base_Type (DT);
1690                end if;
1691
1692                --  An explicit dereference is a legal occurrence of an
1693                --  incomplete type imported through a limited_with clause,
1694                --  if the full view is visible.
1695
1696                if From_With_Type (DT)
1697                  and then not From_With_Type (Scope (DT))
1698                  and then
1699                    (Is_Immediately_Visible (Scope (DT))
1700                      or else
1701                        (Is_Child_Unit (Scope (DT))
1702                           and then Is_Visible_Child_Unit (Scope (DT))))
1703                then
1704                   Set_Etype (N, Available_View (DT));
1705
1706                else
1707                   Set_Etype (N, DT);
1708                end if;
1709             end;
1710
1711          elsif Etype (P) /= Any_Type then
1712             Error_Msg_N ("prefix of dereference must be an access type", N);
1713             return;
1714          end if;
1715
1716       else
1717          Get_First_Interp (P, I, It);
1718          while Present (It.Nam) loop
1719             T := It.Typ;
1720
1721             if Is_Access_Type (T) then
1722                Add_One_Interp (N, Designated_Type (T), Designated_Type (T));
1723             end if;
1724
1725             Get_Next_Interp (I, It);
1726          end loop;
1727
1728          --  Error if no interpretation of the prefix has an access type
1729
1730          if Etype (N) = Any_Type then
1731             Error_Msg_N
1732               ("access type required in prefix of explicit dereference", P);
1733             Set_Etype (N, Any_Type);
1734             return;
1735          end if;
1736       end if;
1737
1738       if Is_Function_Type
1739         and then Nkind (Parent (N)) /= N_Indexed_Component
1740
1741         and then (Nkind (Parent (N)) /= N_Function_Call
1742                    or else N /= Name (Parent (N)))
1743
1744         and then (Nkind (Parent (N)) /= N_Procedure_Call_Statement
1745                    or else N /= Name (Parent (N)))
1746
1747         and then Nkind (Parent (N)) /= N_Subprogram_Renaming_Declaration
1748         and then (Nkind (Parent (N)) /= N_Attribute_Reference
1749                     or else
1750                       (Attribute_Name (Parent (N)) /= Name_Address
1751                         and then
1752                        Attribute_Name (Parent (N)) /= Name_Access))
1753       then
1754          --  Name is a function call with no actuals, in a context that
1755          --  requires deproceduring (including as an actual in an enclosing
1756          --  function or procedure call). There are some pathological cases
1757          --  where the prefix might include functions that return access to
1758          --  subprograms and others that return a regular type. Disambiguation
1759          --  of those has to take place in Resolve.
1760
1761          New_N :=
1762            Make_Function_Call (Loc,
1763            Name => Make_Explicit_Dereference (Loc, P),
1764            Parameter_Associations => New_List);
1765
1766          --  If the prefix is overloaded, remove operations that have formals,
1767          --  we know that this is a parameterless call.
1768
1769          if Is_Overloaded (P) then
1770             Get_First_Interp (P, I, It);
1771             while Present (It.Nam) loop
1772                T := It.Typ;
1773
1774                if No (First_Formal (Base_Type (Designated_Type (T)))) then
1775                   Set_Etype (P, T);
1776                else
1777                   Remove_Interp (I);
1778                end if;
1779
1780                Get_Next_Interp (I, It);
1781             end loop;
1782          end if;
1783
1784          Rewrite (N, New_N);
1785          Analyze (N);
1786
1787       elsif not Is_Function_Type
1788         and then Is_Overloaded (N)
1789       then
1790          --  The prefix may include access to subprograms and other access
1791          --  types. If the context selects the interpretation that is a
1792          --  function call (not a procedure call) we cannot rewrite the node
1793          --  yet, but we include the result of the call interpretation.
1794
1795          Get_First_Interp (N, I, It);
1796          while Present (It.Nam) loop
1797             if Ekind (Base_Type (It.Typ)) = E_Subprogram_Type
1798                and then Etype (Base_Type (It.Typ)) /= Standard_Void_Type
1799                and then Nkind (Parent (N)) /= N_Procedure_Call_Statement
1800             then
1801                Add_One_Interp (N, Etype (It.Typ), Etype (It.Typ));
1802             end if;
1803
1804             Get_Next_Interp (I, It);
1805          end loop;
1806       end if;
1807
1808       --  A value of remote access-to-class-wide must not be dereferenced
1809       --  (RM E.2.2(16)).
1810
1811       Validate_Remote_Access_To_Class_Wide_Type (N);
1812    end Analyze_Explicit_Dereference;
1813
1814    ------------------------
1815    -- Analyze_Expression --
1816    ------------------------
1817
1818    procedure Analyze_Expression (N : Node_Id) is
1819    begin
1820       Analyze (N);
1821       Check_Parameterless_Call (N);
1822    end Analyze_Expression;
1823
1824    -------------------------------------
1825    -- Analyze_Expression_With_Actions --
1826    -------------------------------------
1827
1828    procedure Analyze_Expression_With_Actions (N : Node_Id) is
1829       A : Node_Id;
1830
1831    begin
1832       A := First (Actions (N));
1833       loop
1834          Analyze (A);
1835          Next (A);
1836          exit when No (A);
1837       end loop;
1838
1839       Analyze_Expression (Expression (N));
1840       Set_Etype (N, Etype (Expression (N)));
1841    end Analyze_Expression_With_Actions;
1842
1843    ------------------------------------
1844    -- Analyze_Indexed_Component_Form --
1845    ------------------------------------
1846
1847    procedure Analyze_Indexed_Component_Form (N : Node_Id) is
1848       P     : constant Node_Id := Prefix (N);
1849       Exprs : constant List_Id := Expressions (N);
1850       Exp   : Node_Id;
1851       P_T   : Entity_Id;
1852       E     : Node_Id;
1853       U_N   : Entity_Id;
1854
1855       procedure Process_Function_Call;
1856       --  Prefix in indexed component form is an overloadable entity,
1857       --  so the node is a function call. Reformat it as such.
1858
1859       procedure Process_Indexed_Component;
1860       --  Prefix in indexed component form is actually an indexed component.
1861       --  This routine processes it, knowing that the prefix is already
1862       --  resolved.
1863
1864       procedure Process_Indexed_Component_Or_Slice;
1865       --  An indexed component with a single index may designate a slice if
1866       --  the index is a subtype mark. This routine disambiguates these two
1867       --  cases by resolving the prefix to see if it is a subtype mark.
1868
1869       procedure Process_Overloaded_Indexed_Component;
1870       --  If the prefix of an indexed component is overloaded, the proper
1871       --  interpretation is selected by the index types and the context.
1872
1873       ---------------------------
1874       -- Process_Function_Call --
1875       ---------------------------
1876
1877       procedure Process_Function_Call is
1878          Actual : Node_Id;
1879
1880       begin
1881          Change_Node (N, N_Function_Call);
1882          Set_Name (N, P);
1883          Set_Parameter_Associations (N, Exprs);
1884
1885          --  Analyze actuals prior to analyzing the call itself
1886
1887          Actual := First (Parameter_Associations (N));
1888          while Present (Actual) loop
1889             Analyze (Actual);
1890             Check_Parameterless_Call (Actual);
1891
1892             --  Move to next actual. Note that we use Next, not Next_Actual
1893             --  here. The reason for this is a bit subtle. If a function call
1894             --  includes named associations, the parser recognizes the node as
1895             --  a call, and it is analyzed as such. If all associations are
1896             --  positional, the parser builds an indexed_component node, and
1897             --  it is only after analysis of the prefix that the construct
1898             --  is recognized as a call, in which case Process_Function_Call
1899             --  rewrites the node and analyzes the actuals. If the list of
1900             --  actuals is malformed, the parser may leave the node as an
1901             --  indexed component (despite the presence of named associations).
1902             --  The iterator Next_Actual is equivalent to Next if the list is
1903             --  positional, but follows the normalized chain of actuals when
1904             --  named associations are present. In this case normalization has
1905             --  not taken place, and actuals remain unanalyzed, which leads to
1906             --  subsequent crashes or loops if there is an attempt to continue
1907             --  analysis of the program.
1908
1909             Next (Actual);
1910          end loop;
1911
1912          Analyze_Call (N);
1913       end Process_Function_Call;
1914
1915       -------------------------------
1916       -- Process_Indexed_Component --
1917       -------------------------------
1918
1919       procedure Process_Indexed_Component is
1920          Exp        : Node_Id;
1921          Array_Type : Entity_Id;
1922          Index      : Node_Id;
1923          Pent       : Entity_Id := Empty;
1924
1925       begin
1926          Exp := First (Exprs);
1927
1928          if Is_Overloaded (P) then
1929             Process_Overloaded_Indexed_Component;
1930
1931          else
1932             Array_Type := Etype (P);
1933
1934             if Is_Entity_Name (P) then
1935                Pent := Entity (P);
1936             elsif Nkind (P) = N_Selected_Component
1937               and then Is_Entity_Name (Selector_Name (P))
1938             then
1939                Pent := Entity (Selector_Name (P));
1940             end if;
1941
1942             --  Prefix must be appropriate for an array type, taking into
1943             --  account a possible implicit dereference.
1944
1945             if Is_Access_Type (Array_Type) then
1946                Error_Msg_NW (Warn_On_Dereference, "?implicit dereference", N);
1947                Array_Type := Process_Implicit_Dereference_Prefix (Pent, P);
1948             end if;
1949
1950             if Is_Array_Type (Array_Type) then
1951                null;
1952
1953             elsif Present (Pent) and then Ekind (Pent) = E_Entry_Family then
1954                Analyze (Exp);
1955                Set_Etype (N, Any_Type);
1956
1957                if not Has_Compatible_Type
1958                  (Exp, Entry_Index_Type (Pent))
1959                then
1960                   Error_Msg_N ("invalid index type in entry name", N);
1961
1962                elsif Present (Next (Exp)) then
1963                   Error_Msg_N ("too many subscripts in entry reference", N);
1964
1965                else
1966                   Set_Etype (N,  Etype (P));
1967                end if;
1968
1969                return;
1970
1971             elsif Is_Record_Type (Array_Type)
1972               and then Remote_AST_I_Dereference (P)
1973             then
1974                return;
1975
1976             elsif Array_Type = Any_Type then
1977                Set_Etype (N, Any_Type);
1978
1979                --  In most cases the analysis of the prefix will have emitted
1980                --  an error already, but if the prefix may be interpreted as a
1981                --  call in prefixed notation, the report is left to the caller.
1982                --  To prevent cascaded errors, report only if no previous ones.
1983
1984                if Serious_Errors_Detected = 0 then
1985                   Error_Msg_N ("invalid prefix in indexed component", P);
1986
1987                   if Nkind (P) = N_Expanded_Name then
1988                      Error_Msg_NE ("\& is not visible", P, Selector_Name (P));
1989                   end if;
1990                end if;
1991
1992                return;
1993
1994             --  Here we definitely have a bad indexing
1995
1996             else
1997                if Nkind (Parent (N)) = N_Requeue_Statement
1998                  and then Present (Pent) and then Ekind (Pent) = E_Entry
1999                then
2000                   Error_Msg_N
2001                     ("REQUEUE does not permit parameters", First (Exprs));
2002
2003                elsif Is_Entity_Name (P)
2004                  and then Etype (P) = Standard_Void_Type
2005                then
2006                   Error_Msg_NE ("incorrect use of&", P, Entity (P));
2007
2008                else
2009                   Error_Msg_N ("array type required in indexed component", P);
2010                end if;
2011
2012                Set_Etype (N, Any_Type);
2013                return;
2014             end if;
2015
2016             Index := First_Index (Array_Type);
2017             while Present (Index) and then Present (Exp) loop
2018                if not Has_Compatible_Type (Exp, Etype (Index)) then
2019                   Wrong_Type (Exp, Etype (Index));
2020                   Set_Etype (N, Any_Type);
2021                   return;
2022                end if;
2023
2024                Next_Index (Index);
2025                Next (Exp);
2026             end loop;
2027
2028             Set_Etype (N, Component_Type (Array_Type));
2029
2030             if Present (Index) then
2031                Error_Msg_N
2032                  ("too few subscripts in array reference", First (Exprs));
2033
2034             elsif Present (Exp) then
2035                Error_Msg_N ("too many subscripts in array reference", Exp);
2036             end if;
2037          end if;
2038       end Process_Indexed_Component;
2039
2040       ----------------------------------------
2041       -- Process_Indexed_Component_Or_Slice --
2042       ----------------------------------------
2043
2044       procedure Process_Indexed_Component_Or_Slice is
2045       begin
2046          Exp := First (Exprs);
2047          while Present (Exp) loop
2048             Analyze_Expression (Exp);
2049             Next (Exp);
2050          end loop;
2051
2052          Exp := First (Exprs);
2053
2054          --  If one index is present, and it is a subtype name, then the
2055          --  node denotes a slice (note that the case of an explicit range
2056          --  for a slice was already built as an N_Slice node in the first
2057          --  place, so that case is not handled here).
2058
2059          --  We use a replace rather than a rewrite here because this is one
2060          --  of the cases in which the tree built by the parser is plain wrong.
2061
2062          if No (Next (Exp))
2063            and then Is_Entity_Name (Exp)
2064            and then Is_Type (Entity (Exp))
2065          then
2066             Replace (N,
2067                Make_Slice (Sloc (N),
2068                  Prefix => P,
2069                  Discrete_Range => New_Copy (Exp)));
2070             Analyze (N);
2071
2072          --  Otherwise (more than one index present, or single index is not
2073          --  a subtype name), then we have the indexed component case.
2074
2075          else
2076             Process_Indexed_Component;
2077          end if;
2078       end Process_Indexed_Component_Or_Slice;
2079
2080       ------------------------------------------
2081       -- Process_Overloaded_Indexed_Component --
2082       ------------------------------------------
2083
2084       procedure Process_Overloaded_Indexed_Component is
2085          Exp   : Node_Id;
2086          I     : Interp_Index;
2087          It    : Interp;
2088          Typ   : Entity_Id;
2089          Index : Node_Id;
2090          Found : Boolean;
2091
2092       begin
2093          Set_Etype (N, Any_Type);
2094
2095          Get_First_Interp (P, I, It);
2096          while Present (It.Nam) loop
2097             Typ := It.Typ;
2098
2099             if Is_Access_Type (Typ) then
2100                Typ := Designated_Type (Typ);
2101                Error_Msg_NW (Warn_On_Dereference, "?implicit dereference", N);
2102             end if;
2103
2104             if Is_Array_Type (Typ) then
2105
2106                --  Got a candidate: verify that index types are compatible
2107
2108                Index := First_Index (Typ);
2109                Found := True;
2110                Exp := First (Exprs);
2111                while Present (Index) and then Present (Exp) loop
2112                   if Has_Compatible_Type (Exp, Etype (Index)) then
2113                      null;
2114                   else
2115                      Found := False;
2116                      Remove_Interp (I);
2117                      exit;
2118                   end if;
2119
2120                   Next_Index (Index);
2121                   Next (Exp);
2122                end loop;
2123
2124                if Found and then No (Index) and then No (Exp) then
2125                   Add_One_Interp (N,
2126                      Etype (Component_Type (Typ)),
2127                      Etype (Component_Type (Typ)));
2128                end if;
2129             end if;
2130
2131             Get_Next_Interp (I, It);
2132          end loop;
2133
2134          if Etype (N) = Any_Type then
2135             Error_Msg_N ("no legal interpretation for indexed component", N);
2136             Set_Is_Overloaded (N, False);
2137          end if;
2138
2139          End_Interp_List;
2140       end Process_Overloaded_Indexed_Component;
2141
2142    --  Start of processing for Analyze_Indexed_Component_Form
2143
2144    begin
2145       --  Get name of array, function or type
2146
2147       Analyze (P);
2148
2149       if Nkind_In (N, N_Function_Call, N_Procedure_Call_Statement) then
2150
2151          --  If P is an explicit dereference whose prefix is of a
2152          --  remote access-to-subprogram type, then N has already
2153          --  been rewritten as a subprogram call and analyzed.
2154
2155          return;
2156       end if;
2157
2158       pragma Assert (Nkind (N) = N_Indexed_Component);
2159
2160       P_T := Base_Type (Etype (P));
2161
2162       if Is_Entity_Name (P) then
2163          U_N := Entity (P);
2164
2165          if Is_Type (U_N) then
2166
2167             --  Reformat node as a type conversion
2168
2169             E := Remove_Head (Exprs);
2170
2171             if Present (First (Exprs)) then
2172                Error_Msg_N
2173                 ("argument of type conversion must be single expression", N);
2174             end if;
2175
2176             Change_Node (N, N_Type_Conversion);
2177             Set_Subtype_Mark (N, P);
2178             Set_Etype (N, U_N);
2179             Set_Expression (N, E);
2180
2181             --  After changing the node, call for the specific Analysis
2182             --  routine directly, to avoid a double call to the expander.
2183
2184             Analyze_Type_Conversion (N);
2185             return;
2186          end if;
2187
2188          if Is_Overloadable (U_N) then
2189             Process_Function_Call;
2190
2191          elsif Ekind (Etype (P)) = E_Subprogram_Type
2192            or else (Is_Access_Type (Etype (P))
2193                       and then
2194                         Ekind (Designated_Type (Etype (P))) =
2195                                                    E_Subprogram_Type)
2196          then
2197             --  Call to access_to-subprogram with possible implicit dereference
2198
2199             Process_Function_Call;
2200
2201          elsif Is_Generic_Subprogram (U_N) then
2202
2203             --  A common beginner's (or C++ templates fan) error
2204
2205             Error_Msg_N ("generic subprogram cannot be called", N);
2206             Set_Etype (N, Any_Type);
2207             return;
2208
2209          else
2210             Process_Indexed_Component_Or_Slice;
2211          end if;
2212
2213       --  If not an entity name, prefix is an expression that may denote
2214       --  an array or an access-to-subprogram.
2215
2216       else
2217          if Ekind (P_T) = E_Subprogram_Type
2218            or else (Is_Access_Type (P_T)
2219                      and then
2220                        Ekind (Designated_Type (P_T)) = E_Subprogram_Type)
2221          then
2222             Process_Function_Call;
2223
2224          elsif Nkind (P) = N_Selected_Component
2225            and then Is_Overloadable (Entity (Selector_Name (P)))
2226          then
2227             Process_Function_Call;
2228
2229          else
2230             --  Indexed component, slice, or a call to a member of a family
2231             --  entry, which will be converted to an entry call later.
2232
2233             Process_Indexed_Component_Or_Slice;
2234          end if;
2235       end if;
2236    end Analyze_Indexed_Component_Form;
2237
2238    ------------------------
2239    -- Analyze_Logical_Op --
2240    ------------------------
2241
2242    procedure Analyze_Logical_Op (N : Node_Id) is
2243       L     : constant Node_Id := Left_Opnd (N);
2244       R     : constant Node_Id := Right_Opnd (N);
2245       Op_Id : Entity_Id := Entity (N);
2246
2247    begin
2248       Set_Etype (N, Any_Type);
2249       Candidate_Type := Empty;
2250
2251       Analyze_Expression (L);
2252       Analyze_Expression (R);
2253
2254       if Present (Op_Id) then
2255
2256          if Ekind (Op_Id) = E_Operator then
2257             Find_Boolean_Types (L, R, Op_Id, N);
2258          else
2259             Add_One_Interp (N, Op_Id, Etype (Op_Id));
2260          end if;
2261
2262       else
2263          Op_Id := Get_Name_Entity_Id (Chars (N));
2264          while Present (Op_Id) loop
2265             if Ekind (Op_Id) = E_Operator then
2266                Find_Boolean_Types (L, R, Op_Id, N);
2267             else
2268                Analyze_User_Defined_Binary_Op (N, Op_Id);
2269             end if;
2270
2271             Op_Id := Homonym (Op_Id);
2272          end loop;
2273       end if;
2274
2275       Operator_Check (N);
2276    end Analyze_Logical_Op;
2277
2278    ---------------------------
2279    -- Analyze_Membership_Op --
2280    ---------------------------
2281
2282    procedure Analyze_Membership_Op (N : Node_Id) is
2283       L     : constant Node_Id := Left_Opnd (N);
2284       R     : constant Node_Id := Right_Opnd (N);
2285
2286       Index : Interp_Index;
2287       It    : Interp;
2288       Found : Boolean := False;
2289       I_F   : Interp_Index;
2290       T_F   : Entity_Id;
2291
2292       procedure Try_One_Interp (T1 : Entity_Id);
2293       --  Routine to try one proposed interpretation. Note that the context
2294       --  of the operation plays no role in resolving the arguments, so that
2295       --  if there is more than one interpretation of the operands that is
2296       --  compatible with a membership test, the operation is ambiguous.
2297
2298       --------------------
2299       -- Try_One_Interp --
2300       --------------------
2301
2302       procedure Try_One_Interp (T1 : Entity_Id) is
2303       begin
2304          if Has_Compatible_Type (R, T1) then
2305             if Found
2306               and then Base_Type (T1) /= Base_Type (T_F)
2307             then
2308                It := Disambiguate (L, I_F, Index, Any_Type);
2309
2310                if It = No_Interp then
2311                   Ambiguous_Operands (N);
2312                   Set_Etype (L, Any_Type);
2313                   return;
2314
2315                else
2316                   T_F := It.Typ;
2317                end if;
2318
2319             else
2320                Found := True;
2321                T_F   := T1;
2322                I_F   := Index;
2323             end if;
2324
2325             Set_Etype (L, T_F);
2326          end if;
2327       end Try_One_Interp;
2328
2329       procedure Analyze_Set_Membership;
2330       --  If a set of alternatives is present, analyze each and find the
2331       --  common type to which they must all resolve.
2332
2333       ----------------------------
2334       -- Analyze_Set_Membership --
2335       ----------------------------
2336
2337       procedure Analyze_Set_Membership is
2338          Alt               : Node_Id;
2339          Index             : Interp_Index;
2340          It                : Interp;
2341          Candidate_Interps : Node_Id;
2342          Common_Type       : Entity_Id := Empty;
2343
2344       begin
2345          Analyze (L);
2346          Candidate_Interps := L;
2347
2348          if not Is_Overloaded (L) then
2349             Common_Type := Etype (L);
2350
2351             Alt := First (Alternatives (N));
2352             while Present (Alt) loop
2353                Analyze (Alt);
2354
2355                if not Has_Compatible_Type (Alt, Common_Type) then
2356                   Wrong_Type (Alt, Common_Type);
2357                end if;
2358
2359                Next (Alt);
2360             end loop;
2361
2362          else
2363             Alt := First (Alternatives (N));
2364             while Present (Alt) loop
2365                Analyze (Alt);
2366                if not Is_Overloaded (Alt) then
2367                   Common_Type := Etype (Alt);
2368
2369                else
2370                   Get_First_Interp (Alt, Index, It);
2371                   while Present (It.Typ) loop
2372                      if not
2373                        Has_Compatible_Type (Candidate_Interps, It.Typ)
2374                      then
2375                         Remove_Interp (Index);
2376                      end if;
2377
2378                      Get_Next_Interp (Index, It);
2379                   end loop;
2380
2381                   Get_First_Interp (Alt, Index, It);
2382
2383                   if No (It.Typ) then
2384                      Error_Msg_N ("alternative has no legal type", Alt);
2385                      return;
2386                   end if;
2387
2388                   --  If alternative is not overloaded, we have a unique type
2389                   --  for all of them.
2390
2391                   Set_Etype (Alt, It.Typ);
2392                   Get_Next_Interp (Index, It);
2393
2394                   if No (It.Typ) then
2395                      Set_Is_Overloaded (Alt, False);
2396                      Common_Type := Etype (Alt);
2397                   end if;
2398
2399                   Candidate_Interps := Alt;
2400                end if;
2401
2402                Next (Alt);
2403             end loop;
2404          end if;
2405
2406          Set_Etype (N, Standard_Boolean);
2407
2408          if Present (Common_Type) then
2409             Set_Etype (L, Common_Type);
2410             Set_Is_Overloaded (L, False);
2411
2412          else
2413             Error_Msg_N ("cannot resolve membership operation", N);
2414          end if;
2415       end Analyze_Set_Membership;
2416
2417    --  Start of processing for Analyze_Membership_Op
2418
2419    begin
2420       Analyze_Expression (L);
2421
2422       if No (R)
2423         and then Ada_Version >= Ada_2012
2424       then
2425          Analyze_Set_Membership;
2426          return;
2427       end if;
2428
2429       if Nkind (R) = N_Range
2430         or else (Nkind (R) = N_Attribute_Reference
2431                   and then Attribute_Name (R) = Name_Range)
2432       then
2433          Analyze (R);
2434
2435          if not Is_Overloaded (L) then
2436             Try_One_Interp (Etype (L));
2437
2438          else
2439             Get_First_Interp (L, Index, It);
2440             while Present (It.Typ) loop
2441                Try_One_Interp (It.Typ);
2442                Get_Next_Interp (Index, It);
2443             end loop;
2444          end if;
2445
2446       --  If not a range, it can only be a subtype mark, or else there
2447       --  is a more basic error, to be diagnosed in Find_Type.
2448
2449       else
2450          Find_Type (R);
2451
2452          if Is_Entity_Name (R) then
2453             Check_Fully_Declared (Entity (R), R);
2454          end if;
2455       end if;
2456
2457       --  Compatibility between expression and subtype mark or range is
2458       --  checked during resolution. The result of the operation is Boolean
2459       --  in any case.
2460
2461       Set_Etype (N, Standard_Boolean);
2462
2463       if Comes_From_Source (N)
2464         and then Present (Right_Opnd (N))
2465         and then Is_CPP_Class (Etype (Etype (Right_Opnd (N))))
2466       then
2467          Error_Msg_N ("membership test not applicable to cpp-class types", N);
2468       end if;
2469    end Analyze_Membership_Op;
2470
2471    ----------------------
2472    -- Analyze_Negation --
2473    ----------------------
2474
2475    procedure Analyze_Negation (N : Node_Id) is
2476       R     : constant Node_Id := Right_Opnd (N);
2477       Op_Id : Entity_Id := Entity (N);
2478
2479    begin
2480       Set_Etype (N, Any_Type);
2481       Candidate_Type := Empty;
2482
2483       Analyze_Expression (R);
2484
2485       if Present (Op_Id) then
2486          if Ekind (Op_Id) = E_Operator then
2487             Find_Negation_Types (R, Op_Id, N);
2488          else
2489             Add_One_Interp (N, Op_Id, Etype (Op_Id));
2490          end if;
2491
2492       else
2493          Op_Id := Get_Name_Entity_Id (Chars (N));
2494          while Present (Op_Id) loop
2495             if Ekind (Op_Id) = E_Operator then
2496                Find_Negation_Types (R, Op_Id, N);
2497             else
2498                Analyze_User_Defined_Unary_Op (N, Op_Id);
2499             end if;
2500
2501             Op_Id := Homonym (Op_Id);
2502          end loop;
2503       end if;
2504
2505       Operator_Check (N);
2506    end Analyze_Negation;
2507
2508    ------------------
2509    -- Analyze_Null --
2510    ------------------
2511
2512    procedure Analyze_Null (N : Node_Id) is
2513    begin
2514       Set_Etype (N, Any_Access);
2515    end Analyze_Null;
2516
2517    ----------------------
2518    -- Analyze_One_Call --
2519    ----------------------
2520
2521    procedure Analyze_One_Call
2522       (N          : Node_Id;
2523        Nam        : Entity_Id;
2524        Report     : Boolean;
2525        Success    : out Boolean;
2526        Skip_First : Boolean := False)
2527    is
2528       Actuals : constant List_Id   := Parameter_Associations (N);
2529       Prev_T  : constant Entity_Id := Etype (N);
2530
2531       Must_Skip  : constant Boolean := Skip_First
2532                      or else Nkind (Original_Node (N)) = N_Selected_Component
2533                      or else
2534                        (Nkind (Original_Node (N)) = N_Indexed_Component
2535                           and then Nkind (Prefix (Original_Node (N)))
2536                             = N_Selected_Component);
2537       --  The first formal must be omitted from the match when trying to find
2538       --  a primitive operation that is a possible interpretation, and also
2539       --  after the call has been rewritten, because the corresponding actual
2540       --  is already known to be compatible, and because this may be an
2541       --  indexing of a call with default parameters.
2542
2543       Formal      : Entity_Id;
2544       Actual      : Node_Id;
2545       Is_Indexed  : Boolean := False;
2546       Is_Indirect : Boolean := False;
2547       Subp_Type   : constant Entity_Id := Etype (Nam);
2548       Norm_OK     : Boolean;
2549
2550       function Operator_Hidden_By (Fun : Entity_Id) return Boolean;
2551       --  There may be a user-defined operator that hides the current
2552       --  interpretation. We must check for this independently of the
2553       --  analysis of the call with the user-defined operation, because
2554       --  the parameter names may be wrong and yet the hiding takes place.
2555       --  This fixes a problem with ACATS test B34014O.
2556       --
2557       --  When the type Address is a visible integer type, and the DEC
2558       --  system extension is visible, the predefined operator may be
2559       --  hidden as well, by one of the address operations in auxdec.
2560       --  Finally, The abstract operations on address do not hide the
2561       --  predefined operator (this is the purpose of making them abstract).
2562
2563       procedure Indicate_Name_And_Type;
2564       --  If candidate interpretation matches, indicate name and type of
2565       --  result on call node.
2566
2567       ----------------------------
2568       -- Indicate_Name_And_Type --
2569       ----------------------------
2570
2571       procedure Indicate_Name_And_Type is
2572       begin
2573          Add_One_Interp (N, Nam, Etype (Nam));
2574          Success := True;
2575
2576          --  If the prefix of the call is a name, indicate the entity
2577          --  being called. If it is not a name,  it is an expression that
2578          --  denotes an access to subprogram or else an entry or family. In
2579          --  the latter case, the name is a selected component, and the entity
2580          --  being called is noted on the selector.
2581
2582          if not Is_Type (Nam) then
2583             if Is_Entity_Name (Name (N)) then
2584                Set_Entity (Name (N), Nam);
2585
2586             elsif Nkind (Name (N)) = N_Selected_Component then
2587                Set_Entity (Selector_Name (Name (N)),  Nam);
2588             end if;
2589          end if;
2590
2591          if Debug_Flag_E and not Report then
2592             Write_Str (" Overloaded call ");
2593             Write_Int (Int (N));
2594             Write_Str (" compatible with ");
2595             Write_Int (Int (Nam));
2596             Write_Eol;
2597          end if;
2598       end Indicate_Name_And_Type;
2599
2600       ------------------------
2601       -- Operator_Hidden_By --
2602       ------------------------
2603
2604       function Operator_Hidden_By (Fun : Entity_Id) return Boolean is
2605          Act1  : constant Node_Id   := First_Actual (N);
2606          Act2  : constant Node_Id   := Next_Actual (Act1);
2607          Form1 : constant Entity_Id := First_Formal (Fun);
2608          Form2 : constant Entity_Id := Next_Formal (Form1);
2609
2610       begin
2611          if Ekind (Fun) /= E_Function
2612            or else Is_Abstract_Subprogram (Fun)
2613          then
2614             return False;
2615
2616          elsif not Has_Compatible_Type (Act1, Etype (Form1)) then
2617             return False;
2618
2619          elsif Present (Form2) then
2620             if
2621               No (Act2) or else not Has_Compatible_Type (Act2, Etype (Form2))
2622             then
2623                return False;
2624             end if;
2625
2626          elsif Present (Act2) then
2627             return False;
2628          end if;
2629
2630          --  Now we know that the arity of the operator matches the function,
2631          --  and the function call is a valid interpretation. The function
2632          --  hides the operator if it has the right signature, or if one of
2633          --  its operands is a non-abstract operation on Address when this is
2634          --  a visible integer type.
2635
2636          return Hides_Op (Fun, Nam)
2637            or else Is_Descendent_Of_Address (Etype (Form1))
2638            or else
2639              (Present (Form2)
2640                and then Is_Descendent_Of_Address (Etype (Form2)));
2641       end Operator_Hidden_By;
2642
2643    --  Start of processing for Analyze_One_Call
2644
2645    begin
2646       Success := False;
2647
2648       --  If the subprogram has no formals or if all the formals have defaults,
2649       --  and the return type is an array type, the node may denote an indexing
2650       --  of the result of a parameterless call. In Ada 2005, the subprogram
2651       --  may have one non-defaulted formal, and the call may have been written
2652       --  in prefix notation, so that the rebuilt parameter list has more than
2653       --  one actual.
2654
2655       if not Is_Overloadable (Nam)
2656         and then Ekind (Nam) /= E_Subprogram_Type
2657         and then Ekind (Nam) /= E_Entry_Family
2658       then
2659          return;
2660       end if;
2661
2662       --  An indexing requires at least one actual
2663
2664       if not Is_Empty_List (Actuals)
2665         and then
2666           (Needs_No_Actuals (Nam)
2667             or else
2668               (Needs_One_Actual (Nam)
2669                  and then Present (Next_Actual (First (Actuals)))))
2670       then
2671          if Is_Array_Type (Subp_Type) then
2672             Is_Indexed := Try_Indexed_Call (N, Nam, Subp_Type, Must_Skip);
2673
2674          elsif Is_Access_Type (Subp_Type)
2675            and then Is_Array_Type (Designated_Type (Subp_Type))
2676          then
2677             Is_Indexed :=
2678               Try_Indexed_Call
2679                 (N, Nam, Designated_Type (Subp_Type), Must_Skip);
2680
2681          --  The prefix can also be a parameterless function that returns an
2682          --  access to subprogram, in which case this is an indirect call.
2683          --  If this succeeds, an explicit dereference is added later on,
2684          --  in Analyze_Call or Resolve_Call.
2685
2686          elsif Is_Access_Type (Subp_Type)
2687            and then Ekind (Designated_Type (Subp_Type)) = E_Subprogram_Type
2688          then
2689             Is_Indirect := Try_Indirect_Call (N, Nam, Subp_Type);
2690          end if;
2691
2692       end if;
2693
2694       --  If the call has been transformed into a slice, it is of the form
2695       --  F (Subtype) where F is parameterless. The node has been rewritten in
2696       --  Try_Indexed_Call and there is nothing else to do.
2697
2698       if Is_Indexed
2699         and then  Nkind (N) = N_Slice
2700       then
2701          return;
2702       end if;
2703
2704       Normalize_Actuals
2705         (N, Nam, (Report and not Is_Indexed and not Is_Indirect), Norm_OK);
2706
2707       if not Norm_OK then
2708
2709          --  If an indirect call is a possible interpretation, indicate
2710          --  success to the caller.
2711
2712          if Is_Indirect then
2713             Success := True;
2714             return;
2715
2716          --  Mismatch in number or names of parameters
2717
2718          elsif Debug_Flag_E then
2719             Write_Str (" normalization fails in call ");
2720             Write_Int (Int (N));
2721             Write_Str (" with subprogram ");
2722             Write_Int (Int (Nam));
2723             Write_Eol;
2724          end if;
2725
2726       --  If the context expects a function call, discard any interpretation
2727       --  that is a procedure. If the node is not overloaded, leave as is for
2728       --  better error reporting when type mismatch is found.
2729
2730       elsif Nkind (N) = N_Function_Call
2731         and then Is_Overloaded (Name (N))
2732         and then Ekind (Nam) = E_Procedure
2733       then
2734          return;
2735
2736       --  Ditto for function calls in a procedure context
2737
2738       elsif Nkind (N) = N_Procedure_Call_Statement
2739          and then Is_Overloaded (Name (N))
2740          and then Etype (Nam) /= Standard_Void_Type
2741       then
2742          return;
2743
2744       elsif No (Actuals) then
2745
2746          --  If Normalize succeeds, then there are default parameters for
2747          --  all formals.
2748
2749          Indicate_Name_And_Type;
2750
2751       elsif Ekind (Nam) = E_Operator then
2752          if Nkind (N) = N_Procedure_Call_Statement then
2753             return;
2754          end if;
2755
2756          --  This can occur when the prefix of the call is an operator
2757          --  name or an expanded name whose selector is an operator name.
2758
2759          Analyze_Operator_Call (N, Nam);
2760
2761          if Etype (N) /= Prev_T then
2762
2763             --  Check that operator is not hidden by a function interpretation
2764
2765             if Is_Overloaded (Name (N)) then
2766                declare
2767                   I  : Interp_Index;
2768                   It : Interp;
2769
2770                begin
2771                   Get_First_Interp (Name (N), I, It);
2772                   while Present (It.Nam) loop
2773                      if Operator_Hidden_By (It.Nam) then
2774                         Set_Etype (N, Prev_T);
2775                         return;
2776                      end if;
2777
2778                      Get_Next_Interp (I, It);
2779                   end loop;
2780                end;
2781             end if;
2782
2783             --  If operator matches formals, record its name on the call.
2784             --  If the operator is overloaded, Resolve will select the
2785             --  correct one from the list of interpretations. The call
2786             --  node itself carries the first candidate.
2787
2788             Set_Entity (Name (N), Nam);
2789             Success := True;
2790
2791          elsif Report and then Etype (N) = Any_Type then
2792             Error_Msg_N ("incompatible arguments for operator", N);
2793          end if;
2794
2795       else
2796          --  Normalize_Actuals has chained the named associations in the
2797          --  correct order of the formals.
2798
2799          Actual := First_Actual (N);
2800          Formal := First_Formal (Nam);
2801
2802          --  If we are analyzing a call rewritten from object notation,
2803          --  skip first actual, which may be rewritten later as an
2804          --  explicit dereference.
2805
2806          if Must_Skip then
2807             Next_Actual (Actual);
2808             Next_Formal (Formal);
2809          end if;
2810
2811          while Present (Actual) and then Present (Formal) loop
2812             if Nkind (Parent (Actual)) /= N_Parameter_Association
2813               or else Chars (Selector_Name (Parent (Actual))) = Chars (Formal)
2814             then
2815                --  The actual can be compatible with the formal, but we must
2816                --  also check that the context is not an address type that is
2817                --  visibly an integer type, as is the case in VMS_64. In this
2818                --  case the use of literals is illegal, except in the body of
2819                --  descendents of system, where arithmetic operations on
2820                --  address are of course used.
2821
2822                if Has_Compatible_Type (Actual, Etype (Formal))
2823                  and then
2824                   (Etype (Actual) /= Universal_Integer
2825                     or else not Is_Descendent_Of_Address (Etype (Formal))
2826                     or else
2827                       Is_Predefined_File_Name
2828                         (Unit_File_Name (Get_Source_Unit (N))))
2829                then
2830                   Next_Actual (Actual);
2831                   Next_Formal (Formal);
2832
2833                else
2834                   if Debug_Flag_E then
2835                      Write_Str (" type checking fails in call ");
2836                      Write_Int (Int (N));
2837                      Write_Str (" with formal ");
2838                      Write_Int (Int (Formal));
2839                      Write_Str (" in subprogram ");
2840                      Write_Int (Int (Nam));
2841                      Write_Eol;
2842                   end if;
2843
2844                   if Report and not Is_Indexed and not Is_Indirect then
2845
2846                      --  Ada 2005 (AI-251): Complete the error notification
2847                      --  to help new Ada 2005 users.
2848
2849                      if Is_Class_Wide_Type (Etype (Formal))
2850                        and then Is_Interface (Etype (Etype (Formal)))
2851                        and then not Interface_Present_In_Ancestor
2852                                       (Typ   => Etype (Actual),
2853                                        Iface => Etype (Etype (Formal)))
2854                      then
2855                         Error_Msg_NE
2856                           ("(Ada 2005) does not implement interface }",
2857                            Actual, Etype (Etype (Formal)));
2858                      end if;
2859
2860                      Wrong_Type (Actual, Etype (Formal));
2861
2862                      if Nkind (Actual) = N_Op_Eq
2863                        and then Nkind (Left_Opnd (Actual)) = N_Identifier
2864                      then
2865                         Formal := First_Formal (Nam);
2866                         while Present (Formal) loop
2867                            if Chars (Left_Opnd (Actual)) = Chars (Formal) then
2868                               Error_Msg_N -- CODEFIX
2869                                 ("possible misspelling of `='>`!", Actual);
2870                               exit;
2871                            end if;
2872
2873                            Next_Formal (Formal);
2874                         end loop;
2875                      end if;
2876
2877                      if All_Errors_Mode then
2878                         Error_Msg_Sloc := Sloc (Nam);
2879
2880                         if Is_Overloadable (Nam)
2881                           and then Present (Alias (Nam))
2882                           and then not Comes_From_Source (Nam)
2883                         then
2884                            Error_Msg_NE
2885                              ("\\  =='> in call to inherited operation & #!",
2886                               Actual, Nam);
2887
2888                         elsif Ekind (Nam) = E_Subprogram_Type then
2889                            declare
2890                               Access_To_Subprogram_Typ :
2891                                 constant Entity_Id :=
2892                                   Defining_Identifier
2893                                     (Associated_Node_For_Itype (Nam));
2894                            begin
2895                               Error_Msg_NE (
2896                                 "\\  =='> in call to dereference of &#!",
2897                                 Actual, Access_To_Subprogram_Typ);
2898                            end;
2899
2900                         else
2901                            Error_Msg_NE
2902                              ("\\  =='> in call to &#!", Actual, Nam);
2903
2904                         end if;
2905                      end if;
2906                   end if;
2907
2908                   return;
2909                end if;
2910
2911             else
2912                --  Normalize_Actuals has verified that a default value exists
2913                --  for this formal. Current actual names a subsequent formal.
2914
2915                Next_Formal (Formal);
2916             end if;
2917          end loop;
2918
2919          --  On exit, all actuals match
2920
2921          Indicate_Name_And_Type;
2922       end if;
2923    end Analyze_One_Call;
2924
2925    ---------------------------
2926    -- Analyze_Operator_Call --
2927    ---------------------------
2928
2929    procedure Analyze_Operator_Call (N : Node_Id; Op_Id : Entity_Id) is
2930       Op_Name : constant Name_Id := Chars (Op_Id);
2931       Act1    : constant Node_Id := First_Actual (N);
2932       Act2    : constant Node_Id := Next_Actual (Act1);
2933
2934    begin
2935       --  Binary operator case
2936
2937       if Present (Act2) then
2938
2939          --  If more than two operands, then not binary operator after all
2940
2941          if Present (Next_Actual (Act2)) then
2942             return;
2943
2944          elsif     Op_Name = Name_Op_Add
2945            or else Op_Name = Name_Op_Subtract
2946            or else Op_Name = Name_Op_Multiply
2947            or else Op_Name = Name_Op_Divide
2948            or else Op_Name = Name_Op_Mod
2949            or else Op_Name = Name_Op_Rem
2950            or else Op_Name = Name_Op_Expon
2951          then
2952             Find_Arithmetic_Types (Act1, Act2, Op_Id, N);
2953
2954          elsif     Op_Name =  Name_Op_And
2955            or else Op_Name = Name_Op_Or
2956            or else Op_Name = Name_Op_Xor
2957          then
2958             Find_Boolean_Types (Act1, Act2, Op_Id, N);
2959
2960          elsif     Op_Name = Name_Op_Lt
2961            or else Op_Name = Name_Op_Le
2962            or else Op_Name = Name_Op_Gt
2963            or else Op_Name = Name_Op_Ge
2964          then
2965             Find_Comparison_Types (Act1, Act2, Op_Id,  N);
2966
2967          elsif     Op_Name = Name_Op_Eq
2968            or else Op_Name = Name_Op_Ne
2969          then
2970             Find_Equality_Types (Act1, Act2, Op_Id,  N);
2971
2972          elsif     Op_Name = Name_Op_Concat then
2973             Find_Concatenation_Types (Act1, Act2, Op_Id, N);
2974
2975          --  Is this else null correct, or should it be an abort???
2976
2977          else
2978             null;
2979          end if;
2980
2981       --  Unary operator case
2982
2983       else
2984          if Op_Name = Name_Op_Subtract or else
2985             Op_Name = Name_Op_Add      or else
2986             Op_Name = Name_Op_Abs
2987          then
2988             Find_Unary_Types (Act1, Op_Id, N);
2989
2990          elsif
2991             Op_Name = Name_Op_Not
2992          then
2993             Find_Negation_Types (Act1, Op_Id, N);
2994
2995          --  Is this else null correct, or should it be an abort???
2996
2997          else
2998             null;
2999          end if;
3000       end if;
3001    end Analyze_Operator_Call;
3002
3003    -------------------------------------------
3004    -- Analyze_Overloaded_Selected_Component --
3005    -------------------------------------------
3006
3007    procedure Analyze_Overloaded_Selected_Component (N : Node_Id) is
3008       Nam   : constant Node_Id := Prefix (N);
3009       Sel   : constant Node_Id := Selector_Name (N);
3010       Comp  : Entity_Id;
3011       I     : Interp_Index;
3012       It    : Interp;
3013       T     : Entity_Id;
3014
3015    begin
3016       Set_Etype (Sel, Any_Type);
3017
3018       Get_First_Interp (Nam, I, It);
3019       while Present (It.Typ) loop
3020          if Is_Access_Type (It.Typ) then
3021             T := Designated_Type (It.Typ);
3022             Error_Msg_NW (Warn_On_Dereference, "?implicit dereference", N);
3023          else
3024             T := It.Typ;
3025          end if;
3026
3027          if Is_Record_Type (T) then
3028
3029             --  If the prefix is a class-wide type, the visible components are
3030             --  those of the base type.
3031
3032             if Is_Class_Wide_Type (T) then
3033                T := Etype (T);
3034             end if;
3035
3036             Comp := First_Entity (T);
3037             while Present (Comp) loop
3038                if Chars (Comp) = Chars (Sel)
3039                  and then Is_Visible_Component (Comp)
3040                then
3041
3042                   --  AI05-105:  if the context is an object renaming with
3043                   --  an anonymous access type, the expected type of the
3044                   --  object must be anonymous. This is a name resolution rule.
3045
3046                   if Nkind (Parent (N)) /= N_Object_Renaming_Declaration
3047                     or else No (Access_Definition (Parent (N)))
3048                     or else Ekind (Etype (Comp)) = E_Anonymous_Access_Type
3049                     or else
3050                       Ekind (Etype (Comp)) = E_Anonymous_Access_Subprogram_Type
3051                   then
3052                      Set_Entity (Sel, Comp);
3053                      Set_Etype (Sel, Etype (Comp));
3054                      Add_One_Interp (N, Etype (Comp), Etype (Comp));
3055
3056                      --  This also specifies a candidate to resolve the name.
3057                      --  Further overloading will be resolved from context.
3058                      --  The selector name itself does not carry overloading
3059                      --  information.
3060
3061                      Set_Etype (Nam, It.Typ);
3062
3063                   else
3064                      --  Named access type in the context of a renaming
3065                      --  declaration with an access definition. Remove
3066                      --  inapplicable candidate.
3067
3068                      Remove_Interp (I);
3069                   end if;
3070                end if;
3071
3072                Next_Entity (Comp);
3073             end loop;
3074
3075          elsif Is_Concurrent_Type (T) then
3076             Comp := First_Entity (T);
3077             while Present (Comp)
3078               and then Comp /= First_Private_Entity (T)
3079             loop
3080                if Chars (Comp) = Chars (Sel) then
3081                   if Is_Overloadable (Comp) then
3082                      Add_One_Interp (Sel, Comp, Etype (Comp));
3083                   else
3084                      Set_Entity_With_Style_Check (Sel, Comp);
3085                      Generate_Reference (Comp, Sel);
3086                   end if;
3087
3088                   Set_Etype (Sel, Etype (Comp));
3089                   Set_Etype (N,   Etype (Comp));
3090                   Set_Etype (Nam, It.Typ);
3091
3092                   --  For access type case, introduce explicit dereference for
3093                   --  more uniform treatment of entry calls. Do this only once
3094                   --  if several interpretations yield an access type.
3095
3096                   if Is_Access_Type (Etype (Nam))
3097                     and then Nkind (Nam) /= N_Explicit_Dereference
3098                   then
3099                      Insert_Explicit_Dereference (Nam);
3100                      Error_Msg_NW
3101                        (Warn_On_Dereference, "?implicit dereference", N);
3102                   end if;
3103                end if;
3104
3105                Next_Entity (Comp);
3106             end loop;
3107
3108             Set_Is_Overloaded (N, Is_Overloaded (Sel));
3109          end if;
3110
3111          Get_Next_Interp (I, It);
3112       end loop;
3113
3114       if Etype (N) = Any_Type
3115         and then not Try_Object_Operation (N)
3116       then
3117          Error_Msg_NE ("undefined selector& for overloaded prefix", N, Sel);
3118          Set_Entity (Sel, Any_Id);
3119          Set_Etype  (Sel, Any_Type);
3120       end if;
3121    end Analyze_Overloaded_Selected_Component;
3122
3123    ----------------------------------
3124    -- Analyze_Qualified_Expression --
3125    ----------------------------------
3126
3127    procedure Analyze_Qualified_Expression (N : Node_Id) is
3128       Mark : constant Entity_Id := Subtype_Mark (N);
3129       Expr : constant Node_Id   := Expression (N);
3130       I    : Interp_Index;
3131       It   : Interp;
3132       T    : Entity_Id;
3133
3134    begin
3135       Analyze_Expression (Expr);
3136
3137       Set_Etype (N, Any_Type);
3138       Find_Type (Mark);
3139       T := Entity (Mark);
3140       Set_Etype (N, T);
3141
3142       if T = Any_Type then
3143          return;
3144       end if;
3145
3146       Check_Fully_Declared (T, N);
3147
3148       --  If expected type is class-wide, check for exact match before
3149       --  expansion, because if the expression is a dispatching call it
3150       --  may be rewritten as explicit dereference with class-wide result.
3151       --  If expression is overloaded, retain only interpretations that
3152       --  will yield exact matches.
3153
3154       if Is_Class_Wide_Type (T) then
3155          if not Is_Overloaded (Expr) then
3156             if  Base_Type (Etype (Expr)) /= Base_Type (T) then
3157                if Nkind (Expr) = N_Aggregate then
3158                   Error_Msg_N ("type of aggregate cannot be class-wide", Expr);
3159                else
3160                   Wrong_Type (Expr, T);
3161                end if;
3162             end if;
3163
3164          else
3165             Get_First_Interp (Expr, I, It);
3166
3167             while Present (It.Nam) loop
3168                if Base_Type (It.Typ) /= Base_Type (T) then
3169                   Remove_Interp (I);
3170                end if;
3171
3172                Get_Next_Interp (I, It);
3173             end loop;
3174          end if;
3175       end if;
3176
3177       Set_Etype  (N, T);
3178    end Analyze_Qualified_Expression;
3179
3180    -----------------------------------
3181    -- Analyze_Quantified_Expression --
3182    -----------------------------------
3183
3184    procedure Analyze_Quantified_Expression (N : Node_Id) is
3185       Loc : constant Source_Ptr := Sloc (N);
3186       Ent : constant Entity_Id :=
3187               New_Internal_Entity
3188                 (E_Loop, Current_Scope, Sloc (N), 'L');
3189
3190       Iterator : Node_Id;
3191    begin
3192       Set_Etype  (Ent,  Standard_Void_Type);
3193       Set_Parent (Ent, N);
3194
3195       Iterator :=
3196         Make_Iteration_Scheme (Loc,
3197            Loop_Parameter_Specification =>  Loop_Parameter_Specification (N));
3198
3199       Push_Scope (Ent);
3200       Analyze_Iteration_Scheme (Iterator);
3201       Analyze (Condition (N));
3202       End_Scope;
3203       Set_Etype (N, Standard_Boolean);
3204    end Analyze_Quantified_Expression;
3205
3206    -------------------
3207    -- Analyze_Range --
3208    -------------------
3209
3210    procedure Analyze_Range (N : Node_Id) is
3211       L        : constant Node_Id := Low_Bound (N);
3212       H        : constant Node_Id := High_Bound (N);
3213       I1, I2   : Interp_Index;
3214       It1, It2 : Interp;
3215
3216       procedure Check_Common_Type (T1, T2 : Entity_Id);
3217       --  Verify the compatibility of two types,  and choose the
3218       --  non universal one if the other is universal.
3219
3220       procedure Check_High_Bound (T : Entity_Id);
3221       --  Test one interpretation of the low bound against all those
3222       --  of the high bound.
3223
3224       procedure Check_Universal_Expression (N : Node_Id);
3225       --  In Ada83, reject bounds of a universal range that are not
3226       --  literals or entity names.
3227
3228       -----------------------
3229       -- Check_Common_Type --
3230       -----------------------
3231
3232       procedure Check_Common_Type (T1, T2 : Entity_Id) is
3233       begin
3234          if Covers (T1 => T1, T2 => T2)
3235               or else
3236             Covers (T1 => T2, T2 => T1)
3237          then
3238             if T1 = Universal_Integer
3239               or else T1 = Universal_Real
3240               or else T1 = Any_Character
3241             then
3242                Add_One_Interp (N, Base_Type (T2), Base_Type (T2));
3243
3244             elsif T1 = T2 then
3245                Add_One_Interp (N, T1, T1);
3246
3247             else
3248                Add_One_Interp (N, Base_Type (T1), Base_Type (T1));
3249             end if;
3250          end if;
3251       end Check_Common_Type;
3252
3253       ----------------------
3254       -- Check_High_Bound --
3255       ----------------------
3256
3257       procedure Check_High_Bound (T : Entity_Id) is
3258       begin
3259          if not Is_Overloaded (H) then
3260             Check_Common_Type (T, Etype (H));
3261          else
3262             Get_First_Interp (H, I2, It2);
3263             while Present (It2.Typ) loop
3264                Check_Common_Type (T, It2.Typ);
3265                Get_Next_Interp (I2, It2);
3266             end loop;
3267          end if;
3268       end Check_High_Bound;
3269
3270       -----------------------------
3271       -- Is_Universal_Expression --
3272       -----------------------------
3273
3274       procedure Check_Universal_Expression (N : Node_Id) is
3275       begin
3276          if Etype (N) = Universal_Integer
3277            and then Nkind (N) /= N_Integer_Literal
3278            and then not Is_Entity_Name (N)
3279            and then Nkind (N) /= N_Attribute_Reference
3280          then
3281             Error_Msg_N ("illegal bound in discrete range", N);
3282          end if;
3283       end Check_Universal_Expression;
3284
3285    --  Start of processing for Analyze_Range
3286
3287    begin
3288       Set_Etype (N, Any_Type);
3289       Analyze_Expression (L);
3290       Analyze_Expression (H);
3291
3292       if Etype (L) = Any_Type or else Etype (H) = Any_Type then
3293          return;
3294
3295       else
3296          if not Is_Overloaded (L) then
3297             Check_High_Bound (Etype (L));
3298          else
3299             Get_First_Interp (L, I1, It1);
3300             while Present (It1.Typ) loop
3301                Check_High_Bound (It1.Typ);
3302                Get_Next_Interp (I1, It1);
3303             end loop;
3304          end if;
3305
3306          --  If result is Any_Type, then we did not find a compatible pair
3307
3308          if Etype (N) = Any_Type then
3309             Error_Msg_N ("incompatible types in range ", N);
3310          end if;
3311       end if;
3312
3313       if Ada_Version = Ada_83
3314         and then
3315           (Nkind (Parent (N)) = N_Loop_Parameter_Specification
3316              or else Nkind (Parent (N)) = N_Constrained_Array_Definition)
3317       then
3318          Check_Universal_Expression (L);
3319          Check_Universal_Expression (H);
3320       end if;
3321    end Analyze_Range;
3322
3323    -----------------------
3324    -- Analyze_Reference --
3325    -----------------------
3326
3327    procedure Analyze_Reference (N : Node_Id) is
3328       P        : constant Node_Id := Prefix (N);
3329       E        : Entity_Id;
3330       T        : Entity_Id;
3331       Acc_Type : Entity_Id;
3332
3333    begin
3334       Analyze (P);
3335
3336       --  An interesting error check, if we take the 'Reference of an object
3337       --  for which a pragma Atomic or Volatile has been given, and the type
3338       --  of the object is not Atomic or Volatile, then we are in trouble. The
3339       --  problem is that no trace of the atomic/volatile status will remain
3340       --  for the backend to respect when it deals with the resulting pointer,
3341       --  since the pointer type will not be marked atomic (it is a pointer to
3342       --  the base type of the object).
3343
3344       --  It is not clear if that can ever occur, but in case it does, we will
3345       --  generate an error message. Not clear if this message can ever be
3346       --  generated, and pretty clear that it represents a bug if it is, still
3347       --  seems worth checking, except in CodePeer mode where we do not really
3348       --  care and don't want to bother the user.
3349
3350       T := Etype (P);
3351
3352       if Is_Entity_Name (P)
3353         and then Is_Object_Reference (P)
3354         and then not CodePeer_Mode
3355       then
3356          E := Entity (P);
3357          T := Etype (P);
3358
3359          if (Has_Atomic_Components   (E)
3360                and then not Has_Atomic_Components   (T))
3361            or else
3362             (Has_Volatile_Components (E)
3363                and then not Has_Volatile_Components (T))
3364            or else (Is_Atomic   (E) and then not Is_Atomic   (T))
3365            or else (Is_Volatile (E) and then not Is_Volatile (T))
3366          then
3367             Error_Msg_N ("cannot take reference to Atomic/Volatile object", N);
3368          end if;
3369       end if;
3370
3371       --  Carry on with normal processing
3372
3373       Acc_Type := Create_Itype (E_Allocator_Type, N);
3374       Set_Etype (Acc_Type,  Acc_Type);
3375       Set_Directly_Designated_Type (Acc_Type, Etype (P));
3376       Set_Etype (N, Acc_Type);
3377    end Analyze_Reference;
3378
3379    --------------------------------
3380    -- Analyze_Selected_Component --
3381    --------------------------------
3382
3383    --  Prefix is a record type or a task or protected type. In the latter case,
3384    --  the selector must denote a visible entry.
3385
3386    procedure Analyze_Selected_Component (N : Node_Id) is
3387       Name          : constant Node_Id := Prefix (N);
3388       Sel           : constant Node_Id := Selector_Name (N);
3389       Act_Decl      : Node_Id;
3390       Comp          : Entity_Id;
3391       Has_Candidate : Boolean := False;
3392       In_Scope      : Boolean;
3393       Parent_N      : Node_Id;
3394       Pent          : Entity_Id := Empty;
3395       Prefix_Type   : Entity_Id;
3396
3397       Type_To_Use : Entity_Id;
3398       --  In most cases this is the Prefix_Type, but if the Prefix_Type is
3399       --  a class-wide type, we use its root type, whose components are
3400       --  present in the class-wide type.
3401
3402       Is_Single_Concurrent_Object : Boolean;
3403       --  Set True if the prefix is a single task or a single protected object
3404
3405       procedure Find_Component_In_Instance (Rec : Entity_Id);
3406       --  In an instance, a component of a private extension may not be visible
3407       --  while it was visible in the generic. Search candidate scope for a
3408       --  component with the proper identifier. This is only done if all other
3409       --  searches have failed. When the match is found (it always will be),
3410       --  the Etype of both N and Sel are set from this component, and the
3411       --  entity of Sel is set to reference this component.
3412
3413       function Has_Mode_Conformant_Spec (Comp : Entity_Id) return Boolean;
3414       --  It is known that the parent of N denotes a subprogram call. Comp
3415       --  is an overloadable component of the concurrent type of the prefix.
3416       --  Determine whether all formals of the parent of N and Comp are mode
3417       --  conformant. If the parent node is not analyzed yet it may be an
3418       --  indexed component rather than a function call.
3419
3420       --------------------------------
3421       -- Find_Component_In_Instance --
3422       --------------------------------
3423
3424       procedure Find_Component_In_Instance (Rec : Entity_Id) is
3425          Comp : Entity_Id;
3426
3427       begin
3428          Comp := First_Component (Rec);
3429          while Present (Comp) loop
3430             if Chars (Comp) = Chars (Sel) then
3431                Set_Entity_With_Style_Check (Sel, Comp);
3432                Set_Etype (Sel, Etype (Comp));
3433                Set_Etype (N,   Etype (Comp));
3434                return;
3435             end if;
3436
3437             Next_Component (Comp);
3438          end loop;
3439
3440          --  This must succeed because code was legal in the generic
3441
3442          raise Program_Error;
3443       end Find_Component_In_Instance;
3444
3445       ------------------------------
3446       -- Has_Mode_Conformant_Spec --
3447       ------------------------------
3448
3449       function Has_Mode_Conformant_Spec (Comp : Entity_Id) return Boolean is
3450          Comp_Param : Entity_Id;
3451          Param      : Node_Id;
3452          Param_Typ  : Entity_Id;
3453
3454       begin
3455          Comp_Param := First_Formal (Comp);
3456
3457          if Nkind (Parent (N)) = N_Indexed_Component then
3458             Param := First (Expressions (Parent (N)));
3459          else
3460             Param := First (Parameter_Associations (Parent (N)));
3461          end if;
3462
3463          while Present (Comp_Param)
3464            and then Present (Param)
3465          loop
3466             Param_Typ := Find_Parameter_Type (Param);
3467
3468             if Present (Param_Typ)
3469               and then
3470                 not Conforming_Types
3471                      (Etype (Comp_Param), Param_Typ, Mode_Conformant)
3472             then
3473                return False;
3474             end if;
3475
3476             Next_Formal (Comp_Param);
3477             Next (Param);
3478          end loop;
3479
3480          --  One of the specs has additional formals
3481
3482          if Present (Comp_Param) or else Present (Param) then
3483             return False;
3484          end if;
3485
3486          return True;
3487       end Has_Mode_Conformant_Spec;
3488
3489    --  Start of processing for Analyze_Selected_Component
3490
3491    begin
3492       Set_Etype (N, Any_Type);
3493
3494       if Is_Overloaded (Name) then
3495          Analyze_Overloaded_Selected_Component (N);
3496          return;
3497
3498       elsif Etype (Name) = Any_Type then
3499          Set_Entity (Sel, Any_Id);
3500          Set_Etype (Sel, Any_Type);
3501          return;
3502
3503       else
3504          Prefix_Type := Etype (Name);
3505       end if;
3506
3507       if Is_Access_Type (Prefix_Type) then
3508
3509          --  A RACW object can never be used as prefix of a selected component
3510          --  since that means it is dereferenced without being a controlling
3511          --  operand of a dispatching operation (RM E.2.2(16/1)). Before
3512          --  reporting an error, we must check whether this is actually a
3513          --  dispatching call in prefix form.
3514
3515          if Is_Remote_Access_To_Class_Wide_Type (Prefix_Type)
3516            and then Comes_From_Source (N)
3517          then
3518             if Try_Object_Operation (N) then
3519                return;
3520             else
3521                Error_Msg_N
3522                  ("invalid dereference of a remote access-to-class-wide value",
3523                   N);
3524             end if;
3525
3526          --  Normal case of selected component applied to access type
3527
3528          else
3529             Error_Msg_NW (Warn_On_Dereference, "?implicit dereference", N);
3530
3531             if Is_Entity_Name (Name) then
3532                Pent := Entity (Name);
3533             elsif Nkind (Name) = N_Selected_Component
3534               and then Is_Entity_Name (Selector_Name (Name))
3535             then
3536                Pent := Entity (Selector_Name (Name));
3537             end if;
3538
3539             Prefix_Type := Process_Implicit_Dereference_Prefix (Pent, Name);
3540          end if;
3541
3542       --  If we have an explicit dereference of a remote access-to-class-wide
3543       --  value, then issue an error (see RM-E.2.2(16/1)). However we first
3544       --  have to check for the case of a prefix that is a controlling operand
3545       --  of a prefixed dispatching call, as the dereference is legal in that
3546       --  case. Normally this condition is checked in Validate_Remote_Access_
3547       --  To_Class_Wide_Type, but we have to defer the checking for selected
3548       --  component prefixes because of the prefixed dispatching call case.
3549       --  Note that implicit dereferences are checked for this just above.
3550
3551       elsif Nkind (Name) = N_Explicit_Dereference
3552         and then Is_Remote_Access_To_Class_Wide_Type (Etype (Prefix (Name)))
3553         and then Comes_From_Source (N)
3554       then
3555          if Try_Object_Operation (N) then
3556             return;
3557          else
3558             Error_Msg_N
3559               ("invalid dereference of a remote access-to-class-wide value",
3560                N);
3561          end if;
3562       end if;
3563
3564       --  (Ada 2005): if the prefix is the limited view of a type, and
3565       --  the context already includes the full view, use the full view
3566       --  in what follows, either to retrieve a component of to find
3567       --  a primitive operation. If the prefix is an explicit dereference,
3568       --  set the type of the prefix to reflect this transformation.
3569       --  If the non-limited view is itself an incomplete type, get the
3570       --  full view if available.
3571
3572       if Is_Incomplete_Type (Prefix_Type)
3573         and then From_With_Type (Prefix_Type)
3574         and then Present (Non_Limited_View (Prefix_Type))
3575       then
3576          Prefix_Type := Get_Full_View (Non_Limited_View (Prefix_Type));
3577
3578          if Nkind (N) = N_Explicit_Dereference then
3579             Set_Etype (Prefix (N), Prefix_Type);
3580          end if;
3581
3582       elsif Ekind (Prefix_Type) = E_Class_Wide_Type
3583         and then From_With_Type (Prefix_Type)
3584         and then Present (Non_Limited_View (Etype (Prefix_Type)))
3585       then
3586          Prefix_Type :=
3587            Class_Wide_Type (Non_Limited_View (Etype (Prefix_Type)));
3588
3589          if Nkind (N) = N_Explicit_Dereference then
3590             Set_Etype (Prefix (N), Prefix_Type);
3591          end if;
3592       end if;
3593
3594       if Ekind (Prefix_Type) = E_Private_Subtype then
3595          Prefix_Type := Base_Type (Prefix_Type);
3596       end if;
3597
3598       Type_To_Use := Prefix_Type;
3599
3600       --  For class-wide types, use the entity list of the root type. This
3601       --  indirection is specially important for private extensions because
3602       --  only the root type get switched (not the class-wide type).
3603
3604       if Is_Class_Wide_Type (Prefix_Type) then
3605          Type_To_Use := Root_Type (Prefix_Type);
3606       end if;
3607
3608       --  If the prefix is a single concurrent object, use its name in error
3609       --  messages, rather than that of its anonymous type.
3610
3611       Is_Single_Concurrent_Object :=
3612         Is_Concurrent_Type (Prefix_Type)
3613           and then Is_Internal_Name (Chars (Prefix_Type))
3614           and then not Is_Derived_Type (Prefix_Type)
3615           and then Is_Entity_Name (Name);
3616
3617       Comp := First_Entity (Type_To_Use);
3618
3619       --  If the selector has an original discriminant, the node appears in
3620       --  an instance. Replace the discriminant with the corresponding one
3621       --  in the current discriminated type. For nested generics, this must
3622       --  be done transitively, so note the new original discriminant.
3623
3624       if Nkind (Sel) = N_Identifier
3625         and then Present (Original_Discriminant (Sel))
3626       then
3627          Comp := Find_Corresponding_Discriminant (Sel, Prefix_Type);
3628
3629          --  Mark entity before rewriting, for completeness and because
3630          --  subsequent semantic checks might examine the original node.
3631
3632          Set_Entity (Sel, Comp);
3633          Rewrite (Selector_Name (N),
3634            New_Occurrence_Of (Comp, Sloc (N)));
3635          Set_Original_Discriminant (Selector_Name (N), Comp);
3636          Set_Etype (N, Etype (Comp));
3637
3638          if Is_Access_Type (Etype (Name)) then
3639             Insert_Explicit_Dereference (Name);
3640             Error_Msg_NW (Warn_On_Dereference, "?implicit dereference", N);
3641          end if;
3642
3643       elsif Is_Record_Type (Prefix_Type) then
3644
3645          --  Find component with given name
3646
3647          while Present (Comp) loop
3648             if Chars (Comp) = Chars (Sel)
3649               and then Is_Visible_Component (Comp)
3650             then
3651                Set_Entity_With_Style_Check (Sel, Comp);
3652                Set_Etype (Sel, Etype (Comp));
3653
3654                if Ekind (Comp) = E_Discriminant then
3655                   if Is_Unchecked_Union (Base_Type (Prefix_Type)) then
3656                      Error_Msg_N
3657                        ("cannot reference discriminant of Unchecked_Union",
3658                         Sel);
3659                   end if;
3660
3661                   if Is_Generic_Type (Prefix_Type)
3662                        or else
3663                      Is_Generic_Type (Root_Type (Prefix_Type))
3664                   then
3665                      Set_Original_Discriminant (Sel, Comp);
3666                   end if;
3667                end if;
3668
3669                --  Resolve the prefix early otherwise it is not possible to
3670                --  build the actual subtype of the component: it may need
3671                --  to duplicate this prefix and duplication is only allowed
3672                --  on fully resolved expressions.
3673
3674                Resolve (Name);
3675
3676                --  Ada 2005 (AI-50217): Check wrong use of incomplete types or
3677                --  subtypes in a package specification.
3678                --  Example:
3679
3680                --    limited with Pkg;
3681                --    package Pkg is
3682                --       type Acc_Inc is access Pkg.T;
3683                --       X : Acc_Inc;
3684                --       N : Natural := X.all.Comp;  --  ERROR, limited view
3685                --    end Pkg;                       --  Comp is not visible
3686
3687                if Nkind (Name) = N_Explicit_Dereference
3688                  and then From_With_Type (Etype (Prefix (Name)))
3689                  and then not Is_Potentially_Use_Visible (Etype (Name))
3690                  and then Nkind (Parent (Cunit_Entity (Current_Sem_Unit))) =
3691                             N_Package_Specification
3692                then
3693                   Error_Msg_NE
3694                     ("premature usage of incomplete}", Prefix (Name),
3695                      Etype (Prefix (Name)));
3696                end if;
3697
3698                --  We never need an actual subtype for the case of a selection
3699                --  for a indexed component of a non-packed array, since in
3700                --  this case gigi generates all the checks and can find the
3701                --  necessary bounds information.
3702
3703                --  We also do not need an actual subtype for the case of a
3704                --  first, last, length, or range attribute applied to a
3705                --  non-packed array, since gigi can again get the bounds in
3706                --  these cases (gigi cannot handle the packed case, since it
3707                --  has the bounds of the packed array type, not the original
3708                --  bounds of the type). However, if the prefix is itself a
3709                --  selected component, as in a.b.c (i), gigi may regard a.b.c
3710                --  as a dynamic-sized temporary, so we do generate an actual
3711                --  subtype for this case.
3712
3713                Parent_N := Parent (N);
3714
3715                if not Is_Packed (Etype (Comp))
3716                  and then
3717                    ((Nkind (Parent_N) = N_Indexed_Component
3718                        and then Nkind (Name) /= N_Selected_Component)
3719                      or else
3720                       (Nkind (Parent_N) = N_Attribute_Reference
3721                          and then (Attribute_Name (Parent_N) = Name_First
3722                                      or else
3723                                    Attribute_Name (Parent_N) = Name_Last
3724                                      or else
3725                                    Attribute_Name (Parent_N) = Name_Length
3726                                      or else
3727                                    Attribute_Name (Parent_N) = Name_Range)))
3728                then
3729                   Set_Etype (N, Etype (Comp));
3730
3731                --  If full analysis is not enabled, we do not generate an
3732                --  actual subtype, because in the absence of expansion
3733                --  reference to a formal of a protected type, for example,
3734                --  will not be properly transformed, and will lead to
3735                --  out-of-scope references in gigi.
3736
3737                --  In all other cases, we currently build an actual subtype.
3738                --  It seems likely that many of these cases can be avoided,
3739                --  but right now, the front end makes direct references to the
3740                --  bounds (e.g. in generating a length check), and if we do
3741                --  not make an actual subtype, we end up getting a direct
3742                --  reference to a discriminant, which will not do.
3743
3744                elsif Full_Analysis then
3745                   Act_Decl :=
3746                     Build_Actual_Subtype_Of_Component (Etype (Comp), N);
3747                   Insert_Action (N, Act_Decl);
3748
3749                   if No (Act_Decl) then
3750                      Set_Etype (N, Etype (Comp));
3751
3752                   else
3753                      --  Component type depends on discriminants. Enter the
3754                      --  main attributes of the subtype.
3755
3756                      declare
3757                         Subt : constant Entity_Id :=
3758                                  Defining_Identifier (Act_Decl);
3759
3760                      begin
3761                         Set_Etype (Subt, Base_Type (Etype (Comp)));
3762                         Set_Ekind (Subt, Ekind (Etype (Comp)));
3763                         Set_Etype (N, Subt);
3764                      end;
3765                   end if;
3766
3767                --  If Full_Analysis not enabled, just set the Etype
3768
3769                else
3770                   Set_Etype (N, Etype (Comp));
3771                end if;
3772
3773                return;
3774             end if;
3775
3776             --  If the prefix is a private extension, check only the visible
3777             --  components of the partial view. This must include the tag,
3778             --  which can appear in expanded code in a tag check.
3779
3780             if Ekind (Type_To_Use) = E_Record_Type_With_Private
3781               and then  Chars (Selector_Name (N)) /= Name_uTag
3782             then
3783                exit when Comp = Last_Entity (Type_To_Use);
3784             end if;
3785
3786             Next_Entity (Comp);
3787          end loop;
3788
3789          --  Ada 2005 (AI-252): The selected component can be interpreted as
3790          --  a prefixed view of a subprogram. Depending on the context, this is
3791          --  either a name that can appear in a renaming declaration, or part
3792          --  of an enclosing call given in prefix form.
3793
3794          --  Ada 2005 (AI05-0030): In the case of dispatching requeue, the
3795          --  selected component should resolve to a name.
3796
3797          if Ada_Version >= Ada_2005
3798            and then Is_Tagged_Type (Prefix_Type)
3799            and then not Is_Concurrent_Type (Prefix_Type)
3800          then
3801             if Nkind (Parent (N)) = N_Generic_Association
3802               or else Nkind (Parent (N)) = N_Requeue_Statement
3803               or else Nkind (Parent (N)) = N_Subprogram_Renaming_Declaration
3804             then
3805                if Find_Primitive_Operation (N) then
3806                   return;
3807                end if;
3808
3809             elsif Try_Object_Operation (N) then
3810                return;
3811             end if;
3812
3813             --  If the transformation fails, it will be necessary to redo the
3814             --  analysis with all errors enabled, to indicate candidate
3815             --  interpretations and reasons for each failure ???
3816
3817          end if;
3818
3819       elsif Is_Private_Type (Prefix_Type) then
3820
3821          --  Allow access only to discriminants of the type. If the type has
3822          --  no full view, gigi uses the parent type for the components, so we
3823          --  do the same here.
3824
3825          if No (Full_View (Prefix_Type)) then
3826             Type_To_Use := Root_Type (Base_Type (Prefix_Type));
3827             Comp := First_Entity (Type_To_Use);
3828          end if;
3829
3830          while Present (Comp) loop
3831             if Chars (Comp) = Chars (Sel) then
3832                if Ekind (Comp) = E_Discriminant then
3833                   Set_Entity_With_Style_Check (Sel, Comp);
3834                   Generate_Reference (Comp, Sel);
3835
3836                   Set_Etype (Sel, Etype (Comp));
3837                   Set_Etype (N,   Etype (Comp));
3838
3839                   if Is_Generic_Type (Prefix_Type)
3840                     or else Is_Generic_Type (Root_Type (Prefix_Type))
3841                   then
3842                      Set_Original_Discriminant (Sel, Comp);
3843                   end if;
3844
3845                --  Before declaring an error, check whether this is tagged
3846                --  private type and a call to a primitive operation.
3847
3848                elsif Ada_Version >= Ada_2005
3849                  and then Is_Tagged_Type (Prefix_Type)
3850                  and then Try_Object_Operation (N)
3851                then
3852                   return;
3853
3854                else
3855                   Error_Msg_Node_2 := First_Subtype (Prefix_Type);
3856                   Error_Msg_NE ("invisible selector& for }", N, Sel);
3857                   Set_Entity (Sel, Any_Id);
3858                   Set_Etype (N, Any_Type);
3859                end if;
3860
3861                return;
3862             end if;
3863
3864             Next_Entity (Comp);
3865          end loop;
3866
3867       elsif Is_Concurrent_Type (Prefix_Type) then
3868
3869          --  Find visible operation with given name. For a protected type,
3870          --  the possible candidates are discriminants, entries or protected
3871          --  procedures. For a task type, the set can only include entries or
3872          --  discriminants if the task type is not an enclosing scope. If it
3873          --  is an enclosing scope (e.g. in an inner task) then all entities
3874          --  are visible, but the prefix must denote the enclosing scope, i.e.
3875          --  can only be a direct name or an expanded name.
3876
3877          Set_Etype (Sel, Any_Type);
3878          In_Scope := In_Open_Scopes (Prefix_Type);
3879
3880          while Present (Comp) loop
3881             if Chars (Comp) = Chars (Sel) then
3882                if Is_Overloadable (Comp) then
3883                   Add_One_Interp (Sel, Comp, Etype (Comp));
3884
3885                   --  If the prefix is tagged, the correct interpretation may
3886                   --  lie in the primitive or class-wide operations of the
3887                   --  type. Perform a simple conformance check to determine
3888                   --  whether Try_Object_Operation should be invoked even if
3889                   --  a visible entity is found.
3890
3891                   if Is_Tagged_Type (Prefix_Type)
3892                     and then
3893                       Nkind_In (Parent (N), N_Procedure_Call_Statement,
3894                                             N_Function_Call,
3895                                             N_Indexed_Component)
3896                     and then Has_Mode_Conformant_Spec (Comp)
3897                   then
3898                      Has_Candidate := True;
3899                   end if;
3900
3901                --  Note: a selected component may not denote a component of a
3902                --  protected type (4.1.3(7)).
3903
3904                elsif Ekind_In (Comp, E_Discriminant, E_Entry_Family)
3905                  or else (In_Scope
3906                             and then not Is_Protected_Type (Prefix_Type)
3907                             and then Is_Entity_Name (Name))
3908                then
3909                   Set_Entity_With_Style_Check (Sel, Comp);
3910                   Generate_Reference (Comp, Sel);
3911
3912                else
3913                   goto Next_Comp;
3914                end if;
3915
3916                Set_Etype (Sel, Etype (Comp));
3917                Set_Etype (N,   Etype (Comp));
3918
3919                if Ekind (Comp) = E_Discriminant then
3920                   Set_Original_Discriminant (Sel, Comp);
3921                end if;
3922
3923                --  For access type case, introduce explicit dereference for
3924                --  more uniform treatment of entry calls.
3925
3926                if Is_Access_Type (Etype (Name)) then
3927                   Insert_Explicit_Dereference (Name);
3928                   Error_Msg_NW
3929                     (Warn_On_Dereference, "?implicit dereference", N);
3930                end if;
3931             end if;
3932
3933             <<Next_Comp>>
3934                Next_Entity (Comp);
3935                exit when not In_Scope
3936                  and then
3937                    Comp = First_Private_Entity (Base_Type (Prefix_Type));
3938          end loop;
3939
3940          --  If there is no visible entity with the given name or none of the
3941          --  visible entities are plausible interpretations, check whether
3942          --  there is some other primitive operation with that name.
3943
3944          if Ada_Version >= Ada_2005
3945            and then Is_Tagged_Type (Prefix_Type)
3946          then
3947             if (Etype (N) = Any_Type
3948                   or else not Has_Candidate)
3949               and then Try_Object_Operation (N)
3950             then
3951                return;
3952
3953             --  If the context is not syntactically a procedure call, it
3954             --  may be a call to a primitive function declared outside of
3955             --  the synchronized type.
3956
3957             --  If the context is a procedure call, there might still be
3958             --  an overloading between an entry and a primitive procedure
3959             --  declared outside of the synchronized type, called in prefix
3960             --  notation. This is harder to disambiguate because in one case
3961             --  the controlling formal is implicit ???
3962
3963             elsif Nkind (Parent (N)) /= N_Procedure_Call_Statement
3964               and then Nkind (Parent (N)) /= N_Indexed_Component
3965               and then Try_Object_Operation (N)
3966             then
3967                return;
3968             end if;
3969          end if;
3970
3971          if Etype (N) = Any_Type and then Is_Protected_Type (Prefix_Type) then
3972             --  Case of a prefix of a protected type: selector might denote
3973             --  an invisible private component.
3974
3975             Comp := First_Private_Entity (Base_Type (Prefix_Type));
3976             while Present (Comp) and then Chars (Comp) /= Chars (Sel) loop
3977                Next_Entity (Comp);
3978             end loop;
3979
3980             if Present (Comp) then
3981                if Is_Single_Concurrent_Object then
3982                   Error_Msg_Node_2 := Entity (Name);
3983                   Error_Msg_NE ("invisible selector& for &", N, Sel);
3984
3985                else
3986                   Error_Msg_Node_2 := First_Subtype (Prefix_Type);
3987                   Error_Msg_NE ("invisible selector& for }", N, Sel);
3988                end if;
3989                return;
3990             end if;
3991          end if;
3992
3993          Set_Is_Overloaded (N, Is_Overloaded (Sel));
3994
3995       else
3996          --  Invalid prefix
3997
3998          Error_Msg_NE ("invalid prefix in selected component&", N, Sel);
3999       end if;
4000
4001       --  If N still has no type, the component is not defined in the prefix
4002
4003       if Etype (N) = Any_Type then
4004
4005          if Is_Single_Concurrent_Object then
4006             Error_Msg_Node_2 := Entity (Name);
4007             Error_Msg_NE ("no selector& for&", N, Sel);
4008
4009             Check_Misspelled_Selector (Type_To_Use, Sel);
4010
4011          elsif Is_Generic_Type (Prefix_Type)
4012            and then Ekind (Prefix_Type) = E_Record_Type_With_Private
4013            and then Prefix_Type /= Etype (Prefix_Type)
4014            and then Is_Record_Type (Etype (Prefix_Type))
4015          then
4016             --  If this is a derived formal type, the parent may have
4017             --  different visibility at this point. Try for an inherited
4018             --  component before reporting an error.
4019
4020             Set_Etype (Prefix (N), Etype (Prefix_Type));
4021             Analyze_Selected_Component (N);
4022             return;
4023
4024          --  Similarly, if this is the actual for a formal derived type, the
4025          --  component inherited from the generic parent may not be visible
4026          --  in the actual, but the selected component is legal.
4027
4028          elsif Ekind (Prefix_Type) = E_Record_Subtype_With_Private
4029            and then Is_Generic_Actual_Type (Prefix_Type)
4030            and then Present (Full_View (Prefix_Type))
4031          then
4032
4033             Find_Component_In_Instance
4034               (Generic_Parent_Type (Parent (Prefix_Type)));
4035             return;
4036
4037          --  Finally, the formal and the actual may be private extensions,
4038          --  but the generic is declared in a child unit of the parent, and
4039          --  an addtional step is needed to retrieve the proper scope.
4040
4041          elsif In_Instance
4042            and then Present (Parent_Subtype (Etype (Base_Type (Prefix_Type))))
4043          then
4044             Find_Component_In_Instance
4045               (Parent_Subtype (Etype (Base_Type (Prefix_Type))));
4046             return;
4047
4048          --  Component not found, specialize error message when appropriate
4049
4050          else
4051             if Ekind (Prefix_Type) = E_Record_Subtype then
4052
4053                --  Check whether this is a component of the base type which
4054                --  is absent from a statically constrained subtype. This will
4055                --  raise constraint error at run time, but is not a compile-
4056                --  time error. When the selector is illegal for base type as
4057                --  well fall through and generate a compilation error anyway.
4058
4059                Comp := First_Component (Base_Type (Prefix_Type));
4060                while Present (Comp) loop
4061                   if Chars (Comp) = Chars (Sel)
4062                     and then Is_Visible_Component (Comp)
4063                   then
4064                      Set_Entity_With_Style_Check (Sel, Comp);
4065                      Generate_Reference (Comp, Sel);
4066                      Set_Etype (Sel, Etype (Comp));
4067                      Set_Etype (N,   Etype (Comp));
4068
4069                      --  Emit appropriate message. Gigi will replace the
4070                      --  node subsequently with the appropriate Raise.
4071
4072                      Apply_Compile_Time_Constraint_Error
4073                        (N, "component not present in }?",
4074                         CE_Discriminant_Check_Failed,
4075                         Ent => Prefix_Type, Rep => False);
4076                      Set_Raises_Constraint_Error (N);
4077                      return;
4078                   end if;
4079
4080                   Next_Component (Comp);
4081                end loop;
4082
4083             end if;
4084
4085             Error_Msg_Node_2 := First_Subtype (Prefix_Type);
4086             Error_Msg_NE ("no selector& for}", N, Sel);
4087
4088             Check_Misspelled_Selector (Type_To_Use, Sel);
4089          end if;
4090
4091          Set_Entity (Sel, Any_Id);
4092          Set_Etype (Sel, Any_Type);
4093       end if;
4094    end Analyze_Selected_Component;
4095
4096    ---------------------------
4097    -- Analyze_Short_Circuit --
4098    ---------------------------
4099
4100    procedure Analyze_Short_Circuit (N : Node_Id) is
4101       L   : constant Node_Id := Left_Opnd  (N);
4102       R   : constant Node_Id := Right_Opnd (N);
4103       Ind : Interp_Index;
4104       It  : Interp;
4105
4106    begin
4107       Analyze_Expression (L);
4108       Analyze_Expression (R);
4109       Set_Etype (N, Any_Type);
4110
4111       if not Is_Overloaded (L) then
4112          if Root_Type (Etype (L)) = Standard_Boolean
4113            and then Has_Compatible_Type (R, Etype (L))
4114          then
4115             Add_One_Interp (N, Etype (L), Etype (L));
4116          end if;
4117
4118       else
4119          Get_First_Interp (L, Ind, It);
4120          while Present (It.Typ) loop
4121             if Root_Type (It.Typ) = Standard_Boolean
4122               and then Has_Compatible_Type (R, It.Typ)
4123             then
4124                Add_One_Interp (N, It.Typ, It.Typ);
4125             end if;
4126
4127             Get_Next_Interp (Ind, It);
4128          end loop;
4129       end if;
4130
4131       --  Here we have failed to find an interpretation. Clearly we know that
4132       --  it is not the case that both operands can have an interpretation of
4133       --  Boolean, but this is by far the most likely intended interpretation.
4134       --  So we simply resolve both operands as Booleans, and at least one of
4135       --  these resolutions will generate an error message, and we do not need
4136       --  to give another error message on the short circuit operation itself.
4137
4138       if Etype (N) = Any_Type then
4139          Resolve (L, Standard_Boolean);
4140          Resolve (R, Standard_Boolean);
4141          Set_Etype (N, Standard_Boolean);
4142       end if;
4143    end Analyze_Short_Circuit;
4144
4145    -------------------
4146    -- Analyze_Slice --
4147    -------------------
4148
4149    procedure Analyze_Slice (N : Node_Id) is
4150       P          : constant Node_Id := Prefix (N);
4151       D          : constant Node_Id := Discrete_Range (N);
4152       Array_Type : Entity_Id;
4153
4154       procedure Analyze_Overloaded_Slice;
4155       --  If the prefix is overloaded, select those interpretations that
4156       --  yield a one-dimensional array type.
4157
4158       ------------------------------
4159       -- Analyze_Overloaded_Slice --
4160       ------------------------------
4161
4162       procedure Analyze_Overloaded_Slice is
4163          I   : Interp_Index;
4164          It  : Interp;
4165          Typ : Entity_Id;
4166
4167       begin
4168          Set_Etype (N, Any_Type);
4169
4170          Get_First_Interp (P, I, It);
4171          while Present (It.Nam) loop
4172             Typ := It.Typ;
4173
4174             if Is_Access_Type (Typ) then
4175                Typ := Designated_Type (Typ);
4176                Error_Msg_NW (Warn_On_Dereference, "?implicit dereference", N);
4177             end if;
4178
4179             if Is_Array_Type (Typ)
4180               and then Number_Dimensions (Typ) = 1
4181               and then Has_Compatible_Type (D, Etype (First_Index (Typ)))
4182             then
4183                Add_One_Interp (N, Typ, Typ);
4184             end if;
4185
4186             Get_Next_Interp (I, It);
4187          end loop;
4188
4189          if Etype (N) = Any_Type then
4190             Error_Msg_N ("expect array type in prefix of slice",  N);
4191          end if;
4192       end Analyze_Overloaded_Slice;
4193
4194    --  Start of processing for Analyze_Slice
4195
4196    begin
4197       Analyze (P);
4198       Analyze (D);
4199
4200       if Is_Overloaded (P) then
4201          Analyze_Overloaded_Slice;
4202
4203       else
4204          Array_Type := Etype (P);
4205          Set_Etype (N, Any_Type);
4206
4207          if Is_Access_Type (Array_Type) then
4208             Array_Type := Designated_Type (Array_Type);
4209             Error_Msg_NW (Warn_On_Dereference, "?implicit dereference", N);
4210          end if;
4211
4212          if not Is_Array_Type (Array_Type) then
4213             Wrong_Type (P, Any_Array);
4214
4215          elsif Number_Dimensions (Array_Type) > 1 then
4216             Error_Msg_N
4217               ("type is not one-dimensional array in slice prefix", N);
4218
4219          elsif not
4220            Has_Compatible_Type (D, Etype (First_Index (Array_Type)))
4221          then
4222             Wrong_Type (D, Etype (First_Index (Array_Type)));
4223
4224          else
4225             Set_Etype (N, Array_Type);
4226          end if;
4227       end if;
4228    end Analyze_Slice;
4229
4230    -----------------------------
4231    -- Analyze_Type_Conversion --
4232    -----------------------------
4233
4234    procedure Analyze_Type_Conversion (N : Node_Id) is
4235       Expr : constant Node_Id := Expression (N);
4236       T    : Entity_Id;
4237
4238    begin
4239       --  If Conversion_OK is set, then the Etype is already set, and the
4240       --  only processing required is to analyze the expression. This is
4241       --  used to construct certain "illegal" conversions which are not
4242       --  allowed by Ada semantics, but can be handled OK by Gigi, see
4243       --  Sinfo for further details.
4244
4245       if Conversion_OK (N) then
4246          Analyze (Expr);
4247          return;
4248       end if;
4249
4250       --  Otherwise full type analysis is required, as well as some semantic
4251       --  checks to make sure the argument of the conversion is appropriate.
4252
4253       Find_Type (Subtype_Mark (N));
4254       T := Entity (Subtype_Mark (N));
4255       Set_Etype (N, T);
4256       Check_Fully_Declared (T, N);
4257       Analyze_Expression (Expr);
4258       Validate_Remote_Type_Type_Conversion (N);
4259
4260       --  Only remaining step is validity checks on the argument. These
4261       --  are skipped if the conversion does not come from the source.
4262
4263       if not Comes_From_Source (N) then
4264          return;
4265
4266       --  If there was an error in a generic unit, no need to replicate the
4267       --  error message. Conversely, constant-folding in the generic may
4268       --  transform the argument of a conversion into a string literal, which
4269       --  is legal. Therefore the following tests are not performed in an
4270       --  instance.
4271
4272       elsif In_Instance then
4273          return;
4274
4275       elsif Nkind (Expr) = N_Null then
4276          Error_Msg_N ("argument of conversion cannot be null", N);
4277          Error_Msg_N ("\use qualified expression instead", N);
4278          Set_Etype (N, Any_Type);
4279
4280       elsif Nkind (Expr) = N_Aggregate then
4281          Error_Msg_N ("argument of conversion cannot be aggregate", N);
4282          Error_Msg_N ("\use qualified expression instead", N);
4283
4284       elsif Nkind (Expr) = N_Allocator then
4285          Error_Msg_N ("argument of conversion cannot be an allocator", N);
4286          Error_Msg_N ("\use qualified expression instead", N);
4287
4288       elsif Nkind (Expr) = N_String_Literal then
4289          Error_Msg_N ("argument of conversion cannot be string literal", N);
4290          Error_Msg_N ("\use qualified expression instead", N);
4291
4292       elsif Nkind (Expr) = N_Character_Literal then
4293          if Ada_Version = Ada_83 then
4294             Resolve (Expr, T);
4295          else
4296             Error_Msg_N ("argument of conversion cannot be character literal",
4297               N);
4298             Error_Msg_N ("\use qualified expression instead", N);
4299          end if;
4300
4301       elsif Nkind (Expr) = N_Attribute_Reference
4302         and then
4303           (Attribute_Name (Expr) = Name_Access            or else
4304            Attribute_Name (Expr) = Name_Unchecked_Access  or else
4305            Attribute_Name (Expr) = Name_Unrestricted_Access)
4306       then
4307          Error_Msg_N ("argument of conversion cannot be access", N);
4308          Error_Msg_N ("\use qualified expression instead", N);
4309       end if;
4310    end Analyze_Type_Conversion;
4311
4312    ----------------------
4313    -- Analyze_Unary_Op --
4314    ----------------------
4315
4316    procedure Analyze_Unary_Op (N : Node_Id) is
4317       R     : constant Node_Id := Right_Opnd (N);
4318       Op_Id : Entity_Id := Entity (N);
4319
4320    begin
4321       Set_Etype (N, Any_Type);
4322       Candidate_Type := Empty;
4323
4324       Analyze_Expression (R);
4325
4326       if Present (Op_Id) then
4327          if Ekind (Op_Id) = E_Operator then
4328             Find_Unary_Types (R, Op_Id,  N);
4329          else
4330             Add_One_Interp (N, Op_Id, Etype (Op_Id));
4331          end if;
4332
4333       else
4334          Op_Id := Get_Name_Entity_Id (Chars (N));
4335          while Present (Op_Id) loop
4336             if Ekind (Op_Id) = E_Operator then
4337                if No (Next_Entity (First_Entity (Op_Id))) then
4338                   Find_Unary_Types (R, Op_Id,  N);
4339                end if;
4340
4341             elsif Is_Overloadable (Op_Id) then
4342                Analyze_User_Defined_Unary_Op (N, Op_Id);
4343             end if;
4344
4345             Op_Id := Homonym (Op_Id);
4346          end loop;
4347       end if;
4348
4349       Operator_Check (N);
4350    end Analyze_Unary_Op;
4351
4352    ----------------------------------
4353    -- Analyze_Unchecked_Expression --
4354    ----------------------------------
4355
4356    procedure Analyze_Unchecked_Expression (N : Node_Id) is
4357    begin
4358       Analyze (Expression (N), Suppress => All_Checks);
4359       Set_Etype (N, Etype (Expression (N)));
4360       Save_Interps (Expression (N), N);
4361    end Analyze_Unchecked_Expression;
4362
4363    ---------------------------------------
4364    -- Analyze_Unchecked_Type_Conversion --
4365    ---------------------------------------
4366
4367    procedure Analyze_Unchecked_Type_Conversion (N : Node_Id) is
4368    begin
4369       Find_Type (Subtype_Mark (N));
4370       Analyze_Expression (Expression (N));
4371       Set_Etype (N, Entity (Subtype_Mark (N)));
4372    end Analyze_Unchecked_Type_Conversion;
4373
4374    ------------------------------------
4375    -- Analyze_User_Defined_Binary_Op --
4376    ------------------------------------
4377
4378    procedure Analyze_User_Defined_Binary_Op
4379      (N     : Node_Id;
4380       Op_Id : Entity_Id)
4381    is
4382    begin
4383       --  Only do analysis if the operator Comes_From_Source, since otherwise
4384       --  the operator was generated by the expander, and all such operators
4385       --  always refer to the operators in package Standard.
4386
4387       if Comes_From_Source (N) then
4388          declare
4389             F1 : constant Entity_Id := First_Formal (Op_Id);
4390             F2 : constant Entity_Id := Next_Formal (F1);
4391
4392          begin
4393             --  Verify that Op_Id is a visible binary function. Note that since
4394             --  we know Op_Id is overloaded, potentially use visible means use
4395             --  visible for sure (RM 9.4(11)).
4396
4397             if Ekind (Op_Id) = E_Function
4398               and then Present (F2)
4399               and then (Is_Immediately_Visible (Op_Id)
4400                          or else Is_Potentially_Use_Visible (Op_Id))
4401               and then Has_Compatible_Type (Left_Opnd (N), Etype (F1))
4402               and then Has_Compatible_Type (Right_Opnd (N), Etype (F2))
4403             then
4404                Add_One_Interp (N, Op_Id, Etype (Op_Id));
4405
4406                --  If the left operand is overloaded, indicate that the
4407                --  current type is a viable candidate. This is redundant
4408                --  in most cases, but for equality and comparison operators
4409                --  where the context does not impose a type on the operands,
4410                --  setting the proper type is necessary to avoid subsequent
4411                --  ambiguities during resolution, when both user-defined and
4412                --  predefined operators may be candidates.
4413
4414                if Is_Overloaded (Left_Opnd (N)) then
4415                   Set_Etype (Left_Opnd (N), Etype (F1));
4416                end if;
4417
4418                if Debug_Flag_E then
4419                   Write_Str ("user defined operator ");
4420                   Write_Name (Chars (Op_Id));
4421                   Write_Str (" on node ");
4422                   Write_Int (Int (N));
4423                   Write_Eol;
4424                end if;
4425             end if;
4426          end;
4427       end if;
4428    end Analyze_User_Defined_Binary_Op;
4429
4430    -----------------------------------
4431    -- Analyze_User_Defined_Unary_Op --
4432    -----------------------------------
4433
4434    procedure Analyze_User_Defined_Unary_Op
4435      (N     : Node_Id;
4436       Op_Id : Entity_Id)
4437    is
4438    begin
4439       --  Only do analysis if the operator Comes_From_Source, since otherwise
4440       --  the operator was generated by the expander, and all such operators
4441       --  always refer to the operators in package Standard.
4442
4443       if Comes_From_Source (N) then
4444          declare
4445             F : constant Entity_Id := First_Formal (Op_Id);
4446
4447          begin
4448             --  Verify that Op_Id is a visible unary function. Note that since
4449             --  we know Op_Id is overloaded, potentially use visible means use
4450             --  visible for sure (RM 9.4(11)).
4451
4452             if Ekind (Op_Id) = E_Function
4453               and then No (Next_Formal (F))
4454               and then (Is_Immediately_Visible (Op_Id)
4455                          or else Is_Potentially_Use_Visible (Op_Id))
4456               and then Has_Compatible_Type (Right_Opnd (N), Etype (F))
4457             then
4458                Add_One_Interp (N, Op_Id, Etype (Op_Id));
4459             end if;
4460          end;
4461       end if;
4462    end Analyze_User_Defined_Unary_Op;
4463
4464    ---------------------------
4465    -- Check_Arithmetic_Pair --
4466    ---------------------------
4467
4468    procedure Check_Arithmetic_Pair
4469      (T1, T2 : Entity_Id;
4470       Op_Id  : Entity_Id;
4471       N      : Node_Id)
4472    is
4473       Op_Name : constant Name_Id := Chars (Op_Id);
4474
4475       function Has_Fixed_Op (Typ : Entity_Id; Op : Entity_Id) return Boolean;
4476       --  Check whether the fixed-point type Typ has a user-defined operator
4477       --  (multiplication or division) that should hide the corresponding
4478       --  predefined operator. Used to implement Ada 2005 AI-264, to make
4479       --  such operators more visible and therefore useful.
4480
4481       --  If the name of the operation is an expanded name with prefix
4482       --  Standard, the predefined universal fixed operator is available,
4483       --  as specified by AI-420 (RM 4.5.5 (19.1/2)).
4484
4485       function Specific_Type (T1, T2 : Entity_Id) return Entity_Id;
4486       --  Get specific type (i.e. non-universal type if there is one)
4487
4488       ------------------
4489       -- Has_Fixed_Op --
4490       ------------------
4491
4492       function Has_Fixed_Op (Typ : Entity_Id; Op : Entity_Id) return Boolean is
4493          Bas : constant Entity_Id := Base_Type (Typ);
4494          Ent : Entity_Id;
4495          F1  : Entity_Id;
4496          F2  : Entity_Id;
4497
4498       begin
4499          --  If the universal_fixed operation is given explicitly the rule
4500          --  concerning primitive operations of the type do not apply.
4501
4502          if Nkind (N) = N_Function_Call
4503            and then Nkind (Name (N)) = N_Expanded_Name
4504            and then Entity (Prefix (Name (N))) = Standard_Standard
4505          then
4506             return False;
4507          end if;
4508
4509          --  The operation is treated as primitive if it is declared in the
4510          --  same scope as the type, and therefore on the same entity chain.
4511
4512          Ent := Next_Entity (Typ);
4513          while Present (Ent) loop
4514             if Chars (Ent) = Chars (Op) then
4515                F1 := First_Formal (Ent);
4516                F2 := Next_Formal (F1);
4517
4518                --  The operation counts as primitive if either operand or
4519                --  result are of the given base type, and both operands are
4520                --  fixed point types.
4521
4522                if (Base_Type (Etype (F1)) = Bas
4523                     and then Is_Fixed_Point_Type (Etype (F2)))
4524
4525                  or else
4526                    (Base_Type (Etype (F2)) = Bas
4527                      and then Is_Fixed_Point_Type (Etype (F1)))
4528
4529                  or else
4530                    (Base_Type (Etype (Ent)) = Bas
4531                      and then Is_Fixed_Point_Type (Etype (F1))
4532                      and then Is_Fixed_Point_Type (Etype (F2)))
4533                then
4534                   return True;
4535                end if;
4536             end if;
4537
4538             Next_Entity (Ent);
4539          end loop;
4540
4541          return False;
4542       end Has_Fixed_Op;
4543
4544       -------------------
4545       -- Specific_Type --
4546       -------------------
4547
4548       function Specific_Type (T1, T2 : Entity_Id) return Entity_Id is
4549       begin
4550          if T1 = Universal_Integer or else T1 = Universal_Real then
4551             return Base_Type (T2);
4552          else
4553             return Base_Type (T1);
4554          end if;
4555       end Specific_Type;
4556
4557    --  Start of processing for Check_Arithmetic_Pair
4558
4559    begin
4560       if Op_Name = Name_Op_Add or else Op_Name = Name_Op_Subtract then
4561
4562          if Is_Numeric_Type (T1)
4563            and then Is_Numeric_Type (T2)
4564            and then (Covers (T1 => T1, T2 => T2)
4565                        or else
4566                      Covers (T1 => T2, T2 => T1))
4567          then
4568             Add_One_Interp (N, Op_Id, Specific_Type (T1, T2));
4569          end if;
4570
4571       elsif Op_Name = Name_Op_Multiply or else Op_Name = Name_Op_Divide then
4572
4573          if Is_Fixed_Point_Type (T1)
4574            and then (Is_Fixed_Point_Type (T2)
4575                        or else T2 = Universal_Real)
4576          then
4577             --  If Treat_Fixed_As_Integer is set then the Etype is already set
4578             --  and no further processing is required (this is the case of an
4579             --  operator constructed by Exp_Fixd for a fixed point operation)
4580             --  Otherwise add one interpretation with universal fixed result
4581             --  If the operator is given in  functional notation, it comes
4582             --  from source and Fixed_As_Integer cannot apply.
4583
4584             if (Nkind (N) not in N_Op
4585                  or else not Treat_Fixed_As_Integer (N))
4586               and then
4587                 (not Has_Fixed_Op (T1, Op_Id)
4588                   or else Nkind (Parent (N)) = N_Type_Conversion)
4589             then
4590                Add_One_Interp (N, Op_Id, Universal_Fixed);
4591             end if;
4592
4593          elsif Is_Fixed_Point_Type (T2)
4594            and then (Nkind (N) not in N_Op
4595                       or else not Treat_Fixed_As_Integer (N))
4596            and then T1 = Universal_Real
4597            and then
4598              (not Has_Fixed_Op (T1, Op_Id)
4599                or else Nkind (Parent (N)) = N_Type_Conversion)
4600          then
4601             Add_One_Interp (N, Op_Id, Universal_Fixed);
4602
4603          elsif Is_Numeric_Type (T1)
4604            and then Is_Numeric_Type (T2)
4605            and then (Covers (T1 => T1, T2 => T2)
4606                        or else
4607                      Covers (T1 => T2, T2 => T1))
4608          then
4609             Add_One_Interp (N, Op_Id, Specific_Type (T1, T2));
4610
4611          elsif Is_Fixed_Point_Type (T1)
4612            and then (Base_Type (T2) = Base_Type (Standard_Integer)
4613                        or else T2 = Universal_Integer)
4614          then
4615             Add_One_Interp (N, Op_Id, T1);
4616
4617          elsif T2 = Universal_Real
4618            and then Base_Type (T1) = Base_Type (Standard_Integer)
4619            and then Op_Name = Name_Op_Multiply
4620          then
4621             Add_One_Interp (N, Op_Id, Any_Fixed);
4622
4623          elsif T1 = Universal_Real
4624            and then Base_Type (T2) = Base_Type (Standard_Integer)
4625          then
4626             Add_One_Interp (N, Op_Id, Any_Fixed);
4627
4628          elsif Is_Fixed_Point_Type (T2)
4629            and then (Base_Type (T1) = Base_Type (Standard_Integer)
4630                        or else T1 = Universal_Integer)
4631            and then Op_Name = Name_Op_Multiply
4632          then
4633             Add_One_Interp (N, Op_Id, T2);
4634
4635          elsif T1 = Universal_Real and then T2 = Universal_Integer then
4636             Add_One_Interp (N, Op_Id, T1);
4637
4638          elsif T2 = Universal_Real
4639            and then T1 = Universal_Integer
4640            and then Op_Name = Name_Op_Multiply
4641          then
4642             Add_One_Interp (N, Op_Id, T2);
4643          end if;
4644
4645       elsif Op_Name = Name_Op_Mod or else Op_Name = Name_Op_Rem then
4646
4647          --  Note: The fixed-point operands case with Treat_Fixed_As_Integer
4648          --  set does not require any special processing, since the Etype is
4649          --  already set (case of operation constructed by Exp_Fixed).
4650
4651          if Is_Integer_Type (T1)
4652            and then (Covers (T1 => T1, T2 => T2)
4653                        or else
4654                      Covers (T1 => T2, T2 => T1))
4655          then
4656             Add_One_Interp (N, Op_Id, Specific_Type (T1, T2));
4657          end if;
4658
4659       elsif Op_Name = Name_Op_Expon then
4660          if Is_Numeric_Type (T1)
4661            and then not Is_Fixed_Point_Type (T1)
4662            and then (Base_Type (T2) = Base_Type (Standard_Integer)
4663                       or else T2 = Universal_Integer)
4664          then
4665             Add_One_Interp (N, Op_Id, Base_Type (T1));
4666          end if;
4667
4668       else pragma Assert (Nkind (N) in N_Op_Shift);
4669
4670          --  If not one of the predefined operators, the node may be one
4671          --  of the intrinsic functions. Its kind is always specific, and
4672          --  we can use it directly, rather than the name of the operation.
4673
4674          if Is_Integer_Type (T1)
4675            and then (Base_Type (T2) = Base_Type (Standard_Integer)
4676                       or else T2 = Universal_Integer)
4677          then
4678             Add_One_Interp (N, Op_Id, Base_Type (T1));
4679          end if;
4680       end if;
4681    end Check_Arithmetic_Pair;
4682
4683    -------------------------------
4684    -- Check_Misspelled_Selector --
4685    -------------------------------
4686
4687    procedure Check_Misspelled_Selector
4688      (Prefix : Entity_Id;
4689       Sel    : Node_Id)
4690    is
4691       Max_Suggestions   : constant := 2;
4692       Nr_Of_Suggestions : Natural := 0;
4693
4694       Suggestion_1 : Entity_Id := Empty;
4695       Suggestion_2 : Entity_Id := Empty;
4696
4697       Comp : Entity_Id;
4698
4699    begin
4700       --  All the components of the prefix of selector Sel are matched
4701       --  against  Sel and a count is maintained of possible misspellings.
4702       --  When at the end of the analysis there are one or two (not more!)
4703       --  possible misspellings, these misspellings will be suggested as
4704       --  possible correction.
4705
4706       if not (Is_Private_Type (Prefix) or else Is_Record_Type (Prefix)) then
4707
4708          --  Concurrent types should be handled as well ???
4709
4710          return;
4711       end if;
4712
4713       Comp  := First_Entity (Prefix);
4714       while Nr_Of_Suggestions <= Max_Suggestions and then Present (Comp) loop
4715          if Is_Visible_Component (Comp) then
4716             if Is_Bad_Spelling_Of (Chars (Comp), Chars (Sel)) then
4717                Nr_Of_Suggestions := Nr_Of_Suggestions + 1;
4718
4719                case Nr_Of_Suggestions is
4720                   when 1      => Suggestion_1 := Comp;
4721                   when 2      => Suggestion_2 := Comp;
4722                   when others => exit;
4723                end case;
4724             end if;
4725          end if;
4726
4727          Comp := Next_Entity (Comp);
4728       end loop;
4729
4730       --  Report at most two suggestions
4731
4732       if Nr_Of_Suggestions = 1 then
4733          Error_Msg_NE -- CODEFIX
4734            ("\possible misspelling of&", Sel, Suggestion_1);
4735
4736       elsif Nr_Of_Suggestions = 2 then
4737          Error_Msg_Node_2 := Suggestion_2;
4738          Error_Msg_NE -- CODEFIX
4739            ("\possible misspelling of& or&", Sel, Suggestion_1);
4740       end if;
4741    end Check_Misspelled_Selector;
4742
4743    ----------------------
4744    -- Defined_In_Scope --
4745    ----------------------
4746
4747    function Defined_In_Scope (T : Entity_Id; S : Entity_Id) return Boolean
4748    is
4749       S1 : constant Entity_Id := Scope (Base_Type (T));
4750    begin
4751       return S1 = S
4752         or else (S1 = System_Aux_Id and then S = Scope (S1));
4753    end Defined_In_Scope;
4754
4755    -------------------
4756    -- Diagnose_Call --
4757    -------------------
4758
4759    procedure Diagnose_Call (N : Node_Id; Nam : Node_Id) is
4760       Actual           : Node_Id;
4761       X                : Interp_Index;
4762       It               : Interp;
4763       Err_Mode         : Boolean;
4764       New_Nam          : Node_Id;
4765       Void_Interp_Seen : Boolean := False;
4766
4767       Success : Boolean;
4768       pragma Warnings (Off, Boolean);
4769
4770    begin
4771       if Ada_Version >= Ada_2005 then
4772          Actual := First_Actual (N);
4773          while Present (Actual) loop
4774
4775             --  Ada 2005 (AI-50217): Post an error in case of premature
4776             --  usage of an entity from the limited view.
4777
4778             if not Analyzed (Etype (Actual))
4779              and then From_With_Type (Etype (Actual))
4780             then
4781                Error_Msg_Qual_Level := 1;
4782                Error_Msg_NE
4783                 ("missing with_clause for scope of imported type&",
4784                   Actual, Etype (Actual));
4785                Error_Msg_Qual_Level := 0;
4786             end if;
4787
4788             Next_Actual (Actual);
4789          end loop;
4790       end if;
4791
4792       --   Analyze each candidate call again, with full error reporting
4793       --   for each.
4794
4795       Error_Msg_N
4796         ("no candidate interpretations match the actuals:!", Nam);
4797       Err_Mode := All_Errors_Mode;
4798       All_Errors_Mode := True;
4799
4800       --  If this is a call to an operation of a concurrent type,
4801       --  the failed interpretations have been removed from the
4802       --  name. Recover them to provide full diagnostics.
4803
4804       if Nkind (Parent (Nam)) = N_Selected_Component then
4805          Set_Entity (Nam, Empty);
4806          New_Nam := New_Copy_Tree (Parent (Nam));
4807          Set_Is_Overloaded (New_Nam, False);
4808          Set_Is_Overloaded (Selector_Name (New_Nam), False);
4809          Set_Parent (New_Nam, Parent (Parent (Nam)));
4810          Analyze_Selected_Component (New_Nam);
4811          Get_First_Interp (Selector_Name (New_Nam), X, It);
4812       else
4813          Get_First_Interp (Nam, X, It);
4814       end if;
4815
4816       while Present (It.Nam) loop
4817          if Etype (It.Nam) = Standard_Void_Type then
4818             Void_Interp_Seen := True;
4819          end if;
4820
4821          Analyze_One_Call (N, It.Nam, True, Success);
4822          Get_Next_Interp (X, It);
4823       end loop;
4824
4825       if Nkind (N) = N_Function_Call then
4826          Get_First_Interp (Nam, X, It);
4827          while Present (It.Nam) loop
4828             if Ekind_In (It.Nam, E_Function, E_Operator) then
4829                return;
4830             else
4831                Get_Next_Interp (X, It);
4832             end if;
4833          end loop;
4834
4835          --  If all interpretations are procedures, this deserves a
4836          --  more precise message. Ditto if this appears as the prefix
4837          --  of a selected component, which may be a lexical error.
4838
4839          Error_Msg_N
4840            ("\context requires function call, found procedure name", Nam);
4841
4842          if Nkind (Parent (N)) = N_Selected_Component
4843            and then N = Prefix (Parent (N))
4844          then
4845             Error_Msg_N -- CODEFIX
4846               ("\period should probably be semicolon", Parent (N));
4847          end if;
4848
4849       elsif Nkind (N) = N_Procedure_Call_Statement
4850         and then not Void_Interp_Seen
4851       then
4852          Error_Msg_N (
4853          "\function name found in procedure call", Nam);
4854       end if;
4855
4856       All_Errors_Mode := Err_Mode;
4857    end Diagnose_Call;
4858
4859    ---------------------------
4860    -- Find_Arithmetic_Types --
4861    ---------------------------
4862
4863    procedure Find_Arithmetic_Types
4864      (L, R  : Node_Id;
4865       Op_Id : Entity_Id;
4866       N     : Node_Id)
4867    is
4868       Index1 : Interp_Index;
4869       Index2 : Interp_Index;
4870       It1    : Interp;
4871       It2    : Interp;
4872
4873       procedure Check_Right_Argument (T : Entity_Id);
4874       --  Check right operand of operator
4875
4876       --------------------------
4877       -- Check_Right_Argument --
4878       --------------------------
4879
4880       procedure Check_Right_Argument (T : Entity_Id) is
4881       begin
4882          if not Is_Overloaded (R) then
4883             Check_Arithmetic_Pair (T, Etype (R), Op_Id,  N);
4884          else
4885             Get_First_Interp (R, Index2, It2);
4886             while Present (It2.Typ) loop
4887                Check_Arithmetic_Pair (T, It2.Typ, Op_Id, N);
4888                Get_Next_Interp (Index2, It2);
4889             end loop;
4890          end if;
4891       end Check_Right_Argument;
4892
4893    --  Start of processing for Find_Arithmetic_Types
4894
4895    begin
4896       if not Is_Overloaded (L) then
4897          Check_Right_Argument (Etype (L));
4898
4899       else
4900          Get_First_Interp (L, Index1, It1);
4901          while Present (It1.Typ) loop
4902             Check_Right_Argument (It1.Typ);
4903             Get_Next_Interp (Index1, It1);
4904          end loop;
4905       end if;
4906
4907    end Find_Arithmetic_Types;
4908
4909    ------------------------
4910    -- Find_Boolean_Types --
4911    ------------------------
4912
4913    procedure Find_Boolean_Types
4914      (L, R  : Node_Id;
4915       Op_Id : Entity_Id;
4916       N     : Node_Id)
4917    is
4918       Index : Interp_Index;
4919       It    : Interp;
4920
4921       procedure Check_Numeric_Argument (T : Entity_Id);
4922       --  Special case for logical operations one of whose operands is an
4923       --  integer literal. If both are literal the result is any modular type.
4924
4925       ----------------------------
4926       -- Check_Numeric_Argument --
4927       ----------------------------
4928
4929       procedure Check_Numeric_Argument (T : Entity_Id) is
4930       begin
4931          if T = Universal_Integer then
4932             Add_One_Interp (N, Op_Id, Any_Modular);
4933
4934          elsif Is_Modular_Integer_Type (T) then
4935             Add_One_Interp (N, Op_Id, T);
4936          end if;
4937       end Check_Numeric_Argument;
4938
4939    --  Start of processing for Find_Boolean_Types
4940
4941    begin
4942       if not Is_Overloaded (L) then
4943          if Etype (L) = Universal_Integer
4944            or else Etype (L) = Any_Modular
4945          then
4946             if not Is_Overloaded (R) then
4947                Check_Numeric_Argument (Etype (R));
4948
4949             else
4950                Get_First_Interp (R, Index, It);
4951                while Present (It.Typ) loop
4952                   Check_Numeric_Argument (It.Typ);
4953                   Get_Next_Interp (Index, It);
4954                end loop;
4955             end if;
4956
4957          --  If operands are aggregates, we must assume that they may be
4958          --  boolean arrays, and leave disambiguation for the second pass.
4959          --  If only one is an aggregate, verify that the other one has an
4960          --  interpretation as a boolean array
4961
4962          elsif Nkind (L) = N_Aggregate then
4963             if Nkind (R) = N_Aggregate then
4964                Add_One_Interp (N, Op_Id, Etype (L));
4965
4966             elsif not Is_Overloaded (R) then
4967                if Valid_Boolean_Arg (Etype (R)) then
4968                   Add_One_Interp (N, Op_Id, Etype (R));
4969                end if;
4970
4971             else
4972                Get_First_Interp (R, Index, It);
4973                while Present (It.Typ) loop
4974                   if Valid_Boolean_Arg (It.Typ) then
4975                      Add_One_Interp (N, Op_Id, It.Typ);
4976                   end if;
4977
4978                   Get_Next_Interp (Index, It);
4979                end loop;
4980             end if;
4981
4982          elsif Valid_Boolean_Arg (Etype (L))
4983            and then Has_Compatible_Type (R, Etype (L))
4984          then
4985             Add_One_Interp (N, Op_Id, Etype (L));
4986          end if;
4987
4988       else
4989          Get_First_Interp (L, Index, It);
4990          while Present (It.Typ) loop
4991             if Valid_Boolean_Arg (It.Typ)
4992               and then Has_Compatible_Type (R, It.Typ)
4993             then
4994                Add_One_Interp (N, Op_Id, It.Typ);
4995             end if;
4996
4997             Get_Next_Interp (Index, It);
4998          end loop;
4999       end if;
5000    end Find_Boolean_Types;
5001
5002    ---------------------------
5003    -- Find_Comparison_Types --
5004    ---------------------------
5005
5006    procedure Find_Comparison_Types
5007      (L, R  : Node_Id;
5008       Op_Id : Entity_Id;
5009       N     : Node_Id)
5010    is
5011       Index : Interp_Index;
5012       It    : Interp;
5013       Found : Boolean := False;
5014       I_F   : Interp_Index;
5015       T_F   : Entity_Id;
5016       Scop  : Entity_Id := Empty;
5017
5018       procedure Try_One_Interp (T1 : Entity_Id);
5019       --  Routine to try one proposed interpretation. Note that the context
5020       --  of the operator plays no role in resolving the arguments, so that
5021       --  if there is more than one interpretation of the operands that is
5022       --  compatible with comparison, the operation is ambiguous.
5023
5024       --------------------
5025       -- Try_One_Interp --
5026       --------------------
5027
5028       procedure Try_One_Interp (T1 : Entity_Id) is
5029       begin
5030
5031          --  If the operator is an expanded name, then the type of the operand
5032          --  must be defined in the corresponding scope. If the type is
5033          --  universal, the context will impose the correct type.
5034
5035          if Present (Scop)
5036             and then not Defined_In_Scope (T1, Scop)
5037             and then T1 /= Universal_Integer
5038             and then T1 /= Universal_Real
5039             and then T1 /= Any_String
5040             and then T1 /= Any_Composite
5041          then
5042             return;
5043          end if;
5044
5045          if Valid_Comparison_Arg (T1)
5046            and then Has_Compatible_Type (R, T1)
5047          then
5048             if Found
5049               and then Base_Type (T1) /= Base_Type (T_F)
5050             then
5051                It := Disambiguate (L, I_F, Index, Any_Type);
5052
5053                if It = No_Interp then
5054                   Ambiguous_Operands (N);
5055                   Set_Etype (L, Any_Type);
5056                   return;
5057
5058                else
5059                   T_F := It.Typ;
5060                end if;
5061
5062             else
5063                Found := True;
5064                T_F   := T1;
5065                I_F   := Index;
5066             end if;
5067
5068             Set_Etype (L, T_F);
5069             Find_Non_Universal_Interpretations (N, R, Op_Id, T1);
5070
5071          end if;
5072       end Try_One_Interp;
5073
5074    --  Start of processing for Find_Comparison_Types
5075
5076    begin
5077       --  If left operand is aggregate, the right operand has to
5078       --  provide a usable type for it.
5079
5080       if Nkind (L) = N_Aggregate
5081         and then Nkind (R) /= N_Aggregate
5082       then
5083          Find_Comparison_Types (L => R, R => L, Op_Id => Op_Id, N => N);
5084          return;
5085       end if;
5086
5087       if Nkind (N) = N_Function_Call
5088          and then Nkind (Name (N)) = N_Expanded_Name
5089       then
5090          Scop := Entity (Prefix (Name (N)));
5091
5092          --  The prefix may be a package renaming, and the subsequent test
5093          --  requires the original package.
5094
5095          if Ekind (Scop) = E_Package
5096            and then Present (Renamed_Entity (Scop))
5097          then
5098             Scop := Renamed_Entity (Scop);
5099             Set_Entity (Prefix (Name (N)), Scop);
5100          end if;
5101       end if;
5102
5103       if not Is_Overloaded (L) then
5104          Try_One_Interp (Etype (L));
5105
5106       else
5107          Get_First_Interp (L, Index, It);
5108          while Present (It.Typ) loop
5109             Try_One_Interp (It.Typ);
5110             Get_Next_Interp (Index, It);
5111          end loop;
5112       end if;
5113    end Find_Comparison_Types;
5114
5115    ----------------------------------------
5116    -- Find_Non_Universal_Interpretations --
5117    ----------------------------------------
5118
5119    procedure Find_Non_Universal_Interpretations
5120      (N     : Node_Id;
5121       R     : Node_Id;
5122       Op_Id : Entity_Id;
5123       T1    : Entity_Id)
5124    is
5125       Index : Interp_Index;
5126       It    : Interp;
5127
5128    begin
5129       if T1 = Universal_Integer
5130         or else T1 = Universal_Real
5131       then
5132          if not Is_Overloaded (R) then
5133             Add_One_Interp
5134               (N, Op_Id, Standard_Boolean, Base_Type (Etype (R)));
5135          else
5136             Get_First_Interp (R, Index, It);
5137             while Present (It.Typ) loop
5138                if Covers (It.Typ, T1) then
5139                   Add_One_Interp
5140                     (N, Op_Id, Standard_Boolean, Base_Type (It.Typ));
5141                end if;
5142
5143                Get_Next_Interp (Index, It);
5144             end loop;
5145          end if;
5146       else
5147          Add_One_Interp (N, Op_Id, Standard_Boolean, Base_Type (T1));
5148       end if;
5149    end Find_Non_Universal_Interpretations;
5150
5151    ------------------------------
5152    -- Find_Concatenation_Types --
5153    ------------------------------
5154
5155    procedure Find_Concatenation_Types
5156      (L, R  : Node_Id;
5157       Op_Id : Entity_Id;
5158       N     : Node_Id)
5159    is
5160       Op_Type : constant Entity_Id := Etype (Op_Id);
5161
5162    begin
5163       if Is_Array_Type (Op_Type)
5164         and then not Is_Limited_Type (Op_Type)
5165
5166         and then (Has_Compatible_Type (L, Op_Type)
5167                     or else
5168                   Has_Compatible_Type (L, Component_Type (Op_Type)))
5169
5170         and then (Has_Compatible_Type (R, Op_Type)
5171                     or else
5172                   Has_Compatible_Type (R, Component_Type (Op_Type)))
5173       then
5174          Add_One_Interp (N, Op_Id, Op_Type);
5175       end if;
5176    end Find_Concatenation_Types;
5177
5178    -------------------------
5179    -- Find_Equality_Types --
5180    -------------------------
5181
5182    procedure Find_Equality_Types
5183      (L, R  : Node_Id;
5184       Op_Id : Entity_Id;
5185       N     : Node_Id)
5186    is
5187       Index : Interp_Index;
5188       It    : Interp;
5189       Found : Boolean := False;
5190       I_F   : Interp_Index;
5191       T_F   : Entity_Id;
5192       Scop  : Entity_Id := Empty;
5193
5194       procedure Try_One_Interp (T1 : Entity_Id);
5195       --  The context of the equality operator plays no role in resolving the
5196       --  arguments, so that if there is more than one interpretation of the
5197       --  operands that is compatible with equality, the construct is ambiguous
5198       --  and an error can be emitted now, after trying to disambiguate, i.e.
5199       --  applying preference rules.
5200
5201       --------------------
5202       -- Try_One_Interp --
5203       --------------------
5204
5205       procedure Try_One_Interp (T1 : Entity_Id) is
5206          Bas : constant Entity_Id := Base_Type (T1);
5207
5208       begin
5209          --  If the operator is an expanded name, then the type of the operand
5210          --  must be defined in the corresponding scope. If the type is
5211          --  universal, the context will impose the correct type. An anonymous
5212          --  type for a 'Access reference is also universal in this sense, as
5213          --  the actual type is obtained from context.
5214          --  In Ada 2005, the equality operator for anonymous access types
5215          --  is declared in Standard, and preference rules apply to it.
5216
5217          if Present (Scop) then
5218             if Defined_In_Scope (T1, Scop)
5219               or else T1 = Universal_Integer
5220               or else T1 = Universal_Real
5221               or else T1 = Any_Access
5222               or else T1 = Any_String
5223               or else T1 = Any_Composite
5224               or else (Ekind (T1) = E_Access_Subprogram_Type
5225                         and then not Comes_From_Source (T1))
5226             then
5227                null;
5228
5229             elsif Ekind (T1) = E_Anonymous_Access_Type
5230               and then Scop = Standard_Standard
5231             then
5232                null;
5233
5234             else
5235                --  The scope does not contain an operator for the type
5236
5237                return;
5238             end if;
5239
5240          --  If we have infix notation, the operator must be usable.
5241          --  Within an instance, if the type is already established we
5242          --  know it is correct.
5243          --  In Ada 2005, the equality on anonymous access types is declared
5244          --  in Standard, and is always visible.
5245
5246          elsif In_Open_Scopes (Scope (Bas))
5247            or else Is_Potentially_Use_Visible (Bas)
5248            or else In_Use (Bas)
5249            or else (In_Use (Scope (Bas))
5250                      and then not Is_Hidden (Bas))
5251            or else (In_Instance
5252                      and then First_Subtype (T1) = First_Subtype (Etype (R)))
5253            or else Ekind (T1) = E_Anonymous_Access_Type
5254          then
5255             null;
5256
5257          else
5258             --  Save candidate type for subsquent error message, if any
5259
5260             if not Is_Limited_Type (T1) then
5261                Candidate_Type := T1;
5262             end if;
5263
5264             return;
5265          end if;
5266
5267          --  Ada 2005 (AI-230): Keep restriction imposed by Ada 83 and 95:
5268          --  Do not allow anonymous access types in equality operators.
5269
5270          if Ada_Version < Ada_2005
5271            and then Ekind (T1) = E_Anonymous_Access_Type
5272          then
5273             return;
5274          end if;
5275
5276          if T1 /= Standard_Void_Type
5277            and then not Is_Limited_Type (T1)
5278            and then not Is_Limited_Composite (T1)
5279            and then Has_Compatible_Type (R, T1)
5280          then
5281             if Found
5282               and then Base_Type (T1) /= Base_Type (T_F)
5283             then
5284                It := Disambiguate (L, I_F, Index, Any_Type);
5285
5286                if It = No_Interp then
5287                   Ambiguous_Operands (N);
5288                   Set_Etype (L, Any_Type);
5289                   return;
5290
5291                else
5292                   T_F := It.Typ;
5293                end if;
5294
5295             else
5296                Found := True;
5297                T_F   := T1;
5298                I_F   := Index;
5299             end if;
5300
5301             if not Analyzed (L) then
5302                Set_Etype (L, T_F);
5303             end if;
5304
5305             Find_Non_Universal_Interpretations (N, R, Op_Id, T1);
5306
5307             --  Case of operator was not visible, Etype still set to Any_Type
5308
5309             if Etype (N) = Any_Type then
5310                Found := False;
5311             end if;
5312
5313          elsif Scop = Standard_Standard
5314            and then Ekind (T1) = E_Anonymous_Access_Type
5315          then
5316             Found := True;
5317          end if;
5318       end Try_One_Interp;
5319
5320    --  Start of processing for Find_Equality_Types
5321
5322    begin
5323       --  If left operand is aggregate, the right operand has to
5324       --  provide a usable type for it.
5325
5326       if Nkind (L) = N_Aggregate
5327         and then Nkind (R) /= N_Aggregate
5328       then
5329          Find_Equality_Types (L => R, R => L, Op_Id => Op_Id, N => N);
5330          return;
5331       end if;
5332
5333       if Nkind (N) = N_Function_Call
5334          and then Nkind (Name (N)) = N_Expanded_Name
5335       then
5336          Scop := Entity (Prefix (Name (N)));
5337
5338          --  The prefix may be a package renaming, and the subsequent test
5339          --  requires the original package.
5340
5341          if Ekind (Scop) = E_Package
5342            and then Present (Renamed_Entity (Scop))
5343          then
5344             Scop := Renamed_Entity (Scop);
5345             Set_Entity (Prefix (Name (N)), Scop);
5346          end if;
5347       end if;
5348
5349       if not Is_Overloaded (L) then
5350          Try_One_Interp (Etype (L));
5351
5352       else
5353          Get_First_Interp (L, Index, It);
5354          while Present (It.Typ) loop
5355             Try_One_Interp (It.Typ);
5356             Get_Next_Interp (Index, It);
5357          end loop;
5358       end if;
5359    end Find_Equality_Types;
5360
5361    -------------------------
5362    -- Find_Negation_Types --
5363    -------------------------
5364
5365    procedure Find_Negation_Types
5366      (R     : Node_Id;
5367       Op_Id : Entity_Id;
5368       N     : Node_Id)
5369    is
5370       Index : Interp_Index;
5371       It    : Interp;
5372
5373    begin
5374       if not Is_Overloaded (R) then
5375          if Etype (R) = Universal_Integer then
5376             Add_One_Interp (N, Op_Id, Any_Modular);
5377          elsif Valid_Boolean_Arg (Etype (R)) then
5378             Add_One_Interp (N, Op_Id, Etype (R));
5379          end if;
5380
5381       else
5382          Get_First_Interp (R, Index, It);
5383          while Present (It.Typ) loop
5384             if Valid_Boolean_Arg (It.Typ) then
5385                Add_One_Interp (N, Op_Id, It.Typ);
5386             end if;
5387
5388             Get_Next_Interp (Index, It);
5389          end loop;
5390       end if;
5391    end Find_Negation_Types;
5392
5393    ------------------------------
5394    -- Find_Primitive_Operation --
5395    ------------------------------
5396
5397    function Find_Primitive_Operation (N : Node_Id) return Boolean is
5398       Obj : constant Node_Id := Prefix (N);
5399       Op  : constant Node_Id := Selector_Name (N);
5400
5401       Prim  : Elmt_Id;
5402       Prims : Elist_Id;
5403       Typ   : Entity_Id;
5404
5405    begin
5406       Set_Etype (Op, Any_Type);
5407
5408       if Is_Access_Type (Etype (Obj)) then
5409          Typ := Designated_Type (Etype (Obj));
5410       else
5411          Typ := Etype (Obj);
5412       end if;
5413
5414       if Is_Class_Wide_Type (Typ) then
5415          Typ := Root_Type (Typ);
5416       end if;
5417
5418       Prims := Primitive_Operations (Typ);
5419
5420       Prim := First_Elmt (Prims);
5421       while Present (Prim) loop
5422          if Chars (Node (Prim)) = Chars (Op) then
5423             Add_One_Interp (Op, Node (Prim), Etype (Node (Prim)));
5424             Set_Etype (N, Etype (Node (Prim)));
5425          end if;
5426
5427          Next_Elmt (Prim);
5428       end loop;
5429
5430       --  Now look for class-wide operations of the type or any of its
5431       --  ancestors by iterating over the homonyms of the selector.
5432
5433       declare
5434          Cls_Type : constant Entity_Id := Class_Wide_Type (Typ);
5435          Hom      : Entity_Id;
5436
5437       begin
5438          Hom := Current_Entity (Op);
5439          while Present (Hom) loop
5440             if (Ekind (Hom) = E_Procedure
5441                   or else
5442                 Ekind (Hom) = E_Function)
5443               and then Scope (Hom) = Scope (Typ)
5444               and then Present (First_Formal (Hom))
5445               and then
5446                 (Base_Type (Etype (First_Formal (Hom))) = Cls_Type
5447                   or else
5448                     (Is_Access_Type (Etype (First_Formal (Hom)))
5449                        and then
5450                          Ekind (Etype (First_Formal (Hom))) =
5451                            E_Anonymous_Access_Type
5452                        and then
5453                          Base_Type
5454                            (Designated_Type (Etype (First_Formal (Hom)))) =
5455                                                                 Cls_Type))
5456             then
5457                Add_One_Interp (Op, Hom, Etype (Hom));
5458                Set_Etype (N, Etype (Hom));
5459             end if;
5460
5461             Hom := Homonym (Hom);
5462          end loop;
5463       end;
5464
5465       return Etype (Op) /= Any_Type;
5466    end Find_Primitive_Operation;
5467
5468    ----------------------
5469    -- Find_Unary_Types --
5470    ----------------------
5471
5472    procedure Find_Unary_Types
5473      (R     : Node_Id;
5474       Op_Id : Entity_Id;
5475       N     : Node_Id)
5476    is
5477       Index : Interp_Index;
5478       It    : Interp;
5479
5480    begin
5481       if not Is_Overloaded (R) then
5482          if Is_Numeric_Type (Etype (R)) then
5483             Add_One_Interp (N, Op_Id, Base_Type (Etype (R)));
5484          end if;
5485
5486       else
5487          Get_First_Interp (R, Index, It);
5488          while Present (It.Typ) loop
5489             if Is_Numeric_Type (It.Typ) then
5490                Add_One_Interp (N, Op_Id, Base_Type (It.Typ));
5491             end if;
5492
5493             Get_Next_Interp (Index, It);
5494          end loop;
5495       end if;
5496    end Find_Unary_Types;
5497
5498    ------------------
5499    -- Junk_Operand --
5500    ------------------
5501
5502    function Junk_Operand (N : Node_Id) return Boolean is
5503       Enode : Node_Id;
5504
5505    begin
5506       if Error_Posted (N) then
5507          return False;
5508       end if;
5509
5510       --  Get entity to be tested
5511
5512       if Is_Entity_Name (N)
5513         and then Present (Entity (N))
5514       then
5515          Enode := N;
5516
5517       --  An odd case, a procedure name gets converted to a very peculiar
5518       --  function call, and here is where we detect this happening.
5519
5520       elsif Nkind (N) = N_Function_Call
5521         and then Is_Entity_Name (Name (N))
5522         and then Present (Entity (Name (N)))
5523       then
5524          Enode := Name (N);
5525
5526       --  Another odd case, there are at least some cases of selected
5527       --  components where the selected component is not marked as having
5528       --  an entity, even though the selector does have an entity
5529
5530       elsif Nkind (N) = N_Selected_Component
5531         and then Present (Entity (Selector_Name (N)))
5532       then
5533          Enode := Selector_Name (N);
5534
5535       else
5536          return False;
5537       end if;
5538
5539       --  Now test the entity we got to see if it is a bad case
5540
5541       case Ekind (Entity (Enode)) is
5542
5543          when E_Package =>
5544             Error_Msg_N
5545               ("package name cannot be used as operand", Enode);
5546
5547          when Generic_Unit_Kind =>
5548             Error_Msg_N
5549               ("generic unit name cannot be used as operand", Enode);
5550
5551          when Type_Kind =>
5552             Error_Msg_N
5553               ("subtype name cannot be used as operand", Enode);
5554
5555          when Entry_Kind =>
5556             Error_Msg_N
5557               ("entry name cannot be used as operand", Enode);
5558
5559          when E_Procedure =>
5560             Error_Msg_N
5561               ("procedure name cannot be used as operand", Enode);
5562
5563          when E_Exception =>
5564             Error_Msg_N
5565               ("exception name cannot be used as operand", Enode);
5566
5567          when E_Block | E_Label | E_Loop =>
5568             Error_Msg_N
5569               ("label name cannot be used as operand", Enode);
5570
5571          when others =>
5572             return False;
5573
5574       end case;
5575
5576       return True;
5577    end Junk_Operand;
5578
5579    --------------------
5580    -- Operator_Check --
5581    --------------------
5582
5583    procedure Operator_Check (N : Node_Id) is
5584    begin
5585       Remove_Abstract_Operations (N);
5586
5587       --  Test for case of no interpretation found for operator
5588
5589       if Etype (N) = Any_Type then
5590          declare
5591             L     : Node_Id;
5592             R     : Node_Id;
5593             Op_Id : Entity_Id := Empty;
5594
5595          begin
5596             R := Right_Opnd (N);
5597
5598             if Nkind (N) in N_Binary_Op then
5599                L := Left_Opnd (N);
5600             else
5601                L := Empty;
5602             end if;
5603
5604             --  If either operand has no type, then don't complain further,
5605             --  since this simply means that we have a propagated error.
5606
5607             if R = Error
5608               or else Etype (R) = Any_Type
5609               or else (Nkind (N) in N_Binary_Op and then Etype (L) = Any_Type)
5610             then
5611                return;
5612
5613             --  We explicitly check for the case of concatenation of component
5614             --  with component to avoid reporting spurious matching array types
5615             --  that might happen to be lurking in distant packages (such as
5616             --  run-time packages). This also prevents inconsistencies in the
5617             --  messages for certain ACVC B tests, which can vary depending on
5618             --  types declared in run-time interfaces. Another improvement when
5619             --  aggregates are present is to look for a well-typed operand.
5620
5621             elsif Present (Candidate_Type)
5622               and then (Nkind (N) /= N_Op_Concat
5623                          or else Is_Array_Type (Etype (L))
5624                          or else Is_Array_Type (Etype (R)))
5625             then
5626
5627                if Nkind (N) = N_Op_Concat then
5628                   if Etype (L) /= Any_Composite
5629                     and then Is_Array_Type (Etype (L))
5630                   then
5631                      Candidate_Type := Etype (L);
5632
5633                   elsif Etype (R) /= Any_Composite
5634                     and then Is_Array_Type (Etype (R))
5635                   then
5636                      Candidate_Type := Etype (R);
5637                   end if;
5638                end if;
5639
5640                Error_Msg_NE -- CODEFIX
5641                  ("operator for} is not directly visible!",
5642                   N, First_Subtype (Candidate_Type));
5643                Error_Msg_N -- CODEFIX
5644                  ("use clause would make operation legal!",  N);
5645                return;
5646
5647             --  If either operand is a junk operand (e.g. package name), then
5648             --  post appropriate error messages, but do not complain further.
5649
5650             --  Note that the use of OR in this test instead of OR ELSE is
5651             --  quite deliberate, we may as well check both operands in the
5652             --  binary operator case.
5653
5654             elsif Junk_Operand (R)
5655               or (Nkind (N) in N_Binary_Op and then Junk_Operand (L))
5656             then
5657                return;
5658
5659             --  If we have a logical operator, one of whose operands is
5660             --  Boolean, then we know that the other operand cannot resolve to
5661             --  Boolean (since we got no interpretations), but in that case we
5662             --  pretty much know that the other operand should be Boolean, so
5663             --  resolve it that way (generating an error)
5664
5665             elsif Nkind_In (N, N_Op_And, N_Op_Or, N_Op_Xor) then
5666                if Etype (L) = Standard_Boolean then
5667                   Resolve (R, Standard_Boolean);
5668                   return;
5669                elsif Etype (R) = Standard_Boolean then
5670                   Resolve (L, Standard_Boolean);
5671                   return;
5672                end if;
5673
5674             --  For an arithmetic operator or comparison operator, if one
5675             --  of the operands is numeric, then we know the other operand
5676             --  is not the same numeric type. If it is a non-numeric type,
5677             --  then probably it is intended to match the other operand.
5678
5679             elsif Nkind_In (N, N_Op_Add,
5680                                N_Op_Divide,
5681                                N_Op_Ge,
5682                                N_Op_Gt,
5683                                N_Op_Le)
5684               or else
5685                   Nkind_In (N, N_Op_Lt,
5686                                N_Op_Mod,
5687                                N_Op_Multiply,
5688                                N_Op_Rem,
5689                                N_Op_Subtract)
5690             then
5691                if Is_Numeric_Type (Etype (L))
5692                  and then not Is_Numeric_Type (Etype (R))
5693                then
5694                   Resolve (R, Etype (L));
5695                   return;
5696
5697                elsif Is_Numeric_Type (Etype (R))
5698                  and then not Is_Numeric_Type (Etype (L))
5699                then
5700                   Resolve (L, Etype (R));
5701                   return;
5702                end if;
5703
5704             --  Comparisons on A'Access are common enough to deserve a
5705             --  special message.
5706
5707             elsif Nkind_In (N, N_Op_Eq, N_Op_Ne)
5708                and then Ekind (Etype (L)) = E_Access_Attribute_Type
5709                and then Ekind (Etype (R)) = E_Access_Attribute_Type
5710             then
5711                Error_Msg_N
5712                  ("two access attributes cannot be compared directly", N);
5713                Error_Msg_N
5714                  ("\use qualified expression for one of the operands",
5715                    N);
5716                return;
5717
5718             --  Another one for C programmers
5719
5720             elsif Nkind (N) = N_Op_Concat
5721               and then Valid_Boolean_Arg (Etype (L))
5722               and then Valid_Boolean_Arg (Etype (R))
5723             then
5724                Error_Msg_N ("invalid operands for concatenation", N);
5725                Error_Msg_N -- CODEFIX
5726                  ("\maybe AND was meant", N);
5727                return;
5728
5729             --  A special case for comparison of access parameter with null
5730
5731             elsif Nkind (N) = N_Op_Eq
5732               and then Is_Entity_Name (L)
5733               and then Nkind (Parent (Entity (L))) = N_Parameter_Specification
5734               and then Nkind (Parameter_Type (Parent (Entity (L)))) =
5735                                                   N_Access_Definition
5736               and then Nkind (R) = N_Null
5737             then
5738                Error_Msg_N ("access parameter is not allowed to be null", L);
5739                Error_Msg_N ("\(call would raise Constraint_Error)", L);
5740                return;
5741
5742             --  Another special case for exponentiation, where the right
5743             --  operand must be Natural, independently of the base.
5744
5745             elsif Nkind (N) = N_Op_Expon
5746               and then Is_Numeric_Type (Etype (L))
5747               and then not Is_Overloaded (R)
5748               and then
5749                 First_Subtype (Base_Type (Etype (R))) /= Standard_Integer
5750               and then Base_Type (Etype (R)) /= Universal_Integer
5751             then
5752                Error_Msg_NE
5753                  ("exponent must be of type Natural, found}", R, Etype (R));
5754                return;
5755             end if;
5756
5757             --  If we fall through then just give general message. Note that in
5758             --  the following messages, if the operand is overloaded we choose
5759             --  an arbitrary type to complain about, but that is probably more
5760             --  useful than not giving a type at all.
5761
5762             if Nkind (N) in N_Unary_Op then
5763                Error_Msg_Node_2 := Etype (R);
5764                Error_Msg_N ("operator& not defined for}", N);
5765                return;
5766
5767             else
5768                if Nkind (N) in N_Binary_Op then
5769                   if not Is_Overloaded (L)
5770                     and then not Is_Overloaded (R)
5771                     and then Base_Type (Etype (L)) = Base_Type (Etype (R))
5772                   then
5773                      Error_Msg_Node_2 := First_Subtype (Etype (R));
5774                      Error_Msg_N ("there is no applicable operator& for}", N);
5775
5776                   else
5777                      --  Another attempt to find a fix: one of the candidate
5778                      --  interpretations may not be use-visible. This has
5779                      --  already been checked for predefined operators, so
5780                      --  we examine only user-defined functions.
5781
5782                      Op_Id := Get_Name_Entity_Id (Chars (N));
5783
5784                      while Present (Op_Id) loop
5785                         if Ekind (Op_Id) /= E_Operator
5786                           and then Is_Overloadable (Op_Id)
5787                         then
5788                            if not Is_Immediately_Visible (Op_Id)
5789                              and then not In_Use (Scope (Op_Id))
5790                              and then not Is_Abstract_Subprogram (Op_Id)
5791                              and then not Is_Hidden (Op_Id)
5792                              and then Ekind (Scope (Op_Id)) = E_Package
5793                              and then
5794                                Has_Compatible_Type
5795                                  (L, Etype (First_Formal (Op_Id)))
5796                              and then Present
5797                               (Next_Formal (First_Formal (Op_Id)))
5798                              and then
5799                                Has_Compatible_Type
5800                                  (R,
5801                                   Etype (Next_Formal (First_Formal (Op_Id))))
5802                            then
5803                               Error_Msg_N
5804                                 ("No legal interpretation for operator&", N);
5805                               Error_Msg_NE
5806                                 ("\use clause on& would make operation legal",
5807                                    N, Scope (Op_Id));
5808                               exit;
5809                            end if;
5810                         end if;
5811
5812                         Op_Id := Homonym (Op_Id);
5813                      end loop;
5814
5815                      if No (Op_Id) then
5816                         Error_Msg_N ("invalid operand types for operator&", N);
5817
5818                         if Nkind (N) /= N_Op_Concat then
5819                            Error_Msg_NE ("\left operand has}!",  N, Etype (L));
5820                            Error_Msg_NE ("\right operand has}!", N, Etype (R));
5821                         end if;
5822                      end if;
5823                   end if;
5824                end if;
5825             end if;
5826          end;
5827       end if;
5828    end Operator_Check;
5829
5830    -----------------------------------------
5831    -- Process_Implicit_Dereference_Prefix --
5832    -----------------------------------------
5833
5834    function Process_Implicit_Dereference_Prefix
5835      (E : Entity_Id;
5836       P : Entity_Id) return Entity_Id
5837    is
5838       Ref : Node_Id;
5839       Typ : constant Entity_Id := Designated_Type (Etype (P));
5840
5841    begin
5842       if Present (E)
5843         and then (Operating_Mode = Check_Semantics or else not Expander_Active)
5844       then
5845          --  We create a dummy reference to E to ensure that the reference
5846          --  is not considered as part of an assignment (an implicit
5847          --  dereference can never assign to its prefix). The Comes_From_Source
5848          --  attribute needs to be propagated for accurate warnings.
5849
5850          Ref := New_Reference_To (E, Sloc (P));
5851          Set_Comes_From_Source (Ref, Comes_From_Source (P));
5852          Generate_Reference (E, Ref);
5853       end if;
5854
5855       --  An implicit dereference is a legal occurrence of an
5856       --  incomplete type imported through a limited_with clause,
5857       --  if the full view is visible.
5858
5859       if From_With_Type (Typ)
5860         and then not From_With_Type (Scope (Typ))
5861         and then
5862           (Is_Immediately_Visible (Scope (Typ))
5863             or else
5864               (Is_Child_Unit (Scope (Typ))
5865                  and then Is_Visible_Child_Unit (Scope (Typ))))
5866       then
5867          return Available_View (Typ);
5868       else
5869          return Typ;
5870       end if;
5871
5872    end Process_Implicit_Dereference_Prefix;
5873
5874    --------------------------------
5875    -- Remove_Abstract_Operations --
5876    --------------------------------
5877
5878    procedure Remove_Abstract_Operations (N : Node_Id) is
5879       Abstract_Op    : Entity_Id := Empty;
5880       Address_Kludge : Boolean := False;
5881       I              : Interp_Index;
5882       It             : Interp;
5883
5884       --  AI-310: If overloaded, remove abstract non-dispatching operations. We
5885       --  activate this if either extensions are enabled, or if the abstract
5886       --  operation in question comes from a predefined file. This latter test
5887       --  allows us to use abstract to make operations invisible to users. In
5888       --  particular, if type Address is non-private and abstract subprograms
5889       --  are used to hide its operators, they will be truly hidden.
5890
5891       type Operand_Position is (First_Op, Second_Op);
5892       Univ_Type : constant Entity_Id := Universal_Interpretation (N);
5893
5894       procedure Remove_Address_Interpretations (Op : Operand_Position);
5895       --  Ambiguities may arise when the operands are literal and the address
5896       --  operations in s-auxdec are visible. In that case, remove the
5897       --  interpretation of a literal as Address, to retain the semantics of
5898       --  Address as a private type.
5899
5900       ------------------------------------
5901       -- Remove_Address_Interpretations --
5902       ------------------------------------
5903
5904       procedure Remove_Address_Interpretations (Op : Operand_Position) is
5905          Formal : Entity_Id;
5906
5907       begin
5908          if Is_Overloaded (N) then
5909             Get_First_Interp (N, I, It);
5910             while Present (It.Nam) loop
5911                Formal := First_Entity (It.Nam);
5912
5913                if Op = Second_Op then
5914                   Formal := Next_Entity (Formal);
5915                end if;
5916
5917                if Is_Descendent_Of_Address (Etype (Formal)) then
5918                   Address_Kludge := True;
5919                   Remove_Interp (I);
5920                end if;
5921
5922                Get_Next_Interp (I, It);
5923             end loop;
5924          end if;
5925       end Remove_Address_Interpretations;
5926
5927    --  Start of processing for Remove_Abstract_Operations
5928
5929    begin
5930       if Is_Overloaded (N) then
5931          Get_First_Interp (N, I, It);
5932
5933          while Present (It.Nam) loop
5934             if Is_Overloadable (It.Nam)
5935               and then Is_Abstract_Subprogram (It.Nam)
5936               and then not Is_Dispatching_Operation (It.Nam)
5937             then
5938                Abstract_Op := It.Nam;
5939
5940                if Is_Descendent_Of_Address (It.Typ) then
5941                   Address_Kludge := True;
5942                   Remove_Interp (I);
5943                   exit;
5944
5945                --  In Ada 2005, this operation does not participate in Overload
5946                --  resolution. If the operation is defined in a predefined
5947                --  unit, it is one of the operations declared abstract in some
5948                --  variants of System, and it must be removed as well.
5949
5950                elsif Ada_Version >= Ada_2005
5951                  or else Is_Predefined_File_Name
5952                            (Unit_File_Name (Get_Source_Unit (It.Nam)))
5953                then
5954                   Remove_Interp (I);
5955                   exit;
5956                end if;
5957             end if;
5958
5959             Get_Next_Interp (I, It);
5960          end loop;
5961
5962          if No (Abstract_Op) then
5963
5964             --  If some interpretation yields an integer type, it is still
5965             --  possible that there are address interpretations. Remove them
5966             --  if one operand is a literal, to avoid spurious ambiguities
5967             --  on systems where Address is a visible integer type.
5968
5969             if Is_Overloaded (N)
5970               and then Nkind (N) in N_Op
5971               and then Is_Integer_Type (Etype (N))
5972             then
5973                if Nkind (N) in N_Binary_Op then
5974                   if Nkind (Right_Opnd (N)) = N_Integer_Literal then
5975                      Remove_Address_Interpretations (Second_Op);
5976
5977                   elsif Nkind (Right_Opnd (N)) = N_Integer_Literal then
5978                      Remove_Address_Interpretations (First_Op);
5979                   end if;
5980                end if;
5981             end if;
5982
5983          elsif Nkind (N) in N_Op then
5984
5985             --  Remove interpretations that treat literals as addresses. This
5986             --  is never appropriate, even when Address is defined as a visible
5987             --  Integer type. The reason is that we would really prefer Address
5988             --  to behave as a private type, even in this case, which is there
5989             --  only to accommodate oddities of VMS address sizes. If Address
5990             --  is a visible integer type, we get lots of overload ambiguities.
5991
5992             if Nkind (N) in N_Binary_Op then
5993                declare
5994                   U1 : constant Boolean :=
5995                      Present (Universal_Interpretation (Right_Opnd (N)));
5996                   U2 : constant Boolean :=
5997                      Present (Universal_Interpretation (Left_Opnd (N)));
5998
5999                begin
6000                   if U1 then
6001                      Remove_Address_Interpretations (Second_Op);
6002                   end if;
6003
6004                   if U2 then
6005                      Remove_Address_Interpretations (First_Op);
6006                   end if;
6007
6008                   if not (U1 and U2) then
6009
6010                      --  Remove corresponding predefined operator, which is
6011                      --  always added to the overload set.
6012
6013                      Get_First_Interp (N, I, It);
6014                      while Present (It.Nam) loop
6015                         if Scope (It.Nam) = Standard_Standard
6016                           and then Base_Type (It.Typ) =
6017                                    Base_Type (Etype (Abstract_Op))
6018                         then
6019                            Remove_Interp (I);
6020                         end if;
6021
6022                         Get_Next_Interp (I, It);
6023                      end loop;
6024
6025                   elsif Is_Overloaded (N)
6026                     and then Present (Univ_Type)
6027                   then
6028                      --  If both operands have a universal interpretation,
6029                      --  it is still necessary to remove interpretations that
6030                      --  yield Address. Any remaining ambiguities will be
6031                      --  removed in Disambiguate.
6032
6033                      Get_First_Interp (N, I, It);
6034                      while Present (It.Nam) loop
6035                         if Is_Descendent_Of_Address (It.Typ) then
6036                            Remove_Interp (I);
6037
6038                         elsif not Is_Type (It.Nam) then
6039                            Set_Entity (N, It.Nam);
6040                         end if;
6041
6042                         Get_Next_Interp (I, It);
6043                      end loop;
6044                   end if;
6045                end;
6046             end if;
6047
6048          elsif Nkind (N) = N_Function_Call
6049            and then
6050              (Nkind (Name (N)) = N_Operator_Symbol
6051                 or else
6052                   (Nkind (Name (N)) = N_Expanded_Name
6053                      and then
6054                        Nkind (Selector_Name (Name (N))) = N_Operator_Symbol))
6055          then
6056
6057             declare
6058                Arg1 : constant Node_Id := First (Parameter_Associations (N));
6059                U1   : constant Boolean :=
6060                         Present (Universal_Interpretation (Arg1));
6061                U2   : constant Boolean :=
6062                         Present (Next (Arg1)) and then
6063                         Present (Universal_Interpretation (Next (Arg1)));
6064
6065             begin
6066                if U1 then
6067                   Remove_Address_Interpretations (First_Op);
6068                end if;
6069
6070                if U2 then
6071                   Remove_Address_Interpretations (Second_Op);
6072                end if;
6073
6074                if not (U1 and U2) then
6075                   Get_First_Interp (N, I, It);
6076                   while Present (It.Nam) loop
6077                      if Scope (It.Nam) = Standard_Standard
6078                        and then It.Typ = Base_Type (Etype (Abstract_Op))
6079                      then
6080                         Remove_Interp (I);
6081                      end if;
6082
6083                      Get_Next_Interp (I, It);
6084                   end loop;
6085                end if;
6086             end;
6087          end if;
6088
6089          --  If the removal has left no valid interpretations, emit an error
6090          --  message now and label node as illegal.
6091
6092          if Present (Abstract_Op) then
6093             Get_First_Interp (N, I, It);
6094
6095             if No (It.Nam) then
6096
6097                --  Removal of abstract operation left no viable candidate
6098
6099                Set_Etype (N, Any_Type);
6100                Error_Msg_Sloc := Sloc (Abstract_Op);
6101                Error_Msg_NE
6102                  ("cannot call abstract operation& declared#", N, Abstract_Op);
6103
6104             --  In Ada 2005, an abstract operation may disable predefined
6105             --  operators. Since the context is not yet known, we mark the
6106             --  predefined operators as potentially hidden. Do not include
6107             --  predefined operators when addresses are involved since this
6108             --  case is handled separately.
6109
6110             elsif Ada_Version >= Ada_2005
6111               and then not Address_Kludge
6112             then
6113                while Present (It.Nam) loop
6114                   if Is_Numeric_Type (It.Typ)
6115                     and then Scope (It.Typ) = Standard_Standard
6116                   then
6117                      Set_Abstract_Op (I, Abstract_Op);
6118                   end if;
6119
6120                   Get_Next_Interp (I, It);
6121                end loop;
6122             end if;
6123          end if;
6124       end if;
6125    end Remove_Abstract_Operations;
6126
6127    -----------------------
6128    -- Try_Indirect_Call --
6129    -----------------------
6130
6131    function Try_Indirect_Call
6132      (N   : Node_Id;
6133       Nam : Entity_Id;
6134       Typ : Entity_Id) return Boolean
6135    is
6136       Actual : Node_Id;
6137       Formal : Entity_Id;
6138
6139       Call_OK : Boolean;
6140       pragma Warnings (Off, Call_OK);
6141
6142    begin
6143       Normalize_Actuals (N, Designated_Type (Typ), False, Call_OK);
6144
6145       Actual := First_Actual (N);
6146       Formal := First_Formal (Designated_Type (Typ));
6147       while Present (Actual) and then Present (Formal) loop
6148          if not Has_Compatible_Type (Actual, Etype (Formal)) then
6149             return False;
6150          end if;
6151
6152          Next (Actual);
6153          Next_Formal (Formal);
6154       end loop;
6155
6156       if No (Actual) and then No (Formal) then
6157          Add_One_Interp (N, Nam, Etype (Designated_Type (Typ)));
6158
6159          --  Nam is a candidate interpretation for the name in the call,
6160          --  if it is not an indirect call.
6161
6162          if not Is_Type (Nam)
6163             and then Is_Entity_Name (Name (N))
6164          then
6165             Set_Entity (Name (N), Nam);
6166          end if;
6167
6168          return True;
6169       else
6170          return False;
6171       end if;
6172    end Try_Indirect_Call;
6173
6174    ----------------------
6175    -- Try_Indexed_Call --
6176    ----------------------
6177
6178    function Try_Indexed_Call
6179      (N          : Node_Id;
6180       Nam        : Entity_Id;
6181       Typ        : Entity_Id;
6182       Skip_First : Boolean) return Boolean
6183    is
6184       Loc     : constant Source_Ptr := Sloc (N);
6185       Actuals : constant List_Id    := Parameter_Associations (N);
6186       Actual  : Node_Id;
6187       Index   : Entity_Id;
6188
6189    begin
6190       Actual := First (Actuals);
6191
6192       --  If the call was originally written in prefix form, skip the first
6193       --  actual, which is obviously not defaulted.
6194
6195       if Skip_First then
6196          Next (Actual);
6197       end if;
6198
6199       Index := First_Index (Typ);
6200       while Present (Actual) and then Present (Index) loop
6201
6202          --  If the parameter list has a named association, the expression
6203          --  is definitely a call and not an indexed component.
6204
6205          if Nkind (Actual) = N_Parameter_Association then
6206             return False;
6207          end if;
6208
6209          if Is_Entity_Name (Actual)
6210            and then Is_Type (Entity (Actual))
6211            and then No (Next (Actual))
6212          then
6213             --  A single actual that is a type name indicates a slice if the
6214             --  type is discrete, and an error otherwise.
6215
6216             if Is_Discrete_Type (Entity (Actual)) then
6217                Rewrite (N,
6218                  Make_Slice (Loc,
6219                    Prefix =>
6220                      Make_Function_Call (Loc,
6221                        Name => Relocate_Node (Name (N))),
6222                    Discrete_Range =>
6223                      New_Occurrence_Of (Entity (Actual), Sloc (Actual))));
6224
6225                Analyze (N);
6226
6227             else
6228                Error_Msg_N ("invalid use of type in expression", Actual);
6229                Set_Etype (N, Any_Type);
6230             end if;
6231
6232             return True;
6233
6234          elsif not Has_Compatible_Type (Actual, Etype (Index)) then
6235             return False;
6236          end if;
6237
6238          Next (Actual);
6239          Next_Index (Index);
6240       end loop;
6241
6242       if No (Actual) and then No (Index) then
6243          Add_One_Interp (N, Nam, Component_Type (Typ));
6244
6245          --  Nam is a candidate interpretation for the name in the call,
6246          --  if it is not an indirect call.
6247
6248          if not Is_Type (Nam)
6249             and then Is_Entity_Name (Name (N))
6250          then
6251             Set_Entity (Name (N), Nam);
6252          end if;
6253
6254          return True;
6255       else
6256          return False;
6257       end if;
6258    end Try_Indexed_Call;
6259
6260    --------------------------
6261    -- Try_Object_Operation --
6262    --------------------------
6263
6264    function Try_Object_Operation (N : Node_Id) return Boolean is
6265       K              : constant Node_Kind  := Nkind (Parent (N));
6266       Is_Subprg_Call : constant Boolean    := Nkind_In
6267                                                (K, N_Procedure_Call_Statement,
6268                                                    N_Function_Call);
6269       Loc            : constant Source_Ptr := Sloc (N);
6270       Obj            : constant Node_Id    := Prefix (N);
6271
6272       Subprog : constant Node_Id    :=
6273                   Make_Identifier (Sloc (Selector_Name (N)),
6274                     Chars => Chars (Selector_Name (N)));
6275       --  Identifier on which possible interpretations will be collected
6276
6277       Report_Error : Boolean := False;
6278       --  If no candidate interpretation matches the context, redo the
6279       --  analysis with error enabled to provide additional information.
6280
6281       Actual          : Node_Id;
6282       Candidate       : Entity_Id := Empty;
6283       New_Call_Node   : Node_Id := Empty;
6284       Node_To_Replace : Node_Id;
6285       Obj_Type        : Entity_Id := Etype (Obj);
6286       Success         : Boolean := False;
6287
6288       function Valid_Candidate
6289         (Success : Boolean;
6290          Call    : Node_Id;
6291          Subp    : Entity_Id) return Entity_Id;
6292       --  If the subprogram is a valid interpretation, record it, and add
6293       --  to the list of interpretations of Subprog.
6294
6295       procedure Complete_Object_Operation
6296         (Call_Node       : Node_Id;
6297          Node_To_Replace : Node_Id);
6298       --  Make Subprog the name of Call_Node, replace Node_To_Replace with
6299       --  Call_Node, insert the object (or its dereference) as the first actual
6300       --  in the call, and complete the analysis of the call.
6301
6302       procedure Report_Ambiguity (Op : Entity_Id);
6303       --  If a prefixed procedure call is ambiguous, indicate whether the
6304       --  call includes an implicit dereference or an implicit 'Access.
6305
6306       procedure Transform_Object_Operation
6307         (Call_Node       : out Node_Id;
6308          Node_To_Replace : out Node_Id);
6309       --  Transform Obj.Operation (X, Y,,) into Operation (Obj, X, Y ..)
6310       --  Call_Node is the resulting subprogram call, Node_To_Replace is
6311       --  either N or the parent of N, and Subprog is a reference to the
6312       --  subprogram we are trying to match.
6313
6314       function Try_Class_Wide_Operation
6315         (Call_Node       : Node_Id;
6316          Node_To_Replace : Node_Id) return Boolean;
6317       --  Traverse all ancestor types looking for a class-wide subprogram
6318       --  for which the current operation is a valid non-dispatching call.
6319
6320       procedure Try_One_Prefix_Interpretation (T : Entity_Id);
6321       --  If prefix is overloaded, its interpretation may include different
6322       --  tagged types, and we must examine the primitive operations and
6323       --  the class-wide operations of each in order to find candidate
6324       --  interpretations for the call as a whole.
6325
6326       function Try_Primitive_Operation
6327         (Call_Node       : Node_Id;
6328          Node_To_Replace : Node_Id) return Boolean;
6329       --  Traverse the list of primitive subprograms looking for a dispatching
6330       --  operation for which the current node is a valid call .
6331
6332       ---------------------
6333       -- Valid_Candidate --
6334       ---------------------
6335
6336       function Valid_Candidate
6337         (Success : Boolean;
6338          Call    : Node_Id;
6339          Subp    : Entity_Id) return Entity_Id
6340       is
6341          Arr_Type  : Entity_Id;
6342          Comp_Type : Entity_Id;
6343
6344       begin
6345          --  If the subprogram is a valid interpretation, record it in global
6346          --  variable Subprog, to collect all possible overloadings.
6347
6348          if Success then
6349             if Subp /= Entity (Subprog) then
6350                Add_One_Interp (Subprog, Subp, Etype (Subp));
6351             end if;
6352          end if;
6353
6354          --  If the call may be an indexed call, retrieve component type of
6355          --  resulting expression, and add possible interpretation.
6356
6357          Arr_Type  := Empty;
6358          Comp_Type := Empty;
6359
6360          if Nkind (Call) = N_Function_Call
6361            and then Nkind (Parent (N)) = N_Indexed_Component
6362            and then Needs_One_Actual (Subp)
6363          then
6364             if Is_Array_Type (Etype (Subp)) then
6365                Arr_Type := Etype (Subp);
6366
6367             elsif Is_Access_Type (Etype (Subp))
6368               and then Is_Array_Type (Designated_Type (Etype (Subp)))
6369             then
6370                Arr_Type := Designated_Type (Etype (Subp));
6371             end if;
6372          end if;
6373
6374          if Present (Arr_Type) then
6375
6376             --  Verify that the actuals (excluding the object)
6377             --  match the types of the indices.
6378
6379             declare
6380                Actual : Node_Id;
6381                Index  : Node_Id;
6382
6383             begin
6384                Actual := Next (First_Actual (Call));
6385                Index  := First_Index (Arr_Type);
6386                while Present (Actual) and then Present (Index) loop
6387                   if not Has_Compatible_Type (Actual, Etype (Index)) then
6388                      Arr_Type := Empty;
6389                      exit;
6390                   end if;
6391
6392                   Next_Actual (Actual);
6393                   Next_Index  (Index);
6394                end loop;
6395
6396                if No (Actual)
6397                   and then No (Index)
6398                   and then Present (Arr_Type)
6399                then
6400                   Comp_Type := Component_Type (Arr_Type);
6401                end if;
6402             end;
6403
6404             if Present (Comp_Type)
6405               and then Etype (Subprog) /= Comp_Type
6406             then
6407                Add_One_Interp (Subprog, Subp, Comp_Type);
6408             end if;
6409          end if;
6410
6411          if Etype (Call) /= Any_Type then
6412             return Subp;
6413          else
6414             return Empty;
6415          end if;
6416       end Valid_Candidate;
6417
6418       -------------------------------
6419       -- Complete_Object_Operation --
6420       -------------------------------
6421
6422       procedure Complete_Object_Operation
6423         (Call_Node       : Node_Id;
6424          Node_To_Replace : Node_Id)
6425       is
6426          Control      : constant Entity_Id := First_Formal (Entity (Subprog));
6427          Formal_Type  : constant Entity_Id := Etype (Control);
6428          First_Actual : Node_Id;
6429
6430       begin
6431          --  Place the name of the operation, with its interpretations,
6432          --  on the rewritten call.
6433
6434          Set_Name (Call_Node, Subprog);
6435
6436          First_Actual := First (Parameter_Associations (Call_Node));
6437
6438          --  For cross-reference purposes, treat the new node as being in
6439          --  the source if the original one is.
6440
6441          Set_Comes_From_Source (Subprog, Comes_From_Source (N));
6442          Set_Comes_From_Source (Call_Node, Comes_From_Source (N));
6443
6444          if Nkind (N) = N_Selected_Component
6445            and then not Inside_A_Generic
6446          then
6447             Set_Entity (Selector_Name (N), Entity (Subprog));
6448          end if;
6449
6450          --  If need be, rewrite first actual as an explicit dereference
6451          --  If the call is overloaded, the rewriting can only be done
6452          --  once the primitive operation is identified.
6453
6454          if Is_Overloaded (Subprog) then
6455
6456             --  The prefix itself may be overloaded, and its interpretations
6457             --  must be propagated to the new actual in the call.
6458
6459             if Is_Overloaded (Obj) then
6460                Save_Interps (Obj, First_Actual);
6461             end if;
6462
6463             Rewrite (First_Actual, Obj);
6464
6465          elsif not Is_Access_Type (Formal_Type)
6466            and then Is_Access_Type (Etype (Obj))
6467          then
6468             Rewrite (First_Actual,
6469               Make_Explicit_Dereference (Sloc (Obj), Obj));
6470             Analyze (First_Actual);
6471
6472             --  If we need to introduce an explicit dereference, verify that
6473             --  the resulting actual is compatible with the mode of the formal.
6474
6475             if Ekind (First_Formal (Entity (Subprog))) /= E_In_Parameter
6476               and then Is_Access_Constant (Etype (Obj))
6477             then
6478                Error_Msg_NE
6479                  ("expect variable in call to&", Prefix (N), Entity (Subprog));
6480             end if;
6481
6482          --  Conversely, if the formal is an access parameter and the object
6483          --  is not, replace the actual with a 'Access reference. Its analysis
6484          --  will check that the object is aliased.
6485
6486          elsif Is_Access_Type (Formal_Type)
6487            and then not Is_Access_Type (Etype (Obj))
6488          then
6489             --  A special case: A.all'access is illegal if A is an access to a
6490             --  constant and the context requires an access to a variable.
6491
6492             if not Is_Access_Constant (Formal_Type) then
6493                if (Nkind (Obj) = N_Explicit_Dereference
6494                     and then Is_Access_Constant (Etype (Prefix (Obj))))
6495                  or else not Is_Variable (Obj)
6496                then
6497                   Error_Msg_NE
6498                     ("actual for& must be a variable", Obj, Control);
6499                end if;
6500             end if;
6501
6502             Rewrite (First_Actual,
6503               Make_Attribute_Reference (Loc,
6504                 Attribute_Name => Name_Access,
6505                 Prefix => Relocate_Node (Obj)));
6506
6507             if not Is_Aliased_View (Obj) then
6508                Error_Msg_NE
6509                  ("object in prefixed call to& must be aliased"
6510                       & " (RM-2005 4.3.1 (13))",
6511                  Prefix (First_Actual), Subprog);
6512             end if;
6513
6514             Analyze (First_Actual);
6515
6516          else
6517             if Is_Overloaded (Obj) then
6518                Save_Interps (Obj, First_Actual);
6519             end if;
6520
6521             Rewrite (First_Actual, Obj);
6522          end if;
6523
6524          Rewrite (Node_To_Replace, Call_Node);
6525
6526          --  Propagate the interpretations collected in subprog to the new
6527          --  function call node, to be resolved from context.
6528
6529          if Is_Overloaded (Subprog) then
6530             Save_Interps (Subprog, Node_To_Replace);
6531
6532          else
6533             Analyze (Node_To_Replace);
6534
6535             --  If the operation has been rewritten into a call, which may get
6536             --  subsequently an explicit dereference, preserve the type on the
6537             --  original node (selected component or indexed component) for
6538             --  subsequent legality tests, e.g. Is_Variable. which examines
6539             --  the original node.
6540
6541             if Nkind (Node_To_Replace) = N_Function_Call then
6542                Set_Etype
6543                  (Original_Node (Node_To_Replace), Etype (Node_To_Replace));
6544             end if;
6545          end if;
6546       end Complete_Object_Operation;
6547
6548       ----------------------
6549       -- Report_Ambiguity --
6550       ----------------------
6551
6552       procedure Report_Ambiguity (Op : Entity_Id) is
6553          Access_Formal : constant Boolean :=
6554                            Is_Access_Type (Etype (First_Formal (Op)));
6555          Access_Actual : constant Boolean :=
6556                            Is_Access_Type (Etype (Prefix (N)));
6557
6558       begin
6559          Error_Msg_Sloc := Sloc (Op);
6560
6561          if Access_Formal and then not Access_Actual then
6562             if Nkind (Parent (Op)) = N_Full_Type_Declaration then
6563                Error_Msg_N
6564                  ("\possible interpretation"
6565                    & " (inherited, with implicit 'Access) #", N);
6566             else
6567                Error_Msg_N
6568                  ("\possible interpretation (with implicit 'Access) #", N);
6569             end if;
6570
6571          elsif not Access_Formal and then Access_Actual then
6572             if Nkind (Parent (Op)) = N_Full_Type_Declaration then
6573                Error_Msg_N
6574                  ("\possible interpretation"
6575                    & " ( inherited, with implicit dereference) #", N);
6576             else
6577                Error_Msg_N
6578                  ("\possible interpretation (with implicit dereference) #", N);
6579             end if;
6580
6581          else
6582             if Nkind (Parent (Op)) = N_Full_Type_Declaration then
6583                Error_Msg_N ("\possible interpretation (inherited)#", N);
6584             else
6585                Error_Msg_N -- CODEFIX
6586                  ("\possible interpretation#", N);
6587             end if;
6588          end if;
6589       end Report_Ambiguity;
6590
6591       --------------------------------
6592       -- Transform_Object_Operation --
6593       --------------------------------
6594
6595       procedure Transform_Object_Operation
6596         (Call_Node       : out Node_Id;
6597          Node_To_Replace : out Node_Id)
6598       is
6599          Dummy : constant Node_Id := New_Copy (Obj);
6600          --  Placeholder used as a first parameter in the call, replaced
6601          --  eventually by the proper object.
6602
6603          Parent_Node : constant Node_Id := Parent (N);
6604
6605          Actual  : Node_Id;
6606          Actuals : List_Id;
6607
6608       begin
6609          --  Common case covering 1) Call to a procedure and 2) Call to a
6610          --  function that has some additional actuals.
6611
6612          if Nkind_In (Parent_Node, N_Function_Call,
6613                                    N_Procedure_Call_Statement)
6614
6615             --  N is a selected component node containing the name of the
6616             --  subprogram. If N is not the name of the parent node we must
6617             --  not replace the parent node by the new construct. This case
6618             --  occurs when N is a parameterless call to a subprogram that
6619             --  is an actual parameter of a call to another subprogram. For
6620             --  example:
6621             --            Some_Subprogram (..., Obj.Operation, ...)
6622
6623             and then Name (Parent_Node) = N
6624          then
6625             Node_To_Replace := Parent_Node;
6626
6627             Actuals := Parameter_Associations (Parent_Node);
6628
6629             if Present (Actuals) then
6630                Prepend (Dummy, Actuals);
6631             else
6632                Actuals := New_List (Dummy);
6633             end if;
6634
6635             if Nkind (Parent_Node) = N_Procedure_Call_Statement then
6636                Call_Node :=
6637                  Make_Procedure_Call_Statement (Loc,
6638                    Name => New_Copy (Subprog),
6639                    Parameter_Associations => Actuals);
6640
6641             else
6642                Call_Node :=
6643                  Make_Function_Call (Loc,
6644                    Name => New_Copy (Subprog),
6645                    Parameter_Associations => Actuals);
6646
6647             end if;
6648
6649          --  Before analysis, a function call appears as an indexed component
6650          --  if there are no named associations.
6651
6652          elsif Nkind (Parent_Node) =  N_Indexed_Component
6653            and then N = Prefix (Parent_Node)
6654          then
6655             Node_To_Replace := Parent_Node;
6656             Actuals := Expressions (Parent_Node);
6657
6658             Actual := First (Actuals);
6659             while Present (Actual) loop
6660                Analyze (Actual);
6661                Next (Actual);
6662             end loop;
6663
6664             Prepend (Dummy, Actuals);
6665
6666             Call_Node :=
6667                Make_Function_Call (Loc,
6668                  Name => New_Copy (Subprog),
6669                  Parameter_Associations => Actuals);
6670
6671          --  Parameterless call: Obj.F is rewritten as F (Obj)
6672
6673          else
6674             Node_To_Replace := N;
6675
6676             Call_Node :=
6677                Make_Function_Call (Loc,
6678                  Name => New_Copy (Subprog),
6679                  Parameter_Associations => New_List (Dummy));
6680          end if;
6681       end Transform_Object_Operation;
6682
6683       ------------------------------
6684       -- Try_Class_Wide_Operation --
6685       ------------------------------
6686
6687       function Try_Class_Wide_Operation
6688         (Call_Node       : Node_Id;
6689          Node_To_Replace : Node_Id) return Boolean
6690       is
6691          Anc_Type    : Entity_Id;
6692          Matching_Op : Entity_Id := Empty;
6693          Error       : Boolean;
6694
6695          procedure Traverse_Homonyms
6696            (Anc_Type : Entity_Id;
6697             Error    : out Boolean);
6698          --  Traverse the homonym chain of the subprogram searching for those
6699          --  homonyms whose first formal has the Anc_Type's class-wide type,
6700          --  or an anonymous access type designating the class-wide type. If
6701          --  an ambiguity is detected, then Error is set to True.
6702
6703          procedure Traverse_Interfaces
6704            (Anc_Type : Entity_Id;
6705             Error    : out Boolean);
6706          --  Traverse the list of interfaces, if any, associated with Anc_Type
6707          --  and search for acceptable class-wide homonyms associated with each
6708          --  interface. If an ambiguity is detected, then Error is set to True.
6709
6710          -----------------------
6711          -- Traverse_Homonyms --
6712          -----------------------
6713
6714          procedure Traverse_Homonyms
6715            (Anc_Type : Entity_Id;
6716             Error    : out Boolean)
6717          is
6718             Cls_Type    : Entity_Id;
6719             Hom         : Entity_Id;
6720             Hom_Ref     : Node_Id;
6721             Success     : Boolean;
6722
6723          begin
6724             Error := False;
6725
6726             Cls_Type := Class_Wide_Type (Anc_Type);
6727
6728             Hom := Current_Entity (Subprog);
6729
6730             --  Find operation whose first parameter is of the class-wide
6731             --  type, a subtype thereof, or an anonymous access to same.
6732
6733             while Present (Hom) loop
6734                if (Ekind (Hom) = E_Procedure
6735                      or else
6736                    Ekind (Hom) = E_Function)
6737                  and then Scope (Hom) = Scope (Anc_Type)
6738                  and then Present (First_Formal (Hom))
6739                  and then
6740                    (Base_Type (Etype (First_Formal (Hom))) = Cls_Type
6741                      or else
6742                        (Is_Access_Type (Etype (First_Formal (Hom)))
6743                           and then
6744                             Ekind (Etype (First_Formal (Hom))) =
6745                               E_Anonymous_Access_Type
6746                           and then
6747                             Base_Type
6748                               (Designated_Type (Etype (First_Formal (Hom)))) =
6749                                                                    Cls_Type))
6750                then
6751                   Set_Etype (Call_Node, Any_Type);
6752                   Set_Is_Overloaded (Call_Node, False);
6753                   Success := False;
6754
6755                   if No (Matching_Op) then
6756                      Hom_Ref := New_Reference_To (Hom, Sloc (Subprog));
6757                      Set_Etype (Call_Node, Any_Type);
6758                      Set_Parent (Call_Node, Parent (Node_To_Replace));
6759
6760                      Set_Name (Call_Node, Hom_Ref);
6761
6762                      Analyze_One_Call
6763                        (N          => Call_Node,
6764                         Nam        => Hom,
6765                         Report     => Report_Error,
6766                         Success    => Success,
6767                         Skip_First => True);
6768
6769                      Matching_Op :=
6770                        Valid_Candidate (Success, Call_Node, Hom);
6771
6772                   else
6773                      Analyze_One_Call
6774                        (N          => Call_Node,
6775                         Nam        => Hom,
6776                         Report     => Report_Error,
6777                         Success    => Success,
6778                         Skip_First => True);
6779
6780                      if Present (Valid_Candidate (Success, Call_Node, Hom))
6781                        and then Nkind (Call_Node) /= N_Function_Call
6782                      then
6783                         Error_Msg_NE ("ambiguous call to&", N, Hom);
6784                         Report_Ambiguity (Matching_Op);
6785                         Report_Ambiguity (Hom);
6786                         Error := True;
6787                         return;
6788                      end if;
6789                   end if;
6790                end if;
6791
6792                Hom := Homonym (Hom);
6793             end loop;
6794          end Traverse_Homonyms;
6795
6796          -------------------------
6797          -- Traverse_Interfaces --
6798          -------------------------
6799
6800          procedure Traverse_Interfaces
6801            (Anc_Type : Entity_Id;
6802             Error    : out Boolean)
6803          is
6804             Intface_List : constant List_Id :=
6805                              Abstract_Interface_List (Anc_Type);
6806             Intface      : Node_Id;
6807
6808          begin
6809             Error := False;
6810
6811             if Is_Non_Empty_List (Intface_List) then
6812                Intface := First (Intface_List);
6813                while Present (Intface) loop
6814
6815                   --  Look for acceptable class-wide homonyms associated with
6816                   --  the interface.
6817
6818                   Traverse_Homonyms (Etype (Intface), Error);
6819
6820                   if Error then
6821                      return;
6822                   end if;
6823
6824                   --  Continue the search by looking at each of the interface's
6825                   --  associated interface ancestors.
6826
6827                   Traverse_Interfaces (Etype (Intface), Error);
6828
6829                   if Error then
6830                      return;
6831                   end if;
6832
6833                   Next (Intface);
6834                end loop;
6835             end if;
6836          end Traverse_Interfaces;
6837
6838       --  Start of processing for Try_Class_Wide_Operation
6839
6840       begin
6841          --  Loop through ancestor types (including interfaces), traversing
6842          --  the homonym chain of the subprogram, trying out those homonyms
6843          --  whose first formal has the class-wide type of the ancestor, or
6844          --  an anonymous access type designating the class-wide type.
6845
6846          Anc_Type := Obj_Type;
6847          loop
6848             --  Look for a match among homonyms associated with the ancestor
6849
6850             Traverse_Homonyms (Anc_Type, Error);
6851
6852             if Error then
6853                return True;
6854             end if;
6855
6856             --  Continue the search for matches among homonyms associated with
6857             --  any interfaces implemented by the ancestor.
6858
6859             Traverse_Interfaces (Anc_Type, Error);
6860
6861             if Error then
6862                return True;
6863             end if;
6864
6865             exit when Etype (Anc_Type) = Anc_Type;
6866             Anc_Type := Etype (Anc_Type);
6867          end loop;
6868
6869          if Present (Matching_Op) then
6870             Set_Etype (Call_Node, Etype (Matching_Op));
6871          end if;
6872
6873          return Present (Matching_Op);
6874       end Try_Class_Wide_Operation;
6875
6876       -----------------------------------
6877       -- Try_One_Prefix_Interpretation --
6878       -----------------------------------
6879
6880       procedure Try_One_Prefix_Interpretation (T : Entity_Id) is
6881       begin
6882          Obj_Type := T;
6883
6884          if Is_Access_Type (Obj_Type) then
6885             Obj_Type := Designated_Type (Obj_Type);
6886          end if;
6887
6888          if Ekind (Obj_Type) = E_Private_Subtype then
6889             Obj_Type := Base_Type (Obj_Type);
6890          end if;
6891
6892          if Is_Class_Wide_Type (Obj_Type) then
6893             Obj_Type := Etype (Class_Wide_Type (Obj_Type));
6894          end if;
6895
6896          --  The type may have be obtained through a limited_with clause,
6897          --  in which case the primitive operations are available on its
6898          --  non-limited view. If still incomplete, retrieve full view.
6899
6900          if Ekind (Obj_Type) = E_Incomplete_Type
6901            and then From_With_Type (Obj_Type)
6902          then
6903             Obj_Type := Get_Full_View (Non_Limited_View (Obj_Type));
6904          end if;
6905
6906          --  If the object is not tagged, or the type is still an incomplete
6907          --  type, this is not a prefixed call.
6908
6909          if not Is_Tagged_Type (Obj_Type)
6910            or else Is_Incomplete_Type (Obj_Type)
6911          then
6912             return;
6913          end if;
6914
6915          if Try_Primitive_Operation
6916               (Call_Node       => New_Call_Node,
6917                Node_To_Replace => Node_To_Replace)
6918            or else
6919              Try_Class_Wide_Operation
6920                (Call_Node       => New_Call_Node,
6921                 Node_To_Replace => Node_To_Replace)
6922          then
6923             null;
6924          end if;
6925       end Try_One_Prefix_Interpretation;
6926
6927       -----------------------------
6928       -- Try_Primitive_Operation --
6929       -----------------------------
6930
6931       function Try_Primitive_Operation
6932         (Call_Node       : Node_Id;
6933          Node_To_Replace : Node_Id) return Boolean
6934       is
6935          Elmt        : Elmt_Id;
6936          Prim_Op     : Entity_Id;
6937          Matching_Op : Entity_Id := Empty;
6938          Prim_Op_Ref : Node_Id   := Empty;
6939
6940          Corr_Type   : Entity_Id := Empty;
6941          --  If the prefix is a synchronized type, the controlling type of
6942          --  the primitive operation is the corresponding record type, else
6943          --  this is the object type itself.
6944
6945          Success     : Boolean   := False;
6946
6947          function Collect_Generic_Type_Ops (T : Entity_Id) return Elist_Id;
6948          --  For tagged types the candidate interpretations are found in
6949          --  the list of primitive operations of the type and its ancestors.
6950          --  For formal tagged types we have to find the operations declared
6951          --  in the same scope as the type (including in the generic formal
6952          --  part) because the type itself carries no primitive operations,
6953          --  except for formal derived types that inherit the operations of
6954          --  the parent and progenitors.
6955          --  If the context is a generic subprogram body, the generic formals
6956          --  are visible by name, but are not in the entity list of the
6957          --  subprogram because that list starts with the subprogram formals.
6958          --  We retrieve the candidate operations from the generic declaration.
6959
6960          function Is_Private_Overriding (Op : Entity_Id) return Boolean;
6961          --  An operation that overrides an inherited operation in the private
6962          --  part of its package may be hidden, but if the inherited operation
6963          --  is visible a direct call to it will dispatch to the private one,
6964          --  which is therefore a valid candidate.
6965
6966          function Valid_First_Argument_Of (Op : Entity_Id) return Boolean;
6967          --  Verify that the prefix, dereferenced if need be, is a valid
6968          --  controlling argument in a call to Op. The remaining actuals
6969          --  are checked in the subsequent call to Analyze_One_Call.
6970
6971          ------------------------------
6972          -- Collect_Generic_Type_Ops --
6973          ------------------------------
6974
6975          function Collect_Generic_Type_Ops (T : Entity_Id) return Elist_Id is
6976             Bas        : constant Entity_Id := Base_Type (T);
6977             Candidates : constant Elist_Id := New_Elmt_List;
6978             Subp       : Entity_Id;
6979             Formal     : Entity_Id;
6980
6981             procedure Check_Candidate;
6982             --  The operation is a candidate if its first parameter is a
6983             --  controlling operand of the desired type.
6984
6985             -----------------------
6986             --  Check_Candidate; --
6987             -----------------------
6988
6989             procedure Check_Candidate is
6990             begin
6991                Formal := First_Formal (Subp);
6992
6993                if Present (Formal)
6994                  and then Is_Controlling_Formal (Formal)
6995                  and then
6996                    (Base_Type (Etype (Formal)) = Bas
6997                      or else
6998                        (Is_Access_Type (Etype (Formal))
6999                          and then Designated_Type (Etype (Formal)) = Bas))
7000                then
7001                   Append_Elmt (Subp, Candidates);
7002                end if;
7003             end Check_Candidate;
7004
7005          --  Start of processing for Collect_Generic_Type_Ops
7006
7007          begin
7008             if Is_Derived_Type (T) then
7009                return Primitive_Operations (T);
7010
7011             elsif Ekind_In (Scope (T), E_Procedure, E_Function) then
7012
7013                --  Scan the list of generic formals to find subprograms
7014                --  that may have a first controlling formal of the type.
7015
7016                if Nkind (Unit_Declaration_Node (Scope (T)))
7017                  = N_Generic_Subprogram_Declaration
7018                then
7019                   declare
7020                      Decl : Node_Id;
7021
7022                   begin
7023                      Decl :=
7024                        First (Generic_Formal_Declarations
7025                                (Unit_Declaration_Node (Scope (T))));
7026                      while Present (Decl) loop
7027                         if Nkind (Decl) in N_Formal_Subprogram_Declaration then
7028                            Subp := Defining_Entity (Decl);
7029                            Check_Candidate;
7030                         end if;
7031
7032                         Next (Decl);
7033                      end loop;
7034                   end;
7035                end if;
7036                return Candidates;
7037
7038             else
7039                --  Scan the list of entities declared in the same scope as
7040                --  the type. In general this will be an open scope, given that
7041                --  the call we are analyzing can only appear within a generic
7042                --  declaration or body (either the one that declares T, or a
7043                --  child unit).
7044
7045                --  For a subtype representing a generic actual type, go to the
7046                --  base type.
7047
7048                if Is_Generic_Actual_Type (T) then
7049                   Subp := First_Entity (Scope (Base_Type (T)));
7050                else
7051                   Subp := First_Entity (Scope (T));
7052                end if;
7053
7054                while Present (Subp) loop
7055                   if Is_Overloadable (Subp) then
7056                      Check_Candidate;
7057                   end if;
7058
7059                   Next_Entity (Subp);
7060                end loop;
7061
7062                return Candidates;
7063             end if;
7064          end Collect_Generic_Type_Ops;
7065
7066          ---------------------------
7067          -- Is_Private_Overriding --
7068          ---------------------------
7069
7070          function Is_Private_Overriding (Op : Entity_Id) return Boolean is
7071             Visible_Op : constant Entity_Id := Homonym (Op);
7072
7073          begin
7074             return Present (Visible_Op)
7075               and then Scope (Op) = Scope (Visible_Op)
7076               and then not Comes_From_Source (Visible_Op)
7077               and then Alias (Visible_Op) = Op
7078               and then not Is_Hidden (Visible_Op);
7079          end Is_Private_Overriding;
7080
7081          -----------------------------
7082          -- Valid_First_Argument_Of --
7083          -----------------------------
7084
7085          function Valid_First_Argument_Of (Op : Entity_Id) return Boolean is
7086             Typ : Entity_Id := Etype (First_Formal (Op));
7087
7088          begin
7089             if Is_Concurrent_Type (Typ)
7090               and then Present (Corresponding_Record_Type (Typ))
7091             then
7092                Typ := Corresponding_Record_Type (Typ);
7093             end if;
7094
7095             --  Simple case. Object may be a subtype of the tagged type or
7096             --  may be the corresponding record of a synchronized type.
7097
7098             return Obj_Type = Typ
7099               or else Base_Type (Obj_Type) = Typ
7100               or else Corr_Type = Typ
7101
7102                --  Prefix can be dereferenced
7103
7104               or else
7105                 (Is_Access_Type (Corr_Type)
7106                   and then Designated_Type (Corr_Type) = Typ)
7107
7108                --  Formal is an access parameter, for which the object
7109                --  can provide an access.
7110
7111               or else
7112                 (Ekind (Typ) = E_Anonymous_Access_Type
7113                   and then Designated_Type (Typ) = Base_Type (Corr_Type));
7114          end Valid_First_Argument_Of;
7115
7116       --  Start of processing for Try_Primitive_Operation
7117
7118       begin
7119          --  Look for subprograms in the list of primitive operations. The name
7120          --  must be identical, and the kind of call indicates the expected
7121          --  kind of operation (function or procedure). If the type is a
7122          --  (tagged) synchronized type, the primitive ops are attached to the
7123          --  corresponding record (base) type.
7124
7125          if Is_Concurrent_Type (Obj_Type) then
7126             if Present (Corresponding_Record_Type (Obj_Type)) then
7127                Corr_Type := Base_Type (Corresponding_Record_Type (Obj_Type));
7128                Elmt := First_Elmt (Primitive_Operations (Corr_Type));
7129             else
7130                Corr_Type := Obj_Type;
7131                Elmt := First_Elmt (Collect_Generic_Type_Ops (Obj_Type));
7132             end if;
7133
7134          elsif not Is_Generic_Type (Obj_Type) then
7135             Corr_Type := Obj_Type;
7136             Elmt := First_Elmt (Primitive_Operations (Obj_Type));
7137
7138          else
7139             Corr_Type := Obj_Type;
7140             Elmt := First_Elmt (Collect_Generic_Type_Ops (Obj_Type));
7141          end if;
7142
7143          while Present (Elmt) loop
7144             Prim_Op := Node (Elmt);
7145
7146             if Chars (Prim_Op) = Chars (Subprog)
7147               and then Present (First_Formal (Prim_Op))
7148               and then Valid_First_Argument_Of (Prim_Op)
7149               and then
7150                 (Nkind (Call_Node) = N_Function_Call)
7151                    = (Ekind (Prim_Op) = E_Function)
7152             then
7153                --  Ada 2005 (AI-251): If this primitive operation corresponds
7154                --  with an immediate ancestor interface there is no need to add
7155                --  it to the list of interpretations; the corresponding aliased
7156                --  primitive is also in this list of primitive operations and
7157                --  will be used instead.
7158
7159                if (Present (Interface_Alias (Prim_Op))
7160                     and then Is_Ancestor (Find_Dispatching_Type
7161                                             (Alias (Prim_Op)), Corr_Type))
7162
7163                  --  Do not consider hidden primitives unless the type is in an
7164                  --  open scope or we are within an instance, where visibility
7165                  --  is known to be correct, or else if this is an overriding
7166                  --  operation in the private part for an inherited operation.
7167
7168                  or else (Is_Hidden (Prim_Op)
7169                            and then not Is_Immediately_Visible (Obj_Type)
7170                            and then not In_Instance
7171                            and then not Is_Private_Overriding (Prim_Op))
7172                then
7173                   goto Continue;
7174                end if;
7175
7176                Set_Etype (Call_Node, Any_Type);
7177                Set_Is_Overloaded (Call_Node, False);
7178
7179                if No (Matching_Op) then
7180                   Prim_Op_Ref := New_Reference_To (Prim_Op, Sloc (Subprog));
7181                   Candidate := Prim_Op;
7182
7183                   Set_Parent (Call_Node, Parent (Node_To_Replace));
7184
7185                   Set_Name (Call_Node, Prim_Op_Ref);
7186                   Success := False;
7187
7188                   Analyze_One_Call
7189                     (N          => Call_Node,
7190                      Nam        => Prim_Op,
7191                      Report     => Report_Error,
7192                      Success    => Success,
7193                      Skip_First => True);
7194
7195                   Matching_Op := Valid_Candidate (Success, Call_Node, Prim_Op);
7196
7197                --  More than one interpretation, collect for subsequent
7198                --  disambiguation. If this is a procedure call and there
7199                --  is another match, report ambiguity now.
7200
7201                else
7202                   Analyze_One_Call
7203                     (N          => Call_Node,
7204                      Nam        => Prim_Op,
7205                      Report     => Report_Error,
7206                      Success    => Success,
7207                      Skip_First => True);
7208
7209                   if Present (Valid_Candidate (Success, Call_Node, Prim_Op))
7210                     and then Nkind (Call_Node) /= N_Function_Call
7211                   then
7212                      Error_Msg_NE ("ambiguous call to&", N, Prim_Op);
7213                      Report_Ambiguity (Matching_Op);
7214                      Report_Ambiguity (Prim_Op);
7215                      return True;
7216                   end if;
7217                end if;
7218             end if;
7219
7220             <<Continue>>
7221             Next_Elmt (Elmt);
7222          end loop;
7223
7224          if Present (Matching_Op) then
7225             Set_Etype (Call_Node, Etype (Matching_Op));
7226          end if;
7227
7228          return Present (Matching_Op);
7229       end Try_Primitive_Operation;
7230
7231    --  Start of processing for Try_Object_Operation
7232
7233    begin
7234       Analyze_Expression (Obj);
7235
7236       --  Analyze the actuals if node is known to be a subprogram call
7237
7238       if Is_Subprg_Call and then N = Name (Parent (N)) then
7239          Actual := First (Parameter_Associations (Parent (N)));
7240          while Present (Actual) loop
7241             Analyze_Expression (Actual);
7242             Next (Actual);
7243          end loop;
7244       end if;
7245
7246       --  Build a subprogram call node, using a copy of Obj as its first
7247       --  actual. This is a placeholder, to be replaced by an explicit
7248       --  dereference when needed.
7249
7250       Transform_Object_Operation
7251         (Call_Node       => New_Call_Node,
7252          Node_To_Replace => Node_To_Replace);
7253
7254       Set_Etype (New_Call_Node, Any_Type);
7255       Set_Etype (Subprog, Any_Type);
7256       Set_Parent (New_Call_Node, Parent (Node_To_Replace));
7257
7258       if not Is_Overloaded (Obj) then
7259          Try_One_Prefix_Interpretation (Obj_Type);
7260
7261       else
7262          declare
7263             I  : Interp_Index;
7264             It : Interp;
7265          begin
7266             Get_First_Interp (Obj, I, It);
7267             while Present (It.Nam) loop
7268                Try_One_Prefix_Interpretation (It.Typ);
7269                Get_Next_Interp (I, It);
7270             end loop;
7271          end;
7272       end if;
7273
7274       if Etype (New_Call_Node) /= Any_Type then
7275          Complete_Object_Operation
7276            (Call_Node       => New_Call_Node,
7277             Node_To_Replace => Node_To_Replace);
7278          return True;
7279
7280       elsif Present (Candidate) then
7281
7282          --  The argument list is not type correct. Re-analyze with error
7283          --  reporting enabled, and use one of the possible candidates.
7284          --  In All_Errors_Mode, re-analyze all failed interpretations.
7285
7286          if All_Errors_Mode then
7287             Report_Error := True;
7288             if Try_Primitive_Operation
7289                 (Call_Node       => New_Call_Node,
7290                  Node_To_Replace => Node_To_Replace)
7291
7292               or else
7293                 Try_Class_Wide_Operation
7294                   (Call_Node       => New_Call_Node,
7295                    Node_To_Replace => Node_To_Replace)
7296             then
7297                null;
7298             end if;
7299
7300          else
7301             Analyze_One_Call
7302               (N          => New_Call_Node,
7303                Nam        => Candidate,
7304                Report     => True,
7305                Success    => Success,
7306                Skip_First => True);
7307          end if;
7308
7309          --  No need for further errors
7310
7311          return True;
7312
7313       else
7314          --  There was no candidate operation, so report it as an error
7315          --  in the caller: Analyze_Selected_Component.
7316
7317          return False;
7318       end if;
7319    end Try_Object_Operation;
7320
7321    ---------
7322    -- wpo --
7323    ---------
7324
7325    procedure wpo (T : Entity_Id) is
7326       Op : Entity_Id;
7327       E  : Elmt_Id;
7328
7329    begin
7330       if not Is_Tagged_Type (T) then
7331          return;
7332       end if;
7333
7334       E := First_Elmt (Primitive_Operations (Base_Type (T)));
7335       while Present (E) loop
7336          Op := Node (E);
7337          Write_Int (Int (Op));
7338          Write_Str (" === ");
7339          Write_Name (Chars (Op));
7340          Write_Str (" in ");
7341          Write_Name (Chars (Scope (Op)));
7342          Next_Elmt (E);
7343          Write_Eol;
7344       end loop;
7345    end wpo;
7346
7347 end Sem_Ch4;