gcc/ada/s-pooloc.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                    S Y S T E M . P O O L _ L O C A L                     --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.11 $
  10 --                                                                          --
  11 --          Copyright (C) 1992-2001, Free Software Foundation, Inc.         --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 with System.Memory;
  37 with System.Storage_Elements;
  38 with System.Address_To_Access_Conversions;
  39
  40 package body System.Pool_Local is
  41
  42    package SSE renames System.Storage_Elements;
  43    use type SSE.Storage_Offset;
  44
  45    Pointer_Size  : constant SSE.Storage_Offset := Address'Size / Storage_Unit;
  46    Pointers_Size : constant SSE.Storage_Offset := 2 * Pointer_Size;
  47
  48    type Acc_Address is access all Address;
  49    package Addr is new Address_To_Access_Conversions (Address);
  50
  51    -----------------------
  52    -- Local Subprograms --
  53    -----------------------
  54
  55    function Next (A : Address) return Acc_Address;
  56    --  Given an address of a block, return an access to the next block
  57
  58    function Prev (A : Address) return Acc_Address;
  59    --  Given an address of a block, return an access to the previous block
  60
  61    --------------
  62    -- Allocate --
  63    --------------
  64
  65    procedure Allocate
  66      (Pool         : in out Unbounded_Reclaim_Pool;
  67       Address      : out System.Address;
  68       Storage_Size : SSE.Storage_Count;
  69       Alignment    : SSE.Storage_Count)
  70    is
  71       Allocated : constant System.Address :=
  72         Memory.Alloc (Memory.size_t (Storage_Size + Pointers_Size));
  73
  74    begin
  75       --  The call to Alloc returns an address whose alignment is compatible
  76       --  with the worst case alignment requirement for the machine; thus the
  77       --  Alignment argument can be safely ignored.
  78
  79       if Allocated = Null_Address then
  80          raise Storage_Error;
  81       else
  82          Address := Allocated + Pointers_Size;
  83          Next (Allocated).all := Pool.First;
  84          Prev (Allocated).all := Null_Address;
  85
  86          if Pool.First /= Null_Address then
  87             Prev (Pool.First).all := Allocated;
  88          end if;
  89
  90          Pool.First := Allocated;
  91       end if;
  92    end Allocate;
  93
  94    ----------------
  95    -- Deallocate --
  96    ----------------
  97
  98    procedure Deallocate
  99      (Pool         : in out Unbounded_Reclaim_Pool;
 100       Address      : System.Address;
 101       Storage_Size : SSE.Storage_Count;
 102       Alignment    : SSE.Storage_Count)
 103    is
 104       Allocated : constant System.Address := Address - Pointers_Size;
 105    begin
 106       if Prev (Allocated).all = Null_Address then
 107          Pool.First := Next (Allocated).all;
 108          Prev (Pool.First).all := Null_Address;
 109       else
 110          Next (Prev (Allocated).all).all := Next (Allocated).all;
 111       end if;
 112
 113       if Next (Allocated).all /= Null_Address then
 114          Prev (Next (Allocated).all).all := Prev (Allocated).all;
 115       end if;
 116
 117       Memory.Free (Allocated);
 118    end Deallocate;
 119
 120    --------------
 121    -- Finalize --
 122    --------------
 123
 124    procedure Finalize (Pool : in out Unbounded_Reclaim_Pool) is
 125       N         : System.Address := Pool.First;
 126       Allocated : System.Address;
 127
 128    begin
 129       while N /= Null_Address loop
 130          Allocated := N;
 131          N := Next (N).all;
 132          Memory.Free (Allocated);
 133       end loop;
 134    end Finalize;
 135
 136    ----------
 137    -- Next --
 138    ----------
 139
 140    function Next (A : Address) return Acc_Address is
 141    begin
 142       return Acc_Address (Addr.To_Pointer (A));
 143    end Next;
 144
 145    ----------
 146    -- Prev --
 147    ----------
 148
 149    function Prev (A : Address) return Acc_Address is
 150    begin
 151       return Acc_Address (Addr.To_Pointer (A + Pointer_Size));
 152    end Prev;
 153
 154 end System.Pool_Local;