gcc/ada/prj-env.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              P R J . E N V                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package implements services for Project-aware tools, mostly related
  27 --  to the environment (configuration pragma files, path files, mapping files).
  28
  29 package Prj.Env is
  30
  31    procedure Initialize (In_Tree : Project_Tree_Ref);
  32    --  Initialize global components relative to environment variables
  33
  34    procedure Print_Sources (In_Tree : Project_Tree_Ref);
  35    --  Output the list of sources, after Project files have been scanned
  36
  37    procedure Create_Mapping (In_Tree : Project_Tree_Ref);
  38    --  Create in memory mapping from the sources of all the projects (in body
  39    --  of package Fmap), so that Osint.Find_File will find the correct path
  40    --  corresponding to a source.
  41
  42    procedure Create_Mapping_File
  43      (Project  : Project_Id;
  44       Language : Name_Id;
  45       In_Tree  : Project_Tree_Ref;
  46       Name     : out Path_Name_Type);
  47    --  Create a temporary mapping file for project Project. For each source or
  48    --  template of Language in the Project, put the mapping of its file
  49    --  name and path name in this file.
  50    --
  51    --  Implementation note: we pass a language name, not a language_index here,
  52    --  since the latter would have to match exactly the index of that language
  53    --  for the specified project, and that is not information available in
  54    --  buildgpr.adb.
  55    --
  56    --  See fmap for a description of the format of the mapping file
  57
  58    procedure Set_Mapping_File_Initial_State_To_Empty
  59      (In_Tree : Project_Tree_Ref);
  60    --  When creating a mapping file, create an empty map. This case occurs when
  61    --  run time source files are found in the project files. This only applies
  62    --  to the Ada_Only mode.
  63
  64    procedure Create_Config_Pragmas_File
  65      (For_Project          : Project_Id;
  66       In_Tree              : Project_Tree_Ref);
  67    --  If there needs to have SFN pragmas, either for non standard naming
  68    --  schemes or for individual units.
  69
  70    procedure Create_New_Path_File
  71      (In_Tree   : Project_Tree_Ref;
  72       Path_FD   : out File_Descriptor;
  73       Path_Name : out Path_Name_Type);
  74    --  Create a new temporary path file. Get the file name in Path_Name.
  75    --  The name is normally obtained by increasing the number in
  76    --  Temp_Path_File_Name by 1.
  77
  78    function Ada_Include_Path
  79      (Project : Project_Id;
  80       In_Tree : Project_Tree_Ref) return String_Access;
  81    --  Get the source search path of a Project file. For the first call,
  82    --  compute it and cache it.
  83
  84    function Ada_Include_Path
  85      (Project   : Project_Id;
  86       In_Tree   : Project_Tree_Ref;
  87       Recursive : Boolean) return String;
  88    --  Get the source search path of a Project file. If Recursive it True, get
  89    --  all the source directories of the imported and modified project files
  90    --  (recursively). If Recursive is False, just get the path for the source
  91    --  directories of Project. Note: the resulting String may be empty if there
  92    --  is no source directory in the project file.
  93
  94    function Ada_Objects_Path
  95      (Project             : Project_Id;
  96       In_Tree             : Project_Tree_Ref;
  97       Including_Libraries : Boolean := True) return String_Access;
  98    --  Get the ADA_OBJECTS_PATH of a Project file. For the first call, compute
  99    --  it and cache it. When Including_Libraries is False, do not include the
 100    --  object directories of the library projects, and do not cache the result.
 101
 102    procedure Set_Ada_Paths
 103      (Project             : Project_Id;
 104       In_Tree             : Project_Tree_Ref;
 105       Including_Libraries : Boolean);
 106    --  Set the environment variables for additional project path files, after
 107    --  creating the path files if necessary.
 108
 109    procedure Delete_All_Path_Files (In_Tree : Project_Tree_Ref);
 110    --  Delete all temporary path files that have been created by Set_Ada_Paths
 111
 112    function File_Name_Of_Library_Unit_Body
 113      (Name              : String;
 114       Project           : Project_Id;
 115       In_Tree           : Project_Tree_Ref;
 116       Main_Project_Only : Boolean := True;
 117       Full_Path         : Boolean := False) return String;
 118    --  Returns the file name of a library unit, in canonical case. Name may or
 119    --  may not have an extension (corresponding to the naming scheme of the
 120    --  project). If there is no body with this name, but there is a spec, the
 121    --  name of the spec is returned.
 122    --
 123    --  If Full_Path is False (the default), the simple file name is returned.
 124    --
 125    --  If Full_Path is True, the absolute path name is returned.
 126    --
 127    --  If neither a body nor a spec can be found, an empty string is returned.
 128    --  If Main_Project_Only is True, the unit must be an immediate source of
 129    --  Project. If it is False, it may be a source of one of its imported
 130    --  projects.
 131
 132    function Project_Of
 133      (Name         : String;
 134       Main_Project : Project_Id;
 135       In_Tree      : Project_Tree_Ref) return Project_Id;
 136    --  Get the project of a source. The source file name may be truncated
 137    --  (".adb" or ".ads" may be missing). If the source is in a project being
 138    --  extended, return the ultimate extending project. If it is not a source
 139    --  of any project, return No_Project.
 140
 141    procedure Get_Reference
 142      (Source_File_Name : String;
 143       In_Tree          : Project_Tree_Ref;
 144       Project          : out Project_Id;
 145       Path             : out Path_Name_Type);
 146    --  Returns the project of a source and its path in displayable form
 147
 148    generic
 149       with procedure Action (Path : String);
 150    procedure For_All_Source_Dirs
 151      (Project : Project_Id;
 152       In_Tree : Project_Tree_Ref);
 153    --  Iterate through all the source directories of a project, including those
 154    --  of imported or modified projects.
 155    --  Only returns those directories that potentially contain Ada sources (ie
 156    --  ignore projects that have no Ada sources
 157
 158    generic
 159       with procedure Action (Path : String);
 160    procedure For_All_Object_Dirs (Project : Project_Id);
 161    --  Iterate through all the object directories of a project, including
 162    --  those of imported or modified projects.
 163
 164 end Prj.Env;