gcc/ada/s-intman-vxworks.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --           S Y S T E M . I N T E R R U P T _ M A N A G E M E N T          --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the VxWorks version of this package.
  35
  36 --  It is likely to need tailoring to fit each operating system
  37 --  and machine architecture.
  38
  39 --  PLEASE DO NOT add any dependences on other packages.
  40 --  This package is designed to work with or without tasking support.
  41
  42 --  See the other warnings in the package specification before making
  43 --  any modifications to this file.
  44
  45 --  Make a careful study of all signals available under the OS,
  46 --  to see which need to be reserved, kept always unmasked,
  47 --  or kept always unmasked.
  48 --  Be on the lookout for special signals that
  49 --  may be used by the thread library.
  50
  51 with Interfaces.C;
  52
  53 with System.OS_Interface;
  54 --  used for various Constants, Signal and types
  55
  56 package body System.Interrupt_Management is
  57
  58    use System.OS_Interface;
  59    use type Interfaces.C.int;
  60
  61    type Signal_List is array (Signal_ID range <>) of Signal_ID;
  62    Exception_Signals : constant Signal_List (1 .. 4) :=
  63                          (SIGFPE, SIGILL, SIGSEGV, SIGBUS);
  64
  65    --  Keep these variables global so that they are initialized only once
  66    --  What are "these variables" ???, I see only one
  67
  68    Exception_Action : aliased struct_sigaction;
  69
  70    procedure Map_And_Raise_Exception (signo : Signal);
  71    pragma Import (C, Map_And_Raise_Exception, "__gnat_map_signal");
  72    --  Map signal to Ada exception and raise it.  Different versions
  73    --  of VxWorks need different mappings.
  74
  75    -----------------------
  76    -- Local Subprograms --
  77    -----------------------
  78
  79    procedure Notify_Exception (signo : Signal);
  80    --  Identify the Ada exception to be raised using
  81    --  the information when the system received a synchronous signal.
  82
  83    ----------------------
  84    -- Notify_Exception --
  85    ----------------------
  86
  87    procedure Notify_Exception (signo : Signal) is
  88       Mask   : aliased sigset_t;
  89
  90       Result : int;
  91       pragma Unreferenced (Result);
  92
  93    begin
  94       Result := pthread_sigmask (SIG_SETMASK, null, Mask'Unchecked_Access);
  95       Result := sigdelset (Mask'Access, signo);
  96       Result := pthread_sigmask (SIG_SETMASK, Mask'Unchecked_Access, null);
  97
  98       Map_And_Raise_Exception (signo);
  99    end Notify_Exception;
 100
 101    ---------------------------
 102    -- Initialize_Interrupts --
 103    ---------------------------
 104
 105    --  Since there is no signal inheritance between VxWorks tasks, we need
 106    --  to initialize signal handling in each task.
 107
 108    procedure Initialize_Interrupts is
 109       Result  : int;
 110       old_act : aliased struct_sigaction;
 111
 112    begin
 113       for J in Exception_Signals'Range loop
 114          Result :=
 115            sigaction
 116              (Signal (Exception_Signals (J)), Exception_Action'Access,
 117               old_act'Unchecked_Access);
 118          pragma Assert (Result = 0);
 119       end loop;
 120    end Initialize_Interrupts;
 121
 122 begin
 123    declare
 124       mask   : aliased sigset_t;
 125       Result : int;
 126
 127       function State (Int : Interrupt_ID) return Character;
 128       pragma Import (C, State, "__gnat_get_interrupt_state");
 129       --  Get interrupt state.  Defined in a-init.c
 130       --  The input argument is the interrupt number,
 131       --  and the result is one of the following:
 132
 133       Runtime : constant Character := 'r';
 134       Default : constant Character := 's';
 135       --    'n'   this interrupt not set by any Interrupt_State pragma
 136       --    'u'   Interrupt_State pragma set state to User
 137       --    'r'   Interrupt_State pragma set state to Runtime
 138       --    's'   Interrupt_State pragma set state to System (use "default"
 139       --           system handler)
 140
 141    begin
 142       --  Initialize signal handling
 143
 144       --  Change this if you want to use another signal for task abort.
 145       --  SIGTERM might be a good one.
 146
 147       Abort_Task_Signal := SIGABRT;
 148
 149       Exception_Action.sa_handler := Notify_Exception'Address;
 150       Exception_Action.sa_flags := SA_ONSTACK;
 151       Result := sigemptyset (mask'Access);
 152       pragma Assert (Result = 0);
 153
 154       for J in Exception_Signals'Range loop
 155          Result := sigaddset (mask'Access, Signal (Exception_Signals (J)));
 156          pragma Assert (Result = 0);
 157       end loop;
 158
 159       Exception_Action.sa_mask := mask;
 160
 161       --  Initialize hardware interrupt handling
 162
 163       pragma Assert (Reserve = (Interrupt_ID'Range => False));
 164
 165       --  Check all interrupts for state that requires keeping them reserved
 166
 167       for J in Interrupt_ID'Range loop
 168          if State (J) = Default or else State (J) = Runtime then
 169             Reserve (J) := True;
 170          end if;
 171       end loop;
 172
 173       --  Add exception signals to the set of unmasked signals
 174
 175       for J in Exception_Signals'Range loop
 176          Keep_Unmasked (Exception_Signals (J)) := True;
 177       end loop;
 178
 179       --  The abort signal must also be unmasked
 180
 181       Keep_Unmasked (Abort_Task_Signal) := True;
 182    end;
 183 end System.Interrupt_Management;