gcc/ada/s-memory.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         S Y S T E M . M E M O R Y                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2002 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  24 -- MA 02111-1307, USA.                                                      --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- GNAT was originally developed  by the GNAT team at  New York University. --
  34 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 --  This is the default implementation of this package.
  39
  40 --  This implementation assumes that the underlying malloc/free/realloc
  41 --  implementation is thread safe, and thus, no additional lock is required.
  42 --  Note that we still need to defer abortion because on most systems,
  43 --  an asynchronous signal (as used for implementing asynchronous abortion
  44 --  of task) cannot safely be handled while malloc is executing.
  45
  46 --  If you are not using Ada constructs containing the "abort" keyword,
  47 --  then you can remove the calls to Abort_Defer.all and Abort_Undefer.all
  48 --  from this unit.
  49
  50 with Ada.Exceptions;
  51 with System.Soft_Links;
  52 with System.Parameters;
  53
  54 package body System.Memory is
  55
  56    use Ada.Exceptions;
  57    use System.Soft_Links;
  58
  59    function c_malloc (Size : size_t) return System.Address;
  60    pragma Import (C, c_malloc, "malloc");
  61
  62    procedure c_free (Ptr : System.Address);
  63    pragma Import (C, c_free, "free");
  64
  65    function c_realloc
  66      (Ptr : System.Address; Size : size_t) return System.Address;
  67    pragma Import (C, c_realloc, "realloc");
  68
  69    -----------
  70    -- Alloc --
  71    -----------
  72
  73    function Alloc (Size : size_t) return System.Address is
  74       Result      : System.Address;
  75       Actual_Size : size_t := Size;
  76
  77    begin
  78       if Size = size_t'Last then
  79          Raise_Exception (Storage_Error'Identity, "object too large");
  80       end if;
  81
  82       --  Change size from zero to non-zero. We still want a proper pointer
  83       --  for the zero case because pointers to zero length objects have to
  84       --  be distinct, but we can't just go ahead and allocate zero bytes,
  85       --  since some malloc's return zero for a zero argument.
  86
  87       if Size = 0 then
  88          Actual_Size := 1;
  89       end if;
  90
  91       if Parameters.No_Abort then
  92          Result := c_malloc (Actual_Size);
  93       else
  94          Abort_Defer.all;
  95          Result := c_malloc (Actual_Size);
  96          Abort_Undefer.all;
  97       end if;
  98
  99       if Result = System.Null_Address then
 100          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 101       end if;
 102
 103       return Result;
 104    end Alloc;
 105
 106    ----------
 107    -- Free --
 108    ----------
 109
 110    procedure Free (Ptr : System.Address) is
 111    begin
 112       if Parameters.No_Abort then
 113          c_free (Ptr);
 114       else
 115          Abort_Defer.all;
 116          c_free (Ptr);
 117          Abort_Undefer.all;
 118       end if;
 119    end Free;
 120
 121    -------------
 122    -- Realloc --
 123    -------------
 124
 125    function Realloc
 126      (Ptr  : System.Address;
 127       Size : size_t)
 128       return System.Address
 129    is
 130       Result      : System.Address;
 131       Actual_Size : size_t := Size;
 132
 133    begin
 134       if Size = size_t'Last then
 135          Raise_Exception (Storage_Error'Identity, "object too large");
 136       end if;
 137
 138       if Parameters.No_Abort then
 139          Result := c_realloc (Ptr, Actual_Size);
 140       else
 141          Abort_Defer.all;
 142          Result := c_realloc (Ptr, Actual_Size);
 143          Abort_Undefer.all;
 144       end if;
 145
 146       if Result = System.Null_Address then
 147          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 148       end if;
 149
 150       return Result;
 151    end Realloc;
 152
 153 end System.Memory;