gcc/ada/s-carsi8.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                   GNU ADA RUNTIME LIBRARY COMPONENTS                     --
   4 --                                                                          --
   5 --         S Y S T E M . C O M P A R E _ A R R A Y _ S I G N E D _ 8        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Unchecked_Conversion;
  35
  36 package body System.Compare_Array_Signed_8 is
  37
  38    function "+" (Left, Right : Address) return Address;
  39    pragma Import (Intrinsic, "+");
  40    --  Provide addition operation on type Address (this may not be directly
  41    --  available if type System.Address is non-private and the operations on
  42    --  the type are made abstract to hide them from public users of System.
  43
  44    type Word is mod 2 ** 32;
  45    --  Used to process operands by words
  46
  47    type Big_Words is array (Natural) of Word;
  48    type Big_Words_Ptr is access Big_Words;
  49    --  Array type used to access by words
  50
  51    type Byte is range -128 .. +127;
  52    for Byte'Size use 8;
  53    --  Used to process operands by bytes
  54
  55    type Big_Bytes is array (Natural) of Byte;
  56    type Big_Bytes_Ptr is access Big_Bytes;
  57    --  Array type used to access by bytes
  58
  59    function To_Big_Words is new
  60      Unchecked_Conversion (System.Address, Big_Words_Ptr);
  61
  62    function To_Big_Bytes is new
  63      Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  64
  65    ----------------------
  66    -- Compare_Array_S8 --
  67    ----------------------
  68
  69    function Compare_Array_S8
  70      (Left      : System.Address;
  71       Right     : System.Address;
  72       Left_Len  : Natural;
  73       Right_Len : Natural)
  74       return      Integer
  75    is
  76       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  77
  78    begin
  79       --  If operands are non-aligned, or length is too short, go by bytes
  80
  81       if (((Left or Right) and 2#11#) /= 0) or else Compare_Len < 4 then
  82          return Compare_Array_S8_Unaligned (Left, Right, Left_Len, Right_Len);
  83       end if;
  84
  85       --  Here we can go by words
  86
  87       declare
  88          LeftP  : constant Big_Words_Ptr := To_Big_Words (Left);
  89          RightP : constant Big_Words_Ptr := To_Big_Words (Right);
  90          Clen4  : constant Natural       := Compare_Len / 4 - 1;
  91          Clen4F : constant Natural       := Clen4 * 4;
  92
  93       begin
  94          for J in 0 .. Clen4 loop
  95             if LeftP (J) /= RightP (J) then
  96                return Compare_Array_S8_Unaligned
  97                         (Left  + Address (4 * J),
  98                          Right + Address (4 * J),
  99                          4, 4);
 100             end if;
 101          end loop;
 102
 103          return Compare_Array_S8_Unaligned
 104                   (Left      + Address (Clen4F),
 105                    Right     + Address (Clen4F),
 106                    Left_Len  - Clen4F,
 107                    Right_Len - Clen4F);
 108       end;
 109    end Compare_Array_S8;
 110
 111    --------------------------------
 112    -- Compare_Array_S8_Unaligned --
 113    --------------------------------
 114
 115    function Compare_Array_S8_Unaligned
 116      (Left      : System.Address;
 117       Right     : System.Address;
 118       Left_Len  : Natural;
 119       Right_Len : Natural)
 120       return      Integer
 121    is
 122       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 123
 124       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 125       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 126
 127    begin
 128       for J in 0 .. Compare_Len - 1 loop
 129          if LeftP (J) /= RightP (J) then
 130             if LeftP (J) > RightP (J) then
 131                return +1;
 132             else
 133                return -1;
 134             end if;
 135          end if;
 136       end loop;
 137
 138       if Left_Len = Right_Len then
 139          return 0;
 140       elsif Left_Len > Right_Len then
 141          return +1;
 142       else
 143          return -1;
 144       end if;
 145    end Compare_Array_S8_Unaligned;
 146
 147 end System.Compare_Array_Signed_8;