gcc/ada/s-carun8.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --       S Y S T E M . C O M P A R E _ A R R A Y _ U N S I G N E D _ 8      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 pragma Warnings (Off);
  35 pragma Compiler_Unit;
  36 pragma Warnings (On);
  37
  38 with System.Address_Operations; use System.Address_Operations;
  39
  40 with Ada.Unchecked_Conversion;
  41
  42 package body System.Compare_Array_Unsigned_8 is
  43
  44    type Word is mod 2 ** 32;
  45    --  Used to process operands by words
  46
  47    type Big_Words is array (Natural) of Word;
  48    type Big_Words_Ptr is access Big_Words;
  49    for Big_Words_Ptr'Storage_Size use 0;
  50    --  Array type used to access by words
  51
  52    type Byte is mod 2 ** 8;
  53    --  Used to process operands by bytes
  54
  55    type Big_Bytes is array (Natural) of Byte;
  56    type Big_Bytes_Ptr is access Big_Bytes;
  57    for Big_Bytes_Ptr'Storage_Size use 0;
  58    --  Array type used to access by bytes
  59
  60    function To_Big_Words is new
  61      Ada.Unchecked_Conversion (System.Address, Big_Words_Ptr);
  62
  63    function To_Big_Bytes is new
  64      Ada.Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  65
  66    ----------------------
  67    -- Compare_Array_U8 --
  68    ----------------------
  69
  70    function Compare_Array_U8
  71      (Left      : System.Address;
  72       Right     : System.Address;
  73       Left_Len  : Natural;
  74       Right_Len : Natural) return Integer
  75    is
  76       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  77
  78    begin
  79       --  If operands are non-aligned, or length is too short, go by bytes
  80
  81       if (ModA (OrA (Left, Right), 4) /= 0) or else Compare_Len < 4 then
  82          return Compare_Array_U8_Unaligned (Left, Right, Left_Len, Right_Len);
  83       end if;
  84
  85       --  Here we can go by words
  86
  87       declare
  88          LeftP                   : constant Big_Words_Ptr :=
  89                                      To_Big_Words (Left);
  90          RightP                  : constant Big_Words_Ptr :=
  91                                      To_Big_Words (Right);
  92          Words_To_Compare        : constant Natural := Compare_Len / 4;
  93          Bytes_Compared_As_Words : constant Natural := Words_To_Compare * 4;
  94
  95       begin
  96          for J in 0 .. Words_To_Compare - 1 loop
  97             if LeftP (J) /= RightP (J) then
  98                return Compare_Array_U8_Unaligned
  99                         (AddA (Left,  Address (4 * J)),
 100                          AddA (Right, Address (4 * J)),
 101                          4, 4);
 102             end if;
 103          end loop;
 104
 105          return Compare_Array_U8_Unaligned
 106                   (AddA (Left,  Address (Bytes_Compared_As_Words)),
 107                    AddA (Right, Address (Bytes_Compared_As_Words)),
 108                    Left_Len  - Bytes_Compared_As_Words,
 109                    Right_Len - Bytes_Compared_As_Words);
 110       end;
 111    end Compare_Array_U8;
 112
 113    --------------------------------
 114    -- Compare_Array_U8_Unaligned --
 115    --------------------------------
 116
 117    function Compare_Array_U8_Unaligned
 118      (Left      : System.Address;
 119       Right     : System.Address;
 120       Left_Len  : Natural;
 121       Right_Len : Natural) return Integer
 122    is
 123       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 124
 125       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 126       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 127
 128    begin
 129       for J in 0 .. Compare_Len - 1 loop
 130          if LeftP (J) /= RightP (J) then
 131             if LeftP (J) > RightP (J) then
 132                return +1;
 133             else
 134                return -1;
 135             end if;
 136          end if;
 137       end loop;
 138
 139       if Left_Len = Right_Len then
 140          return 0;
 141       elsif Left_Len > Right_Len then
 142          return +1;
 143       else
 144          return -1;
 145       end if;
 146    end Compare_Array_U8_Unaligned;
 147
 148 end System.Compare_Array_Unsigned_8;