gcc/ada/s-taprob.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --      S Y S T E M . T A S K I N G . P R O T E C T E D _ O B J E C T S     --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --             Copyright (C) 1991-1994, Florida State University            --
  10 --             Copyright (C) 1995-2003, Ada Core Technologies               --
  11 --                                                                          --
  12 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNARL was developed by the GNARL team at Florida State University.       --
  31 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 pragma Polling (Off);
  36 --  Turn off polling, we do not want ATC polling to take place during
  37 --  tasking operations. It causes infinite loops and other problems.
  38
  39 with System.Task_Primitives.Operations;
  40 --  used for Write_Lock
  41 --           Unlock
  42
  43 with System.Parameters;
  44 --  used for Runtime_Traces
  45
  46 with System.Traces;
  47 --  used for Send_Trace_Info
  48
  49 package body System.Tasking.Protected_Objects is
  50
  51    use System.Task_Primitives.Operations;
  52    use System.Traces;
  53
  54    -------------------------
  55    -- Finalize_Protection --
  56    -------------------------
  57
  58    procedure Finalize_Protection (Object : in out Protection) is
  59    begin
  60       Finalize_Lock (Object.L'Unrestricted_Access);
  61    end Finalize_Protection;
  62
  63    ---------------------------
  64    -- Initialize_Protection --
  65    ---------------------------
  66
  67    procedure Initialize_Protection
  68      (Object           : Protection_Access;
  69       Ceiling_Priority : Integer)
  70    is
  71       Init_Priority : Integer := Ceiling_Priority;
  72    begin
  73       if Init_Priority = Unspecified_Priority then
  74          Init_Priority  := System.Priority'Last;
  75       end if;
  76
  77       Initialize_Lock (Init_Priority, Object.L'Access);
  78       Object.Ceiling := System.Any_Priority (Init_Priority);
  79    end Initialize_Protection;
  80
  81    ----------
  82    -- Lock --
  83    ----------
  84
  85    procedure Lock (Object : Protection_Access) is
  86       Ceiling_Violation : Boolean;
  87    begin
  88       --  The lock is made without defering abortion.
  89
  90       --  Therefore the abortion has to be deferred before calling this
  91       --  routine. This means that the compiler has to generate a Defer_Abort
  92       --  call before the call to Lock.
  93
  94       --  The caller is responsible for undeferring abortion, and compiler
  95       --  generated calls must be protected with cleanup handlers to ensure
  96       --  that abortion is undeferred in all cases.
  97
  98       Write_Lock (Object.L'Access, Ceiling_Violation);
  99
 100       if Parameters.Runtime_Traces then
 101          Send_Trace_Info (PO_Lock);
 102       end if;
 103
 104       if Ceiling_Violation then
 105          raise Program_Error;
 106       end if;
 107    end Lock;
 108
 109    --------------------
 110    -- Lock_Read_Only --
 111    --------------------
 112
 113    procedure Lock_Read_Only (Object : Protection_Access) is
 114       Ceiling_Violation : Boolean;
 115    begin
 116       Read_Lock (Object.L'Access, Ceiling_Violation);
 117
 118       if Parameters.Runtime_Traces then
 119          Send_Trace_Info (PO_Lock);
 120       end if;
 121
 122       if Ceiling_Violation then
 123          raise Program_Error;
 124       end if;
 125    end Lock_Read_Only;
 126
 127    ------------
 128    -- Unlock --
 129    ------------
 130
 131    procedure Unlock (Object : Protection_Access) is
 132    begin
 133       Unlock (Object.L'Access);
 134
 135       if Parameters.Runtime_Traces then
 136          Send_Trace_Info (PO_Unlock);
 137       end if;
 138    end Unlock;
 139
 140 end System.Tasking.Protected_Objects;