gcc/ada/s-stalib.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --              S Y S T E M . S T A N D A R D _ L I B R A R Y               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This package is included in all programs. It contains declarations that
  33 --  are required to be part of every Ada program. A special mechanism is
  34 --  required to ensure that these are loaded, since it may be the case in
  35 --  some programs that the only references to these required packages are
  36 --  from C code or from code generated directly by Gigi, an in both cases
  37 --  the binder is not aware of such references.
  38
  39 --  System.Standard_Library also includes data that must be present in every
  40 --  program, in particular the definitions of all the standard and also some
  41 --  subprograms that must be present in every program.
  42
  43 --  The binder unconditionally includes s-stalib.ali, which ensures that this
  44 --  package and the packages it references are included in all Ada programs,
  45 --  together with the included data.
  46
  47 pragma Compiler_Unit;
  48
  49 pragma Polling (Off);
  50 --  We must turn polling off for this unit, because otherwise we get
  51 --  elaboration circularities with Ada.Exceptions if polling is on.
  52
  53 with System;
  54 with Ada.Unchecked_Conversion;
  55
  56 package System.Standard_Library is
  57    pragma Warnings (Off);
  58    pragma Preelaborate_05;
  59    pragma Warnings (On);
  60
  61    type Big_String_Ptr is access all String (Positive);
  62    for Big_String_Ptr'Storage_Size use 0;
  63    --  A non-fat pointer type for null terminated strings
  64
  65    function To_Ptr is
  66      new Ada.Unchecked_Conversion (System.Address, Big_String_Ptr);
  67
  68    ---------------------------------------------
  69    -- Type For Enumeration Image Index Tables --
  70    ---------------------------------------------
  71
  72    --  Note: these types are declared at the start of this unit, since
  73    --  they must appear before any enumeration types declared in this
  74    --  unit. Note that the spec of system is already elaborated at
  75    --  this point (since we are a child of system), which means that
  76    --  enumeration types in package System cannot use these types.
  77
  78    type Image_Index_Table_8 is
  79      array (Integer range <>) of Short_Short_Integer;
  80    type Image_Index_Table_16 is
  81      array (Integer range <>) of Short_Integer;
  82    type Image_Index_Table_32 is
  83      array (Integer range <>) of Integer;
  84    --  These types are used to generate the index vector used for enumeration
  85    --  type image tables. See spec of Exp_Imgv in the main GNAT sources for a
  86    --  full description of the data structures that are used here.
  87
  88    -------------------------------------
  89    -- Exception Declarations and Data --
  90    -------------------------------------
  91
  92    type Raise_Action is access procedure;
  93    --  A pointer to a procedure used in the Raise_Hook field
  94
  95    type Exception_Data;
  96    type Exception_Data_Ptr is access all Exception_Data;
  97    --  An equivalent of Exception_Id that is public
  98
  99    type Exception_Code is mod 2 ** Integer'Size;
 100    --  A scalar value bound to some exception data. Typically used for
 101    --  imported or exported exceptions on VMS. Having a separate type for this
 102    --  is useful to enforce consistency throughout the various run-time units
 103    --  handling such codes, and having it unsigned is the most appropriate
 104    --  choice for it's currently single use on VMS.
 105
 106    --  ??? The construction in Cstand has no way to access the proper type
 107    --  node for Exception_Code, and currently uses Standard_Unsigned as a
 108    --  fallback. The representations shall match, and the size clause below
 109    --  is aimed at ensuring that.
 110
 111    for Exception_Code'Size use Integer'Size;
 112
 113    --  The following record defines the underlying representation of exceptions
 114
 115    --  WARNING! Any changes to this may need to be reflected in the following
 116    --  locations in the compiler and runtime code:
 117
 118    --    1. The Internal_Exception routine in s-exctab.adb
 119    --    2. The processing in gigi that tests Not_Handled_By_Others
 120    --    3. Expand_N_Exception_Declaration in Exp_Ch11
 121    --    4. The construction of the exception type in Cstand
 122
 123    type Exception_Data is record
 124       Not_Handled_By_Others : Boolean;
 125       --  Normally set False, indicating that the exception is handled in the
 126       --  usual way by others (i.e. an others handler handles the exception).
 127       --  Set True to indicate that this exception is not caught by others
 128       --  handlers, but must be explicitly named in a handler. This latter
 129       --  setting is currently used by the Abort_Signal.
 130
 131       Lang : Character;
 132       --  A character indicating the language raising the exception.
 133       --  Set to "A" for exceptions defined by an Ada program.
 134       --  Set to "V" for imported VMS exceptions.
 135
 136       Name_Length : Natural;
 137       --  Length of fully expanded name of exception
 138
 139       Full_Name : System.Address;
 140       --  Fully expanded name of exception, null terminated
 141       --  You can use To_Ptr to convert this to a string.
 142
 143       HTable_Ptr : Exception_Data_Ptr;
 144       --  Hash table pointer used to link entries together in the hash table
 145       --  built (by Register_Exception in s-exctab.adb) for converting between
 146       --  identities and names.
 147
 148       Import_Code : Exception_Code;
 149       --  Value for imported exceptions. Needed only for the handling of
 150       --  Import/Export_Exception for the VMS case, but present in all
 151       --  implementations (we might well extend this mechanism for other
 152       --  systems in the future).
 153
 154       Raise_Hook : Raise_Action;
 155       --  This field can be used to place a "hook" on an exception. If the
 156       --  value is non-null, then it points to a procedure which is called
 157       --  whenever the exception is raised. This call occurs immediately,
 158       --  before any other actions taken by the raise (and in particular
 159       --  before any unwinding of the stack occurs).
 160    end record;
 161
 162    --  Definitions for standard predefined exceptions defined in Standard,
 163
 164    --  Why are the NULs necessary here, seems like they should not be
 165    --  required, since Gigi is supposed to add a Nul to each name ???
 166
 167    Constraint_Error_Name : constant String := "CONSTRAINT_ERROR" & ASCII.NUL;
 168    Program_Error_Name    : constant String := "PROGRAM_ERROR"    & ASCII.NUL;
 169    Storage_Error_Name    : constant String := "STORAGE_ERROR"    & ASCII.NUL;
 170    Tasking_Error_Name    : constant String := "TASKING_ERROR"    & ASCII.NUL;
 171    Abort_Signal_Name     : constant String := "_ABORT_SIGNAL"    & ASCII.NUL;
 172
 173    Numeric_Error_Name    : constant String := "NUMERIC_ERROR"    & ASCII.NUL;
 174    --  This is used only in the Ada 83 case, but it is not worth having a
 175    --  separate version of s-stalib.ads for use in Ada 83 mode.
 176
 177    Constraint_Error_Def : aliased Exception_Data :=
 178      (Not_Handled_By_Others => False,
 179       Lang                  => 'A',
 180       Name_Length           => Constraint_Error_Name'Length,
 181       Full_Name             => Constraint_Error_Name'Address,
 182       HTable_Ptr            => null,
 183       Import_Code           => 0,
 184       Raise_Hook            => null);
 185
 186    Numeric_Error_Def : aliased Exception_Data :=
 187      (Not_Handled_By_Others => False,
 188       Lang                  => 'A',
 189       Name_Length           => Numeric_Error_Name'Length,
 190       Full_Name             => Numeric_Error_Name'Address,
 191       HTable_Ptr            => null,
 192       Import_Code           => 0,
 193       Raise_Hook            => null);
 194
 195    Program_Error_Def : aliased Exception_Data :=
 196      (Not_Handled_By_Others => False,
 197       Lang                  => 'A',
 198       Name_Length           => Program_Error_Name'Length,
 199       Full_Name             => Program_Error_Name'Address,
 200       HTable_Ptr            => null,
 201       Import_Code           => 0,
 202       Raise_Hook            => null);
 203
 204    Storage_Error_Def : aliased Exception_Data :=
 205      (Not_Handled_By_Others => False,
 206       Lang                  => 'A',
 207       Name_Length           => Storage_Error_Name'Length,
 208       Full_Name             => Storage_Error_Name'Address,
 209       HTable_Ptr            => null,
 210       Import_Code           => 0,
 211       Raise_Hook            => null);
 212
 213    Tasking_Error_Def : aliased Exception_Data :=
 214      (Not_Handled_By_Others => False,
 215       Lang                  => 'A',
 216       Name_Length           => Tasking_Error_Name'Length,
 217       Full_Name             => Tasking_Error_Name'Address,
 218       HTable_Ptr            => null,
 219       Import_Code           => 0,
 220       Raise_Hook            => null);
 221
 222    Abort_Signal_Def : aliased Exception_Data :=
 223      (Not_Handled_By_Others => True,
 224       Lang                  => 'A',
 225       Name_Length           => Abort_Signal_Name'Length,
 226       Full_Name             => Abort_Signal_Name'Address,
 227       HTable_Ptr            => null,
 228       Import_Code           => 0,
 229       Raise_Hook            => null);
 230
 231    pragma Export (C, Constraint_Error_Def, "constraint_error");
 232    pragma Export (C, Numeric_Error_Def,    "numeric_error");
 233    pragma Export (C, Program_Error_Def,    "program_error");
 234    pragma Export (C, Storage_Error_Def,    "storage_error");
 235    pragma Export (C, Tasking_Error_Def,    "tasking_error");
 236    pragma Export (C, Abort_Signal_Def,     "_abort_signal");
 237
 238    Local_Partition_ID : Natural := 0;
 239    --  This variable contains the local Partition_ID that will be used when
 240    --  building exception occurrences. In distributed mode, it will be
 241    --  set by each partition to the correct value during the elaboration.
 242
 243    type Exception_Trace_Kind is
 244      (RM_Convention,
 245       --  No particular trace is requested, only unhandled exceptions
 246       --  in the environment task (following the RM) will be printed.
 247       --  This is the default behavior.
 248
 249       Every_Raise,
 250       --  Denotes every possible raise event, either explicit or due to
 251       --  a specific language rule, within the context of a task or not.
 252
 253       Unhandled_Raise
 254       --  Denotes the raise events corresponding to exceptions for which
 255       --  there is no user defined handler.
 256      );
 257    --  Provide a way to denote different kinds of automatic traces related
 258    --  to exceptions that can be requested.
 259
 260    Exception_Trace : Exception_Trace_Kind := RM_Convention;
 261    pragma Atomic (Exception_Trace);
 262    --  By default, follow the RM convention
 263
 264    -----------------
 265    -- Subprograms --
 266    -----------------
 267
 268    procedure Abort_Undefer_Direct;
 269    pragma Inline (Abort_Undefer_Direct);
 270    --  A little procedure that just calls Abort_Undefer.all, for use in
 271    --  clean up procedures, which only permit a simple subprogram name.
 272
 273    procedure Adafinal;
 274    --  Performs the Ada Runtime finalization the first time it is invoked.
 275    --  All subsequent calls are ignored.
 276
 277 end System.Standard_Library;