gcc/ada/s-osinte-vxworks.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                  GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                --
   4 --                                                                          --
   5 --                    S Y S T E M . O S _ I N T E R F A C E                 --
   6 --                                                                          --
   7 --                                   S p e c                                --
   8 --                                                                          --
   9 --             Copyright (C) 1991-1994, Florida State University            --
  10 --          Copyright (C) 1995-2007, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  20 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  21 -- Boston, MA 02110-1301, USA.                                              --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNARL was developed by the GNARL team at Florida State University.       --
  31 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is the VxWorks version of this package
  36
  37 --  This package encapsulates all direct interfaces to OS services
  38 --  that are needed by children of System.
  39
  40 --  PLEASE DO NOT add any with-clauses to this package or remove the pragma
  41 --  Preelaborate. This package is designed to be a bottom-level (leaf) package.
  42
  43 with Interfaces.C;
  44 with System.VxWorks;
  45
  46 package System.OS_Interface is
  47    pragma Preelaborate;
  48
  49    subtype int        is Interfaces.C.int;
  50    subtype short      is Short_Integer;
  51    type unsigned_int  is mod 2 ** int'Size;
  52    type long          is new Long_Integer;
  53    type unsigned_long is mod 2 ** long'Size;
  54    type size_t        is mod 2 ** Standard'Address_Size;
  55
  56    -----------
  57    -- Errno --
  58    -----------
  59
  60    function errno return int;
  61    pragma Import (C, errno, "errnoGet");
  62
  63    EINTR     : constant := 4;
  64    EAGAIN    : constant := 35;
  65    ENOMEM    : constant := 12;
  66    EINVAL    : constant := 22;
  67    ETIMEDOUT : constant := 60;
  68
  69    FUNC_ERR  : constant := -1;
  70
  71    ----------------------------
  72    -- Signals and Interrupts --
  73    ----------------------------
  74
  75    NSIG : constant := 32;
  76    --  Number of signals on the target OS
  77    type Signal is new int range 0 .. Interfaces.C."-" (NSIG, 1);
  78
  79    Max_HW_Interrupt : constant := System.VxWorks.Num_HW_Interrupts - 1;
  80    type HW_Interrupt is new int range 0 .. Max_HW_Interrupt;
  81
  82    Max_Interrupt : constant := Max_HW_Interrupt;
  83
  84    SIGILL  : constant :=  4; --  illegal instruction (not reset)
  85    SIGABRT : constant :=  6; --  used by abort, replace SIGIOT in the future
  86    SIGFPE  : constant :=  8; --  floating point exception
  87    SIGBUS  : constant := 10; --  bus error
  88    SIGSEGV : constant := 11; --  segmentation violation
  89
  90    -----------------------------------
  91    -- Signal processing definitions --
  92    -----------------------------------
  93
  94    --  The how in sigprocmask()
  95
  96    SIG_BLOCK   : constant := 1;
  97    SIG_UNBLOCK : constant := 2;
  98    SIG_SETMASK : constant := 3;
  99
 100    --  The sa_flags in struct sigaction
 101
 102    SA_SIGINFO   : constant := 16#0002#;
 103    SA_ONSTACK   : constant := 16#0004#;
 104
 105    SIG_DFL : constant := 0;
 106    SIG_IGN : constant := 1;
 107
 108    type sigset_t is private;
 109
 110    type struct_sigaction is record
 111       sa_handler : System.Address;
 112       sa_mask    : sigset_t;
 113       sa_flags   : int;
 114    end record;
 115    pragma Convention (C, struct_sigaction);
 116    type struct_sigaction_ptr is access all struct_sigaction;
 117
 118    function sigaddset (set : access sigset_t; sig : Signal) return int;
 119    pragma Import (C, sigaddset, "sigaddset");
 120
 121    function sigdelset (set : access sigset_t; sig : Signal) return int;
 122    pragma Import (C, sigdelset, "sigdelset");
 123
 124    function sigfillset (set : access sigset_t) return int;
 125    pragma Import (C, sigfillset, "sigfillset");
 126
 127    function sigismember (set : access sigset_t; sig : Signal) return int;
 128    pragma Import (C, sigismember, "sigismember");
 129
 130    function sigemptyset (set : access sigset_t) return int;
 131    pragma Import (C, sigemptyset, "sigemptyset");
 132
 133    function sigaction
 134      (sig  : Signal;
 135       act  : struct_sigaction_ptr;
 136       oact : struct_sigaction_ptr) return int;
 137    pragma Import (C, sigaction, "sigaction");
 138
 139    type isr_address is access procedure (sig : int);
 140    pragma Convention (C, isr_address);
 141
 142    function c_signal (sig : Signal; handler : isr_address) return isr_address;
 143    pragma Import (C, c_signal, "signal");
 144
 145    function sigwait (set : access sigset_t; sig : access Signal) return int;
 146    pragma Inline (sigwait);
 147
 148    function pthread_sigmask
 149      (how  : int;
 150       set  : access sigset_t;
 151       oset : access sigset_t) return int;
 152    pragma Import (C, pthread_sigmask, "sigprocmask");
 153
 154    type t_id is new long;
 155    subtype Thread_Id is t_id;
 156
 157    function kill (pid : t_id; sig : Signal) return int;
 158    pragma Inline (kill);
 159
 160    function getpid return t_id;
 161    pragma Inline (getpid);
 162
 163    function Task_Stop (tid : t_id) return int;
 164    pragma Inline (Task_Stop);
 165    --  If we are in the kernel space, stop the task whose t_id is
 166    --  given in parameter in such a way that it can be examined by the
 167    --  debugger. This typically maps to taskSuspend on VxWorks 5 and
 168    --  to taskStop on VxWorks 6.
 169
 170    function Task_Cont (tid : t_id) return int;
 171    pragma Inline (Task_Cont);
 172    --  If we are in the kernel space, continue the task whose t_id is
 173    --  given in parameter if it has been stopped previously to be examined
 174    --  by the debugger (e.g. by taskStop). It typically maps to taskResume
 175    --  on VxWorks 5 and to taskCont on VxWorks 6.
 176
 177    function Int_Lock return int;
 178    pragma Inline (Int_Lock);
 179    --  If we are in the kernel space, lock interrupts. It typically maps to
 180    --  intLock.
 181
 182    function Int_Unlock return int;
 183    pragma Inline (Int_Unlock);
 184    --  If we are in the kernel space, unlock interrupts. It typically maps to
 185    --  intUnlock.
 186
 187    ----------
 188    -- Time --
 189    ----------
 190
 191    type time_t is new unsigned_long;
 192
 193    type timespec is record
 194       ts_sec  : time_t;
 195       ts_nsec : long;
 196    end record;
 197    pragma Convention (C, timespec);
 198
 199    type clockid_t is private;
 200
 201    CLOCK_REALTIME : constant clockid_t;   --  System wide realtime clock
 202
 203    function To_Duration (TS : timespec) return Duration;
 204    pragma Inline (To_Duration);
 205
 206    function To_Timespec (D : Duration) return timespec;
 207    pragma Inline (To_Timespec);
 208
 209    function To_Clock_Ticks (D : Duration) return int;
 210    --  Convert a duration value (in seconds) into clock ticks
 211
 212    function clock_gettime
 213      (clock_id : clockid_t; tp : access timespec) return int;
 214    pragma Import (C, clock_gettime, "clock_gettime");
 215
 216    type ULONG is new unsigned_long;
 217
 218    procedure tickSet (ticks : ULONG);
 219    pragma Import (C, tickSet, "tickSet");
 220
 221    function tickGet return ULONG;
 222    pragma Import (C, tickGet, "tickGet");
 223
 224    ----------------------
 225    -- Utility Routines --
 226    ----------------------
 227
 228    function To_VxWorks_Priority (Priority : int) return int;
 229    pragma Inline (To_VxWorks_Priority);
 230    --  Convenience routine to convert between VxWorks priority and Ada priority
 231
 232    --------------------------
 233    -- VxWorks specific API --
 234    --------------------------
 235
 236    subtype STATUS is int;
 237    --  Equivalent of the C type STATUS
 238
 239    OK    : constant STATUS := 0;
 240    ERROR : constant STATUS := Interfaces.C.int (-1);
 241
 242    function taskIdVerify (tid : t_id)  return STATUS;
 243    pragma Import (C, taskIdVerify, "taskIdVerify");
 244
 245    function taskIdSelf return t_id;
 246    pragma Import (C, taskIdSelf, "taskIdSelf");
 247
 248    function taskOptionsGet (tid : t_id; pOptions : access int) return int;
 249    pragma Import (C, taskOptionsGet, "taskOptionsGet");
 250
 251    function taskSuspend (tid : t_id) return int;
 252    pragma Import (C, taskSuspend, "taskSuspend");
 253
 254    function taskResume (tid : t_id) return int;
 255    pragma Import (C, taskResume, "taskResume");
 256
 257    function taskIsSuspended (tid : t_id) return int;
 258    pragma Import (C, taskIsSuspended, "taskIsSuspended");
 259
 260    function taskDelay (ticks : int) return int;
 261    procedure taskDelay (ticks : int);
 262    pragma Import (C, taskDelay, "taskDelay");
 263
 264    function sysClkRateGet return int;
 265    pragma Import (C, sysClkRateGet, "sysClkRateGet");
 266
 267    --  VxWorks 5.x specific functions
 268
 269    function taskVarAdd
 270      (tid : t_id; pVar : access System.Address) return int;
 271    pragma Import (C, taskVarAdd, "taskVarAdd");
 272
 273    function taskVarDelete
 274      (tid : t_id; pVar : access System.Address) return int;
 275    pragma Import (C, taskVarDelete, "taskVarDelete");
 276
 277    function taskVarSet
 278      (tid   : t_id;
 279       pVar  : access System.Address;
 280       value : System.Address) return int;
 281    pragma Import (C, taskVarSet, "taskVarSet");
 282
 283    function taskVarGet
 284      (tid  : t_id;
 285       pVar : access System.Address) return int;
 286    pragma Import (C, taskVarGet, "taskVarGet");
 287
 288    --  VxWorks 6.x specific functions
 289
 290    function tlsKeyCreate return int;
 291    pragma Import (C, tlsKeyCreate, "tlsKeyCreate");
 292
 293    function tlsValueGet (key : int) return System.Address;
 294    pragma Import (C, tlsValueGet, "tlsValueGet");
 295
 296    function tlsValueSet (key : int; value : System.Address) return STATUS;
 297    pragma Import (C, tlsValueSet, "tlsValueSet");
 298
 299    --  Option flags for taskSpawn
 300
 301    VX_UNBREAKABLE    : constant := 16#0002#;
 302    VX_FP_PRIVATE_ENV : constant := 16#0080#;
 303    VX_NO_STACK_FILL  : constant := 16#0100#;
 304
 305    function taskSpawn
 306      (name          : System.Address;  --  Pointer to task name
 307       priority      : int;
 308       options       : int;
 309       stacksize     : size_t;
 310       start_routine : System.Address;
 311       arg1          : System.Address;
 312       arg2          : int := 0;
 313       arg3          : int := 0;
 314       arg4          : int := 0;
 315       arg5          : int := 0;
 316       arg6          : int := 0;
 317       arg7          : int := 0;
 318       arg8          : int := 0;
 319       arg9          : int := 0;
 320       arg10         : int := 0) return t_id;
 321    pragma Import (C, taskSpawn, "taskSpawn");
 322
 323    procedure taskDelete (tid : t_id);
 324    pragma Import (C, taskDelete, "taskDelete");
 325
 326    function Set_Time_Slice (ticks : int) return int;
 327    pragma Inline (Set_Time_Slice);
 328    --  Calls kernelTimeSlice under VxWorks 5.x
 329    --  Do nothing under VxWorks 6.x
 330
 331    function taskPriorityGet (tid : t_id; pPriority : access int) return int;
 332    pragma Import (C, taskPriorityGet, "taskPriorityGet");
 333
 334    function taskPrioritySet (tid : t_id; newPriority : int) return int;
 335    pragma Import (C, taskPrioritySet, "taskPrioritySet");
 336
 337    --  Semaphore creation flags
 338
 339    SEM_Q_FIFO         : constant := 0;
 340    SEM_Q_PRIORITY     : constant := 1;
 341    SEM_DELETE_SAFE    : constant := 4;  -- only valid for binary semaphore
 342    SEM_INVERSION_SAFE : constant := 8;  -- only valid for binary semaphore
 343
 344    --  Semaphore initial state flags
 345
 346    SEM_EMPTY : constant := 0;
 347    SEM_FULL  : constant := 1;
 348
 349    --  Semaphore take (semTake) time constants
 350
 351    WAIT_FOREVER : constant := -1;
 352    NO_WAIT      : constant := 0;
 353
 354    --  Error codes (errno). The lower level 16 bits are the error code, with
 355    --  the upper 16 bits representing the module number in which the error
 356    --  occurred. By convention, the module number is 0 for UNIX errors. VxWorks
 357    --  reserves module numbers 1-500, with the remaining module numbers being
 358    --  available for user applications.
 359
 360    M_objLib                 : constant := 61 * 2**16;
 361    --  semTake() failure with ticks = NO_WAIT
 362    S_objLib_OBJ_UNAVAILABLE : constant := M_objLib + 2;
 363    --  semTake() timeout with ticks > NO_WAIT
 364    S_objLib_OBJ_TIMEOUT     : constant := M_objLib + 4;
 365
 366    type SEM_ID is new System.Address;
 367    --  typedef struct semaphore *SEM_ID;
 368
 369    --  We use two different kinds of VxWorks semaphores: mutex and binary
 370    --  semaphores. A null ID is returned when a semaphore cannot be created.
 371
 372    function semBCreate (options : int; initial_state : int) return SEM_ID;
 373    pragma Import (C, semBCreate, "semBCreate");
 374    --  Create a binary semaphore. Return ID, or 0 if memory could not
 375    --  be allocated.
 376
 377    function semMCreate (options : int) return SEM_ID;
 378    pragma Import (C, semMCreate, "semMCreate");
 379
 380    function semDelete (Sem : SEM_ID) return int;
 381    pragma Import (C, semDelete, "semDelete");
 382    --  Delete a semaphore
 383
 384    function semGive (Sem : SEM_ID) return int;
 385    pragma Import (C, semGive, "semGive");
 386
 387    function semTake (Sem : SEM_ID; timeout : int) return int;
 388    pragma Import (C, semTake, "semTake");
 389    --  Attempt to take binary semaphore.  Error is returned if operation
 390    --  times out
 391
 392    function semFlush (SemID : SEM_ID) return STATUS;
 393    pragma Import (C, semFlush, "semFlush");
 394    --  Release all threads blocked on the semaphore
 395
 396 private
 397    type sigset_t is new long;
 398
 399    type pid_t is new int;
 400
 401    ERROR_PID : constant pid_t := -1;
 402
 403    type clockid_t is new int;
 404    CLOCK_REALTIME : constant clockid_t := 0;
 405
 406 end System.OS_Interface;