gcc/ada/s-imgwch.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                     S Y S T E M . I M G _ W C H A R                      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Interfaces; use Interfaces;
  35
  36 with System.Img_Char; use System.Img_Char;
  37 with System.WCh_Con;  use System.WCh_Con;
  38 with System.WCh_WtS;  use System.WCh_WtS;
  39
  40 package body System.Img_WChar is
  41
  42    --------------------------
  43    -- Image_Wide_Character --
  44    --------------------------
  45
  46    function Image_Wide_Character
  47      (V  : Wide_Character;
  48       EM : WC_Encoding_Method) return String
  49    is
  50       Val : constant Unsigned_16 := Wide_Character'Pos (V);
  51       WS  : Wide_String (1 .. 3);
  52
  53    begin
  54       --  If in range of standard character, use standard character routine
  55
  56       if Val < 16#80#
  57         or else (Val <= 16#FF#
  58                   and then EM not in WC_Upper_Half_Encoding_Method)
  59       then
  60          return Image_Character (Character'Val (Val));
  61
  62       --  if the value is one of the last two characters in the type, use
  63       --  their language-defined names (3.5.2(3)).
  64
  65       elsif Val = 16#FFFE# then
  66          return "FFFE";
  67
  68       elsif Val = 16#FFFF# then
  69          return "FFFF";
  70
  71       --  Otherwise return an appropriate escape sequence (i.e. one matching
  72       --  the convention implemented by Scn.Wide_Char). The easiest thing is
  73       --  to build a wide string for the result, and then use the Wide_Value
  74       --  function to build the resulting String.
  75
  76       else
  77          WS (1) := ''';
  78          WS (2) := V;
  79          WS (3) := ''';
  80
  81          return Wide_String_To_String (WS, EM);
  82       end if;
  83    end Image_Wide_Character;
  84
  85    -------------------------------
  86    -- Image_Wide_Wide_Character --
  87    -------------------------------
  88
  89    function Image_Wide_Wide_Character
  90      (V  : Wide_Wide_Character;
  91       EM : WC_Encoding_Method) return String
  92    is
  93       Val : constant Unsigned_32 := Wide_Wide_Character'Pos (V);
  94       WS  : Wide_Wide_String (1 .. 3);
  95
  96    begin
  97       --  If in range of standard Wide_Character, then we use the
  98       --  Wide_Character routine
  99
 100       if Val <= 16#FFFF# then
 101          return Image_Wide_Character (Wide_Character'Val (Val), EM);
 102
 103       --  Otherwise return an appropriate escape sequence (i.e. one matching
 104       --  the convention implemented by Scn.Wide_Wide_Char). The easiest thing
 105       --  is to build a wide string for the result, and then use the
 106       --  Wide_Wide_Value function to build the resulting String.
 107
 108       else
 109          WS (1) := ''';
 110          WS (2) := V;
 111          WS (3) := ''';
 112
 113          return Wide_Wide_String_To_String (WS, EM);
 114       end if;
 115    end Image_Wide_Wide_Character;
 116
 117 end System.Img_WChar;