gcc/ada/s-stalib.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --              S Y S T E M . S T A N D A R D _ L I B R A R Y               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package is included in all programs. It contains declarations that
  35 --  are required to be part of every Ada program. A special mechanism is
  36 --  required to ensure that these are loaded, since it may be the case in
  37 --  some programs that the only references to these required packages are
  38 --  from C code or from code generated directly by Gigi, an in both cases
  39 --  the binder is not aware of such references.
  40
  41 --  System.Standard_Library also includes data that must be present in every
  42 --  program, in particular the definitions of all the standard and also some
  43 --  subprograms that must be present in every program.
  44
  45 --  The binder unconditionally includes s-stalib.ali, which ensures that this
  46 --  package and the packages it references are included in all Ada programs,
  47 --  together with the included data.
  48
  49 pragma Warnings (Off);
  50 pragma Compiler_Unit;
  51 pragma Warnings (On);
  52
  53 pragma Polling (Off);
  54 --  We must turn polling off for this unit, because otherwise we get
  55 --  elaboration circularities with Ada.Exceptions if polling is on.
  56
  57 with System;
  58 with Ada.Unchecked_Conversion;
  59
  60 package System.Standard_Library is
  61    pragma Warnings (Off);
  62    pragma Preelaborate_05;
  63    pragma Warnings (On);
  64
  65    type Big_String_Ptr is access all String (Positive);
  66    for Big_String_Ptr'Storage_Size use 0;
  67    --  A non-fat pointer type for null terminated strings
  68
  69    function To_Ptr is
  70      new Ada.Unchecked_Conversion (System.Address, Big_String_Ptr);
  71
  72    ---------------------------------------------
  73    -- Type For Enumeration Image Index Tables --
  74    ---------------------------------------------
  75
  76    --  Note: these types are declared at the start of this unit, since
  77    --  they must appear before any enumeration types declared in this
  78    --  unit. Note that the spec of system is already elaborated at
  79    --  this point (since we are a child of system), which means that
  80    --  enumeration types in package System cannot use these types.
  81
  82    type Image_Index_Table_8 is
  83      array (Integer range <>) of Short_Short_Integer;
  84    type Image_Index_Table_16 is
  85      array (Integer range <>) of Short_Integer;
  86    type Image_Index_Table_32 is
  87      array (Integer range <>) of Integer;
  88    --  These types are used to generate the index vector used for enumeration
  89    --  type image tables. See spec of Exp_Imgv in the main GNAT sources for a
  90    --  full description of the data structures that are used here.
  91
  92    -------------------------------------
  93    -- Exception Declarations and Data --
  94    -------------------------------------
  95
  96    type Raise_Action is access procedure;
  97    --  A pointer to a procedure used in the Raise_Hook field
  98
  99    type Exception_Data;
 100    type Exception_Data_Ptr is access all Exception_Data;
 101    --  An equivalent of Exception_Id that is public
 102
 103    type Exception_Code is mod 2 ** Integer'Size;
 104    --  A scalar value bound to some exception data. Typically used for
 105    --  imported or exported exceptions on VMS. Having a separate type for this
 106    --  is useful to enforce consistency throughout the various run-time units
 107    --  handling such codes, and having it unsigned is the most appropriate
 108    --  choice for it's currently single use on VMS.
 109
 110    --  ??? The construction in Cstand has no way to access the proper type
 111    --  node for Exception_Code, and currently uses Standard_Unsigned as a
 112    --  fallback. The representations shall match, and the size clause below
 113    --  is aimed at ensuring that.
 114
 115    for Exception_Code'Size use Integer'Size;
 116
 117    --  The following record defines the underlying representation of exceptions
 118
 119    --  WARNING! Any changes to this may need to be reflected in the following
 120    --  locations in the compiler and runtime code:
 121
 122    --    1. The Internal_Exception routine in s-exctab.adb
 123    --    2. The processing in gigi that tests Not_Handled_By_Others
 124    --    3. Expand_N_Exception_Declaration in Exp_Ch11
 125    --    4. The construction of the exception type in Cstand
 126
 127    type Exception_Data is record
 128       Not_Handled_By_Others : Boolean;
 129       --  Normally set False, indicating that the exception is handled in the
 130       --  usual way by others (i.e. an others handler handles the exception).
 131       --  Set True to indicate that this exception is not caught by others
 132       --  handlers, but must be explicitly named in a handler. This latter
 133       --  setting is currently used by the Abort_Signal.
 134
 135       Lang : Character;
 136       --  A character indicating the language raising the exception.
 137       --  Set to "A" for exceptions defined by an Ada program.
 138       --  Set to "V" for imported VMS exceptions.
 139
 140       Name_Length : Natural;
 141       --  Length of fully expanded name of exception
 142
 143       Full_Name : System.Address;
 144       --  Fully expanded name of exception, null terminated
 145       --  You can use To_Ptr to convert this to a string.
 146
 147       HTable_Ptr : Exception_Data_Ptr;
 148       --  Hash table pointer used to link entries together in the hash table
 149       --  built (by Register_Exception in s-exctab.adb) for converting between
 150       --  identities and names.
 151
 152       Import_Code : Exception_Code;
 153       --  Value for imported exceptions. Needed only for the handling of
 154       --  Import/Export_Exception for the VMS case, but present in all
 155       --  implementations (we might well extend this mechanism for other
 156       --  systems in the future).
 157
 158       Raise_Hook : Raise_Action;
 159       --  This field can be used to place a "hook" on an exception. If the
 160       --  value is non-null, then it points to a procedure which is called
 161       --  whenever the exception is raised. This call occurs immediately,
 162       --  before any other actions taken by the raise (and in particular
 163       --  before any unwinding of the stack occurs).
 164    end record;
 165
 166    --  Definitions for standard predefined exceptions defined in Standard,
 167
 168    --  Why are the NULs necessary here, seems like they should not be
 169    --  required, since Gigi is supposed to add a Nul to each name ???
 170
 171    Constraint_Error_Name : constant String := "CONSTRAINT_ERROR" & ASCII.NUL;
 172    Program_Error_Name    : constant String := "PROGRAM_ERROR"    & ASCII.NUL;
 173    Storage_Error_Name    : constant String := "STORAGE_ERROR"    & ASCII.NUL;
 174    Tasking_Error_Name    : constant String := "TASKING_ERROR"    & ASCII.NUL;
 175    Abort_Signal_Name     : constant String := "_ABORT_SIGNAL"    & ASCII.NUL;
 176
 177    Numeric_Error_Name    : constant String := "NUMERIC_ERROR"    & ASCII.NUL;
 178    --  This is used only in the Ada 83 case, but it is not worth having a
 179    --  separate version of s-stalib.ads for use in Ada 83 mode.
 180
 181    Constraint_Error_Def : aliased Exception_Data :=
 182      (Not_Handled_By_Others => False,
 183       Lang                  => 'A',
 184       Name_Length           => Constraint_Error_Name'Length,
 185       Full_Name             => Constraint_Error_Name'Address,
 186       HTable_Ptr            => null,
 187       Import_Code           => 0,
 188       Raise_Hook            => null);
 189
 190    Numeric_Error_Def : aliased Exception_Data :=
 191      (Not_Handled_By_Others => False,
 192       Lang                  => 'A',
 193       Name_Length           => Numeric_Error_Name'Length,
 194       Full_Name             => Numeric_Error_Name'Address,
 195       HTable_Ptr            => null,
 196       Import_Code           => 0,
 197       Raise_Hook            => null);
 198
 199    Program_Error_Def : aliased Exception_Data :=
 200      (Not_Handled_By_Others => False,
 201       Lang                  => 'A',
 202       Name_Length           => Program_Error_Name'Length,
 203       Full_Name             => Program_Error_Name'Address,
 204       HTable_Ptr            => null,
 205       Import_Code           => 0,
 206       Raise_Hook            => null);
 207
 208    Storage_Error_Def : aliased Exception_Data :=
 209      (Not_Handled_By_Others => False,
 210       Lang                  => 'A',
 211       Name_Length           => Storage_Error_Name'Length,
 212       Full_Name             => Storage_Error_Name'Address,
 213       HTable_Ptr            => null,
 214       Import_Code           => 0,
 215       Raise_Hook            => null);
 216
 217    Tasking_Error_Def : aliased Exception_Data :=
 218      (Not_Handled_By_Others => False,
 219       Lang                  => 'A',
 220       Name_Length           => Tasking_Error_Name'Length,
 221       Full_Name             => Tasking_Error_Name'Address,
 222       HTable_Ptr            => null,
 223       Import_Code           => 0,
 224       Raise_Hook            => null);
 225
 226    Abort_Signal_Def : aliased Exception_Data :=
 227      (Not_Handled_By_Others => True,
 228       Lang                  => 'A',
 229       Name_Length           => Abort_Signal_Name'Length,
 230       Full_Name             => Abort_Signal_Name'Address,
 231       HTable_Ptr            => null,
 232       Import_Code           => 0,
 233       Raise_Hook            => null);
 234
 235    pragma Export (C, Constraint_Error_Def, "constraint_error");
 236    pragma Export (C, Numeric_Error_Def,    "numeric_error");
 237    pragma Export (C, Program_Error_Def,    "program_error");
 238    pragma Export (C, Storage_Error_Def,    "storage_error");
 239    pragma Export (C, Tasking_Error_Def,    "tasking_error");
 240    pragma Export (C, Abort_Signal_Def,     "_abort_signal");
 241
 242    Local_Partition_ID : Natural := 0;
 243    --  This variable contains the local Partition_ID that will be used when
 244    --  building exception occurrences. In distributed mode, it will be
 245    --  set by each partition to the correct value during the elaboration.
 246
 247    type Exception_Trace_Kind is
 248      (RM_Convention,
 249       --  No particular trace is requested, only unhandled exceptions
 250       --  in the environment task (following the RM) will be printed.
 251       --  This is the default behavior.
 252
 253       Every_Raise,
 254       --  Denotes every possible raise event, either explicit or due to
 255       --  a specific language rule, within the context of a task or not.
 256
 257       Unhandled_Raise
 258       --  Denotes the raise events corresponding to exceptions for which
 259       --  there is no user defined handler.
 260      );
 261    --  Provide a way to denote different kinds of automatic traces related
 262    --  to exceptions that can be requested.
 263
 264    Exception_Trace : Exception_Trace_Kind := RM_Convention;
 265    pragma Atomic (Exception_Trace);
 266    --  By default, follow the RM convention
 267
 268    -----------------
 269    -- Subprograms --
 270    -----------------
 271
 272    procedure Abort_Undefer_Direct;
 273    pragma Inline (Abort_Undefer_Direct);
 274    --  A little procedure that just calls Abort_Undefer.all, for use in
 275    --  clean up procedures, which only permit a simple subprogram name.
 276
 277    procedure Adafinal;
 278    --  Performs the Ada Runtime finalization the first time it is invoked.
 279    --  All subsequent calls are ignored.
 280
 281 end System.Standard_Library;