gcc/ada/s-taprop-hpux-dce.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --     S Y S T E M . T A S K _ P R I M I T I V E S . O P E R A T I O N S    --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --         Copyright (C) 1992-2009, Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is a HP-UX DCE threads (HPUX 10) version of this package
  33
  34 --  This package contains all the GNULL primitives that interface directly with
  35 --  the underlying OS.
  36
  37 pragma Polling (Off);
  38 --  Turn off polling, we do not want ATC polling to take place during tasking
  39 --  operations. It causes infinite loops and other problems.
  40
  41 with Ada.Unchecked_Conversion;
  42 with Ada.Unchecked_Deallocation;
  43
  44 with Interfaces.C;
  45
  46 with System.Tasking.Debug;
  47 with System.Interrupt_Management;
  48 with System.OS_Primitives;
  49 with System.Task_Primitives.Interrupt_Operations;
  50
  51 pragma Warnings (Off);
  52 with System.Interrupt_Management.Operations;
  53 pragma Elaborate_All (System.Interrupt_Management.Operations);
  54 pragma Warnings (On);
  55
  56 with System.Soft_Links;
  57 --  We use System.Soft_Links instead of System.Tasking.Initialization
  58 --  because the later is a higher level package that we shouldn't depend on.
  59 --  For example when using the restricted run time, it is replaced by
  60 --  System.Tasking.Restricted.Stages.
  61
  62 package body System.Task_Primitives.Operations is
  63
  64    package SSL renames System.Soft_Links;
  65
  66    use System.Tasking.Debug;
  67    use System.Tasking;
  68    use Interfaces.C;
  69    use System.OS_Interface;
  70    use System.Parameters;
  71    use System.OS_Primitives;
  72
  73    package PIO renames System.Task_Primitives.Interrupt_Operations;
  74
  75    ----------------
  76    -- Local Data --
  77    ----------------
  78
  79    --  The followings are logically constants, but need to be initialized
  80    --  at run time.
  81
  82    Single_RTS_Lock : aliased RTS_Lock;
  83    --  This is a lock to allow only one thread of control in the RTS at
  84    --  a time; it is used to execute in mutual exclusion from all other tasks.
  85    --  Used mainly in Single_Lock mode, but also to protect All_Tasks_List
  86
  87    ATCB_Key : aliased pthread_key_t;
  88    --  Key used to find the Ada Task_Id associated with a thread
  89
  90    Environment_Task_Id : Task_Id;
  91    --  A variable to hold Task_Id for the environment task
  92
  93    Unblocked_Signal_Mask : aliased sigset_t;
  94    --  The set of signals that should unblocked in all tasks
  95
  96    Time_Slice_Val : Integer;
  97    pragma Import (C, Time_Slice_Val, "__gl_time_slice_val");
  98
  99    Dispatching_Policy : Character;
 100    pragma Import (C, Dispatching_Policy, "__gl_task_dispatching_policy");
 101
 102    --  Note: the reason that Locking_Policy is not needed is that this
 103    --  is not implemented for DCE threads. The HPUX 10 port is at this
 104    --  stage considered dead, and no further work is planned on it.
 105
 106    Foreign_Task_Elaborated : aliased Boolean := True;
 107    --  Used to identified fake tasks (i.e., non-Ada Threads)
 108
 109    --------------------
 110    -- Local Packages --
 111    --------------------
 112
 113    package Specific is
 114
 115       procedure Initialize (Environment_Task : Task_Id);
 116       pragma Inline (Initialize);
 117       --  Initialize various data needed by this package
 118
 119       function Is_Valid_Task return Boolean;
 120       pragma Inline (Is_Valid_Task);
 121       --  Does the executing thread have a TCB?
 122
 123       procedure Set (Self_Id : Task_Id);
 124       pragma Inline (Set);
 125       --  Set the self id for the current task
 126
 127       function Self return Task_Id;
 128       pragma Inline (Self);
 129       --  Return a pointer to the Ada Task Control Block of the calling task
 130
 131    end Specific;
 132
 133    package body Specific is separate;
 134    --  The body of this package is target specific
 135
 136    ---------------------------------
 137    -- Support for foreign threads --
 138    ---------------------------------
 139
 140    function Register_Foreign_Thread (Thread : Thread_Id) return Task_Id;
 141    --  Allocate and Initialize a new ATCB for the current Thread
 142
 143    function Register_Foreign_Thread
 144      (Thread : Thread_Id) return Task_Id is separate;
 145
 146    -----------------------
 147    -- Local Subprograms --
 148    -----------------------
 149
 150    procedure Abort_Handler (Sig : Signal);
 151
 152    function To_Address is
 153      new Ada.Unchecked_Conversion (Task_Id, System.Address);
 154
 155    -------------------
 156    -- Abort_Handler --
 157    -------------------
 158
 159    procedure Abort_Handler (Sig : Signal) is
 160       pragma Unreferenced (Sig);
 161
 162       Self_Id : constant Task_Id := Self;
 163       Result  : Interfaces.C.int;
 164       Old_Set : aliased sigset_t;
 165
 166    begin
 167       if Self_Id.Deferral_Level = 0
 168         and then Self_Id.Pending_ATC_Level < Self_Id.ATC_Nesting_Level
 169         and then not Self_Id.Aborting
 170       then
 171          Self_Id.Aborting := True;
 172
 173          --  Make sure signals used for RTS internal purpose are unmasked
 174
 175          Result :=
 176            pthread_sigmask
 177              (SIG_UNBLOCK,
 178               Unblocked_Signal_Mask'Access,
 179               Old_Set'Access);
 180          pragma Assert (Result = 0);
 181
 182          raise Standard'Abort_Signal;
 183       end if;
 184    end Abort_Handler;
 185
 186    -----------------
 187    -- Stack_Guard --
 188    -----------------
 189
 190    --  The underlying thread system sets a guard page at the bottom of a thread
 191    --  stack, so nothing is needed.
 192    --  ??? Check the comment above
 193
 194    procedure Stack_Guard (T : ST.Task_Id; On : Boolean) is
 195       pragma Unreferenced (T, On);
 196    begin
 197       null;
 198    end Stack_Guard;
 199
 200    -------------------
 201    -- Get_Thread_Id --
 202    -------------------
 203
 204    function Get_Thread_Id (T : ST.Task_Id) return OSI.Thread_Id is
 205    begin
 206       return T.Common.LL.Thread;
 207    end Get_Thread_Id;
 208
 209    ----------
 210    -- Self --
 211    ----------
 212
 213    function Self return Task_Id renames Specific.Self;
 214
 215    ---------------------
 216    -- Initialize_Lock --
 217    ---------------------
 218
 219    --  Note: mutexes and cond_variables needed per-task basis are initialized
 220    --  in Initialize_TCB and the Storage_Error is handled. Other mutexes (such
 221    --  as RTS_Lock, Memory_Lock...) used in RTS is initialized before any
 222    --  status change of RTS. Therefore raising Storage_Error in the following
 223    --  routines should be able to be handled safely.
 224
 225    procedure Initialize_Lock
 226      (Prio : System.Any_Priority;
 227       L    : not null access Lock)
 228    is
 229       Attributes : aliased pthread_mutexattr_t;
 230       Result     : Interfaces.C.int;
 231
 232    begin
 233       Result := pthread_mutexattr_init (Attributes'Access);
 234       pragma Assert (Result = 0 or else Result = ENOMEM);
 235
 236       if Result = ENOMEM then
 237          raise Storage_Error;
 238       end if;
 239
 240       L.Priority := Prio;
 241
 242       Result := pthread_mutex_init (L.L'Access, Attributes'Access);
 243       pragma Assert (Result = 0 or else Result = ENOMEM);
 244
 245       if Result = ENOMEM then
 246          raise Storage_Error;
 247       end if;
 248
 249       Result := pthread_mutexattr_destroy (Attributes'Access);
 250       pragma Assert (Result = 0);
 251    end Initialize_Lock;
 252
 253    procedure Initialize_Lock
 254      (L     : not null access RTS_Lock;
 255       Level : Lock_Level)
 256    is
 257       pragma Unreferenced (Level);
 258
 259       Attributes : aliased pthread_mutexattr_t;
 260       Result     : Interfaces.C.int;
 261
 262    begin
 263       Result := pthread_mutexattr_init (Attributes'Access);
 264       pragma Assert (Result = 0 or else Result = ENOMEM);
 265
 266       if Result = ENOMEM then
 267          raise Storage_Error;
 268       end if;
 269
 270       Result := pthread_mutex_init (L, Attributes'Access);
 271
 272       pragma Assert (Result = 0 or else Result = ENOMEM);
 273
 274       if Result = ENOMEM then
 275          raise Storage_Error;
 276       end if;
 277
 278       Result := pthread_mutexattr_destroy (Attributes'Access);
 279       pragma Assert (Result = 0);
 280    end Initialize_Lock;
 281
 282    -------------------
 283    -- Finalize_Lock --
 284    -------------------
 285
 286    procedure Finalize_Lock (L : not null access Lock) is
 287       Result : Interfaces.C.int;
 288    begin
 289       Result := pthread_mutex_destroy (L.L'Access);
 290       pragma Assert (Result = 0);
 291    end Finalize_Lock;
 292
 293    procedure Finalize_Lock (L : not null access RTS_Lock) is
 294       Result : Interfaces.C.int;
 295    begin
 296       Result := pthread_mutex_destroy (L);
 297       pragma Assert (Result = 0);
 298    end Finalize_Lock;
 299
 300    ----------------
 301    -- Write_Lock --
 302    ----------------
 303
 304    procedure Write_Lock
 305      (L                 : not null access Lock;
 306       Ceiling_Violation : out Boolean)
 307    is
 308       Result : Interfaces.C.int;
 309
 310    begin
 311       L.Owner_Priority := Get_Priority (Self);
 312
 313       if L.Priority < L.Owner_Priority then
 314          Ceiling_Violation := True;
 315          return;
 316       end if;
 317
 318       Result := pthread_mutex_lock (L.L'Access);
 319       pragma Assert (Result = 0);
 320       Ceiling_Violation := False;
 321    end Write_Lock;
 322
 323    procedure Write_Lock
 324      (L           : not null access RTS_Lock;
 325       Global_Lock : Boolean := False)
 326    is
 327       Result : Interfaces.C.int;
 328    begin
 329       if not Single_Lock or else Global_Lock then
 330          Result := pthread_mutex_lock (L);
 331          pragma Assert (Result = 0);
 332       end if;
 333    end Write_Lock;
 334
 335    procedure Write_Lock (T : Task_Id) is
 336       Result : Interfaces.C.int;
 337    begin
 338       if not Single_Lock then
 339          Result := pthread_mutex_lock (T.Common.LL.L'Access);
 340          pragma Assert (Result = 0);
 341       end if;
 342    end Write_Lock;
 343
 344    ---------------
 345    -- Read_Lock --
 346    ---------------
 347
 348    procedure Read_Lock
 349      (L                 : not null access Lock;
 350       Ceiling_Violation : out Boolean)
 351    is
 352    begin
 353       Write_Lock (L, Ceiling_Violation);
 354    end Read_Lock;
 355
 356    ------------
 357    -- Unlock --
 358    ------------
 359
 360    procedure Unlock (L : not null access Lock) is
 361       Result : Interfaces.C.int;
 362    begin
 363       Result := pthread_mutex_unlock (L.L'Access);
 364       pragma Assert (Result = 0);
 365    end Unlock;
 366
 367    procedure Unlock
 368      (L           : not null access RTS_Lock;
 369       Global_Lock : Boolean := False)
 370    is
 371       Result : Interfaces.C.int;
 372    begin
 373       if not Single_Lock or else Global_Lock then
 374          Result := pthread_mutex_unlock (L);
 375          pragma Assert (Result = 0);
 376       end if;
 377    end Unlock;
 378
 379    procedure Unlock (T : Task_Id) is
 380       Result : Interfaces.C.int;
 381    begin
 382       if not Single_Lock then
 383          Result := pthread_mutex_unlock (T.Common.LL.L'Access);
 384          pragma Assert (Result = 0);
 385       end if;
 386    end Unlock;
 387
 388    -----------------
 389    -- Set_Ceiling --
 390    -----------------
 391
 392    --  Dynamic priority ceilings are not supported by the underlying system
 393
 394    procedure Set_Ceiling
 395      (L    : not null access Lock;
 396       Prio : System.Any_Priority)
 397    is
 398       pragma Unreferenced (L, Prio);
 399    begin
 400       null;
 401    end Set_Ceiling;
 402
 403    -----------
 404    -- Sleep --
 405    -----------
 406
 407    procedure Sleep
 408      (Self_ID : Task_Id;
 409       Reason  : System.Tasking.Task_States)
 410    is
 411       pragma Unreferenced (Reason);
 412
 413       Result : Interfaces.C.int;
 414    begin
 415       if Single_Lock then
 416          Result :=
 417            pthread_cond_wait
 418              (Self_ID.Common.LL.CV'Access, Single_RTS_Lock'Access);
 419       else
 420          Result :=
 421            pthread_cond_wait
 422              (Self_ID.Common.LL.CV'Access, Self_ID.Common.LL.L'Access);
 423       end if;
 424
 425       --  EINTR is not considered a failure
 426
 427       pragma Assert (Result = 0 or else Result = EINTR);
 428    end Sleep;
 429
 430    -----------------
 431    -- Timed_Sleep --
 432    -----------------
 433
 434    procedure Timed_Sleep
 435      (Self_ID  : Task_Id;
 436       Time     : Duration;
 437       Mode     : ST.Delay_Modes;
 438       Reason   : System.Tasking.Task_States;
 439       Timedout : out Boolean;
 440       Yielded  : out Boolean)
 441    is
 442       pragma Unreferenced (Reason);
 443
 444       Check_Time : constant Duration := Monotonic_Clock;
 445       Abs_Time   : Duration;
 446       Request    : aliased timespec;
 447       Result     : Interfaces.C.int;
 448
 449    begin
 450       Timedout := True;
 451       Yielded := False;
 452
 453       if Mode = Relative then
 454          Abs_Time := Duration'Min (Time, Max_Sensible_Delay) + Check_Time;
 455       else
 456          Abs_Time := Duration'Min (Check_Time + Max_Sensible_Delay, Time);
 457       end if;
 458
 459       if Abs_Time > Check_Time then
 460          Request := To_Timespec (Abs_Time);
 461
 462          loop
 463             exit when Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level;
 464
 465             if Single_Lock then
 466                Result :=
 467                  pthread_cond_timedwait
 468                    (Self_ID.Common.LL.CV'Access,
 469                     Single_RTS_Lock'Access,
 470                     Request'Access);
 471
 472             else
 473                Result :=
 474                  pthread_cond_timedwait
 475                    (Self_ID.Common.LL.CV'Access,
 476                     Self_ID.Common.LL.L'Access,
 477                     Request'Access);
 478             end if;
 479
 480             exit when Abs_Time <= Monotonic_Clock;
 481
 482             if Result = 0 or Result = EINTR then
 483
 484                --  Somebody may have called Wakeup for us
 485
 486                Timedout := False;
 487                exit;
 488             end if;
 489
 490             pragma Assert (Result = ETIMEDOUT);
 491          end loop;
 492       end if;
 493    end Timed_Sleep;
 494
 495    -----------------
 496    -- Timed_Delay --
 497    -----------------
 498
 499    procedure Timed_Delay
 500      (Self_ID : Task_Id;
 501       Time    : Duration;
 502       Mode    : ST.Delay_Modes)
 503    is
 504       Check_Time : constant Duration := Monotonic_Clock;
 505       Abs_Time   : Duration;
 506       Request    : aliased timespec;
 507
 508       Result : Interfaces.C.int;
 509       pragma Warnings (Off, Result);
 510
 511    begin
 512       if Single_Lock then
 513          Lock_RTS;
 514       end if;
 515
 516       Write_Lock (Self_ID);
 517
 518       if Mode = Relative then
 519          Abs_Time := Time + Check_Time;
 520       else
 521          Abs_Time := Duration'Min (Check_Time + Max_Sensible_Delay, Time);
 522       end if;
 523
 524       if Abs_Time > Check_Time then
 525          Request := To_Timespec (Abs_Time);
 526          Self_ID.Common.State := Delay_Sleep;
 527
 528          loop
 529             exit when Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level;
 530
 531             if Single_Lock then
 532                Result :=
 533                  pthread_cond_timedwait
 534                    (Self_ID.Common.LL.CV'Access,
 535                     Single_RTS_Lock'Access,
 536                     Request'Access);
 537             else
 538                Result :=
 539                  pthread_cond_timedwait
 540                    (Self_ID.Common.LL.CV'Access,
 541                     Self_ID.Common.LL.L'Access,
 542                     Request'Access);
 543             end if;
 544
 545             exit when Abs_Time <= Monotonic_Clock;
 546
 547             pragma Assert (Result = 0 or else
 548               Result = ETIMEDOUT or else
 549               Result = EINTR);
 550          end loop;
 551
 552          Self_ID.Common.State := Runnable;
 553       end if;
 554
 555       Unlock (Self_ID);
 556
 557       if Single_Lock then
 558          Unlock_RTS;
 559       end if;
 560
 561       Result := sched_yield;
 562    end Timed_Delay;
 563
 564    ---------------------
 565    -- Monotonic_Clock --
 566    ---------------------
 567
 568    function Monotonic_Clock return Duration is
 569       TS     : aliased timespec;
 570       Result : Interfaces.C.int;
 571    begin
 572       Result := Clock_Gettime (CLOCK_REALTIME, TS'Unchecked_Access);
 573       pragma Assert (Result = 0);
 574       return To_Duration (TS);
 575    end Monotonic_Clock;
 576
 577    -------------------
 578    -- RT_Resolution --
 579    -------------------
 580
 581    function RT_Resolution return Duration is
 582    begin
 583       return 10#1.0#E-6;
 584    end RT_Resolution;
 585
 586    ------------
 587    -- Wakeup --
 588    ------------
 589
 590    procedure Wakeup (T : Task_Id; Reason : System.Tasking.Task_States) is
 591       pragma Unreferenced (Reason);
 592       Result : Interfaces.C.int;
 593    begin
 594       Result := pthread_cond_signal (T.Common.LL.CV'Access);
 595       pragma Assert (Result = 0);
 596    end Wakeup;
 597
 598    -----------
 599    -- Yield --
 600    -----------
 601
 602    procedure Yield (Do_Yield : Boolean := True) is
 603       Result : Interfaces.C.int;
 604       pragma Unreferenced (Result);
 605    begin
 606       if Do_Yield then
 607          Result := sched_yield;
 608       end if;
 609    end Yield;
 610
 611    ------------------
 612    -- Set_Priority --
 613    ------------------
 614
 615    type Prio_Array_Type is array (System.Any_Priority) of Integer;
 616    pragma Atomic_Components (Prio_Array_Type);
 617
 618    Prio_Array : Prio_Array_Type;
 619    --  Global array containing the id of the currently running task for
 620    --  each priority.
 621    --
 622    --  Note: assume we are on single processor with run-til-blocked scheduling
 623
 624    procedure Set_Priority
 625      (T                   : Task_Id;
 626       Prio                : System.Any_Priority;
 627       Loss_Of_Inheritance : Boolean := False)
 628    is
 629       Result     : Interfaces.C.int;
 630       Array_Item : Integer;
 631       Param      : aliased struct_sched_param;
 632
 633       function Get_Policy (Prio : System.Any_Priority) return Character;
 634       pragma Import (C, Get_Policy, "__gnat_get_specific_dispatching");
 635       --  Get priority specific dispatching policy
 636
 637       Priority_Specific_Policy : constant Character := Get_Policy (Prio);
 638       --  Upper case first character of the policy name corresponding to the
 639       --  task as set by a Priority_Specific_Dispatching pragma.
 640
 641    begin
 642       Param.sched_priority  := Interfaces.C.int (Underlying_Priorities (Prio));
 643
 644       if Dispatching_Policy = 'R'
 645         or else Priority_Specific_Policy = 'R'
 646         or else Time_Slice_Val > 0
 647       then
 648          Result :=
 649            pthread_setschedparam
 650              (T.Common.LL.Thread, SCHED_RR, Param'Access);
 651
 652       elsif Dispatching_Policy = 'F'
 653         or else Priority_Specific_Policy = 'F'
 654         or else Time_Slice_Val = 0
 655       then
 656          Result :=
 657            pthread_setschedparam
 658              (T.Common.LL.Thread, SCHED_FIFO, Param'Access);
 659
 660       else
 661          Result :=
 662            pthread_setschedparam
 663              (T.Common.LL.Thread, SCHED_OTHER, Param'Access);
 664       end if;
 665
 666       pragma Assert (Result = 0);
 667
 668       if Dispatching_Policy = 'F' or else Priority_Specific_Policy = 'F' then
 669
 670          --  Annex D requirement [RM D.2.2 par. 9]:
 671          --    If the task drops its priority due to the loss of inherited
 672          --    priority, it is added at the head of the ready queue for its
 673          --    new active priority.
 674
 675          if Loss_Of_Inheritance
 676            and then Prio < T.Common.Current_Priority
 677          then
 678             Array_Item := Prio_Array (T.Common.Base_Priority) + 1;
 679             Prio_Array (T.Common.Base_Priority) := Array_Item;
 680
 681             loop
 682                --  Let some processes a chance to arrive
 683
 684                Yield;
 685
 686                --  Then wait for our turn to proceed
 687
 688                exit when Array_Item = Prio_Array (T.Common.Base_Priority)
 689                  or else Prio_Array (T.Common.Base_Priority) = 1;
 690             end loop;
 691
 692             Prio_Array (T.Common.Base_Priority) :=
 693               Prio_Array (T.Common.Base_Priority) - 1;
 694          end if;
 695       end if;
 696
 697       T.Common.Current_Priority := Prio;
 698    end Set_Priority;
 699
 700    ------------------
 701    -- Get_Priority --
 702    ------------------
 703
 704    function Get_Priority (T : Task_Id) return System.Any_Priority is
 705    begin
 706       return T.Common.Current_Priority;
 707    end Get_Priority;
 708
 709    ----------------
 710    -- Enter_Task --
 711    ----------------
 712
 713    procedure Enter_Task (Self_ID : Task_Id) is
 714    begin
 715       Self_ID.Common.LL.Thread := pthread_self;
 716       Specific.Set (Self_ID);
 717    end Enter_Task;
 718
 719    --------------
 720    -- New_ATCB --
 721    --------------
 722
 723    function New_ATCB (Entry_Num : Task_Entry_Index) return Task_Id is
 724    begin
 725       return new Ada_Task_Control_Block (Entry_Num);
 726    end New_ATCB;
 727
 728    -------------------
 729    -- Is_Valid_Task --
 730    -------------------
 731
 732    function Is_Valid_Task return Boolean renames Specific.Is_Valid_Task;
 733
 734    -----------------------------
 735    -- Register_Foreign_Thread --
 736    -----------------------------
 737
 738    function Register_Foreign_Thread return Task_Id is
 739    begin
 740       if Is_Valid_Task then
 741          return Self;
 742       else
 743          return Register_Foreign_Thread (pthread_self);
 744       end if;
 745    end Register_Foreign_Thread;
 746
 747    --------------------
 748    -- Initialize_TCB --
 749    --------------------
 750
 751    procedure Initialize_TCB (Self_ID : Task_Id; Succeeded : out Boolean) is
 752       Mutex_Attr : aliased pthread_mutexattr_t;
 753       Result     : Interfaces.C.int;
 754       Cond_Attr  : aliased pthread_condattr_t;
 755
 756    begin
 757       if not Single_Lock then
 758          Result := pthread_mutexattr_init (Mutex_Attr'Access);
 759          pragma Assert (Result = 0 or else Result = ENOMEM);
 760
 761          if Result = 0 then
 762             Result :=
 763               pthread_mutex_init
 764                 (Self_ID.Common.LL.L'Access, Mutex_Attr'Access);
 765             pragma Assert (Result = 0 or else Result = ENOMEM);
 766          end if;
 767
 768          if Result /= 0 then
 769             Succeeded := False;
 770             return;
 771          end if;
 772
 773          Result := pthread_mutexattr_destroy (Mutex_Attr'Access);
 774          pragma Assert (Result = 0);
 775       end if;
 776
 777       Result := pthread_condattr_init (Cond_Attr'Access);
 778       pragma Assert (Result = 0 or else Result = ENOMEM);
 779
 780       if Result = 0 then
 781          Result :=
 782            pthread_cond_init
 783              (Self_ID.Common.LL.CV'Access,
 784               Cond_Attr'Access);
 785          pragma Assert (Result = 0 or else Result = ENOMEM);
 786       end if;
 787
 788       if Result = 0 then
 789          Succeeded := True;
 790       else
 791          if not Single_Lock then
 792             Result := pthread_mutex_destroy (Self_ID.Common.LL.L'Access);
 793             pragma Assert (Result = 0);
 794          end if;
 795
 796          Succeeded := False;
 797       end if;
 798
 799       Result := pthread_condattr_destroy (Cond_Attr'Access);
 800       pragma Assert (Result = 0);
 801    end Initialize_TCB;
 802
 803    -----------------
 804    -- Create_Task --
 805    -----------------
 806
 807    procedure Create_Task
 808      (T          : Task_Id;
 809       Wrapper    : System.Address;
 810       Stack_Size : System.Parameters.Size_Type;
 811       Priority   : System.Any_Priority;
 812       Succeeded  : out Boolean)
 813    is
 814       Attributes : aliased pthread_attr_t;
 815       Result     : Interfaces.C.int;
 816
 817       function Thread_Body_Access is new
 818         Ada.Unchecked_Conversion (System.Address, Thread_Body);
 819
 820    begin
 821       Result := pthread_attr_init (Attributes'Access);
 822       pragma Assert (Result = 0 or else Result = ENOMEM);
 823
 824       if Result /= 0 then
 825          Succeeded := False;
 826          return;
 827       end if;
 828
 829       Result := pthread_attr_setstacksize
 830         (Attributes'Access, Interfaces.C.size_t (Stack_Size));
 831       pragma Assert (Result = 0);
 832
 833       --  Since the initial signal mask of a thread is inherited from the
 834       --  creator, and the Environment task has all its signals masked, we
 835       --  do not need to manipulate caller's signal mask at this point.
 836       --  All tasks in RTS will have All_Tasks_Mask initially.
 837
 838       Result := pthread_create
 839         (T.Common.LL.Thread'Access,
 840          Attributes'Access,
 841          Thread_Body_Access (Wrapper),
 842          To_Address (T));
 843       pragma Assert (Result = 0 or else Result = EAGAIN);
 844
 845       Succeeded := Result = 0;
 846
 847       pthread_detach (T.Common.LL.Thread'Access);
 848       --  Detach the thread using pthread_detach, since DCE threads do not have
 849       --  pthread_attr_set_detachstate.
 850
 851       Result := pthread_attr_destroy (Attributes'Access);
 852       pragma Assert (Result = 0);
 853
 854       Set_Priority (T, Priority);
 855    end Create_Task;
 856
 857    ------------------
 858    -- Finalize_TCB --
 859    ------------------
 860
 861    procedure Finalize_TCB (T : Task_Id) is
 862       Result  : Interfaces.C.int;
 863       Tmp     : Task_Id := T;
 864       Is_Self : constant Boolean := T = Self;
 865
 866       procedure Free is new
 867         Ada.Unchecked_Deallocation (Ada_Task_Control_Block, Task_Id);
 868
 869    begin
 870       if not Single_Lock then
 871          Result := pthread_mutex_destroy (T.Common.LL.L'Access);
 872          pragma Assert (Result = 0);
 873       end if;
 874
 875       Result := pthread_cond_destroy (T.Common.LL.CV'Access);
 876       pragma Assert (Result = 0);
 877
 878       if T.Known_Tasks_Index /= -1 then
 879          Known_Tasks (T.Known_Tasks_Index) := null;
 880       end if;
 881
 882       Free (Tmp);
 883
 884       if Is_Self then
 885          Specific.Set (null);
 886       end if;
 887    end Finalize_TCB;
 888
 889    ---------------
 890    -- Exit_Task --
 891    ---------------
 892
 893    procedure Exit_Task is
 894    begin
 895       Specific.Set (null);
 896    end Exit_Task;
 897
 898    ----------------
 899    -- Abort_Task --
 900    ----------------
 901
 902    procedure Abort_Task (T : Task_Id) is
 903    begin
 904       --  Interrupt Server_Tasks may be waiting on an "event" flag (signal)
 905
 906       if T.Common.State = Interrupt_Server_Blocked_On_Event_Flag then
 907          System.Interrupt_Management.Operations.Interrupt_Self_Process
 908            (System.Interrupt_Management.Interrupt_ID
 909              (PIO.Get_Interrupt_ID (T)));
 910       end if;
 911    end Abort_Task;
 912
 913    ----------------
 914    -- Initialize --
 915    ----------------
 916
 917    procedure Initialize (S : in out Suspension_Object) is
 918       Mutex_Attr : aliased pthread_mutexattr_t;
 919       Cond_Attr  : aliased pthread_condattr_t;
 920       Result     : Interfaces.C.int;
 921    begin
 922       --  Initialize internal state (always to False (ARM D.10(6)))
 923
 924       S.State := False;
 925       S.Waiting := False;
 926
 927       --  Initialize internal mutex
 928
 929       Result := pthread_mutex_init (S.L'Access, Mutex_Attr'Access);
 930       pragma Assert (Result = 0 or else Result = ENOMEM);
 931
 932       if Result = ENOMEM then
 933          raise Storage_Error;
 934       end if;
 935
 936       --  Initialize internal condition variable
 937
 938       Result := pthread_cond_init (S.CV'Access, Cond_Attr'Access);
 939       pragma Assert (Result = 0 or else Result = ENOMEM);
 940
 941       if Result /= 0 then
 942          Result := pthread_mutex_destroy (S.L'Access);
 943          pragma Assert (Result = 0);
 944
 945          if Result = ENOMEM then
 946             raise Storage_Error;
 947          end if;
 948       end if;
 949    end Initialize;
 950
 951    --------------
 952    -- Finalize --
 953    --------------
 954
 955    procedure Finalize (S : in out Suspension_Object) is
 956       Result  : Interfaces.C.int;
 957
 958    begin
 959       --  Destroy internal mutex
 960
 961       Result := pthread_mutex_destroy (S.L'Access);
 962       pragma Assert (Result = 0);
 963
 964       --  Destroy internal condition variable
 965
 966       Result := pthread_cond_destroy (S.CV'Access);
 967       pragma Assert (Result = 0);
 968    end Finalize;
 969
 970    -------------------
 971    -- Current_State --
 972    -------------------
 973
 974    function Current_State (S : Suspension_Object) return Boolean is
 975    begin
 976       --  We do not want to use lock on this read operation. State is marked
 977       --  as Atomic so that we ensure that the value retrieved is correct.
 978
 979       return S.State;
 980    end Current_State;
 981
 982    ---------------
 983    -- Set_False --
 984    ---------------
 985
 986    procedure Set_False (S : in out Suspension_Object) is
 987       Result  : Interfaces.C.int;
 988
 989    begin
 990       SSL.Abort_Defer.all;
 991
 992       Result := pthread_mutex_lock (S.L'Access);
 993       pragma Assert (Result = 0);
 994
 995       S.State := False;
 996
 997       Result := pthread_mutex_unlock (S.L'Access);
 998       pragma Assert (Result = 0);
 999
1000       SSL.Abort_Undefer.all;
1001    end Set_False;
1002
1003    --------------
1004    -- Set_True --
1005    --------------
1006
1007    procedure Set_True (S : in out Suspension_Object) is
1008       Result : Interfaces.C.int;
1009
1010    begin
1011       SSL.Abort_Defer.all;
1012
1013       Result := pthread_mutex_lock (S.L'Access);
1014       pragma Assert (Result = 0);
1015
1016       --  If there is already a task waiting on this suspension object then
1017       --  we resume it, leaving the state of the suspension object to False,
1018       --  as it is specified in ARM D.10 par. 9. Otherwise, it just leaves
1019       --  the state to True.
1020
1021       if S.Waiting then
1022          S.Waiting := False;
1023          S.State := False;
1024
1025          Result := pthread_cond_signal (S.CV'Access);
1026          pragma Assert (Result = 0);
1027
1028       else
1029          S.State := True;
1030       end if;
1031
1032       Result := pthread_mutex_unlock (S.L'Access);
1033       pragma Assert (Result = 0);
1034
1035       SSL.Abort_Undefer.all;
1036    end Set_True;
1037
1038    ------------------------
1039    -- Suspend_Until_True --
1040    ------------------------
1041
1042    procedure Suspend_Until_True (S : in out Suspension_Object) is
1043       Result : Interfaces.C.int;
1044
1045    begin
1046       SSL.Abort_Defer.all;
1047
1048       Result := pthread_mutex_lock (S.L'Access);
1049       pragma Assert (Result = 0);
1050
1051       if S.Waiting then
1052          --  Program_Error must be raised upon calling Suspend_Until_True
1053          --  if another task is already waiting on that suspension object
1054          --  (ARM D.10 par. 10).
1055
1056          Result := pthread_mutex_unlock (S.L'Access);
1057          pragma Assert (Result = 0);
1058
1059          SSL.Abort_Undefer.all;
1060
1061          raise Program_Error;
1062       else
1063          --  Suspend the task if the state is False. Otherwise, the task
1064          --  continues its execution, and the state of the suspension object
1065          --  is set to False (ARM D.10 par. 9).
1066
1067          if S.State then
1068             S.State := False;
1069          else
1070             S.Waiting := True;
1071
1072             loop
1073                --  Loop in case pthread_cond_wait returns earlier than expected
1074                --  (e.g. in case of EINTR caused by a signal).
1075
1076                Result := pthread_cond_wait (S.CV'Access, S.L'Access);
1077                pragma Assert (Result = 0 or else Result = EINTR);
1078
1079                exit when not S.Waiting;
1080             end loop;
1081          end if;
1082
1083          Result := pthread_mutex_unlock (S.L'Access);
1084          pragma Assert (Result = 0);
1085
1086          SSL.Abort_Undefer.all;
1087       end if;
1088    end Suspend_Until_True;
1089
1090    ----------------
1091    -- Check_Exit --
1092    ----------------
1093
1094    --  Dummy version
1095
1096    function Check_Exit (Self_ID : ST.Task_Id) return Boolean is
1097       pragma Unreferenced (Self_ID);
1098    begin
1099       return True;
1100    end Check_Exit;
1101
1102    --------------------
1103    -- Check_No_Locks --
1104    --------------------
1105
1106    function Check_No_Locks (Self_ID : ST.Task_Id) return Boolean is
1107       pragma Unreferenced (Self_ID);
1108    begin
1109       return True;
1110    end Check_No_Locks;
1111
1112    ----------------------
1113    -- Environment_Task --
1114    ----------------------
1115
1116    function Environment_Task return Task_Id is
1117    begin
1118       return Environment_Task_Id;
1119    end Environment_Task;
1120
1121    --------------
1122    -- Lock_RTS --
1123    --------------
1124
1125    procedure Lock_RTS is
1126    begin
1127       Write_Lock (Single_RTS_Lock'Access, Global_Lock => True);
1128    end Lock_RTS;
1129
1130    ----------------
1131    -- Unlock_RTS --
1132    ----------------
1133
1134    procedure Unlock_RTS is
1135    begin
1136       Unlock (Single_RTS_Lock'Access, Global_Lock => True);
1137    end Unlock_RTS;
1138
1139    ------------------
1140    -- Suspend_Task --
1141    ------------------
1142
1143    function Suspend_Task
1144      (T           : ST.Task_Id;
1145       Thread_Self : Thread_Id) return Boolean
1146    is
1147       pragma Unreferenced (T);
1148       pragma Unreferenced (Thread_Self);
1149    begin
1150       return False;
1151    end Suspend_Task;
1152
1153    -----------------
1154    -- Resume_Task --
1155    -----------------
1156
1157    function Resume_Task
1158      (T           : ST.Task_Id;
1159       Thread_Self : Thread_Id) return Boolean
1160    is
1161       pragma Unreferenced (T);
1162       pragma Unreferenced (Thread_Self);
1163    begin
1164       return False;
1165    end Resume_Task;
1166
1167    --------------------
1168    -- Stop_All_Tasks --
1169    --------------------
1170
1171    procedure Stop_All_Tasks is
1172    begin
1173       null;
1174    end Stop_All_Tasks;
1175
1176    ---------------
1177    -- Stop_Task --
1178    ---------------
1179
1180    function Stop_Task (T : ST.Task_Id) return Boolean is
1181       pragma Unreferenced (T);
1182    begin
1183       return False;
1184    end Stop_Task;
1185
1186    -------------------
1187    -- Continue_Task --
1188    -------------------
1189
1190    function Continue_Task (T : ST.Task_Id) return Boolean is
1191       pragma Unreferenced (T);
1192    begin
1193       return False;
1194    end Continue_Task;
1195
1196    ----------------
1197    -- Initialize --
1198    ----------------
1199
1200    procedure Initialize (Environment_Task : Task_Id) is
1201       act     : aliased struct_sigaction;
1202       old_act : aliased struct_sigaction;
1203       Tmp_Set : aliased sigset_t;
1204       Result  : Interfaces.C.int;
1205
1206       function State
1207         (Int : System.Interrupt_Management.Interrupt_ID) return Character;
1208       pragma Import (C, State, "__gnat_get_interrupt_state");
1209       --  Get interrupt state. Defined in a-init.c. The input argument is
1210       --  the interrupt number, and the result is one of the following:
1211
1212       Default : constant Character := 's';
1213       --    'n'   this interrupt not set by any Interrupt_State pragma
1214       --    'u'   Interrupt_State pragma set state to User
1215       --    'r'   Interrupt_State pragma set state to Runtime
1216       --    's'   Interrupt_State pragma set state to System (use "default"
1217       --           system handler)
1218
1219    begin
1220       Environment_Task_Id := Environment_Task;
1221
1222       Interrupt_Management.Initialize;
1223
1224       --  Initialize the lock used to synchronize chain of all ATCBs
1225
1226       Initialize_Lock (Single_RTS_Lock'Access, RTS_Lock_Level);
1227
1228       Specific.Initialize (Environment_Task);
1229
1230       --  Make environment task known here because it doesn't go through
1231       --  Activate_Tasks, which does it for all other tasks.
1232
1233       Known_Tasks (Known_Tasks'First) := Environment_Task;
1234       Environment_Task.Known_Tasks_Index := Known_Tasks'First;
1235
1236       Enter_Task (Environment_Task);
1237
1238       --  Install the abort-signal handler
1239
1240       if State (System.Interrupt_Management.Abort_Task_Interrupt)
1241                                                      /= Default
1242       then
1243          act.sa_flags := 0;
1244          act.sa_handler := Abort_Handler'Address;
1245
1246          Result := sigemptyset (Tmp_Set'Access);
1247          pragma Assert (Result = 0);
1248          act.sa_mask := Tmp_Set;
1249
1250          Result :=
1251            sigaction (
1252              Signal (System.Interrupt_Management.Abort_Task_Interrupt),
1253              act'Unchecked_Access,
1254              old_act'Unchecked_Access);
1255          pragma Assert (Result = 0);
1256       end if;
1257    end Initialize;
1258
1259    --  NOTE: Unlike other pthread implementations, we do *not* mask all
1260    --  signals here since we handle signals using the process-wide primitive
1261    --  signal, rather than using sigthreadmask and sigwait. The reason of
1262    --  this difference is that sigwait doesn't work when some critical
1263    --  signals (SIGABRT, SIGPIPE) are masked.
1264
1265 end System.Task_Primitives.Operations;