gcc/ada/sem_ch11.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ C H 1 1                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Checks;   use Checks;
  29 with Einfo;    use Einfo;
  30 with Errout;   use Errout;
  31 with Lib;      use Lib;
  32 with Lib.Xref; use Lib.Xref;
  33 with Nlists;   use Nlists;
  34 with Nmake;    use Nmake;
  35 with Opt;      use Opt;
  36 with Restrict; use Restrict;
  37 with Rident;   use Rident;
  38 with Rtsfind;  use Rtsfind;
  39 with Sem;      use Sem;
  40 with Sem_Ch5;  use Sem_Ch5;
  41 with Sem_Ch8;  use Sem_Ch8;
  42 with Sem_Res;  use Sem_Res;
  43 with Sem_Util; use Sem_Util;
  44 with Sinfo;    use Sinfo;
  45 with Stand;    use Stand;
  46 with Uintp;    use Uintp;
  47
  48 package body Sem_Ch11 is
  49
  50    -----------------------------------
  51    -- Analyze_Exception_Declaration --
  52    -----------------------------------
  53
  54    procedure Analyze_Exception_Declaration (N : Node_Id) is
  55       Id : constant Entity_Id := Defining_Identifier (N);
  56       PF : constant Boolean   := Is_Pure (Current_Scope);
  57
  58    begin
  59       Generate_Definition (Id);
  60       Enter_Name          (Id);
  61       Set_Ekind           (Id, E_Exception);
  62       Set_Exception_Code  (Id, Uint_0);
  63       Set_Etype           (Id, Standard_Exception_Type);
  64
  65       Set_Is_Statically_Allocated (Id);
  66       Set_Is_Pure (Id, PF);
  67    end Analyze_Exception_Declaration;
  68
  69    --------------------------------
  70    -- Analyze_Exception_Handlers --
  71    --------------------------------
  72
  73    procedure Analyze_Exception_Handlers (L : List_Id) is
  74       Handler : Node_Id;
  75       Choice  : Entity_Id;
  76       Id      : Node_Id;
  77       H_Scope : Entity_Id := Empty;
  78
  79       procedure Check_Duplication (Id : Node_Id);
  80       --  Iterate through the identifiers in each handler to find duplicates
  81
  82       function Others_Present return Boolean;
  83       --  Returns True if others handler is present
  84
  85       -----------------------
  86       -- Check_Duplication --
  87       -----------------------
  88
  89       procedure Check_Duplication (Id : Node_Id) is
  90          Handler   : Node_Id;
  91          Id1       : Node_Id;
  92          Id_Entity : Entity_Id := Entity (Id);
  93
  94       begin
  95          if Present (Renamed_Entity (Id_Entity)) then
  96             Id_Entity := Renamed_Entity (Id_Entity);
  97          end if;
  98
  99          Handler := First_Non_Pragma (L);
 100          while Present (Handler) loop
 101             Id1 := First (Exception_Choices (Handler));
 102             while Present (Id1) loop
 103
 104                --  Only check against the exception choices which precede
 105                --  Id in the handler, since the ones that follow Id have not
 106                --  been analyzed yet and will be checked in a subsequent call.
 107
 108                if Id = Id1 then
 109                   return;
 110
 111                elsif Nkind (Id1) /= N_Others_Choice
 112                  and then
 113                    (Id_Entity = Entity (Id1)
 114                       or else (Id_Entity = Renamed_Entity (Entity (Id1))))
 115                then
 116                   if Handler /= Parent (Id) then
 117                      Error_Msg_Sloc := Sloc (Id1);
 118                      Error_Msg_NE
 119                        ("exception choice duplicates &#", Id, Id1);
 120
 121                   else
 122                      if Ada_Version = Ada_83
 123                        and then Comes_From_Source (Id)
 124                      then
 125                         Error_Msg_N
 126                           ("(Ada 83): duplicate exception choice&", Id);
 127                      end if;
 128                   end if;
 129                end if;
 130
 131                Next_Non_Pragma (Id1);
 132             end loop;
 133
 134             Next (Handler);
 135          end loop;
 136       end Check_Duplication;
 137
 138       --------------------
 139       -- Others_Present --
 140       --------------------
 141
 142       function Others_Present return Boolean is
 143          H : Node_Id;
 144
 145       begin
 146          H := First (L);
 147          while Present (H) loop
 148             if Nkind (H) /= N_Pragma
 149               and then Nkind (First (Exception_Choices (H))) = N_Others_Choice
 150             then
 151                return True;
 152             end if;
 153
 154             Next (H);
 155          end loop;
 156
 157          return False;
 158       end Others_Present;
 159
 160    --  Start processing for Analyze_Exception_Handlers
 161
 162    begin
 163       Handler := First (L);
 164       Check_Restriction (No_Exceptions, Handler);
 165       Check_Restriction (No_Exception_Handlers, Handler);
 166
 167       --  Kill current remembered values, since we don't know where we were
 168       --  when the exception was raised.
 169
 170       Kill_Current_Values;
 171
 172       --  Loop through handlers (which can include pragmas)
 173
 174       while Present (Handler) loop
 175
 176          --  If pragma just analyze it
 177
 178          if Nkind (Handler) = N_Pragma then
 179             Analyze (Handler);
 180
 181          --  Otherwise we have a real exception handler
 182
 183          else
 184             --  Deal with choice parameter. The exception handler is
 185             --  a declarative part for it, so it constitutes a scope
 186             --  for visibility purposes. We create an entity to denote
 187             --  the whole exception part, and use it as the scope of all
 188             --  the choices, which may even have the same name without
 189             --  conflict. This scope plays no other role in expansion or
 190             --  or code generation.
 191
 192             Choice := Choice_Parameter (Handler);
 193
 194             if Present (Choice) then
 195                if No (H_Scope) then
 196                   H_Scope := New_Internal_Entity
 197                     (E_Block, Current_Scope, Sloc (Choice), 'E');
 198                end if;
 199
 200                New_Scope (H_Scope);
 201                Set_Etype (H_Scope, Standard_Void_Type);
 202
 203                --  Set the Finalization Chain entity to Error means that it
 204                --  should not be used at that level but the parent one
 205                --  should be used instead.
 206
 207                --  ??? this usage needs documenting in Einfo/Exp_Ch7 ???
 208                --  ??? using Error for this non-error condition is nasty ???
 209
 210                Set_Finalization_Chain_Entity (H_Scope, Error);
 211
 212                Enter_Name (Choice);
 213                Set_Ekind (Choice, E_Variable);
 214                Set_Etype (Choice, RTE (RE_Exception_Occurrence));
 215                Generate_Definition (Choice);
 216
 217                --  Set source assigned flag, since in effect this field
 218                --  is always assigned an initial value by the exception.
 219
 220                Set_Never_Set_In_Source (Choice, False);
 221             end if;
 222
 223             Id := First (Exception_Choices (Handler));
 224             while Present (Id) loop
 225                if Nkind (Id) = N_Others_Choice then
 226                   if Present (Next (Id))
 227                     or else Present (Next (Handler))
 228                     or else Present (Prev (Id))
 229                   then
 230                      Error_Msg_N ("OTHERS must appear alone and last", Id);
 231                   end if;
 232
 233                else
 234                   Analyze (Id);
 235
 236                   if not Is_Entity_Name (Id)
 237                     or else Ekind (Entity (Id)) /= E_Exception
 238                   then
 239                      Error_Msg_N ("exception name expected", Id);
 240
 241                   else
 242                      if Present (Renamed_Entity (Entity (Id))) then
 243                         if Entity (Id) = Standard_Numeric_Error
 244                           and then Warn_On_Obsolescent_Feature
 245                         then
 246                            Error_Msg_N
 247                              ("Numeric_Error is an " &
 248                               "obsolescent feature ('R'M 'J.6(1))?", Id);
 249                            Error_Msg_N
 250                              ("|use Constraint_Error instead?", Id);
 251                         end if;
 252                      end if;
 253
 254                      Check_Duplication (Id);
 255
 256                      --  Check for exception declared within generic formal
 257                      --  package (which is illegal, see RM 11.2(8))
 258
 259                      declare
 260                         Ent  : Entity_Id := Entity (Id);
 261                         Scop : Entity_Id;
 262
 263                      begin
 264                         if Present (Renamed_Entity (Ent)) then
 265                            Ent := Renamed_Entity (Ent);
 266                         end if;
 267
 268                         Scop := Scope (Ent);
 269                         while Scop /= Standard_Standard
 270                           and then Ekind (Scop) = E_Package
 271                         loop
 272                            --  If the exception is declared in an inner
 273                            --  instance, nothing else to check.
 274
 275                            if Is_Generic_Instance (Scop) then
 276                               exit;
 277
 278                            elsif Nkind (Declaration_Node (Scop)) =
 279                                            N_Package_Specification
 280                              and then
 281                                Nkind (Original_Node (Parent
 282                                  (Declaration_Node (Scop)))) =
 283                                            N_Formal_Package_Declaration
 284                            then
 285                               Error_Msg_NE
 286                                 ("exception& is declared in "  &
 287                                  "generic formal package", Id, Ent);
 288                               Error_Msg_N
 289                                 ("\and therefore cannot appear in " &
 290                                  "handler ('R'M 11.2(8))", Id);
 291                               exit;
 292                            end if;
 293
 294                            Scop := Scope (Scop);
 295                         end loop;
 296                      end;
 297                   end if;
 298                end if;
 299
 300                Next (Id);
 301             end loop;
 302
 303             --  Check for redundant handler (has only raise statement) and
 304             --  is either an others handler, or is a specific handler when
 305             --  no others handler is present.
 306
 307             if Warn_On_Redundant_Constructs
 308               and then List_Length (Statements (Handler)) = 1
 309               and then Nkind (First (Statements (Handler))) = N_Raise_Statement
 310               and then No (Name (First (Statements (Handler))))
 311               and then (not Others_Present
 312                           or else Nkind (First (Exception_Choices (Handler))) =
 313                                               N_Others_Choice)
 314             then
 315                Error_Msg_N
 316                  ("useless handler contains only a reraise statement?",
 317                   Handler);
 318             end if;
 319
 320             --  Now analyze the statements of this handler
 321
 322             Analyze_Statements (Statements (Handler));
 323
 324             --  If a choice was present, we created a special scope for it,
 325             --  so this is where we pop that special scope to get rid of it.
 326
 327             if Present (Choice) then
 328                End_Scope;
 329             end if;
 330          end if;
 331
 332          Next (Handler);
 333       end loop;
 334    end Analyze_Exception_Handlers;
 335
 336    --------------------------------
 337    -- Analyze_Handled_Statements --
 338    --------------------------------
 339
 340    procedure Analyze_Handled_Statements (N : Node_Id) is
 341       Handlers : constant List_Id := Exception_Handlers (N);
 342
 343    begin
 344       if Present (Handlers) then
 345          Kill_All_Checks;
 346       end if;
 347
 348       Analyze_Statements (Statements (N));
 349
 350       if Present (Handlers) then
 351          Analyze_Exception_Handlers (Handlers);
 352
 353       elsif Present (At_End_Proc (N)) then
 354          Analyze (At_End_Proc (N));
 355       end if;
 356    end Analyze_Handled_Statements;
 357
 358    -----------------------------
 359    -- Analyze_Raise_Statement --
 360    -----------------------------
 361
 362    procedure Analyze_Raise_Statement (N : Node_Id) is
 363       Exception_Id   : constant Node_Id := Name (N);
 364       Exception_Name : Entity_Id := Empty;
 365       P              : Node_Id;
 366       Nkind_P        : Node_Kind;
 367
 368    begin
 369       Check_Unreachable_Code (N);
 370
 371       --  Check exception restrictions on the original source
 372
 373       if Comes_From_Source (N) then
 374          Check_Restriction (No_Exceptions, N);
 375       end if;
 376
 377       --  Check for useless assignment to OUT or IN OUT scalar
 378       --  immediately preceding the raise. Right now we only look
 379       --  at assignment statements, we could do more.
 380
 381       if Is_List_Member (N) then
 382          declare
 383             P : Node_Id;
 384             L : Node_Id;
 385
 386          begin
 387             P := Prev (N);
 388
 389             if Present (P)
 390               and then Nkind (P) = N_Assignment_Statement
 391             then
 392                L := Name (P);
 393
 394                if Is_Scalar_Type (Etype (L))
 395                  and then Is_Entity_Name (L)
 396                  and then Is_Formal (Entity (L))
 397                then
 398                   Error_Msg_N
 399                     ("?assignment to pass-by-copy formal may have no effect",
 400                       P);
 401                   Error_Msg_N
 402                     ("\?RAISE statement is abnormal return" &
 403                      " ('R'M 6.4.1(17))", P);
 404                end if;
 405             end if;
 406          end;
 407       end if;
 408
 409       --  Reraise statement
 410
 411       if No (Exception_Id) then
 412
 413          P := Parent (N);
 414          Nkind_P := Nkind (P);
 415
 416          while Nkind_P /= N_Exception_Handler
 417            and then Nkind_P /= N_Subprogram_Body
 418            and then Nkind_P /= N_Package_Body
 419            and then Nkind_P /= N_Task_Body
 420            and then Nkind_P /= N_Entry_Body
 421          loop
 422             P := Parent (P);
 423             Nkind_P := Nkind (P);
 424          end loop;
 425
 426          if Nkind (P) /= N_Exception_Handler then
 427             Error_Msg_N
 428               ("reraise statement must appear directly in a handler", N);
 429          end if;
 430
 431       --  Normal case with exception id present
 432
 433       else
 434          Analyze (Exception_Id);
 435
 436          if Is_Entity_Name (Exception_Id) then
 437             Exception_Name := Entity (Exception_Id);
 438          end if;
 439
 440          if No (Exception_Name)
 441            or else Ekind (Exception_Name) /= E_Exception
 442          then
 443             Error_Msg_N
 444               ("exception name expected in raise statement", Exception_Id);
 445          end if;
 446       end if;
 447    end Analyze_Raise_Statement;
 448
 449    -----------------------------
 450    -- Analyze_Raise_xxx_Error --
 451    -----------------------------
 452
 453    --  Normally, the Etype is already set (when this node is used within
 454    --  an expression, since it is copied from the node which it rewrites).
 455    --  If this node is used in a statement context, then we set the type
 456    --  Standard_Void_Type. This is used both by Gigi and by the front end
 457    --  to distinguish the statement use and the subexpression use.
 458
 459    --  The only other required processing is to take care of the Condition
 460    --  field if one is present.
 461
 462    procedure Analyze_Raise_xxx_Error (N : Node_Id) is
 463    begin
 464       if No (Etype (N)) then
 465          Set_Etype (N, Standard_Void_Type);
 466       end if;
 467
 468       if Present (Condition (N)) then
 469          Analyze_And_Resolve (Condition (N), Standard_Boolean);
 470       end if;
 471
 472       --  Deal with static cases in obvious manner
 473
 474       if Nkind (Condition (N)) = N_Identifier then
 475          if Entity (Condition (N)) = Standard_True then
 476             Set_Condition (N, Empty);
 477
 478          elsif Entity (Condition (N)) = Standard_False then
 479             Rewrite (N, Make_Null_Statement (Sloc (N)));
 480          end if;
 481       end if;
 482    end Analyze_Raise_xxx_Error;
 483
 484    -----------------------------
 485    -- Analyze_Subprogram_Info --
 486    -----------------------------
 487
 488    procedure Analyze_Subprogram_Info (N : Node_Id) is
 489    begin
 490       Set_Etype (N, RTE (RE_Code_Loc));
 491    end Analyze_Subprogram_Info;
 492
 493 end Sem_Ch11;