gcc/ada/prj.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  P R J                                   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Ada.Characters.Handling; use Ada.Characters.Handling;
  27 with Ada.Unchecked_Deallocation;
  28
  29 with Debug;
  30 with Osint;    use Osint;
  31 with Output;   use Output;
  32 with Prj.Attr;
  33 with Prj.Err;  use Prj.Err;
  34 with Snames;   use Snames;
  35 with Uintp;    use Uintp;
  36
  37 with GNAT.Directory_Operations; use GNAT.Directory_Operations;
  38
  39 with System.Case_Util; use System.Case_Util;
  40 with System.HTable;
  41
  42 package body Prj is
  43
  44    Object_Suffix : constant String := Get_Target_Object_Suffix.all;
  45    --  File suffix for object files
  46
  47    Initial_Buffer_Size : constant := 100;
  48    --  Initial size for extensible buffer used in Add_To_Buffer
  49
  50    The_Empty_String : Name_Id := No_Name;
  51
  52    subtype Known_Casing is Casing_Type range All_Upper_Case .. Mixed_Case;
  53
  54    type Cst_String_Access is access constant String;
  55
  56    All_Lower_Case_Image : aliased constant String := "lowercase";
  57    All_Upper_Case_Image : aliased constant String := "UPPERCASE";
  58    Mixed_Case_Image     : aliased constant String := "MixedCase";
  59
  60    The_Casing_Images : constant array (Known_Casing) of Cst_String_Access :=
  61                          (All_Lower_Case => All_Lower_Case_Image'Access,
  62                           All_Upper_Case => All_Upper_Case_Image'Access,
  63                           Mixed_Case     => Mixed_Case_Image'Access);
  64
  65    Project_Empty : constant Project_Data :=
  66                      (Qualifier                      => Unspecified,
  67                       Externally_Built               => False,
  68                       Config                         => Default_Project_Config,
  69                       Name                           => No_Name,
  70                       Display_Name                   => No_Name,
  71                       Path                           => No_Path_Information,
  72                       Virtual                        => False,
  73                       Location                       => No_Location,
  74                       Mains                          => Nil_String,
  75                       Directory                      => No_Path_Information,
  76                       Library                        => False,
  77                       Library_Dir                    => No_Path_Information,
  78                       Library_Src_Dir                => No_Path_Information,
  79                       Library_ALI_Dir                => No_Path_Information,
  80                       Library_Name                   => No_Name,
  81                       Library_Kind                   => Static,
  82                       Lib_Internal_Name              => No_Name,
  83                       Standalone_Library             => False,
  84                       Lib_Interface_ALIs             => Nil_String,
  85                       Lib_Auto_Init                  => False,
  86                       Libgnarl_Needed                => Unknown,
  87                       Symbol_Data                    => No_Symbols,
  88                       Interfaces_Defined             => False,
  89                       Include_Path                   => null,
  90                       Include_Data_Set               => False,
  91                       Source_Dirs                    => Nil_String,
  92                       Source_Dir_Ranks               => No_Number_List,
  93                       Object_Directory               => No_Path_Information,
  94                       Library_TS                     => Empty_Time_Stamp,
  95                       Exec_Directory                 => No_Path_Information,
  96                       Extends                        => No_Project,
  97                       Extended_By                    => No_Project,
  98                       Languages                      => No_Language_Index,
  99                       Decl                           => No_Declarations,
 100                       Imported_Projects              => null,
 101                       All_Imported_Projects          => null,
 102                       Ada_Include_Path               => null,
 103                       Imported_Directories_Switches  => null,
 104                       Ada_Objects_Path               => null,
 105                       Objects_Path                   => null,
 106                       Include_Path_File              => No_Path,
 107                       Objects_Path_File_With_Libs    => No_Path,
 108                       Objects_Path_File_Without_Libs => No_Path,
 109                       Config_File_Name               => No_Path,
 110                       Config_File_Temp               => False,
 111                       Config_Checked                 => False,
 112                       Need_To_Build_Lib              => False,
 113                       Depth                          => 0,
 114                       Unkept_Comments                => False);
 115
 116    procedure Free (Project : in out Project_Id);
 117    --  Free memory allocated for Project
 118
 119    procedure Free_List (Languages : in out Language_Ptr);
 120    procedure Free_List (Source : in out Source_Id);
 121    procedure Free_List (Languages : in out Language_List);
 122    --  Free memory allocated for the list of languages or sources
 123
 124    procedure Free_Units (Table : in out Units_Htable.Instance);
 125    --  Free memory allocated for unit information in the project
 126
 127    procedure Language_Changed (Iter : in out Source_Iterator);
 128    procedure Project_Changed (Iter : in out Source_Iterator);
 129    --  Called when a new project or language was selected for this iterator
 130
 131    function Contains_ALI_Files (Dir : Path_Name_Type) return Boolean;
 132    --  Return True if there is at least one ALI file in the directory Dir
 133
 134    -------------------
 135    -- Add_To_Buffer --
 136    -------------------
 137
 138    procedure Add_To_Buffer
 139      (S    : String;
 140       To   : in out String_Access;
 141       Last : in out Natural)
 142    is
 143    begin
 144       if To = null then
 145          To := new String (1 .. Initial_Buffer_Size);
 146          Last := 0;
 147       end if;
 148
 149       --  If Buffer is too small, double its size
 150
 151       while Last + S'Length > To'Last loop
 152          declare
 153             New_Buffer : constant  String_Access :=
 154                            new String (1 .. 2 * Last);
 155
 156          begin
 157             New_Buffer (1 .. Last) := To (1 .. Last);
 158             Free (To);
 159             To := New_Buffer;
 160          end;
 161       end loop;
 162
 163       To (Last + 1 .. Last + S'Length) := S;
 164       Last := Last + S'Length;
 165    end Add_To_Buffer;
 166
 167    ---------------------------
 168    -- Delete_Temporary_File --
 169    ---------------------------
 170
 171    procedure Delete_Temporary_File
 172      (Tree : Project_Tree_Ref;
 173       Path : Path_Name_Type)
 174    is
 175       Dont_Care : Boolean;
 176       pragma Warnings (Off, Dont_Care);
 177
 178    begin
 179       if not Debug.Debug_Flag_N then
 180          if Current_Verbosity = High then
 181             Write_Line ("Removing temp file: " & Get_Name_String (Path));
 182          end if;
 183
 184          Delete_File (Get_Name_String (Path), Dont_Care);
 185
 186          for Index in
 187            1 .. Temp_Files_Table.Last (Tree.Private_Part.Temp_Files)
 188          loop
 189             if Tree.Private_Part.Temp_Files.Table (Index) = Path then
 190                Tree.Private_Part.Temp_Files.Table (Index) := No_Path;
 191             end if;
 192          end loop;
 193       end if;
 194    end Delete_Temporary_File;
 195
 196    ---------------------------
 197    -- Delete_All_Temp_Files --
 198    ---------------------------
 199
 200    procedure Delete_All_Temp_Files (Tree : Project_Tree_Ref) is
 201       Dont_Care : Boolean;
 202       pragma Warnings (Off, Dont_Care);
 203
 204       Path : Path_Name_Type;
 205
 206    begin
 207       if not Debug.Debug_Flag_N then
 208          for Index in
 209            1 .. Temp_Files_Table.Last (Tree.Private_Part.Temp_Files)
 210          loop
 211             Path := Tree.Private_Part.Temp_Files.Table (Index);
 212
 213             if Path /= No_Path then
 214                if Current_Verbosity = High then
 215                   Write_Line ("Removing temp file: "
 216                               & Get_Name_String (Path));
 217                end if;
 218
 219                Delete_File (Get_Name_String (Path), Dont_Care);
 220             end if;
 221          end loop;
 222
 223          Temp_Files_Table.Free (Tree.Private_Part.Temp_Files);
 224          Temp_Files_Table.Init (Tree.Private_Part.Temp_Files);
 225       end if;
 226
 227       --  If any of the environment variables ADA_PRJ_INCLUDE_FILE or
 228       --  ADA_PRJ_OBJECTS_FILE has been set, then reset their value to
 229       --  the empty string. On VMS, this has the effect of deassigning
 230       --  the logical names.
 231
 232       if Tree.Private_Part.Current_Source_Path_File /= No_Path then
 233          Setenv (Project_Include_Path_File, "");
 234       end if;
 235
 236       if Tree.Private_Part.Current_Object_Path_File /= No_Path then
 237          Setenv (Project_Objects_Path_File, "");
 238       end if;
 239    end Delete_All_Temp_Files;
 240
 241    ---------------------
 242    -- Dependency_Name --
 243    ---------------------
 244
 245    function Dependency_Name
 246      (Source_File_Name : File_Name_Type;
 247       Dependency       : Dependency_File_Kind) return File_Name_Type
 248    is
 249    begin
 250       case Dependency is
 251          when None =>
 252             return No_File;
 253
 254          when Makefile =>
 255             return
 256               File_Name_Type
 257                 (Extend_Name
 258                    (Source_File_Name, Makefile_Dependency_Suffix));
 259
 260          when ALI_File =>
 261             return
 262               File_Name_Type
 263                 (Extend_Name
 264                    (Source_File_Name, ALI_Dependency_Suffix));
 265       end case;
 266    end Dependency_Name;
 267
 268    ----------------
 269    -- Empty_File --
 270    ----------------
 271
 272    function Empty_File return File_Name_Type is
 273    begin
 274       return File_Name_Type (The_Empty_String);
 275    end Empty_File;
 276
 277    -------------------
 278    -- Empty_Project --
 279    -------------------
 280
 281    function Empty_Project return Project_Data is
 282    begin
 283       Prj.Initialize (Tree => No_Project_Tree);
 284       return Project_Empty;
 285    end Empty_Project;
 286
 287    ------------------
 288    -- Empty_String --
 289    ------------------
 290
 291    function Empty_String return Name_Id is
 292    begin
 293       return The_Empty_String;
 294    end Empty_String;
 295
 296    ------------
 297    -- Expect --
 298    ------------
 299
 300    procedure Expect (The_Token : Token_Type; Token_Image : String) is
 301    begin
 302       if Token /= The_Token then
 303          --  ??? Should pass user flags here instead
 304          Error_Msg (Gnatmake_Flags, Token_Image & " expected", Token_Ptr);
 305       end if;
 306    end Expect;
 307
 308    -----------------
 309    -- Extend_Name --
 310    -----------------
 311
 312    function Extend_Name
 313      (File        : File_Name_Type;
 314       With_Suffix : String) return File_Name_Type
 315    is
 316       Last : Positive;
 317
 318    begin
 319       Get_Name_String (File);
 320       Last := Name_Len + 1;
 321
 322       while Name_Len /= 0 and then Name_Buffer (Name_Len) /= '.' loop
 323          Name_Len := Name_Len - 1;
 324       end loop;
 325
 326       if Name_Len <= 1 then
 327          Name_Len := Last;
 328       end if;
 329
 330       for J in With_Suffix'Range loop
 331          Name_Buffer (Name_Len) := With_Suffix (J);
 332          Name_Len := Name_Len + 1;
 333       end loop;
 334
 335       Name_Len := Name_Len - 1;
 336       return Name_Find;
 337
 338    end Extend_Name;
 339
 340    ---------------------
 341    -- Project_Changed --
 342    ---------------------
 343
 344    procedure Project_Changed (Iter : in out Source_Iterator) is
 345    begin
 346       Iter.Language := Iter.Project.Project.Languages;
 347       Language_Changed (Iter);
 348    end Project_Changed;
 349
 350    ----------------------
 351    -- Language_Changed --
 352    ----------------------
 353
 354    procedure Language_Changed (Iter : in out Source_Iterator) is
 355    begin
 356       Iter.Current  := No_Source;
 357
 358       if Iter.Language_Name /= No_Name then
 359          while Iter.Language /= null
 360            and then Iter.Language.Name /= Iter.Language_Name
 361          loop
 362             Iter.Language := Iter.Language.Next;
 363          end loop;
 364       end if;
 365
 366       --  If there is no matching language in this project, move to next
 367
 368       if Iter.Language = No_Language_Index then
 369          if Iter.All_Projects then
 370             Iter.Project := Iter.Project.Next;
 371
 372             if Iter.Project /= null then
 373                Project_Changed (Iter);
 374             end if;
 375
 376          else
 377             Iter.Project := null;
 378          end if;
 379
 380       else
 381          Iter.Current := Iter.Language.First_Source;
 382
 383          if Iter.Current = No_Source then
 384             Iter.Language := Iter.Language.Next;
 385             Language_Changed (Iter);
 386          end if;
 387       end if;
 388    end Language_Changed;
 389
 390    ---------------------
 391    -- For_Each_Source --
 392    ---------------------
 393
 394    function For_Each_Source
 395      (In_Tree  : Project_Tree_Ref;
 396       Project  : Project_Id := No_Project;
 397       Language : Name_Id := No_Name) return Source_Iterator
 398    is
 399       Iter : Source_Iterator;
 400    begin
 401       Iter := Source_Iterator'
 402         (In_Tree       => In_Tree,
 403          Project       => In_Tree.Projects,
 404          All_Projects  => Project = No_Project,
 405          Language_Name => Language,
 406          Language      => No_Language_Index,
 407          Current       => No_Source);
 408
 409       if Project /= null then
 410          while Iter.Project /= null
 411            and then Iter.Project.Project /= Project
 412          loop
 413             Iter.Project := Iter.Project.Next;
 414          end loop;
 415       end if;
 416
 417       Project_Changed (Iter);
 418
 419       return Iter;
 420    end For_Each_Source;
 421
 422    -------------
 423    -- Element --
 424    -------------
 425
 426    function Element (Iter : Source_Iterator) return Source_Id is
 427    begin
 428       return Iter.Current;
 429    end Element;
 430
 431    ----------
 432    -- Next --
 433    ----------
 434
 435    procedure Next (Iter : in out Source_Iterator) is
 436    begin
 437       Iter.Current := Iter.Current.Next_In_Lang;
 438       if Iter.Current = No_Source then
 439          Iter.Language := Iter.Language.Next;
 440          Language_Changed (Iter);
 441       end if;
 442    end Next;
 443
 444    --------------------------------
 445    -- For_Every_Project_Imported --
 446    --------------------------------
 447
 448    procedure For_Every_Project_Imported
 449      (By             : Project_Id;
 450       With_State     : in out State;
 451       Imported_First : Boolean := False)
 452    is
 453       use Project_Boolean_Htable;
 454       Seen : Project_Boolean_Htable.Instance := Project_Boolean_Htable.Nil;
 455
 456       procedure Recursive_Check (Project : Project_Id);
 457       --  Check if a project has already been seen. If not seen, mark it as
 458       --  Seen, Call Action, and check all its imported projects.
 459
 460       ---------------------
 461       -- Recursive_Check --
 462       ---------------------
 463
 464       procedure Recursive_Check (Project : Project_Id) is
 465          List : Project_List;
 466
 467       begin
 468          if not Get (Seen, Project) then
 469             Set (Seen, Project, True);
 470
 471             if not Imported_First then
 472                Action (Project, With_State);
 473             end if;
 474
 475             --  Visited all extended projects
 476
 477             if Project.Extends /= No_Project then
 478                Recursive_Check (Project.Extends);
 479             end if;
 480
 481             --  Visited all imported projects
 482
 483             List := Project.Imported_Projects;
 484             while List /= null loop
 485                Recursive_Check (List.Project);
 486                List := List.Next;
 487             end loop;
 488
 489             if Imported_First then
 490                Action (Project, With_State);
 491             end if;
 492          end if;
 493       end Recursive_Check;
 494
 495    --  Start of processing for For_Every_Project_Imported
 496
 497    begin
 498       Recursive_Check (Project => By);
 499       Reset (Seen);
 500    end For_Every_Project_Imported;
 501
 502    -----------------
 503    -- Find_Source --
 504    -----------------
 505
 506    function Find_Source
 507      (In_Tree          : Project_Tree_Ref;
 508       Project          : Project_Id;
 509       In_Imported_Only : Boolean := False;
 510       In_Extended_Only : Boolean := False;
 511       Base_Name        : File_Name_Type) return Source_Id
 512    is
 513       Result : Source_Id  := No_Source;
 514
 515       procedure Look_For_Sources (Proj : Project_Id; Src : in out Source_Id);
 516       --  Look for Base_Name in the sources of Proj
 517
 518       ----------------------
 519       -- Look_For_Sources --
 520       ----------------------
 521
 522       procedure Look_For_Sources (Proj : Project_Id; Src : in out Source_Id) is
 523          Iterator : Source_Iterator;
 524
 525       begin
 526          Iterator := For_Each_Source (In_Tree => In_Tree, Project => Proj);
 527          while Element (Iterator) /= No_Source loop
 528             if Element (Iterator).File = Base_Name then
 529                Src := Element (Iterator);
 530                return;
 531             end if;
 532
 533             Next (Iterator);
 534          end loop;
 535       end Look_For_Sources;
 536
 537       procedure For_Imported_Projects is new For_Every_Project_Imported
 538         (State => Source_Id, Action => Look_For_Sources);
 539
 540       Proj : Project_Id;
 541
 542    --  Start of processing for Find_Source
 543
 544    begin
 545       if In_Extended_Only then
 546          Proj := Project;
 547          while Proj /= No_Project loop
 548             Look_For_Sources (Proj, Result);
 549             exit when Result /= No_Source;
 550
 551             Proj := Proj.Extends;
 552          end loop;
 553
 554       elsif In_Imported_Only then
 555          Look_For_Sources (Project, Result);
 556
 557          if Result = No_Source then
 558             For_Imported_Projects
 559               (By         => Project,
 560                With_State => Result);
 561          end if;
 562       else
 563          Look_For_Sources (No_Project, Result);
 564       end if;
 565
 566       return Result;
 567    end Find_Source;
 568
 569    ----------
 570    -- Hash --
 571    ----------
 572
 573    function Hash is new System.HTable.Hash (Header_Num => Header_Num);
 574    --  Used in implementation of other functions Hash below
 575
 576    function Hash (Name : File_Name_Type) return Header_Num is
 577    begin
 578       return Hash (Get_Name_String (Name));
 579    end Hash;
 580
 581    function Hash (Name : Name_Id) return Header_Num is
 582    begin
 583       return Hash (Get_Name_String (Name));
 584    end Hash;
 585
 586    function Hash (Name : Path_Name_Type) return Header_Num is
 587    begin
 588       return Hash (Get_Name_String (Name));
 589    end Hash;
 590
 591    function Hash (Project : Project_Id) return Header_Num is
 592    begin
 593       if Project = No_Project then
 594          return Header_Num'First;
 595       else
 596          return Hash (Get_Name_String (Project.Name));
 597       end if;
 598    end Hash;
 599
 600    -----------
 601    -- Image --
 602    -----------
 603
 604    function Image (The_Casing : Casing_Type) return String is
 605    begin
 606       return The_Casing_Images (The_Casing).all;
 607    end Image;
 608
 609    -----------------------------
 610    -- Is_Standard_GNAT_Naming --
 611    -----------------------------
 612
 613    function Is_Standard_GNAT_Naming
 614      (Naming : Lang_Naming_Data) return Boolean
 615    is
 616    begin
 617       return Get_Name_String (Naming.Spec_Suffix) = ".ads"
 618         and then Get_Name_String (Naming.Body_Suffix) = ".adb"
 619         and then Get_Name_String (Naming.Dot_Replacement) = "-";
 620    end Is_Standard_GNAT_Naming;
 621
 622    ----------------
 623    -- Initialize --
 624    ----------------
 625
 626    procedure Initialize (Tree : Project_Tree_Ref) is
 627    begin
 628       if The_Empty_String = No_Name then
 629          Uintp.Initialize;
 630          Name_Len := 0;
 631          The_Empty_String := Name_Find;
 632
 633          Prj.Attr.Initialize;
 634          Set_Name_Table_Byte (Name_Project,  Token_Type'Pos (Tok_Project));
 635          Set_Name_Table_Byte (Name_Extends,  Token_Type'Pos (Tok_Extends));
 636          Set_Name_Table_Byte (Name_External, Token_Type'Pos (Tok_External));
 637       end if;
 638
 639       if Tree /= No_Project_Tree then
 640          Reset (Tree);
 641       end if;
 642    end Initialize;
 643
 644    ------------------
 645    -- Is_Extending --
 646    ------------------
 647
 648    function Is_Extending
 649      (Extending : Project_Id;
 650       Extended  : Project_Id) return Boolean
 651    is
 652       Proj : Project_Id;
 653
 654    begin
 655       Proj := Extending;
 656       while Proj /= No_Project loop
 657          if Proj = Extended then
 658             return True;
 659          end if;
 660
 661          Proj := Proj.Extends;
 662       end loop;
 663
 664       return False;
 665    end Is_Extending;
 666
 667    -----------------
 668    -- Object_Name --
 669    -----------------
 670
 671    function Object_Name
 672      (Source_File_Name   : File_Name_Type;
 673       Object_File_Suffix : Name_Id := No_Name) return File_Name_Type
 674    is
 675    begin
 676       if Object_File_Suffix = No_Name then
 677          return Extend_Name
 678            (Source_File_Name, Object_Suffix);
 679       else
 680          return Extend_Name
 681            (Source_File_Name, Get_Name_String (Object_File_Suffix));
 682       end if;
 683    end Object_Name;
 684
 685    ----------------------
 686    -- Record_Temp_File --
 687    ----------------------
 688
 689    procedure Record_Temp_File
 690      (Tree : Project_Tree_Ref;
 691       Path : Path_Name_Type)
 692    is
 693    begin
 694       Temp_Files_Table.Append (Tree.Private_Part.Temp_Files, Path);
 695    end Record_Temp_File;
 696
 697    ----------
 698    -- Free --
 699    ----------
 700
 701    procedure Free (Project : in out Project_Id) is
 702       procedure Unchecked_Free is new Ada.Unchecked_Deallocation
 703         (Project_Data, Project_Id);
 704
 705    begin
 706       if Project /= null then
 707          Free (Project.Include_Path);
 708          Free (Project.Ada_Include_Path);
 709          Free (Project.Objects_Path);
 710          Free (Project.Ada_Objects_Path);
 711          Free_List (Project.Imported_Projects, Free_Project => False);
 712          Free_List (Project.All_Imported_Projects, Free_Project => False);
 713          Free_List (Project.Languages);
 714
 715          Unchecked_Free (Project);
 716       end if;
 717    end Free;
 718
 719    ---------------
 720    -- Free_List --
 721    ---------------
 722
 723    procedure Free_List (Languages : in out Language_List) is
 724       procedure Unchecked_Free is new Ada.Unchecked_Deallocation
 725         (Language_List_Element, Language_List);
 726       Tmp : Language_List;
 727    begin
 728       while Languages /= null loop
 729          Tmp := Languages.Next;
 730          Unchecked_Free (Languages);
 731          Languages := Tmp;
 732       end loop;
 733    end Free_List;
 734
 735    ---------------
 736    -- Free_List --
 737    ---------------
 738
 739    procedure Free_List (Source : in out Source_Id) is
 740       procedure Unchecked_Free is new
 741         Ada.Unchecked_Deallocation (Source_Data, Source_Id);
 742
 743       Tmp : Source_Id;
 744
 745    begin
 746       while Source /= No_Source loop
 747          Tmp := Source.Next_In_Lang;
 748          Free_List (Source.Alternate_Languages);
 749
 750          if Source.Unit /= null
 751            and then Source.Kind in Spec_Or_Body
 752          then
 753             Source.Unit.File_Names (Source.Kind) := null;
 754          end if;
 755
 756          Unchecked_Free (Source);
 757          Source := Tmp;
 758       end loop;
 759    end Free_List;
 760
 761    ---------------
 762    -- Free_List --
 763    ---------------
 764
 765    procedure Free_List
 766      (List         : in out Project_List;
 767       Free_Project : Boolean)
 768    is
 769       procedure Unchecked_Free is new
 770         Ada.Unchecked_Deallocation (Project_List_Element, Project_List);
 771
 772       Tmp : Project_List;
 773
 774    begin
 775       while List /= null loop
 776          Tmp := List.Next;
 777
 778          if Free_Project then
 779             Free (List.Project);
 780          end if;
 781
 782          Unchecked_Free (List);
 783          List := Tmp;
 784       end loop;
 785    end Free_List;
 786
 787    ---------------
 788    -- Free_List --
 789    ---------------
 790
 791    procedure Free_List (Languages : in out Language_Ptr) is
 792       procedure Unchecked_Free is new
 793         Ada.Unchecked_Deallocation (Language_Data, Language_Ptr);
 794
 795       Tmp : Language_Ptr;
 796
 797    begin
 798       while Languages /= null loop
 799          Tmp := Languages.Next;
 800          Free_List (Languages.First_Source);
 801          Unchecked_Free (Languages);
 802          Languages := Tmp;
 803       end loop;
 804    end Free_List;
 805
 806    ----------------
 807    -- Free_Units --
 808    ----------------
 809
 810    procedure Free_Units (Table : in out Units_Htable.Instance) is
 811       procedure Unchecked_Free is new
 812         Ada.Unchecked_Deallocation (Unit_Data, Unit_Index);
 813
 814       Unit : Unit_Index;
 815
 816    begin
 817       Unit := Units_Htable.Get_First (Table);
 818       while Unit /= No_Unit_Index loop
 819          if Unit.File_Names (Spec) /= null then
 820             Unit.File_Names (Spec).Unit := No_Unit_Index;
 821          end if;
 822
 823          if Unit.File_Names (Impl) /= null then
 824             Unit.File_Names (Impl).Unit := No_Unit_Index;
 825          end if;
 826
 827          Unchecked_Free (Unit);
 828          Unit := Units_Htable.Get_Next (Table);
 829       end loop;
 830
 831       Units_Htable.Reset (Table);
 832    end Free_Units;
 833
 834    ----------
 835    -- Free --
 836    ----------
 837
 838    procedure Free (Tree : in out Project_Tree_Ref) is
 839       procedure Unchecked_Free is new
 840         Ada.Unchecked_Deallocation (Project_Tree_Data, Project_Tree_Ref);
 841
 842    begin
 843       if Tree /= null then
 844          Name_List_Table.Free (Tree.Name_Lists);
 845          Number_List_Table.Free (Tree.Number_Lists);
 846          String_Element_Table.Free (Tree.String_Elements);
 847          Variable_Element_Table.Free (Tree.Variable_Elements);
 848          Array_Element_Table.Free (Tree.Array_Elements);
 849          Array_Table.Free (Tree.Arrays);
 850          Package_Table.Free (Tree.Packages);
 851          Source_Paths_Htable.Reset (Tree.Source_Paths_HT);
 852
 853          Free_List (Tree.Projects, Free_Project => True);
 854          Free_Units (Tree.Units_HT);
 855
 856          --  Private part
 857
 858          Temp_Files_Table.Free  (Tree.Private_Part.Temp_Files);
 859
 860          Unchecked_Free (Tree);
 861       end if;
 862    end Free;
 863
 864    -----------
 865    -- Reset --
 866    -----------
 867
 868    procedure Reset (Tree : Project_Tree_Ref) is
 869    begin
 870       --  Visible tables
 871
 872       Name_List_Table.Init          (Tree.Name_Lists);
 873       Number_List_Table.Init        (Tree.Number_Lists);
 874       String_Element_Table.Init     (Tree.String_Elements);
 875       Variable_Element_Table.Init   (Tree.Variable_Elements);
 876       Array_Element_Table.Init      (Tree.Array_Elements);
 877       Array_Table.Init              (Tree.Arrays);
 878       Package_Table.Init            (Tree.Packages);
 879       Source_Paths_Htable.Reset     (Tree.Source_Paths_HT);
 880
 881       Free_List (Tree.Projects, Free_Project => True);
 882       Free_Units (Tree.Units_HT);
 883
 884       --  Private part table
 885
 886       Temp_Files_Table.Init       (Tree.Private_Part.Temp_Files);
 887
 888       Tree.Private_Part.Current_Source_Path_File := No_Path;
 889       Tree.Private_Part.Current_Object_Path_File := No_Path;
 890    end Reset;
 891
 892    -------------------
 893    -- Switches_Name --
 894    -------------------
 895
 896    function Switches_Name
 897      (Source_File_Name : File_Name_Type) return File_Name_Type
 898    is
 899    begin
 900       return Extend_Name (Source_File_Name, Switches_Dependency_Suffix);
 901    end Switches_Name;
 902
 903    -----------
 904    -- Value --
 905    -----------
 906
 907    function Value (Image : String) return Casing_Type is
 908    begin
 909       for Casing in The_Casing_Images'Range loop
 910          if To_Lower (Image) = To_Lower (The_Casing_Images (Casing).all) then
 911             return Casing;
 912          end if;
 913       end loop;
 914
 915       raise Constraint_Error;
 916    end Value;
 917
 918    ---------------------
 919    -- Has_Ada_Sources --
 920    ---------------------
 921
 922    function Has_Ada_Sources (Data : Project_Id) return Boolean is
 923       Lang : Language_Ptr;
 924
 925    begin
 926       Lang := Data.Languages;
 927       while Lang /= No_Language_Index loop
 928          if Lang.Name = Name_Ada then
 929             return Lang.First_Source /= No_Source;
 930          end if;
 931          Lang := Lang.Next;
 932       end loop;
 933
 934       return False;
 935    end Has_Ada_Sources;
 936
 937    ------------------------
 938    -- Contains_ALI_Files --
 939    ------------------------
 940
 941    function Contains_ALI_Files (Dir : Path_Name_Type) return Boolean is
 942       Dir_Name : constant String := Get_Name_String (Dir);
 943       Direct   : Dir_Type;
 944       Name     : String (1 .. 1_000);
 945       Last     : Natural;
 946       Result   : Boolean := False;
 947
 948    begin
 949       Open (Direct, Dir_Name);
 950
 951       --  For each file in the directory, check if it is an ALI file
 952
 953       loop
 954          Read (Direct, Name, Last);
 955          exit when Last = 0;
 956          Canonical_Case_File_Name (Name (1 .. Last));
 957          Result := Last >= 5 and then Name (Last - 3 .. Last) = ".ali";
 958          exit when Result;
 959       end loop;
 960
 961       Close (Direct);
 962       return Result;
 963
 964    exception
 965       --  If there is any problem, close the directory if open and return True.
 966       --  The library directory will be added to the path.
 967
 968       when others =>
 969          if Is_Open (Direct) then
 970             Close (Direct);
 971          end if;
 972
 973          return True;
 974    end Contains_ALI_Files;
 975
 976    --------------------------
 977    -- Get_Object_Directory --
 978    --------------------------
 979
 980    function Get_Object_Directory
 981      (Project             : Project_Id;
 982       Including_Libraries : Boolean;
 983       Only_If_Ada         : Boolean := False) return Path_Name_Type
 984    is
 985    begin
 986       if (Project.Library and then Including_Libraries)
 987         or else
 988           (Project.Object_Directory /= No_Path_Information
 989             and then (not Including_Libraries or else not Project.Library))
 990       then
 991          --  For a library project, add the library ALI directory if there is
 992          --  no object directory or if the library ALI directory contains ALI
 993          --  files; otherwise add the object directory.
 994
 995          if Project.Library then
 996             if Project.Object_Directory = No_Path_Information
 997               or else Contains_ALI_Files (Project.Library_ALI_Dir.Name)
 998             then
 999                return Project.Library_ALI_Dir.Name;
1000             else
1001                return Project.Object_Directory.Name;
1002             end if;
1003
1004             --  For a non-library project, add object directory if it is not a
1005             --  virtual project, and if there are Ada sources in the project or
1006             --  one of the projects it extends. If there are no Ada sources,
1007             --  adding the object directory could disrupt the order of the
1008             --  object dirs in the path.
1009
1010          elsif not Project.Virtual then
1011             declare
1012                Add_Object_Dir : Boolean;
1013                Prj            : Project_Id;
1014
1015             begin
1016                Add_Object_Dir := not Only_If_Ada;
1017                Prj := Project;
1018                while not Add_Object_Dir and then Prj /= No_Project loop
1019                   if Has_Ada_Sources (Prj) then
1020                      Add_Object_Dir := True;
1021                   else
1022                      Prj := Prj.Extends;
1023                   end if;
1024                end loop;
1025
1026                if Add_Object_Dir then
1027                   return Project.Object_Directory.Name;
1028                end if;
1029             end;
1030          end if;
1031       end if;
1032
1033       return No_Path;
1034    end Get_Object_Directory;
1035
1036    -----------------------------------
1037    -- Ultimate_Extending_Project_Of --
1038    -----------------------------------
1039
1040    function Ultimate_Extending_Project_Of
1041      (Proj : Project_Id) return Project_Id
1042    is
1043       Prj : Project_Id;
1044
1045    begin
1046       Prj := Proj;
1047       while Prj /= null and then Prj.Extended_By /= No_Project loop
1048          Prj := Prj.Extended_By;
1049       end loop;
1050
1051       return Prj;
1052    end Ultimate_Extending_Project_Of;
1053
1054    -----------------------------------
1055    -- Compute_All_Imported_Projects --
1056    -----------------------------------
1057
1058    procedure Compute_All_Imported_Projects (Project : Project_Id) is
1059
1060       procedure Recursive_Add (Prj : Project_Id; Dummy : in out Boolean);
1061       --  Recursively add the projects imported by project Project, but not
1062       --  those that are extended.
1063
1064       -------------------
1065       -- Recursive_Add --
1066       -------------------
1067
1068       procedure Recursive_Add (Prj : Project_Id; Dummy : in out Boolean) is
1069          pragma Unreferenced (Dummy);
1070          List    : Project_List;
1071          Prj2    : Project_Id;
1072
1073       begin
1074          --  A project is not importing itself
1075
1076          Prj2 := Ultimate_Extending_Project_Of (Prj);
1077
1078          if Project /= Prj2 then
1079
1080             --  Check that the project is not already in the list. We know the
1081             --  one passed to Recursive_Add have never been visited before, but
1082             --  the one passed it are the extended projects.
1083
1084             List := Project.All_Imported_Projects;
1085             while List /= null loop
1086                if List.Project = Prj2 then
1087                   return;
1088                end if;
1089
1090                List := List.Next;
1091             end loop;
1092
1093             --  Add it to the list
1094
1095             Project.All_Imported_Projects :=
1096               new Project_List_Element'
1097                 (Project => Prj2,
1098                  Next    => Project.All_Imported_Projects);
1099          end if;
1100       end Recursive_Add;
1101
1102       procedure For_All_Projects is
1103         new For_Every_Project_Imported (Boolean, Recursive_Add);
1104
1105       Dummy : Boolean := False;
1106
1107    begin
1108       Free_List (Project.All_Imported_Projects, Free_Project => False);
1109       For_All_Projects (Project, Dummy);
1110    end Compute_All_Imported_Projects;
1111
1112    -------------------
1113    -- Is_Compilable --
1114    -------------------
1115
1116    function Is_Compilable (Source : Source_Id) return Boolean is
1117    begin
1118       return Source.Language.Config.Compiler_Driver /= No_File
1119         and then Length_Of_Name (Source.Language.Config.Compiler_Driver) /= 0
1120         and then not Source.Locally_Removed;
1121    end Is_Compilable;
1122
1123    ------------------------------
1124    -- Object_To_Global_Archive --
1125    ------------------------------
1126
1127    function Object_To_Global_Archive (Source : Source_Id) return Boolean is
1128    begin
1129       return Source.Language.Config.Kind = File_Based
1130         and then Source.Kind = Impl
1131         and then Source.Language.Config.Objects_Linked
1132         and then Is_Compilable (Source)
1133         and then Source.Language.Config.Object_Generated;
1134    end Object_To_Global_Archive;
1135
1136    ----------------------------
1137    -- Get_Language_From_Name --
1138    ----------------------------
1139
1140    function Get_Language_From_Name
1141      (Project : Project_Id;
1142       Name    : String) return Language_Ptr
1143    is
1144       N      : Name_Id;
1145       Result : Language_Ptr;
1146
1147    begin
1148       Name_Len := Name'Length;
1149       Name_Buffer (1 .. Name_Len) := Name;
1150       To_Lower (Name_Buffer (1 .. Name_Len));
1151       N := Name_Find;
1152
1153       Result := Project.Languages;
1154       while Result /= No_Language_Index loop
1155          if Result.Name = N then
1156             return Result;
1157          end if;
1158
1159          Result := Result.Next;
1160       end loop;
1161
1162       return No_Language_Index;
1163    end Get_Language_From_Name;
1164
1165    ----------------
1166    -- Other_Part --
1167    ----------------
1168
1169    function Other_Part (Source : Source_Id) return Source_Id is
1170    begin
1171       if Source.Unit /= No_Unit_Index then
1172          case Source.Kind is
1173             when Impl =>
1174                return Source.Unit.File_Names (Spec);
1175             when Spec =>
1176                return Source.Unit.File_Names (Impl);
1177             when Sep =>
1178                return No_Source;
1179          end case;
1180       else
1181          return No_Source;
1182       end if;
1183    end Other_Part;
1184
1185    ------------------
1186    -- Create_Flags --
1187    ------------------
1188
1189    function Create_Flags
1190      (Report_Error               : Error_Handler;
1191       When_No_Sources            : Error_Warning;
1192       Require_Sources_Other_Lang : Boolean := True;
1193       Allow_Duplicate_Basenames  : Boolean := True;
1194       Compiler_Driver_Mandatory  : Boolean := False;
1195       Error_On_Unknown_Language  : Boolean := True;
1196       Require_Obj_Dirs           : Error_Warning := Error)
1197       return Processing_Flags
1198    is
1199    begin
1200       return Processing_Flags'
1201         (Report_Error               => Report_Error,
1202          When_No_Sources            => When_No_Sources,
1203          Require_Sources_Other_Lang => Require_Sources_Other_Lang,
1204          Allow_Duplicate_Basenames  => Allow_Duplicate_Basenames,
1205          Error_On_Unknown_Language  => Error_On_Unknown_Language,
1206          Compiler_Driver_Mandatory  => Compiler_Driver_Mandatory,
1207          Require_Obj_Dirs           => Require_Obj_Dirs);
1208    end Create_Flags;
1209
1210 begin
1211    --  Make sure that the standard config and user project file extensions are
1212    --  compatible with canonical case file naming.
1213
1214    Canonical_Case_File_Name (Config_Project_File_Extension);
1215    Canonical_Case_File_Name (Project_File_Extension);
1216 end Prj;