gcc/ada/s-fatgen.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                       S Y S T E M . F A T _ G E N                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2003 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  The implementation here is portable to any IEEE implementation. It does
  35 --  not handle non-binary radix, and also assumes that model numbers and
  36 --  machine numbers are basically identical, which is not true of all possible
  37 --  floating-point implementations. On a non-IEEE machine, this body must be
  38 --  specialized appropriately, or better still, its generic instantiations
  39 --  should be replaced by efficient machine-specific code.
  40
  41 with Ada.Unchecked_Conversion;
  42 with System;
  43 package body System.Fat_Gen is
  44
  45    Float_Radix        : constant T := T (T'Machine_Radix);
  46    Radix_To_M_Minus_1 : constant T := Float_Radix ** (T'Machine_Mantissa - 1);
  47
  48    pragma Assert (T'Machine_Radix = 2);
  49    --  This version does not handle radix 16
  50
  51    --  Constants for Decompose and Scaling
  52
  53    Rad    : constant T := T (T'Machine_Radix);
  54    Invrad : constant T := 1.0 / Rad;
  55
  56    subtype Expbits is Integer range 0 .. 6;
  57    --  2 ** (2 ** 7) might overflow.  how big can radix-16 exponents get?
  58
  59    Log_Power : constant array (Expbits) of Integer := (1, 2, 4, 8, 16, 32, 64);
  60
  61    R_Power : constant array (Expbits) of T :=
  62      (Rad **  1,
  63       Rad **  2,
  64       Rad **  4,
  65       Rad **  8,
  66       Rad ** 16,
  67       Rad ** 32,
  68       Rad ** 64);
  69
  70    R_Neg_Power : constant array (Expbits) of T :=
  71      (Invrad **  1,
  72       Invrad **  2,
  73       Invrad **  4,
  74       Invrad **  8,
  75       Invrad ** 16,
  76       Invrad ** 32,
  77       Invrad ** 64);
  78
  79    -----------------------
  80    -- Local Subprograms --
  81    -----------------------
  82
  83    procedure Decompose (XX : T; Frac : out T; Expo : out UI);
  84    --  Decomposes a floating-point number into fraction and exponent parts
  85
  86    function Gradual_Scaling  (Adjustment : UI) return T;
  87    --  Like Scaling with a first argument of 1.0, but returns the smallest
  88    --  denormal rather than zero when the adjustment is smaller than
  89    --  Machine_Emin. Used for Succ and Pred.
  90
  91    --------------
  92    -- Adjacent --
  93    --------------
  94
  95    function Adjacent (X, Towards : T) return T is
  96    begin
  97       if Towards = X then
  98          return X;
  99
 100       elsif Towards > X then
 101          return Succ (X);
 102
 103       else
 104          return Pred (X);
 105       end if;
 106    end Adjacent;
 107
 108    -------------
 109    -- Ceiling --
 110    -------------
 111
 112    function Ceiling (X : T) return T is
 113       XT : constant T := Truncation (X);
 114
 115    begin
 116       if X <= 0.0 then
 117          return XT;
 118
 119       elsif X = XT then
 120          return X;
 121
 122       else
 123          return XT + 1.0;
 124       end if;
 125    end Ceiling;
 126
 127    -------------
 128    -- Compose --
 129    -------------
 130
 131    function Compose (Fraction : T; Exponent : UI) return T is
 132       Arg_Frac : T;
 133       Arg_Exp  : UI;
 134
 135    begin
 136       Decompose (Fraction, Arg_Frac, Arg_Exp);
 137       return Scaling (Arg_Frac, Exponent);
 138    end Compose;
 139
 140    ---------------
 141    -- Copy_Sign --
 142    ---------------
 143
 144    function Copy_Sign (Value, Sign : T) return T is
 145       Result : T;
 146
 147       function Is_Negative (V : T) return Boolean;
 148       pragma Import (Intrinsic, Is_Negative);
 149
 150    begin
 151       Result := abs Value;
 152
 153       if Is_Negative (Sign) then
 154          return -Result;
 155       else
 156          return Result;
 157       end if;
 158    end Copy_Sign;
 159
 160    ---------------
 161    -- Decompose --
 162    ---------------
 163
 164    procedure Decompose (XX : T; Frac : out T; Expo : out UI) is
 165       X : constant T := T'Machine (XX);
 166
 167    begin
 168       if X = 0.0 then
 169          Frac := X;
 170          Expo := 0;
 171
 172          --  More useful would be defining Expo to be T'Machine_Emin - 1 or
 173          --  T'Machine_Emin - T'Machine_Mantissa, which would preserve
 174          --  monotonicity of the exponent function ???
 175
 176       --  Check for infinities, transfinites, whatnot.
 177
 178       elsif X > T'Safe_Last then
 179          Frac := Invrad;
 180          Expo := T'Machine_Emax + 1;
 181
 182       elsif X < T'Safe_First then
 183          Frac := -Invrad;
 184          Expo := T'Machine_Emax + 2;    -- how many extra negative values?
 185
 186       else
 187          --  Case of nonzero finite x. Essentially, we just multiply
 188          --  by Rad ** (+-2**N) to reduce the range.
 189
 190          declare
 191             Ax : T  := abs X;
 192             Ex : UI := 0;
 193
 194          --  Ax * Rad ** Ex is invariant.
 195
 196          begin
 197             if Ax >= 1.0 then
 198                while Ax >= R_Power (Expbits'Last) loop
 199                   Ax := Ax * R_Neg_Power (Expbits'Last);
 200                   Ex := Ex + Log_Power (Expbits'Last);
 201                end loop;
 202
 203                --  Ax < Rad ** 64
 204
 205                for N in reverse Expbits'First .. Expbits'Last - 1 loop
 206                   if Ax >= R_Power (N) then
 207                      Ax := Ax * R_Neg_Power (N);
 208                      Ex := Ex + Log_Power (N);
 209                   end if;
 210
 211                   --  Ax < R_Power (N)
 212                end loop;
 213
 214                --  1 <= Ax < Rad
 215
 216                Ax := Ax * Invrad;
 217                Ex := Ex + 1;
 218
 219             else
 220                --  0 < ax < 1
 221
 222                while Ax < R_Neg_Power (Expbits'Last) loop
 223                   Ax := Ax * R_Power (Expbits'Last);
 224                   Ex := Ex - Log_Power (Expbits'Last);
 225                end loop;
 226
 227                --  Rad ** -64 <= Ax < 1
 228
 229                for N in reverse Expbits'First .. Expbits'Last - 1 loop
 230                   if Ax < R_Neg_Power (N) then
 231                      Ax := Ax * R_Power (N);
 232                      Ex := Ex - Log_Power (N);
 233                   end if;
 234
 235                   --  R_Neg_Power (N) <= Ax < 1
 236                end loop;
 237             end if;
 238
 239             if X > 0.0 then
 240                Frac := Ax;
 241             else
 242                Frac := -Ax;
 243             end if;
 244
 245             Expo := Ex;
 246          end;
 247       end if;
 248    end Decompose;
 249
 250    --------------
 251    -- Exponent --
 252    --------------
 253
 254    function Exponent (X : T) return UI is
 255       X_Frac : T;
 256       X_Exp  : UI;
 257
 258    begin
 259       Decompose (X, X_Frac, X_Exp);
 260       return X_Exp;
 261    end Exponent;
 262
 263    -----------
 264    -- Floor --
 265    -----------
 266
 267    function Floor (X : T) return T is
 268       XT : constant T := Truncation (X);
 269
 270    begin
 271       if X >= 0.0 then
 272          return XT;
 273
 274       elsif XT = X then
 275          return X;
 276
 277       else
 278          return XT - 1.0;
 279       end if;
 280    end Floor;
 281
 282    --------------
 283    -- Fraction --
 284    --------------
 285
 286    function Fraction (X : T) return T is
 287       X_Frac : T;
 288       X_Exp  : UI;
 289
 290    begin
 291       Decompose (X, X_Frac, X_Exp);
 292       return X_Frac;
 293    end Fraction;
 294
 295    ---------------------
 296    -- Gradual_Scaling --
 297    ---------------------
 298
 299    function Gradual_Scaling  (Adjustment : UI) return T is
 300       Y  : T;
 301       Y1 : T;
 302       Ex : UI := Adjustment;
 303
 304    begin
 305       if Adjustment < T'Machine_Emin then
 306          Y  := 2.0 ** T'Machine_Emin;
 307          Y1 := Y;
 308          Ex := Ex - T'Machine_Emin;
 309
 310          while Ex <= 0 loop
 311             Y := T'Machine (Y / 2.0);
 312
 313             if Y = 0.0 then
 314                return Y1;
 315             end if;
 316
 317             Ex := Ex + 1;
 318             Y1 := Y;
 319          end loop;
 320
 321          return Y1;
 322
 323       else
 324          return Scaling (1.0, Adjustment);
 325       end if;
 326    end Gradual_Scaling;
 327
 328    ------------------
 329    -- Leading_Part --
 330    ------------------
 331
 332    function Leading_Part (X : T; Radix_Digits : UI) return T is
 333       L    : UI;
 334       Y, Z : T;
 335
 336    begin
 337       if Radix_Digits >= T'Machine_Mantissa then
 338          return X;
 339
 340       else
 341          L := Exponent (X) - Radix_Digits;
 342          Y := Truncation (Scaling (X, -L));
 343          Z := Scaling (Y, L);
 344          return Z;
 345       end if;
 346
 347    end Leading_Part;
 348
 349    -------------
 350    -- Machine --
 351    -------------
 352
 353    --  The trick with Machine is to force the compiler to store the result
 354    --  in memory so that we do not have extra precision used. The compiler
 355    --  is clever, so we have to outwit its possible optimizations! We do
 356    --  this by using an intermediate pragma Volatile location.
 357
 358    function Machine (X : T) return T is
 359       Temp : T;
 360       pragma Volatile (Temp);
 361
 362    begin
 363       Temp := X;
 364       return Temp;
 365    end Machine;
 366
 367    -----------
 368    -- Model --
 369    -----------
 370
 371    --  We treat Model as identical to Machine. This is true of IEEE and other
 372    --  nice floating-point systems, but not necessarily true of all systems.
 373
 374    function Model (X : T) return T is
 375    begin
 376       return Machine (X);
 377    end Model;
 378
 379    ----------
 380    -- Pred --
 381    ----------
 382
 383    --  Subtract from the given number a number equivalent to the value of its
 384    --  least significant bit. Given that the most significant bit represents
 385    --  a value of 1.0 * radix ** (exp - 1), the value we want is obtained by
 386    --  shifting this by (mantissa-1) bits to the right, i.e. decreasing the
 387    --  exponent by that amount.
 388
 389    --  Zero has to be treated specially, since its exponent is zero
 390
 391    function Pred (X : T) return T is
 392       X_Frac : T;
 393       X_Exp  : UI;
 394
 395    begin
 396       if X = 0.0 then
 397          return -Succ (X);
 398
 399       else
 400          Decompose (X, X_Frac, X_Exp);
 401
 402          --  A special case, if the number we had was a positive power of
 403          --  two, then we want to subtract half of what we would otherwise
 404          --  subtract, since the exponent is going to be reduced.
 405
 406          if X_Frac = 0.5 and then X > 0.0 then
 407             return X - Gradual_Scaling (X_Exp - T'Machine_Mantissa - 1);
 408
 409          --  Otherwise the exponent stays the same
 410
 411          else
 412             return X - Gradual_Scaling (X_Exp - T'Machine_Mantissa);
 413          end if;
 414       end if;
 415    end Pred;
 416
 417    ---------------
 418    -- Remainder --
 419    ---------------
 420
 421    function Remainder (X, Y : T) return T is
 422       A        : T;
 423       B        : T;
 424       Arg      : T;
 425       P        : T;
 426       Arg_Frac : T;
 427       P_Frac   : T;
 428       Sign_X   : T;
 429       IEEE_Rem : T;
 430       Arg_Exp  : UI;
 431       P_Exp    : UI;
 432       K        : UI;
 433       P_Even   : Boolean;
 434
 435    begin
 436       if X > 0.0 then
 437          Sign_X :=  1.0;
 438          Arg := X;
 439       else
 440          Sign_X := -1.0;
 441          Arg := -X;
 442       end if;
 443
 444       P := abs Y;
 445
 446       if Arg < P then
 447          P_Even := True;
 448          IEEE_Rem := Arg;
 449          P_Exp := Exponent (P);
 450
 451       else
 452          Decompose (Arg, Arg_Frac, Arg_Exp);
 453          Decompose (P,   P_Frac,   P_Exp);
 454
 455          P := Compose (P_Frac, Arg_Exp);
 456          K := Arg_Exp - P_Exp;
 457          P_Even := True;
 458          IEEE_Rem := Arg;
 459
 460          for Cnt in reverse 0 .. K loop
 461             if IEEE_Rem >= P then
 462                P_Even := False;
 463                IEEE_Rem := IEEE_Rem - P;
 464             else
 465                P_Even := True;
 466             end if;
 467
 468             P := P * 0.5;
 469          end loop;
 470       end if;
 471
 472       --  That completes the calculation of modulus remainder. The final
 473       --  step is get the IEEE remainder. Here we need to compare Rem with
 474       --  (abs Y) / 2. We must be careful of unrepresentable Y/2 value
 475       --  caused by subnormal numbers
 476
 477       if P_Exp >= 0 then
 478          A := IEEE_Rem;
 479          B := abs Y * 0.5;
 480
 481       else
 482          A := IEEE_Rem * 2.0;
 483          B := abs Y;
 484       end if;
 485
 486       if A > B or else (A = B and then not P_Even) then
 487          IEEE_Rem := IEEE_Rem - abs Y;
 488       end if;
 489
 490       return Sign_X * IEEE_Rem;
 491
 492    end Remainder;
 493
 494    --------------
 495    -- Rounding --
 496    --------------
 497
 498    function Rounding (X : T) return T is
 499       Result : T;
 500       Tail   : T;
 501
 502    begin
 503       Result := Truncation (abs X);
 504       Tail   := abs X - Result;
 505
 506       if Tail >= 0.5  then
 507          Result := Result + 1.0;
 508       end if;
 509
 510       if X > 0.0 then
 511          return Result;
 512
 513       elsif X < 0.0 then
 514          return -Result;
 515
 516       --  For zero case, make sure sign of zero is preserved
 517
 518       else
 519          return X;
 520       end if;
 521
 522    end Rounding;
 523
 524    -------------
 525    -- Scaling --
 526    -------------
 527
 528    --  Return x * rad ** adjustment quickly,
 529    --  or quietly underflow to zero, or overflow naturally.
 530
 531    function Scaling (X : T; Adjustment : UI) return T is
 532    begin
 533       if X = 0.0 or else Adjustment = 0 then
 534          return X;
 535       end if;
 536
 537       --  Nonzero x. essentially, just multiply repeatedly by Rad ** (+-2**n).
 538
 539       declare
 540          Y  : T  := X;
 541          Ex : UI := Adjustment;
 542
 543       --  Y * Rad ** Ex is invariant
 544
 545       begin
 546          if Ex < 0 then
 547             while Ex <= -Log_Power (Expbits'Last) loop
 548                Y := Y * R_Neg_Power (Expbits'Last);
 549                Ex := Ex + Log_Power (Expbits'Last);
 550             end loop;
 551
 552             --  -64 < Ex <= 0
 553
 554             for N in reverse Expbits'First .. Expbits'Last - 1 loop
 555                if Ex <= -Log_Power (N) then
 556                   Y := Y * R_Neg_Power (N);
 557                   Ex := Ex + Log_Power (N);
 558                end if;
 559
 560                --  -Log_Power (N) < Ex <= 0
 561             end loop;
 562
 563             --  Ex = 0
 564
 565          else
 566             --  Ex >= 0
 567
 568             while Ex >= Log_Power (Expbits'Last) loop
 569                Y := Y * R_Power (Expbits'Last);
 570                Ex := Ex - Log_Power (Expbits'Last);
 571             end loop;
 572
 573             --  0 <= Ex < 64
 574
 575             for N in reverse Expbits'First .. Expbits'Last - 1 loop
 576                if Ex >= Log_Power (N) then
 577                   Y := Y * R_Power (N);
 578                   Ex := Ex - Log_Power (N);
 579                end if;
 580
 581                --  0 <= Ex < Log_Power (N)
 582             end loop;
 583
 584             --  Ex = 0
 585          end if;
 586          return Y;
 587       end;
 588    end Scaling;
 589
 590    ----------
 591    -- Succ --
 592    ----------
 593
 594    --  Similar computation to that of Pred: find value of least significant
 595    --  bit of given number, and add. Zero has to be treated specially since
 596    --  the exponent can be zero, and also we want the smallest denormal if
 597    --  denormals are supported.
 598
 599    function Succ (X : T) return T is
 600       X_Frac : T;
 601       X_Exp  : UI;
 602       X1, X2 : T;
 603
 604    begin
 605       if X = 0.0 then
 606          X1 := 2.0 ** T'Machine_Emin;
 607
 608          --  Following loop generates smallest denormal
 609
 610          loop
 611             X2 := T'Machine (X1 / 2.0);
 612             exit when X2 = 0.0;
 613             X1 := X2;
 614          end loop;
 615
 616          return X1;
 617
 618       else
 619          Decompose (X, X_Frac, X_Exp);
 620
 621          --  A special case, if the number we had was a negative power of
 622          --  two, then we want to add half of what we would otherwise add,
 623          --  since the exponent is going to be reduced.
 624
 625          if X_Frac = 0.5 and then X < 0.0 then
 626             return X + Gradual_Scaling (X_Exp - T'Machine_Mantissa - 1);
 627
 628          --  Otherwise the exponent stays the same
 629
 630          else
 631             return X + Gradual_Scaling (X_Exp - T'Machine_Mantissa);
 632          end if;
 633       end if;
 634    end Succ;
 635
 636    ----------------
 637    -- Truncation --
 638    ----------------
 639
 640    --  The basic approach is to compute
 641
 642    --    T'Machine (RM1 + N) - RM1.
 643
 644    --  where N >= 0.0 and RM1 = radix ** (mantissa - 1)
 645
 646    --  This works provided that the intermediate result (RM1 + N) does not
 647    --  have extra precision (which is why we call Machine). When we compute
 648    --  RM1 + N, the exponent of N will be normalized and the mantissa shifted
 649    --  shifted appropriately so the lower order bits, which cannot contribute
 650    --  to the integer part of N, fall off on the right. When we subtract RM1
 651    --  again, the significant bits of N are shifted to the left, and what we
 652    --  have is an integer, because only the first e bits are different from
 653    --  zero (assuming binary radix here).
 654
 655    function Truncation (X : T) return T is
 656       Result : T;
 657
 658    begin
 659       Result := abs X;
 660
 661       if Result >= Radix_To_M_Minus_1 then
 662          return Machine (X);
 663
 664       else
 665          Result := Machine (Radix_To_M_Minus_1 + Result) - Radix_To_M_Minus_1;
 666
 667          if Result > abs X  then
 668             Result := Result - 1.0;
 669          end if;
 670
 671          if X > 0.0 then
 672             return  Result;
 673
 674          elsif X < 0.0 then
 675             return -Result;
 676
 677          --  For zero case, make sure sign of zero is preserved
 678
 679          else
 680             return X;
 681          end if;
 682       end if;
 683
 684    end Truncation;
 685
 686    -----------------------
 687    -- Unbiased_Rounding --
 688    -----------------------
 689
 690    function Unbiased_Rounding (X : T) return T is
 691       Abs_X  : constant T := abs X;
 692       Result : T;
 693       Tail   : T;
 694
 695    begin
 696       Result := Truncation (Abs_X);
 697       Tail   := Abs_X - Result;
 698
 699       if Tail > 0.5  then
 700          Result := Result + 1.0;
 701
 702       elsif Tail = 0.5 then
 703          Result := 2.0 * Truncation ((Result / 2.0) + 0.5);
 704       end if;
 705
 706       if X > 0.0 then
 707          return Result;
 708
 709       elsif X < 0.0 then
 710          return -Result;
 711
 712       --  For zero case, make sure sign of zero is preserved
 713
 714       else
 715          return X;
 716       end if;
 717
 718    end Unbiased_Rounding;
 719
 720    -----------
 721    -- Valid --
 722    -----------
 723
 724    function Valid (X : access T) return Boolean is
 725
 726       IEEE_Emin : constant Integer := T'Machine_Emin - 1;
 727       IEEE_Emax : constant Integer := T'Machine_Emax - 1;
 728
 729       IEEE_Bias : constant Integer := -(IEEE_Emin - 1);
 730
 731       subtype IEEE_Exponent_Range is
 732         Integer range IEEE_Emin - 1 .. IEEE_Emax + 1;
 733
 734       --  The implementation of this floating point attribute uses
 735       --  a representation type Float_Rep that allows direct access to
 736       --  the exponent and mantissa parts of a floating point number.
 737
 738       --  The Float_Rep type is an array of Float_Word elements. This
 739       --  representation is chosen to make it possible to size the
 740       --  type based on a generic parameter. Since the array size is
 741       --  known at compile-time, efficient code can still be generated.
 742       --  The size of Float_Word elements should be large enough to allow
 743       --  accessing the exponent in one read, but small enough so that all
 744       --  floating point object sizes are a multiple of the Float_Word'Size.
 745
 746       --  The following conditions must be met for all possible
 747       --  instantiations of the attributes package:
 748
 749       --    - T'Size is an integral multiple of Float_Word'Size
 750
 751       --    - The exponent and sign are completely contained in a single
 752       --      component of Float_Rep, named Most_Significant_Word (MSW).
 753
 754       --    - The sign occupies the most significant bit of the MSW
 755       --      and the exponent is in the following bits.
 756       --      Unused bits (if any) are in the least significant part.
 757
 758       type Float_Word is mod 2**Positive'Min (System.Word_Size, 32);
 759       type Rep_Index is range 0 .. 7;
 760
 761       Rep_Last : constant Rep_Index := (T'Size - 1) / Float_Word'Size;
 762
 763       type Float_Rep is array (Rep_Index range 0 .. Rep_Last) of Float_Word;
 764
 765       pragma Suppress_Initialization (Float_Rep);
 766       --  This pragma supresses the generation of an initialization procedure
 767       --  for type Float_Rep when operating in Initialize/Normalize_Scalars
 768       --  mode. This is not just a matter of efficiency, but of functionality,
 769       --  since Valid has a pragma Inline_Always, which is not permitted if
 770       --  there are nested subprograms present.
 771
 772       Most_Significant_Word : constant Rep_Index :=
 773                                 Rep_Last * Standard'Default_Bit_Order;
 774       --  Finding the location of the Exponent_Word is a bit tricky.
 775       --  In general we assume Word_Order = Bit_Order.
 776       --  This expression needs to be refined for VMS.
 777
 778       Exponent_Factor : constant Float_Word :=
 779                           2**(Float_Word'Size - 1) /
 780                             Float_Word (IEEE_Emax - IEEE_Emin + 3) *
 781                               Boolean'Pos (T'Size /= 96) +
 782                                 Boolean'Pos (T'Size = 96);
 783       --  Factor that the extracted exponent needs to be divided by
 784       --  to be in range 0 .. IEEE_Emax - IEEE_Emin + 2.
 785       --  Special kludge: Exponent_Factor is 0 for x86 double extended
 786       --  as GCC adds 16 unused bits to the type.
 787
 788       Exponent_Mask : constant Float_Word :=
 789                         Float_Word (IEEE_Emax - IEEE_Emin + 2) *
 790                           Exponent_Factor;
 791       --  Value needed to mask out the exponent field.
 792       --  This assumes that the range IEEE_Emin - 1 .. IEEE_Emax + 1
 793       --  contains 2**N values, for some N in Natural.
 794
 795       function To_Float is new Ada.Unchecked_Conversion (Float_Rep, T);
 796
 797       type Float_Access is access all T;
 798       function To_Address is
 799          new Ada.Unchecked_Conversion (Float_Access, System.Address);
 800
 801       XA : constant System.Address := To_Address (Float_Access (X));
 802
 803       R : Float_Rep;
 804       pragma Import (Ada, R);
 805       for R'Address use XA;
 806       --  R is a view of the input floating-point parameter. Note that we
 807       --  must avoid copying the actual bits of this parameter in float
 808       --  form (since it may be a signalling NaN.
 809
 810       E  : constant IEEE_Exponent_Range :=
 811              Integer ((R (Most_Significant_Word) and Exponent_Mask) /
 812                                                         Exponent_Factor)
 813                - IEEE_Bias;
 814       --  Mask/Shift T to only get bits from the exponent
 815       --  Then convert biased value to integer value.
 816
 817       SR : Float_Rep;
 818       --  Float_Rep representation of significant of X.all
 819
 820    begin
 821       if T'Denorm then
 822
 823          --  All denormalized numbers are valid, so only invalid numbers
 824          --  are overflows and NaN's, both with exponent = Emax + 1.
 825
 826          return E /= IEEE_Emax + 1;
 827
 828       end if;
 829
 830       --  All denormalized numbers except 0.0 are invalid
 831
 832       --  Set exponent of X to zero, so we end up with the significand, which
 833       --  definitely is a valid number and can be converted back to a float.
 834
 835       SR := R;
 836       SR (Most_Significant_Word) :=
 837            (SR (Most_Significant_Word)
 838              and not Exponent_Mask) + Float_Word (IEEE_Bias) * Exponent_Factor;
 839
 840       return (E in IEEE_Emin .. IEEE_Emax) or else
 841          ((E = IEEE_Emin - 1) and then abs To_Float (SR) = 1.0);
 842    end Valid;
 843
 844    ---------------------
 845    -- Unaligned_Valid --
 846    ---------------------
 847
 848    function Unaligned_Valid (A : System.Address) return Boolean is
 849       subtype FS is String (1 .. T'Size / Character'Size);
 850       type FSP is access FS;
 851
 852       function To_FSP is new Ada.Unchecked_Conversion (Address, FSP);
 853
 854       Local_T : aliased T;
 855
 856    begin
 857       To_FSP (Local_T'Address).all := To_FSP (A).all;
 858       return Valid (Local_T'Access);
 859    end Unaligned_Valid;
 860
 861 end System.Fat_Gen;