gcc/ada/s-taprop-mingw.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --     S Y S T E M . T A S K _ P R I M I T I V E S . O P E R A T I O N S    --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is a NT (native) version of this package
  33
  34 --  This package contains all the GNULL primitives that interface directly with
  35 --  the underlying OS.
  36
  37 pragma Polling (Off);
  38 --  Turn off polling, we do not want ATC polling to take place during tasking
  39 --  operations. It causes infinite loops and other problems.
  40
  41 with Ada.Unchecked_Deallocation;
  42
  43 with Interfaces.C;
  44 with Interfaces.C.Strings;
  45
  46 with System.Multiprocessors;
  47 with System.Tasking.Debug;
  48 with System.OS_Primitives;
  49 with System.Task_Info;
  50 with System.Interrupt_Management;
  51 with System.Win32.Ext;
  52
  53 with System.Soft_Links;
  54 --  We use System.Soft_Links instead of System.Tasking.Initialization because
  55 --  the later is a higher level package that we shouldn't depend on. For
  56 --  example when using the restricted run time, it is replaced by
  57 --  System.Tasking.Restricted.Stages.
  58
  59 package body System.Task_Primitives.Operations is
  60
  61    package SSL renames System.Soft_Links;
  62
  63    use System.Tasking.Debug;
  64    use System.Tasking;
  65    use Interfaces.C;
  66    use Interfaces.C.Strings;
  67    use System.OS_Interface;
  68    use System.Parameters;
  69    use System.OS_Primitives;
  70    use System.Task_Info;
  71    use System.Win32;
  72    use System.Win32.Ext;
  73
  74    pragma Link_With ("-Xlinker --stack=0x200000,0x1000");
  75    --  Change the default stack size (2 MB) for tasking programs on Windows.
  76    --  This allows about 1000 tasks running at the same time. Note that
  77    --  we set the stack size for non tasking programs on System unit.
  78    --  Also note that under Windows XP, we use a Windows XP extension to
  79    --  specify the stack size on a per task basis, as done under other OSes.
  80
  81    ---------------------
  82    -- Local Functions --
  83    ---------------------
  84
  85    procedure InitializeCriticalSection (pCriticalSection : access RTS_Lock);
  86    procedure InitializeCriticalSection
  87      (pCriticalSection : access CRITICAL_SECTION);
  88    pragma Import
  89      (Stdcall, InitializeCriticalSection, "InitializeCriticalSection");
  90
  91    procedure EnterCriticalSection (pCriticalSection : access RTS_Lock);
  92    procedure EnterCriticalSection
  93      (pCriticalSection : access CRITICAL_SECTION);
  94    pragma Import (Stdcall, EnterCriticalSection, "EnterCriticalSection");
  95
  96    procedure LeaveCriticalSection (pCriticalSection : access RTS_Lock);
  97    procedure LeaveCriticalSection (pCriticalSection : access CRITICAL_SECTION);
  98    pragma Import (Stdcall, LeaveCriticalSection, "LeaveCriticalSection");
  99
 100    procedure DeleteCriticalSection (pCriticalSection : access RTS_Lock);
 101    procedure DeleteCriticalSection
 102      (pCriticalSection : access CRITICAL_SECTION);
 103    pragma Import (Stdcall, DeleteCriticalSection, "DeleteCriticalSection");
 104
 105    ----------------
 106    -- Local Data --
 107    ----------------
 108
 109    Environment_Task_Id : Task_Id;
 110    --  A variable to hold Task_Id for the environment task
 111
 112    Single_RTS_Lock : aliased RTS_Lock;
 113    --  This is a lock to allow only one thread of control in the RTS at
 114    --  a time; it is used to execute in mutual exclusion from all other tasks.
 115    --  Used mainly in Single_Lock mode, but also to protect All_Tasks_List
 116
 117    Time_Slice_Val : Integer;
 118    pragma Import (C, Time_Slice_Val, "__gl_time_slice_val");
 119
 120    Dispatching_Policy : Character;
 121    pragma Import (C, Dispatching_Policy, "__gl_task_dispatching_policy");
 122
 123    function Get_Policy (Prio : System.Any_Priority) return Character;
 124    pragma Import (C, Get_Policy, "__gnat_get_specific_dispatching");
 125    --  Get priority specific dispatching policy
 126
 127    Foreign_Task_Elaborated : aliased Boolean := True;
 128    --  Used to identified fake tasks (i.e., non-Ada Threads)
 129
 130    Annex_D : Boolean := False;
 131    --  Set to True if running with Annex-D semantics
 132
 133    ------------------------------------
 134    -- The thread local storage index --
 135    ------------------------------------
 136
 137    TlsIndex : DWORD;
 138    pragma Export (Ada, TlsIndex);
 139    --  To ensure that this variable won't be local to this package, since
 140    --  in some cases, inlining forces this variable to be global anyway.
 141
 142    --------------------
 143    -- Local Packages --
 144    --------------------
 145
 146    package Specific is
 147
 148       function Is_Valid_Task return Boolean;
 149       pragma Inline (Is_Valid_Task);
 150       --  Does executing thread have a TCB?
 151
 152       procedure Set (Self_Id : Task_Id);
 153       pragma Inline (Set);
 154       --  Set the self id for the current task
 155
 156    end Specific;
 157
 158    package body Specific is
 159
 160       function Is_Valid_Task return Boolean is
 161       begin
 162          return TlsGetValue (TlsIndex) /= System.Null_Address;
 163       end Is_Valid_Task;
 164
 165       procedure Set (Self_Id : Task_Id) is
 166          Succeeded : BOOL;
 167       begin
 168          Succeeded := TlsSetValue (TlsIndex, To_Address (Self_Id));
 169          pragma Assert (Succeeded = Win32.TRUE);
 170       end Set;
 171
 172    end Specific;
 173
 174    ---------------------------------
 175    -- Support for foreign threads --
 176    ---------------------------------
 177
 178    function Register_Foreign_Thread (Thread : Thread_Id) return Task_Id;
 179    --  Allocate and Initialize a new ATCB for the current Thread
 180
 181    function Register_Foreign_Thread
 182      (Thread : Thread_Id) return Task_Id is separate;
 183
 184    ----------------------------------
 185    -- Condition Variable Functions --
 186    ----------------------------------
 187
 188    procedure Initialize_Cond (Cond : not null access Condition_Variable);
 189    --  Initialize given condition variable Cond
 190
 191    procedure Finalize_Cond (Cond : not null access Condition_Variable);
 192    --  Finalize given condition variable Cond
 193
 194    procedure Cond_Signal (Cond : not null access Condition_Variable);
 195    --  Signal condition variable Cond
 196
 197    procedure Cond_Wait
 198      (Cond : not null access Condition_Variable;
 199       L    : not null access RTS_Lock);
 200    --  Wait on conditional variable Cond, using lock L
 201
 202    procedure Cond_Timed_Wait
 203      (Cond      : not null access Condition_Variable;
 204       L         : not null access RTS_Lock;
 205       Rel_Time  : Duration;
 206       Timed_Out : out Boolean;
 207       Status    : out Integer);
 208    --  Do timed wait on condition variable Cond using lock L. The duration
 209    --  of the timed wait is given by Rel_Time. When the condition is
 210    --  signalled, Timed_Out shows whether or not a time out occurred.
 211    --  Status is only valid if Timed_Out is False, in which case it
 212    --  shows whether Cond_Timed_Wait completed successfully.
 213
 214    ---------------------
 215    -- Initialize_Cond --
 216    ---------------------
 217
 218    procedure Initialize_Cond (Cond : not null access Condition_Variable) is
 219       hEvent : HANDLE;
 220    begin
 221       hEvent := CreateEvent (null, Win32.TRUE, Win32.FALSE, Null_Ptr);
 222       pragma Assert (hEvent /= 0);
 223       Cond.all := Condition_Variable (hEvent);
 224    end Initialize_Cond;
 225
 226    -------------------
 227    -- Finalize_Cond --
 228    -------------------
 229
 230    --  No such problem here, DosCloseEventSem has been derived.
 231    --  What does such refer to in above comment???
 232
 233    procedure Finalize_Cond (Cond : not null access Condition_Variable) is
 234       Result : BOOL;
 235    begin
 236       Result := CloseHandle (HANDLE (Cond.all));
 237       pragma Assert (Result = Win32.TRUE);
 238    end Finalize_Cond;
 239
 240    -----------------
 241    -- Cond_Signal --
 242    -----------------
 243
 244    procedure Cond_Signal (Cond : not null access Condition_Variable) is
 245       Result : BOOL;
 246    begin
 247       Result := SetEvent (HANDLE (Cond.all));
 248       pragma Assert (Result = Win32.TRUE);
 249    end Cond_Signal;
 250
 251    ---------------
 252    -- Cond_Wait --
 253    ---------------
 254
 255    --  Pre-condition: Cond is posted
 256    --                 L is locked.
 257
 258    --  Post-condition: Cond is posted
 259    --                  L is locked.
 260
 261    procedure Cond_Wait
 262      (Cond : not null access Condition_Variable;
 263       L    : not null access RTS_Lock)
 264    is
 265       Result      : DWORD;
 266       Result_Bool : BOOL;
 267
 268    begin
 269       --  Must reset Cond BEFORE L is unlocked
 270
 271       Result_Bool := ResetEvent (HANDLE (Cond.all));
 272       pragma Assert (Result_Bool = Win32.TRUE);
 273       Unlock (L, Global_Lock => True);
 274
 275       --  No problem if we are interrupted here: if the condition is signaled,
 276       --  WaitForSingleObject will simply not block
 277
 278       Result := WaitForSingleObject (HANDLE (Cond.all), Wait_Infinite);
 279       pragma Assert (Result = 0);
 280
 281       Write_Lock (L, Global_Lock => True);
 282    end Cond_Wait;
 283
 284    ---------------------
 285    -- Cond_Timed_Wait --
 286    ---------------------
 287
 288    --  Pre-condition: Cond is posted
 289    --                 L is locked.
 290
 291    --  Post-condition: Cond is posted
 292    --                  L is locked.
 293
 294    procedure Cond_Timed_Wait
 295      (Cond      : not null access Condition_Variable;
 296       L         : not null access RTS_Lock;
 297       Rel_Time  : Duration;
 298       Timed_Out : out Boolean;
 299       Status    : out Integer)
 300    is
 301       Time_Out_Max : constant DWORD := 16#FFFF0000#;
 302       --  NT 4 can't handle excessive timeout values (e.g. DWORD'Last - 1)
 303
 304       Time_Out    : DWORD;
 305       Result      : BOOL;
 306       Wait_Result : DWORD;
 307
 308    begin
 309       --  Must reset Cond BEFORE L is unlocked
 310
 311       Result := ResetEvent (HANDLE (Cond.all));
 312       pragma Assert (Result = Win32.TRUE);
 313       Unlock (L, Global_Lock => True);
 314
 315       --  No problem if we are interrupted here: if the condition is signaled,
 316       --  WaitForSingleObject will simply not block.
 317
 318       if Rel_Time <= 0.0 then
 319          Timed_Out := True;
 320          Wait_Result := 0;
 321
 322       else
 323          Time_Out :=
 324            (if Rel_Time >= Duration (Time_Out_Max) / 1000
 325             then Time_Out_Max
 326             else DWORD (Rel_Time * 1000));
 327
 328          Wait_Result := WaitForSingleObject (HANDLE (Cond.all), Time_Out);
 329
 330          if Wait_Result = WAIT_TIMEOUT then
 331             Timed_Out := True;
 332             Wait_Result := 0;
 333          else
 334             Timed_Out := False;
 335          end if;
 336       end if;
 337
 338       Write_Lock (L, Global_Lock => True);
 339
 340       --  Ensure post-condition
 341
 342       if Timed_Out then
 343          Result := SetEvent (HANDLE (Cond.all));
 344          pragma Assert (Result = Win32.TRUE);
 345       end if;
 346
 347       Status := Integer (Wait_Result);
 348    end Cond_Timed_Wait;
 349
 350    ------------------
 351    -- Stack_Guard  --
 352    ------------------
 353
 354    --  The underlying thread system sets a guard page at the bottom of a thread
 355    --  stack, so nothing is needed.
 356    --  ??? Check the comment above
 357
 358    procedure Stack_Guard (T : ST.Task_Id; On : Boolean) is
 359       pragma Unreferenced (T, On);
 360    begin
 361       null;
 362    end Stack_Guard;
 363
 364    --------------------
 365    -- Get_Thread_Id  --
 366    --------------------
 367
 368    function Get_Thread_Id (T : ST.Task_Id) return OSI.Thread_Id is
 369    begin
 370       return T.Common.LL.Thread;
 371    end Get_Thread_Id;
 372
 373    ----------
 374    -- Self --
 375    ----------
 376
 377    function Self return Task_Id is
 378       Self_Id : constant Task_Id := To_Task_Id (TlsGetValue (TlsIndex));
 379    begin
 380       if Self_Id = null then
 381          return Register_Foreign_Thread (GetCurrentThread);
 382       else
 383          return Self_Id;
 384       end if;
 385    end Self;
 386
 387    ---------------------
 388    -- Initialize_Lock --
 389    ---------------------
 390
 391    --  Note: mutexes and cond_variables needed per-task basis are initialized
 392    --  in Initialize_TCB and the Storage_Error is handled. Other mutexes (such
 393    --  as RTS_Lock, Memory_Lock...) used in the RTS is initialized before any
 394    --  status change of RTS. Therefore raising Storage_Error in the following
 395    --  routines should be able to be handled safely.
 396
 397    procedure Initialize_Lock
 398      (Prio : System.Any_Priority;
 399       L    : not null access Lock)
 400    is
 401    begin
 402       InitializeCriticalSection (L.Mutex'Access);
 403       L.Owner_Priority := 0;
 404       L.Priority := Prio;
 405    end Initialize_Lock;
 406
 407    procedure Initialize_Lock
 408      (L : not null access RTS_Lock; Level : Lock_Level)
 409    is
 410       pragma Unreferenced (Level);
 411    begin
 412       InitializeCriticalSection (L);
 413    end Initialize_Lock;
 414
 415    -------------------
 416    -- Finalize_Lock --
 417    -------------------
 418
 419    procedure Finalize_Lock (L : not null access Lock) is
 420    begin
 421       DeleteCriticalSection (L.Mutex'Access);
 422    end Finalize_Lock;
 423
 424    procedure Finalize_Lock (L : not null access RTS_Lock) is
 425    begin
 426       DeleteCriticalSection (L);
 427    end Finalize_Lock;
 428
 429    ----------------
 430    -- Write_Lock --
 431    ----------------
 432
 433    procedure Write_Lock
 434      (L : not null access Lock; Ceiling_Violation : out Boolean) is
 435    begin
 436       L.Owner_Priority := Get_Priority (Self);
 437
 438       if L.Priority < L.Owner_Priority then
 439          Ceiling_Violation := True;
 440          return;
 441       end if;
 442
 443       EnterCriticalSection (L.Mutex'Access);
 444
 445       Ceiling_Violation := False;
 446    end Write_Lock;
 447
 448    procedure Write_Lock
 449      (L           : not null access RTS_Lock;
 450       Global_Lock : Boolean := False)
 451    is
 452    begin
 453       if not Single_Lock or else Global_Lock then
 454          EnterCriticalSection (L);
 455       end if;
 456    end Write_Lock;
 457
 458    procedure Write_Lock (T : Task_Id) is
 459    begin
 460       if not Single_Lock then
 461          EnterCriticalSection (T.Common.LL.L'Access);
 462       end if;
 463    end Write_Lock;
 464
 465    ---------------
 466    -- Read_Lock --
 467    ---------------
 468
 469    procedure Read_Lock
 470      (L : not null access Lock; Ceiling_Violation : out Boolean) is
 471    begin
 472       Write_Lock (L, Ceiling_Violation);
 473    end Read_Lock;
 474
 475    ------------
 476    -- Unlock --
 477    ------------
 478
 479    procedure Unlock (L : not null access Lock) is
 480    begin
 481       LeaveCriticalSection (L.Mutex'Access);
 482    end Unlock;
 483
 484    procedure Unlock
 485      (L : not null access RTS_Lock; Global_Lock : Boolean := False) is
 486    begin
 487       if not Single_Lock or else Global_Lock then
 488          LeaveCriticalSection (L);
 489       end if;
 490    end Unlock;
 491
 492    procedure Unlock (T : Task_Id) is
 493    begin
 494       if not Single_Lock then
 495          LeaveCriticalSection (T.Common.LL.L'Access);
 496       end if;
 497    end Unlock;
 498
 499    -----------------
 500    -- Set_Ceiling --
 501    -----------------
 502
 503    --  Dynamic priority ceilings are not supported by the underlying system
 504
 505    procedure Set_Ceiling
 506      (L    : not null access Lock;
 507       Prio : System.Any_Priority)
 508    is
 509       pragma Unreferenced (L, Prio);
 510    begin
 511       null;
 512    end Set_Ceiling;
 513
 514    -----------
 515    -- Sleep --
 516    -----------
 517
 518    procedure Sleep
 519      (Self_ID : Task_Id;
 520       Reason  : System.Tasking.Task_States)
 521    is
 522       pragma Unreferenced (Reason);
 523
 524    begin
 525       pragma Assert (Self_ID = Self);
 526
 527       if Single_Lock then
 528          Cond_Wait (Self_ID.Common.LL.CV'Access, Single_RTS_Lock'Access);
 529       else
 530          Cond_Wait (Self_ID.Common.LL.CV'Access, Self_ID.Common.LL.L'Access);
 531       end if;
 532
 533       if Self_ID.Deferral_Level = 0
 534         and then Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level
 535       then
 536          Unlock (Self_ID);
 537          raise Standard'Abort_Signal;
 538       end if;
 539    end Sleep;
 540
 541    -----------------
 542    -- Timed_Sleep --
 543    -----------------
 544
 545    --  This is for use within the run-time system, so abort is assumed to be
 546    --  already deferred, and the caller should be holding its own ATCB lock.
 547
 548    procedure Timed_Sleep
 549      (Self_ID  : Task_Id;
 550       Time     : Duration;
 551       Mode     : ST.Delay_Modes;
 552       Reason   : System.Tasking.Task_States;
 553       Timedout : out Boolean;
 554       Yielded  : out Boolean)
 555    is
 556       pragma Unreferenced (Reason);
 557       Check_Time : Duration := Monotonic_Clock;
 558       Rel_Time   : Duration;
 559       Abs_Time   : Duration;
 560
 561       Result : Integer;
 562       pragma Unreferenced (Result);
 563
 564       Local_Timedout : Boolean;
 565
 566    begin
 567       Timedout := True;
 568       Yielded  := False;
 569
 570       if Mode = Relative then
 571          Rel_Time := Time;
 572          Abs_Time := Duration'Min (Time, Max_Sensible_Delay) + Check_Time;
 573       else
 574          Rel_Time := Time - Check_Time;
 575          Abs_Time := Time;
 576       end if;
 577
 578       if Rel_Time > 0.0 then
 579          loop
 580             exit when Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level;
 581
 582             if Single_Lock then
 583                Cond_Timed_Wait
 584                  (Self_ID.Common.LL.CV'Access,
 585                   Single_RTS_Lock'Access,
 586                   Rel_Time, Local_Timedout, Result);
 587             else
 588                Cond_Timed_Wait
 589                  (Self_ID.Common.LL.CV'Access,
 590                   Self_ID.Common.LL.L'Access,
 591                   Rel_Time, Local_Timedout, Result);
 592             end if;
 593
 594             Check_Time := Monotonic_Clock;
 595             exit when Abs_Time <= Check_Time;
 596
 597             if not Local_Timedout then
 598
 599                --  Somebody may have called Wakeup for us
 600
 601                Timedout := False;
 602                exit;
 603             end if;
 604
 605             Rel_Time := Abs_Time - Check_Time;
 606          end loop;
 607       end if;
 608    end Timed_Sleep;
 609
 610    -----------------
 611    -- Timed_Delay --
 612    -----------------
 613
 614    procedure Timed_Delay
 615      (Self_ID : Task_Id;
 616       Time    : Duration;
 617       Mode    : ST.Delay_Modes)
 618    is
 619       Check_Time : Duration := Monotonic_Clock;
 620       Rel_Time   : Duration;
 621       Abs_Time   : Duration;
 622
 623       Timedout : Boolean;
 624       Result   : Integer;
 625       pragma Unreferenced (Timedout, Result);
 626
 627    begin
 628       if Single_Lock then
 629          Lock_RTS;
 630       end if;
 631
 632       Write_Lock (Self_ID);
 633
 634       if Mode = Relative then
 635          Rel_Time := Time;
 636          Abs_Time := Time + Check_Time;
 637       else
 638          Rel_Time := Time - Check_Time;
 639          Abs_Time := Time;
 640       end if;
 641
 642       if Rel_Time > 0.0 then
 643          Self_ID.Common.State := Delay_Sleep;
 644
 645          loop
 646             exit when Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level;
 647
 648             if Single_Lock then
 649                Cond_Timed_Wait
 650                  (Self_ID.Common.LL.CV'Access,
 651                   Single_RTS_Lock'Access,
 652                   Rel_Time, Timedout, Result);
 653             else
 654                Cond_Timed_Wait
 655                  (Self_ID.Common.LL.CV'Access,
 656                   Self_ID.Common.LL.L'Access,
 657                   Rel_Time, Timedout, Result);
 658             end if;
 659
 660             Check_Time := Monotonic_Clock;
 661             exit when Abs_Time <= Check_Time;
 662
 663             Rel_Time := Abs_Time - Check_Time;
 664          end loop;
 665
 666          Self_ID.Common.State := Runnable;
 667       end if;
 668
 669       Unlock (Self_ID);
 670
 671       if Single_Lock then
 672          Unlock_RTS;
 673       end if;
 674
 675       Yield;
 676    end Timed_Delay;
 677
 678    ------------
 679    -- Wakeup --
 680    ------------
 681
 682    procedure Wakeup (T : Task_Id; Reason : System.Tasking.Task_States) is
 683       pragma Unreferenced (Reason);
 684    begin
 685       Cond_Signal (T.Common.LL.CV'Access);
 686    end Wakeup;
 687
 688    -----------
 689    -- Yield --
 690    -----------
 691
 692    procedure Yield (Do_Yield : Boolean := True) is
 693    begin
 694       if Do_Yield then
 695          SwitchToThread;
 696
 697       elsif Annex_D then
 698          --  If running with Annex-D semantics we need a delay
 699          --  above 0 milliseconds here otherwise processes give
 700          --  enough time to the other tasks to have a chance to
 701          --  run.
 702          --
 703          --  This makes cxd8002 ACATS pass on Windows.
 704
 705          Sleep (1);
 706       end if;
 707    end Yield;
 708
 709    ------------------
 710    -- Set_Priority --
 711    ------------------
 712
 713    type Prio_Array_Type is array (System.Any_Priority) of Integer;
 714    pragma Atomic_Components (Prio_Array_Type);
 715
 716    Prio_Array : Prio_Array_Type;
 717    --  Global array containing the id of the currently running task for
 718    --  each priority.
 719    --
 720    --  Note: we assume that we are on a single processor with run-til-blocked
 721    --  scheduling.
 722
 723    procedure Set_Priority
 724      (T                   : Task_Id;
 725       Prio                : System.Any_Priority;
 726       Loss_Of_Inheritance : Boolean := False)
 727    is
 728       Res        : BOOL;
 729       Array_Item : Integer;
 730
 731    begin
 732       Res := SetThreadPriority
 733         (T.Common.LL.Thread, Interfaces.C.int (Underlying_Priorities (Prio)));
 734       pragma Assert (Res = Win32.TRUE);
 735
 736       if Dispatching_Policy = 'F' or else Get_Policy (Prio) = 'F' then
 737
 738          --  Annex D requirement [RM D.2.2 par. 9]:
 739          --    If the task drops its priority due to the loss of inherited
 740          --    priority, it is added at the head of the ready queue for its
 741          --    new active priority.
 742
 743          if Loss_Of_Inheritance
 744            and then Prio < T.Common.Current_Priority
 745          then
 746             Array_Item := Prio_Array (T.Common.Base_Priority) + 1;
 747             Prio_Array (T.Common.Base_Priority) := Array_Item;
 748
 749             loop
 750                --  Let some processes a chance to arrive
 751
 752                Yield;
 753
 754                --  Then wait for our turn to proceed
 755
 756                exit when Array_Item = Prio_Array (T.Common.Base_Priority)
 757                  or else Prio_Array (T.Common.Base_Priority) = 1;
 758             end loop;
 759
 760             Prio_Array (T.Common.Base_Priority) :=
 761               Prio_Array (T.Common.Base_Priority) - 1;
 762          end if;
 763       end if;
 764
 765       T.Common.Current_Priority := Prio;
 766    end Set_Priority;
 767
 768    ------------------
 769    -- Get_Priority --
 770    ------------------
 771
 772    function Get_Priority (T : Task_Id) return System.Any_Priority is
 773    begin
 774       return T.Common.Current_Priority;
 775    end Get_Priority;
 776
 777    ----------------
 778    -- Enter_Task --
 779    ----------------
 780
 781    --  There were two paths were we needed to call Enter_Task :
 782    --  1) from System.Task_Primitives.Operations.Initialize
 783    --  2) from System.Tasking.Stages.Task_Wrapper
 784
 785    --  The thread initialisation has to be done only for the first case
 786
 787    --  This is because the GetCurrentThread NT call does not return the real
 788    --  thread handler but only a "pseudo" one. It is not possible to release
 789    --  the thread handle and free the system resources from this "pseudo"
 790    --  handle. So we really want to keep the real thread handle set in
 791    --  System.Task_Primitives.Operations.Create_Task during thread creation.
 792
 793    procedure Enter_Task (Self_ID : Task_Id) is
 794       procedure Init_Float;
 795       pragma Import (C, Init_Float, "__gnat_init_float");
 796       --  Properly initializes the FPU for x86 systems
 797
 798       procedure Get_Stack_Bounds (Base : Address; Limit : Address);
 799       pragma Import (C, Get_Stack_Bounds, "__gnat_get_stack_bounds");
 800       --  Get stack boundaries
 801    begin
 802       Specific.Set (Self_ID);
 803       Init_Float;
 804
 805       if Self_ID.Common.Task_Info /= null
 806         and then
 807           Self_ID.Common.Task_Info.CPU >= CPU_Number (Number_Of_Processors)
 808       then
 809          raise Invalid_CPU_Number;
 810       end if;
 811
 812       Self_ID.Common.LL.Thread_Id := GetCurrentThreadId;
 813
 814       Get_Stack_Bounds
 815         (Self_ID.Common.Compiler_Data.Pri_Stack_Info.Base'Address,
 816          Self_ID.Common.Compiler_Data.Pri_Stack_Info.Limit'Address);
 817    end Enter_Task;
 818
 819    --------------
 820    -- New_ATCB --
 821    --------------
 822
 823    function New_ATCB (Entry_Num : Task_Entry_Index) return Task_Id is
 824    begin
 825       return new Ada_Task_Control_Block (Entry_Num);
 826    end New_ATCB;
 827
 828    -------------------
 829    -- Is_Valid_Task --
 830    -------------------
 831
 832    function Is_Valid_Task return Boolean renames Specific.Is_Valid_Task;
 833
 834    -----------------------------
 835    -- Register_Foreign_Thread --
 836    -----------------------------
 837
 838    function Register_Foreign_Thread return Task_Id is
 839    begin
 840       if Is_Valid_Task then
 841          return Self;
 842       else
 843          return Register_Foreign_Thread (GetCurrentThread);
 844       end if;
 845    end Register_Foreign_Thread;
 846
 847    --------------------
 848    -- Initialize_TCB --
 849    --------------------
 850
 851    procedure Initialize_TCB (Self_ID : Task_Id; Succeeded : out Boolean) is
 852    begin
 853       --  Initialize thread ID to 0, this is needed to detect threads that
 854       --  are not yet activated.
 855
 856       Self_ID.Common.LL.Thread := 0;
 857
 858       Initialize_Cond (Self_ID.Common.LL.CV'Access);
 859
 860       if not Single_Lock then
 861          Initialize_Lock (Self_ID.Common.LL.L'Access, ATCB_Level);
 862       end if;
 863
 864       Succeeded := True;
 865    end Initialize_TCB;
 866
 867    -----------------
 868    -- Create_Task --
 869    -----------------
 870
 871    procedure Create_Task
 872      (T          : Task_Id;
 873       Wrapper    : System.Address;
 874       Stack_Size : System.Parameters.Size_Type;
 875       Priority   : System.Any_Priority;
 876       Succeeded  : out Boolean)
 877    is
 878       Initial_Stack_Size : constant := 1024;
 879       --  We set the initial stack size to 1024. On Windows version prior to XP
 880       --  there is no way to fix a task stack size. Only the initial stack size
 881       --  can be set, the operating system will raise the task stack size if
 882       --  needed.
 883
 884       function Is_Windows_XP return Integer;
 885       pragma Import (C, Is_Windows_XP, "__gnat_is_windows_xp");
 886       --  Returns 1 if running on Windows XP
 887
 888       hTask          : HANDLE;
 889       TaskId         : aliased DWORD;
 890       pTaskParameter : Win32.PVOID;
 891       Result         : DWORD;
 892       Entry_Point    : PTHREAD_START_ROUTINE;
 893
 894       use type System.Multiprocessors.CPU_Range;
 895
 896    begin
 897       pTaskParameter := To_Address (T);
 898
 899       Entry_Point := To_PTHREAD_START_ROUTINE (Wrapper);
 900
 901       if Is_Windows_XP = 1 then
 902          hTask := CreateThread
 903            (null,
 904             DWORD (Stack_Size),
 905             Entry_Point,
 906             pTaskParameter,
 907             DWORD (Create_Suspended) or
 908               DWORD (Stack_Size_Param_Is_A_Reservation),
 909             TaskId'Unchecked_Access);
 910       else
 911          hTask := CreateThread
 912            (null,
 913             Initial_Stack_Size,
 914             Entry_Point,
 915             pTaskParameter,
 916             DWORD (Create_Suspended),
 917             TaskId'Unchecked_Access);
 918       end if;
 919
 920       --  Step 1: Create the thread in blocked mode
 921
 922       if hTask = 0 then
 923          Succeeded := False;
 924          return;
 925       end if;
 926
 927       --  Step 2: set its TCB
 928
 929       T.Common.LL.Thread := hTask;
 930
 931       --  Note: it would be useful to initialize Thread_Id right away to avoid
 932       --  a race condition in gdb where Thread_ID may not have the right value
 933       --  yet, but GetThreadId is a Vista specific API, not available under XP:
 934       --  T.Common.LL.Thread_Id := GetThreadId (hTask); so instead we set the
 935       --  field to 0 to avoid having a random value. Thread_Id is initialized
 936       --  in Enter_Task anyway.
 937
 938       T.Common.LL.Thread_Id := 0;
 939
 940       --  Step 3: set its priority (child has inherited priority from parent)
 941
 942       Set_Priority (T, Priority);
 943
 944       if Time_Slice_Val = 0
 945         or else Dispatching_Policy = 'F'
 946         or else Get_Policy (Priority) = 'F'
 947       then
 948          --  Here we need Annex D semantics so we disable the NT priority
 949          --  boost. A priority boost is temporarily given by the system to
 950          --  a thread when it is taken out of a wait state.
 951
 952          SetThreadPriorityBoost (hTask, DisablePriorityBoost => Win32.TRUE);
 953       end if;
 954
 955       --  Step 4: Handle pragma CPU and Task_Info
 956
 957       if T.Common.Base_CPU /= System.Multiprocessors.Not_A_Specific_CPU then
 958
 959          --  The CPU numbering in pragma CPU starts at 1 while the subprogram
 960          --  to set the affinity starts at 0, therefore we must substract 1.
 961
 962          Result := SetThreadIdealProcessor
 963            (hTask, ProcessorId (T.Common.Base_CPU) - 1);
 964          pragma Assert (Result = 1);
 965
 966       elsif T.Common.Task_Info /= null then
 967          if T.Common.Task_Info.CPU /= Task_Info.Any_CPU then
 968             Result := SetThreadIdealProcessor (hTask, T.Common.Task_Info.CPU);
 969             pragma Assert (Result = 1);
 970          end if;
 971       end if;
 972
 973       --  Step 5: Now, start it for good
 974
 975       Result := ResumeThread (hTask);
 976       pragma Assert (Result = 1);
 977
 978       Succeeded := Result = 1;
 979    end Create_Task;
 980
 981    ------------------
 982    -- Finalize_TCB --
 983    ------------------
 984
 985    procedure Finalize_TCB (T : Task_Id) is
 986       Self_ID   : Task_Id := T;
 987       Result    : DWORD;
 988       Succeeded : BOOL;
 989       Is_Self   : constant Boolean := T = Self;
 990
 991       procedure Free is new
 992         Ada.Unchecked_Deallocation (Ada_Task_Control_Block, Task_Id);
 993
 994    begin
 995       if not Single_Lock then
 996          Finalize_Lock (T.Common.LL.L'Access);
 997       end if;
 998
 999       Finalize_Cond (T.Common.LL.CV'Access);
1000
1001       if T.Known_Tasks_Index /= -1 then
1002          Known_Tasks (T.Known_Tasks_Index) := null;
1003       end if;
1004
1005       if Self_ID.Common.LL.Thread /= 0 then
1006
1007          --  This task has been activated. Wait for the thread to terminate
1008          --  then close it. This is needed to release system resources.
1009
1010          Result := WaitForSingleObject (T.Common.LL.Thread, Wait_Infinite);
1011          pragma Assert (Result /= WAIT_FAILED);
1012          Succeeded := CloseHandle (T.Common.LL.Thread);
1013          pragma Assert (Succeeded = Win32.TRUE);
1014       end if;
1015
1016       Free (Self_ID);
1017
1018       if Is_Self then
1019          Specific.Set (null);
1020       end if;
1021    end Finalize_TCB;
1022
1023    ---------------
1024    -- Exit_Task --
1025    ---------------
1026
1027    procedure Exit_Task is
1028    begin
1029       Specific.Set (null);
1030    end Exit_Task;
1031
1032    ----------------
1033    -- Abort_Task --
1034    ----------------
1035
1036    procedure Abort_Task (T : Task_Id) is
1037       pragma Unreferenced (T);
1038    begin
1039       null;
1040    end Abort_Task;
1041
1042    ----------------------
1043    -- Environment_Task --
1044    ----------------------
1045
1046    function Environment_Task return Task_Id is
1047    begin
1048       return Environment_Task_Id;
1049    end Environment_Task;
1050
1051    --------------
1052    -- Lock_RTS --
1053    --------------
1054
1055    procedure Lock_RTS is
1056    begin
1057       Write_Lock (Single_RTS_Lock'Access, Global_Lock => True);
1058    end Lock_RTS;
1059
1060    ----------------
1061    -- Unlock_RTS --
1062    ----------------
1063
1064    procedure Unlock_RTS is
1065    begin
1066       Unlock (Single_RTS_Lock'Access, Global_Lock => True);
1067    end Unlock_RTS;
1068
1069    ----------------
1070    -- Initialize --
1071    ----------------
1072
1073    procedure Initialize (Environment_Task : Task_Id) is
1074       Discard : BOOL;
1075       pragma Unreferenced (Discard);
1076
1077       Result : DWORD;
1078
1079       use type System.Multiprocessors.CPU_Range;
1080
1081    begin
1082       Environment_Task_Id := Environment_Task;
1083       OS_Primitives.Initialize;
1084       Interrupt_Management.Initialize;
1085
1086       if Time_Slice_Val = 0 or else Dispatching_Policy = 'F' then
1087          --  Here we need Annex D semantics, switch the current process to the
1088          --  Realtime_Priority_Class.
1089
1090          Discard := OS_Interface.SetPriorityClass
1091                       (GetCurrentProcess, Realtime_Priority_Class);
1092
1093          Annex_D := True;
1094       end if;
1095
1096       TlsIndex := TlsAlloc;
1097
1098       --  Initialize the lock used to synchronize chain of all ATCBs
1099
1100       Initialize_Lock (Single_RTS_Lock'Access, RTS_Lock_Level);
1101
1102       Environment_Task.Common.LL.Thread := GetCurrentThread;
1103
1104       --  Make environment task known here because it doesn't go through
1105       --  Activate_Tasks, which does it for all other tasks.
1106
1107       Known_Tasks (Known_Tasks'First) := Environment_Task;
1108       Environment_Task.Known_Tasks_Index := Known_Tasks'First;
1109
1110       Enter_Task (Environment_Task);
1111
1112       --  pragma CPU for the environment task
1113
1114       if Environment_Task.Common.Base_CPU /=
1115          System.Multiprocessors.Not_A_Specific_CPU
1116       then
1117          --  The CPU numbering in pragma CPU starts at 1 while the subprogram
1118          --  to set the affinity starts at 0, therefore we must substract 1.
1119
1120          Result :=
1121            SetThreadIdealProcessor
1122              (Environment_Task.Common.LL.Thread,
1123               ProcessorId (Environment_Task.Common.Base_CPU) - 1);
1124          pragma Assert (Result = 1);
1125       end if;
1126    end Initialize;
1127
1128    ---------------------
1129    -- Monotonic_Clock --
1130    ---------------------
1131
1132    function Monotonic_Clock return Duration
1133      renames System.OS_Primitives.Monotonic_Clock;
1134
1135    -------------------
1136    -- RT_Resolution --
1137    -------------------
1138
1139    function RT_Resolution return Duration is
1140    begin
1141       return 0.000_001; --  1 micro-second
1142    end RT_Resolution;
1143
1144    ----------------
1145    -- Initialize --
1146    ----------------
1147
1148    procedure Initialize (S : in out Suspension_Object) is
1149    begin
1150       --  Initialize internal state. It is always initialized to False (ARM
1151       --  D.10 par. 6).
1152
1153       S.State := False;
1154       S.Waiting := False;
1155
1156       --  Initialize internal mutex
1157
1158       InitializeCriticalSection (S.L'Access);
1159
1160       --  Initialize internal condition variable
1161
1162       S.CV := CreateEvent (null, Win32.TRUE, Win32.FALSE, Null_Ptr);
1163       pragma Assert (S.CV /= 0);
1164    end Initialize;
1165
1166    --------------
1167    -- Finalize --
1168    --------------
1169
1170    procedure Finalize (S : in out Suspension_Object) is
1171       Result : BOOL;
1172
1173    begin
1174       --  Destroy internal mutex
1175
1176       DeleteCriticalSection (S.L'Access);
1177
1178       --  Destroy internal condition variable
1179
1180       Result := CloseHandle (S.CV);
1181       pragma Assert (Result = Win32.TRUE);
1182    end Finalize;
1183
1184    -------------------
1185    -- Current_State --
1186    -------------------
1187
1188    function Current_State (S : Suspension_Object) return Boolean is
1189    begin
1190       --  We do not want to use lock on this read operation. State is marked
1191       --  as Atomic so that we ensure that the value retrieved is correct.
1192
1193       return S.State;
1194    end Current_State;
1195
1196    ---------------
1197    -- Set_False --
1198    ---------------
1199
1200    procedure Set_False (S : in out Suspension_Object) is
1201    begin
1202       SSL.Abort_Defer.all;
1203
1204       EnterCriticalSection (S.L'Access);
1205
1206       S.State := False;
1207
1208       LeaveCriticalSection (S.L'Access);
1209
1210       SSL.Abort_Undefer.all;
1211    end Set_False;
1212
1213    --------------
1214    -- Set_True --
1215    --------------
1216
1217    procedure Set_True (S : in out Suspension_Object) is
1218       Result : BOOL;
1219    begin
1220       SSL.Abort_Defer.all;
1221
1222       EnterCriticalSection (S.L'Access);
1223
1224       --  If there is already a task waiting on this suspension object then
1225       --  we resume it, leaving the state of the suspension object to False,
1226       --  as it is specified in ARM D.10 par. 9. Otherwise, it just leaves
1227       --  the state to True.
1228
1229       if S.Waiting then
1230          S.Waiting := False;
1231          S.State := False;
1232
1233          Result := SetEvent (S.CV);
1234          pragma Assert (Result = Win32.TRUE);
1235       else
1236          S.State := True;
1237       end if;
1238
1239       LeaveCriticalSection (S.L'Access);
1240
1241       SSL.Abort_Undefer.all;
1242    end Set_True;
1243
1244    ------------------------
1245    -- Suspend_Until_True --
1246    ------------------------
1247
1248    procedure Suspend_Until_True (S : in out Suspension_Object) is
1249       Result      : DWORD;
1250       Result_Bool : BOOL;
1251
1252    begin
1253       SSL.Abort_Defer.all;
1254
1255       EnterCriticalSection (S.L'Access);
1256
1257       if S.Waiting then
1258          --  Program_Error must be raised upon calling Suspend_Until_True
1259          --  if another task is already waiting on that suspension object
1260          --  (ARM D.10 par. 10).
1261
1262          LeaveCriticalSection (S.L'Access);
1263
1264          SSL.Abort_Undefer.all;
1265
1266          raise Program_Error;
1267       else
1268          --  Suspend the task if the state is False. Otherwise, the task
1269          --  continues its execution, and the state of the suspension object
1270          --  is set to False (ARM D.10 par. 9).
1271
1272          if S.State then
1273             S.State := False;
1274
1275             LeaveCriticalSection (S.L'Access);
1276
1277             SSL.Abort_Undefer.all;
1278          else
1279             S.Waiting := True;
1280
1281             --  Must reset CV BEFORE L is unlocked
1282
1283             Result_Bool := ResetEvent (S.CV);
1284             pragma Assert (Result_Bool = Win32.TRUE);
1285
1286             LeaveCriticalSection (S.L'Access);
1287
1288             SSL.Abort_Undefer.all;
1289
1290             Result := WaitForSingleObject (S.CV, Wait_Infinite);
1291             pragma Assert (Result = 0);
1292          end if;
1293       end if;
1294    end Suspend_Until_True;
1295
1296    ----------------
1297    -- Check_Exit --
1298    ----------------
1299
1300    --  Dummy versions.  The only currently working versions is for solaris
1301    --  (native).
1302
1303    function Check_Exit (Self_ID : ST.Task_Id) return Boolean is
1304       pragma Unreferenced (Self_ID);
1305    begin
1306       return True;
1307    end Check_Exit;
1308
1309    --------------------
1310    -- Check_No_Locks --
1311    --------------------
1312
1313    function Check_No_Locks (Self_ID : ST.Task_Id) return Boolean is
1314       pragma Unreferenced (Self_ID);
1315    begin
1316       return True;
1317    end Check_No_Locks;
1318
1319    ------------------
1320    -- Suspend_Task --
1321    ------------------
1322
1323    function Suspend_Task
1324      (T           : ST.Task_Id;
1325       Thread_Self : Thread_Id) return Boolean
1326    is
1327    begin
1328       if T.Common.LL.Thread /= Thread_Self then
1329          return SuspendThread (T.Common.LL.Thread) = NO_ERROR;
1330       else
1331          return True;
1332       end if;
1333    end Suspend_Task;
1334
1335    -----------------
1336    -- Resume_Task --
1337    -----------------
1338
1339    function Resume_Task
1340      (T           : ST.Task_Id;
1341       Thread_Self : Thread_Id) return Boolean
1342    is
1343    begin
1344       if T.Common.LL.Thread /= Thread_Self then
1345          return ResumeThread (T.Common.LL.Thread) = NO_ERROR;
1346       else
1347          return True;
1348       end if;
1349    end Resume_Task;
1350
1351    --------------------
1352    -- Stop_All_Tasks --
1353    --------------------
1354
1355    procedure Stop_All_Tasks is
1356    begin
1357       null;
1358    end Stop_All_Tasks;
1359
1360    ---------------
1361    -- Stop_Task --
1362    ---------------
1363
1364    function Stop_Task (T : ST.Task_Id) return Boolean is
1365       pragma Unreferenced (T);
1366    begin
1367       return False;
1368    end Stop_Task;
1369
1370    -------------------
1371    -- Continue_Task --
1372    -------------------
1373
1374    function Continue_Task (T : ST.Task_Id) return Boolean is
1375       pragma Unreferenced (T);
1376    begin
1377       return False;
1378    end Continue_Task;
1379
1380 end System.Task_Primitives.Operations;