gcc/ada/prj-ext.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              P R J . E X T                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2000-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  Subprograms to set, get and cache external references, to be used as
  27 --  External functions in project files.
  28
  29 with GNAT.Dynamic_HTables;
  30
  31 package Prj.Ext is
  32
  33    -------------------------
  34    -- External References --
  35    -------------------------
  36
  37    --  External references influence the way a project tree is processed (in
  38    --  particular they provide the values for the typed string variables that
  39    --  are then used in case constructions).
  40
  41    --  External references are project-tree specific, so that when multiple
  42    --  trees are loaded in parallel we can have different scenarios (or even
  43    --  load the same tree twice and see different views of it).
  44
  45    type External_References is private;
  46    No_External_Refs : constant External_References;
  47
  48    procedure Initialize
  49      (Self      : out External_References;
  50       Copy_From : External_References := No_External_Refs);
  51    --  Initialize Self, and copy all values from Copy_From if needed.
  52    --  This has no effect if Self was already initialized.
  53
  54    procedure Free (Self : in out External_References);
  55    --  Free memory used by Self
  56
  57    procedure Add
  58      (Self          : External_References;
  59       External_Name : String;
  60       Value         : String);
  61    --  Add an external reference (or modify an existing one)
  62
  63    function Value_Of
  64      (Self          : External_References;
  65       External_Name : Name_Id;
  66       With_Default  : Name_Id := No_Name)
  67       return          Name_Id;
  68    --  Get the value of an external reference, and cache it for future uses
  69
  70    function Check
  71      (Self        : External_References;
  72       Declaration : String) return Boolean;
  73    --  Check that an external declaration <external>=<value> is correct.
  74    --  If it is correct, the external reference is Added.
  75
  76    procedure Reset (Self : External_References);
  77    --  Clear the internal data structure that stores the external references
  78    --  and free any allocated memory.
  79
  80 private
  81
  82    --  Use a Static_HTable, not a Simple_HTable.
  83    --  The issue is that we need to be able to copy the contents of the table
  84    --  (in Initialize), but this isn't doable for Simple_HTable for which
  85    --  iterators do not return the key.
  86
  87    type Name_To_Name;
  88    type Name_To_Name_Ptr is access all Name_To_Name;
  89    type Name_To_Name is record
  90       Key   : Name_Id;
  91       Value : Name_Id;
  92       Next  : Name_To_Name_Ptr;
  93    end record;
  94
  95    procedure Set_Next (E : Name_To_Name_Ptr; Next : Name_To_Name_Ptr);
  96    function  Next     (E : Name_To_Name_Ptr) return Name_To_Name_Ptr;
  97    function  Get_Key  (E : Name_To_Name_Ptr) return Name_Id;
  98
  99    package Name_To_Name_HTable is new GNAT.Dynamic_HTables.Static_HTable
 100      (Header_Num => Header_Num,
 101       Element    => Name_To_Name,
 102       Elmt_Ptr   => Name_To_Name_Ptr,
 103       Null_Ptr   => null,
 104       Set_Next   => Set_Next,
 105       Next       => Next,
 106       Key        => Name_Id,
 107       Get_Key    => Get_Key,
 108       Hash       => Hash,
 109       Equal      => "=");
 110    --  General type for htables associating name_id to name_id. This is in
 111    --  particular used to store the values of external references.
 112
 113    type Instance_Access is access all Name_To_Name_HTable.Instance;
 114
 115    type External_References is record
 116       Refs : Instance_Access;
 117       --  External references are stored in this hash table (and manipulated
 118       --  through subprogrames in prj-ext.ads). External references are
 119       --  project-tree specific so that one can load the same tree twice but
 120       --  have two views of it, for instance.
 121    end record;
 122
 123    No_External_Refs : constant External_References := (Refs => null);
 124
 125 end Prj.Ext;