gcc/ada/s-casi16.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                   GNU ADA RUNTIME LIBRARY COMPONENTS                     --
   4 --                                                                          --
   5 --        S Y S T E M . C O M P A R E _ A R R A Y _ S I G N E D _ 16        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Unchecked_Conversion;
  35
  36 package body System.Compare_Array_Signed_16 is
  37
  38    function "+" (Left, Right : Address) return Address;
  39    pragma Import (Intrinsic, "+");
  40    --  Provide addition operation on type Address (this may not be directly
  41    --  available if type System.Address is non-private and the operations on
  42    --  the type are made abstract to hide them from public users of System.
  43
  44    type Word is mod 2 ** 32;
  45    --  Used to process operands by words
  46
  47    type Half is range -(2 ** 15) .. (2 ** 15) - 1;
  48    for Half'Size use 16;
  49    --  Used to process operands by half words
  50
  51    type Uhalf is record
  52       H : Half;
  53    end record;
  54    pragma Pack (Uhalf);
  55    for Uhalf'Alignment use 1;
  56    --  Used to process operands when unaligned
  57
  58    type WP is access Word;
  59    type HP is access Half;
  60    type UP is access Uhalf;
  61
  62    function W is new Unchecked_Conversion (Address, WP);
  63    function H is new Unchecked_Conversion (Address, HP);
  64    function U is new Unchecked_Conversion (Address, UP);
  65
  66    -----------------------
  67    -- Compare_Array_S16 --
  68    -----------------------
  69
  70    function Compare_Array_S16
  71      (Left      : System.Address;
  72       Right     : System.Address;
  73       Left_Len  : Natural;
  74       Right_Len : Natural)
  75       return      Integer
  76    is
  77       Clen : Natural := Natural'Min (Left_Len, Right_Len);
  78       --  Number of elements left to compare
  79
  80       L : Address := Left;
  81       R : Address := Right;
  82       --  Pointers to next elements to compare
  83
  84    begin
  85       --  Go by words if possible
  86
  87       if ((Left or Right) and (4 - 1)) = 0 then
  88          while Clen > 1
  89            and then W (L).all = W (R).all
  90          loop
  91             Clen := Clen - 2;
  92             L := L + 4;
  93             R := R + 4;
  94          end loop;
  95       end if;
  96
  97       --  Case of going by aligned half words
  98
  99       if ((Left or Right) and (2 - 1)) = 0 then
 100          while Clen /= 0 loop
 101             if H (L).all /= H (R).all then
 102                if H (L).all > H (R).all then
 103                   return +1;
 104                else
 105                   return -1;
 106                end if;
 107             end if;
 108
 109             Clen := Clen - 1;
 110             L := L + 2;
 111             R := R + 2;
 112          end loop;
 113
 114       --  Case of going by unaligned half words
 115
 116       else
 117          while Clen /= 0 loop
 118             if U (L).H /= U (R).H then
 119                if U (L).H > U (R).H then
 120                   return +1;
 121                else
 122                   return -1;
 123                end if;
 124             end if;
 125
 126             Clen := Clen - 1;
 127             L := L + 2;
 128             R := R + 2;
 129          end loop;
 130       end if;
 131
 132       --  Here if common section equal, result decided by lengths
 133
 134       if Left_Len = Right_Len then
 135          return 0;
 136       elsif Left_Len > Right_Len then
 137          return +1;
 138       else
 139          return -1;
 140       end if;
 141    end Compare_Array_S16;
 142
 143 end System.Compare_Array_Signed_16;