gcc/ada/s-taskin.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                        S Y S T E M . T A S K I N G                       --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 pragma Polling (Off);
  35 --  Turn off polling, we do not want ATC polling to take place during
  36 --  tasking operations. It causes infinite loops and other problems.
  37
  38 with System.Task_Primitives.Operations;
  39 --  used for Self
  40
  41 with System.Storage_Elements;
  42 --  Needed for initializing Stack_Info.Size
  43
  44 package body System.Tasking is
  45
  46    package STPO renames System.Task_Primitives.Operations;
  47
  48    ---------------------
  49    -- Detect_Blocking --
  50    ---------------------
  51
  52    function Detect_Blocking return Boolean is
  53       GL_Detect_Blocking : Integer;
  54       pragma Import (C, GL_Detect_Blocking, "__gl_detect_blocking");
  55       --  Global variable exported by the binder generated file.
  56       --  A value equal to 1 indicates that pragma Detect_Blocking is active,
  57       --  while 0 is used for the pragma not being present.
  58
  59    begin
  60       return GL_Detect_Blocking = 1;
  61    end Detect_Blocking;
  62
  63    ----------
  64    -- Self --
  65    ----------
  66
  67    function Self return Task_Id renames STPO.Self;
  68
  69    ---------------------
  70    -- Initialize_ATCB --
  71    ---------------------
  72
  73    procedure Initialize_ATCB
  74      (Self_ID          : Task_Id;
  75       Task_Entry_Point : Task_Procedure_Access;
  76       Task_Arg         : System.Address;
  77       Parent           : Task_Id;
  78       Elaborated       : Access_Boolean;
  79       Base_Priority    : System.Any_Priority;
  80       Task_Info        : System.Task_Info.Task_Info_Type;
  81       Stack_Size       : System.Parameters.Size_Type;
  82       T                : Task_Id;
  83       Success          : out Boolean) is
  84    begin
  85       T.Common.State := Unactivated;
  86
  87       --  Initialize T.Common.LL
  88
  89       STPO.Initialize_TCB (T, Success);
  90
  91       if not Success then
  92          return;
  93       end if;
  94
  95       T.Common.Parent := Parent;
  96       T.Common.Base_Priority := Base_Priority;
  97       T.Common.Current_Priority := 0;
  98       T.Common.Protected_Action_Nesting := 0;
  99       T.Common.Call := null;
 100       T.Common.Task_Arg := Task_Arg;
 101       T.Common.Task_Entry_Point := Task_Entry_Point;
 102       T.Common.Activator := Self_ID;
 103       T.Common.Wait_Count := 0;
 104       T.Common.Elaborated := Elaborated;
 105       T.Common.Activation_Failed := False;
 106       T.Common.Task_Info := Task_Info;
 107       T.Common.Global_Task_Lock_Nesting := 0;
 108       T.Common.Fall_Back_Handler := null;
 109       T.Common.Specific_Handler  := null;
 110
 111       if T.Common.Parent = null then
 112          --  For the environment task, the adjusted stack size is
 113          --  meaningless. For example, an unspecified Stack_Size means
 114          --  that the stack size is determined by the environment, or
 115          --  can grow dynamically. The Stack_Checking algorithm
 116          --  therefore needs to use the requested size, or 0 in
 117          --  case of an unknown size.
 118
 119          T.Common.Compiler_Data.Pri_Stack_Info.Size :=
 120             Storage_Elements.Storage_Offset (Stack_Size);
 121
 122       else
 123          T.Common.Compiler_Data.Pri_Stack_Info.Size :=
 124            Storage_Elements.Storage_Offset
 125              (Parameters.Adjust_Storage_Size (Stack_Size));
 126       end if;
 127
 128       --  Link the task into the list of all tasks
 129
 130       T.Common.All_Tasks_Link := All_Tasks_List;
 131       All_Tasks_List := T;
 132    end Initialize_ATCB;
 133
 134    ----------------
 135    -- Initialize --
 136    ----------------
 137
 138    Main_Task_Image : constant String := "main_task";
 139    --  Image of environment task
 140
 141    Main_Priority : Integer;
 142    pragma Import (C, Main_Priority, "__gl_main_priority");
 143    --  Priority for main task. Note that this is of type Integer, not
 144    --  Priority, because we use the value -1 to indicate the default
 145    --  main priority, and that is of course not in Priority'range.
 146
 147    Initialized : Boolean := False;
 148    --  Used to prevent multiple calls to Initialize
 149
 150    procedure Initialize is
 151       T             : Task_Id;
 152       Success       : Boolean;
 153       Base_Priority : Any_Priority;
 154
 155    begin
 156       if Initialized then
 157          return;
 158       end if;
 159
 160       Initialized := True;
 161
 162       --  Initialize Environment Task
 163
 164       if Main_Priority = Unspecified_Priority then
 165          Base_Priority := Default_Priority;
 166       else
 167          Base_Priority := Priority (Main_Priority);
 168       end if;
 169
 170       Success := True;
 171       T := STPO.New_ATCB (0);
 172       Initialize_ATCB
 173         (null, null, Null_Address, Null_Task, null, Base_Priority,
 174          Task_Info.Unspecified_Task_Info, 0, T, Success);
 175       pragma Assert (Success);
 176
 177       STPO.Initialize (T);
 178       STPO.Set_Priority (T, T.Common.Base_Priority);
 179       T.Common.State := Runnable;
 180       T.Common.Task_Image_Len := Main_Task_Image'Length;
 181       T.Common.Task_Image (Main_Task_Image'Range) := Main_Task_Image;
 182
 183       --  Only initialize the first element since others are not relevant
 184       --  in ravenscar mode. Rest of the initialization is done in Init_RTS.
 185
 186       T.Entry_Calls (1).Self := T;
 187    end Initialize;
 188
 189 end System.Tasking;