gcc/ada/s-stalib.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --              S Y S T E M . S T A N D A R D _ L I B R A R Y               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2002 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package is included in all programs. It contains declarations that
  35 --  are required to be part of every Ada program. A special mechanism is
  36 --  required to ensure that these are loaded, since it may be the case in
  37 --  some programs that the only references to these required packages are
  38 --  from C code or from code generated directly by Gigi, an in both cases
  39 --  the binder is not aware of such references.
  40
  41 --  System.Standard_Library also includes data that must be present in every
  42 --  program, in particular the definitions of all the standard and also some
  43 --  subprograms that must be present in every program.
  44
  45 --  The binder unconditionally includes s-stalib.ali, which ensures that this
  46 --  package and the packages it references are included in all Ada programs,
  47 --  together with the included data.
  48
  49 pragma Polling (Off);
  50 --  We must turn polling off for this unit, because otherwise we get
  51 --  elaboration circularities with Ada.Exceptions if polling is on.
  52
  53 with System;
  54 with Unchecked_Conversion;
  55
  56 package System.Standard_Library is
  57
  58    pragma Suppress (All_Checks);
  59    --  Suppress explicitely all the checks to work around the Solaris linker
  60    --  bug when using gnatmake -f -a (but without -gnatp). This is not needed
  61    --  with Solaris 2.6, so eventually can be removed ???
  62
  63    type Big_String_Ptr is access all String (Positive);
  64    --  A non-fat pointer type for null terminated strings
  65
  66    function To_Ptr is
  67      new Unchecked_Conversion (System.Address, Big_String_Ptr);
  68
  69    ---------------------------------------------
  70    -- Type For Enumeration Image Index Tables --
  71    ---------------------------------------------
  72
  73    --  Note: these types are declared at the start of this unit, since
  74    --  they must appear before any enumeration types declared in this
  75    --  unit. Note that the spec of system is already elaborated at
  76    --  this point (since we are a child of system), which means that
  77    --  enumeration types in package System cannot use these types.
  78
  79    type Image_Index_Table_8 is
  80      array (Integer range <>) of Short_Short_Integer;
  81    type Image_Index_Table_16 is
  82      array (Integer range <>) of Short_Integer;
  83    type Image_Index_Table_32 is
  84      array (Integer range <>) of Integer;
  85    --  These types are used to generate the index vector used for enumeration
  86    --  type image tables. See spec of Exp_Imgv in the main GNAT sources for a
  87    --  full description of the data structures that are used here.
  88
  89    -------------------------------------
  90    -- Exception Declarations and Data --
  91    -------------------------------------
  92
  93    type Raise_Action is access procedure;
  94    --  A pointer to a procedure used in the Raise_Hook field
  95
  96    type Exception_Data;
  97    type Exception_Data_Ptr is access all Exception_Data;
  98    --  An equivalent of Exception_Id that is public
  99
 100    --  The following record defines the underlying representation of exceptions
 101
 102    --  WARNING! Any changes to this may need to be reflectd in the following
 103    --  locations in the compiler and runtime code:
 104
 105    --    1. The Internal_Exception routine in s-exctab.adb
 106    --    2. The processing in gigi that tests Not_Handled_By_Others
 107    --    3. Expand_N_Exception_Declaration in Exp_Ch11
 108    --    4. The construction of the exception type in Cstand
 109
 110    type Exception_Data is record
 111       Not_Handled_By_Others : Boolean;
 112       --  Normally set False, indicating that the exception is handled in the
 113       --  usual way by others (i.e. an others handler handles the exception).
 114       --  Set True to indicate that this exception is not caught by others
 115       --  handlers, but must be explicitly named in a handler. This latter
 116       --  setting is currently used by the Abort_Signal.
 117
 118       Lang : Character;
 119       --  A character indicating the language raising the exception.
 120       --  Set to "A" for exceptions defined by an Ada program.
 121       --  Set to "V" for imported VMS exceptions.
 122
 123       Name_Length : Natural;
 124       --  Length of fully expanded name of exception
 125
 126       Full_Name : Big_String_Ptr;
 127       --  Fully expanded name of exception, null terminated
 128
 129       HTable_Ptr : Exception_Data_Ptr;
 130       --  Hash table pointer used to link entries together in the hash table
 131       --  built (by Register_Exception in s-exctab.adb) for converting between
 132       --  identities and names.
 133
 134       Import_Code : Integer;
 135       --  Value for imported exceptions. Needed only for the handling of
 136       --  Import/Export_Exception for the VMS case, but present in all
 137       --  implementations (we might well extend this mechanism for other
 138       --  systems in the future).
 139
 140       Raise_Hook : Raise_Action;
 141       --  This field can be used to place a "hook" on an exception. If the
 142       --  value is non-null, then it points to a procedure which is called
 143       --  whenever the exception is raised. This call occurs immediately,
 144       --  before any other actions taken by the raise (and in particular
 145       --  before any unwinding of the stack occurs).
 146
 147    end record;
 148
 149    --  Definitions for standard predefined exceptions defined in Standard,
 150
 151    --  Why are the Nul's necessary here, seems like they should not be
 152    --  required, since Gigi is supposed to add a Nul to each name ???
 153
 154    Constraint_Error_Name : constant String := "CONSTRAINT_ERROR" & ASCII.NUL;
 155    Program_Error_Name    : constant String := "PROGRAM_ERROR"    & ASCII.NUL;
 156    Storage_Error_Name    : constant String := "STORAGE_ERROR"    & ASCII.NUL;
 157    Tasking_Error_Name    : constant String := "TASKING_ERROR"    & ASCII.NUL;
 158    Abort_Signal_Name     : constant String := "_ABORT_SIGNAL"    & ASCII.NUL;
 159
 160    Numeric_Error_Name    : constant String := "NUMERIC_ERROR"    & ASCII.NUL;
 161    --  This is used only in the Ada 83 case, but it is not worth having a
 162    --  separate version of s-stalib.ads for use in Ada 83 mode.
 163
 164    Constraint_Error_Def : aliased Exception_Data :=
 165      (Not_Handled_By_Others => False,
 166       Lang                  => 'A',
 167       Name_Length           => Constraint_Error_Name'Length,
 168       Full_Name             => To_Ptr (Constraint_Error_Name'Address),
 169       HTable_Ptr            => null,
 170       Import_Code           => 0,
 171       Raise_Hook            => null);
 172
 173    Numeric_Error_Def : aliased Exception_Data :=
 174      (Not_Handled_By_Others => False,
 175       Lang                  => 'A',
 176       Name_Length           => Numeric_Error_Name'Length,
 177       Full_Name             => To_Ptr (Numeric_Error_Name'Address),
 178       HTable_Ptr            => null,
 179       Import_Code           => 0,
 180       Raise_Hook            => null);
 181
 182    Program_Error_Def : aliased Exception_Data :=
 183      (Not_Handled_By_Others => False,
 184       Lang                  => 'A',
 185       Name_Length           => Program_Error_Name'Length,
 186       Full_Name             => To_Ptr (Program_Error_Name'Address),
 187       HTable_Ptr            => null,
 188       Import_Code           => 0,
 189       Raise_Hook            => null);
 190
 191    Storage_Error_Def : aliased Exception_Data :=
 192      (Not_Handled_By_Others => False,
 193       Lang                  => 'A',
 194       Name_Length           => Storage_Error_Name'Length,
 195       Full_Name             => To_Ptr (Storage_Error_Name'Address),
 196       HTable_Ptr            => null,
 197       Import_Code           => 0,
 198       Raise_Hook            => null);
 199
 200    Tasking_Error_Def : aliased Exception_Data :=
 201      (Not_Handled_By_Others => False,
 202       Lang                  => 'A',
 203       Name_Length           => Tasking_Error_Name'Length,
 204       Full_Name             => To_Ptr (Tasking_Error_Name'Address),
 205       HTable_Ptr            => null,
 206       Import_Code           => 0,
 207       Raise_Hook            => null);
 208
 209    Abort_Signal_Def : aliased Exception_Data :=
 210      (Not_Handled_By_Others => True,
 211       Lang                  => 'A',
 212       Name_Length           => Abort_Signal_Name'Length,
 213       Full_Name             => To_Ptr (Abort_Signal_Name'Address),
 214       HTable_Ptr            => null,
 215       Import_Code           => 0,
 216       Raise_Hook            => null);
 217
 218    pragma Export (C, Constraint_Error_Def, "constraint_error");
 219    pragma Export (C, Numeric_Error_Def,    "numeric_error");
 220    pragma Export (C, Program_Error_Def,    "program_error");
 221    pragma Export (C, Storage_Error_Def,    "storage_error");
 222    pragma Export (C, Tasking_Error_Def,    "tasking_error");
 223    pragma Export (C, Abort_Signal_Def,     "_abort_signal");
 224
 225    Local_Partition_ID : Natural := 0;
 226    --  This variable contains the local Partition_ID that will be used when
 227    --  building exception occurrences. In distributed mode, it will be
 228    --  set by each partition to the correct value during the elaboration.
 229
 230    type Exception_Trace_Kind is
 231      (RM_Convention,
 232       --  No particular trace is requested, only unhandled exceptions
 233       --  in the environment task (following the RM) will be printed.
 234       --  This is the default behavior.
 235
 236       Every_Raise,
 237       --  Denotes every possible raise event, either explicit or due to
 238       --  a specific language rule, within the context of a task or not.
 239
 240       Unhandled_Raise
 241       --  Denotes the raise events corresponding to exceptions for which
 242       --  there is no user defined handler.
 243      );
 244    --  Provide a way to denote different kinds of automatic traces related
 245    --  to exceptions that can be requested.
 246
 247    Exception_Trace : Exception_Trace_Kind := RM_Convention;
 248    pragma Atomic (Exception_Trace);
 249    --  By default, follow the RM convention.
 250
 251    -----------------
 252    -- Subprograms --
 253    -----------------
 254
 255    procedure Abort_Undefer_Direct;
 256    pragma Inline (Abort_Undefer_Direct);
 257    --  A little procedure that just calls Abort_Undefer.all, for use in
 258    --  clean up procedures, which only permit a simple subprogram name.
 259
 260    procedure Adafinal;
 261    --  Performs the Ada Runtime finalization the first time it is invoked.
 262    --  All subsequent calls are ignored.
 263
 264 end System.Standard_Library;