gcc/ada/s-memory.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         S Y S T E M . M E M O R Y                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2003 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the default implementation of this package.
  35
  36 --  This implementation assumes that the underlying malloc/free/realloc
  37 --  implementation is thread safe, and thus, no additional lock is required.
  38 --  Note that we still need to defer abortion because on most systems,
  39 --  an asynchronous signal (as used for implementing asynchronous abortion
  40 --  of task) cannot safely be handled while malloc is executing.
  41
  42 --  If you are not using Ada constructs containing the "abort" keyword,
  43 --  then you can remove the calls to Abort_Defer.all and Abort_Undefer.all
  44 --  from this unit.
  45
  46 with Ada.Exceptions;
  47 with System.Soft_Links;
  48 with System.Parameters;
  49
  50 package body System.Memory is
  51
  52    use Ada.Exceptions;
  53    use System.Soft_Links;
  54
  55    function c_malloc (Size : size_t) return System.Address;
  56    pragma Import (C, c_malloc, "malloc");
  57
  58    procedure c_free (Ptr : System.Address);
  59    pragma Import (C, c_free, "free");
  60
  61    function c_realloc
  62      (Ptr : System.Address; Size : size_t) return System.Address;
  63    pragma Import (C, c_realloc, "realloc");
  64
  65    -----------
  66    -- Alloc --
  67    -----------
  68
  69    function Alloc (Size : size_t) return System.Address is
  70       Result      : System.Address;
  71       Actual_Size : size_t := Size;
  72
  73    begin
  74       if Size = size_t'Last then
  75          Raise_Exception (Storage_Error'Identity, "object too large");
  76       end if;
  77
  78       --  Change size from zero to non-zero. We still want a proper pointer
  79       --  for the zero case because pointers to zero length objects have to
  80       --  be distinct, but we can't just go ahead and allocate zero bytes,
  81       --  since some malloc's return zero for a zero argument.
  82
  83       if Size = 0 then
  84          Actual_Size := 1;
  85       end if;
  86
  87       if Parameters.No_Abort then
  88          Result := c_malloc (Actual_Size);
  89       else
  90          Abort_Defer.all;
  91          Result := c_malloc (Actual_Size);
  92          Abort_Undefer.all;
  93       end if;
  94
  95       if Result = System.Null_Address then
  96          Raise_Exception (Storage_Error'Identity, "heap exhausted");
  97       end if;
  98
  99       return Result;
 100    end Alloc;
 101
 102    ----------
 103    -- Free --
 104    ----------
 105
 106    procedure Free (Ptr : System.Address) is
 107    begin
 108       if Parameters.No_Abort then
 109          c_free (Ptr);
 110       else
 111          Abort_Defer.all;
 112          c_free (Ptr);
 113          Abort_Undefer.all;
 114       end if;
 115    end Free;
 116
 117    -------------
 118    -- Realloc --
 119    -------------
 120
 121    function Realloc
 122      (Ptr  : System.Address;
 123       Size : size_t)
 124       return System.Address
 125    is
 126       Result      : System.Address;
 127       Actual_Size : constant size_t := Size;
 128
 129    begin
 130       if Size = size_t'Last then
 131          Raise_Exception (Storage_Error'Identity, "object too large");
 132       end if;
 133
 134       if Parameters.No_Abort then
 135          Result := c_realloc (Ptr, Actual_Size);
 136       else
 137          Abort_Defer.all;
 138          Result := c_realloc (Ptr, Actual_Size);
 139          Abort_Undefer.all;
 140       end if;
 141
 142       if Result = System.Null_Address then
 143          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 144       end if;
 145
 146       return Result;
 147    end Realloc;
 148
 149 end System.Memory;