gcc/ada/scn.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  S C N                                   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Csets;    use Csets;
  29 with Hostparm;
  30 with Namet;    use Namet;
  31 with Opt;      use Opt;
  32 with Scans;    use Scans;
  33 with Sinfo;    use Sinfo;
  34 with Sinput;   use Sinput;
  35
  36 package body Scn is
  37
  38    use ASCII;
  39
  40    Used_As_Identifier : array (Token_Type) of Boolean;
  41    --  Flags set True if a given keyword is used as an identifier (used to
  42    --  make sure that we only post an error message for incorrect use of a
  43    --  keyword as an identifier once for a given keyword).
  44
  45    procedure Check_End_Of_Line;
  46    --  Called when end of line encountered. Checks that line is not
  47    --  too long, and that other style checks for the end of line are met.
  48
  49    function Determine_License return License_Type;
  50    --  Scan header of file and check that it has an appropriate GNAT-style
  51    --  header with a proper license statement. Returns GPL, Unrestricted,
  52    --  or Modified_GPL depending on header. If none of these, returns Unknown.
  53
  54    procedure Error_Long_Line;
  55    --  Signal error of excessively long line
  56
  57    ---------------
  58    -- Post_Scan --
  59    ---------------
  60
  61    procedure Post_Scan is
  62    begin
  63       case Token is
  64          when Tok_Char_Literal =>
  65             Token_Node := New_Node (N_Character_Literal, Token_Ptr);
  66             Set_Char_Literal_Value (Token_Node, Character_Code);
  67             Set_Chars (Token_Node, Token_Name);
  68
  69          when Tok_Identifier =>
  70             Token_Node := New_Node (N_Identifier, Token_Ptr);
  71             Set_Chars (Token_Node, Token_Name);
  72
  73          when Tok_Real_Literal =>
  74             Token_Node := New_Node (N_Real_Literal, Token_Ptr);
  75             Set_Realval (Token_Node, Real_Literal_Value);
  76
  77          when Tok_Integer_Literal =>
  78             Token_Node := New_Node (N_Integer_Literal, Token_Ptr);
  79             Set_Intval (Token_Node, Int_Literal_Value);
  80
  81          when Tok_String_Literal =>
  82             Token_Node := New_Node (N_String_Literal, Token_Ptr);
  83             Set_Has_Wide_Character (Token_Node, Wide_Character_Found);
  84             Set_Strval (Token_Node, String_Literal_Id);
  85
  86          when Tok_Operator_Symbol =>
  87             Token_Node := New_Node (N_Operator_Symbol, Token_Ptr);
  88             Set_Chars (Token_Node, Token_Name);
  89             Set_Strval (Token_Node, String_Literal_Id);
  90
  91          when others =>
  92             null;
  93       end case;
  94    end Post_Scan;
  95
  96    -----------------------
  97    -- Check_End_Of_Line --
  98    -----------------------
  99
 100    procedure Check_End_Of_Line is
 101       Len : constant Int := Int (Scan_Ptr) - Int (Current_Line_Start);
 102
 103    begin
 104       if Len > Hostparm.Max_Line_Length then
 105          Error_Long_Line;
 106
 107       elsif Style_Check then
 108          Style.Check_Line_Terminator (Len);
 109       end if;
 110    end Check_End_Of_Line;
 111
 112    -----------------------
 113    -- Determine_License --
 114    -----------------------
 115
 116    function Determine_License return License_Type is
 117       GPL_Found : Boolean := False;
 118
 119       function Contains (S : String) return Boolean;
 120       --  See if current comment contains successive non-blank characters
 121       --  matching the contents of S. If so leave Scan_Ptr unchanged and
 122       --  return True, otherwise leave Scan_Ptr unchanged and return False.
 123
 124       procedure Skip_EOL;
 125       --  Skip to line terminator character
 126
 127       --------------
 128       -- Contains --
 129       --------------
 130
 131       function Contains (S : String) return Boolean is
 132          CP : Natural;
 133          SP : Source_Ptr;
 134          SS : Source_Ptr;
 135
 136       begin
 137          SP := Scan_Ptr;
 138          while Source (SP) /= CR and then Source (SP) /= LF loop
 139             if Source (SP) = S (S'First) then
 140                SS := SP;
 141                CP := S'First;
 142
 143                loop
 144                   SS := SS + 1;
 145                   CP := CP + 1;
 146
 147                   if CP > S'Last then
 148                      return True;
 149                   end if;
 150
 151                   while Source (SS) = ' ' loop
 152                      SS := SS + 1;
 153                   end loop;
 154
 155                   exit when Source (SS) /= S (CP);
 156                end loop;
 157             end if;
 158
 159             SP := SP + 1;
 160          end loop;
 161
 162          return False;
 163       end Contains;
 164
 165       --------------
 166       -- Skip_EOL --
 167       --------------
 168
 169       procedure Skip_EOL is
 170       begin
 171          while Source (Scan_Ptr) /= CR
 172            and then Source (Scan_Ptr) /= LF
 173            and then Source (Scan_Ptr) /= EOF
 174          loop
 175             Scan_Ptr := Scan_Ptr + 1;
 176          end loop;
 177       end Skip_EOL;
 178
 179    --  Start of processing for Determine_License
 180
 181    begin
 182       loop
 183          if Source (Scan_Ptr) /= '-'
 184            or else Source (Scan_Ptr + 1) /= '-'
 185          then
 186             if GPL_Found then
 187                return GPL;
 188             else
 189                return Unknown;
 190             end if;
 191
 192          elsif Contains ("Asaspecialexception") then
 193             if GPL_Found then
 194                return Modified_GPL;
 195             end if;
 196
 197          elsif Contains ("GNUGeneralPublicLicense") then
 198             GPL_Found := True;
 199
 200          elsif
 201              Contains
 202                ("ThisspecificationisadaptedfromtheAdaSemanticInterface")
 203            or else
 204              Contains
 205               ("ThisspecificationisderivedfromtheAdaReferenceManual")
 206          then
 207             return Unrestricted;
 208          end if;
 209
 210          Skip_EOL;
 211
 212          Check_End_Of_Line;
 213
 214          if Source (Scan_Ptr) /= EOF then
 215
 216             --  We have to take into account a degenerate case when the source
 217             --  file contains only comments and no Ada code.
 218
 219             declare
 220                Physical : Boolean;
 221
 222             begin
 223                Skip_Line_Terminators (Scan_Ptr, Physical);
 224
 225                --  If we are at start of physical line, update scan pointers
 226                --  to reflect the start of the new line.
 227
 228                if Physical then
 229                   Current_Line_Start       := Scan_Ptr;
 230                   Start_Column             := Scanner.Set_Start_Column;
 231                   First_Non_Blank_Location := Scan_Ptr;
 232                end if;
 233             end;
 234          end if;
 235       end loop;
 236    end Determine_License;
 237
 238    ----------------------------
 239    -- Determine_Token_Casing --
 240    ----------------------------
 241
 242    function Determine_Token_Casing return Casing_Type is
 243    begin
 244       return Scanner.Determine_Token_Casing;
 245    end Determine_Token_Casing;
 246
 247    ---------------------
 248    -- Error_Long_Line --
 249    ---------------------
 250
 251    procedure Error_Long_Line is
 252    begin
 253       Error_Msg
 254         ("this line is too long",
 255          Current_Line_Start + Hostparm.Max_Line_Length);
 256    end Error_Long_Line;
 257
 258    ------------------------
 259    -- Initialize_Scanner --
 260    ------------------------
 261
 262    procedure Initialize_Scanner
 263      (Unit  : Unit_Number_Type;
 264       Index : Source_File_Index)
 265    is
 266       GNAT_Hedr : constant Text_Buffer (1 .. 78) := (others => '-');
 267
 268    begin
 269       Scanner.Initialize_Scanner (Unit, Index);
 270
 271       --  Set default for Comes_From_Source (except if we are going to process
 272       --  an artificial string internally created within the compiler and
 273       --  placed into internal source duffer). All nodes built now until we
 274       --  reenter the analyzer will have Comes_From_Source set to True
 275
 276       if Index /= Internal_Source_File then
 277          Set_Comes_From_Source_Default (True);
 278       end if;
 279
 280       --  Check license if GNAT type header possibly present
 281
 282       if Source_Last (Index) - Scan_Ptr > 80
 283         and then Source (Scan_Ptr .. Scan_Ptr + 77) = GNAT_Hedr
 284       then
 285          Set_License (Current_Source_File, Determine_License);
 286       end if;
 287
 288       --  Because of the License stuff above, Scng.Initialize_Scanner cannot
 289       --  call Scan. Scan initial token (note this initializes Prev_Token,
 290       --  Prev_Token_Ptr).
 291
 292       --  There are two reasons not to do the Scan step in case if we
 293       --  initialize the scanner for the internal source buffer:
 294
 295       --  - The artificial string may not be created by the compiler in this
 296       --    buffer when we call Initialize_Scanner
 297
 298       --  - For these artificial strings a special way of scanning is used, so
 299       --    the standard step of the scanner may just break the algorithm of
 300       --    processing these strings.
 301
 302       if Index /= Internal_Source_File then
 303          Scan;
 304       end if;
 305
 306       --  Clear flags for reserved words used as indentifiers
 307
 308       for J in Token_Type loop
 309          Used_As_Identifier (J) := False;
 310       end loop;
 311    end Initialize_Scanner;
 312
 313    ------------------------------
 314    -- Scan_Reserved_Identifier --
 315    ------------------------------
 316
 317    procedure Scan_Reserved_Identifier (Force_Msg : Boolean) is
 318       Token_Chars : constant String := Token_Type'Image (Token);
 319
 320    begin
 321       --  We have in Token_Chars the image of the Token name, i.e. Tok_xxx.
 322       --  This code extracts the xxx and makes an identifier out of it.
 323
 324       Name_Len := 0;
 325
 326       for J in 5 .. Token_Chars'Length loop
 327          Name_Len := Name_Len + 1;
 328          Name_Buffer (Name_Len) := Fold_Lower (Token_Chars (J));
 329       end loop;
 330
 331       Token_Name := Name_Find;
 332
 333       if not Used_As_Identifier (Token) or else Force_Msg then
 334          Error_Msg_Name_1 := Token_Name;
 335          Error_Msg_SC ("reserved word* cannot be used as identifier!");
 336          Used_As_Identifier (Token) := True;
 337       end if;
 338
 339       Token := Tok_Identifier;
 340       Token_Node := New_Node (N_Identifier, Token_Ptr);
 341       Set_Chars (Token_Node, Token_Name);
 342    end Scan_Reserved_Identifier;
 343
 344 end Scn;