gcc/ada/s-intman-posix.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --           S Y S T E M . I N T E R R U P T _ M A N A G E M E N T          --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the POSIX threads version of this package
  35
  36 --  PLEASE DO NOT add any dependences on other packages. ??? why not ???
  37 --  This package is designed to work with or without tasking support.
  38
  39 --  See the other warnings in the package specification before making
  40 --  any modifications to this file.
  41
  42 --  Make a careful study of all signals available under the OS, to see which
  43 --  need to be reserved, kept always unmasked, or kept always unmasked. Be on
  44 --  the lookout for special signals that may be used by the thread library.
  45
  46 --  Since this is a multi target file, the signal <-> exception mapping
  47 --  is simple minded. If you need a more precise and target specific
  48 --  signal handling, create a new s-intman.adb that will fit your needs.
  49
  50 --  This file assumes that:
  51
  52 --    SIGFPE, SIGILL, SIGSEGV and SIGBUS exist. They are mapped as follows:
  53 --      SIGPFE  => Constraint_Error
  54 --      SIGILL  => Program_Error
  55 --      SIGSEGV => Storage_Error
  56 --      SIGBUS  => Storage_Error
  57
  58 --    SIGINT exists and will be kept unmasked unless the pragma
  59 --     Unreserve_All_Interrupts is specified anywhere in the application.
  60
  61 --    System.OS_Interface contains the following:
  62 --      SIGADAABORT: the signal that will be used to abort tasks.
  63 --      Unmasked: the OS specific set of signals that should be unmasked in
  64 --                all the threads. SIGADAABORT is unmasked by
  65 --                default
  66 --      Reserved: the OS specific set of signals that are reserved.
  67
  68 with Interfaces.C;
  69 --  used for int and other types
  70
  71 with System.OS_Interface;
  72 --  used for various Constants, Signal and types
  73
  74 package body System.Interrupt_Management is
  75
  76    use Interfaces.C;
  77    use System.OS_Interface;
  78
  79    type Interrupt_List is array (Interrupt_ID range <>) of Interrupt_ID;
  80    Exception_Interrupts : constant Interrupt_List :=
  81      (SIGFPE, SIGILL, SIGSEGV, SIGBUS);
  82
  83    Unreserve_All_Interrupts : Interfaces.C.int;
  84    pragma Import
  85      (C, Unreserve_All_Interrupts, "__gl_unreserve_all_interrupts");
  86
  87    -----------------------
  88    -- Local Subprograms --
  89    -----------------------
  90
  91    procedure Notify_Exception
  92      (signo    : Signal;
  93       siginfo  : System.Address;
  94       ucontext : System.Address);
  95    --  This function identifies the Ada exception to be raised using
  96    --  the information when the system received a synchronous signal.
  97    --  Since this function is machine and OS dependent, different code
  98    --  has to be provided for different target.
  99
 100    ----------------------
 101    -- Notify_Exception --
 102    ----------------------
 103
 104    Signal_Mask : aliased sigset_t;
 105    --  The set of signals handled by Notify_Exception
 106
 107    procedure Notify_Exception
 108      (signo    : Signal;
 109       siginfo  : System.Address;
 110       ucontext : System.Address)
 111    is
 112       pragma Unreferenced (siginfo);
 113
 114       --  The GCC unwinder requires adjustments to the signal's machine
 115       --  context to be able to properly unwind through the signal handler.
 116       --  This is achieved by the target specific subprogram below, provided
 117       --  by init.c to be usable by the non-tasking handler also.
 118
 119       procedure Adjust_Context_For_Raise
 120         (signo    : Signal;
 121          ucontext : System.Address);
 122       pragma Import
 123         (C, Adjust_Context_For_Raise, "__gnat_adjust_context_for_raise");
 124
 125       Result  : Interfaces.C.int;
 126
 127    begin
 128       --  With the __builtin_longjmp, the signal mask is not restored, so we
 129       --  need to restore it explicitely.
 130
 131       Result := pthread_sigmask (SIG_UNBLOCK, Signal_Mask'Access, null);
 132       pragma Assert (Result = 0);
 133
 134       --  Perform the necessary context adjustments required by the GCC/ZCX
 135       --  unwinder, harmless in the SJLJ case.
 136
 137       Adjust_Context_For_Raise (signo, ucontext);
 138
 139       --  Check that treatment of exception propagation here
 140       --  is consistent with treatment of the abort signal in
 141       --  System.Task_Primitives.Operations.
 142
 143       case signo is
 144          when SIGFPE =>
 145             raise Constraint_Error;
 146          when SIGILL =>
 147             raise Program_Error;
 148          when SIGSEGV =>
 149             raise Storage_Error;
 150          when SIGBUS =>
 151             raise Storage_Error;
 152          when others =>
 153             null;
 154       end case;
 155    end Notify_Exception;
 156
 157 -------------------------
 158 -- Package Elaboration --
 159 -------------------------
 160
 161 begin
 162    declare
 163       act     : aliased struct_sigaction;
 164       old_act : aliased struct_sigaction;
 165       Result  : System.OS_Interface.int;
 166
 167       function State (Int : Interrupt_ID) return Character;
 168       pragma Import (C, State, "__gnat_get_interrupt_state");
 169       --  Get interrupt state. Defined in a-init.c
 170       --  The input argument is the interrupt number,
 171       --  and the result is one of the following:
 172
 173       User    : constant Character := 'u';
 174       Runtime : constant Character := 'r';
 175       Default : constant Character := 's';
 176       --    'n'   this interrupt not set by any Interrupt_State pragma
 177       --    'u'   Interrupt_State pragma set state to User
 178       --    'r'   Interrupt_State pragma set state to Runtime
 179       --    's'   Interrupt_State pragma set state to System (use "default"
 180       --           system handler)
 181
 182    begin
 183       --  Need to call pthread_init very early because it is doing signal
 184       --  initializations.
 185
 186       pthread_init;
 187
 188       Abort_Task_Interrupt := SIGADAABORT;
 189
 190       act.sa_handler := Notify_Exception'Address;
 191
 192       act.sa_flags := SA_SIGINFO;
 193
 194       --  Setting SA_SIGINFO asks the kernel to pass more than just the signal
 195       --  number argument to the handler when it is called. The set of extra
 196       --  parameters includes a pointer to the interrupted context, which the
 197       --  ZCX propagation scheme needs.
 198
 199       --  Most man pages for sigaction mention that sa_sigaction should be set
 200       --  instead of sa_handler when SA_SIGINFO is on.  In practice, the two
 201       --  fields are actually union'ed and located at the same offset.
 202
 203       --  On some targets, we set sa_flags to SA_NODEFER so that during the
 204       --  handler execution we do not change the Signal_Mask to be masked for
 205       --  the Signal.
 206
 207       --  This is a temporary fix to the problem that the Signal_Mask is
 208       --  not restored after the exception (longjmp) from the handler.
 209       --  The right fix should be made in sigsetjmp so that we save
 210       --  the Signal_Set and restore it after a longjmp.
 211
 212       --  Since SA_NODEFER is obsolete, instead we reset explicitely
 213       --  the mask in the exception handler.
 214
 215       Result := sigemptyset (Signal_Mask'Access);
 216       pragma Assert (Result = 0);
 217
 218       --  Add signals that map to Ada exceptions to the mask.
 219       for J in Exception_Interrupts'Range loop
 220          if State (Exception_Interrupts (J)) /= Default  then
 221             Result :=
 222             sigaddset (Signal_Mask'Access, Signal (Exception_Interrupts (J)));
 223             pragma Assert (Result = 0);
 224          end if;
 225       end loop;
 226
 227       act.sa_mask := Signal_Mask;
 228
 229       pragma Assert (Keep_Unmasked = (Interrupt_ID'Range => False));
 230       pragma Assert (Reserve = (Interrupt_ID'Range => False));
 231
 232       --  Process state of exception signals
 233       for J in Exception_Interrupts'Range loop
 234          if State (Exception_Interrupts (J)) /= User then
 235             Keep_Unmasked (Exception_Interrupts (J)) := True;
 236             Reserve (Exception_Interrupts (J)) := True;
 237
 238             if State (Exception_Interrupts (J)) /= Default then
 239                Result :=
 240                  sigaction
 241                  (Signal (Exception_Interrupts (J)), act'Unchecked_Access,
 242                   old_act'Unchecked_Access);
 243                pragma Assert (Result = 0);
 244             end if;
 245          end if;
 246       end loop;
 247
 248       if State (Abort_Task_Interrupt) /= User then
 249          Keep_Unmasked (Abort_Task_Interrupt) := True;
 250          Reserve (Abort_Task_Interrupt) := True;
 251       end if;
 252
 253       --  Set SIGINT to unmasked state as long as it is not in "User"
 254       --  state. Check for Unreserve_All_Interrupts last
 255
 256       if State (SIGINT) /= User then
 257          Keep_Unmasked (SIGINT) := True;
 258          Reserve (SIGINT) := True;
 259       end if;
 260
 261       --  Check all signals for state that requires keeping them
 262       --  unmasked and reserved
 263
 264       for J in Interrupt_ID'Range loop
 265          if State (J) = Default or else State (J) = Runtime then
 266             Keep_Unmasked (J) := True;
 267             Reserve (J) := True;
 268          end if;
 269       end loop;
 270
 271       --  Add the set of signals that must always be unmasked for this target
 272
 273       for J in Unmasked'Range loop
 274          Keep_Unmasked (Interrupt_ID (Unmasked (J))) := True;
 275          Reserve (Interrupt_ID (Unmasked (J))) := True;
 276       end loop;
 277
 278       --  Add target-specific reserved signals
 279
 280       for J in Reserved'Range loop
 281          Reserve (Interrupt_ID (Reserved (J))) := True;
 282       end loop;
 283
 284       --  Process pragma Unreserve_All_Interrupts. This overrides any
 285       --  settings due to pragma Interrupt_State:
 286
 287       if Unreserve_All_Interrupts /= 0 then
 288          Keep_Unmasked (SIGINT) := False;
 289          Reserve (SIGINT) := False;
 290       end if;
 291
 292       --  We do not have Signal 0 in reality. We just use this value
 293       --  to identify non-existent signals (see s-intnam.ads). Therefore,
 294       --  Signal 0 should not be used in all signal related operations hence
 295       --  mark it as reserved.
 296
 297       Reserve (0) := True;
 298    end;
 299 end System.Interrupt_Management;