gcc/ada/s-intman-vxworks.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --           S Y S T E M . I N T E R R U P T _ M A N A G E M E N T          --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is the VxWorks version of this package
  33
  34 --  It is simpler than other versions because the Ada interrupt handling
  35 --  mechanisms are used for hardware interrupts rather than signals.
  36
  37 package body System.Interrupt_Management is
  38
  39    use System.OS_Interface;
  40    use type Interfaces.C.int;
  41
  42    type Signal_List is array (Signal_ID range <>) of Signal_ID;
  43    Exception_Signals : constant Signal_List (1 .. 4) :=
  44                          (SIGFPE, SIGILL, SIGSEGV, SIGBUS);
  45
  46    Exception_Action : aliased struct_sigaction;
  47    --  Keep this a variable global so that it is initialized only once
  48
  49    Signal_Mask : aliased sigset_t;
  50    pragma Import (C, Signal_Mask, "__gnat_signal_mask");
  51    --  Mask indicating that all exception signals are to be masked
  52    --  when a signal is propagated.
  53
  54    procedure Notify_Exception
  55      (signo      : Signal;
  56       siginfo    : System.Address;
  57       sigcontext : System.Address);
  58    pragma Import (C, Notify_Exception, "__gnat_error_handler");
  59    --  Map a signal to Ada exception and raise it.  Different versions
  60    --  of VxWorks need different mappings. This is addressed in init.c in
  61    --  __gnat_map_signal.
  62
  63    -----------------------
  64    -- Local Subprograms --
  65    -----------------------
  66
  67    function State (Int : Interrupt_ID) return Character;
  68    pragma Import (C, State, "__gnat_get_interrupt_state");
  69    --  Get interrupt state. Defined in init.c The input argument is the
  70    --  hardware interrupt number, and the result is one of the following:
  71
  72    Runtime : constant Character := 'r';
  73    Default : constant Character := 's';
  74    --    'n'   this interrupt not set by any Interrupt_State pragma
  75    --    'u'   Interrupt_State pragma set state to User
  76    --    'r'   Interrupt_State pragma set state to Runtime
  77    --    's'   Interrupt_State pragma set state to System (use "default"
  78    --           system handler)
  79
  80    ---------------------------
  81    -- Initialize_Interrupts --
  82    ---------------------------
  83
  84    --  Since there is no signal inheritance between VxWorks tasks, we need
  85    --  to initialize signal handling in each task.
  86
  87    procedure Initialize_Interrupts is
  88       Result  : int;
  89       old_act : aliased struct_sigaction;
  90    begin
  91       for J in Exception_Signals'Range loop
  92          Result :=
  93            sigaction
  94              (Signal (Exception_Signals (J)), Exception_Action'Access,
  95               old_act'Unchecked_Access);
  96          pragma Assert (Result = 0);
  97       end loop;
  98    end Initialize_Interrupts;
  99
 100    ----------------
 101    -- Initialize --
 102    ----------------
 103
 104    Initialized : Boolean := False;
 105    --  Set to True once Initialize is called, further calls have no effect
 106
 107    procedure Initialize is
 108
 109    begin
 110       if Initialized then
 111          return;
 112       end if;
 113
 114       Initialized := True;
 115
 116       --  Change this if you want to use another signal for task abort.
 117       --  SIGTERM might be a good one.
 118
 119       Abort_Task_Interrupt := SIGABRT;
 120
 121       --  Signal_Mask was initialized in __gnat_install_handler
 122
 123       Exception_Action.sa_handler := Notify_Exception'Address;
 124       Exception_Action.sa_flags := SA_ONSTACK + SA_SIGINFO;
 125       Exception_Action.sa_mask := Signal_Mask;
 126
 127       --  Initialize hardware interrupt handling
 128
 129       pragma Assert (Reserve = (Interrupt_ID'Range => False));
 130
 131       --  Check all interrupts for state that requires keeping them reserved
 132
 133       for J in Interrupt_ID'Range loop
 134          if State (J) = Default or else State (J) = Runtime then
 135             Reserve (J) := True;
 136          end if;
 137       end loop;
 138
 139    end Initialize;
 140
 141 end System.Interrupt_Management;