gcc/ada/s-carun8.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --       S Y S T E M . C O M P A R E _ A R R A Y _ U N S I G N E D _ 8      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 pragma Warnings (Off);
  35 pragma Compiler_Unit;
  36 pragma Warnings (On);
  37
  38 with System.Address_Operations; use System.Address_Operations;
  39
  40 with Ada.Unchecked_Conversion;
  41
  42 package body System.Compare_Array_Unsigned_8 is
  43
  44    type Word is mod 2 ** 32;
  45    --  Used to process operands by words
  46
  47    type Big_Words is array (Natural) of Word;
  48    type Big_Words_Ptr is access Big_Words;
  49    --  Array type used to access by words
  50
  51    type Byte is mod 2 ** 8;
  52    --  Used to process operands by bytes
  53
  54    type Big_Bytes is array (Natural) of Byte;
  55    type Big_Bytes_Ptr is access Big_Bytes;
  56    --  Array type used to access by bytes
  57
  58    function To_Big_Words is new
  59      Ada.Unchecked_Conversion (System.Address, Big_Words_Ptr);
  60
  61    function To_Big_Bytes is new
  62      Ada.Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  63
  64    ----------------------
  65    -- Compare_Array_U8 --
  66    ----------------------
  67
  68    function Compare_Array_U8
  69      (Left      : System.Address;
  70       Right     : System.Address;
  71       Left_Len  : Natural;
  72       Right_Len : Natural) return Integer
  73    is
  74       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  75
  76    begin
  77       --  If operands are non-aligned, or length is too short, go by bytes
  78
  79       if (ModA (OrA (Left, Right), 4) /= 0) or else Compare_Len < 4 then
  80          return Compare_Array_U8_Unaligned (Left, Right, Left_Len, Right_Len);
  81       end if;
  82
  83       --  Here we can go by words
  84
  85       declare
  86          LeftP                   : constant Big_Words_Ptr :=
  87                                      To_Big_Words (Left);
  88          RightP                  : constant Big_Words_Ptr :=
  89                                      To_Big_Words (Right);
  90          Words_To_Compare        : constant Natural := Compare_Len / 4;
  91          Bytes_Compared_As_Words : constant Natural := Words_To_Compare * 4;
  92
  93       begin
  94          for J in 0 .. Words_To_Compare - 1 loop
  95             if LeftP (J) /= RightP (J) then
  96                return Compare_Array_U8_Unaligned
  97                         (AddA (Left,  Address (4 * J)),
  98                          AddA (Right, Address (4 * J)),
  99                          4, 4);
 100             end if;
 101          end loop;
 102
 103          return Compare_Array_U8_Unaligned
 104                   (AddA (Left,  Address (Bytes_Compared_As_Words)),
 105                    AddA (Right, Address (Bytes_Compared_As_Words)),
 106                    Left_Len  - Bytes_Compared_As_Words,
 107                    Right_Len - Bytes_Compared_As_Words);
 108       end;
 109    end Compare_Array_U8;
 110
 111    --------------------------------
 112    -- Compare_Array_U8_Unaligned --
 113    --------------------------------
 114
 115    function Compare_Array_U8_Unaligned
 116      (Left      : System.Address;
 117       Right     : System.Address;
 118       Left_Len  : Natural;
 119       Right_Len : Natural) return Integer
 120    is
 121       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 122
 123       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 124       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 125
 126    begin
 127       for J in 0 .. Compare_Len - 1 loop
 128          if LeftP (J) /= RightP (J) then
 129             if LeftP (J) > RightP (J) then
 130                return +1;
 131             else
 132                return -1;
 133             end if;
 134          end if;
 135       end loop;
 136
 137       if Left_Len = Right_Len then
 138          return 0;
 139       elsif Left_Len > Right_Len then
 140          return +1;
 141       else
 142          return -1;
 143       end if;
 144    end Compare_Array_U8_Unaligned;
 145
 146 end System.Compare_Array_Unsigned_8;