gcc/ada/sem_case.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ C A S E                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --         Copyright (C) 1996-2001 Free Software Foundation, Inc.           --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Types; use Types;
  28
  29 --  Package containing all the routines to process a list of discrete choices.
  30 --  Such lists can occur in 3 different constructs: case statements, array
  31 --  aggregates and record variants. We have factorized what used to be 3 very
  32 --  similar sets of routines here. If you didn't figure it out already Choi
  33 --  in the package name stands for Choices.
  34
  35 package Sem_Case is
  36
  37    type Choice_Bounds is record
  38      Lo   : Node_Id;
  39      Hi   : Node_Id;
  40      Node : Node_Id;
  41    end record;
  42
  43    type Choice_Table_Type is array (Pos range <>) of Choice_Bounds;
  44    --  Table type used to sort the choices present in a case statement,
  45    --  array aggregate or record variant.
  46
  47    procedure No_OP (C : Node_Id);
  48    --  The no-operation routine. Does absolutely nothing. Can be used
  49    --  in the following generic for the parameter Process_Empty_Choice.
  50
  51    generic
  52       with function Get_Alternatives (N : Node_Id) return List_Id;
  53       --  Function needed to get to the actual list of case statement
  54       --  alternatives, or array aggregate component associations or
  55       --  record variants from which we can then access the actual lists
  56       --  of discrete choices. N is the node for the original construct
  57       --  ie a case statement, an array aggregate or a record variant.
  58
  59       with function Get_Choices (A : Node_Id) return List_Id;
  60       --  Given a case statement alternative, array aggregate component
  61       --  association or record variant A we need different access functions
  62       --  to get to the actual list of discrete choices.
  63
  64       with procedure Process_Empty_Choice (Choice : Node_Id);
  65       --  Processing to carry out for an empty Choice.
  66
  67       with procedure Process_Non_Static_Choice (Choice : Node_Id);
  68       --  Processing to carry out for a non static Choice.
  69
  70       with procedure Process_Associated_Node (A : Node_Id);
  71       --  Associated to each case alternative, aggregate component
  72       --  association or record variant A there is a node or list of nodes
  73       --  that need semantic processing. This routine implements that
  74       --  processing.
  75
  76    package Generic_Choices_Processing is
  77
  78       function Number_Of_Choices (N : Node_Id) return Nat;
  79       --  Iterates through the choices of N, (N can be a case statement,
  80       --  array aggregate or record variant), counting all the Choice nodes
  81       --  except for the Others choice.
  82
  83       procedure Analyze_Choices
  84         (N              : Node_Id;
  85          Subtyp         : Entity_Id;
  86          Choice_Table   : in out Choice_Table_Type;
  87          Last_Choice    : out Nat;
  88          Raises_CE      : out Boolean;
  89          Others_Present : out Boolean);
  90       --  From a case statement, array aggregate or record variant N, this
  91       --  routine analyzes the corresponding list of discrete choices.
  92       --  Subtyp is the subtype of the discrete choices. The type against
  93       --  which the discrete choices must be resolved is its base type.
  94       --
  95       --  On entry Choice_Table must be big enough to contain all the
  96       --  discrete choices encountered.
  97       --
  98       --  On exit Choice_Table contains all the static and non empty
  99       --  discrete choices in sorted order. Last_Choice gives the position
 100       --  of the last valid choice in Choice_Table, Choice_Table'First
 101       --  contains the first. We can have Last_Choice < Choice_Table'Last
 102       --  for one (or several) of the following reasons:
 103       --
 104       --    (a) The list of choices contained a non static choice
 105       --
 106       --    (b) The list of choices contained an empty choice
 107       --        (something like "1 .. 0 => ")
 108       --
 109       --    (c) One of the bounds of a discrete choice contains an
 110       --        error or raises constraint error.
 111       --
 112       --  In one of the bounds of a discrete choice raises a constraint
 113       --  error the flag Raise_CE is set.
 114       --
 115       --  Finally Others_Present is set to True if an Others choice is
 116       --  present in the list of choices.
 117
 118    end Generic_Choices_Processing;
 119
 120 end Sem_Case;