gcc/ada/scans.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                S C A N S                                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2003 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Types;  use Types;
  35 with Uintp;  use Uintp;
  36 with Urealp; use Urealp;
  37
  38 package Scans is
  39
  40 --  The scanner maintains a current state in the global variables defined
  41 --  in this package. The call to the Scan routine advances this state to
  42 --  the next token. The state is initialized by the call to one of the
  43 --  initialization routines in Sinput.
  44
  45    --  The following type is used to identify token types returned by Scan.
  46    --  The class column in this table indicates the token classes which
  47    --  apply to the token, as defined by subsquent subtype declarations.
  48
  49    --  Note: the coding in SCN depends on the fact that the first entry in
  50    --  this type declaration is *not* for a reserved word. For details on
  51    --  why there is this requirement, see Scn.Initialize_Scanner.
  52
  53    type Token_Type is (
  54
  55       --  Token name          Token type   Class(es)
  56
  57       Tok_Integer_Literal, -- numeric lit  Literal, Lit_Or_Name
  58
  59       Tok_Real_Literal,    -- numeric lit  Literal, Lit_Or_Name
  60
  61       Tok_String_Literal,  -- string lit   Literal. Lit_Or_Name
  62
  63       Tok_Char_Literal,    -- char lit     Name, Literal. Lit_Or_Name
  64
  65       Tok_Operator_Symbol, -- op symbol    Name, Literal, Lit_Or_Name, Desig
  66
  67       Tok_Identifier,      -- identifer    Name, Lit_Or_Name, Desig
  68
  69       Tok_Double_Asterisk, -- **
  70
  71       Tok_Ampersand,       -- &            Binary_Addop
  72       Tok_Minus,           -- -            Binary_Addop, Unary_Addop
  73       Tok_Plus,            -- +            Binary_Addop, Unary_Addop
  74
  75       Tok_Asterisk,        -- *            Mulop
  76       Tok_Mod,             -- MOD          Mulop
  77       Tok_Rem,             -- REM          Mulop
  78       Tok_Slash,           -- /            Mulop
  79
  80       Tok_New,             -- NEW
  81
  82       Tok_Abs,             -- ABS
  83       Tok_Others,          -- OTHERS
  84       Tok_Null,            -- NULL
  85
  86       Tok_Dot,             -- .            Namext
  87       Tok_Apostrophe,      -- '            Namext
  88
  89       Tok_Left_Paren,      -- (            Namext, Consk
  90
  91       Tok_Delta,           -- DELTA        Atkwd, Sterm, Consk
  92       Tok_Digits,          -- DIGITS       Atkwd, Sterm, Consk
  93       Tok_Range,           -- RANGE        Atkwd, Sterm, Consk
  94
  95       Tok_Right_Paren,     -- )            Sterm
  96       Tok_Comma,           -- ,            Sterm
  97
  98       Tok_And,             -- AND          Logop, Sterm
  99       Tok_Or,              -- OR           Logop, Sterm
 100       Tok_Xor,             -- XOR          Logop, Sterm
 101
 102       Tok_Less,            -- <            Relop, Sterm
 103       Tok_Equal,           -- =            Relop, Sterm
 104       Tok_Greater,         -- >            Relop, Sterm
 105       Tok_Not_Equal,       -- /=           Relop, Sterm
 106       Tok_Greater_Equal,   -- >=           Relop, Sterm
 107       Tok_Less_Equal,      -- <=           Relop, Sterm
 108
 109       Tok_In,              -- IN           Relop, Sterm
 110       Tok_Not,             -- NOT          Relop, Sterm
 111
 112       Tok_Box,             -- <>           Relop, Eterm, Sterm
 113       Tok_Colon_Equal,     -- :=           Eterm, Sterm
 114       Tok_Colon,           -- :            Eterm, Sterm
 115       Tok_Greater_Greater, -- >>           Eterm, Sterm
 116
 117       Tok_Abstract,        -- ABSTRACT     Eterm, Sterm
 118       Tok_Access,          -- ACCESS       Eterm, Sterm
 119       Tok_Aliased,         -- ALIASED      Eterm, Sterm
 120       Tok_All,             -- ALL          Eterm, Sterm
 121       Tok_Array,           -- ARRAY        Eterm, Sterm
 122       Tok_At,              -- AT           Eterm, Sterm
 123       Tok_Body,            -- BODY         Eterm, Sterm
 124       Tok_Constant,        -- CONSTANT     Eterm, Sterm
 125       Tok_Do,              -- DO           Eterm, Sterm
 126       Tok_Is,              -- IS           Eterm, Sterm
 127       Tok_Limited,         -- LIMITED      Eterm, Sterm
 128       Tok_Of,              -- OF           Eterm, Sterm
 129       Tok_Out,             -- OUT          Eterm, Sterm
 130       Tok_Record,          -- RECORD       Eterm, Sterm
 131       Tok_Renames,         -- RENAMES      Eterm, Sterm
 132       Tok_Reverse,         -- REVERSE      Eterm, Sterm
 133       Tok_Tagged,          -- TAGGED       Eterm, Sterm
 134       Tok_Then,            -- THEN         Eterm, Sterm
 135
 136       Tok_Less_Less,       -- <<           Eterm, Sterm, After_SM
 137
 138       Tok_Abort,           -- ABORT        Eterm, Sterm, After_SM
 139       Tok_Accept,          -- ACCEPT       Eterm, Sterm, After_SM
 140       Tok_Case,            -- CASE         Eterm, Sterm, After_SM
 141       Tok_Delay,           -- DELAY        Eterm, Sterm, After_SM
 142       Tok_Else,            -- ELSE         Eterm, Sterm, After_SM
 143       Tok_Elsif,           -- ELSIF        Eterm, Sterm, After_SM
 144       Tok_End,             -- END          Eterm, Sterm, After_SM
 145       Tok_Exception,       -- EXCEPTION    Eterm, Sterm, After_SM
 146       Tok_Exit,            -- EXIT         Eterm, Sterm, After_SM
 147       Tok_Goto,            -- GOTO         Eterm, Sterm, After_SM
 148       Tok_If,              -- IF           Eterm, Sterm, After_SM
 149       Tok_Pragma,          -- PRAGMA       Eterm, Sterm, After_SM
 150       Tok_Raise,           -- RAISE        Eterm, Sterm, After_SM
 151       Tok_Requeue,         -- REQUEUE      Eterm, Sterm, After_SM
 152       Tok_Return,          -- RETURN       Eterm, Sterm, After_SM
 153       Tok_Select,          -- SELECT       Eterm, Sterm, After_SM
 154       Tok_Terminate,       -- TERMINATE    Eterm, Sterm, After_SM
 155       Tok_Until,           -- UNTIL        Eterm, Sterm, After_SM
 156       Tok_When,            -- WHEN         Eterm, Sterm, After_SM
 157
 158       Tok_Begin,           -- BEGIN        Eterm, Sterm, After_SM, Labeled_Stmt
 159       Tok_Declare,         -- DECLARE      Eterm, Sterm, After_SM, Labeled_Stmt
 160       Tok_For,             -- FOR          Eterm, Sterm, After_SM, Labeled_Stmt
 161       Tok_Loop,            -- LOOP         Eterm, Sterm, After_SM, Labeled_Stmt
 162       Tok_While,           -- WHILE        Eterm, Sterm, After_SM, Labeled_Stmt
 163
 164       Tok_Entry,           -- ENTRY        Eterm, Sterm, Declk, Deckn, After_SM
 165       Tok_Protected,       -- PROTECTED    Eterm, Sterm, Declk, Deckn, After_SM
 166       Tok_Task,            -- TASK         Eterm, Sterm, Declk, Deckn, After_SM
 167       Tok_Type,            -- TYPE         Eterm, Sterm, Declk, Deckn, After_SM
 168       Tok_Subtype,         -- SUBTYPE      Eterm, Sterm, Declk, Deckn, After_SM
 169       Tok_Use,             -- USE          Eterm, Sterm, Declk, Deckn, After_SM
 170
 171       Tok_Function,        -- FUNCTION     Eterm, Sterm, Cunit, Declk, After_SM
 172       Tok_Generic,         -- GENERIC      Eterm, Sterm, Cunit, Declk, After_SM
 173       Tok_Package,         -- PACKAGE      Eterm, Sterm, Cunit, Declk, After_SM
 174       Tok_Procedure,       -- PROCEDURE    Eterm, Sterm, Cunit, Declk, After_SM
 175
 176       Tok_Private,         -- PRIVATE      Eterm, Sterm, Cunit, After_SM
 177       Tok_With,            -- WITH         Eterm, Sterm, Cunit, After_SM
 178       Tok_Separate,        -- SEPARATE     Eterm, Sterm, Cunit, After_SM
 179
 180       Tok_EOF,             -- End of file  Eterm, Sterm, Cterm, After_SM
 181
 182       Tok_Semicolon,       -- ;            Eterm, Sterm, Cterm
 183
 184       Tok_Arrow,           -- =>           Sterm, Cterm, Chtok
 185
 186       Tok_Vertical_Bar,    -- |            Cterm, Sterm, Chtok
 187
 188       Tok_Dot_Dot,         -- ..           Sterm, Chtok
 189
 190       --  The following three entries are used only when scanning project
 191       --  files.
 192
 193       Tok_Project,
 194       Tok_Extends,
 195       Tok_External,
 196       Tok_Comment,
 197
 198       --  The following entry is used by the preprocessor and when scanning
 199       --  project files.
 200
 201       Tok_End_Of_Line,
 202
 203       --  The following entry is used by the preprocessor
 204
 205       Tok_Special,
 206
 207       No_Token);
 208       --  No_Token is used for initializing Token values to indicate that
 209       --  no value has been set yet.
 210
 211    --  Note: in the RM, operator symbol is a special case of string literal.
 212    --  We distinguish at the lexical level in this compiler, since there are
 213    --  many syntactic situations in which only an operator symbol is allowed.
 214
 215    --  The following subtype declarations group the token types into classes.
 216    --  These are used for class tests in the parser.
 217
 218       subtype Token_Class_Numeric_Literal is
 219         Token_Type range Tok_Integer_Literal .. Tok_Real_Literal;
 220       --  Numeric literal
 221
 222       subtype Token_Class_Literal is
 223         Token_Type range Tok_Integer_Literal .. Tok_Operator_Symbol;
 224       --  Literal
 225
 226       subtype Token_Class_Lit_Or_Name is
 227         Token_Type range Tok_Integer_Literal .. Tok_Identifier;
 228
 229       subtype Token_Class_Binary_Addop is
 230         Token_Type range Tok_Ampersand .. Tok_Plus;
 231       --  Binary adding operator (& + -)
 232
 233       subtype Token_Class_Unary_Addop is
 234         Token_Type range Tok_Minus .. Tok_Plus;
 235       --  Unary adding operator (+ -)
 236
 237       subtype Token_Class_Mulop is
 238         Token_Type range Tok_Asterisk .. Tok_Slash;
 239       --  Multiplying operator
 240
 241       subtype Token_Class_Logop is
 242         Token_Type range Tok_And .. Tok_Xor;
 243       --  Logical operator (and, or, xor)
 244
 245       subtype Token_Class_Relop is
 246         Token_Type range Tok_Less .. Tok_Box;
 247       --  Relational operator (= /= < <= > >= not, in plus <> to catch misuse
 248       --  of Pascal style not equal operator).
 249
 250       subtype Token_Class_Name is
 251         Token_Type range Tok_Char_Literal .. Tok_Identifier;
 252       --  First token of name (4.1),
 253       --    (identifier, char literal, operator symbol)
 254
 255       subtype Token_Class_Desig is
 256         Token_Type range Tok_Operator_Symbol .. Tok_Identifier;
 257       --  Token which can be a Designator (identifier, operator symbol)
 258
 259       subtype Token_Class_Namext is
 260         Token_Type range Tok_Dot .. Tok_Left_Paren;
 261       --  Name extension tokens. These are tokens which can appear immediately
 262       --  after a name to extend it recursively (period, quote, left paren)
 263
 264       subtype Token_Class_Consk is
 265         Token_Type range Tok_Left_Paren .. Tok_Range;
 266       --  Keywords which can start constraint
 267       --    (left paren, delta, digits, range)
 268
 269       subtype Token_Class_Eterm is
 270         Token_Type range Tok_Colon_Equal .. Tok_Semicolon;
 271       --  Expression terminators. These tokens can never appear within a simple
 272       --  expression. This is used for error recovery purposes (if we encounter
 273       --  an error in an expression, we simply scan to the next Eterm token).
 274
 275       subtype Token_Class_Sterm is
 276         Token_Type range Tok_Delta .. Tok_Dot_Dot;
 277       --  Simple_Expression terminators. A Simple_Expression must be followed
 278       --  by a token in this class, or an error message is issued complaining
 279       --  about a missing binary operator.
 280
 281       subtype Token_Class_Atkwd is
 282         Token_Type range Tok_Delta .. Tok_Range;
 283       --  Attribute keywords. This class includes keywords which can be used
 284       --  as an Attribute_Designator, namely DELTA, DIGITS and RANGE
 285
 286       subtype Token_Class_Cterm is
 287         Token_Type range Tok_EOF .. Tok_Vertical_Bar;
 288       --  Choice terminators. These tokens terminate a choice. This is used for
 289       --  error recovery purposes (if we encounter an error in a Choice, we
 290       --  simply scan to the next Cterm token).
 291
 292       subtype Token_Class_Chtok is
 293         Token_Type range Tok_Arrow .. Tok_Dot_Dot;
 294       --  Choice tokens. These tokens signal a choice when used in an Aggregate
 295
 296       subtype Token_Class_Cunit is
 297         Token_Type range Tok_Function .. Tok_Separate;
 298       --  Tokens which can begin a compilation unit
 299
 300       subtype Token_Class_Declk is
 301         Token_Type range Tok_Entry .. Tok_Procedure;
 302       --  Keywords which start a declaration
 303
 304       subtype Token_Class_Deckn is
 305         Token_Type range Tok_Entry .. Tok_Use;
 306       --  Keywords which start a declaration but can't start a compilation unit
 307
 308       subtype Token_Class_After_SM is
 309         Token_Type range Tok_Less_Less .. Tok_EOF;
 310       --  Tokens which always, or almost always, appear after a semicolon. Used
 311       --  in the Resync_Past_Semicolon routine to avoid gobbling up stuff when
 312       --  a semicolon is missing. Of significance only for error recovery.
 313
 314       subtype Token_Class_Labeled_Stmt is
 315         Token_Type range Tok_Begin .. Tok_While;
 316       --  Tokens which start labeled statements
 317
 318       type Token_Flag_Array is array (Token_Type) of Boolean;
 319       Is_Reserved_Keyword : constant Token_Flag_Array := Token_Flag_Array'(
 320          Tok_Mod      .. Tok_Rem      => True,
 321          Tok_New      .. Tok_Null     => True,
 322          Tok_Delta    .. Tok_Range    => True,
 323          Tok_And      .. Tok_Xor      => True,
 324          Tok_In       .. Tok_Not      => True,
 325          Tok_Abstract .. Tok_Then     => True,
 326          Tok_Abort    .. Tok_Separate => True,
 327          others                       => False);
 328       --  Flag array used to test for reserved word
 329
 330    --------------------------
 331    -- Scan State Variables --
 332    --------------------------
 333
 334    --  Note: these variables can only be referenced during the parsing of a
 335    --  file. Reference to any of them from Sem or the expander is wrong.
 336
 337    Scan_Ptr : Source_Ptr;
 338    --  Current scan pointer location. After a call to Scan, this points
 339    --  just past the end of the token just scanned.
 340
 341    Token : Token_Type;
 342    --  Type of current token
 343
 344    Token_Ptr : Source_Ptr;
 345    --  Pointer to first character of current token
 346
 347    Current_Line_Start : Source_Ptr;
 348    --  Pointer to first character of line containing current token
 349
 350    Start_Column : Column_Number;
 351    --  Starting column number (zero origin) of the first non-blank character
 352    --  on the line containing the current token. This is used for error
 353    --  recovery circuits which depend on looking at the column line up.
 354
 355    Checksum : Word;
 356    --  Used to accumulate a CRC representing the tokens in the source
 357    --  file being compiled. This CRC includes only program tokens, and
 358    --  excludes comments.
 359
 360    First_Non_Blank_Location : Source_Ptr;
 361    --  Location of first non-blank character on the line containing the
 362    --  current token (i.e. the location of the character whose column number
 363    --  is stored in Start_Column).
 364
 365    Token_Node : Node_Id := Empty;
 366    --  Node table Id for the current token. This is set only if the current
 367    --  token is one for which the scanner constructs a node (i.e. it is an
 368    --  identifier, operator symbol, or literal. For other token types,
 369    --  Token_Node is undefined.
 370
 371    Token_Name : Name_Id := No_Name;
 372    --  For identifiers, this is set to the Name_Id of the identifier scanned.
 373    --  For all other tokens, Token_Name is set to Error_Name. Note that it
 374    --  would be possible for the caller to extract this information from
 375    --  Token_Node. We set Token_Name separately for two reasons. First it
 376    --  allows a quicker test for a specific identifier. Second, it allows
 377    --  a version of the parser to be built that does not build tree nodes,
 378    --  usable as a syntax checker.
 379
 380    Prev_Token : Token_Type := No_Token;
 381    --  Type of previous token
 382
 383    Prev_Token_Ptr : Source_Ptr;
 384    --  Pointer to first character of previous token
 385
 386    Version_To_Be_Found : Boolean;
 387    --  This flag is True if the scanner is still looking for an RCS version
 388    --  number in a comment. Normally it is initialized to False so that this
 389    --  circuit is not activated. If the -dv switch is set, then this flag is
 390    --  initialized to True, and then reset when the version number is found.
 391    --  We do things this way to minimize the impact on comment scanning.
 392
 393    Character_Code : Char_Code;
 394    --  Valid only when Token is Tok_Char_Literal.
 395
 396    Real_Literal_Value : Ureal;
 397    --  Valid only when Token is Tok_Real_Literal
 398
 399    Int_Literal_Value : Uint;
 400    --  Valid only when Token = Tok_Integer_Literal;
 401
 402    String_Literal_Id : String_Id;
 403    --  Id for currently scanned string value.
 404    --  Valid only when Token = Tok_String_Literal or Tok_Operator_Symbol.
 405
 406    Wide_Character_Found : Boolean := False;
 407    --  Set True if wide character found.
 408    --  Valid only when Token = Tok_String_Literal.
 409
 410    Special_Character : Character;
 411    --  Valid only when Token = Tok_Special
 412
 413    Comment_Id : Name_Id := No_Name;
 414    --  Valid only when Token = Tok_Comment. Store the string that follows
 415    --  the two '-' of a comment.
 416
 417    --------------------------------------------------------
 418    -- Procedures for Saving and Restoring the Scan State --
 419    --------------------------------------------------------
 420
 421    --  The following procedures can be used to save and restore the entire
 422    --  scan state. They are used in cases where it is necessary to backup
 423    --  the scan during the parse.
 424
 425    type Saved_Scan_State is private;
 426    --  Used for saving and restoring the scan state
 427
 428    procedure Save_Scan_State (Saved_State : out Saved_Scan_State);
 429    pragma Inline (Save_Scan_State);
 430    --  Saves the current scan state for possible later restoration. Note that
 431    --  there is no harm in saving the state and then never restoring it.
 432
 433    procedure Restore_Scan_State (Saved_State : in Saved_Scan_State);
 434    pragma Inline (Restore_Scan_State);
 435    --  Restores a scan state saved by a call to Save_Scan_State.
 436    --  The saved scan state must refer to the current source file.
 437
 438 private
 439    type Saved_Scan_State is record
 440       Save_Scan_Ptr                 : Source_Ptr;
 441       Save_Token                    : Token_Type;
 442       Save_Token_Ptr                : Source_Ptr;
 443       Save_Current_Line_Start       : Source_Ptr;
 444       Save_Start_Column             : Column_Number;
 445       Save_Checksum                 : Word;
 446       Save_First_Non_Blank_Location : Source_Ptr;
 447       Save_Token_Node               : Node_Id;
 448       Save_Token_Name               : Name_Id;
 449       Save_Prev_Token               : Token_Type;
 450       Save_Prev_Token_Ptr           : Source_Ptr;
 451    end record;
 452
 453 end Scans;