gcc/ada/scans.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                S C A N S                                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Types;  use Types;
  35 with Uintp;  use Uintp;
  36 with Urealp; use Urealp;
  37
  38 package Scans is
  39
  40 --  The scanner maintains a current state in the global variables defined
  41 --  in this package. The call to the Scan routine advances this state to
  42 --  the next token. The state is initialized by the call to one of the
  43 --  initialization routines in Sinput.
  44
  45    --  The following type is used to identify token types returned by Scan.
  46    --  The class column in this table indicates the token classes which
  47    --  apply to the token, as defined by subsquent subtype declarations.
  48
  49    --  Note: the coding in SCN depends on the fact that the first entry in
  50    --  this type declaration is *not* for a reserved word. For details on
  51    --  why there is this requirement, see Scn.Initialize_Scanner.
  52
  53    type Token_Type is (
  54
  55       --  Token name          Token type   Class(es)
  56
  57       Tok_Integer_Literal, -- numeric lit  Literal, Lit_Or_Name
  58
  59       Tok_Real_Literal,    -- numeric lit  Literal, Lit_Or_Name
  60
  61       Tok_String_Literal,  -- string lit   Literal. Lit_Or_Name
  62
  63       Tok_Char_Literal,    -- char lit     Name, Literal. Lit_Or_Name
  64
  65       Tok_Operator_Symbol, -- op symbol    Name, Literal, Lit_Or_Name, Desig
  66
  67       Tok_Identifier,      -- identifer    Name, Lit_Or_Name, Desig
  68
  69       Tok_Double_Asterisk, -- **
  70
  71       Tok_Ampersand,       -- &            Binary_Addop
  72       Tok_Minus,           -- -            Binary_Addop, Unary_Addop
  73       Tok_Plus,            -- +            Binary_Addop, Unary_Addop
  74
  75       Tok_Asterisk,        -- *            Mulop
  76       Tok_Mod,             -- MOD          Mulop
  77       Tok_Rem,             -- REM          Mulop
  78       Tok_Slash,           -- /            Mulop
  79
  80       Tok_New,             -- NEW
  81
  82       Tok_Abs,             -- ABS
  83       Tok_Others,          -- OTHERS
  84       Tok_Null,            -- NULL
  85
  86       Tok_Dot,             -- .            Namext
  87       Tok_Apostrophe,      -- '            Namext
  88
  89       Tok_Left_Paren,      -- (            Namext, Consk
  90
  91       Tok_Delta,           -- DELTA        Atkwd, Sterm, Consk
  92       Tok_Digits,          -- DIGITS       Atkwd, Sterm, Consk
  93       Tok_Range,           -- RANGE        Atkwd, Sterm, Consk
  94
  95       Tok_Right_Paren,     -- )            Sterm
  96       Tok_Comma,           -- ,            Sterm
  97
  98       Tok_And,             -- AND          Logop, Sterm
  99       Tok_Or,              -- OR           Logop, Sterm
 100       Tok_Xor,             -- XOR          Logop, Sterm
 101
 102       Tok_Less,            -- <            Relop, Sterm
 103       Tok_Equal,           -- =            Relop, Sterm
 104       Tok_Greater,         -- >            Relop, Sterm
 105       Tok_Not_Equal,       -- /=           Relop, Sterm
 106       Tok_Greater_Equal,   -- >=           Relop, Sterm
 107       Tok_Less_Equal,      -- <=           Relop, Sterm
 108
 109       Tok_In,              -- IN           Relop, Sterm
 110       Tok_Not,             -- NOT          Relop, Sterm
 111
 112       Tok_Box,             -- <>           Relop, Eterm, Sterm
 113       Tok_Colon_Equal,     -- :=           Eterm, Sterm
 114       Tok_Colon,           -- :            Eterm, Sterm
 115       Tok_Greater_Greater, -- >>           Eterm, Sterm
 116
 117       Tok_Abstract,        -- ABSTRACT     Eterm, Sterm
 118       Tok_Access,          -- ACCESS       Eterm, Sterm
 119       Tok_Aliased,         -- ALIASED      Eterm, Sterm
 120       Tok_All,             -- ALL          Eterm, Sterm
 121       Tok_Array,           -- ARRAY        Eterm, Sterm
 122       Tok_At,              -- AT           Eterm, Sterm
 123       Tok_Body,            -- BODY         Eterm, Sterm
 124       Tok_Constant,        -- CONSTANT     Eterm, Sterm
 125       Tok_Do,              -- DO           Eterm, Sterm
 126       Tok_Is,              -- IS           Eterm, Sterm
 127       Tok_Interface,       -- INTERFACE    Eterm, Sterm
 128       Tok_Limited,         -- LIMITED      Eterm, Sterm
 129       Tok_Of,              -- OF           Eterm, Sterm
 130       Tok_Out,             -- OUT          Eterm, Sterm
 131       Tok_Record,          -- RECORD       Eterm, Sterm
 132       Tok_Renames,         -- RENAMES      Eterm, Sterm
 133       Tok_Reverse,         -- REVERSE      Eterm, Sterm
 134       Tok_Tagged,          -- TAGGED       Eterm, Sterm
 135       Tok_Then,            -- THEN         Eterm, Sterm
 136
 137       Tok_Less_Less,       -- <<           Eterm, Sterm, After_SM
 138
 139       Tok_Abort,           -- ABORT        Eterm, Sterm, After_SM
 140       Tok_Accept,          -- ACCEPT       Eterm, Sterm, After_SM
 141       Tok_Case,            -- CASE         Eterm, Sterm, After_SM
 142       Tok_Delay,           -- DELAY        Eterm, Sterm, After_SM
 143       Tok_Else,            -- ELSE         Eterm, Sterm, After_SM
 144       Tok_Elsif,           -- ELSIF        Eterm, Sterm, After_SM
 145       Tok_End,             -- END          Eterm, Sterm, After_SM
 146       Tok_Exception,       -- EXCEPTION    Eterm, Sterm, After_SM
 147       Tok_Exit,            -- EXIT         Eterm, Sterm, After_SM
 148       Tok_Goto,            -- GOTO         Eterm, Sterm, After_SM
 149       Tok_If,              -- IF           Eterm, Sterm, After_SM
 150       Tok_Pragma,          -- PRAGMA       Eterm, Sterm, After_SM
 151       Tok_Raise,           -- RAISE        Eterm, Sterm, After_SM
 152       Tok_Requeue,         -- REQUEUE      Eterm, Sterm, After_SM
 153       Tok_Return,          -- RETURN       Eterm, Sterm, After_SM
 154       Tok_Select,          -- SELECT       Eterm, Sterm, After_SM
 155       Tok_Terminate,       -- TERMINATE    Eterm, Sterm, After_SM
 156       Tok_Until,           -- UNTIL        Eterm, Sterm, After_SM
 157       Tok_When,            -- WHEN         Eterm, Sterm, After_SM
 158
 159       Tok_Begin,           -- BEGIN        Eterm, Sterm, After_SM, Labeled_Stmt
 160       Tok_Declare,         -- DECLARE      Eterm, Sterm, After_SM, Labeled_Stmt
 161       Tok_For,             -- FOR          Eterm, Sterm, After_SM, Labeled_Stmt
 162       Tok_Loop,            -- LOOP         Eterm, Sterm, After_SM, Labeled_Stmt
 163       Tok_While,           -- WHILE        Eterm, Sterm, After_SM, Labeled_Stmt
 164
 165       Tok_Entry,           -- ENTRY        Eterm, Sterm, Declk, Deckn, After_SM
 166       Tok_Protected,       -- PROTECTED    Eterm, Sterm, Declk, Deckn, After_SM
 167       Tok_Task,            -- TASK         Eterm, Sterm, Declk, Deckn, After_SM
 168       Tok_Type,            -- TYPE         Eterm, Sterm, Declk, Deckn, After_SM
 169       Tok_Subtype,         -- SUBTYPE      Eterm, Sterm, Declk, Deckn, After_SM
 170       Tok_Overriding,      -- OVERRIDING   Eterm, Sterm, Declk, Declk, After_SM
 171       Tok_Synchronized,    -- SYNCHRONIZED Eterm, Sterm, Declk, Deckn, After_SM
 172       Tok_Use,             -- USE          Eterm, Sterm, Declk, Deckn, After_SM
 173
 174       Tok_Function,        -- FUNCTION     Eterm, Sterm, Cunit, Declk, After_SM
 175       Tok_Generic,         -- GENERIC      Eterm, Sterm, Cunit, Declk, After_SM
 176       Tok_Package,         -- PACKAGE      Eterm, Sterm, Cunit, Declk, After_SM
 177       Tok_Procedure,       -- PROCEDURE    Eterm, Sterm, Cunit, Declk, After_SM
 178
 179       Tok_Private,         -- PRIVATE      Eterm, Sterm, Cunit, After_SM
 180       Tok_With,            -- WITH         Eterm, Sterm, Cunit, After_SM
 181       Tok_Separate,        -- SEPARATE     Eterm, Sterm, Cunit, After_SM
 182
 183       Tok_EOF,             -- End of file  Eterm, Sterm, Cterm, After_SM
 184
 185       Tok_Semicolon,       -- ;            Eterm, Sterm, Cterm
 186
 187       Tok_Arrow,           -- =>           Sterm, Cterm, Chtok
 188
 189       Tok_Vertical_Bar,    -- |            Cterm, Sterm, Chtok
 190
 191       Tok_Dot_Dot,         -- ..           Sterm, Chtok
 192
 193       --  The following three entries are used only when scanning project
 194       --  files.
 195
 196       Tok_Project,
 197       Tok_Extends,
 198       Tok_External,
 199       Tok_Comment,
 200
 201       --  The following entry is used by the preprocessor and when scanning
 202       --  project files.
 203
 204       Tok_End_Of_Line,
 205
 206       --  The following entry is used by the preprocessor
 207
 208       Tok_Special,
 209
 210       No_Token);
 211       --  No_Token is used for initializing Token values to indicate that
 212       --  no value has been set yet.
 213
 214    --  Note: in the RM, operator symbol is a special case of string literal.
 215    --  We distinguish at the lexical level in this compiler, since there are
 216    --  many syntactic situations in which only an operator symbol is allowed.
 217
 218    --  The following subtype declarations group the token types into classes.
 219    --  These are used for class tests in the parser.
 220
 221       subtype Token_Class_Numeric_Literal is
 222         Token_Type range Tok_Integer_Literal .. Tok_Real_Literal;
 223       --  Numeric literal
 224
 225       subtype Token_Class_Literal is
 226         Token_Type range Tok_Integer_Literal .. Tok_Operator_Symbol;
 227       --  Literal
 228
 229       subtype Token_Class_Lit_Or_Name is
 230         Token_Type range Tok_Integer_Literal .. Tok_Identifier;
 231
 232       subtype Token_Class_Binary_Addop is
 233         Token_Type range Tok_Ampersand .. Tok_Plus;
 234       --  Binary adding operator (& + -)
 235
 236       subtype Token_Class_Unary_Addop is
 237         Token_Type range Tok_Minus .. Tok_Plus;
 238       --  Unary adding operator (+ -)
 239
 240       subtype Token_Class_Mulop is
 241         Token_Type range Tok_Asterisk .. Tok_Slash;
 242       --  Multiplying operator
 243
 244       subtype Token_Class_Logop is
 245         Token_Type range Tok_And .. Tok_Xor;
 246       --  Logical operator (and, or, xor)
 247
 248       subtype Token_Class_Relop is
 249         Token_Type range Tok_Less .. Tok_Box;
 250       --  Relational operator (= /= < <= > >= not, in plus <> to catch misuse
 251       --  of Pascal style not equal operator).
 252
 253       subtype Token_Class_Name is
 254         Token_Type range Tok_Char_Literal .. Tok_Identifier;
 255       --  First token of name (4.1),
 256       --    (identifier, char literal, operator symbol)
 257
 258       subtype Token_Class_Desig is
 259         Token_Type range Tok_Operator_Symbol .. Tok_Identifier;
 260       --  Token which can be a Designator (identifier, operator symbol)
 261
 262       subtype Token_Class_Namext is
 263         Token_Type range Tok_Dot .. Tok_Left_Paren;
 264       --  Name extension tokens. These are tokens which can appear immediately
 265       --  after a name to extend it recursively (period, quote, left paren)
 266
 267       subtype Token_Class_Consk is
 268         Token_Type range Tok_Left_Paren .. Tok_Range;
 269       --  Keywords which can start constraint
 270       --    (left paren, delta, digits, range)
 271
 272       subtype Token_Class_Eterm is
 273         Token_Type range Tok_Colon_Equal .. Tok_Semicolon;
 274       --  Expression terminators. These tokens can never appear within a simple
 275       --  expression. This is used for error recovery purposes (if we encounter
 276       --  an error in an expression, we simply scan to the next Eterm token).
 277
 278       subtype Token_Class_Sterm is
 279         Token_Type range Tok_Delta .. Tok_Dot_Dot;
 280       --  Simple_Expression terminators. A Simple_Expression must be followed
 281       --  by a token in this class, or an error message is issued complaining
 282       --  about a missing binary operator.
 283
 284       subtype Token_Class_Atkwd is
 285         Token_Type range Tok_Delta .. Tok_Range;
 286       --  Attribute keywords. This class includes keywords which can be used
 287       --  as an Attribute_Designator, namely DELTA, DIGITS and RANGE
 288
 289       subtype Token_Class_Cterm is
 290         Token_Type range Tok_EOF .. Tok_Vertical_Bar;
 291       --  Choice terminators. These tokens terminate a choice. This is used for
 292       --  error recovery purposes (if we encounter an error in a Choice, we
 293       --  simply scan to the next Cterm token).
 294
 295       subtype Token_Class_Chtok is
 296         Token_Type range Tok_Arrow .. Tok_Dot_Dot;
 297       --  Choice tokens. These tokens signal a choice when used in an Aggregate
 298
 299       subtype Token_Class_Cunit is
 300         Token_Type range Tok_Function .. Tok_Separate;
 301       --  Tokens which can begin a compilation unit
 302
 303       subtype Token_Class_Declk is
 304         Token_Type range Tok_Entry .. Tok_Procedure;
 305       --  Keywords which start a declaration
 306
 307       subtype Token_Class_Deckn is
 308         Token_Type range Tok_Entry .. Tok_Use;
 309       --  Keywords which start a declaration but can't start a compilation unit
 310
 311       subtype Token_Class_After_SM is
 312         Token_Type range Tok_Less_Less .. Tok_EOF;
 313       --  Tokens which always, or almost always, appear after a semicolon. Used
 314       --  in the Resync_Past_Semicolon routine to avoid gobbling up stuff when
 315       --  a semicolon is missing. Of significance only for error recovery.
 316
 317       subtype Token_Class_Labeled_Stmt is
 318         Token_Type range Tok_Begin .. Tok_While;
 319       --  Tokens which start labeled statements
 320
 321       type Token_Flag_Array is array (Token_Type) of Boolean;
 322       Is_Reserved_Keyword : constant Token_Flag_Array := Token_Flag_Array'(
 323          Tok_Mod      .. Tok_Rem      => True,
 324          Tok_New      .. Tok_Null     => True,
 325          Tok_Delta    .. Tok_Range    => True,
 326          Tok_And      .. Tok_Xor      => True,
 327          Tok_In       .. Tok_Not      => True,
 328          Tok_Abstract .. Tok_Then     => True,
 329          Tok_Abort    .. Tok_Separate => True,
 330          others                       => False);
 331       --  Flag array used to test for reserved word
 332
 333    --------------------------
 334    -- Scan State Variables --
 335    --------------------------
 336
 337    --  Note: these variables can only be referenced during the parsing of a
 338    --  file. Reference to any of them from Sem or the expander is wrong.
 339
 340    Scan_Ptr : Source_Ptr;
 341    --  Current scan pointer location. After a call to Scan, this points
 342    --  just past the end of the token just scanned.
 343
 344    Token : Token_Type;
 345    --  Type of current token
 346
 347    Token_Ptr : Source_Ptr;
 348    --  Pointer to first character of current token
 349
 350    Current_Line_Start : Source_Ptr;
 351    --  Pointer to first character of line containing current token
 352
 353    Start_Column : Column_Number;
 354    --  Starting column number (zero origin) of the first non-blank character
 355    --  on the line containing the current token. This is used for error
 356    --  recovery circuits which depend on looking at the column line up.
 357
 358    Checksum : Word;
 359    --  Used to accumulate a CRC representing the tokens in the source
 360    --  file being compiled. This CRC includes only program tokens, and
 361    --  excludes comments.
 362
 363    First_Non_Blank_Location : Source_Ptr;
 364    --  Location of first non-blank character on the line containing the
 365    --  current token (i.e. the location of the character whose column number
 366    --  is stored in Start_Column).
 367
 368    Token_Node : Node_Id := Empty;
 369    --  Node table Id for the current token. This is set only if the current
 370    --  token is one for which the scanner constructs a node (i.e. it is an
 371    --  identifier, operator symbol, or literal. For other token types,
 372    --  Token_Node is undefined.
 373
 374    Token_Name : Name_Id := No_Name;
 375    --  For identifiers, this is set to the Name_Id of the identifier scanned.
 376    --  For all other tokens, Token_Name is set to Error_Name. Note that it
 377    --  would be possible for the caller to extract this information from
 378    --  Token_Node. We set Token_Name separately for two reasons. First it
 379    --  allows a quicker test for a specific identifier. Second, it allows
 380    --  a version of the parser to be built that does not build tree nodes,
 381    --  usable as a syntax checker.
 382
 383    Prev_Token : Token_Type := No_Token;
 384    --  Type of previous token
 385
 386    Prev_Token_Ptr : Source_Ptr;
 387    --  Pointer to first character of previous token
 388
 389    Version_To_Be_Found : Boolean;
 390    --  This flag is True if the scanner is still looking for an RCS version
 391    --  number in a comment. Normally it is initialized to False so that this
 392    --  circuit is not activated. If the -dv switch is set, then this flag is
 393    --  initialized to True, and then reset when the version number is found.
 394    --  We do things this way to minimize the impact on comment scanning.
 395
 396    Character_Code : Char_Code;
 397    --  Valid only when Token is Tok_Char_Literal.
 398
 399    Real_Literal_Value : Ureal;
 400    --  Valid only when Token is Tok_Real_Literal
 401
 402    Int_Literal_Value : Uint;
 403    --  Valid only when Token = Tok_Integer_Literal;
 404
 405    String_Literal_Id : String_Id;
 406    --  Id for currently scanned string value.
 407    --  Valid only when Token = Tok_String_Literal or Tok_Operator_Symbol.
 408
 409    Wide_Character_Found : Boolean := False;
 410    --  Set True if wide character found.
 411    --  Valid only when Token = Tok_String_Literal.
 412
 413    Special_Character : Character;
 414    --  Valid only when Token = Tok_Special
 415
 416    Comment_Id : Name_Id := No_Name;
 417    --  Valid only when Token = Tok_Comment. Store the string that follows
 418    --  the two '-' of a comment.
 419
 420    --------------------------------------------------------
 421    -- Procedures for Saving and Restoring the Scan State --
 422    --------------------------------------------------------
 423
 424    --  The following procedures can be used to save and restore the entire
 425    --  scan state. They are used in cases where it is necessary to backup
 426    --  the scan during the parse.
 427
 428    type Saved_Scan_State is private;
 429    --  Used for saving and restoring the scan state
 430
 431    procedure Save_Scan_State (Saved_State : out Saved_Scan_State);
 432    pragma Inline (Save_Scan_State);
 433    --  Saves the current scan state for possible later restoration. Note that
 434    --  there is no harm in saving the state and then never restoring it.
 435
 436    procedure Restore_Scan_State (Saved_State : in Saved_Scan_State);
 437    pragma Inline (Restore_Scan_State);
 438    --  Restores a scan state saved by a call to Save_Scan_State.
 439    --  The saved scan state must refer to the current source file.
 440
 441 private
 442    type Saved_Scan_State is record
 443       Save_Scan_Ptr                 : Source_Ptr;
 444       Save_Token                    : Token_Type;
 445       Save_Token_Ptr                : Source_Ptr;
 446       Save_Current_Line_Start       : Source_Ptr;
 447       Save_Start_Column             : Column_Number;
 448       Save_Checksum                 : Word;
 449       Save_First_Non_Blank_Location : Source_Ptr;
 450       Save_Token_Node               : Node_Id;
 451       Save_Token_Name               : Name_Id;
 452       Save_Prev_Token               : Token_Type;
 453       Save_Prev_Token_Ptr           : Source_Ptr;
 454    end record;
 455
 456 end Scans;