gcc/ada/s-taspri-solaris.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                  GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                --
   4 --                                                                          --
   5 --                 S Y S T E M . T A S K _ P R I M I T I V E S              --
   6 --                                                                          --
   7 --                                  S p e c                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is a Solaris version of this package
  35
  36 --  This package provides low-level support for most tasking features
  37
  38 pragma Polling (Off);
  39 --  Turn off polling, we do not want ATC polling to take place during tasking
  40 --  operations. It causes infinite loops and other problems.
  41
  42 with Ada.Unchecked_Conversion;
  43
  44 with System.OS_Interface;
  45
  46 package System.Task_Primitives is
  47    pragma Preelaborate;
  48
  49    type Lock is limited private;
  50    type Lock_Ptr is access all Lock;
  51    --  Should be used for implementation of protected objects
  52
  53    type RTS_Lock is limited private;
  54    type RTS_Lock_Ptr is access all RTS_Lock;
  55    --  Should be used inside the runtime system. The difference between Lock
  56    --  and the RTS_Lock is that the later one serves only as a semaphore so
  57    --  that do not check for ceiling violations.
  58
  59    function To_Lock_Ptr is
  60      new Ada.Unchecked_Conversion (RTS_Lock_Ptr, Lock_Ptr);
  61
  62    type Suspension_Object is limited private;
  63    --  Should be used for the implementation of Ada.Synchronous_Task_Control
  64
  65    type Task_Body_Access is access procedure;
  66    --  Pointer to the task body's entry point (or possibly a wrapper
  67    --  declared local to the GNARL).
  68
  69    type Private_Data is limited private;
  70    --  Any information that the GNULLI needs maintained on a per-task basis.
  71    --  A component of this type is guaranteed to be included in the
  72    --  Ada_Task_Control_Block.
  73
  74    subtype Task_Address is System.Address;
  75    --  In some versions of Task_Primitives, notably for VMS, Task_Address is
  76    --  the short version of address defined in System.Aux_DEC. To avoid
  77    --  dragging Aux_DEC into tasking packages a tasking specific subtype is
  78    --  defined here.
  79
  80    Task_Address_Size : constant := Standard'Address_Size;
  81    --  The size of Task_Address
  82
  83    Alternate_Stack_Size : constant := 0;
  84    --  No alternate signal stack is used on this platform
  85
  86 private
  87
  88    type Private_Task_Serial_Number is mod 2 ** 64;
  89    --  Used to give each task a unique serial number
  90
  91    type Base_Lock is new System.OS_Interface.mutex_t;
  92
  93    type Owner_Int is new Integer;
  94    for Owner_Int'Alignment use Standard'Maximum_Alignment;
  95
  96    type Owner_ID is access all Owner_Int;
  97
  98    function To_Owner_ID is
  99      new Ada.Unchecked_Conversion (System.Address, Owner_ID);
 100
 101    type Lock is record
 102       L              : aliased Base_Lock;
 103       Ceiling        : System.Any_Priority := System.Any_Priority'First;
 104       Saved_Priority : System.Any_Priority :=  System.Any_Priority'First;
 105       Owner          : Owner_ID;
 106       Next           : Lock_Ptr;
 107       Level          : Private_Task_Serial_Number := 0;
 108       Buddy          : Owner_ID;
 109       Frozen         : Boolean := False;
 110    end record;
 111
 112    type RTS_Lock is new Lock;
 113
 114    type Suspension_Object is record
 115       State : Boolean;
 116       pragma Atomic (State);
 117       --  Boolean that indicates whether the object is open. This field is
 118       --  marked Atomic to ensure that we can read its value without locking
 119       --  the access to the Suspension_Object.
 120
 121       Waiting : Boolean;
 122       --  Flag showing if there is a task already suspended on this object
 123
 124       L : aliased System.OS_Interface.mutex_t;
 125       --  Protection for ensuring mutual exclusion on the Suspension_Object
 126
 127       CV : aliased System.OS_Interface.cond_t;
 128       --  Condition variable used to queue threads until condition is signaled
 129    end record;
 130
 131    --  Note that task support on gdb relies on the fact that the first two
 132    --  fields of Private_Data are Thread and LWP.
 133
 134    type Private_Data is record
 135       Thread : aliased System.OS_Interface.thread_t;
 136       pragma Atomic (Thread);
 137       --  Thread field may be updated by two different threads of control.
 138       --  (See, Enter_Task and Create_Task in s-taprop.adb). They put the same
 139       --  value (thr_self value). We do not want to use lock on those
 140       --  operations and the only thing we have to make sure is that they are
 141       --  updated in atomic fashion.
 142
 143       LWP : System.OS_Interface.lwpid_t;
 144       --  The LWP id of the thread. Set by self in Enter_Task
 145
 146       CV : aliased System.OS_Interface.cond_t;
 147       L  : aliased RTS_Lock;
 148       --  Protection for all components is lock L
 149
 150       Active_Priority : System.Any_Priority := System.Any_Priority'First;
 151       --  Simulated active priority, used iff Priority_Ceiling_Support is True
 152
 153       Locking : Lock_Ptr;
 154       Locks   : Lock_Ptr;
 155       Wakeups : Natural := 0;
 156    end record;
 157
 158 end System.Task_Primitives;