gcc/ada/s-valwch.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                     S Y S T E M . V A L _ W C H A R                      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-1997, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Val_Util; use System.Val_Util;
  35 with System.WCh_Con;  use System.WCh_Con;
  36 with System.WCh_StW;  use System.WCh_StW;
  37
  38 package body System.Val_WChar is
  39
  40    --------------------------
  41    -- Value_Wide_Character --
  42    --------------------------
  43
  44    function Value_Wide_Character
  45       (Str  : String;
  46        EM   : WC_Encoding_Method)
  47        return Wide_Character
  48    is
  49       F : Natural;
  50       L : Natural;
  51       S : String (Str'Range) := Str;
  52
  53    begin
  54       Normalize_String (S, F, L);
  55
  56       --  Character literal case
  57
  58       if S (F) = ''' and then S (L) = ''' then
  59
  60          --  If just three characters, simple character case
  61
  62          if L - F = 2 then
  63             return Wide_Character'Val (Character'Pos (S (F + 1)));
  64
  65          --  Otherwise must be a wide character in quotes. The easiest
  66          --  thing is to convert the string to a wide string and then
  67          --  pick up the single character that it should contain.
  68
  69          else
  70             declare
  71                WS : constant Wide_String :=
  72                       String_To_Wide_String (S (F + 1 .. L - 1), EM);
  73
  74             begin
  75                if WS'Length /= 1 then
  76                   raise Constraint_Error;
  77
  78                else
  79                   return WS (WS'First);
  80                end if;
  81             end;
  82          end if;
  83
  84       --  the last two values of the type have language-defined names:
  85
  86       elsif S = "FFFE" then
  87          return Wide_Character'Val (16#FFFE#);
  88
  89       elsif S = "FFFF" then
  90          return Wide_Character'Val (16#FFFF#);
  91
  92       --  Otherwise must be a control character
  93
  94       else
  95          for C in Character'Val (16#00#) .. Character'Val (16#1F#) loop
  96             if S (F .. L) = Character'Image (C) then
  97                return Wide_Character'Val (Character'Pos (C));
  98             end if;
  99          end loop;
 100
 101          for C in Character'Val (16#7F#) .. Character'Val (16#9F#) loop
 102             if S (F .. L) = Character'Image (C) then
 103                return Wide_Character'Val (Character'Pos (C));
 104             end if;
 105          end loop;
 106
 107          raise Constraint_Error;
 108       end if;
 109
 110    end Value_Wide_Character;
 111
 112 end System.Val_WChar;