gcc/ada/s-imgllb.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                       S Y S T E M . I M G _ L L B                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.6 $                              --
  10 --                                                                          --
  11 --     Copyright (C) 1992,1993,1994,1995 Free Software Foundation, Inc.     --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 with System.Unsigned_Types; use System.Unsigned_Types;
  37
  38 package body System.Img_LLB is
  39
  40    ---------------------------------------
  41    -- Set_Image_Based_Long_Long_Integer --
  42    ---------------------------------------
  43
  44    procedure Set_Image_Based_Long_Long_Integer
  45      (V : Long_Long_Integer;
  46       B : Natural;
  47       W : Integer;
  48       S : out String;
  49       P : in out Natural)
  50    is
  51       Start : Natural;
  52
  53    begin
  54       --  Positive case can just use the unsigned circuit directly
  55
  56       if V >= 0 then
  57          Set_Image_Based_Long_Long_Unsigned
  58            (Long_Long_Unsigned (V), B, W, S, P);
  59
  60       --  Negative case has to set a minus sign. Note also that we have to be
  61       --  careful not to generate overflow with the largest negative number.
  62
  63       else
  64          P := P + 1;
  65          S (P) := ' ';
  66          Start := P;
  67
  68          declare
  69             pragma Suppress (Overflow_Check);
  70             pragma Suppress (Range_Check);
  71          begin
  72             Set_Image_Based_Long_Long_Unsigned
  73               (Long_Long_Unsigned (-V), B, W - 1, S, P);
  74          end;
  75
  76          --  Set minus sign in last leading blank location. Because of the
  77          --  code above, there must be at least one such location.
  78
  79          while S (Start + 1) = ' ' loop
  80             Start := Start + 1;
  81          end loop;
  82
  83          S (Start) := '-';
  84       end if;
  85
  86    end Set_Image_Based_Long_Long_Integer;
  87
  88    ----------------------------------------
  89    -- Set_Image_Based_Long_Long_Unsigned --
  90    ----------------------------------------
  91
  92    procedure Set_Image_Based_Long_Long_Unsigned
  93      (V : Long_Long_Unsigned;
  94       B : Natural;
  95       W : Integer;
  96       S : out String;
  97       P : in out Natural)
  98    is
  99       Start : constant Natural := P;
 100       F, T  : Natural;
 101       BU    : constant Long_Long_Unsigned := Long_Long_Unsigned (B);
 102       Hex   : constant array
 103                 (Long_Long_Unsigned range 0 .. 15) of Character :=
 104                                                          "0123456789ABCDEF";
 105
 106       procedure Set_Digits (T : Long_Long_Unsigned);
 107       --  Set digits of absolute value of T
 108
 109       procedure Set_Digits (T : Long_Long_Unsigned) is
 110       begin
 111          if T >= BU then
 112             Set_Digits (T / BU);
 113             P := P + 1;
 114             S (P) := Hex (T mod BU);
 115          else
 116             P := P + 1;
 117             S (P) := Hex (T);
 118          end if;
 119       end Set_Digits;
 120
 121    --  Start of processing for Set_Image_Based_Long_Long_Unsigned
 122
 123    begin
 124
 125       if B >= 10 then
 126          P := P + 1;
 127          S (P) := '1';
 128       end if;
 129
 130       P := P + 1;
 131       S (P) := Character'Val (Character'Pos ('0') + B mod 10);
 132
 133       P := P + 1;
 134       S (P) := '#';
 135
 136       Set_Digits (V);
 137
 138       P := P + 1;
 139       S (P) := '#';
 140
 141       --  Add leading spaces if required by width parameter
 142
 143       if P - Start < W then
 144          F := P;
 145          P := Start + W;
 146          T := P;
 147
 148          while F > Start loop
 149             S (T) := S (F);
 150             T := T - 1;
 151             F := F - 1;
 152          end loop;
 153
 154          for J in Start + 1 .. T loop
 155             S (J) := ' ';
 156          end loop;
 157       end if;
 158
 159    end Set_Image_Based_Long_Long_Unsigned;
 160
 161 end System.Img_LLB;