gcc/ada/s-osinte-darwin.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                   S Y S T E M . O S _ I N T E R F A C E                  --
   6 --                                                                          --
   7 --                                  S p e c                                 --
   8 --                                                                          --
   9 --             Copyright (C) 1991-1994, Florida State University            --
  10 --             Copyright (C) 1995-2006, Free Software Foundation, Inc.      --
  11 --                                                                          --
  12 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  20 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  21 -- Boston, MA 02110-1301, USA.                                              --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNARL was developed by the GNARL team at Florida State University.       --
  31 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is Darwin pthreads version of this package.
  36
  37 --  This package includes all direct interfaces to OS services
  38 --  that are needed by children of System.
  39
  40 --  PLEASE DO NOT add any with-clauses to this package
  41 --  or remove the pragma Elaborate_Body.
  42 --  It is designed to be a bottom-level (leaf) package.
  43
  44 with Interfaces.C;
  45 package System.OS_Interface is
  46    pragma Preelaborate;
  47
  48    subtype int            is Interfaces.C.int;
  49    subtype short          is Interfaces.C.short;
  50    subtype long           is Interfaces.C.long;
  51    subtype unsigned       is Interfaces.C.unsigned;
  52    subtype unsigned_short is Interfaces.C.unsigned_short;
  53    subtype unsigned_long  is Interfaces.C.unsigned_long;
  54    subtype unsigned_char  is Interfaces.C.unsigned_char;
  55    subtype plain_char     is Interfaces.C.plain_char;
  56    subtype size_t         is Interfaces.C.size_t;
  57
  58    -----------
  59    -- Errno --
  60    -----------
  61
  62    function errno return int;
  63    pragma Import (C, errno, "__get_errno");
  64
  65    EINTR     : constant := 4;
  66    ENOMEM    : constant := 12;
  67    EINVAL    : constant := 22;
  68    EAGAIN    : constant := 35;
  69    ETIMEDOUT : constant := 60;
  70
  71    -------------
  72    -- Signals --
  73    -------------
  74
  75    Max_Interrupt : constant := 31;
  76    type Signal is new int range 0 .. Max_Interrupt;
  77    for Signal'Size use int'Size;
  78
  79    SIGHUP     : constant := 1; --  hangup
  80    SIGINT     : constant := 2; --  interrupt (rubout)
  81    SIGQUIT    : constant := 3; --  quit (ASCD FS)
  82    SIGILL     : constant := 4; --  illegal instruction (not reset)
  83    SIGTRAP    : constant := 5; --  trace trap (not reset)
  84    SIGIOT     : constant := 6; --  IOT instruction
  85    SIGABRT    : constant := 6; --  used by abort, replace SIGIOT in the  future
  86    SIGEMT     : constant := 7; --  EMT instruction
  87    SIGFPE     : constant := 8; --  floating point exception
  88    SIGKILL    : constant := 9; --  kill (cannot be caught or ignored)
  89    SIGBUS     : constant := 10; --  bus error
  90    SIGSEGV    : constant := 11; --  segmentation violation
  91    SIGSYS     : constant := 12; --  bad argument to system call
  92    SIGPIPE    : constant := 13; --  write on a pipe with no one to read it
  93    SIGALRM    : constant := 14; --  alarm clock
  94    SIGTERM    : constant := 15; --  software termination signal from kill
  95    SIGURG     : constant := 16; --  urgent condition on IO channel
  96    SIGSTOP    : constant := 17; --  stop (cannot be caught or ignored)
  97    SIGTSTP    : constant := 18; --  user stop requested from tty
  98    SIGCONT    : constant := 19; --  stopped process has been continued
  99    SIGCHLD    : constant := 20; --  child status change
 100    SIGTTIN    : constant := 21; --  background tty read attempted
 101    SIGTTOU    : constant := 22; --  background tty write attempted
 102    SIGIO      : constant := 23; --  I/O possible (Solaris SIGPOLL alias)
 103    SIGXCPU    : constant := 24; --  CPU time limit exceeded
 104    SIGXFSZ    : constant := 25; --  filesize limit exceeded
 105    SIGVTALRM  : constant := 26; --  virtual timer expired
 106    SIGPROF    : constant := 27; --  profiling timer expired
 107    SIGWINCH   : constant := 28; --  window size change
 108    SIGINFO    : constant := 29; --  information request
 109    SIGUSR1    : constant := 30; --  user defined signal 1
 110    SIGUSR2    : constant := 31; --  user defined signal 2
 111
 112    SIGADAABORT : constant := SIGTERM;
 113    --  Change this if you want to use another signal for task abort.
 114    --  SIGTERM might be a good one.
 115
 116    type Signal_Set is array (Natural range <>) of Signal;
 117
 118    Unmasked    : constant Signal_Set :=
 119      (SIGTTIN, SIGTTOU, SIGSTOP, SIGTSTP);
 120
 121    Reserved    : constant Signal_Set :=
 122      (SIGKILL, SIGSTOP);
 123
 124    type sigset_t is private;
 125
 126    function sigaddset (set : access sigset_t; sig : Signal) return int;
 127    pragma Import (C, sigaddset, "sigaddset");
 128
 129    function sigdelset (set : access sigset_t; sig : Signal) return int;
 130    pragma Import (C, sigdelset, "sigdelset");
 131
 132    function sigfillset (set : access sigset_t) return int;
 133    pragma Import (C, sigfillset, "sigfillset");
 134
 135    function sigismember (set : access sigset_t; sig : Signal) return int;
 136    pragma Import (C, sigismember, "sigismember");
 137
 138    function sigemptyset (set : access sigset_t) return int;
 139    pragma Import (C, sigemptyset, "sigemptyset");
 140
 141    type siginfo_t is private;
 142    type ucontext_t is private;
 143
 144    type Signal_Handler is access procedure
 145      (signo   : Signal;
 146       info    : access siginfo_t;
 147       context : access ucontext_t);
 148
 149    type struct_sigaction is record
 150       sa_handler : System.Address;
 151       sa_mask    : sigset_t;
 152       sa_flags   : int;
 153    end record;
 154    pragma Convention (C, struct_sigaction);
 155    type struct_sigaction_ptr is access all struct_sigaction;
 156
 157    SIG_BLOCK   : constant := 1;
 158    SIG_UNBLOCK : constant := 2;
 159    SIG_SETMASK : constant := 3;
 160
 161    SIG_DFL : constant := 0;
 162    SIG_IGN : constant := 1;
 163
 164    SA_SIGINFO : constant := 16#0040#;
 165
 166    function sigaction
 167      (sig  : Signal;
 168       act  : struct_sigaction_ptr;
 169       oact : struct_sigaction_ptr) return int;
 170    pragma Import (C, sigaction, "sigaction");
 171
 172    ----------
 173    -- Time --
 174    ----------
 175
 176    Time_Slice_Supported : constant Boolean := True;
 177    --  Indicates wether time slicing is supported.
 178
 179    type timespec is private;
 180
 181    type clockid_t is private;
 182
 183    CLOCK_REALTIME : constant clockid_t;
 184
 185    function clock_gettime
 186      (clock_id : clockid_t;
 187       tp       : access timespec) return int;
 188
 189    function To_Duration (TS : timespec) return Duration;
 190    pragma Inline (To_Duration);
 191
 192    function To_Timespec (D : Duration) return timespec;
 193    pragma Inline (To_Timespec);
 194
 195    type struct_timeval is private;
 196
 197    function To_Duration (TV : struct_timeval) return Duration;
 198    pragma Inline (To_Duration);
 199
 200    function To_Timeval (D : Duration) return struct_timeval;
 201    pragma Inline (To_Timeval);
 202
 203    -------------------------
 204    -- Priority Scheduling --
 205    -------------------------
 206
 207    SCHED_OTHER : constant := 1;
 208    SCHED_RR    : constant := 2;
 209    SCHED_FIFO  : constant := 4;
 210
 211    function To_Target_Priority
 212      (Prio : System.Any_Priority) return Interfaces.C.int;
 213    --  Maps System.Any_Priority to a POSIX priority.
 214
 215    -------------
 216    -- Process --
 217    -------------
 218
 219    type pid_t is private;
 220
 221    function kill (pid : pid_t; sig : Signal) return int;
 222    pragma Import (C, kill, "kill");
 223
 224    function getpid return pid_t;
 225    pragma Import (C, getpid, "getpid");
 226
 227    ---------
 228    -- LWP --
 229    ---------
 230
 231    function lwp_self return System.Address;
 232    --  lwp_self does not exist on this thread library, revert to pthread_self
 233    --  which is the closest approximation (with getpid). This function is
 234    --  needed to share 7staprop.adb across POSIX-like targets.
 235    pragma Import (C, lwp_self, "pthread_self");
 236
 237    -------------
 238    -- Threads --
 239    -------------
 240
 241    type Thread_Body is access
 242      function (arg : System.Address) return System.Address;
 243    type pthread_t           is private;
 244    subtype Thread_Id        is pthread_t;
 245
 246    type pthread_mutex_t     is limited private;
 247    type pthread_cond_t      is limited private;
 248    type pthread_attr_t      is limited private;
 249    type pthread_mutexattr_t is limited private;
 250    type pthread_condattr_t  is limited private;
 251    type pthread_key_t       is private;
 252
 253    type pthread_mutex_ptr is access all pthread_mutex_t;
 254    type pthread_cond_ptr is access all pthread_cond_t;
 255
 256    PTHREAD_CREATE_DETACHED : constant := 2;
 257
 258    PTHREAD_SCOPE_PROCESS : constant := 2;
 259    PTHREAD_SCOPE_SYSTEM  : constant := 1;
 260
 261    -----------
 262    -- Stack --
 263    -----------
 264
 265    Stack_Base_Available : constant Boolean := False;
 266    --  Indicates wether the stack base is available on this target.
 267    --  This allows us to share s-osinte.adb between all the FSU run time.
 268    --  Note that this value can only be true if pthread_t has a complete
 269    --  definition that corresponds exactly to the C header files.
 270
 271    function Get_Stack_Base (thread : pthread_t) return System.Address;
 272    pragma Inline (Get_Stack_Base);
 273    --  returns the stack base of the specified thread.
 274    --  Only call this function when Stack_Base_Available is True.
 275
 276    function Get_Page_Size return size_t;
 277    function Get_Page_Size return System.Address;
 278    pragma Import (C, Get_Page_Size, "getpagesize");
 279    --  returns the size of a page, or 0 if this is not relevant on this
 280    --  target
 281
 282    PROT_NONE  : constant := 0;
 283    PROT_READ  : constant := 1;
 284    PROT_WRITE : constant := 2;
 285    PROT_EXEC  : constant := 4;
 286    PROT_ALL   : constant := PROT_READ + PROT_WRITE + PROT_EXEC;
 287
 288    PROT_ON    : constant := PROT_NONE;
 289    PROT_OFF   : constant := PROT_ALL;
 290
 291    function mprotect (addr : System.Address;
 292                       len : size_t;
 293                       prot : int) return int;
 294    pragma Import (C, mprotect);
 295
 296    ---------------------------------------
 297    -- Nonstandard Thread Initialization --
 298    ---------------------------------------
 299
 300    procedure pthread_init;
 301
 302    -------------------------
 303    -- POSIX.1c  Section 3 --
 304    -------------------------
 305
 306    function sigwait (set : access sigset_t; sig : access Signal) return int;
 307    pragma Import (C, sigwait, "sigwait");
 308
 309    function pthread_kill (thread : pthread_t; sig : Signal) return int;
 310    pragma Import (C, pthread_kill, "pthread_kill");
 311
 312    function pthread_sigmask
 313      (how  : int;
 314       set  : access sigset_t;
 315       oset : access sigset_t) return int;
 316    pragma Import (C, pthread_sigmask, "pthread_sigmask");
 317
 318    --------------------------
 319    -- POSIX.1c  Section 11 --
 320    --------------------------
 321
 322    function pthread_mutexattr_init
 323      (attr : access pthread_mutexattr_t) return int;
 324    pragma Import (C, pthread_mutexattr_init, "pthread_mutexattr_init");
 325
 326    function pthread_mutexattr_destroy
 327      (attr : access pthread_mutexattr_t) return int;
 328    pragma Import (C, pthread_mutexattr_destroy, "pthread_mutexattr_destroy");
 329
 330    function pthread_mutex_init
 331      (mutex : access pthread_mutex_t;
 332       attr  : access pthread_mutexattr_t) return int;
 333    pragma Import (C, pthread_mutex_init, "pthread_mutex_init");
 334
 335    function pthread_mutex_destroy (mutex : access pthread_mutex_t) return int;
 336    pragma Import (C, pthread_mutex_destroy, "pthread_mutex_destroy");
 337
 338    function pthread_mutex_lock (mutex : access pthread_mutex_t) return int;
 339    pragma Import (C, pthread_mutex_lock, "pthread_mutex_lock");
 340
 341    function pthread_mutex_unlock (mutex : access pthread_mutex_t) return int;
 342    pragma Import (C, pthread_mutex_unlock, "pthread_mutex_unlock");
 343
 344    function pthread_condattr_init
 345      (attr : access pthread_condattr_t) return int;
 346    pragma Import (C, pthread_condattr_init, "pthread_condattr_init");
 347
 348    function pthread_condattr_destroy
 349      (attr : access pthread_condattr_t) return int;
 350    pragma Import (C, pthread_condattr_destroy, "pthread_condattr_destroy");
 351
 352    function pthread_cond_init
 353      (cond : access pthread_cond_t;
 354       attr : access pthread_condattr_t) return int;
 355    pragma Import (C, pthread_cond_init, "pthread_cond_init");
 356
 357    function pthread_cond_destroy (cond : access pthread_cond_t) return int;
 358    pragma Import (C, pthread_cond_destroy, "pthread_cond_destroy");
 359
 360    function pthread_cond_signal (cond : access pthread_cond_t) return int;
 361    pragma Import (C, pthread_cond_signal, "pthread_cond_signal");
 362
 363    function pthread_cond_wait
 364      (cond  : access pthread_cond_t;
 365       mutex : access pthread_mutex_t) return int;
 366    pragma Import (C, pthread_cond_wait, "pthread_cond_wait");
 367
 368    function pthread_cond_timedwait
 369      (cond    : access pthread_cond_t;
 370       mutex   : access pthread_mutex_t;
 371       abstime : access timespec) return int;
 372    pragma Import (C, pthread_cond_timedwait, "pthread_cond_timedwait");
 373
 374    Relative_Timed_Wait : constant Boolean := False;
 375    --  pthread_cond_timedwait requires an absolute delay time
 376
 377    --------------------------
 378    -- POSIX.1c  Section 13 --
 379    --------------------------
 380
 381    PTHREAD_PRIO_NONE    : constant := 0;
 382    PTHREAD_PRIO_INHERIT : constant := 1;
 383    PTHREAD_PRIO_PROTECT : constant := 2;
 384
 385    function pthread_mutexattr_setprotocol
 386      (attr     : access pthread_mutexattr_t;
 387       protocol : int) return int;
 388    pragma Import
 389      (C, pthread_mutexattr_setprotocol, "pthread_mutexattr_setprotocol");
 390
 391    function pthread_mutexattr_setprioceiling
 392      (attr     : access pthread_mutexattr_t;
 393       prioceiling : int) return int;
 394    pragma Import
 395      (C, pthread_mutexattr_setprioceiling,
 396       "pthread_mutexattr_setprioceiling");
 397
 398    type padding is array (int range <>) of Interfaces.C.char;
 399
 400    type struct_sched_param is record
 401       sched_priority : int;  --  scheduling priority
 402       opaque         : padding (1 .. 4);
 403    end record;
 404    pragma Convention (C, struct_sched_param);
 405
 406    function pthread_setschedparam
 407      (thread : pthread_t;
 408       policy : int;
 409       param  : access struct_sched_param) return int;
 410    pragma Import (C, pthread_setschedparam, "pthread_setschedparam");
 411
 412    function pthread_attr_setscope
 413      (attr            : access pthread_attr_t;
 414       contentionscope : int) return int;
 415    pragma Import (C, pthread_attr_setscope, "pthread_attr_setscope");
 416
 417    function pthread_attr_setinheritsched
 418      (attr            : access pthread_attr_t;
 419       inheritsched : int) return int;
 420    pragma Import
 421      (C, pthread_attr_setinheritsched, "pthread_attr_setinheritsched");
 422
 423    function pthread_attr_setschedpolicy
 424      (attr   : access pthread_attr_t;
 425       policy : int) return int;
 426    pragma Import (C, pthread_attr_setschedpolicy, "pthread_attr_setsched");
 427
 428    function sched_yield return int;
 429
 430    ---------------------------
 431    -- P1003.1c - Section 16 --
 432    ---------------------------
 433
 434    function pthread_attr_init (attributes : access pthread_attr_t) return int;
 435    pragma Import (C, pthread_attr_init, "pthread_attr_init");
 436
 437    function pthread_attr_destroy
 438      (attributes : access pthread_attr_t) return int;
 439    pragma Import (C, pthread_attr_destroy, "pthread_attr_destroy");
 440
 441    function pthread_attr_setdetachstate
 442      (attr        : access pthread_attr_t;
 443       detachstate : int) return int;
 444    pragma Import
 445      (C, pthread_attr_setdetachstate, "pthread_attr_setdetachstate");
 446
 447    function pthread_attr_setstacksize
 448      (attr      : access pthread_attr_t;
 449       stacksize : size_t) return int;
 450    pragma Import
 451      (C, pthread_attr_setstacksize, "pthread_attr_setstacksize");
 452
 453    function pthread_create
 454      (thread        : access pthread_t;
 455       attributes    : access pthread_attr_t;
 456       start_routine : Thread_Body;
 457       arg           : System.Address) return int;
 458    pragma Import (C, pthread_create, "pthread_create");
 459
 460    procedure pthread_exit (status : System.Address);
 461    pragma Import (C, pthread_exit, "pthread_exit");
 462
 463    function pthread_self return pthread_t;
 464    pragma Import (C, pthread_self, "pthread_self");
 465
 466    --------------------------
 467    -- POSIX.1c  Section 17 --
 468    --------------------------
 469
 470    function pthread_setspecific
 471      (key   : pthread_key_t;
 472       value : System.Address) return int;
 473    pragma Import (C, pthread_setspecific, "pthread_setspecific");
 474
 475    function pthread_getspecific (key : pthread_key_t) return System.Address;
 476    pragma Import (C, pthread_getspecific, "pthread_getspecific");
 477
 478    type destructor_pointer is access procedure (arg : System.Address);
 479
 480    function pthread_key_create
 481      (key        : access pthread_key_t;
 482       destructor : destructor_pointer) return int;
 483    pragma Import (C, pthread_key_create, "pthread_key_create");
 484
 485 private
 486
 487    type sigset_t is new unsigned;
 488
 489    type int32_t is new int;
 490
 491    type pid_t is new int32_t;
 492
 493    type time_t is new long;
 494
 495    type timespec is record
 496       tv_sec  : time_t;
 497       tv_nsec : int32_t;
 498    end record;
 499    pragma Convention (C, timespec);
 500
 501    type clockid_t is new int;
 502    CLOCK_REALTIME : constant clockid_t := 0;
 503
 504    type struct_timeval is record
 505       tv_sec  : int32_t;
 506       tv_usec : int32_t;
 507    end record;
 508    pragma Convention (C, struct_timeval);
 509
 510    --
 511    --  Darwin specific signal implementation
 512    --
 513    type Pad_Type is array (1 .. 7) of unsigned;
 514    type siginfo_t is record
 515       si_signo  : int;               --  signal number
 516       si_errno  : int;               --  errno association
 517       si_code   : int;               --  signal code
 518       si_pid    : int;               --  sending process
 519       si_uid    : unsigned;          --  sender's ruid
 520       si_status : int;               --  exit value
 521       si_addr   : System.Address;    --  faulting instruction
 522       si_value  : System.Address;    --  signal value
 523       si_band   : long;              --  band event for SIGPOLL
 524       pad       : Pad_Type;          --  RFU
 525    end record;
 526    pragma Convention (C, siginfo_t);
 527
 528    type stack_t is record
 529       ss_sp    : System.Address;
 530       ss_size  : int;
 531       ss_flags : int;
 532    end record;
 533    pragma Convention (C, stack_t);
 534
 535    type mcontext_t is new System.Address;
 536
 537    type ucontext_t is record
 538       uc_onstack  : int;
 539       uc_sigmask  : sigset_t;         --  Signal Mask Used By This Context
 540       uc_stack    : stack_t;          --  Stack Used By This Context
 541       uc_link     : System.Address;   --  Pointer To Resuming Context
 542       uc_mcsize   : size_t;           --  Size of The Machine Context
 543       uc_mcontext : mcontext_t;       --  Machine Specific Context
 544    end record;
 545    pragma Convention (C, ucontext_t);
 546
 547    --
 548    --  Darwin specific pthread implementation
 549    --
 550    type pthread_t is new System.Address;
 551
 552    type pthread_lock_t is new long;
 553
 554    type pthread_attr_t is record
 555       sig    : long;
 556       opaque : padding (1 .. 36);
 557    end record;
 558    pragma Convention (C, pthread_attr_t);
 559
 560    type pthread_mutexattr_t is record
 561       sig    : long;
 562       opaque : padding (1 .. 8);
 563    end record;
 564    pragma Convention (C, pthread_mutexattr_t);
 565
 566    type pthread_mutex_t is record
 567       sig    : long;
 568       opaque : padding (1 .. 40);
 569    end record;
 570    pragma Convention (C, pthread_mutex_t);
 571
 572    type pthread_condattr_t is record
 573       sig    : long;
 574       opaque : padding (1 .. 4);
 575    end record;
 576    pragma Convention (C, pthread_condattr_t);
 577
 578    type pthread_cond_t is record
 579       sig    : long;
 580       opaque : padding (1 .. 24);
 581    end record;
 582    pragma Convention (C, pthread_cond_t);
 583
 584    type pthread_once_t is record
 585       sig    : long;
 586       opaque : padding (1 .. 4);
 587    end record;
 588    pragma Convention (C, pthread_once_t);
 589
 590    type pthread_key_t is new unsigned_long;
 591
 592 end System.OS_Interface;