gcc/ada/s-carun8.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --       S Y S T E M . C O M P A R E _ A R R A Y _ U N S I G N E D _ 8      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2006 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Address_Operations; use System.Address_Operations;
  35
  36 with Unchecked_Conversion;
  37
  38 package body System.Compare_Array_Unsigned_8 is
  39
  40    type Word is mod 2 ** 32;
  41    --  Used to process operands by words
  42
  43    type Big_Words is array (Natural) of Word;
  44    type Big_Words_Ptr is access Big_Words;
  45    --  Array type used to access by words
  46
  47    type Byte is mod 2 ** 8;
  48    --  Used to process operands by bytes
  49
  50    type Big_Bytes is array (Natural) of Byte;
  51    type Big_Bytes_Ptr is access Big_Bytes;
  52    --  Array type used to access by bytes
  53
  54    function To_Big_Words is new
  55      Unchecked_Conversion (System.Address, Big_Words_Ptr);
  56
  57    function To_Big_Bytes is new
  58      Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  59
  60    ----------------------
  61    -- Compare_Array_U8 --
  62    ----------------------
  63
  64    function Compare_Array_U8
  65      (Left      : System.Address;
  66       Right     : System.Address;
  67       Left_Len  : Natural;
  68       Right_Len : Natural) return Integer
  69    is
  70       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  71
  72    begin
  73       --  If operands are non-aligned, or length is too short, go by bytes
  74
  75       if (ModA (OrA (Left, Right), 4) /= 0) or else Compare_Len < 4 then
  76          return Compare_Array_U8_Unaligned (Left, Right, Left_Len, Right_Len);
  77       end if;
  78
  79       --  Here we can go by words
  80
  81       declare
  82          LeftP                   : constant Big_Words_Ptr :=
  83                                      To_Big_Words (Left);
  84          RightP                  : constant Big_Words_Ptr :=
  85                                      To_Big_Words (Right);
  86          Words_To_Compare        : constant Natural := Compare_Len / 4;
  87          Bytes_Compared_As_Words : constant Natural := Words_To_Compare * 4;
  88
  89       begin
  90          for J in 0 .. Words_To_Compare - 1 loop
  91             if LeftP (J) /= RightP (J) then
  92                return Compare_Array_U8_Unaligned
  93                         (AddA (Left,  Address (4 * J)),
  94                          AddA (Right, Address (4 * J)),
  95                          4, 4);
  96             end if;
  97          end loop;
  98
  99          return Compare_Array_U8_Unaligned
 100                   (AddA (Left,  Address (Bytes_Compared_As_Words)),
 101                    AddA (Right, Address (Bytes_Compared_As_Words)),
 102                    Left_Len  - Bytes_Compared_As_Words,
 103                    Right_Len - Bytes_Compared_As_Words);
 104       end;
 105    end Compare_Array_U8;
 106
 107    --------------------------------
 108    -- Compare_Array_U8_Unaligned --
 109    --------------------------------
 110
 111    function Compare_Array_U8_Unaligned
 112      (Left      : System.Address;
 113       Right     : System.Address;
 114       Left_Len  : Natural;
 115       Right_Len : Natural) return Integer
 116    is
 117       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 118
 119       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 120       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 121
 122    begin
 123       for J in 0 .. Compare_Len - 1 loop
 124          if LeftP (J) /= RightP (J) then
 125             if LeftP (J) > RightP (J) then
 126                return +1;
 127             else
 128                return -1;
 129             end if;
 130          end if;
 131       end loop;
 132
 133       if Left_Len = Right_Len then
 134          return 0;
 135       elsif Left_Len > Right_Len then
 136          return +1;
 137       else
 138          return -1;
 139       end if;
 140    end Compare_Array_U8_Unaligned;
 141
 142 end System.Compare_Array_Unsigned_8;