gcc/ada/s-caun32.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                   GNU ADA RUNTIME LIBRARY COMPONENTS                     --
   4 --                                                                          --
   5 --      S Y S T E M . C O M P A R E _ A R R A Y _ U N S I G N E D _ 3 2     --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Unchecked_Conversion;
  35
  36 package body System.Compare_Array_Unsigned_32 is
  37
  38    function "+" (Left, Right : Address) return Address;
  39    pragma Import (Intrinsic, "+");
  40    --  Provide addition operation on type Address (this may not be directly
  41    --  available if type System.Address is non-private and the operations on
  42    --  the type are made abstract to hide them from public users of System.
  43
  44    type Word is mod 2 ** 32;
  45    for Word'Size use 32;
  46    --  Used to process operands by words
  47
  48    type Uword is record
  49       W : Word;
  50    end record;
  51    pragma Pack (Uword);
  52    for Uword'Alignment use 1;
  53    --  Used to process operands when unaligned
  54
  55    type WP is access Word;
  56    type UP is access Uword;
  57
  58    function W is new Unchecked_Conversion (Address, WP);
  59    function U is new Unchecked_Conversion (Address, UP);
  60
  61    -----------------------
  62    -- Compare_Array_U32 --
  63    -----------------------
  64
  65    function Compare_Array_U32
  66      (Left      : System.Address;
  67       Right     : System.Address;
  68       Left_Len  : Natural;
  69       Right_Len : Natural)
  70       return      Integer
  71    is
  72       Clen : Natural := Natural'Min (Left_Len, Right_Len);
  73       --  Number of elements left to compare
  74
  75       L : Address := Left;
  76       R : Address := Right;
  77       --  Pointers to next elements to compare
  78
  79    begin
  80       --  Case of going by aligned words
  81
  82       if ((Left or Right) and (4 - 1)) = 0 then
  83          while Clen /= 0 loop
  84             if W (L).all /= W (R).all then
  85                if W (L).all > W (R).all then
  86                   return +1;
  87                else
  88                   return -1;
  89                end if;
  90             end if;
  91
  92             Clen := Clen - 1;
  93             L := L + 4;
  94             R := R + 4;
  95          end loop;
  96
  97       --  Case of going by unaligned words
  98
  99       else
 100          while Clen /= 0 loop
 101             if U (L).W /= U (R).W then
 102                if U (L).W > U (R).W then
 103                   return +1;
 104                else
 105                   return -1;
 106                end if;
 107             end if;
 108
 109             Clen := Clen - 1;
 110             L := L + 4;
 111             R := R + 4;
 112          end loop;
 113       end if;
 114
 115       --  Here if common section equal, result decided by lengths
 116
 117       if Left_Len = Right_Len then
 118          return 0;
 119       elsif Left_Len > Right_Len then
 120          return +1;
 121       else
 122          return -1;
 123       end if;
 124    end Compare_Array_U32;
 125
 126 end System.Compare_Array_Unsigned_32;